src/compiler/knownfun.lisp

   1 ;;;; This file contains stuff for maintaining a database of special
   2 ;;;; information about functions known to the compiler. This includes
   3 ;;;; semantic information such as side effects and type inference
   4 ;;;; functions as well as transforms and IR2 translators.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!C")
  16
  17 (/show0 "knownfun.lisp 17")
  18
  19 ;;; IR1 boolean function attributes
  20 ;;;
  21 ;;; There are a number of boolean attributes of known functions which
  22 ;;; we like to have in IR1. This information is mostly side effect
  23 ;;; information of a sort, but it is different from the kind of
  24 ;;; information we want in IR2. We aren't interested in a fine
  25 ;;; breakdown of side effects, since we do very little code motion on
  26 ;;; IR1. We are interested in some deeper semantic properties such as
  27 ;;; whether it is safe to pass stack closures to.
  28 (!def-boolean-attribute ir1
  29   ;; may call functions that are passed as arguments. In order to
  30   ;; determine what other effects are present, we must find the
  31   ;; effects of all arguments that may be functions.
  32   call
  33   ;; may incorporate function or number arguments into the result or
  34   ;; somehow pass them upward. Note that this applies to any argument
  35   ;; that *might* be a function or number, not just the arguments that
  36   ;; always are.
  37   unsafe
  38   ;; may fail to return during correct execution. Errors are O.K.
  39   unwind
  40   ;; the (default) worst case. Includes all the other bad things, plus
  41   ;; any other possible bad thing. If this is present, the above bad
  42   ;; attributes will be explicitly present as well.
  43   any
  44   ;; may be constant-folded. The function has no side effects, but may
  45   ;; be affected by side effects on the arguments. e.g. SVREF, MAPC.
  46   ;; Functions that side-effect their arguments are not considered to
  47   ;; be foldable. Although it would be "legal" to constant fold them
  48   ;; (since it "is an error" to modify a constant), we choose not to
  49   ;; mark these functions as foldable in this database.
  50   foldable
  51   ;; may be eliminated if value is unused. The function has no side
  52   ;; effects except possibly cons. If a function might signal errors,
  53   ;; then it is not flushable even if it is movable, foldable or
  54   ;; unsafely-flushable. Implies UNSAFELY-FLUSHABLE. (In safe code
  55   ;; type checking of arguments is always performed by the caller, so
  56   ;; a function which SHOULD signal an error if arguments are not of
  57   ;; declared types may be FLUSHABLE.)
  58   flushable
  59   ;; unsafe call may be eliminated if value is unused. The function
  60   ;; has no side effects except possibly cons and signalling an error
  61   ;; in the safe code. If a function MUST signal errors, then it is
  62   ;; not unsafely-flushable even if it is movable or foldable.
  63   unsafely-flushable
  64   ;; may be moved with impunity. Has no side effects except possibly
  65   ;; consing, and is affected only by its arguments.
  66   ;;
  67   ;; Since it is not used now, its distribution in fndb.lisp is
  68   ;; mere random; use with caution.
  69   movable
  70   ;; The function is a true predicate likely to be open-coded. Convert
  71   ;; any non-conditional uses into (IF <pred> T NIL). Not usually
  72   ;; specified to DEFKNOWN, since this is implementation dependent,
  73   ;; and is usually automatically set by the DEFINE-VOP :CONDITIONAL
  74   ;; option.
  75   predicate
  76   ;; Inhibit any warning for compiling a recursive definition.
  77   ;; (Normally the compiler warns when compiling a recursive
  78   ;; definition for a known function, since it might be a botched
  79   ;; interpreter stub.)
  80   recursive
  81   ;; The function does explicit argument type checking, so the
  82   ;; declared type should not be asserted when a definition is
  83   ;; compiled.
  84   explicit-check)
  85
  86 (defstruct (fun-info #-sb-xc-host (:pure t))
  87   ;; boolean attributes of this function.
  88   (attributes (missing-arg) :type attributes)
  89   ;; TRANSFORM structures describing transforms for this function
  90   (transforms () :type list)
  91   ;; a function which computes the derived type for a call to this
  92   ;; function by examining the arguments. This is null when there is
  93   ;; no special method for this function.
  94   (derive-type nil :type (or function null))
  95   ;; a function that does various unspecified code transformations by
  96   ;; directly hacking the IR. Returns true if further optimizations of
  97   ;; the call shouldn't be attempted.
  98   ;;
  99   ;; KLUDGE: This return convention (non-NIL if you shouldn't do
 100   ;; further optimiz'ns) is backwards from the return convention for
 101   ;; transforms. -- WHN 19990917
 102   (optimizer nil :type (or function null))
 103   ;; a function computing the constant or literal arguments which are
 104   ;; destructively modified by the call.
 105   (destroyed-constant-args nil :type (or function null))
 106   ;; If true, a special-case LTN annotation method that is used in
 107   ;; place of the standard type/policy template selection. It may use
 108   ;; arbitrary code to choose a template, decide to do a full call, or
 109   ;; conspire with the IR2-CONVERT method to do almost anything. The
 110   ;; COMBINATION node is passed as the argument.
 111   (ltn-annotate nil :type (or function null))
 112   ;; If true, the special-case IR2 conversion method for this
 113   ;; function. This deals with funny functions, and anything else that
 114   ;; can't be handled using the template mechanism. The COMBINATION
 115   ;; node and the IR2-BLOCK are passed as arguments.
 116   (ir2-convert nil :type (or function null))
 117   ;; If true, the function can stack-allocate the result. The
 118   ;; COMBINATION node is passed as an argument.
 119   (stack-allocate-result nil :type (or function null))
 120   ;; all the templates that could be used to translate this function
 121   ;; into IR2, sorted by increasing cost.
 122   (templates nil :type list)
 123   ;; If non-null, then this function is a unary type predicate for
 124   ;; this type.
 125   (predicate-type nil :type (or ctype null)))
 126
 127 (defprinter (fun-info)
 128   (attributes :test (not (zerop attributes))
 129               :prin1 (decode-ir1-attributes attributes))
 130   (transforms :test transforms)
 131   (derive-type :test derive-type)
 132   (optimizer :test optimizer)
 133   (ltn-annotate :test ltn-annotate)
 134   (ir2-convert :test ir2-convert)
 135   (templates :test templates)
 136   (predicate-type :test predicate-type))
 137 \f
 138 ;;;; interfaces to defining macros
 139
 140 ;;; an IR1 transform
 141 (defstruct (transform (:copier nil))
 142   ;; the function type which enables this transform.
 143   ;;
 144   ;; (Note that declaring this :TYPE FUN-TYPE probably wouldn't
 145   ;; work because some function types, like (SPECIFIER-TYPE 'FUNCTION0
 146   ;; itself, are represented as BUILT-IN-TYPE, and at least as of
 147   ;; sbcl-0.pre7.54 or so, that's inconsistent with being a
 148   ;; FUN-TYPE.)
 149   (type (missing-arg) :type ctype)
 150   ;; the transformation function. Takes the COMBINATION node and
 151   ;; returns a lambda expression, or throws out.
 152   (function (missing-arg) :type function)
 153   ;; string used in efficiency notes
 154   (note (missing-arg) :type string)
 155   ;; T if we should emit a failure note even if SPEED=INHIBIT-WARNINGS.
 156   (important nil :type (member t nil)))
 157
 158 (defprinter (transform) type note important)
 159
 160 ;;; Grab the FUN-INFO and enter the function, replacing any old
 161 ;;; one with the same type and note.
 162 (declaim (ftype (function (t list function &optional (or string null)
 163                              (member t nil))
 164                           *)
 165                 %deftransform))
 166 (defun %deftransform (name type fun &optional note important)
 167   (let* ((ctype (specifier-type type))
 168          (note (or note "optimize"))
 169          (info (fun-info-or-lose name))
 170          (old (find-if (lambda (x)
 171                          (and (type= (transform-type x) ctype)
 172                               (string-equal (transform-note x) note)
 173                               (eq (transform-important x) important)))
 174                        (fun-info-transforms info))))
 175     (cond (old
 176            (style-warn "Overwriting ~S" old)
 177            (setf (transform-function old) fun
 178                  (transform-note old) note))
 179           (t
 180            (push (make-transform :type ctype :function fun :note note
 181                                  :important important)
 182                  (fun-info-transforms info))))
 183     name))
 184
 185 ;;; Make a FUN-INFO structure with the specified type, attributes
 186 ;;; and optimizers.
 187 (declaim (ftype (function (list list attributes &key
 188                                 (:derive-type (or function null))
 189                                 (:optimizer (or function null))
 190                                 (:destroyed-constant-args (or function null)))
 191                           *)
 192                 %defknown))
 193 (defun %defknown (names type attributes &key derive-type optimizer destroyed-constant-args)
 194   (let ((ctype (specifier-type type))
 195         (info (make-fun-info :attributes attributes
 196                              :derive-type derive-type
 197                              :optimizer optimizer
 198                              :destroyed-constant-args destroyed-constant-args))
 199         (target-env *info-environment*))
 200     (dolist (name names)
 201       (let ((old-fun-info (info :function :info name)))
 202         (when old-fun-info
 203           ;; This is handled as an error because it's generally a bad
 204           ;; thing to blow away all the old optimization stuff. It's
 205           ;; also a potential source of sneaky bugs:
 206           ;;    DEFKNOWN FOO
 207           ;;    DEFTRANSFORM FOO
 208           ;;    DEFKNOWN FOO ; possibly hidden inside some macroexpansion
 209           ;;    ; Now the DEFTRANSFORM doesn't exist in the target Lisp.
 210           ;; However, it's continuable because it might be useful to do
 211           ;; it when testing new optimization stuff interactively.
 212           (cerror "Go ahead, overwrite it."
 213                   "~@<overwriting old FUN-INFO ~2I~_~S ~I~_for ~S~:>"
 214                   old-fun-info name)))
 215       (setf (info :function :type name target-env) ctype)
 216       (setf (info :function :where-from name target-env) :declared)
 217       (setf (info :function :kind name target-env) :function)
 218       (setf (info :function :info name target-env) info)))
 219   names)
 220
 221 ;;; Return the FUN-INFO for NAME or die trying. Since this is
 222 ;;; used by callers who want to modify the info, and the info may be
 223 ;;; shared, we copy it. We don't have to copy the lists, since each
 224 ;;; function that has generators or transforms has already been
 225 ;;; through here.
 226 (declaim (ftype (sfunction (t) fun-info) fun-info-or-lose))
 227 (defun fun-info-or-lose (name)
 228   (let (;; FIXME: Do we need this rebinding here? It's a literal
 229         ;; translation of the old CMU CL rebinding to
 230         ;; (OR *BACKEND-INFO-ENVIRONMENT* *INFO-ENVIRONMENT*),
 231         ;; and it's not obvious whether the rebinding to itself is
 232         ;; needed that SBCL doesn't need *BACKEND-INFO-ENVIRONMENT*.
 233         (*info-environment* *info-environment*))
 234     (let ((old (info :function :info name)))
 235       (unless old (error "~S is not a known function." name))
 236       (setf (info :function :info name) (copy-fun-info old)))))
 237 \f
 238 ;;;; generic type inference methods
 239
 240 ;;; Derive the type to be the type of the xxx'th arg. This can normally
 241 ;;; only be done when the result value is that argument.
 242 (defun result-type-first-arg (call)
 243   (declare (type combination call))
 244   (let ((lvar (first (combination-args call))))
 245     (when lvar (lvar-type lvar))))
 246 (defun result-type-last-arg (call)
 247   (declare (type combination call))
 248   (let ((lvar (car (last (combination-args call)))))
 249     (when lvar (lvar-type lvar))))
 250
 251 ;;; Derive the result type according to the float contagion rules, but
 252 ;;; always return a float. This is used for irrational functions that
 253 ;;; preserve realness of their arguments.
 254 (defun result-type-float-contagion (call)
 255   (declare (type combination call))
 256   (reduce #'numeric-contagion (combination-args call)
 257           :key #'lvar-type
 258           :initial-value (specifier-type 'single-float)))
 259
 260 ;;; Return a closure usable as a derive-type method for accessing the
 261 ;;; N'th argument. If arg is a list, result is a list. If arg is a
 262 ;;; vector, result is a vector with the same element type.
 263 (defun sequence-result-nth-arg (n)
 264   (lambda (call)
 265     (declare (type combination call))
 266     (let ((lvar (nth (1- n) (combination-args call))))
 267       (when lvar
 268         (let ((type (lvar-type lvar)))
 269           (if (array-type-p type)
 270               (specifier-type
 271                `(vector ,(type-specifier (array-type-element-type type))))
 272               (let ((ltype (specifier-type 'list)))
 273                 (when (csubtypep type ltype)
 274                   ltype))))))))
 275
 276 ;;; Derive the type to be the type specifier which is the Nth arg.
 277 (defun result-type-specifier-nth-arg (n)
 278   (lambda (call)
 279     (declare (type combination call))
 280     (let ((lvar (nth (1- n) (combination-args call))))
 281       (when (and lvar (constant-lvar-p lvar))
 282         (careful-specifier-type (lvar-value lvar))))))
 283
 284 ;;; Derive the type to be the type specifier which is the Nth arg,
 285 ;;; with the additional restriptions noted in the CLHS for STRING and
 286 ;;; SIMPLE-STRING, defined to specialize on CHARACTER, and for VECTOR
 287 ;;; (under the page for MAKE-SEQUENCE).
 288 (defun creation-result-type-specifier-nth-arg (n)
 289   (lambda (call)
 290     (declare (type combination call))
 291     (let ((lvar (nth (1- n) (combination-args call))))
 292       (when (and lvar (constant-lvar-p lvar))
 293         (let* ((specifier (lvar-value lvar))
 294                (lspecifier (if (atom specifier) (list specifier) specifier)))
 295           (cond
 296             ((eq (car lspecifier) 'string)
 297              (destructuring-bind (string &rest size)
 298                  lspecifier
 299                (declare (ignore string))
 300                (careful-specifier-type
 301                 `(vector character ,@(when size size)))))
 302             ((eq (car lspecifier) 'simple-string)
 303              (destructuring-bind (simple-string &rest size)
 304                  lspecifier
 305                (declare (ignore simple-string))
 306                (careful-specifier-type
 307                 `(simple-array character ,@(if size (list size) '((*)))))))
 308             (t
 309              (let ((ctype (careful-specifier-type specifier)))
 310                (if (and (array-type-p ctype)
 311                         (eq (array-type-specialized-element-type ctype)
 312                             *wild-type*))
 313                    ;; I don't think I'm allowed to modify what I get
 314                    ;; back from SPECIFIER-TYPE; it is, after all,
 315                    ;; cached.  Better copy it, then.
 316                    (let ((real-ctype (copy-structure ctype)))
 317                      (setf (array-type-element-type real-ctype)
 318                            *universal-type*
 319                            (array-type-specialized-element-type real-ctype)
 320                            *universal-type*)
 321                      real-ctype)
 322                    ctype)))))))))
 323
 324 (defun remove-non-constants-and-nils (fun)
 325   (lambda (list)
 326     (remove-if-not #'lvar-value
 327                    (remove-if-not #'constant-lvar-p (funcall fun list)))))
 328
 329 ;;; FIXME: bad name (first because it uses 1-based indexing; second
 330 ;;; because it doesn't get the nth constant arguments)
 331 (defun nth-constant-args (&rest indices)
 332   (lambda (list)
 333     (let (result)
 334       (do ((i 1 (1+ i))
 335            (list list (cdr list))
 336            (indices indices))
 337           ((null indices) (nreverse result))
 338         (when (= i (car indices))
 339           (when (constant-lvar-p (car list))
 340             (push (car list) result))
 341           (setf indices (cdr indices)))))))
 342
 343 ;;; FIXME: a number of the sequence functions not only do not destroy
 344 ;;; their argument if it is empty, but also leave it alone if :start
 345 ;;; and :end bound a null sequence, or if :count is 0.  This test is a
 346 ;;; bit complicated to implement, verging on the impossible, but for
 347 ;;; extra points (fill #\1 "abc" :start 0 :end 0) should not cause a
 348 ;;; warning.
 349 (defun nth-constant-nonempty-sequence-args (&rest indices)
 350   (lambda (list)
 351     (let (result)
 352       (do ((i 1 (1+ i))
 353            (list list (cdr list))
 354            (indices indices))
 355           ((null indices) (nreverse result))
 356         (when (= i (car indices))
 357           (when (constant-lvar-p (car list))
 358             (let ((value (lvar-value (car list))))
 359               (unless (or (typep value 'null)
 360                           (typep value '(vector * 0)))
 361                 (push (car list) result))))
 362           (setf indices (cdr indices)))))))
 363
 364 (/show0 "knownfun.lisp end of file")