src/compiler/knownfun.lisp

   1 ;;;; This file contains stuff for maintaining a database of special
   2 ;;;; information about functions known to the compiler. This includes
   3 ;;;; semantic information such as side effects and type inference
   4 ;;;; functions as well as transforms and IR2 translators.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!C")
  16
  17 (/show0 "knownfun.lisp 17")
  18
  19 ;;; IR1 boolean function attributes
  20 ;;;
  21 ;;; There are a number of boolean attributes of known functions which
  22 ;;; we like to have in IR1. This information is mostly side effect
  23 ;;; information of a sort, but it is different from the kind of
  24 ;;; information we want in IR2. We aren't interested in a fine
  25 ;;; breakdown of side effects, since we do very little code motion on
  26 ;;; IR1. We are interested in some deeper semantic properties such as
  27 ;;; whether it is safe to pass stack closures to.
  28 (!def-boolean-attribute ir1
  29   ;; may call functions that are passed as arguments. In order to
  30   ;; determine what other effects are present, we must find the
  31   ;; effects of all arguments that may be functions.
  32   call
  33   ;; may incorporate function or number arguments into the result or
  34   ;; somehow pass them upward. Note that this applies to any argument
  35   ;; that *might* be a function or number, not just the arguments that
  36   ;; always are.
  37   unsafe
  38   ;; may fail to return during correct execution. Errors are O.K.
  39   unwind
  40   ;; the (default) worst case. Includes all the other bad things, plus
  41   ;; any other possible bad thing. If this is present, the above bad
  42   ;; attributes will be explicitly present as well.
  43   any
  44   ;; may be constant-folded. The function has no side effects, but may
  45   ;; be affected by side effects on the arguments. e.g. SVREF, MAPC.
  46   ;; Functions that side-effect their arguments are not considered to
  47   ;; be foldable. Although it would be "legal" to constant fold them
  48   ;; (since it "is an error" to modify a constant), we choose not to
  49   ;; mark these functions as foldable in this database.
  50   foldable
  51   ;; may be eliminated if value is unused. The function has no side
  52   ;; effects except possibly cons. If a function might signal errors,
  53   ;; then it is not flushable even if it is movable, foldable or
  54   ;; unsafely-flushable. Implies UNSAFELY-FLUSHABLE. (In safe code
  55   ;; type checking of arguments is always performed by the caller, so
  56   ;; a function which SHOULD signal an error if arguments are not of
  57   ;; declared types may be FLUSHABLE.)
  58   flushable
  59   ;; unsafe call may be eliminated if value is unused. The function
  60   ;; has no side effects except possibly cons and signalling an error
  61   ;; in the safe code. If a function MUST signal errors, then it is
  62   ;; not unsafely-flushable even if it is movable or foldable.
  63   unsafely-flushable
  64   ;; may be moved with impunity. Has no side effects except possibly
  65   ;; consing, and is affected only by its arguments.
  66   movable
  67   ;; The function is a true predicate likely to be open-coded. Convert
  68   ;; any non-conditional uses into (IF <pred> T NIL). Not usually
  69   ;; specified to DEFKNOWN, since this is implementation dependent,
  70   ;; and is usually automatically set by the DEFINE-VOP :CONDITIONAL
  71   ;; option.
  72   predicate
  73   ;; Inhibit any warning for compiling a recursive definition.
  74   ;; (Normally the compiler warns when compiling a recursive
  75   ;; definition for a known function, since it might be a botched
  76   ;; interpreter stub.)
  77   recursive
  78   ;; The function does explicit argument type checking, so the
  79   ;; declared type should not be asserted when a definition is
  80   ;; compiled.
  81   explicit-check)
  82
  83 (defstruct (fun-info #-sb-xc-host (:pure t))
  84   ;; boolean attributes of this function.
  85   (attributes (missing-arg) :type attributes)
  86   ;; TRANSFORM structures describing transforms for this function
  87   (transforms () :type list)
  88   ;; a function which computes the derived type for a call to this
  89   ;; function by examining the arguments. This is null when there is
  90   ;; no special method for this function.
  91   (derive-type nil :type (or function null))
  92   ;; a function that does various unspecified code transformations by
  93   ;; directly hacking the IR. Returns true if further optimizations of
  94   ;; the call shouldn't be attempted.
  95   ;;
  96   ;; KLUDGE: This return convention (non-NIL if you shouldn't do
  97   ;; further optimiz'ns) is backwards from the return convention for
  98   ;; transforms. -- WHN 19990917
  99   (optimizer nil :type (or function null))
 100   ;; If true, a special-case LTN annotation method that is used in
 101   ;; place of the standard type/policy template selection. It may use
 102   ;; arbitrary code to choose a template, decide to do a full call, or
 103   ;; conspire with the IR2-CONVERT method to do almost anything. The
 104   ;; COMBINATION node is passed as the argument.
 105   (ltn-annotate nil :type (or function null))
 106   ;; If true, the special-case IR2 conversion method for this
 107   ;; function. This deals with funny functions, and anything else that
 108   ;; can't be handled using the template mechanism. The Combination
 109   ;; node and the IR2-BLOCK are passed as arguments.
 110   (ir2-convert nil :type (or function null))
 111   ;; all the templates that could be used to translate this function
 112   ;; into IR2, sorted by increasing cost.
 113   (templates nil :type list)
 114   ;; If non-null, then this function is a unary type predicate for
 115   ;; this type.
 116   (predicate-type nil :type (or ctype null)))
 117
 118 (defprinter (fun-info)
 119   (attributes :test (not (zerop attributes))
 120               :prin1 (decode-ir1-attributes attributes))
 121   (transforms :test transforms)
 122   (derive-type :test derive-type)
 123   (optimizer :test optimizer)
 124   (ltn-annotate :test ltn-annotate)
 125   (ir2-convert :test ir2-convert)
 126   (templates :test templates)
 127   (predicate-type :test predicate-type))
 128 \f
 129 ;;;; interfaces to defining macros
 130
 131 ;;; an IR1 transform
 132 (defstruct (transform (:copier nil))
 133   ;; the function type which enables this transform.
 134   ;;
 135   ;; (Note that declaring this :TYPE FUN-TYPE probably wouldn't
 136   ;; work because some function types, like (SPECIFIER-TYPE 'FUNCTION0
 137   ;; itself, are represented as BUILT-IN-TYPE, and at least as of
 138   ;; sbcl-0.pre7.54 or so, that's inconsistent with being a
 139   ;; FUN-TYPE.)
 140   (type (missing-arg) :type ctype)
 141   ;; the transformation function. Takes the COMBINATION node and
 142   ;; returns a lambda expression, or throws out.
 143   (function (missing-arg) :type function)
 144   ;; string used in efficiency notes
 145   (note (missing-arg) :type string)
 146   ;; T if we should emit a failure note even if SPEED=INHIBIT-WARNINGS.
 147   (important nil :type (member t nil)))
 148
 149 (defprinter (transform) type note important)
 150
 151 ;;; Grab the FUN-INFO and enter the function, replacing any old
 152 ;;; one with the same type and note.
 153 (declaim (ftype (function (t list function &optional (or string null)
 154                              (member t nil))
 155                           *)
 156                 %deftransform))
 157 (defun %deftransform (name type fun &optional note important)
 158   (let* ((ctype (specifier-type type))
 159          (note (or note "optimize"))
 160          (info (fun-info-or-lose name))
 161          (old (find-if (lambda (x)
 162                          (and (type= (transform-type x) ctype)
 163                               (string-equal (transform-note x) note)
 164                               (eq (transform-important x) important)))
 165                        (fun-info-transforms info))))
 166     (cond (old
 167            (style-warn "Overwriting ~S" old)
 168            (setf (transform-function old) fun
 169                  (transform-note old) note))
 170           (t
 171            (push (make-transform :type ctype :function fun :note note
 172                                  :important important)
 173                  (fun-info-transforms info))))
 174     name))
 175
 176 ;;; Make a FUN-INFO structure with the specified type, attributes
 177 ;;; and optimizers.
 178 (declaim (ftype (function (list list attributes &key
 179                                 (:derive-type (or function null))
 180                                 (:optimizer (or function null)))
 181                           *)
 182                 %defknown))
 183 (defun %defknown (names type attributes &key derive-type optimizer)
 184   (let ((ctype (specifier-type type))
 185         (info (make-fun-info :attributes attributes
 186                              :derive-type derive-type
 187                              :optimizer optimizer))
 188         (target-env *info-environment*))
 189     (dolist (name names)
 190       (let ((old-fun-info (info :function :info name)))
 191         (when old-fun-info
 192           ;; This is handled as an error because it's generally a bad
 193           ;; thing to blow away all the old optimization stuff. It's
 194           ;; also a potential source of sneaky bugs:
 195           ;;    DEFKNOWN FOO
 196           ;;    DEFTRANSFORM FOO
 197           ;;    DEFKNOWN FOO ; possibly hidden inside some macroexpansion
 198           ;;    ; Now the DEFTRANSFORM doesn't exist in the target Lisp.
 199           ;; However, it's continuable because it might be useful to do
 200           ;; it when testing new optimization stuff interactively.
 201           (cerror "Go ahead, overwrite it."
 202                   "~@<overwriting old FUN-INFO ~2I~_~S ~I~_for ~S~:>"
 203                   old-fun-info name)))
 204       (setf (info :function :type name target-env) ctype)
 205       (setf (info :function :where-from name target-env) :declared)
 206       (setf (info :function :kind name target-env) :function)
 207       (setf (info :function :info name target-env) info)))
 208   names)
 209
 210 ;;; Return the FUN-INFO for NAME or die trying. Since this is
 211 ;;; used by callers who want to modify the info, and the info may be
 212 ;;; shared, we copy it. We don't have to copy the lists, since each
 213 ;;; function that has generators or transforms has already been
 214 ;;; through here.
 215 (declaim (ftype (sfunction (t) fun-info) fun-info-or-lose))
 216 (defun fun-info-or-lose (name)
 217   (let (;; FIXME: Do we need this rebinding here? It's a literal
 218         ;; translation of the old CMU CL rebinding to
 219         ;; (OR *BACKEND-INFO-ENVIRONMENT* *INFO-ENVIRONMENT*),
 220         ;; and it's not obvious whether the rebinding to itself is
 221         ;; needed that SBCL doesn't need *BACKEND-INFO-ENVIRONMENT*.
 222         (*info-environment* *info-environment*))
 223     (let ((old (info :function :info name)))
 224       (unless old (error "~S is not a known function." name))
 225       (setf (info :function :info name) (copy-fun-info old)))))
 226 \f
 227 ;;;; generic type inference methods
 228
 229 ;;; Derive the type to be the type of the xxx'th arg. This can normally
 230 ;;; only be done when the result value is that argument.
 231 (defun result-type-first-arg (call)
 232   (declare (type combination call))
 233   (let ((cont (first (combination-args call))))
 234     (when cont (continuation-type cont))))
 235 (defun result-type-last-arg (call)
 236   (declare (type combination call))
 237   (let ((cont (car (last (combination-args call)))))
 238     (when cont (continuation-type cont))))
 239
 240 ;;; Derive the result type according to the float contagion rules, but
 241 ;;; always return a float. This is used for irrational functions that
 242 ;;; preserve realness of their arguments.
 243 (defun result-type-float-contagion (call)
 244   (declare (type combination call))
 245   (reduce #'numeric-contagion (combination-args call)
 246           :key #'continuation-type
 247           :initial-value (specifier-type 'single-float)))
 248
 249 ;;; Return a closure usable as a derive-type method for accessing the
 250 ;;; N'th argument. If arg is a list, result is a list. If arg is a
 251 ;;; vector, result is a vector with the same element type.
 252 (defun sequence-result-nth-arg (n)
 253   (lambda (call)
 254     (declare (type combination call))
 255     (let ((cont (nth (1- n) (combination-args call))))
 256       (when cont
 257         (let ((type (continuation-type cont)))
 258           (if (array-type-p type)
 259               (specifier-type
 260                `(vector ,(type-specifier (array-type-element-type type))))
 261               (let ((ltype (specifier-type 'list)))
 262                 (when (csubtypep type ltype)
 263                   ltype))))))))
 264
 265 ;;; Derive the type to be the type specifier which is the Nth arg.
 266 (defun result-type-specifier-nth-arg (n)
 267   (lambda (call)
 268     (declare (type combination call))
 269     (let ((cont (nth (1- n) (combination-args call))))
 270       (when (and cont (constant-continuation-p cont))
 271         (careful-specifier-type (continuation-value cont))))))
 272
 273 ;;; Derive the type to be the type specifier which is the Nth arg,
 274 ;;; with the additional restriptions noted in the CLHS for STRING and
 275 ;;; SIMPLE-STRING, defined to specialize on CHARACTER, and for VECTOR
 276 ;;; (under the page for MAKE-SEQUENCE).
 277 (defun creation-result-type-specifier-nth-arg (n)
 278   (lambda (call)
 279     (declare (type combination call))
 280     (let ((cont (nth (1- n) (combination-args call))))
 281       (when (and cont (constant-continuation-p cont))
 282         (let* ((specifier (continuation-value cont))
 283                (lspecifier (if (atom specifier) (list specifier) specifier)))
 284           (cond
 285             ((eq (car lspecifier) 'string)
 286              (destructuring-bind (string &rest size)
 287                  lspecifier
 288                (declare (ignore string))
 289                (careful-specifier-type
 290                 `(vector character ,@(when size size)))))
 291             ((eq (car lspecifier) 'simple-string)
 292              (destructuring-bind (simple-string &rest size)
 293                  lspecifier
 294                (declare (ignore simple-string))
 295                (careful-specifier-type
 296                 `(simple-array character ,@(if size (list size) '((*)))))))
 297             (t
 298              (let ((ctype (careful-specifier-type specifier)))
 299                (if (and (array-type-p ctype)
 300                         (eq (array-type-specialized-element-type ctype)
 301                             *wild-type*))
 302                    ;; I don't think I'm allowed to modify what I get
 303                    ;; back from SPECIFIER-TYPE; it is, after all,
 304                    ;; cached.  Better copy it, then.
 305                    (let ((real-ctype (copy-structure ctype)))
 306                      (setf (array-type-element-type real-ctype)
 307                            *universal-type*
 308                            (array-type-specialized-element-type real-ctype)
 309                            *universal-type*)
 310                      real-ctype)
 311                    ctype)))))))))
 312
 313 (/show0 "knownfun.lisp end of file")