src/compiler/knownfun.lisp

   1 ;;;; This file contains stuff for maintaining a database of special
   2 ;;;; information about functions known to the compiler. This includes
   3 ;;;; semantic information such as side-effects and type inference
   4 ;;;; functions as well as transforms and IR2 translators.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!C")
  16
  17 (/show0 "knownfun.lisp 17")
  18
  19 ;;; IR1 boolean function attributes
  20 ;;;
  21 ;;; There are a number of boolean attributes of known functions which we like
  22 ;;; to have in IR1. This information is mostly side effect information of a
  23 ;;; sort, but it is different from the kind of information we want in IR2. We
  24 ;;; aren't interested in a fine breakdown of side effects, since we do very
  25 ;;; little code motion on IR1. We are interested in some deeper semantic
  26 ;;; properties such as whether it is safe to pass stack closures to.
  27 (def-boolean-attribute ir1
  28   ;; May call functions that are passed as arguments. In order to determine
  29   ;; what other effects are present, we must find the effects of all arguments
  30   ;; that may be functions.
  31   call
  32   ;; May incorporate function or number arguments into the result or somehow
  33   ;; pass them upward. Note that this applies to any argument that *might* be
  34   ;; a function or number, not just the arguments that always are.
  35   unsafe
  36   ;; May fail to return during correct execution. Errors are O.K.
  37   unwind
  38   ;; The (default) worst case. Includes all the other bad things, plus any
  39   ;; other possible bad thing. If this is present, the above bad attributes
  40   ;; will be explicitly present as well.
  41   any
  42   ;; May be constant-folded. The function has no side effects, but may be
  43   ;; affected by side effects on the arguments. e.g. SVREF, MAPC. Functions
  44   ;; that side-effect their arguments are not considered to be foldable.
  45   ;; Although it would be "legal" to constant fold them (since it "is an error"
  46   ;; to modify a constant), we choose not to mark these functions as foldable
  47   ;; in this database.
  48   foldable
  49   ;; May be eliminated if value is unused. The function has no side effects
  50   ;; except possibly CONS. If a function is defined to signal errors, then it
  51   ;; is not flushable even if it is movable or foldable.
  52   flushable
  53   ;; May be moved with impunity. Has no side effects except possibly CONS, and
  54   ;; is affected only by its arguments.
  55   movable
  56   ;; Function is a true predicate likely to be open-coded. Convert any
  57   ;; non-conditional uses into (IF <pred> T NIL).
  58   predicate
  59   ;; Inhibit any warning for compiling a recursive definition. (Normally the
  60   ;; compiler warns when compiling a recursive definition for a known function,
  61   ;; since it might be a botched interpreter stub.)
  62   recursive
  63   ;; Function does explicit argument type checking, so the declared type should
  64   ;; not be asserted when a definition is compiled.
  65   explicit-check)
  66
  67 (defstruct (function-info #-sb-xc-host (:pure t))
  68   ;; Boolean attributes of this function.
  69   (attributes (required-argument) :type attributes)
  70   ;; A list of Transform structures describing transforms for this function.
  71   (transforms () :type list)
  72   ;; A function which computes the derived type for a call to this function by
  73   ;; examining the arguments. This is null when there is no special method for
  74   ;; this function.
  75   (derive-type nil :type (or function null))
  76   ;; A function that does various unspecified code transformations by directly
  77   ;; hacking the IR. Returns true if further optimizations of the call
  78   ;; shouldn't be attempted.
  79   ;;
  80   ;; KLUDGE: This return convention (non-NIL if you shouldn't do further
  81   ;; optimiz'ns) is backwards from the return convention for transforms.
  82   ;; -- WHN 19990917
  83   (optimizer nil :type (or function null))
  84   ;; If true, a special-case LTN annotation method that is used in place of the
  85   ;; standard type/policy template selection. It may use arbitrary code to
  86   ;; choose a template, decide to do a full call, or conspire with the
  87   ;; IR2-Convert method to do almost anything. The Combination node is passed
  88   ;; as the argument.
  89   (ltn-annotate nil :type (or function null))
  90   ;; If true, the special-case IR2 conversion method for this function. This
  91   ;; deals with funny functions, and anything else that can't be handled using
  92   ;; the template mechanism. The Combination node and the IR2-Block are passed
  93   ;; as arguments.
  94   (ir2-convert nil :type (or function null))
  95   ;; A list of all the templates that could be used to translate this function
  96   ;; into IR2, sorted by increasing cost.
  97   (templates nil :type list)
  98   ;; If non-null, then this function is a unary type predicate for this type.
  99   (predicate-type nil :type (or ctype null))
 100   ;; If non-null, use this function to annotate the known call for the byte
 101   ;; compiler. If it returns NIL, then change the call to :full.
 102   (byte-annotate nil :type (or function null)))
 103
 104 (defprinter (function-info)
 105   (transforms :test transforms)
 106   (derive-type :test derive-type)
 107   (optimizer :test optimizer)
 108   (ltn-annotate :test ltn-annotate)
 109   (ir2-convert :test ir2-convert)
 110   (templates :test templates)
 111   (predicate-type :test predicate-type)
 112   (byte-annotate :test byte-annotate))
 113 \f
 114 ;;;; interfaces to defining macros
 115
 116 ;;; an IR1 transform
 117 (defstruct (transform (:copier nil))
 118   ;; the function-type which enables this transform
 119   (type (required-argument) :type ctype)
 120   ;; the transformation function. Takes the COMBINATION node and returns a
 121   ;; lambda, or throws out.
 122   (function (required-argument) :type function)
 123   ;; string used in efficiency notes
 124   (note (required-argument) :type string)
 125   ;; T if we should emit a failure note even if SPEED=INHIBIT-WARNINGS.
 126   (important nil :type (member t nil))
 127   ;; usable for byte code, native code, or both?
 128   ;;
 129   ;; FIXME: Now that there's no byte compiler, this is stale and could
 130   ;; all go away.
 131   (when :native :type (member :byte :native :both)))
 132
 133 (defprinter (transform) type note important when)
 134
 135 ;;; Grab the FUNCTION-INFO and enter the function, replacing any old
 136 ;;; one with the same type and note.
 137 (declaim (ftype (function (t list function &optional (or string null)
 138                              (member t nil) (member :native :byte :both))
 139                           *)
 140                 %deftransform))
 141 (defun %deftransform (name type fun &optional note important (when :native))
 142   (let* ((ctype (specifier-type type))
 143          (note (or note "optimize"))
 144          (info (function-info-or-lose name))
 145          (old (find-if (lambda (x)
 146                          (and (type= (transform-type x) ctype)
 147                               (string-equal (transform-note x) note)
 148                               (eq (transform-important x) important)
 149                               (eq (transform-when x) when)))
 150                        (function-info-transforms info))))
 151     (if old
 152         (setf (transform-function old) fun
 153               (transform-note old) note)
 154         (push (make-transform :type ctype :function fun :note note
 155                               :important important :when when)
 156               (function-info-transforms info)))
 157     name))
 158
 159 ;;; Make a FUNCTION-INFO structure with the specified type, attributes
 160 ;;; and optimizers.
 161 (declaim (ftype (function (list list attributes &key
 162                                 (:derive-type (or function null))
 163                                 (:optimizer (or function null)))
 164                           *)
 165                 %defknown))
 166 (defun %defknown (names type attributes &key derive-type optimizer)
 167   (let ((ctype (specifier-type type))
 168         (info (make-function-info :attributes attributes
 169                                   :derive-type derive-type
 170                                   :optimizer optimizer))
 171         (target-env *info-environment*))
 172     (dolist (name names)
 173       (let ((old-function-info (info :function :info name)))
 174         (when old-function-info
 175           ;; This is handled as an error because it's generally a bad
 176           ;; thing to blow away all the old optimization stuff. It's
 177           ;; also a potential source of sneaky bugs:
 178           ;;    DEFKNOWN FOO
 179           ;;    DEFTRANSFORM FOO
 180           ;;    DEFKNOWN FOO ; possibly hidden inside some macroexpansion
 181           ;;    ; Now the DEFTRANSFORM doesn't exist in the target Lisp.
 182           ;; However, it's continuable because it might be useful to do
 183           ;; it when testing new optimization stuff interactively.
 184           (cerror "Go ahead, overwrite it."
 185                   "~@<overwriting old FUNCTION-INFO ~2I~_~S ~I~_for ~S~:>"
 186                   old-function-info name)))
 187       (setf (info :function :type name target-env) ctype)
 188       (setf (info :function :where-from name target-env) :declared)
 189       (setf (info :function :kind name target-env) :function)
 190       (setf (info :function :info name target-env) info)))
 191   names)
 192
 193 ;;; Return the FUNCTION-INFO for NAME or die trying. Since this is
 194 ;;; used by callers who want to modify the info, and the info may be
 195 ;;; shared, we copy it. We don't have to copy the lists, since each
 196 ;;; function that has generators or transforms has already been
 197 ;;; through here.
 198 (declaim (ftype (function (t) function-info) function-info-or-lose))
 199 (defun function-info-or-lose (name)
 200   (let (;; FIXME: Do we need this rebinding here? It's a literal
 201         ;; translation of the old CMU CL rebinding to
 202         ;; (OR *BACKEND-INFO-ENVIRONMENT* *INFO-ENVIRONMENT*),
 203         ;; and it's not obvious whether the rebinding to itself is
 204         ;; needed that SBCL doesn't need *BACKEND-INFO-ENVIRONMENT*.
 205         (*info-environment* *info-environment*))
 206     (let ((old (info :function :info name)))
 207       (unless old (error "~S is not a known function." name))
 208       (setf (info :function :info name) (copy-function-info old)))))
 209 \f
 210 ;;;; generic type inference methods
 211
 212 ;;; Derive the type to be the type of the xxx'th arg. This can normally
 213 ;;; only be done when the result value is that argument.
 214 (defun result-type-first-arg (call)
 215   (declare (type combination call))
 216   (let ((cont (first (combination-args call))))
 217     (when cont (continuation-type cont))))
 218 (defun result-type-last-arg (call)
 219   (declare (type combination call))
 220   (let ((cont (car (last (combination-args call)))))
 221     (when cont (continuation-type cont))))
 222
 223 ;;; Derive the result type according to the float contagion rules, but
 224 ;;; always return a float. This is used for irrational functions that preserve
 225 ;;; realness of their arguments.
 226 (defun result-type-float-contagion (call)
 227   (declare (type combination call))
 228   (reduce #'numeric-contagion (combination-args call)
 229           :key #'continuation-type
 230           :initial-value (specifier-type 'single-float)))
 231
 232 ;;; Return a closure usable as a derive-type method for accessing the N'th
 233 ;;; argument. If arg is a list, result is a list. If arg is a vector, result
 234 ;;; is a vector with the same element type.
 235 (defun sequence-result-nth-arg (n)
 236   #'(lambda (call)
 237       (declare (type combination call))
 238       (let ((cont (nth (1- n) (combination-args call))))
 239         (when cont
 240           (let ((type (continuation-type cont)))
 241             (if (array-type-p type)
 242                 (specifier-type
 243                  `(vector ,(type-specifier (array-type-element-type type))))
 244                 (let ((ltype (specifier-type 'list)))
 245                   (when (csubtypep type ltype)
 246                     ltype))))))))
 247
 248 ;;; Derive the type to be the type specifier which is the N'th arg.
 249 (defun result-type-specifier-nth-arg (n)
 250   (lambda (call)
 251     (declare (type combination call))
 252     (let ((cont (nth (1- n) (combination-args call))))
 253       (when (and cont (constant-continuation-p cont))
 254         (specifier-type (continuation-value cont))))))
 255
 256 (/show0 "knownfun.lisp end of file")