src/compiler/main.lisp

   1 ;;;; the top-level interfaces to the compiler
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13
  14 ;;; FIXME: Doesn't this belong somewhere else, like early-c.lisp?
  15 (declaim (special *constants* *free-variables* *component-being-compiled*
  16                   *code-vector* *next-location* *result-fixups*
  17                   *free-functions* *source-paths*
  18                   *seen-blocks* *seen-functions* *list-conflicts-table*
  19                   *continuation-number* *continuation-numbers*
  20                   *number-continuations* *tn-id* *tn-ids* *id-tns*
  21                   *label-ids* *label-id* *id-labels*
  22                   *undefined-warnings* *compiler-error-count*
  23                   *compiler-warning-count* *compiler-style-warning-count*
  24                   *compiler-note-count*
  25                   *compiler-error-bailout*
  26                   #!+sb-show *compiler-trace-output*
  27                   *last-source-context* *last-original-source*
  28                   *last-source-form* *last-format-string* *last-format-args*
  29                   *last-message-count* *lexenv*))
  30
  31 (defvar *byte-compile-default* :maybe
  32   #!+sb-doc
  33   "the default value for the :BYTE-COMPILE argument to COMPILE-FILE")
  34
  35 (defvar *byte-compile-top-level*
  36   #-sb-xc-host t
  37   #+sb-xc-host nil ; since the byte compiler isn't supported in cross-compiler
  38   #!+sb-doc
  39   "Similar to *BYTE-COMPILE-DEFAULT*, but controls the compilation of top-level
  40    forms (evaluated at load-time) when the :BYTE-COMPILE argument is :MAYBE
  41    (the default.)  When true, we decide to byte-compile.")
  42
  43 ;;; default value of the :BYTE-COMPILE argument to the compiler
  44 (defvar *byte-compile* :maybe)
  45
  46 ;;; Bound by COMPILE-COMPONENT to T when byte-compiling, and NIL when
  47 ;;; native compiling. During IR1 conversion this can also be :MAYBE,
  48 ;;; in which case we must look at the policy, see (byte-compiling).
  49 (defvar *byte-compiling* :maybe)
  50 (declaim (type (member t nil :maybe) *byte-compile* *byte-compiling*
  51                *byte-compile-default*))
  52
  53 (defvar *check-consistency* nil)
  54 (defvar *all-components*)
  55
  56 ;;; Bind this to a stream to capture various internal debugging output.
  57 #!+sb-show
  58 (defvar *compiler-trace-output* nil)
  59
  60 ;;; The current block compilation state. These are initialized to the
  61 ;;; :BLOCK-COMPILE and :ENTRY-POINTS arguments that COMPILE-FILE was
  62 ;;; called with.
  63 ;;;
  64 ;;; *BLOCK-COMPILE-ARGUMENT* holds the original value of the
  65 ;;; :BLOCK-COMPILE argument, which overrides any internal
  66 ;;; declarations.
  67 (defvar *block-compile*)
  68 (defvar *block-compile-argument*)
  69 (declaim (type (member nil t :specified)
  70                *block-compile* *block-compile-argument*))
  71 (defvar *entry-points*)
  72 (declaim (list *entry-points*))
  73
  74 ;;; When block compiling, used by PROCESS-FORM to accumulate top-level
  75 ;;; lambdas resulting from compiling subforms. (In reverse order.)
  76 (defvar *top-level-lambdas*)
  77 (declaim (list *top-level-lambdas*))
  78
  79 (defvar sb!xc:*compile-verbose* t
  80   #!+sb-doc
  81   "The default for the :VERBOSE argument to COMPILE-FILE.")
  82 (defvar sb!xc:*compile-print* t
  83   #!+sb-doc
  84   "The default for the :PRINT argument to COMPILE-FILE.")
  85 (defvar *compile-progress* nil
  86   #!+sb-doc
  87   "When this is true, the compiler prints to *ERROR-OUTPUT* progress
  88   information about the phases of compilation of each function. (This
  89   is useful mainly in large block compilations.)")
  90
  91 (defvar sb!xc:*compile-file-pathname* nil
  92   #!+sb-doc
  93   "The defaulted pathname of the file currently being compiled, or NIL if not
  94   compiling.")
  95 (defvar sb!xc:*compile-file-truename* nil
  96   #!+sb-doc
  97   "The TRUENAME of the file currently being compiled, or NIL if not
  98   compiling.")
  99
 100 (declaim (type (or pathname null)
 101                sb!xc:*compile-file-pathname*
 102                sb!xc:*compile-file-truename*))
 103
 104 ;;; the values of *PACKAGE* and policy when compilation started
 105 (defvar *initial-package*)
 106 (defvar *initial-policy*)
 107 (defvar *initial-interface-policy*)
 108
 109 ;;; The source-info structure for the current compilation. This is null
 110 ;;; globally to indicate that we aren't currently in any identifiable
 111 ;;; compilation.
 112 (defvar *source-info* nil)
 113
 114 ;;; True if we are within a WITH-COMPILATION-UNIT form (which normally
 115 ;;; causes nested uses to be no-ops).
 116 (defvar *in-compilation-unit* nil)
 117
 118 ;;; Count of the number of compilation units dynamically enclosed by
 119 ;;; the current active WITH-COMPILATION-UNIT that were unwound out of.
 120 (defvar *aborted-compilation-unit-count*)
 121
 122 ;;; Mumble conditional on *COMPILE-PROGRESS*.
 123 (defun maybe-mumble (&rest foo)
 124   (when *compile-progress*
 125     (compiler-mumble "~&")
 126     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 127        (apply #'compiler-mumble foo))))
 128
 129 (deftype object () '(or fasl-file core-object null))
 130
 131 (defvar *compile-object* nil)
 132 (declaim (type object *compile-object*))
 133 \f
 134 ;;;; WITH-COMPILATION-UNIT and WITH-COMPILATION-VALUES
 135
 136 (defmacro sb!xc:with-compilation-unit (options &body body)
 137   #!+sb-doc
 138   "WITH-COMPILATION-UNIT ({Key Value}*) Form*
 139   This form affects compilations that take place within its dynamic extent. It
 140   is intended to be wrapped around the compilation of all files in the same
 141   system. These keywords are defined:
 142     :OVERRIDE Boolean-Form
 143         One of the effects of this form is to delay undefined warnings
 144         until the end of the form, instead of giving them at the end of each
 145         compilation. If OVERRIDE is NIL (the default), then the outermost
 146         WITH-COMPILATION-UNIT form grabs the undefined warnings. Specifying
 147         OVERRIDE true causes that form to grab any enclosed warnings, even if
 148         it is enclosed by another WITH-COMPILATION-UNIT."
 149   `(%with-compilation-unit (lambda () ,@body) ,@options))
 150
 151 (defun %with-compilation-unit (fn &key override)
 152   (let ((succeeded-p nil))
 153     (if (and *in-compilation-unit* (not override))
 154         ;; Inside another WITH-COMPILATION-UNIT, a WITH-COMPILATION-UNIT is
 155         ;; ordinarily (unless OVERRIDE) basically a no-op.
 156         (unwind-protect
 157             (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 158           (unless succeeded-p
 159             (incf *aborted-compilation-unit-count*)))
 160         ;; FIXME: Now *COMPILER-FOO-COUNT* stuff is bound in more than
 161         ;; one place. If we can get rid of the IR1 interpreter, this
 162         ;; should be easier to clean up.
 163         (let ((*aborted-compilation-unit-count* 0)
 164               (*compiler-error-count* 0)
 165               (*compiler-warning-count* 0)
 166               (*compiler-style-warning-count* 0)
 167               (*compiler-note-count* 0)
 168               (*undefined-warnings* nil)
 169               (*in-compilation-unit* t))
 170           (handler-bind ((parse-unknown-type
 171                           (lambda (c)
 172                             (note-undefined-reference
 173                              (parse-unknown-type-specifier c)
 174                              :type))))
 175             (unwind-protect
 176                 (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 177               (unless succeeded-p
 178                 (incf *aborted-compilation-unit-count*))
 179               (summarize-compilation-unit (not succeeded-p))))))))
 180
 181 ;;; This is to be called at the end of a compilation unit. It signals
 182 ;;; any residual warnings about unknown stuff, then prints the total
 183 ;;; error counts. ABORT-P should be true when the compilation unit was
 184 ;;; aborted by throwing out. ABORT-COUNT is the number of dynamically
 185 ;;; enclosed nested compilation units that were aborted.
 186 (defun summarize-compilation-unit (abort-p)
 187   (unless abort-p
 188     (handler-bind ((style-warning #'compiler-style-warning-handler)
 189                    (warning #'compiler-warning-handler))
 190
 191       (let ((undefs (sort *undefined-warnings* #'string<
 192                           :key #'(lambda (x)
 193                                    (let ((x (undefined-warning-name x)))
 194                                      (if (symbolp x)
 195                                          (symbol-name x)
 196                                          (prin1-to-string x)))))))
 197         (unless *converting-for-interpreter*
 198           (dolist (undef undefs)
 199             (let ((name (undefined-warning-name undef))
 200                   (kind (undefined-warning-kind undef))
 201                   (warnings (undefined-warning-warnings undef))
 202                   (undefined-warning-count (undefined-warning-count undef)))
 203               (dolist (*compiler-error-context* warnings)
 204                 (compiler-style-warning "undefined ~(~A~): ~S" kind name))
 205
 206               (let ((warn-count (length warnings)))
 207                 (when (and warnings (> undefined-warning-count warn-count))
 208                   (let ((more (- undefined-warning-count warn-count)))
 209                     (compiler-style-warning
 210                      "~D more use~:P of undefined ~(~A~) ~S"
 211                      more kind name)))))))
 212
 213         (dolist (kind '(:variable :function :type))
 214           (let ((summary (mapcar #'undefined-warning-name
 215                                  (remove kind undefs :test-not #'eq
 216                                          :key #'undefined-warning-kind))))
 217             (when summary
 218               (compiler-style-warning
 219                "~:[This ~(~A~) is~;These ~(~A~)s are~] undefined:~
 220                 ~%  ~{~<~%  ~1:;~S~>~^ ~}"
 221                (cdr summary) kind summary)))))))
 222
 223   (unless (or *converting-for-interpreter*
 224               (and (not abort-p)
 225                    (zerop *aborted-compilation-unit-count*)
 226                    (zerop *compiler-error-count*)
 227                    (zerop *compiler-warning-count*)
 228                    (zerop *compiler-style-warning-count*)
 229                    (zerop *compiler-note-count*)))
 230     (format *error-output* "~&")
 231     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 232       (compiler-mumble "compilation unit ~:[finished~;aborted~]~
 233                        ~[~:;~:*~&  caught ~D fatal ERROR condition~:P~]~
 234                        ~[~:;~:*~&  caught ~D ERROR condition~:P~]~
 235                        ~[~:;~:*~&  caught ~D WARNING condition~:P~]~
 236                        ~[~:;~:*~&  caught ~D STYLE-WARNING condition~:P~]~
 237                        ~[~:;~:*~&  printed ~D note~:P~]"
 238                        abort-p
 239                        *aborted-compilation-unit-count*
 240                        *compiler-error-count*
 241                        *compiler-warning-count*
 242                        *compiler-style-warning-count*
 243                        *compiler-note-count*)))
 244   (format *error-output* "~&"))
 245
 246 ;;; Evaluate BODY, then return (VALUES BODY-VALUE WARNINGS-P
 247 ;;; FAILURE-P), where BODY-VALUE is the first value of the body, and
 248 ;;; WARNINGS-P and FAILURE-P are as in CL:COMPILE or CL:COMPILE-FILE.
 249 ;;; This also wraps up WITH-IR1-NAMESPACE functionality.
 250 (defmacro with-compilation-values (&body body)
 251   `(with-ir1-namespace
 252     (let ((*warnings-p* nil)
 253           (*failure-p* nil))
 254       (values (progn ,@body)
 255               *warnings-p*
 256               *failure-p*))))
 257 \f
 258 ;;;; component compilation
 259
 260 (defparameter *max-optimize-iterations* 3 ; ARB
 261   #!+sb-doc
 262   "The upper limit on the number of times that we will consecutively do IR1
 263   optimization that doesn't introduce any new code. A finite limit is
 264   necessary, since type inference may take arbitrarily long to converge.")
 265
 266 (defevent ir1-optimize-until-done "IR1-OPTIMIZE-UNTIL-DONE called")
 267 (defevent ir1-optimize-maxed-out "hit *MAX-OPTIMIZE-ITERATIONS* limit")
 268
 269 ;;; Repeatedly optimize COMPONENT until no further optimizations can
 270 ;;; be found or we hit our iteration limit. When we hit the limit, we
 271 ;;; clear the component and block REOPTIMIZE flags to discourage the
 272 ;;; next optimization attempt from pounding on the same code.
 273 (defun ir1-optimize-until-done (component)
 274   (declare (type component component))
 275   (maybe-mumble "opt")
 276   (event ir1-optimize-until-done)
 277   (let ((count 0)
 278         (cleared-reanalyze nil))
 279     (loop
 280       (when (component-reanalyze component)
 281         (setq count 0)
 282         (setq cleared-reanalyze t)
 283         (setf (component-reanalyze component) nil))
 284       (setf (component-reoptimize component) nil)
 285       (ir1-optimize component)
 286       (unless (component-reoptimize component)
 287         (maybe-mumble " ")
 288         (return))
 289       (incf count)
 290       (when (= count *max-optimize-iterations*)
 291         (event ir1-optimize-maxed-out)
 292         (maybe-mumble "* ")
 293         (setf (component-reoptimize component) nil)
 294         (do-blocks (block component)
 295           (setf (block-reoptimize block) nil))
 296         (return))
 297       (maybe-mumble "."))
 298     (when cleared-reanalyze
 299       (setf (component-reanalyze component) t)))
 300   (values))
 301
 302 (defparameter *constraint-propagate* t)
 303 (defparameter *reoptimize-after-type-check-max* 5)
 304
 305 (defevent reoptimize-maxed-out
 306   "*REOPTIMIZE-AFTER-TYPE-CHECK-MAX* exceeded.")
 307
 308 ;;; Iterate doing FIND-DFO until no new dead code is discovered.
 309 (defun dfo-as-needed (component)
 310   (declare (type component component))
 311   (when (component-reanalyze component)
 312     (maybe-mumble "DFO")
 313     (loop
 314       (find-dfo component)
 315       (unless (component-reanalyze component)
 316         (maybe-mumble " ")
 317         (return))
 318       (maybe-mumble ".")))
 319   (values))
 320
 321 ;;; Do all the IR1 phases for a non-top-level component.
 322 (defun ir1-phases (component)
 323   (declare (type component component))
 324   (let ((*constraint-number* 0)
 325         (loop-count 1))
 326     (declare (special *constraint-number*))
 327     (loop
 328       (ir1-optimize-until-done component)
 329       (when (or (component-new-functions component)
 330                 (component-reanalyze-functions component))
 331         (maybe-mumble "locall ")
 332         (local-call-analyze component))
 333       (dfo-as-needed component)
 334       (when *constraint-propagate*
 335         (maybe-mumble "constraint ")
 336         (constraint-propagate component))
 337       (maybe-mumble "type ")
 338       ;; Delay the generation of type checks until the type
 339       ;; constraints have had time to propagate, else the compiler can
 340       ;; confuse itself.
 341       (unless (and (or (component-reoptimize component)
 342                        (component-reanalyze component)
 343                        (component-new-functions component)
 344                        (component-reanalyze-functions component))
 345                    (< loop-count (- *reoptimize-after-type-check-max* 2)))
 346         (generate-type-checks component)
 347         (unless (or (component-reoptimize component)
 348                     (component-reanalyze component)
 349                     (component-new-functions component)
 350                     (component-reanalyze-functions component))
 351           (return)))
 352       (when (>= loop-count *reoptimize-after-type-check-max*)
 353         (maybe-mumble "[reoptimize limit]")
 354         (event reoptimize-maxed-out)
 355         (return))
 356       (incf loop-count)))
 357
 358   (ir1-finalize component)
 359   (values))
 360
 361 (defun native-compile-component (component)
 362   (let ((*code-segment* nil)
 363         (*elsewhere* nil))
 364     (maybe-mumble "GTN ")
 365     (gtn-analyze component)
 366     (maybe-mumble "LTN ")
 367     (ltn-analyze component)
 368     (dfo-as-needed component)
 369     (maybe-mumble "control ")
 370     (control-analyze component #'make-ir2-block)
 371
 372     (when (ir2-component-values-receivers (component-info component))
 373       (maybe-mumble "stack ")
 374       (stack-analyze component)
 375       ;; Assign BLOCK-NUMBER for any cleanup blocks introduced by
 376       ;; stack analysis. There shouldn't be any unreachable code after
 377       ;; control, so this won't delete anything.
 378       (dfo-as-needed component))
 379
 380     (unwind-protect
 381         (progn
 382           (maybe-mumble "IR2tran ")
 383           (init-assembler)
 384           (entry-analyze component)
 385           (ir2-convert component)
 386
 387           (when (policy nil (>= speed cspeed))
 388             (maybe-mumble "copy ")
 389             (copy-propagate component))
 390
 391           (select-representations component)
 392
 393           (when *check-consistency*
 394             (maybe-mumble "check2 ")
 395             (check-ir2-consistency component))
 396
 397           (delete-unreferenced-tns component)
 398
 399           (maybe-mumble "life ")
 400           (lifetime-analyze component)
 401
 402           (when *compile-progress*
 403             (compiler-mumble "") ; Sync before doing more output.
 404             (pre-pack-tn-stats component *error-output*))
 405
 406           (when *check-consistency*
 407             (maybe-mumble "check-life ")
 408             (check-life-consistency component))
 409
 410           (maybe-mumble "pack ")
 411           (pack component)
 412
 413           (when *check-consistency*
 414             (maybe-mumble "check-pack ")
 415             (check-pack-consistency component))
 416
 417           #!+sb-show
 418           (when *compiler-trace-output*
 419             (describe-component component *compiler-trace-output*)
 420             (describe-ir2-component component *compiler-trace-output*))
 421
 422           (maybe-mumble "code ")
 423           (multiple-value-bind (code-length trace-table fixups)
 424               (generate-code component)
 425
 426             #!+sb-show
 427             (when *compiler-trace-output*
 428               (format *compiler-trace-output*
 429                       "~|~%disassembly of code for ~S~2%" component)
 430               (sb!disassem:disassemble-assem-segment *code-segment*
 431                                                      *compiler-trace-output*))
 432
 433             (etypecase *compile-object*
 434               (fasl-file
 435                (maybe-mumble "fasl")
 436                (fasl-dump-component component
 437                                     *code-segment*
 438                                     code-length
 439                                     trace-table
 440                                     fixups
 441                                     *compile-object*))
 442               (core-object
 443                (maybe-mumble "core")
 444                (make-core-component component
 445                                     *code-segment*
 446                                     code-length
 447                                     trace-table
 448                                     fixups
 449                                     *compile-object*))
 450               (null))))))
 451
 452   ;; We are done, so don't bother keeping anything around.
 453   (setf (component-info component) nil)
 454
 455   (values))
 456
 457 ;;; Return our best guess for whether we will byte compile code
 458 ;;; currently being IR1 converted. This is only a guess because the
 459 ;;; decision is made on a per-component basis.
 460 ;;;
 461 ;;; FIXME: This should be called something more mnemonic, e.g.
 462 ;;; PROBABLY-BYTE-COMPILING
 463 (defun byte-compiling ()
 464   (if (eq *byte-compiling* :maybe)
 465       (or (eq *byte-compile* t)
 466           (policy nil (and (zerop speed) (<= debug 1))))
 467       (and *byte-compile* *byte-compiling*)))
 468
 469 ;;; Delete components with no external entry points before we try to
 470 ;;; generate code. Unreachable closures can cause IR2 conversion to
 471 ;;; puke on itself, since it is the reference to the closure which
 472 ;;; normally causes the components to be combined. This doesn't really
 473 ;;; cover all cases...
 474 (defun delete-if-no-entries (component)
 475   (dolist (fun (component-lambdas component)
 476                (delete-component component))
 477     (case (functional-kind fun)
 478       (:top-level (return))
 479       (:external
 480        (unless (every #'(lambda (ref)
 481                           (eq (block-component (node-block ref))
 482                               component))
 483                       (leaf-refs fun))
 484          (return))))))
 485
 486 (defun compile-component (component)
 487   (let* ((*component-being-compiled* component)
 488          (*byte-compiling*
 489           (ecase *byte-compile*
 490             ((t) t)
 491             ((nil) nil)
 492             (:maybe
 493              (dolist (fun (component-lambdas component) t)
 494                (unless (policy (lambda-bind fun)
 495                                (and (zerop speed) (<= debug 1)))
 496                  (return nil)))))))
 497
 498     (when sb!xc:*compile-print*
 499       (compiler-mumble "~&; ~:[~;byte ~]compiling ~A: "
 500                        *byte-compiling*
 501                        (component-name component)))
 502
 503     (ir1-phases component)
 504
 505     ;; FIXME: What is MAYBE-MUMBLE for? Do we need it any more?
 506     (maybe-mumble "env ")
 507     (environment-analyze component)
 508     (dfo-as-needed component)
 509
 510     (delete-if-no-entries component)
 511
 512     (unless (eq (block-next (component-head component))
 513                 (component-tail component))
 514       (if *byte-compiling*
 515           (byte-compile-component component)
 516           (native-compile-component component))))
 517
 518   (clear-constant-info)
 519
 520   (when sb!xc:*compile-print*
 521     (compiler-mumble "~&"))
 522
 523   (values))
 524 \f
 525 ;;;; clearing global data structures
 526 ;;;;
 527 ;;;; FIXME: Is it possible to get rid of this stuff, getting rid of
 528 ;;;; global data structures entirely when possible and consing up the
 529 ;;;; others from scratch instead of clearing and reusing them?
 530
 531 ;;; Clear the INFO in constants in the *FREE-VARIABLES*, etc. In
 532 ;;; addition to allowing stuff to be reclaimed, this is required for
 533 ;;; correct assignment of constant offsets, since we need to assign a
 534 ;;; new offset for each component. We don't clear the FUNCTIONAL-INFO
 535 ;;; slots, since they are used to keep track of functions across
 536 ;;; component boundaries.
 537 (defun clear-constant-info ()
 538   (maphash #'(lambda (k v)
 539                (declare (ignore k))
 540                (setf (leaf-info v) nil))
 541            *constants*)
 542   (maphash #'(lambda (k v)
 543                (declare (ignore k))
 544                (when (constant-p v)
 545                  (setf (leaf-info v) nil)))
 546            *free-variables*)
 547   (values))
 548
 549 ;;; Blow away the REFS for all global variables, and let COMPONENT
 550 ;;; be recycled.
 551 (defun clear-ir1-info (component)
 552   (declare (type component component))
 553   (labels ((blast (x)
 554              (maphash #'(lambda (k v)
 555                           (declare (ignore k))
 556                           (when (leaf-p v)
 557                             (setf (leaf-refs v)
 558                                   (delete-if #'here-p (leaf-refs v)))
 559                             (when (basic-var-p v)
 560                               (setf (basic-var-sets v)
 561                                     (delete-if #'here-p (basic-var-sets v))))))
 562                       x))
 563            (here-p (x)
 564              (eq (block-component (node-block x)) component)))
 565     (blast *free-variables*)
 566     (blast *free-functions*)
 567     (blast *constants*))
 568   (values))
 569
 570 ;;; Clear global variables used by the compiler.
 571 ;;;
 572 ;;; FIXME: It seems kinda nasty and unmaintainable to have to do this,
 573 ;;; and it adds overhead even when people aren't using the compiler.
 574 ;;; Perhaps we could make these global vars unbound except when
 575 ;;; actually in use, so that this function could go away.
 576 (defun clear-stuff (&optional (debug-too t))
 577
 578   ;; Clear global tables.
 579   (when (boundp '*free-functions*)
 580     (clrhash *free-functions*)
 581     (clrhash *free-variables*)
 582     (clrhash *constants*))
 583
 584   ;; Clear debug counters and tables.
 585   (clrhash *seen-blocks*)
 586   (clrhash *seen-functions*)
 587   (clrhash *list-conflicts-table*)
 588
 589   (when debug-too
 590     (clrhash *continuation-numbers*)
 591     (clrhash *number-continuations*)
 592     (setq *continuation-number* 0)
 593     (clrhash *tn-ids*)
 594     (clrhash *id-tns*)
 595     (setq *tn-id* 0)
 596     (clrhash *label-ids*)
 597     (clrhash *id-labels*)
 598     (setq *label-id* 0)
 599
 600     ;; Clear some Pack data structures (for GC purposes only).
 601     (assert (not *in-pack*))
 602     (dolist (sb *backend-sb-list*)
 603       (when (finite-sb-p sb)
 604         (fill (finite-sb-live-tns sb) nil))))
 605
 606   ;; (Note: The CMU CL code used to set CL::*GENSYM-COUNTER* to zero here.
 607   ;; Superficially, this seemed harmful -- the user could reasonably be
 608   ;; surprised if *GENSYM-COUNTER* turned back to zero when something was
 609   ;; compiled. A closer inspection showed that this actually turned out to be
 610   ;; harmless in practice, because CLEAR-STUFF was only called from within
 611   ;; forms which bound CL::*GENSYM-COUNTER* to zero. However, this means that
 612   ;; even though zeroing CL::*GENSYM-COUNTER* here turned out to be harmless in
 613   ;; practice, it was also useless in practice. So we don't do it any more.)
 614
 615   (values))
 616 \f
 617 ;;;; trace output
 618
 619 ;;; Print out some useful info about Component to Stream.
 620 (defun describe-component (component *standard-output*)
 621   (declare (type component component))
 622   (format t "~|~%;;;; component: ~S~2%" (component-name component))
 623   (print-blocks component)
 624   (values))
 625
 626 (defun describe-ir2-component (component *standard-output*)
 627   (format t "~%~|~%;;;; IR2 component: ~S~2%" (component-name component))
 628   (format t "entries:~%")
 629   (dolist (entry (ir2-component-entries (component-info component)))
 630     (format t "~4TL~D: ~S~:[~; [closure]~]~%"
 631             (label-id (entry-info-offset entry))
 632             (entry-info-name entry)
 633             (entry-info-closure-p entry)))
 634   (terpri)
 635   (pre-pack-tn-stats component *standard-output*)
 636   (terpri)
 637   (print-ir2-blocks component)
 638   (terpri)
 639   (values))
 640 \f
 641 ;;;; file reading
 642 ;;;;
 643 ;;;; When reading from a file, we have to keep track of some source
 644 ;;;; information. We also exploit our ability to back up for printing
 645 ;;;; the error context and for recovering from errors.
 646 ;;;;
 647 ;;;; The interface we provide to this stuff is the stream-oid
 648 ;;;; Source-Info structure. The bookkeeping is done as a side-effect
 649 ;;;; of getting the next source form.
 650
 651 ;;; A FILE-INFO structure holds all the source information for a
 652 ;;; given file.
 653 (defstruct file-info
 654   ;; If a file, the truename of the corresponding source file. If from
 655   ;; a Lisp form, :LISP. If from a stream, :STREAM.
 656   (name (required-argument) :type (or pathname (member :lisp :stream)))
 657   ;; the defaulted, but not necessarily absolute file name (i.e. prior
 658   ;; to TRUENAME call.) Null if not a file. This is used to set
 659   ;; *COMPILE-FILE-PATHNAME*, and if absolute, is dumped in the
 660   ;; debug-info.
 661   (untruename nil :type (or pathname null))
 662   ;; the file's write date (if relevant)
 663   (write-date nil :type (or unsigned-byte null))
 664   ;; the source path root number of the first form in this file (i.e.
 665   ;; the total number of forms converted previously in this
 666   ;; compilation)
 667   (source-root 0 :type unsigned-byte)
 668   ;; parallel vectors containing the forms read out of the file and
 669   ;; the file positions that reading of each form started at (i.e. the
 670   ;; end of the previous form)
 671   (forms (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t))
 672   (positions (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t)))
 673
 674 ;;; The SOURCE-INFO structure provides a handle on all the source
 675 ;;; information for an entire compilation.
 676 (defstruct (source-info
 677             #-no-ansi-print-object
 678             (:print-object (lambda (s stream)
 679                              (print-unreadable-object (s stream :type t)))))
 680   ;; the UT that compilation started at
 681   (start-time (get-universal-time) :type unsigned-byte)
 682   ;; a list of the FILE-INFO structures for this compilation
 683   (files nil :type list)
 684   ;; the tail of the FILES for the file we are currently reading
 685   (current-file nil :type list)
 686   ;; the stream that we are using to read the CURRENT-FILE, or NIL if
 687   ;; no stream has been opened yet
 688   (stream nil :type (or stream null)))
 689
 690 ;;; Given a list of pathnames, return a SOURCE-INFO structure.
 691 (defun make-file-source-info (files)
 692   (declare (list files))
 693   (let ((file-info
 694          (mapcar (lambda (x)
 695                    (make-file-info :name (truename x)
 696                                    :untruename x
 697                                    :write-date (file-write-date x)))
 698                  files)))
 699
 700     (make-source-info :files file-info
 701                       :current-file file-info)))
 702
 703 ;;; Return a SOURCE-INFO to describe the incremental compilation of
 704 ;;; FORM. Also used by SB!EVAL:INTERNAL-EVAL.
 705 (defun make-lisp-source-info (form)
 706   (make-source-info
 707    :start-time (get-universal-time)
 708    :files (list (make-file-info :name :lisp
 709                                 :forms (vector form)
 710                                 :positions '#(0)))))
 711
 712 ;;; Return a SOURCE-INFO which will read from Stream.
 713 (defun make-stream-source-info (stream)
 714   (let ((files (list (make-file-info :name :stream))))
 715     (make-source-info
 716      :files files
 717      :current-file files
 718      :stream stream)))
 719
 720 ;;; Print an error message for a non-EOF error on STREAM. OLD-POS is a
 721 ;;; preceding file position that hopefully comes before the beginning
 722 ;;; of the line. Of course, this only works on streams that support
 723 ;;; the file-position operation.
 724 (defun normal-read-error (stream old-pos condition)
 725   (declare (type stream stream) (type unsigned-byte old-pos))
 726   (let ((pos (file-position stream)))
 727     (file-position stream old-pos)
 728     (let ((start old-pos))
 729       (loop
 730         (let ((line (read-line stream nil))
 731               (end (file-position stream)))
 732           (when (>= end pos)
 733             ;; FIXME: READER-ERROR also prints the file position. Do we really
 734             ;; need to try to give position information here?
 735             (compiler-abort "read error at ~D:~% \"~A/\\~A\"~%~A"
 736                             pos
 737                             (string-left-trim "         "
 738                                               (subseq line 0 (- pos start)))
 739                             (subseq line (- pos start))
 740                             condition)
 741             (return))
 742           (setq start end)))))
 743   (values))
 744
 745 ;;; Back STREAM up to the position Pos, then read a form with
 746 ;;; *READ-SUPPRESS* on, discarding the result. If an error happens
 747 ;;; during this read, then bail out using COMPILER-ERROR (fatal in
 748 ;;; this context).
 749 (defun ignore-error-form (stream pos)
 750   (declare (type stream stream) (type unsigned-byte pos))
 751   (file-position stream pos)
 752   (handler-case (let ((*read-suppress* t))
 753                   (read stream))
 754     (error (condition)
 755       (declare (ignore condition))
 756       (compiler-error "unable to recover from read error"))))
 757
 758 ;;; Print an error message giving some context for an EOF error. We
 759 ;;; print the first line after POS that contains #\" or #\(, or
 760 ;;; lacking that, the first non-empty line.
 761 (defun unexpected-eof-error (stream pos condition)
 762   (declare (type stream stream) (type unsigned-byte pos))
 763   (let ((res nil))
 764     (file-position stream pos)
 765     (loop
 766       (let ((line (read-line stream nil nil)))
 767         (unless line (return))
 768         (when (or (find #\" line) (find #\( line))
 769           (setq res line)
 770           (return))
 771         (unless (or res (zerop (length line)))
 772           (setq res line))))
 773     (compiler-abort "read error in form starting at ~D:~%~@[ \"~A\"~%~]~A"
 774                     pos
 775                     res
 776                     condition))
 777   (file-position stream (file-length stream))
 778   (values))
 779
 780 ;;; Read a form from STREAM, returning EOF at EOF. If a read error
 781 ;;; happens, then attempt to recover if possible, returning a proxy
 782 ;;; error form.
 783 ;;;
 784 ;;; FIXME: This seems like quite a lot of complexity, and it seems
 785 ;;; impossible to get it quite right. (E.g. the `(CERROR ..) form
 786 ;;; returned here won't do the right thing if it's not in a position
 787 ;;; for an executable form.) I think it might be better to just stop
 788 ;;; trying to recover from read errors, punting all this noise
 789 ;;; (including UNEXPECTED-EOF-ERROR and IGNORE-ERROR-FORM) and doing a
 790 ;;; COMPILER-ABORT instead.
 791 (defun careful-read (stream eof pos)
 792   (handler-case (read stream nil eof)
 793     (error (condition)
 794       (let ((new-pos (file-position stream)))
 795         (cond ((= new-pos (file-length stream))
 796                (unexpected-eof-error stream pos condition))
 797               (t
 798                (normal-read-error stream pos condition)
 799                (ignore-error-form stream pos))))
 800       '(cerror "Skip this form."
 801                "compile-time read error"))))
 802
 803 ;;; If STREAM is present, return it, otherwise open a stream to the
 804 ;;; current file. There must be a current file. When we open a new
 805 ;;; file, we also reset *PACKAGE* and policy. This gives the effect of
 806 ;;; rebinding around each file.
 807 ;;;
 808 ;;; FIXME: Since we now do the standard ANSI thing of only one file
 809 ;;; per compile (unlike the CMU CL extended COMPILE-FILE) can't this
 810 ;;; complexity (including ADVANCE-SOURCE-FILE) go away?
 811 (defun get-source-stream (info)
 812   (declare (type source-info info))
 813   (cond ((source-info-stream info))
 814         (t
 815          (setq *package* *initial-package*)
 816          (setq *default-policy* (copy-policy *initial-policy*))
 817          (setq *default-interface-policy*
 818                (copy-policy *initial-interface-policy*))
 819          (let* ((finfo (first (source-info-current-file info)))
 820                 (name (file-info-name finfo)))
 821            (setq sb!xc:*compile-file-truename* name)
 822            (setq sb!xc:*compile-file-pathname* (file-info-untruename finfo))
 823            (setf (source-info-stream info)
 824                  (open name :direction :input))))))
 825
 826 ;;; Close the stream in INFO if it is open.
 827 (defun close-source-info (info)
 828   (declare (type source-info info))
 829   (let ((stream (source-info-stream info)))
 830     (when stream (close stream)))
 831   (setf (source-info-stream info) nil)
 832   (values))
 833
 834 ;;; Advance INFO to the next source file. If there is no next source
 835 ;;; file, return NIL, otherwise T.
 836 (defun advance-source-file (info)
 837   (declare (type source-info info))
 838   (close-source-info info)
 839   (let ((prev (pop (source-info-current-file info))))
 840     (if (source-info-current-file info)
 841         (let ((current (first (source-info-current-file info))))
 842           (setf (file-info-source-root current)
 843                 (+ (file-info-source-root prev)
 844                    (length (file-info-forms prev))))
 845           t)
 846         nil)))
 847
 848 ;;; Read the sources from the source files and process them.
 849 (defun process-sources (info)
 850   (let* ((file (first (source-info-current-file info)))
 851          (stream (get-source-stream info)))
 852     (loop
 853      (let* ((pos (file-position stream))
 854             (eof '(*eof*))
 855             (form (careful-read stream eof pos)))
 856        (if (eq form eof)
 857          (return)
 858          (let* ((forms (file-info-forms file))
 859                 (current-idx (+ (fill-pointer forms)
 860                                 (file-info-source-root file))))
 861            (vector-push-extend form forms)
 862            (vector-push-extend pos (file-info-positions file))
 863            (clrhash *source-paths*)
 864            (find-source-paths form current-idx)
 865            (process-top-level-form form
 866                                    `(original-source-start 0 ,current-idx))))))
 867     (when (advance-source-file info)
 868       (process-sources info))))
 869
 870 ;;; Return the FILE-INFO describing the INDEX'th form.
 871 (defun find-file-info (index info)
 872   (declare (type index index) (type source-info info))
 873   (dolist (file (source-info-files info))
 874     (when (> (+ (length (file-info-forms file))
 875                 (file-info-source-root file))
 876              index)
 877       (return file))))
 878
 879 ;;; Return the INDEX'th source form read from INFO and the position
 880 ;;; where it was read.
 881 (defun find-source-root (index info)
 882   (declare (type source-info info) (type index index))
 883   (let* ((file (find-file-info index info))
 884          (idx (- index (file-info-source-root file))))
 885     (values (aref (file-info-forms file) idx)
 886             (aref (file-info-positions file) idx))))
 887 \f
 888 ;;;; top-level form processing
 889
 890 ;;; This is called by top-level form processing when we are ready to
 891 ;;; actually compile something. If *BLOCK-COMPILE* is T, then we still
 892 ;;; convert the form, but delay compilation, pushing the result on
 893 ;;; *TOP-LEVEL-LAMBDAS* instead.
 894 (defun convert-and-maybe-compile (form path)
 895   (declare (list path))
 896   (let* ((*lexenv* (make-lexenv :policy *default-policy*
 897                                 :interface-policy *default-interface-policy*))
 898          (tll (ir1-top-level form path nil)))
 899     (cond ((eq *block-compile* t) (push tll *top-level-lambdas*))
 900           (t (compile-top-level (list tll) nil)))))
 901
 902 ;;; Process a PROGN-like portion of a top-level form. Forms is a list of
 903 ;;; the forms, and Path is source path of the form they came out of.
 904 (defun process-top-level-progn (forms path)
 905   (declare (list forms) (list path))
 906   (dolist (form forms)
 907     (process-top-level-form form path)))
 908
 909 ;;; Macroexpand form in the current environment with an error handler.
 910 ;;; We only expand one level, so that we retain all the intervening
 911 ;;; forms in the source path.
 912 (defun preprocessor-macroexpand (form)
 913   (handler-case (sb!xc:macroexpand-1 form *lexenv*)
 914     (error (condition)
 915        (compiler-error "(during macroexpansion)~%~A" condition))))
 916
 917 ;;; Process a top-level use of LOCALLY. We parse declarations and then
 918 ;;; recursively process the body.
 919 ;;;
 920 ;;; Binding *DEFAULT-xxx-POLICY* is pretty much of a hack, since it
 921 ;;; causes LOCALLY to "capture" enclosed proclamations. It is
 922 ;;; necessary because CONVERT-AND-MAYBE-COMPILE uses the value of
 923 ;;; *DEFAULT-POLICY* as the policy. The need for this hack is due to
 924 ;;; the quirk that there is no way to represent in a POLICY that an
 925 ;;; optimize quality came from the default.
 926 ;;; FIXME: Ideally, something should be done so that DECLAIM inside LOCALLY
 927 ;;; works OK. Failing that, at least we could issue a warning instead
 928 ;;; of silently screwing up.
 929 (defun process-top-level-locally (form path)
 930   (declare (list path))
 931   (multiple-value-bind (forms decls) (sb!sys:parse-body (cdr form) nil)
 932     (let* ((*lexenv*
 933             (process-decls decls nil nil (make-continuation)))
 934            (*default-policy* (lexenv-policy *lexenv*))
 935            (*default-interface-policy* (lexenv-interface-policy *lexenv*)))
 936       (process-top-level-progn forms path))))
 937
 938 ;;; Force any pending top-level forms to be compiled and dumped so
 939 ;;; that they will be evaluated in the correct package environment.
 940 ;;; Dump the form to be evaled at (cold) load time, and if EVAL is
 941 ;;; true, eval the form immediately.
 942 (defun process-cold-load-form (form path eval)
 943   (let ((object *compile-object*))
 944     (etypecase object
 945       (fasl-file
 946        (compile-top-level-lambdas () t)
 947        (fasl-dump-cold-load-form form object))
 948       ((or null core-object)
 949        (convert-and-maybe-compile form path)))
 950     (when eval
 951       (eval form))))
 952
 953 (declaim (special *compiler-error-bailout*))
 954
 955 ;;; Process a top-level FORM with the specified source PATH.
 956 ;;;  * If this is a magic top-level form, then do stuff.
 957 ;;;  * If this is a macro, then expand it.
 958 ;;;  * Otherwise, just compile it.
 959 (defun process-top-level-form (form path)
 960
 961   (declare (list path))
 962
 963   (catch 'process-top-level-form-error-abort
 964     (let* ((path (or (gethash form *source-paths*) (cons form path)))
 965            (*compiler-error-bailout*
 966             #'(lambda ()
 967                 (convert-and-maybe-compile
 968                  `(error "execution of a form compiled with errors:~% ~S"
 969                          ',form)
 970                  path)
 971                 (throw 'process-top-level-form-error-abort nil))))
 972       (if (atom form)
 973           (convert-and-maybe-compile form path)
 974           (case (car form)
 975             ;; FIXME: It's not clear to me why we would want this
 976             ;; special case; it might have been needed for some
 977             ;; variation of the old GENESIS system, but it certainly
 978             ;; doesn't seem to be needed for ours. Sometime after the
 979             ;; system is running I'd like to remove it tentatively and
 980             ;; see whether anything breaks, and if nothing does break,
 981             ;; remove it permanently. (And if we *do* want special
 982             ;; treatment of all these, we probably want to treat WARN
 983             ;; the same way..)
 984             ((error cerror break signal)
 985              (process-cold-load-form form path nil))
 986             ;; FIXME: ANSI seems to encourage things like DEFSTRUCT to
 987             ;; be done with EVAL-WHEN, without this kind of one-off
 988             ;; compiler magic.
 989             (sb!kernel:%compiler-defstruct
 990              (convert-and-maybe-compile form path)
 991              (compile-top-level-lambdas () t))
 992             ((eval-when)
 993              (unless (>= (length form) 2)
 994                (compiler-error "EVAL-WHEN form is too short: ~S" form))
 995              (do-eval-when-stuff
 996               (cadr form) (cddr form)
 997               #'(lambda (forms)
 998                   (process-top-level-progn forms path))))
 999             ((macrolet)
1000              (unless (>= (length form) 2)
1001                (compiler-error "MACROLET form is too short: ~S" form))
1002              (do-macrolet-stuff
1003               (cadr form)
1004               #'(lambda ()
1005                   (process-top-level-progn (cddr form) path))))
1006             (locally (process-top-level-locally form path))
1007             (progn (process-top-level-progn (cdr form) path))
1008             (t
1009              (let* ((uform (uncross form))
1010                     (exp (preprocessor-macroexpand uform)))
1011                (if (eq exp uform)
1012                    (convert-and-maybe-compile uform path)
1013                    (process-top-level-form exp path))))))))
1014
1015   (values))
1016 \f
1017 ;;;; load time value support
1018 ;;;;
1019 ;;;; (See EMIT-MAKE-LOAD-FORM.)
1020
1021 ;;; Returns T iff we are currently producing a fasl-file and hence
1022 ;;; constants need to be dumped carefully.
1023 (defun producing-fasl-file ()
1024   (unless *converting-for-interpreter*
1025     (fasl-file-p *compile-object*)))
1026
1027 ;;; Compile FORM and arrange for it to be called at load-time. Return
1028 ;;; the dumper handle and our best guess at the type of the object.
1029 (defun compile-load-time-value
1030        (form &optional
1031              (name (let ((*print-level* 2) (*print-length* 3))
1032                      (format nil "load time value of ~S"
1033                              (if (and (listp form)
1034                                       (eq (car form) 'make-value-cell))
1035                                  (second form)
1036                                  form)))))
1037   (let ((lambda (compile-load-time-stuff form name t)))
1038     (values
1039      (fasl-dump-load-time-value-lambda lambda *compile-object*)
1040      (let ((type (leaf-type lambda)))
1041        (if (function-type-p type)
1042            (single-value-type (function-type-returns type))
1043            *wild-type*)))))
1044
1045 ;;; Compile the FORMS and arrange for them to be called (for effect,
1046 ;;; not value) at load time.
1047 (defun compile-make-load-form-init-forms (forms name)
1048   (let ((lambda (compile-load-time-stuff `(progn ,@forms) name nil)))
1049     (fasl-dump-top-level-lambda-call lambda *compile-object*)))
1050
1051 ;;; Does the actual work of COMPILE-LOAD-TIME-VALUE or
1052 ;;; COMPILE-MAKE-LOAD-FORM- INIT-FORMS.
1053 (defun compile-load-time-stuff (form name for-value)
1054   (with-ir1-namespace
1055    (let* ((*lexenv* (make-null-lexenv))
1056           (lambda (ir1-top-level form *current-path* for-value)))
1057      (setf (leaf-name lambda) name)
1058      (compile-top-level (list lambda) t)
1059      lambda)))
1060
1061 ;;; Called by COMPILE-TOP-LEVEL when it was pased T for
1062 ;;; LOAD-TIME-VALUE-P (which happens in COMPILE-LOAD-TIME-STUFF). We
1063 ;;; don't try to combine this component with anything else and frob
1064 ;;; the name. If not in a :TOP-LEVEL component, then don't bother
1065 ;;; compiling, because it was merged with a run-time component.
1066 (defun compile-load-time-value-lambda (lambdas)
1067   (assert (null (cdr lambdas)))
1068   (let* ((lambda (car lambdas))
1069          (component (block-component (node-block (lambda-bind lambda)))))
1070     (when (eq (component-kind component) :top-level)
1071       (setf (component-name component) (leaf-name lambda))
1072       (compile-component component)
1073       (clear-ir1-info component))))
1074
1075 ;;; The entry point for MAKE-LOAD-FORM support. When IR1 conversion
1076 ;;; finds a constant structure, it invokes this to arrange for proper
1077 ;;; dumping. If it turns out that the constant has already been
1078 ;;; dumped, then we don't need to do anything.
1079 ;;;
1080 ;;; If the constant hasn't been dumped, then we check to see whether
1081 ;;; we are in the process of creating it. We detect this by
1082 ;;; maintaining the special *CONSTANTS-BEING-CREATED* as a list of all
1083 ;;; the constants we are in the process of creating. Actually, each
1084 ;;; entry is a list of the constant and any init forms that need to be
1085 ;;; processed on behalf of that constant.
1086 ;;;
1087 ;;; It's not necessarily an error for this to happen. If we are
1088 ;;; processing the init form for some object that showed up *after*
1089 ;;; the original reference to this constant, then we just need to
1090 ;;; defer the processing of that init form. To detect this, we
1091 ;;; maintain *CONSTANTS-CREATED-SINCE-LAST-INIT* as a list of the
1092 ;;; constants created since the last time we started processing an
1093 ;;; init form. If the constant passed to emit-make-load-form shows up
1094 ;;; in this list, then there is a circular chain through creation
1095 ;;; forms, which is an error.
1096 ;;;
1097 ;;; If there is some intervening init form, then we blow out of
1098 ;;; processing it by throwing to the tag PENDING-INIT. The value we
1099 ;;; throw is the entry from *CONSTANTS-BEING-CREATED*. This is so the
1100 ;;; offending init form can be tacked onto the init forms for the
1101 ;;; circular object.
1102 ;;;
1103 ;;; If the constant doesn't show up in *CONSTANTS-BEING-CREATED*, then
1104 ;;; we have to create it. We call MAKE-LOAD-FORM and check to see
1105 ;;; whether the creation form is the magic value
1106 ;;; :JUST-DUMP-IT-NORMALLY. If it is, then we don't do anything. The
1107 ;;; dumper will eventually get its hands on the object and use the
1108 ;;; normal structure dumping noise on it.
1109 ;;;
1110 ;;; Otherwise, we bind *CONSTANTS-BEING-CREATED* and
1111 ;;; *CONSTANTS-CREATED-SINCE- LAST-INIT* and compile the creation form
1112 ;;; much the way LOAD-TIME-VALUE does. When this finishes, we tell the
1113 ;;; dumper to use that result instead whenever it sees this constant.
1114 ;;;
1115 ;;; Now we try to compile the init form. We bind
1116 ;;; *CONSTANTS-CREATED-SINCE- LAST-INIT* to NIL and compile the init
1117 ;;; form (and any init forms that were added because of circularity
1118 ;;; detection). If this works, great. If not, we add the init forms to
1119 ;;; the init forms for the object that caused the problems and let it
1120 ;;; deal with it.
1121 (defvar *constants-being-created* nil)
1122 (defvar *constants-created-since-last-init* nil)
1123 ;;; FIXME: Shouldn't these^ variables be bound in LET forms?
1124 (defun emit-make-load-form (constant)
1125   (assert (fasl-file-p *compile-object*))
1126   (unless (or (fasl-constant-already-dumped constant *compile-object*)
1127               ;; KLUDGE: This special hack is because I was too lazy
1128               ;; to rework DEF!STRUCT so that the MAKE-LOAD-FORM
1129               ;; function of LAYOUT returns nontrivial forms when
1130               ;; building the cross-compiler but :IGNORE-IT when
1131               ;; cross-compiling or running under the target Lisp. --
1132               ;; WHN 19990914
1133               #+sb-xc-host (typep constant 'layout))
1134     (let ((circular-ref (assoc constant *constants-being-created* :test #'eq)))
1135       (when circular-ref
1136         (when (find constant *constants-created-since-last-init* :test #'eq)
1137           (throw constant t))
1138         (throw 'pending-init circular-ref)))
1139     (multiple-value-bind (creation-form init-form)
1140         (handler-case
1141             (sb!xc:make-load-form constant (make-null-lexenv))
1142           (error (condition)
1143                  (compiler-error "(while making load form for ~S)~%~A"
1144                                  constant
1145                                  condition)))
1146       (case creation-form
1147         (:just-dump-it-normally
1148          (fasl-validate-structure constant *compile-object*)
1149          t)
1150         (:ignore-it
1151          nil)
1152         (t
1153          (compile-top-level-lambdas () t)
1154          (when (fasl-constant-already-dumped constant *compile-object*)
1155            (return-from emit-make-load-form nil))
1156          (let* ((name (let ((*print-level* 1) (*print-length* 2))
1157                         (with-output-to-string (stream)
1158                           (write constant :stream stream))))
1159                 (info (if init-form
1160                           (list constant name init-form)
1161                           (list constant))))
1162            (let ((*constants-being-created*
1163                   (cons info *constants-being-created*))
1164                  (*constants-created-since-last-init*
1165                   (cons constant *constants-created-since-last-init*)))
1166              (when
1167                  (catch constant
1168                    (fasl-note-handle-for-constant
1169                     constant
1170                     (compile-load-time-value
1171                      creation-form
1172                      (format nil "creation form for ~A" name))
1173                     *compile-object*)
1174                    nil)
1175                (compiler-error "circular references in creation form for ~S"
1176                                constant)))
1177            (when (cdr info)
1178              (let* ((*constants-created-since-last-init* nil)
1179                     (circular-ref
1180                      (catch 'pending-init
1181                        (loop for (name form) on (cdr info) by #'cddr
1182                          collect name into names
1183                          collect form into forms
1184                          finally
1185                          (compile-make-load-form-init-forms
1186                           forms
1187                           (format nil "init form~:[~;s~] for ~{~A~^, ~}"
1188                                   (cdr forms) names)))
1189                        nil)))
1190                (when circular-ref
1191                  (setf (cdr circular-ref)
1192                        (append (cdr circular-ref) (cdr info))))))))))))
1193 \f
1194 ;;;; COMPILE-FILE
1195
1196 ;;; We build a list of top-level lambdas, and then periodically smash
1197 ;;; them together into a single component and compile it.
1198 (defvar *pending-top-level-lambdas*)
1199
1200 ;;; The maximum number of top-level lambdas we put in a single
1201 ;;; top-level component.
1202 ;;;
1203 ;;; CMU CL 18b used this nontrivially by default (setting it to 10)
1204 ;;; but consequently suffered from the inability to execute some
1205 ;;; troublesome constructs correctly, e.g. inability to load a fasl
1206 ;;; file compiled from the source file
1207 ;;;   (defpackage "FOO" (:use "CL"))
1208 ;;;   (print 'foo::bar)
1209 ;;; because it would dump data-setup fops (including a FOP-PACKAGE for
1210 ;;; "FOO") for the second form before dumping the the code in the
1211 ;;; first form, or the fop to execute the code in the first form. By
1212 ;;; setting this value to 0 by default, we avoid this badness. This
1213 ;;; increases the number of toplevel form functions, and so increases
1214 ;;; the size of object files.
1215 ;;;
1216 ;;; The variable is still supported because when we are compiling the
1217 ;;; SBCL system itself, which is known not contain any troublesome
1218 ;;; constructs, we can set it to a nonzero value, which reduces the
1219 ;;; number of toplevel form objects, reducing the peak memory usage in
1220 ;;; GENESIS, which is desirable, since at least for SBCL version
1221 ;;; 0.6.7, this is the high water mark for memory usage during system
1222 ;;; construction.
1223 (defparameter *top-level-lambda-max* 0)
1224
1225 (defun object-call-top-level-lambda (tll)
1226   (declare (type functional tll))
1227   (let ((object *compile-object*))
1228     (etypecase object
1229       (fasl-file
1230        (fasl-dump-top-level-lambda-call tll object))
1231       (core-object
1232        (core-call-top-level-lambda tll object))
1233       (null))))
1234
1235 ;;; Add LAMBDAS to the pending lambdas. If this leaves more than
1236 ;;; *TOP-LEVEL-LAMBDA-MAX* lambdas in the list, or if FORCE-P is true,
1237 ;;; then smash the lambdas into a single component, compile it, and
1238 ;;; call the resulting function.
1239 (defun sub-compile-top-level-lambdas (lambdas force-p)
1240   (declare (list lambdas))
1241   (setq *pending-top-level-lambdas*
1242         (append *pending-top-level-lambdas* lambdas))
1243   (let ((pending *pending-top-level-lambdas*))
1244     (when (and pending
1245                (or (> (length pending) *top-level-lambda-max*)
1246                    force-p))
1247       (multiple-value-bind (component tll) (merge-top-level-lambdas pending)
1248         (setq *pending-top-level-lambdas* ())
1249         (let ((*byte-compile* (if (eq *byte-compile* :maybe)
1250                                   *byte-compile-top-level*
1251                                   *byte-compile*)))
1252           (compile-component component))
1253         (clear-ir1-info component)
1254         (object-call-top-level-lambda tll))))
1255   (values))
1256
1257 ;;; Compile top-level code and call the top-level lambdas. We pick off
1258 ;;; top-level lambdas in non-top-level components here, calling
1259 ;;; SUB-c-t-l-l on each subsequence of normal top-level lambdas.
1260 (defun compile-top-level-lambdas (lambdas force-p)
1261   (declare (list lambdas))
1262   (let ((len (length lambdas)))
1263     (flet ((loser (start)
1264              (or (position-if #'(lambda (x)
1265                                   (not (eq (component-kind
1266                                             (block-component
1267                                              (node-block
1268                                               (lambda-bind x))))
1269                                            :top-level)))
1270                               lambdas
1271                               :start start)
1272                  len)))
1273       (do* ((start 0 (1+ loser))
1274             (loser (loser start) (loser start)))
1275            ((>= start len)
1276             (when force-p
1277               (sub-compile-top-level-lambdas nil t)))
1278         (sub-compile-top-level-lambdas (subseq lambdas start loser)
1279                                        (or force-p (/= loser len)))
1280         (unless (= loser len)
1281           (object-call-top-level-lambda (elt lambdas loser))))))
1282   (values))
1283
1284 ;;; Compile LAMBDAS (a list of the lambdas for top-level forms) into
1285 ;;; the object file. We loop doing local call analysis until it
1286 ;;; converges, since a single pass might miss something due to
1287 ;;; components being joined by LET conversion.
1288 ;;;
1289 ;;; LOAD-TIME-VALUE-P seems to control whether it's MAKE-LOAD-FORM and
1290 ;;; COMPILE-LOAD-TIME-VALUE stuff. -- WHN 20000201
1291 (defun compile-top-level (lambdas load-time-value-p)
1292   (declare (list lambdas))
1293   (maybe-mumble "locall ")
1294   (loop
1295     (let ((did-something nil))
1296       (dolist (lambda lambdas)
1297         (let* ((component (block-component (node-block (lambda-bind lambda))))
1298                (*all-components* (list component)))
1299           (when (component-new-functions component)
1300             (setq did-something t)
1301             (local-call-analyze component))))
1302       (unless did-something (return))))
1303
1304   (maybe-mumble "IDFO ")
1305   (multiple-value-bind (components top-components hairy-top)
1306       (find-initial-dfo lambdas)
1307     (let ((*all-components* (append components top-components))
1308           (top-level-closure nil))
1309       (when *check-consistency*
1310         (maybe-mumble "[check]~%")
1311         (check-ir1-consistency *all-components*))
1312
1313       (dolist (component (append hairy-top top-components))
1314         (when (pre-environment-analyze-top-level component)
1315           (setq top-level-closure t)))
1316
1317       (let ((*byte-compile*
1318              (if (and top-level-closure (eq *byte-compile* :maybe))
1319                  nil
1320                  *byte-compile*)))
1321         (dolist (component components)
1322           (compile-component component)
1323           (when (replace-top-level-xeps component)
1324             (setq top-level-closure t)))
1325
1326         (when *check-consistency*
1327           (maybe-mumble "[check]~%")
1328           (check-ir1-consistency *all-components*))
1329
1330         (if load-time-value-p
1331             (compile-load-time-value-lambda lambdas)
1332             (compile-top-level-lambdas lambdas top-level-closure)))
1333
1334       (dolist (component components)
1335         (clear-ir1-info component))
1336       (clear-stuff)))
1337   (values))
1338
1339 ;;; Actually compile any stuff that has been queued up for block
1340 ;;; compilation.
1341 (defun finish-block-compilation ()
1342   (when *block-compile*
1343     (when *top-level-lambdas*
1344       (compile-top-level (nreverse *top-level-lambdas*) nil)
1345       (setq *top-level-lambdas* ()))
1346     (setq *block-compile* nil)
1347     (setq *entry-points* nil)))
1348
1349 ;;; Read all forms from INFO and compile them, with output to OBJECT.
1350 ;;; Return (VALUES NIL WARNINGS-P FAILURE-P).
1351 (defun sub-compile-file (info &optional d-s-info)
1352   (declare (type source-info info))
1353   (let* (;; These are bound in WITH-COMPILATION-UNIT now. -- WHN 20000308
1354          #+nil (*compiler-error-count* 0)
1355          #+nil (*compiler-warning-count* 0)
1356          #+nil (*compiler-style-warning-count* 0)
1357          #+nil (*compiler-note-count* 0)
1358          (*block-compile* *block-compile-argument*)
1359          (*package* (sane-package))
1360          (*initial-package* (sane-package))
1361          (*initial-policy* *default-policy*)
1362          (*initial-interface-policy* *default-interface-policy*)
1363          (*default-policy* (copy-policy *initial-policy*))
1364          (*default-interface-policy* (copy-policy *initial-interface-policy*))
1365          (*lexenv* (make-null-lexenv))
1366          (*converting-for-interpreter* nil)
1367          (*source-info* info)
1368          (sb!xc:*compile-file-pathname* nil)
1369          (sb!xc:*compile-file-truename* nil)
1370          (*top-level-lambdas* ())
1371          (*pending-top-level-lambdas* ())
1372          (*compiler-error-bailout*
1373           (lambda ()
1374             (compiler-mumble "~2&; fatal error, aborting compilation~%")
1375             (return-from sub-compile-file (values nil t t))))
1376          (*current-path* nil)
1377          (*last-source-context* nil)
1378          (*last-original-source* nil)
1379          (*last-source-form* nil)
1380          (*last-format-string* nil)
1381          (*last-format-args* nil)
1382          (*last-message-count* 0)
1383          (*info-environment* (or *backend-info-environment*
1384                                  *info-environment*))
1385          (*gensym-counter* 0))
1386     (with-compilation-values
1387       (sb!xc:with-compilation-unit ()
1388         (clear-stuff)
1389
1390         (process-sources info)
1391
1392         (finish-block-compilation)
1393         (compile-top-level-lambdas () t)
1394         (let ((object *compile-object*))
1395           (etypecase object
1396             (fasl-file (fasl-dump-source-info info object))
1397             (core-object (fix-core-source-info info object d-s-info))
1398             (null)))
1399         nil))))
1400
1401 ;;; Return a list of pathnames for the named files. All the files must
1402 ;;; exist.
1403 (defun verify-source-files (stuff)
1404   (let* ((stuff (if (listp stuff) stuff (list stuff)))
1405          (default-host (make-pathname
1406                         :host (pathname-host (pathname (first stuff))))))
1407     (flet ((try-with-type (path type error-p)
1408              (let ((new (merge-pathnames
1409                          path (make-pathname :type type
1410                                              :defaults default-host))))
1411                (if (probe-file new)
1412                    new
1413                    (and error-p (truename new))))))
1414       (unless stuff
1415         (error "can't compile with no source files"))
1416       (mapcar #'(lambda (x)
1417                   (let ((x (pathname x)))
1418                     (cond ((typep x 'logical-pathname)
1419                            (try-with-type x "LISP" t))
1420                           ((probe-file x) x)
1421                           ((try-with-type x "lisp"  nil))
1422                           ((try-with-type x "lisp"  t)))))
1423               stuff))))
1424
1425 (defun elapsed-time-to-string (tsec)
1426   (multiple-value-bind (tmin sec) (truncate tsec 60)
1427     (multiple-value-bind (thr min) (truncate tmin 60)
1428       (format nil "~D:~2,'0D:~2,'0D" thr min sec))))
1429
1430 ;;; Print some junk at the beginning and end of compilation.
1431 (defun start-error-output (source-info)
1432   (declare (type source-info source-info))
1433   (dolist (x (source-info-files source-info))
1434     (compiler-mumble "~&; compiling file ~S (written ~A):~%"
1435                      (namestring (file-info-name x))
1436                      (sb!int:format-universal-time nil
1437                                                    (file-info-write-date x)
1438                                                    :style :government
1439                                                    :print-weekday nil
1440                                                    :print-timezone nil)))
1441   (values))
1442
1443 (defun finish-error-output (source-info won)
1444   (declare (type source-info source-info))
1445   (compiler-mumble "~&; compilation ~:[aborted after~;finished in~] ~A~&"
1446                    won
1447                    (elapsed-time-to-string
1448                     (- (get-universal-time)
1449                        (source-info-start-time source-info))))
1450   (values))
1451
1452 ;;; Open some files and call SUB-COMPILE-FILE. If something unwinds
1453 ;;; out of the compile, then abort the writing of the output file, so
1454 ;;; we don't overwrite it with known garbage.
1455 (defun sb!xc:compile-file
1456     (input-file
1457      &key
1458      (output-file (cfp-output-file-default input-file))
1459      ;; FIXME: ANSI doesn't seem to say anything about
1460      ;; *COMPILE-VERBOSE* and *COMPILE-PRINT* being rebound by this
1461      ;; function..
1462      ((:verbose sb!xc:*compile-verbose*) sb!xc:*compile-verbose*)
1463      ((:print sb!xc:*compile-print*) sb!xc:*compile-print*)
1464      (external-format :default)
1465      ((:block-compile *block-compile-argument*) nil)
1466      ((:entry-points *entry-points*) nil)
1467      ((:byte-compile *byte-compile*) *byte-compile-default*))
1468   #!+sb-doc
1469   "Compile INPUT-FILE, producing a corresponding fasl file.
1470    :Output-File
1471       The name of the fasl to output.
1472    :Block-Compile
1473       Determines whether multiple functions are compiled together as a unit,
1474       resolving function references at compile time. NIL means that global
1475       function names are never resolved at compilation time.
1476    :Entry-Points
1477       This specifies a list of function names for functions in the file(s) that
1478       must be given global definitions. This only applies to block
1479       compilation. If the value is NIL (the default) then all functions
1480       will be globally defined.
1481    :Byte-Compile {T | NIL | :MAYBE}
1482       Determines whether to compile into interpreted byte code instead of
1483       machine instructions. Byte code is several times smaller, but much
1484       slower. If :MAYBE, then only byte-compile when SPEED is 0 and
1485       DEBUG <= 1. The default is the value of SB-EXT:*BYTE-COMPILE-DEFAULT*,
1486       which is initially :MAYBE."
1487   (unless (eq external-format :default)
1488     (error "Non-:DEFAULT EXTERNAL-FORMAT values are not supported."))
1489   (let* ((fasl-file nil)
1490          (output-file-name nil)
1491          (compile-won nil)
1492          (warnings-p nil)
1493          (failure-p t) ; T in case error keeps this from being set later
1494          ;; KLUDGE: The listifying and unlistifying in the next calls
1495          ;; is to interface to old CMU CL code which accepted and
1496          ;; returned lists of multiple source files. It would be
1497          ;; cleaner to redo VERIFY-SOURCE-FILES and as
1498          ;; VERIFY-SOURCE-FILE, accepting a single source file, and
1499          ;; do a similar transformation on MAKE-FILE-SOURCE-INFO too.
1500          ;; -- WHN 20000201
1501          (input-pathname (first (verify-source-files (list input-file))))
1502          (source-info (make-file-source-info (list input-pathname))))
1503     (unwind-protect
1504         (progn
1505           (when output-file
1506             (setq output-file-name
1507                   (sb!xc:compile-file-pathname input-file
1508                                                :output-file output-file))
1509             (setq fasl-file
1510                   (open-fasl-file output-file-name
1511                                   (namestring input-pathname)
1512                                   (eq *byte-compile* t))))
1513
1514           (when sb!xc:*compile-verbose*
1515             (start-error-output source-info))
1516           (let ((*compile-object* fasl-file)
1517                 dummy)
1518             (multiple-value-setq (dummy warnings-p failure-p)
1519               (sub-compile-file source-info)))
1520           (setq compile-won t))
1521
1522       (close-source-info source-info)
1523
1524       (when fasl-file
1525         (close-fasl-file fasl-file (not compile-won))
1526         (setq output-file-name (pathname (fasl-file-stream fasl-file)))
1527         (when (and compile-won sb!xc:*compile-verbose*)
1528           (compiler-mumble "~2&; ~A written~%" (namestring output-file-name))))
1529
1530       (when sb!xc:*compile-verbose*
1531         (finish-error-output source-info compile-won)))
1532
1533     (values (if output-file
1534                 ;; Hack around filesystem race condition...
1535                 (or (probe-file output-file-name) output-file-name)
1536                 nil)
1537             warnings-p
1538             failure-p)))
1539 \f
1540 ;;; a helper function for COMPILE-FILE-PATHNAME: the default for
1541 ;;; the OUTPUT-FILE argument
1542 ;;;
1543 ;;; ANSI: The defaults for the OUTPUT-FILE are taken from the pathname
1544 ;;; that results from merging the INPUT-FILE with the value of
1545 ;;; *DEFAULT-PATHNAME-DEFAULTS*, except that the type component should
1546 ;;; default to the appropriate implementation-defined default type for
1547 ;;; compiled files.
1548 (defun cfp-output-file-default (input-file)
1549   (let* ((defaults (merge-pathnames input-file
1550                                     *default-pathname-defaults*))
1551          (retyped (make-pathname :type *backend-fasl-file-type*
1552                                  :defaults defaults)))
1553     retyped))
1554
1555 ;;; KLUDGE: Part of the ANSI spec for this seems contradictory:
1556 ;;;   If INPUT-FILE is a logical pathname and OUTPUT-FILE is unsupplied,
1557 ;;;   the result is a logical pathname. If INPUT-FILE is a logical
1558 ;;;   pathname, it is translated into a physical pathname as if by
1559 ;;;   calling TRANSLATE-LOGICAL-PATHNAME.
1560 ;;; So I haven't really tried to make this precisely ANSI-compatible
1561 ;;; at the level of e.g. whether it returns logical pathname or a
1562 ;;; physical pathname. Patches to make it more correct are welcome.
1563 ;;; -- WHN 2000-12-09
1564 (defun sb!xc:compile-file-pathname (input-file
1565                                     &key
1566                                     (output-file (cfp-output-file-default
1567                                                   input-file))
1568                                     &allow-other-keys)
1569   #!+sb-doc
1570   "Return a pathname describing what file COMPILE-FILE would write to given
1571    these arguments."
1572   (pathname output-file))