src/compiler/lexenv.lisp

   1 ;;;; the representation of a lexical environment
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13
  14 #!-sb-fluid (declaim (inline internal-make-lexenv)) ; only called in one place
  15
  16 ;;; The LEXENV represents the lexical environment used for IR1 conversion.
  17 ;;; (This is also what shows up as an ENVIRONMENT value in macroexpansion.)
  18 #!-sb-fluid (declaim (inline internal-make-lexenv)) ; only called in one place
  19 (def!struct (lexenv
  20              (:constructor make-null-lexenv ())
  21              (:constructor make-null-interactive-lexenv
  22                            (&aux (policy (list '(safety . 3)
  23                                                '(compilation-speed . 2)
  24                                                '(debug . 2)
  25                                                '(speed . 1)
  26                                                '(space . 1)
  27                                                '(inhibit-warnings . 1)))))
  28              (:constructor internal-make-lexenv
  29                            (funs vars blocks tags
  30                                  type-restrictions
  31                                  weakend-type-restrictions
  32                                  lambda cleanup policy)))
  33   ;; an alist of (NAME . WHAT), where WHAT is either a FUNCTIONAL (a
  34   ;; local function), a DEFINED-FUN, representing an
  35   ;; INLINE/NOTINLINE declaration, or a list (MACRO . <function>) (a
  36   ;; local macro, with the specifier expander). Note that NAME may be
  37   ;; a (SETF <name>) list, not necessarily a single symbol.
  38   (funs nil :type list)
  39   ;; an alist translating variable names to LEAF structures. A special
  40   ;; binding is indicated by a :SPECIAL GLOBAL-VAR leaf. Each special
  41   ;; binding within the code gets a distinct leaf structure, as does
  42   ;; the current "global" value on entry to the code compiled.
  43   ;; (locally (special ...)) is handled by adding the most recent
  44   ;; special binding to the front of the list.
  45   ;;
  46   ;; If the CDR is (MACRO . <exp>), then <exp> is the expansion of a
  47   ;; symbol macro.
  48   (vars nil :type list)
  49   ;; BLOCKS and TAGS are alists from block and go-tag names to 2-lists
  50   ;; of the form (<entry> <continuation>), where <continuation> is the
  51   ;; continuation to exit to, and <entry> is the corresponding ENTRY node.
  52   (blocks nil :type list)
  53   (tags nil :type list)
  54   ;; an alist (THING . CTYPE) which is used to keep track of
  55   ;; "pervasive" type declarations. When THING is a leaf, this is for
  56   ;; type declarations that pertain to the type in a syntactic extent
  57   ;; which does not correspond to a binding of the affected name. When
  58   ;; THING is a continuation, this is used to track the innermost THE
  59   ;; type declaration.
  60   (type-restrictions nil :type list)
  61   (weakend-type-restrictions nil :type list)
  62   ;; the lexically enclosing lambda, if any
  63   ;;
  64   ;; FIXME: This should be :TYPE (OR CLAMBDA NULL), but it was too hard
  65   ;; to get CLAMBDA defined in time for the cross-compiler.
  66   (lambda nil)
  67   ;; the lexically enclosing cleanup, or NIL if none enclosing within Lambda
  68   (cleanup nil)
  69   ;; the current OPTIMIZE policy
  70   (policy *policy* :type policy))
  71
  72 ;;; support for the idiom (in MACROEXPAND and elsewhere) that NIL is
  73 ;;; to be taken as a null lexical environment
  74 (defun coerce-to-lexenv (x)
  75   (etypecase x
  76     (null (make-null-lexenv))
  77     (lexenv x)))
  78
  79 (defun maybe-inline-syntactic-closure (lambda lexenv)
  80   (declare (type list lambda) (type lexenv lexenv))
  81   (aver (eql (first lambda) 'lambda))
  82   ;; We used to have a trivial implementation, verifying that lexenv
  83   ;; was effectively null. However, this fails to take account of the
  84   ;; idiom
  85   ;;
  86   ;; (declaim (inline foo))
  87   ;; (macrolet ((def (x) `(defun ,x () ...)))
  88   ;;   (def foo))
  89   ;;
  90   ;; which, while too complicated for the cross-compiler to handle in
  91   ;; unfriendly foreign lisp environments, would be good to support in
  92   ;; the target compiler. -- CSR, 2002-05-13 and 2002-11-02
  93   (let ((vars (lexenv-vars lexenv))
  94         (funs (lexenv-funs lexenv)))
  95     (collect ((decls) (macros) (symbol-macros))
  96       (cond
  97         ((or (lexenv-blocks lexenv) (lexenv-tags lexenv)) nil)
  98         ((and (null vars) (null funs)) `(lambda-with-lexenv
  99                                          nil nil nil
 100                                          ,@(cdr lambda)))
 101         ((dolist (x vars nil)
 102            #+sb-xc-host
 103            ;; KLUDGE: too complicated for cross-compilation
 104            (return t)
 105            #-sb-xc-host
 106            (let ((name (car x))
 107                  (what (cdr x)))
 108              ;; only worry about the innermost binding
 109              (when (eq x (assoc name vars :test #'eq))
 110                (typecase what
 111                  (cons
 112                   (aver (eq (car what) 'macro))
 113                   (symbol-macros x))
 114                  (global-var
 115                   ;; A global should not appear in the lexical
 116                   ;; environment? Is this true? FIXME!
 117                   (aver (eq (global-var-kind what) :special))
 118                   (decls `(special ,name)))
 119                  (t
 120                   ;; we can't inline in the presence of this object
 121                   (return t))))))
 122          nil)
 123         ((dolist (x funs nil)
 124            #+sb-xc-host
 125            ;; KLUDGE: too complicated for cross-compilation (and
 126            ;; failure of OAOO in comments, *sigh*)
 127            (return t)
 128            #-sb-xc-host
 129            (let ((name (car x))
 130                  (what (cdr x)))
 131              ;; again, only worry about the innermost binding, but
 132              ;; functions can have name (SETF FOO) so we need to use
 133              ;; EQUAL for the test.
 134              (when (eq x (assoc name funs :test #'equal))
 135                (typecase what
 136                  (cons
 137                   (macros (cons name (function-lambda-expression (cdr what)))))
 138                  ;; FIXME: Is there a good reason for this not to be
 139                  ;; DEFINED-FUN (which :INCLUDEs GLOBAL-VAR, in case
 140                  ;; you're wondering how this ever worked :-)? Maybe
 141                  ;; in conjunction with an AVERrance that it's not an
 142                  ;; (AND GLOBAL-VAR (NOT GLOBAL-FUN))? -- CSR,
 143                  ;; 2002-07-08
 144                  (global-var
 145                   (when (defined-fun-p what)
 146                     (decls `(,(car (rassoc (defined-fun-inlinep what)
 147                                            *inlinep-translations*))
 148                               ,name))))
 149                  (t (return t))))))
 150          nil)
 151         (t
 152          ;; if we get this far, we've successfully dealt with
 153          ;; everything in FUNS and VARS, so:
 154          `(lambda-with-lexenv ,(decls) ,(macros) ,(symbol-macros)
 155                               ,@(cdr lambda)))))))
 156