src/compiler/main.lisp

   1 ;;;; the top level interfaces to the compiler, plus some other
   2 ;;;; compiler-related stuff (e.g. CL:CALL-ARGUMENTS-LIMIT) which
   3 ;;;; doesn't obviously belong anywhere else
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15
  16 ;;; FIXME: Doesn't this belong somewhere else, like early-c.lisp?
  17 (declaim (special *constants* *free-vars* *component-being-compiled*
  18                   *code-vector* *next-location* *result-fixups*
  19                   *free-funs* *source-paths*
  20                   *seen-blocks* *seen-funs* *list-conflicts-table*
  21                   *continuation-number* *continuation-numbers*
  22                   *number-continuations* *tn-id* *tn-ids* *id-tns*
  23                   *label-ids* *label-id* *id-labels*
  24                   *undefined-warnings* *compiler-error-count*
  25                   *compiler-warning-count* *compiler-style-warning-count*
  26                   *compiler-note-count*
  27                   *compiler-error-bailout*
  28                   #!+sb-show *compiler-trace-output*
  29                   *last-source-context* *last-original-source*
  30                   *last-source-form* *last-format-string* *last-format-args*
  31                   *last-message-count* *lexenv* *fun-names-in-this-file*
  32                   *allow-instrumenting*))
  33
  34 ;;; Whether call of a function which cannot be defined causes a full
  35 ;;; warning.
  36 (defvar *flame-on-necessarily-undefined-function* nil)
  37
  38 (defvar *check-consistency* nil)
  39 (defvar *all-components*)
  40
  41 ;;; Set to NIL to disable loop analysis for register allocation.
  42 (defvar *loop-analyze* t)
  43
  44 ;;; Bind this to a stream to capture various internal debugging output.
  45 (defvar *compiler-trace-output* nil)
  46
  47 ;;; The current block compilation state. These are initialized to the
  48 ;;; :BLOCK-COMPILE and :ENTRY-POINTS arguments that COMPILE-FILE was
  49 ;;; called with.
  50 ;;;
  51 ;;; *BLOCK-COMPILE-ARG* holds the original value of the :BLOCK-COMPILE
  52 ;;; argument, which overrides any internal declarations.
  53 (defvar *block-compile*)
  54 (defvar *block-compile-arg*)
  55 (declaim (type (member nil t :specified) *block-compile* *block-compile-arg*))
  56 (defvar *entry-points*)
  57 (declaim (list *entry-points*))
  58
  59 ;;; When block compiling, used by PROCESS-FORM to accumulate top level
  60 ;;; lambdas resulting from compiling subforms. (In reverse order.)
  61 (defvar *toplevel-lambdas*)
  62 (declaim (list *toplevel-lambdas*))
  63
  64 (defvar sb!xc:*compile-verbose* t
  65   #!+sb-doc
  66   "The default for the :VERBOSE argument to COMPILE-FILE.")
  67 (defvar sb!xc:*compile-print* t
  68   #!+sb-doc
  69   "The default for the :PRINT argument to COMPILE-FILE.")
  70 (defvar *compile-progress* nil
  71   #!+sb-doc
  72   "When this is true, the compiler prints to *ERROR-OUTPUT* progress
  73   information about the phases of compilation of each function. (This
  74   is useful mainly in large block compilations.)")
  75
  76 (defvar sb!xc:*compile-file-pathname* nil
  77   #!+sb-doc
  78   "The defaulted pathname of the file currently being compiled, or NIL if not
  79   compiling.")
  80 (defvar sb!xc:*compile-file-truename* nil
  81   #!+sb-doc
  82   "The TRUENAME of the file currently being compiled, or NIL if not
  83   compiling.")
  84
  85 (declaim (type (or pathname null)
  86                sb!xc:*compile-file-pathname*
  87                sb!xc:*compile-file-truename*))
  88
  89 ;;; the SOURCE-INFO structure for the current compilation. This is
  90 ;;; null globally to indicate that we aren't currently in any
  91 ;;; identifiable compilation.
  92 (defvar *source-info* nil)
  93
  94 ;;; This is true if we are within a WITH-COMPILATION-UNIT form (which
  95 ;;; normally causes nested uses to be no-ops).
  96 (defvar *in-compilation-unit* nil)
  97
  98 ;;; Count of the number of compilation units dynamically enclosed by
  99 ;;; the current active WITH-COMPILATION-UNIT that were unwound out of.
 100 (defvar *aborted-compilation-unit-count*)
 101
 102 ;;; Mumble conditional on *COMPILE-PROGRESS*.
 103 (defun maybe-mumble (&rest foo)
 104   (when *compile-progress*
 105     (compiler-mumble "~&")
 106     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 107        (apply #'compiler-mumble foo))))
 108
 109 (deftype object () '(or fasl-output core-object null))
 110
 111 (defvar *compile-object* nil)
 112 (declaim (type object *compile-object*))
 113 \f
 114 ;;;; WITH-COMPILATION-UNIT and WITH-COMPILATION-VALUES
 115
 116 (defmacro sb!xc:with-compilation-unit (options &body body)
 117   #!+sb-doc
 118   "WITH-COMPILATION-UNIT ({Key Value}*) Form*
 119   This form affects compilations that take place within its dynamic extent. It
 120   is intended to be wrapped around the compilation of all files in the same
 121   system. These keywords are defined:
 122     :OVERRIDE Boolean-Form
 123         One of the effects of this form is to delay undefined warnings
 124         until the end of the form, instead of giving them at the end of each
 125         compilation. If OVERRIDE is NIL (the default), then the outermost
 126         WITH-COMPILATION-UNIT form grabs the undefined warnings. Specifying
 127         OVERRIDE true causes that form to grab any enclosed warnings, even if
 128         it is enclosed by another WITH-COMPILATION-UNIT."
 129   `(%with-compilation-unit (lambda () ,@body) ,@options))
 130
 131 (defun %with-compilation-unit (fn &key override)
 132   (declare (type function fn))
 133   (let ((succeeded-p nil))
 134     (if (and *in-compilation-unit* (not override))
 135         ;; Inside another WITH-COMPILATION-UNIT, a WITH-COMPILATION-UNIT is
 136         ;; ordinarily (unless OVERRIDE) basically a no-op.
 137         (unwind-protect
 138              (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 139           (unless succeeded-p
 140             (incf *aborted-compilation-unit-count*)))
 141         (let ((*aborted-compilation-unit-count* 0)
 142               (*compiler-error-count* 0)
 143               (*compiler-warning-count* 0)
 144               (*compiler-style-warning-count* 0)
 145               (*compiler-note-count* 0)
 146               (*undefined-warnings* nil)
 147               (*in-compilation-unit* t))
 148           (sb!thread:with-recursive-lock (*big-compiler-lock*)
 149             (handler-bind ((parse-unknown-type
 150                             (lambda (c)
 151                               (note-undefined-reference
 152                                (parse-unknown-type-specifier c)
 153                                :type))))
 154               (unwind-protect
 155                    (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 156                 (unless succeeded-p
 157                   (incf *aborted-compilation-unit-count*))
 158                 (summarize-compilation-unit (not succeeded-p)))))))))
 159
 160 ;;; Is FUN-NAME something that no conforming program can rely on
 161 ;;; defining as a function?
 162 (defun fun-name-reserved-by-ansi-p (fun-name)
 163   (eq (symbol-package (fun-name-block-name fun-name))
 164       *cl-package*))
 165
 166 ;;; This is to be called at the end of a compilation unit. It signals
 167 ;;; any residual warnings about unknown stuff, then prints the total
 168 ;;; error counts. ABORT-P should be true when the compilation unit was
 169 ;;; aborted by throwing out. ABORT-COUNT is the number of dynamically
 170 ;;; enclosed nested compilation units that were aborted.
 171 (defun summarize-compilation-unit (abort-p)
 172   (unless abort-p
 173     (handler-bind ((style-warning #'compiler-style-warning-handler)
 174                    (warning #'compiler-warning-handler))
 175
 176       (let ((undefs (sort *undefined-warnings* #'string<
 177                           :key (lambda (x)
 178                                  (let ((x (undefined-warning-name x)))
 179                                    (if (symbolp x)
 180                                        (symbol-name x)
 181                                        (prin1-to-string x)))))))
 182         (dolist (undef undefs)
 183           (let ((name (undefined-warning-name undef))
 184                 (kind (undefined-warning-kind undef))
 185                 (warnings (undefined-warning-warnings undef))
 186                 (undefined-warning-count (undefined-warning-count undef)))
 187             (dolist (*compiler-error-context* warnings)
 188               (if #-sb-xc-host (and (eq kind :function)
 189                                     (fun-name-reserved-by-ansi-p name)
 190                                     *flame-on-necessarily-undefined-function*)
 191                   #+sb-xc-host nil
 192                   (case name
 193                     ((declare)
 194                      (compiler-warn
 195                       "~@<There is no function named ~S. References to ~S in ~
 196                        some contexts (like starts of blocks) have special ~
 197                        meaning, but here it would have to be a function, ~
 198                        and that shouldn't be right.~:@>"
 199                       name name))
 200                     (t
 201                      (compiler-warn
 202                       "~@<The ~(~A~) ~S is undefined, and its name is ~
 203                        reserved by ANSI CL so that even if it were ~
 204                        defined later, the code doing so would not be ~
 205                        portable.~:@>"
 206                       kind name)))
 207                   (if (eq kind :variable)
 208                       (compiler-warn "undefined ~(~A~): ~S" kind name)
 209                       (compiler-style-warn "undefined ~(~A~): ~S" kind name))))
 210             (let ((warn-count (length warnings)))
 211               (when (and warnings (> undefined-warning-count warn-count))
 212                 (let ((more (- undefined-warning-count warn-count)))
 213                   (if (eq kind :variable)
 214                       (compiler-warn
 215                        "~W more use~:P of undefined ~(~A~) ~S"
 216                        more kind name)
 217                       (compiler-style-warn
 218                        "~W more use~:P of undefined ~(~A~) ~S"
 219                        more kind name)))))))
 220
 221         (dolist (kind '(:variable :function :type))
 222           (let ((summary (mapcar #'undefined-warning-name
 223                                  (remove kind undefs :test #'neq
 224                                          :key #'undefined-warning-kind))))
 225             (when summary
 226               (if (eq kind :variable)
 227                   (compiler-warn
 228                    "~:[This ~(~A~) is~;These ~(~A~)s are~] undefined:~
 229                     ~%  ~{~<~%  ~1:;~S~>~^ ~}"
 230                    (cdr summary) kind summary)
 231                   (compiler-style-warn
 232                    "~:[This ~(~A~) is~;These ~(~A~)s are~] undefined:~
 233                    ~%  ~{~<~%  ~1:;~S~>~^ ~}"
 234                    (cdr summary) kind summary))))))))
 235
 236   (unless (and (not abort-p)
 237                (zerop *aborted-compilation-unit-count*)
 238                (zerop *compiler-error-count*)
 239                (zerop *compiler-warning-count*)
 240                (zerop *compiler-style-warning-count*)
 241                (zerop *compiler-note-count*))
 242     (format *error-output* "~&")
 243     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 244       (compiler-mumble "compilation unit ~:[finished~;aborted~]~
 245                        ~[~:;~:*~&  caught ~W fatal ERROR condition~:P~]~
 246                        ~[~:;~:*~&  caught ~W ERROR condition~:P~]~
 247                        ~[~:;~:*~&  caught ~W WARNING condition~:P~]~
 248                        ~[~:;~:*~&  caught ~W STYLE-WARNING condition~:P~]~
 249                        ~[~:;~:*~&  printed ~W note~:P~]"
 250                        abort-p
 251                        *aborted-compilation-unit-count*
 252                        *compiler-error-count*
 253                        *compiler-warning-count*
 254                        *compiler-style-warning-count*
 255                        *compiler-note-count*)))
 256   (format *error-output* "~&"))
 257
 258 ;;; Evaluate BODY, then return (VALUES BODY-VALUE WARNINGS-P
 259 ;;; FAILURE-P), where BODY-VALUE is the first value of the body, and
 260 ;;; WARNINGS-P and FAILURE-P are as in CL:COMPILE or CL:COMPILE-FILE.
 261 ;;; This also wraps up WITH-IR1-NAMESPACE functionality.
 262 (defmacro with-compilation-values (&body body)
 263   `(with-ir1-namespace
 264     (let ((*warnings-p* nil)
 265           (*failure-p* nil))
 266       (values (progn ,@body)
 267               *warnings-p*
 268               *failure-p*))))
 269 \f
 270 ;;;; component compilation
 271
 272 (defparameter *max-optimize-iterations* 3 ; ARB
 273   #!+sb-doc
 274   "The upper limit on the number of times that we will consecutively do IR1
 275   optimization that doesn't introduce any new code. A finite limit is
 276   necessary, since type inference may take arbitrarily long to converge.")
 277
 278 (defevent ir1-optimize-until-done "IR1-OPTIMIZE-UNTIL-DONE called")
 279 (defevent ir1-optimize-maxed-out "hit *MAX-OPTIMIZE-ITERATIONS* limit")
 280
 281 ;;; Repeatedly optimize COMPONENT until no further optimizations can
 282 ;;; be found or we hit our iteration limit. When we hit the limit, we
 283 ;;; clear the component and block REOPTIMIZE flags to discourage the
 284 ;;; next optimization attempt from pounding on the same code.
 285 (defun ir1-optimize-until-done (component)
 286   (declare (type component component))
 287   (maybe-mumble "opt")
 288   (event ir1-optimize-until-done)
 289   (let ((count 0)
 290         (cleared-reanalyze nil))
 291     (loop
 292       (when (component-reanalyze component)
 293         (setq count 0)
 294         (setq cleared-reanalyze t)
 295         (setf (component-reanalyze component) nil))
 296       (setf (component-reoptimize component) nil)
 297       (ir1-optimize component)
 298       (cond ((component-reoptimize component)
 299              (incf count)
 300              (when (= count *max-optimize-iterations*)
 301                (maybe-mumble "*")
 302                (cond ((retry-delayed-ir1-transforms :optimize)
 303                       (maybe-mumble "+")
 304                       (setq count 0))
 305                      (t
 306                       (event ir1-optimize-maxed-out)
 307                       (setf (component-reoptimize component) nil)
 308                       (do-blocks (block component)
 309                         (setf (block-reoptimize block) nil))
 310                       (return)))))
 311             ((retry-delayed-ir1-transforms :optimize)
 312              (setf count 0)
 313              (maybe-mumble "+"))
 314             (t
 315              (maybe-mumble " ")
 316              (return)))
 317       (maybe-mumble "."))
 318     (when cleared-reanalyze
 319       (setf (component-reanalyze component) t)))
 320   (values))
 321
 322 (defparameter *constraint-propagate* t)
 323
 324 ;;; KLUDGE: This was bumped from 5 to 10 in a DTC patch ported by MNA
 325 ;;; from CMU CL into sbcl-0.6.11.44, the same one which allowed IR1
 326 ;;; transforms to be delayed. Either DTC or MNA or both didn't explain
 327 ;;; why, and I don't know what the rationale was. -- WHN 2001-04-28
 328 ;;;
 329 ;;; FIXME: It would be good to document why it's important to have a
 330 ;;; large value here, and what the drawbacks of an excessively large
 331 ;;; value are; and it might also be good to make it depend on
 332 ;;; optimization policy.
 333 (defparameter *reoptimize-after-type-check-max* 10)
 334
 335 (defevent reoptimize-maxed-out
 336   "*REOPTIMIZE-AFTER-TYPE-CHECK-MAX* exceeded.")
 337
 338 ;;; Iterate doing FIND-DFO until no new dead code is discovered.
 339 (defun dfo-as-needed (component)
 340   (declare (type component component))
 341   (when (component-reanalyze component)
 342     (maybe-mumble "DFO")
 343     (loop
 344       (find-dfo component)
 345       (unless (component-reanalyze component)
 346         (maybe-mumble " ")
 347         (return))
 348       (maybe-mumble ".")))
 349   (values))
 350
 351 ;;; Do all the IR1 phases for a non-top-level component.
 352 (defun ir1-phases (component)
 353   (declare (type component component))
 354   (aver-live-component component)
 355   (let ((*constraint-number* 0)
 356         (loop-count 1)
 357         (*delayed-ir1-transforms* nil))
 358     (declare (special *constraint-number* *delayed-ir1-transforms*))
 359     (loop
 360       (ir1-optimize-until-done component)
 361       (when (or (component-new-functionals component)
 362                 (component-reanalyze-functionals component))
 363         (maybe-mumble "locall ")
 364         (locall-analyze-component component))
 365       (dfo-as-needed component)
 366       (when *constraint-propagate*
 367         (maybe-mumble "constraint ")
 368         (constraint-propagate component))
 369       (when (retry-delayed-ir1-transforms :constraint)
 370         (maybe-mumble "Rtran "))
 371       (flet ((want-reoptimization-p ()
 372                (or (component-reoptimize component)
 373                    (component-reanalyze component)
 374                    (component-new-functionals component)
 375                    (component-reanalyze-functionals component))))
 376         (unless (and (want-reoptimization-p)
 377                      ;; We delay the generation of type checks until
 378                      ;; the type constraints have had time to
 379                      ;; propagate, else the compiler can confuse itself.
 380                      (< loop-count (- *reoptimize-after-type-check-max* 4)))
 381           (maybe-mumble "type ")
 382           (generate-type-checks component)
 383           (unless (want-reoptimization-p)
 384             (return))))
 385       (when (>= loop-count *reoptimize-after-type-check-max*)
 386         (maybe-mumble "[reoptimize limit]")
 387         (event reoptimize-maxed-out)
 388         (return))
 389       (incf loop-count)))
 390
 391   (ir1-finalize component)
 392   (values))
 393
 394 (defun %compile-component (component)
 395   (let ((*code-segment* nil)
 396         (*elsewhere* nil))
 397     (maybe-mumble "GTN ")
 398     (gtn-analyze component)
 399     (maybe-mumble "LTN ")
 400     (ltn-analyze component)
 401     (dfo-as-needed component)
 402     (maybe-mumble "control ")
 403     (control-analyze component #'make-ir2-block)
 404
 405     (when (or (ir2-component-values-receivers (component-info component))
 406               (component-dx-lvars component))
 407       (maybe-mumble "stack ")
 408       (stack-analyze component)
 409       ;; Assign BLOCK-NUMBER for any cleanup blocks introduced by
 410       ;; stack analysis. There shouldn't be any unreachable code after
 411       ;; control, so this won't delete anything.
 412       (dfo-as-needed component))
 413
 414     (unwind-protect
 415         (progn
 416           (maybe-mumble "IR2tran ")
 417           (init-assembler)
 418           (entry-analyze component)
 419           (ir2-convert component)
 420
 421           (when (policy *lexenv* (>= speed compilation-speed))
 422             (maybe-mumble "copy ")
 423             (copy-propagate component))
 424
 425           (select-representations component)
 426
 427           (when *check-consistency*
 428             (maybe-mumble "check2 ")
 429             (check-ir2-consistency component))
 430
 431           (delete-unreferenced-tns component)
 432
 433           (maybe-mumble "life ")
 434           (lifetime-analyze component)
 435
 436           (when *compile-progress*
 437             (compiler-mumble "") ; Sync before doing more output.
 438             (pre-pack-tn-stats component *error-output*))
 439
 440           (when *check-consistency*
 441             (maybe-mumble "check-life ")
 442             (check-life-consistency component))
 443
 444           (maybe-mumble "pack ")
 445           (pack component)
 446
 447           (when *check-consistency*
 448             (maybe-mumble "check-pack ")
 449             (check-pack-consistency component))
 450
 451           (when *compiler-trace-output*
 452             (describe-component component *compiler-trace-output*)
 453             (describe-ir2-component component *compiler-trace-output*))
 454
 455           (maybe-mumble "code ")
 456           (multiple-value-bind (code-length trace-table fixup-notes)
 457               (generate-code component)
 458
 459             #-sb-xc-host
 460             (when *compiler-trace-output*
 461               (format *compiler-trace-output*
 462                       "~|~%disassembly of code for ~S~2%" component)
 463               (sb!disassem:disassemble-assem-segment *code-segment*
 464                                                      *compiler-trace-output*))
 465
 466             (etypecase *compile-object*
 467               (fasl-output
 468                (maybe-mumble "fasl")
 469                (fasl-dump-component component
 470                                     *code-segment*
 471                                     code-length
 472                                     trace-table
 473                                     fixup-notes
 474                                     *compile-object*))
 475               (core-object
 476                (maybe-mumble "core")
 477                (make-core-component component
 478                                     *code-segment*
 479                                     code-length
 480                                     trace-table
 481                                     fixup-notes
 482                                     *compile-object*))
 483               (null))))))
 484
 485   ;; We're done, so don't bother keeping anything around.
 486   (setf (component-info component) :dead)
 487
 488   (values))
 489
 490 ;;; Delete components with no external entry points before we try to
 491 ;;; generate code. Unreachable closures can cause IR2 conversion to
 492 ;;; puke on itself, since it is the reference to the closure which
 493 ;;; normally causes the components to be combined.
 494 (defun delete-if-no-entries (component)
 495   (dolist (fun (component-lambdas component) (delete-component component))
 496     (when (functional-has-external-references-p fun)
 497       (return))
 498     (case (functional-kind fun)
 499       (:toplevel (return))
 500       (:external
 501        (unless (every (lambda (ref)
 502                         (eq (node-component ref) component))
 503                       (leaf-refs fun))
 504          (return))))))
 505
 506 (defun compile-component (component)
 507
 508   ;; miscellaneous sanity checks
 509   ;;
 510   ;; FIXME: These are basically pretty wimpy compared to the checks done
 511   ;; by the old CHECK-IR1-CONSISTENCY code. It would be really nice to
 512   ;; make those internal consistency checks work again and use them.
 513   (aver-live-component component)
 514   (do-blocks (block component)
 515     (aver (eql (block-component block) component)))
 516   (dolist (lambda (component-lambdas component))
 517     ;; sanity check to prevent weirdness from propagating insidiously as
 518     ;; far from its root cause as it did in bug 138: Make sure that
 519     ;; thing-to-COMPONENT links are consistent.
 520     (aver (eql (lambda-component lambda) component))
 521     (aver (eql (node-component (lambda-bind lambda)) component)))
 522
 523   (let* ((*component-being-compiled* component))
 524     (when sb!xc:*compile-print*
 525       (compiler-mumble "~&; compiling ~A: " (component-name component)))
 526
 527     (ir1-phases component)
 528
 529     (when *loop-analyze*
 530       (find-dominators component)
 531       (loop-analyze component))
 532
 533     #|
 534     (when (and *loop-analyze* *compiler-trace-output*)
 535       (labels ((print-blocks (block)
 536                  (format *compiler-trace-output* "    ~A~%" block)
 537                  (when (block-loop-next block)
 538                    (print-blocks (block-loop-next block))))
 539                (print-loop (loop)
 540                  (format *compiler-trace-output* "loop=~A~%" loop)
 541                  (print-blocks (loop-blocks loop))
 542                  (dolist (l (loop-inferiors loop))
 543                    (print-loop l))))
 544         (print-loop (component-outer-loop component))))
 545     |#
 546
 547     ;; FIXME: What is MAYBE-MUMBLE for? Do we need it any more?
 548     (maybe-mumble "env ")
 549     (physenv-analyze component)
 550     (dfo-as-needed component)
 551
 552     (delete-if-no-entries component)
 553
 554     (unless (eq (block-next (component-head component))
 555                 (component-tail component))
 556       (%compile-component component)))
 557
 558   (clear-constant-info)
 559
 560   (when sb!xc:*compile-print*
 561     (compiler-mumble "~&"))
 562
 563   (values))
 564 \f
 565 ;;;; clearing global data structures
 566 ;;;;
 567 ;;;; FIXME: Is it possible to get rid of this stuff, getting rid of
 568 ;;;; global data structures entirely when possible and consing up the
 569 ;;;; others from scratch instead of clearing and reusing them?
 570
 571 ;;; Clear the INFO in constants in the *FREE-VARS*, etc. In
 572 ;;; addition to allowing stuff to be reclaimed, this is required for
 573 ;;; correct assignment of constant offsets, since we need to assign a
 574 ;;; new offset for each component. We don't clear the FUNCTIONAL-INFO
 575 ;;; slots, since they are used to keep track of functions across
 576 ;;; component boundaries.
 577 (defun clear-constant-info ()
 578   (maphash (lambda (k v)
 579              (declare (ignore k))
 580              (setf (leaf-info v) nil))
 581            *constants*)
 582   (maphash (lambda (k v)
 583              (declare (ignore k))
 584              (when (constant-p v)
 585                (setf (leaf-info v) nil)))
 586            *free-vars*)
 587   (values))
 588
 589 ;;; Blow away the REFS for all global variables, and let COMPONENT
 590 ;;; be recycled.
 591 (defun clear-ir1-info (component)
 592   (declare (type component component))
 593   (labels ((blast (x)
 594              (maphash (lambda (k v)
 595                         (declare (ignore k))
 596                         (when (leaf-p v)
 597                           (setf (leaf-refs v)
 598                                 (delete-if #'here-p (leaf-refs v)))
 599                           (when (basic-var-p v)
 600                             (setf (basic-var-sets v)
 601                                   (delete-if #'here-p (basic-var-sets v))))))
 602                       x))
 603            (here-p (x)
 604              (eq (node-component x) component)))
 605     (blast *free-vars*)
 606     (blast *free-funs*)
 607     (blast *constants*))
 608   (values))
 609
 610 ;;; Clear global variables used by the compiler.
 611 ;;;
 612 ;;; FIXME: It seems kinda nasty and unmaintainable to have to do this,
 613 ;;; and it adds overhead even when people aren't using the compiler.
 614 ;;; Perhaps we could make these global vars unbound except when
 615 ;;; actually in use, so that this function could go away.
 616 (defun clear-stuff (&optional (debug-too t))
 617
 618   ;; Clear global tables.
 619   (when (boundp '*free-funs*)
 620     (clrhash *free-funs*)
 621     (clrhash *free-vars*)
 622     (clrhash *constants*))
 623
 624   ;; Clear debug counters and tables.
 625   (clrhash *seen-blocks*)
 626   (clrhash *seen-funs*)
 627   (clrhash *list-conflicts-table*)
 628
 629   (when debug-too
 630     (clrhash *continuation-numbers*)
 631     (clrhash *number-continuations*)
 632     (setq *continuation-number* 0)
 633     (clrhash *tn-ids*)
 634     (clrhash *id-tns*)
 635     (setq *tn-id* 0)
 636     (clrhash *label-ids*)
 637     (clrhash *id-labels*)
 638     (setq *label-id* 0))
 639
 640   ;; (Note: The CMU CL code used to set CL::*GENSYM-COUNTER* to zero here.
 641   ;; Superficially, this seemed harmful -- the user could reasonably be
 642   ;; surprised if *GENSYM-COUNTER* turned back to zero when something was
 643   ;; compiled. A closer inspection showed that this actually turned out to be
 644   ;; harmless in practice, because CLEAR-STUFF was only called from within
 645   ;; forms which bound CL::*GENSYM-COUNTER* to zero. However, this means that
 646   ;; even though zeroing CL::*GENSYM-COUNTER* here turned out to be harmless in
 647   ;; practice, it was also useless in practice. So we don't do it any more.)
 648
 649   (values))
 650 \f
 651 ;;;; trace output
 652
 653 ;;; Print out some useful info about COMPONENT to STREAM.
 654 (defun describe-component (component *standard-output*)
 655   (declare (type component component))
 656   (format t "~|~%;;;; component: ~S~2%" (component-name component))
 657   (print-all-blocks component)
 658   (values))
 659
 660 (defun describe-ir2-component (component *standard-output*)
 661   (format t "~%~|~%;;;; IR2 component: ~S~2%" (component-name component))
 662   (format t "entries:~%")
 663   (dolist (entry (ir2-component-entries (component-info component)))
 664     (format t "~4TL~D: ~S~:[~; [closure]~]~%"
 665             (label-id (entry-info-offset entry))
 666             (entry-info-name entry)
 667             (entry-info-closure-p entry)))
 668   (terpri)
 669   (pre-pack-tn-stats component *standard-output*)
 670   (terpri)
 671   (print-ir2-blocks component)
 672   (terpri)
 673   (values))
 674 \f
 675 ;;;; file reading
 676 ;;;;
 677 ;;;; When reading from a file, we have to keep track of some source
 678 ;;;; information. We also exploit our ability to back up for printing
 679 ;;;; the error context and for recovering from errors.
 680 ;;;;
 681 ;;;; The interface we provide to this stuff is the stream-oid
 682 ;;;; SOURCE-INFO structure. The bookkeeping is done as a side effect
 683 ;;;; of getting the next source form.
 684
 685 ;;; A FILE-INFO structure holds all the source information for a
 686 ;;; given file.
 687 (def!struct (file-info (:copier nil))
 688   ;; If a file, the truename of the corresponding source file. If from
 689   ;; a Lisp form, :LISP. If from a stream, :STREAM.
 690   (name (missing-arg) :type (or pathname (member :lisp :stream)))
 691   ;; the defaulted, but not necessarily absolute file name (i.e. prior
 692   ;; to TRUENAME call.) Null if not a file. This is used to set
 693   ;; *COMPILE-FILE-PATHNAME*, and if absolute, is dumped in the
 694   ;; debug-info.
 695   (untruename nil :type (or pathname null))
 696   ;; the file's write date (if relevant)
 697   (write-date nil :type (or unsigned-byte null))
 698   ;; the source path root number of the first form in this file (i.e.
 699   ;; the total number of forms converted previously in this
 700   ;; compilation)
 701   (source-root 0 :type unsigned-byte)
 702   ;; parallel vectors containing the forms read out of the file and
 703   ;; the file positions that reading of each form started at (i.e. the
 704   ;; end of the previous form)
 705   (forms (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t))
 706   (positions (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t)))
 707
 708 ;;; The SOURCE-INFO structure provides a handle on all the source
 709 ;;; information for an entire compilation.
 710 (def!struct (source-info
 711              #-no-ansi-print-object
 712              (:print-object (lambda (s stream)
 713                               (print-unreadable-object (s stream :type t))))
 714              (:copier nil))
 715   ;; the UT that compilation started at
 716   (start-time (get-universal-time) :type unsigned-byte)
 717   ;; the FILE-INFO structure for this compilation
 718   (file-info nil :type (or file-info null))
 719   ;; the stream that we are using to read the FILE-INFO, or NIL if
 720   ;; no stream has been opened yet
 721   (stream nil :type (or stream null)))
 722
 723 ;;; Given a pathname, return a SOURCE-INFO structure.
 724 (defun make-file-source-info (file)
 725   (let ((file-info (make-file-info :name (truename file)
 726                                    :untruename file
 727                                    :write-date (file-write-date file))))
 728
 729     (make-source-info :file-info file-info)))
 730
 731 ;;; Return a SOURCE-INFO to describe the incremental compilation of FORM.
 732 (defun make-lisp-source-info (form)
 733   (make-source-info :start-time (get-universal-time)
 734                     :file-info (make-file-info :name :lisp
 735                                                :forms (vector form)
 736                                                :positions '#(0))))
 737
 738 ;;; Return a SOURCE-INFO which will read from STREAM.
 739 (defun make-stream-source-info (stream)
 740   (let ((file-info (make-file-info :name :stream)))
 741     (make-source-info :file-info file-info
 742                       :stream stream)))
 743
 744 ;;; Return a form read from STREAM; or for EOF use the trick,
 745 ;;; popularized by Kent Pitman, of returning STREAM itself. If an
 746 ;;; error happens, then convert it to standard abort-the-compilation
 747 ;;; error condition (possibly recording some extra location
 748 ;;; information).
 749 (defun read-for-compile-file (stream position)
 750   (handler-case (read stream nil stream)
 751     (reader-error (condition)
 752      (error 'input-error-in-compile-file
 753             :condition condition
 754             ;; We don't need to supply :POSITION here because
 755             ;; READER-ERRORs already know their position in the file.
 756             ))
 757     ;; ANSI, in its wisdom, says that READ should return END-OF-FILE
 758     ;; (and that this is not a READER-ERROR) when it encounters end of
 759     ;; file in the middle of something it's trying to read.
 760     (end-of-file (condition)
 761      (error 'input-error-in-compile-file
 762             :condition condition
 763             ;; We need to supply :POSITION here because the END-OF-FILE
 764             ;; condition doesn't carry the position that the user
 765             ;; probably cares about, where the failed READ began.
 766             :position position))))
 767
 768 ;;; If STREAM is present, return it, otherwise open a stream to the
 769 ;;; current file. There must be a current file.
 770 ;;;
 771 ;;; FIXME: This is probably an unnecessarily roundabout way to do
 772 ;;; things now that we process a single file in COMPILE-FILE (unlike
 773 ;;; the old CMU CL code, which accepted multiple files). Also, the old
 774 ;;; comment said
 775 ;;;   When we open a new file, we also reset *PACKAGE* and policy.
 776 ;;;   This gives the effect of rebinding around each file.
 777 ;;; which doesn't seem to be true now. Check to make sure that if
 778 ;;; such rebinding is necessary, it's still done somewhere.
 779 (defun get-source-stream (info)
 780   (declare (type source-info info))
 781   (or (source-info-stream info)
 782       (let* ((file-info (source-info-file-info info))
 783              (name (file-info-name file-info)))
 784         (setf sb!xc:*compile-file-truename* name
 785               sb!xc:*compile-file-pathname* (file-info-untruename file-info)
 786               (source-info-stream info) (open name :direction :input)))))
 787
 788 ;;; Close the stream in INFO if it is open.
 789 (defun close-source-info (info)
 790   (declare (type source-info info))
 791   (let ((stream (source-info-stream info)))
 792     (when stream (close stream)))
 793   (setf (source-info-stream info) nil)
 794   (values))
 795
 796 ;;; Read and compile the source file.
 797 (defun sub-sub-compile-file (info)
 798   (let* ((file-info (source-info-file-info info))
 799          (stream (get-source-stream info)))
 800     (loop
 801      (let* ((pos (file-position stream))
 802             (form (read-for-compile-file stream pos)))
 803        (if (eq form stream) ; i.e., if EOF
 804            (return)
 805            (let* ((forms (file-info-forms file-info))
 806                   (current-idx (+ (fill-pointer forms)
 807                                   (file-info-source-root file-info))))
 808              (vector-push-extend form forms)
 809              (vector-push-extend pos (file-info-positions file-info))
 810              (find-source-paths form current-idx)
 811              (process-toplevel-form form
 812                                     `(original-source-start 0 ,current-idx)
 813                                     nil)))))))
 814
 815 ;;; Return the INDEX'th source form read from INFO and the position
 816 ;;; where it was read.
 817 (defun find-source-root (index info)
 818   (declare (type index index) (type source-info info))
 819   (let ((file-info (source-info-file-info info)))
 820     (values (aref (file-info-forms file-info) index)
 821             (aref (file-info-positions file-info) index))))
 822 \f
 823 ;;;; processing of top level forms
 824
 825 ;;; This is called by top level form processing when we are ready to
 826 ;;; actually compile something. If *BLOCK-COMPILE* is T, then we still
 827 ;;; convert the form, but delay compilation, pushing the result on
 828 ;;; *TOPLEVEL-LAMBDAS* instead.
 829 (defun convert-and-maybe-compile (form path)
 830   (declare (list path))
 831   (let* ((*lexenv* (make-lexenv :policy *policy*
 832                                 :handled-conditions *handled-conditions*
 833                                 :disabled-package-locks *disabled-package-locks*))
 834          (tll (ir1-toplevel form path nil)))
 835     (cond ((eq *block-compile* t) (push tll *toplevel-lambdas*))
 836           (t (compile-toplevel (list tll) nil)))))
 837
 838 ;;; Macroexpand FORM in the current environment with an error handler.
 839 ;;; We only expand one level, so that we retain all the intervening
 840 ;;; forms in the source path.
 841 (defun preprocessor-macroexpand-1 (form)
 842   (handler-case (sb!xc:macroexpand-1 form *lexenv*)
 843     (error (condition)
 844       (compiler-error "(during macroexpansion of ~A)~%~A"
 845                       (let ((*print-level* 1)
 846                             (*print-length* 2))
 847                         (format nil "~S" form))
 848                       condition))))
 849
 850 ;;; Process a PROGN-like portion of a top level form. FORMS is a list of
 851 ;;; the forms, and PATH is the source path of the FORM they came out of.
 852 ;;; COMPILE-TIME-TOO is as in ANSI "3.2.3.1 Processing of Top Level Forms".
 853 (defun process-toplevel-progn (forms path compile-time-too)
 854   (declare (list forms) (list path))
 855   (dolist (form forms)
 856     (process-toplevel-form form path compile-time-too)))
 857
 858 ;;; Process a top level use of LOCALLY, or anything else (e.g.
 859 ;;; MACROLET) at top level which has declarations and ordinary forms.
 860 ;;; We parse declarations and then recursively process the body.
 861 (defun process-toplevel-locally (body path compile-time-too &key vars funs)
 862   (declare (list path))
 863   (multiple-value-bind (forms decls)
 864       (parse-body body :doc-string-allowed nil :toplevel t)
 865     (let* ((*lexenv* (process-decls decls vars funs))
 866            ;; FIXME: VALUES declaration
 867            ;;
 868            ;; Binding *POLICY* is pretty much of a hack, since it
 869            ;; causes LOCALLY to "capture" enclosed proclamations. It
 870            ;; is necessary because CONVERT-AND-MAYBE-COMPILE uses the
 871            ;; value of *POLICY* as the policy. The need for this hack
 872            ;; is due to the quirk that there is no way to represent in
 873            ;; a POLICY that an optimize quality came from the default.
 874            ;;
 875            ;; FIXME: Ideally, something should be done so that DECLAIM
 876            ;; inside LOCALLY works OK. Failing that, at least we could
 877            ;; issue a warning instead of silently screwing up.
 878            (*policy* (lexenv-policy *lexenv*))
 879            ;; This is probably also a hack
 880            (*handled-conditions* (lexenv-handled-conditions *lexenv*))
 881            ;; ditto
 882            (*disabled-package-locks* (lexenv-disabled-package-locks *lexenv*)))
 883       (process-toplevel-progn forms path compile-time-too))))
 884
 885 ;;; Parse an EVAL-WHEN situations list, returning three flags,
 886 ;;; (VALUES COMPILE-TOPLEVEL LOAD-TOPLEVEL EXECUTE), indicating
 887 ;;; the types of situations present in the list.
 888 (defun parse-eval-when-situations (situations)
 889   (when (or (not (listp situations))
 890             (set-difference situations
 891                             '(:compile-toplevel
 892                               compile
 893                               :load-toplevel
 894                               load
 895                               :execute
 896                               eval)))
 897     (compiler-error "bad EVAL-WHEN situation list: ~S" situations))
 898   (let ((deprecated-names (intersection situations '(compile load eval))))
 899     (when deprecated-names
 900       (style-warn "using deprecated EVAL-WHEN situation names~{ ~S~}"
 901                   deprecated-names)))
 902   (values (intersection '(:compile-toplevel compile)
 903                         situations)
 904           (intersection '(:load-toplevel load) situations)
 905           (intersection '(:execute eval) situations)))
 906
 907
 908 ;;; utilities for extracting COMPONENTs of FUNCTIONALs
 909 (defun functional-components (f)
 910   (declare (type functional f))
 911   (etypecase f
 912     (clambda (list (lambda-component f)))
 913     (optional-dispatch (let ((result nil))
 914                          (flet ((maybe-frob (maybe-clambda)
 915                                   (when (and maybe-clambda
 916                                              (promise-ready-p maybe-clambda))
 917                                     (pushnew (lambda-component
 918                                               (force maybe-clambda))
 919                                              result))))
 920                            (map nil #'maybe-frob (optional-dispatch-entry-points f))
 921                            (maybe-frob (optional-dispatch-more-entry f))
 922                            (maybe-frob (optional-dispatch-main-entry f)))
 923                          result))))
 924
 925 (defun make-functional-from-toplevel-lambda (definition
 926                                              &key
 927                                              name
 928                                              (path
 929                                               ;; I'd thought NIL should
 930                                               ;; work, but it doesn't.
 931                                               ;; -- WHN 2001-09-20
 932                                               (missing-arg)))
 933   (let* ((*current-path* path)
 934          (component (make-empty-component))
 935          (*current-component* component))
 936     (setf (component-name component)
 937           (debug-namify "~S initial component" name))
 938     (setf (component-kind component) :initial)
 939     (let* ((locall-fun (let ((*allow-instrumenting* t))
 940                          (ir1-convert-lambdalike
 941                           definition
 942                           :debug-name (debug-namify "top level local call "
 943                                                     name))))
 944            (fun (ir1-convert-lambda (make-xep-lambda-expression locall-fun)
 945                                     :source-name (or name '.anonymous.)
 946                                     :debug-name (unless name
 947                                                   "top level form"))))
 948       (when name
 949         (assert-global-function-definition-type name locall-fun))
 950       (setf (functional-entry-fun fun) locall-fun
 951             (functional-kind fun) :external
 952             (functional-has-external-references-p fun) t)
 953       fun)))
 954
 955 ;;; Compile LAMBDA-EXPRESSION into *COMPILE-OBJECT*, returning a
 956 ;;; description of the result.
 957 ;;;   * If *COMPILE-OBJECT* is a CORE-OBJECT, then write the function
 958 ;;;     into core and return the compiled FUNCTION value.
 959 ;;;   * If *COMPILE-OBJECT* is a fasl file, then write the function
 960 ;;;     into the fasl file and return a dump handle.
 961 ;;;
 962 ;;; If NAME is provided, then we try to use it as the name of the
 963 ;;; function for debugging/diagnostic information.
 964 (defun %compile (lambda-expression
 965                  *compile-object*
 966                  &key
 967                  name
 968                  (path
 969                   ;; This magical idiom seems to be the appropriate
 970                   ;; path for compiling standalone LAMBDAs, judging
 971                   ;; from the CMU CL code and experiment, so it's a
 972                   ;; nice default for things where we don't have a
 973                   ;; real source path (as in e.g. inside CL:COMPILE).
 974                   '(original-source-start 0 0)))
 975   (when name
 976     (legal-fun-name-or-type-error name))
 977   (let* (
 978          (*lexenv* (make-lexenv :policy *policy*
 979                                 :handled-conditions *handled-conditions*
 980                                 :disabled-package-locks *disabled-package-locks*))
 981          (fun (make-functional-from-toplevel-lambda lambda-expression
 982                                                     :name name
 983                                                     :path path)))
 984
 985     ;; FIXME: The compile-it code from here on is sort of a
 986     ;; twisted version of the code in COMPILE-TOPLEVEL. It'd be
 987     ;; better to find a way to share the code there; or
 988     ;; alternatively, to use this code to replace the code there.
 989     ;; (The second alternative might be pretty easy if we used
 990     ;; the :LOCALL-ONLY option to IR1-FOR-LAMBDA. Then maybe the
 991     ;; whole FUNCTIONAL-KIND=:TOPLEVEL case could go away..)
 992
 993     (locall-analyze-clambdas-until-done (list fun))
 994
 995     (multiple-value-bind (components-from-dfo top-components hairy-top)
 996         (find-initial-dfo (list fun))
 997
 998       (let ((*all-components* (append components-from-dfo top-components)))
 999         ;; FIXME: This is more monkey see monkey do based on CMU CL
1000         ;; code. If anyone figures out why to only prescan HAIRY-TOP
1001         ;; and TOP-COMPONENTS here, instead of *ALL-COMPONENTS* or
1002         ;; some other combination of results from FIND-INITIAL-VALUES,
1003         ;; it'd be good to explain it.
1004         (mapc #'preallocate-physenvs-for-toplevelish-lambdas hairy-top)
1005         (mapc #'preallocate-physenvs-for-toplevelish-lambdas top-components)
1006         (dolist (component-from-dfo components-from-dfo)
1007           (compile-component component-from-dfo)
1008           (replace-toplevel-xeps component-from-dfo)))
1009
1010       (let ((entry-table (etypecase *compile-object*
1011                            (fasl-output (fasl-output-entry-table
1012                                          *compile-object*))
1013                            (core-object (core-object-entry-table
1014                                          *compile-object*)))))
1015         (multiple-value-bind (result found-p)
1016             (gethash (leaf-info fun) entry-table)
1017           (aver found-p)
1018           (prog1
1019               result
1020             ;; KLUDGE: This code duplicates some other code in this
1021             ;; file. In the great reorganzation, the flow of program
1022             ;; logic changed from the original CMUCL model, and that
1023             ;; path (as of sbcl-0.7.5 in SUB-COMPILE-FILE) was no
1024             ;; longer followed for CORE-OBJECTS, leading to BUG
1025             ;; 156. This place is transparently not the right one for
1026             ;; this code, but I don't have a clear enough overview of
1027             ;; the compiler to know how to rearrange it all so that
1028             ;; this operation fits in nicely, and it was blocking
1029             ;; reimplementation of (DECLAIM (INLINE FOO)) (MACROLET
1030             ;; ((..)) (DEFUN FOO ...))
1031             ;;
1032             ;; FIXME: This KLUDGE doesn't solve all the problem in an
1033             ;; ideal way, as (1) definitions typed in at the REPL
1034             ;; without an INLINE declaration will give a NULL
1035             ;; FUNCTION-LAMBDA-EXPRESSION (allowable, but not ideal)
1036             ;; and (2) INLINE declarations will yield a
1037             ;; FUNCTION-LAMBDA-EXPRESSION headed by
1038             ;; SB-C:LAMBDA-WITH-LEXENV, even for null LEXENV.  -- CSR,
1039             ;; 2002-07-02
1040             ;;
1041             ;; (2) is probably fairly easy to fix -- it is, after all,
1042             ;; a matter of list manipulation (or possibly of teaching
1043             ;; CL:FUNCTION about SB-C:LAMBDA-WITH-LEXENV).  (1) is
1044             ;; significantly harder, as the association between
1045             ;; function object and source is a tricky one.
1046             ;;
1047             ;; FUNCTION-LAMBDA-EXPRESSION "works" (i.e. returns a
1048             ;; non-NULL list) when the function in question has been
1049             ;; compiled by (COMPILE <x> '(LAMBDA ...)); it does not
1050             ;; work when it has been compiled as part of the top-level
1051             ;; EVAL strategy of compiling everything inside (LAMBDA ()
1052             ;; ...).  -- CSR, 2002-11-02
1053             (when (core-object-p *compile-object*)
1054               (fix-core-source-info *source-info* *compile-object* result))
1055
1056             (mapc #'clear-ir1-info components-from-dfo)
1057             (clear-stuff)))))))
1058
1059 (defun process-toplevel-cold-fset (name lambda-expression path)
1060   (unless (producing-fasl-file)
1061     (error "can't COLD-FSET except in a fasl file"))
1062   (legal-fun-name-or-type-error name)
1063   (fasl-dump-cold-fset name
1064                        (%compile lambda-expression
1065                                  *compile-object*
1066                                  :name name
1067                                  :path path)
1068                        *compile-object*)
1069   (values))
1070
1071 ;;; Process a top level FORM with the specified source PATH.
1072 ;;;  * If this is a magic top level form, then do stuff.
1073 ;;;  * If this is a macro, then expand it.
1074 ;;;  * Otherwise, just compile it.
1075 ;;;
1076 ;;; COMPILE-TIME-TOO is as defined in ANSI
1077 ;;; "3.2.3.1 Processing of Top Level Forms".
1078 (defun process-toplevel-form (form path compile-time-too)
1079
1080   (declare (list path))
1081
1082   (catch 'process-toplevel-form-error-abort
1083     (let* ((path (or (gethash form *source-paths*) (cons form path)))
1084            (*compiler-error-bailout*
1085             (lambda (&optional condition)
1086               (convert-and-maybe-compile
1087                (make-compiler-error-form condition form)
1088                path)
1089               (throw 'process-toplevel-form-error-abort nil))))
1090
1091       (flet ((default-processor (form)
1092                ;; When we're cross-compiling, consider: what should we
1093                ;; do when we hit e.g.
1094                ;;   (EVAL-WHEN (:COMPILE-TOPLEVEL)
1095                ;;     (DEFUN FOO (X) (+ 7 X)))?
1096                ;; DEFUN has a macro definition in the cross-compiler,
1097                ;; and a different macro definition in the target
1098                ;; compiler. The only sensible thing is to use the
1099                ;; target compiler's macro definition, since the
1100                ;; cross-compiler's macro is in general into target
1101                ;; functions which can't meaningfully be executed at
1102                ;; cross-compilation time. So make sure we do the EVAL
1103                ;; here, before we macroexpand.
1104                ;;
1105                ;; Then things get even dicier with something like
1106                ;;   (DEFCONSTANT-EQX SB!XC:LAMBDA-LIST-KEYWORDS ..)
1107                ;; where we have to make sure that we don't uncross
1108                ;; the SB!XC: prefix before we do EVAL, because otherwise
1109                ;; we'd be trying to redefine the cross-compilation host's
1110                ;; constants.
1111                ;;
1112                ;; (Isn't it fun to cross-compile Common Lisp?:-)
1113                #+sb-xc-host
1114                (progn
1115                  (when compile-time-too
1116                    (eval form)) ; letting xc host EVAL do its own macroexpansion
1117                  (let* (;; (We uncross the operator name because things
1118                         ;; like SB!XC:DEFCONSTANT and SB!XC:DEFTYPE
1119                         ;; should be equivalent to their CL: counterparts
1120                         ;; when being compiled as target code. We leave
1121                         ;; the rest of the form uncrossed because macros
1122                         ;; might yet expand into EVAL-WHEN stuff, and
1123                         ;; things inside EVAL-WHEN can't be uncrossed
1124                         ;; until after we've EVALed them in the
1125                         ;; cross-compilation host.)
1126                         (slightly-uncrossed (cons (uncross (first form))
1127                                                   (rest form)))
1128                         (expanded (preprocessor-macroexpand-1
1129                                    slightly-uncrossed)))
1130                    (if (eq expanded slightly-uncrossed)
1131                        ;; (Now that we're no longer processing toplevel
1132                        ;; forms, and hence no longer need to worry about
1133                        ;; EVAL-WHEN, we can uncross everything.)
1134                        (convert-and-maybe-compile expanded path)
1135                        ;; (We have to demote COMPILE-TIME-TOO to NIL
1136                        ;; here, no matter what it was before, since
1137                        ;; otherwise we'd tend to EVAL subforms more than
1138                        ;; once, because of WHEN COMPILE-TIME-TOO form
1139                        ;; above.)
1140                        (process-toplevel-form expanded path nil))))
1141                ;; When we're not cross-compiling, we only need to
1142                ;; macroexpand once, so we can follow the 1-thru-6
1143                ;; sequence of steps in ANSI's "3.2.3.1 Processing of
1144                ;; Top Level Forms".
1145                #-sb-xc-host
1146                (let ((expanded (preprocessor-macroexpand-1 form)))
1147                  (cond ((eq expanded form)
1148                         (when compile-time-too
1149                           (eval-in-lexenv form *lexenv*))
1150                         (convert-and-maybe-compile form path))
1151                        (t
1152                         (process-toplevel-form expanded
1153                                                path
1154                                                compile-time-too))))))
1155         (if (atom form)
1156             #+sb-xc-host
1157             ;; (There are no xc EVAL-WHEN issues in the ATOM case until
1158             ;; (1) SBCL gets smart enough to handle global
1159             ;; DEFINE-SYMBOL-MACRO or SYMBOL-MACROLET and (2) SBCL
1160             ;; implementors start using symbol macros in a way which
1161             ;; interacts with SB-XC/CL distinction.)
1162             (convert-and-maybe-compile form path)
1163             #-sb-xc-host
1164             (default-processor form)
1165             (flet ((need-at-least-one-arg (form)
1166                      (unless (cdr form)
1167                        (compiler-error "~S form is too short: ~S"
1168                                        (car form)
1169                                        form))))
1170               (case (car form)
1171                 ;; In the cross-compiler, top level COLD-FSET arranges
1172                 ;; for static linking at cold init time.
1173                 #+sb-xc-host
1174                 ((cold-fset)
1175                  (aver (not compile-time-too))
1176                  (destructuring-bind (cold-fset fun-name lambda-expression) form
1177                    (declare (ignore cold-fset))
1178                    (process-toplevel-cold-fset fun-name
1179                                                lambda-expression
1180                                                path)))
1181                 ((eval-when macrolet symbol-macrolet);things w/ 1 arg before body
1182                  (need-at-least-one-arg form)
1183                  (destructuring-bind (special-operator magic &rest body) form
1184                    (ecase special-operator
1185                      ((eval-when)
1186                       ;; CT, LT, and E here are as in Figure 3-7 of ANSI
1187                       ;; "3.2.3.1 Processing of Top Level Forms".
1188                       (multiple-value-bind (ct lt e)
1189                           (parse-eval-when-situations magic)
1190                         (let ((new-compile-time-too (or ct
1191                                                         (and compile-time-too
1192                                                              e))))
1193                           (cond (lt (process-toplevel-progn
1194                                      body path new-compile-time-too))
1195                                 (new-compile-time-too (eval-in-lexenv
1196                                                        `(progn ,@body)
1197                                                        *lexenv*))))))
1198                      ((macrolet)
1199                       (funcall-in-macrolet-lexenv
1200                        magic
1201                        (lambda (&key funs prepend)
1202                          (declare (ignore funs))
1203                          (aver (null prepend))
1204                          (process-toplevel-locally body
1205                                                    path
1206                                                    compile-time-too))
1207                        :compile))
1208                      ((symbol-macrolet)
1209                       (funcall-in-symbol-macrolet-lexenv
1210                        magic
1211                        (lambda (&key vars prepend)
1212                          (aver (null prepend))
1213                          (process-toplevel-locally body
1214                                                    path
1215                                                    compile-time-too
1216                                                    :vars vars))
1217                        :compile)))))
1218                 ((locally)
1219                  (process-toplevel-locally (rest form) path compile-time-too))
1220                 ((progn)
1221                  (process-toplevel-progn (rest form) path compile-time-too))
1222                 (t (default-processor form))))))))
1223
1224   (values))
1225 \f
1226 ;;;; load time value support
1227 ;;;;
1228 ;;;; (See EMIT-MAKE-LOAD-FORM.)
1229
1230 ;;; Return T if we are currently producing a fasl file and hence
1231 ;;; constants need to be dumped carefully.
1232 (defun producing-fasl-file ()
1233   (fasl-output-p *compile-object*))
1234
1235 ;;; Compile FORM and arrange for it to be called at load-time. Return
1236 ;;; the dumper handle and our best guess at the type of the object.
1237 (defun compile-load-time-value (form)
1238   (let ((lambda (compile-load-time-stuff form t)))
1239     (values
1240      (fasl-dump-load-time-value-lambda lambda *compile-object*)
1241      (let ((type (leaf-type lambda)))
1242        (if (fun-type-p type)
1243            (single-value-type (fun-type-returns type))
1244            *wild-type*)))))
1245
1246 ;;; Compile the FORMS and arrange for them to be called (for effect,
1247 ;;; not value) at load time.
1248 (defun compile-make-load-form-init-forms (forms)
1249   (let ((lambda (compile-load-time-stuff `(progn ,@forms) nil)))
1250     (fasl-dump-toplevel-lambda-call lambda *compile-object*)))
1251
1252 ;;; Do the actual work of COMPILE-LOAD-TIME-VALUE or
1253 ;;; COMPILE-MAKE-LOAD-FORM-INIT-FORMS.
1254 (defun compile-load-time-stuff (form for-value)
1255   (with-ir1-namespace
1256    (let* ((*lexenv* (make-null-lexenv))
1257           (lambda (ir1-toplevel form *current-path* for-value)))
1258      (compile-toplevel (list lambda) t)
1259      lambda)))
1260
1261 ;;; This is called by COMPILE-TOPLEVEL when it was passed T for
1262 ;;; LOAD-TIME-VALUE-P (which happens in COMPILE-LOAD-TIME-STUFF). We
1263 ;;; don't try to combine this component with anything else and frob
1264 ;;; the name. If not in a :TOPLEVEL component, then don't bother
1265 ;;; compiling, because it was merged with a run-time component.
1266 (defun compile-load-time-value-lambda (lambdas)
1267   (aver (null (cdr lambdas)))
1268   (let* ((lambda (car lambdas))
1269          (component (lambda-component lambda)))
1270     (when (eql (component-kind component) :toplevel)
1271       (setf (component-name component) (leaf-debug-name lambda))
1272       (compile-component component)
1273       (clear-ir1-info component))))
1274 \f
1275 ;;;; COMPILE-FILE
1276
1277 (defun object-call-toplevel-lambda (tll)
1278   (declare (type functional tll))
1279   (let ((object *compile-object*))
1280     (etypecase object
1281       (fasl-output (fasl-dump-toplevel-lambda-call tll object))
1282       (core-object (core-call-toplevel-lambda      tll object))
1283       (null))))
1284
1285 ;;; Smash LAMBDAS into a single component, compile it, and arrange for
1286 ;;; the resulting function to be called.
1287 (defun sub-compile-toplevel-lambdas (lambdas)
1288   (declare (list lambdas))
1289   (when lambdas
1290     (multiple-value-bind (component tll) (merge-toplevel-lambdas lambdas)
1291       (compile-component component)
1292       (clear-ir1-info component)
1293       (object-call-toplevel-lambda tll)))
1294   (values))
1295
1296 ;;; Compile top level code and call the top level lambdas. We pick off
1297 ;;; top level lambdas in non-top-level components here, calling
1298 ;;; SUB-c-t-l-l on each subsequence of normal top level lambdas.
1299 (defun compile-toplevel-lambdas (lambdas)
1300   (declare (list lambdas))
1301   (let ((len (length lambdas)))
1302     (flet ((loser (start)
1303              (or (position-if (lambda (x)
1304                                 (not (eq (component-kind
1305                                           (node-component (lambda-bind x)))
1306                                          :toplevel)))
1307                               lambdas
1308                               ;; this used to read ":start start", but
1309                               ;; start can be greater than len, which
1310                               ;; is an error according to ANSI - CSR,
1311                               ;; 2002-04-25
1312                               :start (min start len))
1313                  len)))
1314       (do* ((start 0 (1+ loser))
1315             (loser (loser start) (loser start)))
1316            ((>= start len))
1317         (sub-compile-toplevel-lambdas (subseq lambdas start loser))
1318         (unless (= loser len)
1319           (object-call-toplevel-lambda (elt lambdas loser))))))
1320   (values))
1321
1322 ;;; Compile LAMBDAS (a list of CLAMBDAs for top level forms) into the
1323 ;;; object file.
1324 ;;;
1325 ;;; LOAD-TIME-VALUE-P seems to control whether it's MAKE-LOAD-FORM and
1326 ;;; COMPILE-LOAD-TIME-VALUE stuff. -- WHN 20000201
1327 (defun compile-toplevel (lambdas load-time-value-p)
1328   (declare (list lambdas))
1329
1330   (maybe-mumble "locall ")
1331   (locall-analyze-clambdas-until-done lambdas)
1332
1333   (maybe-mumble "IDFO ")
1334   (multiple-value-bind (components top-components hairy-top)
1335       (find-initial-dfo lambdas)
1336     (let ((*all-components* (append components top-components)))
1337       (when *check-consistency*
1338         (maybe-mumble "[check]~%")
1339         (check-ir1-consistency *all-components*))
1340
1341       (dolist (component (append hairy-top top-components))
1342         (pre-physenv-analyze-toplevel component))
1343
1344       (dolist (component components)
1345         (compile-component component)
1346         (replace-toplevel-xeps component))
1347
1348       (when *check-consistency*
1349         (maybe-mumble "[check]~%")
1350         (check-ir1-consistency *all-components*))
1351
1352       (if load-time-value-p
1353           (compile-load-time-value-lambda lambdas)
1354           (compile-toplevel-lambdas lambdas))
1355
1356       (mapc #'clear-ir1-info components)
1357       (clear-stuff)))
1358   (values))
1359
1360 ;;; Actually compile any stuff that has been queued up for block
1361 ;;; compilation.
1362 (defun finish-block-compilation ()
1363   (when *block-compile*
1364     (when *toplevel-lambdas*
1365       (compile-toplevel (nreverse *toplevel-lambdas*) nil)
1366       (setq *toplevel-lambdas* ()))
1367     (setq *block-compile* nil)
1368     (setq *entry-points* nil)))
1369
1370 (defun handle-condition-p (condition)
1371   (let ((lexenv
1372          (etypecase *compiler-error-context*
1373            (node
1374             (node-lexenv *compiler-error-context*))
1375            (compiler-error-context
1376             (let ((lexenv (compiler-error-context-lexenv
1377                            *compiler-error-context*)))
1378               (aver lexenv)
1379               lexenv))
1380            (null *lexenv*))))
1381     (let ((muffles (lexenv-handled-conditions lexenv)))
1382       (if (null muffles) ; common case
1383           nil
1384           (dolist (muffle muffles nil)
1385             (destructuring-bind (typespec . restart-name) muffle
1386               (when (and (typep condition typespec)
1387                          (find-restart restart-name condition))
1388                 (return t))))))))
1389
1390 (defun handle-condition-handler (condition)
1391   (let ((lexenv
1392          (etypecase *compiler-error-context*
1393            (node
1394             (node-lexenv *compiler-error-context*))
1395            (compiler-error-context
1396             (let ((lexenv (compiler-error-context-lexenv
1397                            *compiler-error-context*)))
1398               (aver lexenv)
1399               lexenv))
1400            (null *lexenv*))))
1401     (let ((muffles (lexenv-handled-conditions lexenv)))
1402       (aver muffles)
1403       (dolist (muffle muffles (bug "fell through"))
1404         (destructuring-bind (typespec . restart-name) muffle
1405           (when (typep condition typespec)
1406             (awhen (find-restart restart-name condition)
1407               (invoke-restart it))))))))
1408
1409 ;;; Read all forms from INFO and compile them, with output to OBJECT.
1410 ;;; Return (VALUES NIL WARNINGS-P FAILURE-P).
1411 (defun sub-compile-file (info)
1412   (declare (type source-info info))
1413   (let ((*package* (sane-package))
1414         (*readtable* *readtable*)
1415         (sb!xc:*compile-file-pathname* nil) ; really bound in
1416         (sb!xc:*compile-file-truename* nil) ; SUB-SUB-COMPILE-FILE
1417
1418         (*policy* *policy*)
1419         (*handled-conditions* *handled-conditions*)
1420         (*disabled-package-locks* *disabled-package-locks*)
1421         (*lexenv* (make-null-lexenv))
1422         (*block-compile* *block-compile-arg*)
1423         (*source-info* info)
1424         (*toplevel-lambdas* ())
1425         (*fun-names-in-this-file* ())
1426         (*allow-instrumenting* nil)
1427         (*compiler-error-bailout*
1428          (lambda ()
1429            (compiler-mumble "~2&; fatal error, aborting compilation~%")
1430            (return-from sub-compile-file (values nil t t))))
1431         (*current-path* nil)
1432         (*last-source-context* nil)
1433         (*last-original-source* nil)
1434         (*last-source-form* nil)
1435         (*last-format-string* nil)
1436         (*last-format-args* nil)
1437         (*last-message-count* 0)
1438         ;; FIXME: Do we need this rebinding here? It's a literal
1439         ;; translation of the old CMU CL rebinding to
1440         ;; (OR *BACKEND-INFO-ENVIRONMENT* *INFO-ENVIRONMENT*),
1441         ;; and it's not obvious whether the rebinding to itself is
1442         ;; needed that SBCL doesn't need *BACKEND-INFO-ENVIRONMENT*.
1443         (*info-environment* *info-environment*)
1444         (*gensym-counter* 0))
1445     (handler-case
1446         (handler-bind (((satisfies handle-condition-p) #'handle-condition-handler))
1447           (with-compilation-values
1448               (sb!xc:with-compilation-unit ()
1449                 (clear-stuff)
1450
1451                 (sub-sub-compile-file info)
1452
1453                 (finish-block-compilation)
1454                 (let ((object *compile-object*))
1455                   (etypecase object
1456                     (fasl-output (fasl-dump-source-info info object))
1457                     (core-object (fix-core-source-info info object))
1458                     (null)))
1459                 nil)))
1460       ;; Some errors are sufficiently bewildering that we just fail
1461       ;; immediately, without trying to recover and compile more of
1462       ;; the input file.
1463       (fatal-compiler-error (condition)
1464        (signal condition)
1465        (format *error-output*
1466                "~@<compilation aborted because of fatal error: ~2I~_~A~:>"
1467                condition)
1468        (values nil t t)))))
1469
1470 ;;; Return a pathname for the named file. The file must exist.
1471 (defun verify-source-file (pathname-designator)
1472   (let* ((pathname (pathname pathname-designator))
1473          (default-host (make-pathname :host (pathname-host pathname))))
1474     (flet ((try-with-type (path type error-p)
1475              (let ((new (merge-pathnames
1476                          path (make-pathname :type type
1477                                              :defaults default-host))))
1478                (if (probe-file new)
1479                    new
1480                    (and error-p (truename new))))))
1481       (cond ((typep pathname 'logical-pathname)
1482              (try-with-type pathname "LISP" t))
1483             ((probe-file pathname) pathname)
1484             ((try-with-type pathname "lisp"  nil))
1485             ((try-with-type pathname "lisp"  t))))))
1486
1487 (defun elapsed-time-to-string (tsec)
1488   (multiple-value-bind (tmin sec) (truncate tsec 60)
1489     (multiple-value-bind (thr min) (truncate tmin 60)
1490       (format nil "~D:~2,'0D:~2,'0D" thr min sec))))
1491
1492 ;;; Print some junk at the beginning and end of compilation.
1493 (defun start-error-output (source-info)
1494   (declare (type source-info source-info))
1495   (let ((file-info (source-info-file-info source-info)))
1496     (compiler-mumble "~&; compiling file ~S (written ~A):~%"
1497                      (namestring (file-info-name file-info))
1498                      (sb!int:format-universal-time nil
1499                                                    (file-info-write-date
1500                                                     file-info)
1501                                                    :style :government
1502                                                    :print-weekday nil
1503                                                    :print-timezone nil)))
1504   (values))
1505 (defun finish-error-output (source-info won)
1506   (declare (type source-info source-info))
1507   (compiler-mumble "~&; compilation ~:[aborted after~;finished in~] ~A~&"
1508                    won
1509                    (elapsed-time-to-string
1510                     (- (get-universal-time)
1511                        (source-info-start-time source-info))))
1512   (values))
1513
1514 ;;; Open some files and call SUB-COMPILE-FILE. If something unwinds
1515 ;;; out of the compile, then abort the writing of the output file, so
1516 ;;; that we don't overwrite it with known garbage.
1517 (defun sb!xc:compile-file
1518     (input-file
1519      &key
1520
1521      ;; ANSI options
1522      (output-file (cfp-output-file-default input-file))
1523      ;; FIXME: ANSI doesn't seem to say anything about
1524      ;; *COMPILE-VERBOSE* and *COMPILE-PRINT* being rebound by this
1525      ;; function..
1526      ((:verbose sb!xc:*compile-verbose*) sb!xc:*compile-verbose*)
1527      ((:print sb!xc:*compile-print*) sb!xc:*compile-print*)
1528      (external-format :default)
1529
1530      ;; extensions
1531      (trace-file nil)
1532      ((:block-compile *block-compile-arg*) nil))
1533
1534   #!+sb-doc
1535   "Compile INPUT-FILE, producing a corresponding fasl file and returning
1536    its filename. Besides the ANSI &KEY arguments :OUTPUT-FILE, :VERBOSE,
1537    :PRINT, and :EXTERNAL-FORMAT,the following extensions are supported:
1538      :TRACE-FILE
1539         If given, internal data structures are dumped to the specified
1540         file, or if a value of T is given, to a file of *.trace type
1541         derived from the input file name.
1542    Also, as a workaround for vaguely-non-ANSI behavior, the :BLOCK-COMPILE
1543    argument is quasi-supported, to determine whether multiple
1544    functions are compiled together as a unit, resolving function
1545    references at compile time. NIL means that global function names
1546    are never resolved at compilation time. Currently NIL is the
1547    default behavior, because although section 3.2.2.3, \"Semantic
1548    Constraints\", of the ANSI spec allows this behavior under all
1549    circumstances, the compiler's runtime scales badly when it
1550    tries to do this for large files. If/when this performance
1551    problem is fixed, the block compilation default behavior will
1552    probably be made dependent on the SPEED and COMPILATION-SPEED
1553    optimization values, and the :BLOCK-COMPILE argument will probably
1554    become deprecated."
1555
1556   (unless (eq external-format :default)
1557     (error "Non-:DEFAULT EXTERNAL-FORMAT values are not supported."))
1558   (let* ((fasl-output nil)
1559          (output-file-name nil)
1560          (compile-won nil)
1561          (warnings-p nil)
1562          (failure-p t) ; T in case error keeps this from being set later
1563          (input-pathname (verify-source-file input-file))
1564          (source-info (make-file-source-info input-pathname))
1565          (*compiler-trace-output* nil)) ; might be modified below
1566
1567     (unwind-protect
1568         (progn
1569           (when output-file
1570             (setq output-file-name
1571                   (sb!xc:compile-file-pathname input-file
1572                                                :output-file output-file))
1573             (setq fasl-output
1574                   (open-fasl-output output-file-name
1575                                     (namestring input-pathname))))
1576           (when trace-file
1577             (let* ((default-trace-file-pathname
1578                      (make-pathname :type "trace" :defaults input-pathname))
1579                    (trace-file-pathname
1580                     (if (eql trace-file t)
1581                         default-trace-file-pathname
1582                         (merge-pathnames trace-file
1583                                          default-trace-file-pathname))))
1584               (setf *compiler-trace-output*
1585                     (open trace-file-pathname
1586                           :if-exists :supersede
1587                           :direction :output))))
1588
1589           (when sb!xc:*compile-verbose*
1590             (start-error-output source-info))
1591           (let ((*compile-object* fasl-output)
1592                 dummy)
1593             (multiple-value-setq (dummy warnings-p failure-p)
1594               (sub-compile-file source-info)))
1595           (setq compile-won t))
1596
1597       (close-source-info source-info)
1598
1599       (when fasl-output
1600         (close-fasl-output fasl-output (not compile-won))
1601         (setq output-file-name
1602               (pathname (fasl-output-stream fasl-output)))
1603         (when (and compile-won sb!xc:*compile-verbose*)
1604           (compiler-mumble "~2&; ~A written~%" (namestring output-file-name))))
1605
1606       (when sb!xc:*compile-verbose*
1607         (finish-error-output source-info compile-won))
1608
1609       (when *compiler-trace-output*
1610         (close *compiler-trace-output*)))
1611
1612     (values (if output-file
1613                 ;; Hack around filesystem race condition...
1614                 (or (probe-file output-file-name) output-file-name)
1615                 nil)
1616             warnings-p
1617             failure-p)))
1618 \f
1619 ;;; a helper function for COMPILE-FILE-PATHNAME: the default for
1620 ;;; the OUTPUT-FILE argument
1621 ;;;
1622 ;;; ANSI: The defaults for the OUTPUT-FILE are taken from the pathname
1623 ;;; that results from merging the INPUT-FILE with the value of
1624 ;;; *DEFAULT-PATHNAME-DEFAULTS*, except that the type component should
1625 ;;; default to the appropriate implementation-defined default type for
1626 ;;; compiled files.
1627 (defun cfp-output-file-default (input-file)
1628   (let* ((defaults (merge-pathnames input-file *default-pathname-defaults*))
1629          (retyped (make-pathname :type *fasl-file-type* :defaults defaults)))
1630     retyped))
1631
1632 ;;; KLUDGE: Part of the ANSI spec for this seems contradictory:
1633 ;;;   If INPUT-FILE is a logical pathname and OUTPUT-FILE is unsupplied,
1634 ;;;   the result is a logical pathname. If INPUT-FILE is a logical
1635 ;;;   pathname, it is translated into a physical pathname as if by
1636 ;;;   calling TRANSLATE-LOGICAL-PATHNAME.
1637 ;;; So I haven't really tried to make this precisely ANSI-compatible
1638 ;;; at the level of e.g. whether it returns logical pathname or a
1639 ;;; physical pathname. Patches to make it more correct are welcome.
1640 ;;; -- WHN 2000-12-09
1641 (defun sb!xc:compile-file-pathname (input-file
1642                                     &key
1643                                     (output-file (cfp-output-file-default
1644                                                   input-file))
1645                                     &allow-other-keys)
1646   #!+sb-doc
1647   "Return a pathname describing what file COMPILE-FILE would write to given
1648    these arguments."
1649   (merge-pathnames output-file (merge-pathnames input-file)))
1650 \f
1651 ;;;; MAKE-LOAD-FORM stuff
1652
1653 ;;; The entry point for MAKE-LOAD-FORM support. When IR1 conversion
1654 ;;; finds a constant structure, it invokes this to arrange for proper
1655 ;;; dumping. If it turns out that the constant has already been
1656 ;;; dumped, then we don't need to do anything.
1657 ;;;
1658 ;;; If the constant hasn't been dumped, then we check to see whether
1659 ;;; we are in the process of creating it. We detect this by
1660 ;;; maintaining the special *CONSTANTS-BEING-CREATED* as a list of all
1661 ;;; the constants we are in the process of creating. Actually, each
1662 ;;; entry is a list of the constant and any init forms that need to be
1663 ;;; processed on behalf of that constant.
1664 ;;;
1665 ;;; It's not necessarily an error for this to happen. If we are
1666 ;;; processing the init form for some object that showed up *after*
1667 ;;; the original reference to this constant, then we just need to
1668 ;;; defer the processing of that init form. To detect this, we
1669 ;;; maintain *CONSTANTS-CREATED-SINCE-LAST-INIT* as a list of the
1670 ;;; constants created since the last time we started processing an
1671 ;;; init form. If the constant passed to emit-make-load-form shows up
1672 ;;; in this list, then there is a circular chain through creation
1673 ;;; forms, which is an error.
1674 ;;;
1675 ;;; If there is some intervening init form, then we blow out of
1676 ;;; processing it by throwing to the tag PENDING-INIT. The value we
1677 ;;; throw is the entry from *CONSTANTS-BEING-CREATED*. This is so the
1678 ;;; offending init form can be tacked onto the init forms for the
1679 ;;; circular object.
1680 ;;;
1681 ;;; If the constant doesn't show up in *CONSTANTS-BEING-CREATED*, then
1682 ;;; we have to create it. We call MAKE-LOAD-FORM and check to see
1683 ;;; whether the creation form is the magic value
1684 ;;; :SB-JUST-DUMP-IT-NORMALLY. If it is, then we don't do anything. The
1685 ;;; dumper will eventually get its hands on the object and use the
1686 ;;; normal structure dumping noise on it.
1687 ;;;
1688 ;;; Otherwise, we bind *CONSTANTS-BEING-CREATED* and
1689 ;;; *CONSTANTS-CREATED-SINCE- LAST-INIT* and compile the creation form
1690 ;;; much the way LOAD-TIME-VALUE does. When this finishes, we tell the
1691 ;;; dumper to use that result instead whenever it sees this constant.
1692 ;;;
1693 ;;; Now we try to compile the init form. We bind
1694 ;;; *CONSTANTS-CREATED-SINCE-LAST-INIT* to NIL and compile the init
1695 ;;; form (and any init forms that were added because of circularity
1696 ;;; detection). If this works, great. If not, we add the init forms to
1697 ;;; the init forms for the object that caused the problems and let it
1698 ;;; deal with it.
1699 (defvar *constants-being-created* nil)
1700 (defvar *constants-created-since-last-init* nil)
1701 ;;; FIXME: Shouldn't these^ variables be unbound outside LET forms?
1702 (defun emit-make-load-form (constant)
1703   (aver (fasl-output-p *compile-object*))
1704   (unless (or (fasl-constant-already-dumped-p constant *compile-object*)
1705               ;; KLUDGE: This special hack is because I was too lazy
1706               ;; to rework DEF!STRUCT so that the MAKE-LOAD-FORM
1707               ;; function of LAYOUT returns nontrivial forms when
1708               ;; building the cross-compiler but :IGNORE-IT when
1709               ;; cross-compiling or running under the target Lisp. --
1710               ;; WHN 19990914
1711               #+sb-xc-host (typep constant 'layout))
1712     (let ((circular-ref (assoc constant *constants-being-created* :test #'eq)))
1713       (when circular-ref
1714         (when (find constant *constants-created-since-last-init* :test #'eq)
1715           (throw constant t))
1716         (throw 'pending-init circular-ref)))
1717     (multiple-value-bind (creation-form init-form)
1718         (handler-case
1719             (sb!xc:make-load-form constant (make-null-lexenv))
1720           (error (condition)
1721             (compiler-error condition)))
1722       (case creation-form
1723         (:sb-just-dump-it-normally
1724          (fasl-validate-structure constant *compile-object*)
1725          t)
1726         (:ignore-it
1727          nil)
1728         (t
1729          (when (fasl-constant-already-dumped-p constant *compile-object*)
1730            (return-from emit-make-load-form nil))
1731          (let* ((name (let ((*print-level* 1) (*print-length* 2))
1732                         (with-output-to-string (stream)
1733                           (write constant :stream stream))))
1734                 (info (if init-form
1735                           (list constant name init-form)
1736                           (list constant))))
1737            (let ((*constants-being-created*
1738                   (cons info *constants-being-created*))
1739                  (*constants-created-since-last-init*
1740                   (cons constant *constants-created-since-last-init*)))
1741              (when
1742                  (catch constant
1743                    (fasl-note-handle-for-constant
1744                     constant
1745                     (compile-load-time-value
1746                      creation-form)
1747                     *compile-object*)
1748                    nil)
1749                (compiler-error "circular references in creation form for ~S"
1750                                constant)))
1751            (when (cdr info)
1752              (let* ((*constants-created-since-last-init* nil)
1753                     (circular-ref
1754                      (catch 'pending-init
1755                        (loop for (name form) on (cdr info) by #'cddr
1756                          collect name into names
1757                          collect form into forms
1758                          finally (compile-make-load-form-init-forms forms))
1759                        nil)))
1760                (when circular-ref
1761                  (setf (cdr circular-ref)
1762                        (append (cdr circular-ref) (cdr info))))))))))))
1763
1764 \f
1765 ;;;; Host compile time definitions
1766 #+sb-xc-host
1767 (defun compile-in-lexenv (name lambda lexenv)
1768   (declare (ignore lexenv))
1769   (compile name lambda))
1770
1771 #+sb-xc-host
1772 (defun eval-in-lexenv (form lexenv)
1773   (declare (ignore lexenv))
1774   (eval form))