src/compiler/knownfun.lisp

   1 ;;;; This file contains stuff for maintaining a database of special
   2 ;;;; information about functions known to the compiler. This includes
   3 ;;;; semantic information such as side effects and type inference
   4 ;;;; functions as well as transforms and IR2 translators.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!C")
  16
  17 (/show0 "knownfun.lisp 17")
  18
  19 ;;; IR1 boolean function attributes
  20 ;;;
  21 ;;; There are a number of boolean attributes of known functions which
  22 ;;; we like to have in IR1. This information is mostly side effect
  23 ;;; information of a sort, but it is different from the kind of
  24 ;;; information we want in IR2. We aren't interested in a fine
  25 ;;; breakdown of side effects, since we do very little code motion on
  26 ;;; IR1. We are interested in some deeper semantic properties such as
  27 ;;; whether it is safe to pass stack closures to.
  28 ;;;
  29 ;;; FIXME: This whole notion of "bad" explicit attributes is bad for
  30 ;;; maintenance. How confident are we that we have no defknowns for functions
  31 ;;; with functional arguments that are missing the CALL attribute? Much better
  32 ;;; to have NO-CALLS, as it is much less likely to break accidentally.
  33 (!def-boolean-attribute ir1
  34   ;; may call functions that are passed as arguments. In order to
  35   ;; determine what other effects are present, we must find the
  36   ;; effects of all arguments that may be functions.
  37   call
  38   ;; may fail to return during correct execution. Errors are O.K.
  39   ;; UNUSED, BEWARE OF BITROT.
  40   unwind
  41   ;; the (default) worst case. Includes all the other bad things, plus
  42   ;; any other possible bad thing. If this is present, the above bad
  43   ;; attributes will be explicitly present as well.
  44   any
  45   ;; all arguments are safe for dynamic extent.
  46   ;; (We used to have an UNSAFE attribute, which was basically the inverse
  47   ;; of this, but it was unused and bitrotted, so when we started making
  48   ;; use of the information we flipped the name and meaning the safe way
  49   ;; around.)
  50   dx-safe
  51   ;; may be constant-folded. The function has no side effects, but may
  52   ;; be affected by side effects on the arguments. e.g. SVREF, MAPC.
  53   ;; Functions that side-effect their arguments are not considered to
  54   ;; be foldable. Although it would be "legal" to constant fold them
  55   ;; (since it "is an error" to modify a constant), we choose not to
  56   ;; mark these functions as foldable in this database.
  57   foldable
  58   ;; may be eliminated if value is unused. The function has no side
  59   ;; effects except possibly cons. If a function might signal errors,
  60   ;; then it is not flushable even if it is movable, foldable or
  61   ;; unsafely-flushable. Implies UNSAFELY-FLUSHABLE. (In safe code
  62   ;; type checking of arguments is always performed by the caller, so
  63   ;; a function which SHOULD signal an error if arguments are not of
  64   ;; declared types may be FLUSHABLE.)
  65   flushable
  66   ;; unsafe call may be eliminated if value is unused. The function
  67   ;; has no side effects except possibly cons and signalling an error
  68   ;; in the safe code. If a function MUST signal errors, then it is
  69   ;; not unsafely-flushable even if it is movable or foldable.
  70   unsafely-flushable
  71   ;; return value is important, and ignoring it is probably a mistake.
  72   ;; Unlike the other attributes, this is used only for style
  73   ;; warnings and has no effect on optimization.
  74   important-result
  75   ;; may be moved with impunity. Has no side effects except possibly
  76   ;; consing, and is affected only by its arguments.
  77   ;; UNUSED, BEWARE OF BITROT.
  78   movable
  79   ;; The function is a true predicate likely to be open-coded. Convert
  80   ;; any non-conditional uses into (IF <pred> T NIL). Not usually
  81   ;; specified to DEFKNOWN, since this is implementation dependent,
  82   ;; and is usually automatically set by the DEFINE-VOP :CONDITIONAL
  83   ;; option.
  84   predicate
  85   ;; Inhibit any warning for compiling a recursive definition.
  86   ;; (Normally the compiler warns when compiling a recursive
  87   ;; definition for a known function, since it might be a botched
  88   ;; interpreter stub.)
  89   recursive
  90   ;; The function does explicit argument type checking, so the
  91   ;; declared type should not be asserted when a definition is
  92   ;; compiled.
  93   explicit-check
  94   ;; The function should always be translated by a VOP (i.e. it should
  95   ;; should never be converted into a full call).  This is used strictly
  96   ;; as a consistency checking mechanism inside the compiler during IR2
  97   ;; transformation.
  98   always-translatable)
  99
 100 (defstruct (fun-info #-sb-xc-host (:pure t))
 101   ;; boolean attributes of this function.
 102   (attributes (missing-arg) :type attributes)
 103   ;; TRANSFORM structures describing transforms for this function
 104   (transforms () :type list)
 105   ;; a function which computes the derived type for a call to this
 106   ;; function by examining the arguments. This is null when there is
 107   ;; no special method for this function.
 108   (derive-type nil :type (or function null))
 109   ;; a function that does various unspecified code transformations by
 110   ;; directly hacking the IR. Returns true if further optimizations of
 111   ;; the call shouldn't be attempted.
 112   ;;
 113   ;; KLUDGE: This return convention (non-NIL if you shouldn't do
 114   ;; further optimiz'ns) is backwards from the return convention for
 115   ;; transforms. -- WHN 19990917
 116   (optimizer nil :type (or function null))
 117   ;; a function computing the constant or literal arguments which are
 118   ;; destructively modified by the call.
 119   (destroyed-constant-args nil :type (or function null))
 120   ;; If true, a special-case LTN annotation method that is used in
 121   ;; place of the standard type/policy template selection. It may use
 122   ;; arbitrary code to choose a template, decide to do a full call, or
 123   ;; conspire with the IR2-CONVERT method to do almost anything. The
 124   ;; COMBINATION node is passed as the argument.
 125   (ltn-annotate nil :type (or function null))
 126   ;; If true, the special-case IR2 conversion method for this
 127   ;; function. This deals with funny functions, and anything else that
 128   ;; can't be handled using the template mechanism. The COMBINATION
 129   ;; node and the IR2-BLOCK are passed as arguments.
 130   (ir2-convert nil :type (or function null))
 131   ;; If true, the function can stack-allocate the result. The
 132   ;; COMBINATION node is passed as an argument.
 133   (stack-allocate-result nil :type (or function null))
 134   ;; all the templates that could be used to translate this function
 135   ;; into IR2, sorted by increasing cost.
 136   (templates nil :type list)
 137   ;; If non-null, then this function is a unary type predicate for
 138   ;; this type.
 139   (predicate-type nil :type (or ctype null))
 140   ;; If non-null, the index of the argument which becomes the result
 141   ;; of the function.
 142   (result-arg nil :type (or index null)))
 143
 144 (defprinter (fun-info)
 145   (attributes :test (not (zerop attributes))
 146               :prin1 (decode-ir1-attributes attributes))
 147   (transforms :test transforms)
 148   (derive-type :test derive-type)
 149   (optimizer :test optimizer)
 150   (ltn-annotate :test ltn-annotate)
 151   (ir2-convert :test ir2-convert)
 152   (templates :test templates)
 153   (predicate-type :test predicate-type))
 154 \f
 155 ;;;; interfaces to defining macros
 156
 157 ;;; an IR1 transform
 158 (defstruct (transform (:copier nil))
 159   ;; the function type which enables this transform.
 160   ;;
 161   ;; (Note that declaring this :TYPE FUN-TYPE probably wouldn't
 162   ;; work because some function types, like (SPECIFIER-TYPE 'FUNCTION0
 163   ;; itself, are represented as BUILT-IN-TYPE, and at least as of
 164   ;; sbcl-0.pre7.54 or so, that's inconsistent with being a
 165   ;; FUN-TYPE.)
 166   (type (missing-arg) :type ctype)
 167   ;; the transformation function. Takes the COMBINATION node and
 168   ;; returns a lambda expression, or throws out.
 169   (function (missing-arg) :type function)
 170   ;; string used in efficiency notes
 171   (note (missing-arg) :type string)
 172   ;; T if we should emit a failure note even if SPEED=INHIBIT-WARNINGS.
 173   (important nil :type (member t nil)))
 174
 175 (defprinter (transform) type note important)
 176
 177 ;;; Grab the FUN-INFO and enter the function, replacing any old
 178 ;;; one with the same type and note.
 179 (declaim (ftype (function (t list function &optional (or string null)
 180                              (member t nil))
 181                           *)
 182                 %deftransform))
 183 (defun %deftransform (name type fun &optional note important)
 184   (let* ((ctype (specifier-type type))
 185          (note (or note "optimize"))
 186          (info (fun-info-or-lose name))
 187          (old (find-if (lambda (x)
 188                          (and (type= (transform-type x) ctype)
 189                               (string-equal (transform-note x) note)
 190                               (eq (transform-important x) important)))
 191                        (fun-info-transforms info))))
 192     (cond (old
 193            (style-warn 'sb!kernel:redefinition-with-deftransform
 194                        :transform old)
 195            (setf (transform-function old) fun
 196                  (transform-note old) note))
 197           (t
 198            (push (make-transform :type ctype :function fun :note note
 199                                  :important important)
 200                  (fun-info-transforms info))))
 201     name))
 202
 203 ;;; Make a FUN-INFO structure with the specified type, attributes
 204 ;;; and optimizers.
 205 (declaim (ftype (function (list list attributes &key
 206                                 (:derive-type (or function null))
 207                                 (:optimizer (or function null))
 208                                 (:destroyed-constant-args (or function null))
 209                                 (:result-arg (or index null)))
 210                           *)
 211                 %defknown))
 212 (defun %defknown (names type attributes &key derive-type optimizer destroyed-constant-args result-arg)
 213   (let ((ctype (specifier-type type))
 214         (info (make-fun-info :attributes attributes
 215                              :derive-type derive-type
 216                              :optimizer optimizer
 217                              :destroyed-constant-args destroyed-constant-args
 218                              :result-arg result-arg)))
 219     (dolist (name names)
 220       (let ((old-fun-info (info :function :info name)))
 221         (when old-fun-info
 222           ;; This is handled as an error because it's generally a bad
 223           ;; thing to blow away all the old optimization stuff. It's
 224           ;; also a potential source of sneaky bugs:
 225           ;;    DEFKNOWN FOO
 226           ;;    DEFTRANSFORM FOO
 227           ;;    DEFKNOWN FOO ; possibly hidden inside some macroexpansion
 228           ;;    ; Now the DEFTRANSFORM doesn't exist in the target Lisp.
 229           ;; However, it's continuable because it might be useful to do
 230           ;; it when testing new optimization stuff interactively.
 231           (cerror "Go ahead, overwrite it."
 232                   "~@<overwriting old FUN-INFO ~2I~_~S ~I~_for ~S~:>"
 233                   old-fun-info name)))
 234       (setf (info :function :type name) ctype)
 235       (setf (info :function :where-from name) :declared)
 236       (setf (info :function :kind name) :function)
 237       (setf (info :function :info name) info)))
 238   names)
 239
 240 ;;; Return the FUN-INFO for NAME or die trying. Since this is
 241 ;;; used by callers who want to modify the info, and the info may be
 242 ;;; shared, we copy it. We don't have to copy the lists, since each
 243 ;;; function that has generators or transforms has already been
 244 ;;; through here.
 245 (declaim (ftype (sfunction (t) fun-info) fun-info-or-lose))
 246 (defun fun-info-or-lose (name)
 247   (let (;; FIXME: Do we need this rebinding here? It's a literal
 248         ;; translation of the old CMU CL rebinding to
 249         ;; (OR *BACKEND-INFO-ENVIRONMENT* *INFO-ENVIRONMENT*),
 250         ;; and it's not obvious whether the rebinding to itself is
 251         ;; needed that SBCL doesn't need *BACKEND-INFO-ENVIRONMENT*.
 252         (*info-environment* *info-environment*))
 253     (let ((old (info :function :info name)))
 254       (unless old (error "~S is not a known function." name))
 255       (setf (info :function :info name) (copy-fun-info old)))))
 256 \f
 257 ;;;; generic type inference methods
 258
 259 ;;; Derive the type to be the type of the xxx'th arg. This can normally
 260 ;;; only be done when the result value is that argument.
 261 (defun result-type-first-arg (call)
 262   (declare (type combination call))
 263   (let ((lvar (first (combination-args call))))
 264     (when lvar (lvar-type lvar))))
 265 (defun result-type-last-arg (call)
 266   (declare (type combination call))
 267   (let ((lvar (car (last (combination-args call)))))
 268     (when lvar (lvar-type lvar))))
 269
 270 ;;; Derive the result type according to the float contagion rules, but
 271 ;;; always return a float. This is used for irrational functions that
 272 ;;; preserve realness of their arguments.
 273 (defun result-type-float-contagion (call)
 274   (declare (type combination call))
 275   (reduce #'numeric-contagion (combination-args call)
 276           :key #'lvar-type
 277           :initial-value (specifier-type 'single-float)))
 278
 279 ;;; Return a closure usable as a derive-type method for accessing the
 280 ;;; N'th argument. If arg is a list, result is a list. If arg is a
 281 ;;; vector, result is a vector with the same element type.
 282 (defun sequence-result-nth-arg (n)
 283   (lambda (call)
 284     (declare (type combination call))
 285     (let ((lvar (nth (1- n) (combination-args call))))
 286       (when lvar
 287         (let ((type (lvar-type lvar)))
 288           (if (array-type-p type)
 289               (specifier-type
 290                `(vector ,(type-specifier (array-type-element-type type))))
 291               (let ((ltype (specifier-type 'list)))
 292                 (when (csubtypep type ltype)
 293                   ltype))))))))
 294
 295 ;;; Derive the type to be the type specifier which is the Nth arg.
 296 (defun result-type-specifier-nth-arg (n)
 297   (lambda (call)
 298     (declare (type combination call))
 299     (let ((lvar (nth (1- n) (combination-args call))))
 300       (when (and lvar (constant-lvar-p lvar))
 301         (careful-specifier-type (lvar-value lvar))))))
 302
 303 ;;; Derive the type to be the type specifier which is the Nth arg,
 304 ;;; with the additional restriptions noted in the CLHS for STRING and
 305 ;;; SIMPLE-STRING, defined to specialize on CHARACTER, and for VECTOR
 306 ;;; (under the page for MAKE-SEQUENCE).
 307 (defun creation-result-type-specifier-nth-arg (n)
 308   (lambda (call)
 309     (declare (type combination call))
 310     (let ((lvar (nth (1- n) (combination-args call))))
 311       (when (and lvar (constant-lvar-p lvar))
 312         (let* ((specifier (lvar-value lvar))
 313                (lspecifier (if (atom specifier) (list specifier) specifier)))
 314           (cond
 315             ((eq (car lspecifier) 'string)
 316              (destructuring-bind (string &rest size)
 317                  lspecifier
 318                (declare (ignore string))
 319                (careful-specifier-type
 320                 `(vector character ,@(when size size)))))
 321             ((eq (car lspecifier) 'simple-string)
 322              (destructuring-bind (simple-string &rest size)
 323                  lspecifier
 324                (declare (ignore simple-string))
 325                (careful-specifier-type
 326                 `(simple-array character ,@(if size (list size) '((*)))))))
 327             (t
 328              (let ((ctype (careful-specifier-type specifier)))
 329                (if (and (array-type-p ctype)
 330                         (eq (array-type-specialized-element-type ctype)
 331                             *wild-type*))
 332                    ;; I don't think I'm allowed to modify what I get
 333                    ;; back from SPECIFIER-TYPE; it is, after all,
 334                    ;; cached.  Better copy it, then.
 335                    (let ((real-ctype (copy-structure ctype)))
 336                      (setf (array-type-element-type real-ctype)
 337                            *universal-type*
 338                            (array-type-specialized-element-type real-ctype)
 339                            *universal-type*)
 340                      real-ctype)
 341                    ctype)))))))))
 342
 343 (defun remove-non-constants-and-nils (fun)
 344   (lambda (list)
 345     (remove-if-not #'lvar-value
 346                    (remove-if-not #'constant-lvar-p (funcall fun list)))))
 347
 348 ;;; FIXME: bad name (first because it uses 1-based indexing; second
 349 ;;; because it doesn't get the nth constant arguments)
 350 (defun nth-constant-args (&rest indices)
 351   (lambda (list)
 352     (let (result)
 353       (do ((i 1 (1+ i))
 354            (list list (cdr list))
 355            (indices indices))
 356           ((null indices) (nreverse result))
 357         (when (= i (car indices))
 358           (when (constant-lvar-p (car list))
 359             (push (car list) result))
 360           (setf indices (cdr indices)))))))
 361
 362 ;;; FIXME: a number of the sequence functions not only do not destroy
 363 ;;; their argument if it is empty, but also leave it alone if :start
 364 ;;; and :end bound a null sequence, or if :count is 0.  This test is a
 365 ;;; bit complicated to implement, verging on the impossible, but for
 366 ;;; extra points (fill #\1 "abc" :start 0 :end 0) should not cause a
 367 ;;; warning.
 368 (defun nth-constant-nonempty-sequence-args (&rest indices)
 369   (lambda (list)
 370     (let (result)
 371       (do ((i 1 (1+ i))
 372            (list list (cdr list))
 373            (indices indices))
 374           ((null indices) (nreverse result))
 375         (when (= i (car indices))
 376           (when (constant-lvar-p (car list))
 377             (let ((value (lvar-value (car list))))
 378               (unless (or (typep value 'null)
 379                           (typep value '(vector * 0)))
 380                 (push (car list) result))))
 381           (setf indices (cdr indices)))))))
 382
 383 (/show0 "knownfun.lisp end of file")