src/compiler/lexenv.lisp

   1 ;;;; the representation of a lexical environment
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13
  14 ;;; The LEXENV represents the lexical environment used for IR1 conversion.
  15 ;;; (This is also what shows up as an ENVIRONMENT value in macroexpansion.)
  16 #!-sb-fluid (declaim (inline internal-make-lexenv)) ; only called in one place
  17 (def!struct (lexenv
  18              (:constructor make-null-lexenv ())
  19              (:constructor make-null-interactive-lexenv
  20                            (&aux (policy (list '(safety . 3)
  21                                                '(compilation-speed . 2)
  22                                                '(debug . 2)
  23                                                '(speed . 1)
  24                                                '(space . 1)
  25                                                '(inhibit-warnings . 1)))))
  26              (:constructor internal-make-lexenv
  27                            (funs vars blocks tags
  28                                  type-restrictions
  29                                  lambda cleanup handled-conditions
  30                                  disabled-package-locks policy)))
  31   ;; an alist of (NAME . WHAT), where WHAT is either a FUNCTIONAL (a
  32   ;; local function), a DEFINED-FUN, representing an
  33   ;; INLINE/NOTINLINE declaration, or a list (MACRO . <function>) (a
  34   ;; local macro, with the specifier expander). Note that NAME may be
  35   ;; a (SETF <name>) list, not necessarily a single symbol.
  36   (funs nil :type list)
  37   ;; an alist translating variable names to LEAF structures. A special
  38   ;; binding is indicated by a :SPECIAL GLOBAL-VAR leaf. Each special
  39   ;; binding within the code gets a distinct leaf structure, as does
  40   ;; the current "global" value on entry to the code compiled.
  41   ;; (locally (special ...)) is handled by adding the most recent
  42   ;; special binding to the front of the list.
  43   ;;
  44   ;; If the CDR is (MACRO . <exp>), then <exp> is the expansion of a
  45   ;; symbol macro.
  46   (vars nil :type list)
  47   ;; BLOCKS and TAGS are alists from block and go-tag names to 2-lists
  48   ;; of the form (<entry> <continuation>), where <continuation> is the
  49   ;; continuation to exit to, and <entry> is the corresponding ENTRY
  50   ;; node.
  51   (blocks nil :type list)
  52   (tags nil :type list)
  53   ;; an alist (THING . CTYPE) which is used to keep track of
  54   ;; "pervasive" type declarations. When THING is a leaf, this is for
  55   ;; type declarations that pertain to the type in a syntactic extent
  56   ;; which does not correspond to a binding of the affected name.
  57   (type-restrictions nil :type list)
  58   ;; the lexically enclosing lambda, if any
  59   ;;
  60   ;; FIXME: This should be :TYPE (OR CLAMBDA NULL), but it was too hard
  61   ;; to get CLAMBDA defined in time for the cross-compiler.
  62   (lambda nil)
  63   ;; the lexically enclosing cleanup, or NIL if none enclosing within LAMBDA
  64   (cleanup nil)
  65   ;; condition types we handle with a handler around the compiler
  66   (handled-conditions *handled-conditions*)
  67   ;; lexically disabled package locks (list of symbols)
  68   (disabled-package-locks *disabled-package-locks*)
  69   ;; the current OPTIMIZE policy
  70   (policy *policy* :type policy))
  71
  72 ;;; support for the idiom (in MACROEXPAND and elsewhere) that NIL is
  73 ;;; to be taken as a null lexical environment
  74 (defun coerce-to-lexenv (x)
  75   (etypecase x
  76     (null (make-null-lexenv))
  77     (lexenv x)))
  78
  79 (defun maybe-inline-syntactic-closure (lambda lexenv)
  80   (declare (type list lambda) (type lexenv lexenv))
  81   (aver (eql (first lambda) 'lambda))
  82   ;; We used to have a trivial implementation, verifying that lexenv
  83   ;; was effectively null. However, this fails to take account of the
  84   ;; idiom
  85   ;;
  86   ;; (declaim (inline foo))
  87   ;; (macrolet ((def (x) `(defun ,x () ...)))
  88   ;;   (def foo))
  89   ;;
  90   ;; which, while too complicated for the cross-compiler to handle in
  91   ;; unfriendly foreign lisp environments, would be good to support in
  92   ;; the target compiler. -- CSR, 2002-05-13 and 2002-11-02
  93   (let ((vars (lexenv-vars lexenv))
  94         (funs (lexenv-funs lexenv)))
  95     (collect ((decls) (macros) (symbol-macros))
  96       (cond
  97         ((or (lexenv-blocks lexenv) (lexenv-tags lexenv)) nil)
  98         ((and (null vars) (null funs)) `(lambda-with-lexenv
  99                                          nil nil nil
 100                                          ,@(cdr lambda)))
 101         ((dolist (x vars nil)
 102            #+sb-xc-host
 103            ;; KLUDGE: too complicated for cross-compilation
 104            (return t)
 105            #-sb-xc-host
 106            (let ((name (car x))
 107                  (what (cdr x)))
 108              ;; only worry about the innermost binding
 109              (when (eq x (assoc name vars :test #'eq))
 110                (typecase what
 111                  (cons
 112                   (aver (eq (car what) 'macro))
 113                   (symbol-macros x))
 114                  (global-var
 115                   ;; A global should not appear in the lexical
 116                   ;; environment? Is this true? FIXME!
 117                   (aver (eq (global-var-kind what) :special))
 118                   (decls `(special ,name)))
 119                  (t
 120                   ;; we can't inline in the presence of this object
 121                   (return t))))))
 122          nil)
 123         ((dolist (x funs nil)
 124            #+sb-xc-host
 125            ;; KLUDGE: too complicated for cross-compilation (and
 126            ;; failure of OAOO in comments, *sigh*)
 127            (return t)
 128            #-sb-xc-host
 129            (let ((name (car x))
 130                  (what (cdr x)))
 131              ;; again, only worry about the innermost binding, but
 132              ;; functions can have name (SETF FOO) so we need to use
 133              ;; EQUAL for the test.
 134              (when (eq x (assoc name funs :test #'equal))
 135                (typecase what
 136                  (cons
 137                   (macros (cons name (function-lambda-expression (cdr what)))))
 138                  ;; FIXME: Is there a good reason for this not to be
 139                  ;; DEFINED-FUN (which :INCLUDEs GLOBAL-VAR, in case
 140                  ;; you're wondering how this ever worked :-)? Maybe
 141                  ;; in conjunction with an AVERrance that it's not an
 142                  ;; (AND GLOBAL-VAR (NOT GLOBAL-FUN))? -- CSR,
 143                  ;; 2002-07-08
 144                  (global-var
 145                   (when (defined-fun-p what)
 146                     (decls `(,(car (rassoc (defined-fun-inlinep what)
 147                                            *inlinep-translations*))
 148                               ,name))))
 149                  (t (return t))))))
 150          nil)
 151         (t
 152          ;; if we get this far, we've successfully dealt with
 153          ;; everything in FUNS and VARS, so:
 154          `(lambda-with-lexenv ,(decls) ,(macros) ,(symbol-macros)
 155                               ,@(cdr lambda)))))))
 156