src/compiler/lexenv.lisp

   1 ;;;; the representation of a lexical environment
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13
  14 ;;; The LEXENV represents the lexical environment used for IR1 conversion.
  15 ;;; (This is also what shows up as an ENVIRONMENT value in macroexpansion.)
  16 #!-sb-fluid (declaim (inline internal-make-lexenv)) ; only called in one place
  17 (def!struct (lexenv
  18              (:print-function print-lexenv)
  19              (:constructor make-null-lexenv ())
  20              (:constructor internal-make-lexenv
  21                            (funs vars blocks tags
  22                                  type-restrictions
  23                                  lambda cleanup handled-conditions
  24                                  disabled-package-locks %policy user-data)))
  25   ;; an alist of (NAME . WHAT), where WHAT is either a FUNCTIONAL (a
  26   ;; local function), a DEFINED-FUN, representing an
  27   ;; INLINE/NOTINLINE declaration, or a list (MACRO . <function>) (a
  28   ;; local macro, with the specifier expander). Note that NAME may be
  29   ;; a (SETF <name>) list, not necessarily a single symbol.
  30   (funs nil :type list)
  31   ;; an alist translating variable names to LEAF structures. A special
  32   ;; binding is indicated by a :SPECIAL GLOBAL-VAR leaf. Each special
  33   ;; binding within the code gets a distinct leaf structure, as does
  34   ;; the current "global" value on entry to the code compiled.
  35   ;; (locally (special ...)) is handled by adding the most recent
  36   ;; special binding to the front of the list.
  37   ;;
  38   ;; If the CDR is (MACRO . <exp>), then <exp> is the expansion of a
  39   ;; symbol macro.
  40   (vars nil :type list)
  41   ;; BLOCKS and TAGS are alists from block and go-tag names to 2-lists
  42   ;; of the form (<entry> <continuation>), where <continuation> is the
  43   ;; continuation to exit to, and <entry> is the corresponding ENTRY
  44   ;; node.
  45   (blocks nil :type list)
  46   (tags nil :type list)
  47   ;; an alist (THING . CTYPE) which is used to keep track of
  48   ;; "pervasive" type declarations. When THING is a leaf, this is for
  49   ;; type declarations that pertain to the type in a syntactic extent
  50   ;; which does not correspond to a binding of the affected name.
  51   (type-restrictions nil :type list)
  52   ;; the lexically enclosing lambda, if any
  53   ;;
  54   ;; FIXME: This should be :TYPE (OR CLAMBDA NULL), but it was too hard
  55   ;; to get CLAMBDA defined in time for the cross-compiler.
  56   (lambda nil)
  57   ;; the lexically enclosing cleanup, or NIL if none enclosing within LAMBDA
  58   (cleanup nil)
  59   ;; condition types we handle with a handler around the compiler
  60   (handled-conditions *handled-conditions*)
  61   ;; lexically disabled package locks (list of symbols)
  62   (disabled-package-locks *disabled-package-locks*)
  63   ;; the current OPTIMIZE policy. this is null in the null environment,
  64   ;; and the global policy is stored in *POLICY*. (Because we want to
  65   ;; be able to affect it from :WITH-COMPILATION-UNIT.) NIL here also
  66   ;; works as a convenient null-lexenv identifier.
  67   (%policy nil :type policy)
  68   ;; A list associating extra user info to symbols.  The entries
  69   ;; are of the form (:declare name . value),
  70   ;; (:variable name key . value), or (:function name key . value)
  71   (user-data nil :type list))
  72
  73 (defun lexenv-policy (lexenv)
  74   (or (lexenv-%policy lexenv) *policy*))
  75
  76 (defun null-lexenv-p (lexenv)
  77   (not (lexenv-%policy lexenv)))
  78
  79 ;;; support for the idiom (in MACROEXPAND and elsewhere) that NIL is
  80 ;;; to be taken as a null lexical environment
  81 (defun coerce-to-lexenv (x)
  82   (etypecase x
  83     (null (make-null-lexenv))
  84     (lexenv x)))
  85
  86 (defun print-lexenv (lexenv stream level)
  87   (if (null-lexenv-p lexenv)
  88       (print-unreadable-object (lexenv stream)
  89         (write-string "NULL-LEXENV" stream))
  90       (default-structure-print lexenv stream level)))
  91
  92 (defun maybe-inline-syntactic-closure (lambda lexenv)
  93   (declare (type list lambda) (type lexenv lexenv))
  94   (aver (eql (first lambda) 'lambda))
  95   ;; We used to have a trivial implementation, verifying that lexenv
  96   ;; was effectively null. However, this fails to take account of the
  97   ;; idiom
  98   ;;
  99   ;; (declaim (inline foo))
 100   ;; (macrolet ((def (x) `(defun ,x () ...)))
 101   ;;   (def foo))
 102   ;;
 103   ;; which, while too complicated for the cross-compiler to handle in
 104   ;; unfriendly foreign lisp environments, would be good to support in
 105   ;; the target compiler. -- CSR, 2002-05-13 and 2002-11-02
 106   (let ((vars (lexenv-vars lexenv))
 107         (funs (lexenv-funs lexenv)))
 108     (collect ((decls) (macros) (symbol-macros))
 109       (cond
 110         ((or (lexenv-blocks lexenv) (lexenv-tags lexenv)) nil)
 111         ((and (null vars) (null funs)) `(lambda-with-lexenv
 112                                          nil nil nil
 113                                          ,@(cdr lambda)))
 114         ((dolist (x vars nil)
 115            #+sb-xc-host
 116            ;; KLUDGE: too complicated for cross-compilation
 117            (return t)
 118            #-sb-xc-host
 119            (let ((name (car x))
 120                  (what (cdr x)))
 121              ;; only worry about the innermost binding
 122              (when (eq x (assoc name vars :test #'eq))
 123                (typecase what
 124                  (cons
 125                   (aver (eq (car what) 'macro))
 126                   (symbol-macros x))
 127                  (global-var
 128                   ;; A global should not appear in the lexical
 129                   ;; environment? Is this true? FIXME!
 130                   (aver (eq (global-var-kind what) :special))
 131                   (decls `(special ,name)))
 132                  (t
 133                   ;; we can't inline in the presence of this object
 134                   (return t))))))
 135          nil)
 136         ((dolist (x funs nil)
 137            #+sb-xc-host
 138            ;; KLUDGE: too complicated for cross-compilation (and
 139            ;; failure of OAOO in comments, *sigh*)
 140            (return t)
 141            #-sb-xc-host
 142            (let ((name (car x))
 143                  (what (cdr x)))
 144              ;; again, only worry about the innermost binding, but
 145              ;; functions can have name (SETF FOO) so we need to use
 146              ;; EQUAL for the test.
 147              (when (eq x (assoc name funs :test #'equal))
 148                (typecase what
 149                  (cons
 150                   (macros (cons name (function-lambda-expression (cdr what)))))
 151                  ;; FIXME: Is there a good reason for this not to be
 152                  ;; DEFINED-FUN (which :INCLUDEs GLOBAL-VAR, in case
 153                  ;; you're wondering how this ever worked :-)? Maybe
 154                  ;; in conjunction with an AVERrance that it's not an
 155                  ;; (AND GLOBAL-VAR (NOT GLOBAL-FUN))? -- CSR,
 156                  ;; 2002-07-08
 157                  (global-var
 158                   (when (defined-fun-p what)
 159                     (decls `(,(car (rassoc (defined-fun-inlinep what)
 160                                            *inlinep-translations*))
 161                               ,name))))
 162                  (t (return t))))))
 163          nil)
 164         (t
 165          ;; if we get this far, we've successfully dealt with
 166          ;; everything in FUNS and VARS, so:
 167          `(lambda-with-lexenv ,(decls) ,(macros) ,(symbol-macros)
 168                               ,@(cdr lambda)))))))
 169