src/compiler/main.lisp

   1 ;;;; the top-level interfaces to the compiler, plus some other
   2 ;;;; compiler-related stuff (e.g. CL:CALL-ARGUMENTS-LIMIT) which
   3 ;;;; doesn't obviously belong anywhere else
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15
  16 ;;; FIXME: Doesn't this belong somewhere else, like early-c.lisp?
  17 (declaim (special *constants* *free-variables* *component-being-compiled*
  18                   *code-vector* *next-location* *result-fixups*
  19                   *free-functions* *source-paths*
  20                   *seen-blocks* *seen-functions* *list-conflicts-table*
  21                   *continuation-number* *continuation-numbers*
  22                   *number-continuations* *tn-id* *tn-ids* *id-tns*
  23                   *label-ids* *label-id* *id-labels*
  24                   *undefined-warnings* *compiler-error-count*
  25                   *compiler-warning-count* *compiler-style-warning-count*
  26                   *compiler-note-count*
  27                   *compiler-error-bailout*
  28                   #!+sb-show *compiler-trace-output*
  29                   *last-source-context* *last-original-source*
  30                   *last-source-form* *last-format-string* *last-format-args*
  31                   *last-message-count* *lexenv*))
  32
  33 (defvar *check-consistency* nil)
  34 (defvar *all-components*)
  35
  36 ;;; Bind this to a stream to capture various internal debugging output.
  37 (defvar *compiler-trace-output* nil)
  38
  39 ;;; The current block compilation state. These are initialized to the
  40 ;;; :BLOCK-COMPILE and :ENTRY-POINTS arguments that COMPILE-FILE was
  41 ;;; called with.
  42 ;;;
  43 ;;; *BLOCK-COMPILE-ARGUMENT* holds the original value of the
  44 ;;; :BLOCK-COMPILE argument, which overrides any internal
  45 ;;; declarations.
  46 (defvar *block-compile*)
  47 (defvar *block-compile-argument*)
  48 (declaim (type (member nil t :specified)
  49                *block-compile* *block-compile-argument*))
  50 (defvar *entry-points*)
  51 (declaim (list *entry-points*))
  52
  53 ;;; When block compiling, used by PROCESS-FORM to accumulate top-level
  54 ;;; lambdas resulting from compiling subforms. (In reverse order.)
  55 (defvar *top-level-lambdas*)
  56 (declaim (list *top-level-lambdas*))
  57
  58 (defvar sb!xc:*compile-verbose* t
  59   #!+sb-doc
  60   "The default for the :VERBOSE argument to COMPILE-FILE.")
  61 (defvar sb!xc:*compile-print* t
  62   #!+sb-doc
  63   "The default for the :PRINT argument to COMPILE-FILE.")
  64 (defvar *compile-progress* nil
  65   #!+sb-doc
  66   "When this is true, the compiler prints to *ERROR-OUTPUT* progress
  67   information about the phases of compilation of each function. (This
  68   is useful mainly in large block compilations.)")
  69
  70 (defvar sb!xc:*compile-file-pathname* nil
  71   #!+sb-doc
  72   "The defaulted pathname of the file currently being compiled, or NIL if not
  73   compiling.")
  74 (defvar sb!xc:*compile-file-truename* nil
  75   #!+sb-doc
  76   "The TRUENAME of the file currently being compiled, or NIL if not
  77   compiling.")
  78
  79 (declaim (type (or pathname null)
  80                sb!xc:*compile-file-pathname*
  81                sb!xc:*compile-file-truename*))
  82
  83 ;;; the SOURCE-INFO structure for the current compilation. This is
  84 ;;; null globally to indicate that we aren't currently in any
  85 ;;; identifiable compilation.
  86 (defvar *source-info* nil)
  87
  88 ;;; This is true if we are within a WITH-COMPILATION-UNIT form (which
  89 ;;; normally causes nested uses to be no-ops).
  90 (defvar *in-compilation-unit* nil)
  91
  92 ;;; Count of the number of compilation units dynamically enclosed by
  93 ;;; the current active WITH-COMPILATION-UNIT that were unwound out of.
  94 (defvar *aborted-compilation-unit-count*)
  95
  96 ;;; Mumble conditional on *COMPILE-PROGRESS*.
  97 (defun maybe-mumble (&rest foo)
  98   (when *compile-progress*
  99     (compiler-mumble "~&")
 100     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 101        (apply #'compiler-mumble foo))))
 102
 103 (deftype object () '(or fasl-output core-object null))
 104
 105 (defvar *compile-object* nil)
 106 (declaim (type object *compile-object*))
 107 \f
 108 ;;;; WITH-COMPILATION-UNIT and WITH-COMPILATION-VALUES
 109
 110 (defmacro sb!xc:with-compilation-unit (options &body body)
 111   #!+sb-doc
 112   "WITH-COMPILATION-UNIT ({Key Value}*) Form*
 113   This form affects compilations that take place within its dynamic extent. It
 114   is intended to be wrapped around the compilation of all files in the same
 115   system. These keywords are defined:
 116     :OVERRIDE Boolean-Form
 117         One of the effects of this form is to delay undefined warnings
 118         until the end of the form, instead of giving them at the end of each
 119         compilation. If OVERRIDE is NIL (the default), then the outermost
 120         WITH-COMPILATION-UNIT form grabs the undefined warnings. Specifying
 121         OVERRIDE true causes that form to grab any enclosed warnings, even if
 122         it is enclosed by another WITH-COMPILATION-UNIT."
 123   `(%with-compilation-unit (lambda () ,@body) ,@options))
 124
 125 (defun %with-compilation-unit (fn &key override)
 126   (let ((succeeded-p nil))
 127     (if (and *in-compilation-unit* (not override))
 128         ;; Inside another WITH-COMPILATION-UNIT, a WITH-COMPILATION-UNIT is
 129         ;; ordinarily (unless OVERRIDE) basically a no-op.
 130         (unwind-protect
 131             (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 132           (unless succeeded-p
 133             (incf *aborted-compilation-unit-count*)))
 134         ;; FIXME: Now *COMPILER-FOO-COUNT* stuff is bound in more than
 135         ;; one place. If we can get rid of the IR1 interpreter, this
 136         ;; should be easier to clean up.
 137         (let ((*aborted-compilation-unit-count* 0)
 138               (*compiler-error-count* 0)
 139               (*compiler-warning-count* 0)
 140               (*compiler-style-warning-count* 0)
 141               (*compiler-note-count* 0)
 142               (*undefined-warnings* nil)
 143               (*in-compilation-unit* t))
 144           (handler-bind ((parse-unknown-type
 145                           (lambda (c)
 146                             (note-undefined-reference
 147                              (parse-unknown-type-specifier c)
 148                              :type))))
 149             (unwind-protect
 150                 (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 151               (unless succeeded-p
 152                 (incf *aborted-compilation-unit-count*))
 153               (summarize-compilation-unit (not succeeded-p))))))))
 154
 155 ;;; This is to be called at the end of a compilation unit. It signals
 156 ;;; any residual warnings about unknown stuff, then prints the total
 157 ;;; error counts. ABORT-P should be true when the compilation unit was
 158 ;;; aborted by throwing out. ABORT-COUNT is the number of dynamically
 159 ;;; enclosed nested compilation units that were aborted.
 160 (defun summarize-compilation-unit (abort-p)
 161   (unless abort-p
 162     (handler-bind ((style-warning #'compiler-style-warning-handler)
 163                    (warning #'compiler-warning-handler))
 164
 165       (let ((undefs (sort *undefined-warnings* #'string<
 166                           :key #'(lambda (x)
 167                                    (let ((x (undefined-warning-name x)))
 168                                      (if (symbolp x)
 169                                          (symbol-name x)
 170                                          (prin1-to-string x)))))))
 171         (dolist (undef undefs)
 172           (let ((name (undefined-warning-name undef))
 173                 (kind (undefined-warning-kind undef))
 174                 (warnings (undefined-warning-warnings undef))
 175                 (undefined-warning-count (undefined-warning-count undef)))
 176             (dolist (*compiler-error-context* warnings)
 177               (compiler-style-warning "undefined ~(~A~): ~S" kind name))
 178             (let ((warn-count (length warnings)))
 179               (when (and warnings (> undefined-warning-count warn-count))
 180                 (let ((more (- undefined-warning-count warn-count)))
 181                   (compiler-style-warning
 182                    "~D more use~:P of undefined ~(~A~) ~S"
 183                    more kind name))))))
 184
 185         (dolist (kind '(:variable :function :type))
 186           (let ((summary (mapcar #'undefined-warning-name
 187                                  (remove kind undefs :test-not #'eq
 188                                          :key #'undefined-warning-kind))))
 189             (when summary
 190               (compiler-style-warning
 191                "~:[This ~(~A~) is~;These ~(~A~)s are~] undefined:~
 192                 ~%  ~{~<~%  ~1:;~S~>~^ ~}"
 193                (cdr summary) kind summary)))))))
 194
 195   (unless (and (not abort-p)
 196                (zerop *aborted-compilation-unit-count*)
 197                (zerop *compiler-error-count*)
 198                (zerop *compiler-warning-count*)
 199                (zerop *compiler-style-warning-count*)
 200                (zerop *compiler-note-count*))
 201     (format *error-output* "~&")
 202     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 203       (compiler-mumble "compilation unit ~:[finished~;aborted~]~
 204                        ~[~:;~:*~&  caught ~D fatal ERROR condition~:P~]~
 205                        ~[~:;~:*~&  caught ~D ERROR condition~:P~]~
 206                        ~[~:;~:*~&  caught ~D WARNING condition~:P~]~
 207                        ~[~:;~:*~&  caught ~D STYLE-WARNING condition~:P~]~
 208                        ~[~:;~:*~&  printed ~D note~:P~]"
 209                        abort-p
 210                        *aborted-compilation-unit-count*
 211                        *compiler-error-count*
 212                        *compiler-warning-count*
 213                        *compiler-style-warning-count*
 214                        *compiler-note-count*)))
 215   (format *error-output* "~&"))
 216
 217 ;;; Evaluate BODY, then return (VALUES BODY-VALUE WARNINGS-P
 218 ;;; FAILURE-P), where BODY-VALUE is the first value of the body, and
 219 ;;; WARNINGS-P and FAILURE-P are as in CL:COMPILE or CL:COMPILE-FILE.
 220 ;;; This also wraps up WITH-IR1-NAMESPACE functionality.
 221 (defmacro with-compilation-values (&body body)
 222   `(with-ir1-namespace
 223     (let ((*warnings-p* nil)
 224           (*failure-p* nil))
 225       (values (progn ,@body)
 226               *warnings-p*
 227               *failure-p*))))
 228 \f
 229 ;;;; component compilation
 230
 231 (defparameter *max-optimize-iterations* 3 ; ARB
 232   #!+sb-doc
 233   "The upper limit on the number of times that we will consecutively do IR1
 234   optimization that doesn't introduce any new code. A finite limit is
 235   necessary, since type inference may take arbitrarily long to converge.")
 236
 237 (defevent ir1-optimize-until-done "IR1-OPTIMIZE-UNTIL-DONE called")
 238 (defevent ir1-optimize-maxed-out "hit *MAX-OPTIMIZE-ITERATIONS* limit")
 239
 240 ;;; Repeatedly optimize COMPONENT until no further optimizations can
 241 ;;; be found or we hit our iteration limit. When we hit the limit, we
 242 ;;; clear the component and block REOPTIMIZE flags to discourage the
 243 ;;; next optimization attempt from pounding on the same code.
 244 (defun ir1-optimize-until-done (component)
 245   (declare (type component component))
 246   (maybe-mumble "opt")
 247   (event ir1-optimize-until-done)
 248   (let ((count 0)
 249         (cleared-reanalyze nil))
 250     (loop
 251       (when (component-reanalyze component)
 252         (setq count 0)
 253         (setq cleared-reanalyze t)
 254         (setf (component-reanalyze component) nil))
 255       (setf (component-reoptimize component) nil)
 256       (ir1-optimize component)
 257       (cond ((component-reoptimize component)
 258              (incf count)
 259              (when (= count *max-optimize-iterations*)
 260                (maybe-mumble "*")
 261                (cond ((retry-delayed-ir1-transforms :optimize)
 262                       (maybe-mumble "+")
 263                       (setq count 0))
 264                      (t
 265                       (event ir1-optimize-maxed-out)
 266                       (setf (component-reoptimize component) nil)
 267                       (do-blocks (block component)
 268                         (setf (block-reoptimize block) nil))
 269                       (return)))))
 270             ((retry-delayed-ir1-transforms :optimize)
 271              (setf count 0)
 272              (maybe-mumble "+"))
 273             (t
 274              (maybe-mumble " ")
 275              (return)))
 276       (maybe-mumble "."))
 277     (when cleared-reanalyze
 278       (setf (component-reanalyze component) t)))
 279   (values))
 280
 281 (defparameter *constraint-propagate* t)
 282
 283 ;;; KLUDGE: This was bumped from 5 to 10 in a DTC patch ported by MNA
 284 ;;; from CMU CL into sbcl-0.6.11.44, the same one which allowed IR1
 285 ;;; transforms to be delayed. Either DTC or MNA or both didn't explain
 286 ;;; why, and I don't know what the rationale was. -- WHN 2001-04-28
 287 ;;;
 288 ;;; FIXME: It would be good to document why it's important to have a
 289 ;;; large value here, and what the drawbacks of an excessively large
 290 ;;; value are; and it might also be good to make it depend on
 291 ;;; optimization policy.
 292 (defparameter *reoptimize-after-type-check-max* 10)
 293
 294 (defevent reoptimize-maxed-out
 295   "*REOPTIMIZE-AFTER-TYPE-CHECK-MAX* exceeded.")
 296
 297 ;;; Iterate doing FIND-DFO until no new dead code is discovered.
 298 (defun dfo-as-needed (component)
 299   (declare (type component component))
 300   (when (component-reanalyze component)
 301     (maybe-mumble "DFO")
 302     (loop
 303       (find-dfo component)
 304       (unless (component-reanalyze component)
 305         (maybe-mumble " ")
 306         (return))
 307       (maybe-mumble ".")))
 308   (values))
 309
 310 ;;; Do all the IR1 phases for a non-top-level component.
 311 (defun ir1-phases (component)
 312   (declare (type component component))
 313   (let ((*constraint-number* 0)
 314         (loop-count 1)
 315         (*delayed-ir1-transforms* nil))
 316     (declare (special *constraint-number* *delayed-ir1-transforms*))
 317     (loop
 318       (ir1-optimize-until-done component)
 319       (when (or (component-new-functions component)
 320                 (component-reanalyze-functions component))
 321         (maybe-mumble "locall ")
 322         (local-call-analyze component))
 323       (dfo-as-needed component)
 324       (when *constraint-propagate*
 325         (maybe-mumble "constraint ")
 326         (constraint-propagate component))
 327       (when (retry-delayed-ir1-transforms :constraint)
 328         (maybe-mumble "Rtran "))
 329       ;; Delay the generation of type checks until the type
 330       ;; constraints have had time to propagate, else the compiler can
 331       ;; confuse itself.
 332       (unless (and (or (component-reoptimize component)
 333                        (component-reanalyze component)
 334                        (component-new-functions component)
 335                        (component-reanalyze-functions component))
 336                    (< loop-count (- *reoptimize-after-type-check-max* 4)))
 337         (maybe-mumble "type ")
 338         (generate-type-checks component)
 339         (unless (or (component-reoptimize component)
 340                     (component-reanalyze component)
 341                     (component-new-functions component)
 342                     (component-reanalyze-functions component))
 343           (return)))
 344       (when (>= loop-count *reoptimize-after-type-check-max*)
 345         (maybe-mumble "[reoptimize limit]")
 346         (event reoptimize-maxed-out)
 347         (return))
 348       (incf loop-count)))
 349
 350   (ir1-finalize component)
 351   (values))
 352
 353 (defun %compile-component (component)
 354   (/show "entering %COMPILE-COMPONENT")
 355   (let ((*code-segment* nil)
 356         (*elsewhere* nil))
 357     (maybe-mumble "GTN ")
 358     (gtn-analyze component)
 359     (maybe-mumble "LTN ")
 360     (ltn-analyze component)
 361     (dfo-as-needed component)
 362     (maybe-mumble "control ")
 363     (control-analyze component #'make-ir2-block)
 364
 365     (when (ir2-component-values-receivers (component-info component))
 366       (maybe-mumble "stack ")
 367       (stack-analyze component)
 368       ;; Assign BLOCK-NUMBER for any cleanup blocks introduced by
 369       ;; stack analysis. There shouldn't be any unreachable code after
 370       ;; control, so this won't delete anything.
 371       (dfo-as-needed component))
 372
 373     (unwind-protect
 374         (progn
 375           (maybe-mumble "IR2tran ")
 376           (init-assembler)
 377           (entry-analyze component)
 378           (ir2-convert component)
 379
 380           (when (policy *lexenv* (>= speed compilation-speed))
 381             (maybe-mumble "copy ")
 382             (copy-propagate component))
 383
 384           (select-representations component)
 385
 386           (when *check-consistency*
 387             (maybe-mumble "check2 ")
 388             (check-ir2-consistency component))
 389
 390           (delete-unreferenced-tns component)
 391
 392           (maybe-mumble "life ")
 393           (lifetime-analyze component)
 394
 395           (when *compile-progress*
 396             (compiler-mumble "") ; Sync before doing more output.
 397             (pre-pack-tn-stats component *error-output*))
 398
 399           (when *check-consistency*
 400             (maybe-mumble "check-life ")
 401             (check-life-consistency component))
 402
 403           (maybe-mumble "pack ")
 404           (pack component)
 405
 406           (when *check-consistency*
 407             (maybe-mumble "check-pack ")
 408             (check-pack-consistency component))
 409
 410           (when *compiler-trace-output*
 411             (describe-component component *compiler-trace-output*)
 412             (describe-ir2-component component *compiler-trace-output*))
 413
 414           (maybe-mumble "code ")
 415           (multiple-value-bind (code-length trace-table fixups)
 416               (generate-code component)
 417
 418             (when *compiler-trace-output*
 419               (format *compiler-trace-output*
 420                       "~|~%disassembly of code for ~S~2%" component)
 421               (sb!disassem:disassemble-assem-segment *code-segment*
 422                                                      *compiler-trace-output*))
 423
 424             (etypecase *compile-object*
 425               (fasl-output
 426                (maybe-mumble "fasl")
 427                (fasl-dump-component component
 428                                     *code-segment*
 429                                     code-length
 430                                     trace-table
 431                                     fixups
 432                                     *compile-object*))
 433               (core-object
 434                (maybe-mumble "core")
 435                (make-core-component component
 436                                     *code-segment*
 437                                     code-length
 438                                     trace-table
 439                                     fixups
 440                                     *compile-object*))
 441               (null))))))
 442
 443   ;; We're done, so don't bother keeping anything around.
 444   (setf (component-info component) nil)
 445
 446   (/show "leaving %COMPILE-COMPONENT")
 447   (values))
 448
 449 ;;; Delete components with no external entry points before we try to
 450 ;;; generate code. Unreachable closures can cause IR2 conversion to
 451 ;;; puke on itself, since it is the reference to the closure which
 452 ;;; normally causes the components to be combined.
 453 (defun delete-if-no-entries (component)
 454   (dolist (fun (component-lambdas component) (delete-component component))
 455     (when (functional-has-external-references-p fun)
 456       (return))
 457     (case (functional-kind fun)
 458       (:top-level (return))
 459       (:external
 460        (unless (every (lambda (ref)
 461                         (eq (block-component (node-block ref))
 462                             component))
 463                       (leaf-refs fun))
 464          (return))))))
 465
 466 (defun compile-component (component)
 467   (let* ((*component-being-compiled* component))
 468     (when sb!xc:*compile-print*
 469       (compiler-mumble "~&; compiling ~A: " (component-name component)))
 470
 471     (ir1-phases component)
 472
 473     ;; FIXME: What is MAYBE-MUMBLE for? Do we need it any more?
 474     (maybe-mumble "env ")
 475     (physenv-analyze component)
 476     (dfo-as-needed component)
 477
 478     (delete-if-no-entries component)
 479
 480     (unless (eq (block-next (component-head component))
 481                 (component-tail component))
 482       (%compile-component component)))
 483
 484   (clear-constant-info)
 485
 486   (when sb!xc:*compile-print*
 487     (compiler-mumble "~&"))
 488
 489   (values))
 490 \f
 491 ;;;; clearing global data structures
 492 ;;;;
 493 ;;;; FIXME: Is it possible to get rid of this stuff, getting rid of
 494 ;;;; global data structures entirely when possible and consing up the
 495 ;;;; others from scratch instead of clearing and reusing them?
 496
 497 ;;; Clear the INFO in constants in the *FREE-VARIABLES*, etc. In
 498 ;;; addition to allowing stuff to be reclaimed, this is required for
 499 ;;; correct assignment of constant offsets, since we need to assign a
 500 ;;; new offset for each component. We don't clear the FUNCTIONAL-INFO
 501 ;;; slots, since they are used to keep track of functions across
 502 ;;; component boundaries.
 503 (defun clear-constant-info ()
 504   (maphash #'(lambda (k v)
 505                (declare (ignore k))
 506                (setf (leaf-info v) nil))
 507            *constants*)
 508   (maphash #'(lambda (k v)
 509                (declare (ignore k))
 510                (when (constant-p v)
 511                  (setf (leaf-info v) nil)))
 512            *free-variables*)
 513   (values))
 514
 515 ;;; Blow away the REFS for all global variables, and let COMPONENT
 516 ;;; be recycled.
 517 (defun clear-ir1-info (component)
 518   (declare (type component component))
 519   (labels ((blast (x)
 520              (maphash #'(lambda (k v)
 521                           (declare (ignore k))
 522                           (when (leaf-p v)
 523                             (setf (leaf-refs v)
 524                                   (delete-if #'here-p (leaf-refs v)))
 525                             (when (basic-var-p v)
 526                               (setf (basic-var-sets v)
 527                                     (delete-if #'here-p (basic-var-sets v))))))
 528                       x))
 529            (here-p (x)
 530              (eq (block-component (node-block x)) component)))
 531     (blast *free-variables*)
 532     (blast *free-functions*)
 533     (blast *constants*))
 534   (values))
 535
 536 ;;; Clear global variables used by the compiler.
 537 ;;;
 538 ;;; FIXME: It seems kinda nasty and unmaintainable to have to do this,
 539 ;;; and it adds overhead even when people aren't using the compiler.
 540 ;;; Perhaps we could make these global vars unbound except when
 541 ;;; actually in use, so that this function could go away.
 542 (defun clear-stuff (&optional (debug-too t))
 543
 544   ;; Clear global tables.
 545   (when (boundp '*free-functions*)
 546     (clrhash *free-functions*)
 547     (clrhash *free-variables*)
 548     (clrhash *constants*))
 549
 550   ;; Clear debug counters and tables.
 551   (clrhash *seen-blocks*)
 552   (clrhash *seen-functions*)
 553   (clrhash *list-conflicts-table*)
 554
 555   (when debug-too
 556     (clrhash *continuation-numbers*)
 557     (clrhash *number-continuations*)
 558     (setq *continuation-number* 0)
 559     (clrhash *tn-ids*)
 560     (clrhash *id-tns*)
 561     (setq *tn-id* 0)
 562     (clrhash *label-ids*)
 563     (clrhash *id-labels*)
 564     (setq *label-id* 0)
 565
 566     ;; Clear some PACK data structures (for GC purposes only).
 567     (aver (not *in-pack*))
 568     (dolist (sb *backend-sb-list*)
 569       (when (finite-sb-p sb)
 570         (fill (finite-sb-live-tns sb) nil))))
 571
 572   ;; (Note: The CMU CL code used to set CL::*GENSYM-COUNTER* to zero here.
 573   ;; Superficially, this seemed harmful -- the user could reasonably be
 574   ;; surprised if *GENSYM-COUNTER* turned back to zero when something was
 575   ;; compiled. A closer inspection showed that this actually turned out to be
 576   ;; harmless in practice, because CLEAR-STUFF was only called from within
 577   ;; forms which bound CL::*GENSYM-COUNTER* to zero. However, this means that
 578   ;; even though zeroing CL::*GENSYM-COUNTER* here turned out to be harmless in
 579   ;; practice, it was also useless in practice. So we don't do it any more.)
 580
 581   (values))
 582 \f
 583 ;;;; trace output
 584
 585 ;;; Print out some useful info about Component to Stream.
 586 (defun describe-component (component *standard-output*)
 587   (declare (type component component))
 588   (format t "~|~%;;;; component: ~S~2%" (component-name component))
 589   (print-blocks component)
 590   (values))
 591
 592 (defun describe-ir2-component (component *standard-output*)
 593   (format t "~%~|~%;;;; IR2 component: ~S~2%" (component-name component))
 594   (format t "entries:~%")
 595   (dolist (entry (ir2-component-entries (component-info component)))
 596     (format t "~4TL~D: ~S~:[~; [closure]~]~%"
 597             (label-id (entry-info-offset entry))
 598             (entry-info-name entry)
 599             (entry-info-closure-p entry)))
 600   (terpri)
 601   (pre-pack-tn-stats component *standard-output*)
 602   (terpri)
 603   (print-ir2-blocks component)
 604   (terpri)
 605   (values))
 606 \f
 607 ;;;; file reading
 608 ;;;;
 609 ;;;; When reading from a file, we have to keep track of some source
 610 ;;;; information. We also exploit our ability to back up for printing
 611 ;;;; the error context and for recovering from errors.
 612 ;;;;
 613 ;;;; The interface we provide to this stuff is the stream-oid
 614 ;;;; Source-Info structure. The bookkeeping is done as a side-effect
 615 ;;;; of getting the next source form.
 616
 617 ;;; A FILE-INFO structure holds all the source information for a
 618 ;;; given file.
 619 (defstruct (file-info (:copier nil))
 620   ;; If a file, the truename of the corresponding source file. If from
 621   ;; a Lisp form, :LISP. If from a stream, :STREAM.
 622   (name (required-argument) :type (or pathname (member :lisp :stream)))
 623   ;; the defaulted, but not necessarily absolute file name (i.e. prior
 624   ;; to TRUENAME call.) Null if not a file. This is used to set
 625   ;; *COMPILE-FILE-PATHNAME*, and if absolute, is dumped in the
 626   ;; debug-info.
 627   (untruename nil :type (or pathname null))
 628   ;; the file's write date (if relevant)
 629   (write-date nil :type (or unsigned-byte null))
 630   ;; the source path root number of the first form in this file (i.e.
 631   ;; the total number of forms converted previously in this
 632   ;; compilation)
 633   (source-root 0 :type unsigned-byte)
 634   ;; parallel vectors containing the forms read out of the file and
 635   ;; the file positions that reading of each form started at (i.e. the
 636   ;; end of the previous form)
 637   (forms (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t))
 638   (positions (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t)))
 639
 640 ;;; The SOURCE-INFO structure provides a handle on all the source
 641 ;;; information for an entire compilation.
 642 (defstruct (source-info
 643             #-no-ansi-print-object
 644             (:print-object (lambda (s stream)
 645                              (print-unreadable-object (s stream :type t))))
 646             (:copier nil))
 647   ;; the UT that compilation started at
 648   (start-time (get-universal-time) :type unsigned-byte)
 649   ;; the FILE-INFO structure for this compilation
 650   (file-info nil :type (or file-info null))
 651   ;; the stream that we are using to read the FILE-INFO, or NIL if
 652   ;; no stream has been opened yet
 653   (stream nil :type (or stream null)))
 654
 655 ;;; Given a pathname, return a SOURCE-INFO structure.
 656 (defun make-file-source-info (file)
 657   (let ((file-info (make-file-info :name (truename file)
 658                                    :untruename file
 659                                    :write-date (file-write-date file))))
 660
 661     (make-source-info :file-info file-info)))
 662
 663 ;;; Return a SOURCE-INFO to describe the incremental compilation of FORM.
 664 (defun make-lisp-source-info (form)
 665   (make-source-info :start-time (get-universal-time)
 666                     :file-info (make-file-info :name :lisp
 667                                                :forms (vector form)
 668                                                :positions '#(0))))
 669
 670 ;;; Return a SOURCE-INFO which will read from STREAM.
 671 (defun make-stream-source-info (stream)
 672   (let ((file-info (make-file-info :name :stream)))
 673     (make-source-info :file-info file-info
 674                       :stream stream)))
 675
 676 ;;; Return a form read from STREAM; or for EOF use the trick,
 677 ;;; popularized by Kent Pitman, of returning STREAM itself. If an
 678 ;;; error happens, then convert it to standard abort-the-compilation
 679 ;;; error condition (possibly recording some extra location
 680 ;;; information).
 681 (defun read-for-compile-file (stream position)
 682   (handler-case (read stream nil stream)
 683     (reader-error (condition)
 684      (error 'input-error-in-compile-file
 685             :error condition
 686             ;; We don't need to supply :POSITION here because
 687             ;; READER-ERRORs already know their position in the file.
 688             ))
 689     ;; ANSI, in its wisdom, says that READ should return END-OF-FILE
 690     ;; (and that this is not a READER-ERROR) when it encounters end of
 691     ;; file in the middle of something it's trying to read.
 692     (end-of-file (condition)
 693      (error 'input-error-in-compile-file
 694             :error condition
 695             ;; We need to supply :POSITION here because the END-OF-FILE
 696             ;; condition doesn't carry the position that the user
 697             ;; probably cares about, where the failed READ began.
 698             :position position))))
 699
 700 ;;; If STREAM is present, return it, otherwise open a stream to the
 701 ;;; current file. There must be a current file.
 702 ;;;
 703 ;;; FIXME: This is probably an unnecessarily roundabout way to do
 704 ;;; things now that we process a single file in COMPILE-FILE (unlike
 705 ;;; the old CMU CL code, which accepted multiple files). Also, the old
 706 ;;; comment said
 707 ;;;   When we open a new file, we also reset *PACKAGE* and policy.
 708 ;;;   This gives the effect of rebinding around each file.
 709 ;;; which doesn't seem to be true now. Check to make sure that if
 710 ;;; such rebinding is necessary, it's still done somewhere.
 711 (defun get-source-stream (info)
 712   (declare (type source-info info))
 713   (or (source-info-stream info)
 714       (let* ((file-info (source-info-file-info info))
 715              (name (file-info-name file-info)))
 716         (setf sb!xc:*compile-file-truename* name
 717               sb!xc:*compile-file-pathname* (file-info-untruename file-info)
 718               (source-info-stream info) (open name :direction :input)))))
 719
 720 ;;; Close the stream in INFO if it is open.
 721 (defun close-source-info (info)
 722   (declare (type source-info info))
 723   (let ((stream (source-info-stream info)))
 724     (when stream (close stream)))
 725   (setf (source-info-stream info) nil)
 726   (values))
 727
 728 ;;; Read and compile the source file.
 729 (defun sub-sub-compile-file (info)
 730   (let* ((file-info (source-info-file-info info))
 731          (stream (get-source-stream info)))
 732     (loop
 733      (let* ((pos (file-position stream))
 734             (form (read-for-compile-file stream pos)))
 735        (if (eq form stream) ; i.e., if EOF
 736            (return)
 737            (let* ((forms (file-info-forms file-info))
 738                   (current-idx (+ (fill-pointer forms)
 739                                   (file-info-source-root file-info))))
 740              (vector-push-extend form forms)
 741              (vector-push-extend pos (file-info-positions file-info))
 742              (find-source-paths form current-idx)
 743              (process-top-level-form form
 744                                      `(original-source-start 0 ,current-idx)
 745                                      nil)))))))
 746
 747 ;;; Return the INDEX'th source form read from INFO and the position
 748 ;;; where it was read.
 749 (defun find-source-root (index info)
 750   (declare (type index index) (type source-info info))
 751   (let ((file-info (source-info-file-info info)))
 752     (values (aref (file-info-forms file-info) index)
 753             (aref (file-info-positions file-info) index))))
 754 \f
 755 ;;;; top-level form processing
 756
 757 ;;; This is called by top-level form processing when we are ready to
 758 ;;; actually compile something. If *BLOCK-COMPILE* is T, then we still
 759 ;;; convert the form, but delay compilation, pushing the result on
 760 ;;; *TOP-LEVEL-LAMBDAS* instead.
 761 (defun convert-and-maybe-compile (form path)
 762   (declare (list path))
 763   (let* ((*lexenv* (make-lexenv :policy *policy*))
 764          (tll (ir1-top-level form path nil)))
 765     (cond ((eq *block-compile* t) (push tll *top-level-lambdas*))
 766           (t (compile-top-level (list tll) nil)))))
 767
 768 ;;; Macroexpand FORM in the current environment with an error handler.
 769 ;;; We only expand one level, so that we retain all the intervening
 770 ;;; forms in the source path.
 771 (defun preprocessor-macroexpand (form)
 772   (handler-case (sb!xc:macroexpand-1 form *lexenv*)
 773     (error (condition)
 774        (compiler-error "(during macroexpansion)~%~A" condition))))
 775
 776 ;;; Process a PROGN-like portion of a top-level form. FORMS is a list of
 777 ;;; the forms, and PATH is the source path of the FORM they came out of.
 778 ;;; COMPILE-TIME-TOO is as in ANSI "3.2.3.1 Processing of Top Level Forms".
 779 (defun process-top-level-progn (forms path compile-time-too)
 780   (declare (list forms) (list path))
 781   (dolist (form forms)
 782     (process-top-level-form form path compile-time-too)))
 783
 784 ;;; Process a top-level use of LOCALLY, or anything else (e.g.
 785 ;;; MACROLET) at top-level which has declarations and ordinary forms.
 786 ;;; We parse declarations and then recursively process the body.
 787 (defun process-top-level-locally (body path compile-time-too)
 788   (declare (list path))
 789   (multiple-value-bind (forms decls) (sb!sys:parse-body body nil)
 790     (let* ((*lexenv*
 791             (process-decls decls nil nil (make-continuation)))
 792            ;; Binding *POLICY* is pretty much of a hack, since it
 793            ;; causes LOCALLY to "capture" enclosed proclamations. It
 794            ;; is necessary because CONVERT-AND-MAYBE-COMPILE uses the
 795            ;; value of *POLICY* as the policy. The need for this hack
 796            ;; is due to the quirk that there is no way to represent in
 797            ;; a POLICY that an optimize quality came from the default.
 798            ;;
 799            ;; FIXME: Ideally, something should be done so that DECLAIM
 800            ;; inside LOCALLY works OK. Failing that, at least we could
 801            ;; issue a warning instead of silently screwing up.
 802            (*policy* (lexenv-policy *lexenv*)))
 803       (process-top-level-progn forms path compile-time-too))))
 804
 805 ;;; Parse an EVAL-WHEN situations list, returning three flags,
 806 ;;; (VALUES COMPILE-TOPLEVEL LOAD-TOPLEVEL EXECUTE), indicating
 807 ;;; the types of situations present in the list.
 808 (defun parse-eval-when-situations (situations)
 809   (when (or (not (listp situations))
 810             (set-difference situations
 811                             '(:compile-toplevel
 812                               compile
 813                               :load-toplevel
 814                               load
 815                               :execute
 816                               eval)))
 817     (compiler-error "bad EVAL-WHEN situation list: ~S" situations))
 818   (let ((deprecated-names (intersection situations '(compile load eval))))
 819     (when deprecated-names
 820       (style-warn "using deprecated EVAL-WHEN situation names~{ ~S~}"
 821                   deprecated-names)))
 822   (values (intersection '(:compile-toplevel compile)
 823                         situations)
 824           (intersection '(:load-toplevel load) situations)
 825           (intersection '(:execute eval) situations)))
 826
 827
 828 ;;; utilities for extracting COMPONENTs of FUNCTIONALs
 829 (defun clambda-component (clambda)
 830   (block-component (node-block (lambda-bind clambda))))
 831 (defun functional-components (f)
 832   (declare (type functional f))
 833   (etypecase f
 834     (clambda (list (clambda-component f)))
 835     (optional-dispatch (let ((result nil))
 836                          (labels ((frob (clambda)
 837                                     (pushnew (clambda-component clambda)
 838                                              result))
 839                                   (maybe-frob (maybe-clambda)
 840                                     (when maybe-clambda
 841                                       (frob maybe-clambda))))
 842                            (mapc #'frob (optional-dispatch-entry-points f))
 843                            (maybe-frob (optional-dispatch-more-entry f))
 844                            (maybe-frob (optional-dispatch-main-entry f)))))))
 845
 846 (defun make-functional-from-top-level-lambda (definition
 847                                               &key
 848                                               name
 849                                               (path
 850                                                ;; I'd thought NIL should
 851                                                ;; work, but it doesn't.
 852                                                ;; -- WHN 2001-09-20
 853                                                (required-argument)))
 854   (let* ((*current-path* path)
 855          (component (make-empty-component))
 856          (*current-component* component))
 857     (setf (component-name component)
 858           (format nil "~S initial component" name))
 859     (setf (component-kind component) :initial)
 860     (let* ((locall-fun (ir1-convert-lambda definition
 861                                            (format nil "locall ~S" name)))
 862            (fun (ir1-convert-lambda (make-xep-lambda locall-fun) name)))
 863       (setf (functional-entry-function fun) locall-fun
 864             (functional-kind fun) :external
 865             (functional-has-external-references-p fun) t)
 866       fun)))
 867
 868 ;;; Compile LAMBDA-EXPRESSION into *COMPILE-OBJECT*, returning a
 869 ;;; description of the result.
 870 ;;;   * If *COMPILE-OBJECT* is a CORE-OBJECT, then write the function
 871 ;;;     into core and return the compiled FUNCTION value.
 872 ;;;   * If *COMPILE-OBJECT* is a fasl file, then write the function
 873 ;;;     into the fasl file and return a dump handle.
 874 ;;;
 875 ;;; If NAME is provided, then we try to use it as the name of the
 876 ;;; function for debugging/diagnostic information.
 877 (defun %compile (lambda-expression
 878                  *compile-object*
 879                  &key
 880                  name
 881                  (path
 882                   ;; This magical idiom seems to be the appropriate
 883                   ;; path for compiling standalone LAMBDAs, judging
 884                   ;; from the CMU CL code and experiment, so it's a
 885                   ;; nice default for things where we don't have a
 886                   ;; real source path (as in e.g. inside CL:COMPILE).
 887                   '(original-source-start 0 0)))
 888   (/show "entering %COMPILE" name)
 889   (unless (or (null name) (legal-fun-name-p name))
 890     (error "not a legal function name: ~S" name))
 891   (let* ((*lexenv* (make-lexenv :policy *policy*))
 892          (fun (make-functional-from-top-level-lambda lambda-expression
 893                                                      :name name
 894                                                      :path path)))
 895
 896     (/noshow fun)
 897
 898     ;; FIXME: The compile-it code from here on is sort of a
 899     ;; twisted version of the code in COMPILE-TOP-LEVEL. It'd be
 900     ;; better to find a way to share the code there; or
 901     ;; alternatively, to use this code to replace the code there.
 902     ;; (The second alternative might be pretty easy if we used
 903     ;; the :LOCALL-ONLY option to IR1-FOR-LAMBDA. Then maybe the
 904     ;; whole FUNCTIONAL-KIND=:TOP-LEVEL case could go away..)
 905
 906     (/show "about to LOCAL-CALL-ANALYZE-UNTIL-DONE")
 907     (local-call-analyze-until-done (list fun))
 908
 909     (multiple-value-bind (components-from-dfo top-components hairy-top)
 910         (find-initial-dfo (list fun))
 911
 912       (let ((*all-components* (append components-from-dfo top-components)))
 913         (/noshow components-from-dfo top-components *all-components*)
 914         (mapc #'preallocate-physenvs-for-top-levelish-lambdas
 915               (append hairy-top top-components))
 916         (dolist (component-from-dfo components-from-dfo)
 917           (/show "compiling a COMPONENT-FROM-DFO")
 918           (compile-component component-from-dfo)
 919           (/show "about to REPLACE-TOP-LEVEL-XEPS")
 920           (replace-top-level-xeps component-from-dfo)))
 921
 922       (/show "about to go into PROG1")
 923       (prog1
 924           (let ((entry-table (etypecase *compile-object*
 925                                (fasl-output (fasl-output-entry-table
 926                                              *compile-object*))
 927                                (core-object (core-object-entry-table
 928                                              *compile-object*)))))
 929             (multiple-value-bind (result found-p)
 930                 (gethash (leaf-info fun) entry-table)
 931               (aver found-p)
 932               result))
 933         (mapc #'clear-ir1-info components-from-dfo)
 934         (clear-stuff)
 935         (/show "returning from %COMPILE")))))
 936
 937 (defun process-top-level-cold-fset (name lambda-expression path)
 938   (/show "entering PROCESS-TOP-LEVEL-COLD-FSET" name)
 939   (unless (producing-fasl-file)
 940     (error "can't COLD-FSET except in a fasl file"))
 941   (unless (legal-fun-name-p name)
 942     (error "not a legal function name: ~S" name))
 943   (fasl-dump-cold-fset name
 944                        (%compile lambda-expression
 945                                  *compile-object*
 946                                  :name name
 947                                  :path path)
 948                        *compile-object*)
 949   (/show "finished with PROCESS-TOP-LEVEL-COLD-FSET" name)
 950   (values))
 951
 952 ;;; Process a top-level FORM with the specified source PATH.
 953 ;;;  * If this is a magic top-level form, then do stuff.
 954 ;;;  * If this is a macro, then expand it.
 955 ;;;  * Otherwise, just compile it.
 956 ;;;
 957 ;;; COMPILE-TIME-TOO is as defined in ANSI
 958 ;;; "3.2.3.1 Processing of Top Level Forms".
 959 (defun process-top-level-form (form path compile-time-too)
 960
 961   (declare (list path))
 962
 963   (catch 'process-top-level-form-error-abort
 964     (let* ((path (or (gethash form *source-paths*) (cons form path)))
 965            (*compiler-error-bailout*
 966             (lambda ()
 967               (convert-and-maybe-compile
 968                `(error "execution of a form compiled with errors:~% ~S"
 969                        ',form)
 970                path)
 971               (throw 'process-top-level-form-error-abort nil))))
 972
 973       (if (atom form)
 974           ;; (There are no EVAL-WHEN issues in the ATOM case until
 975           ;; SBCL gets smart enough to handle global
 976           ;; DEFINE-SYMBOL-MACRO.)
 977           (convert-and-maybe-compile form path)
 978           (flet ((need-at-least-one-arg (form)
 979                    (unless (cdr form)
 980                      (compiler-error "~S form is too short: ~S"
 981                                      (car form)
 982                                      form))))
 983             (case (car form)
 984               ;; In the cross-compiler, top level COLD-FSET arranges
 985               ;; for static linking at cold init time.
 986               #+sb-xc-host
 987               ((cold-fset)
 988                (aver (not compile-time-too))
 989                (destructuring-bind (cold-fset fun-name lambda-expression) form
 990                  (declare (ignore cold-fset))
 991                  (process-top-level-cold-fset fun-name
 992                                               lambda-expression
 993                                               path)))
 994               ((eval-when macrolet symbol-macrolet);things w/ 1 arg before body
 995                (need-at-least-one-arg form)
 996                (destructuring-bind (special-operator magic &rest body) form
 997                  (ecase special-operator
 998                    ((eval-when)
 999                     ;; CT, LT, and E here are as in Figure 3-7 of ANSI
1000                     ;; "3.2.3.1 Processing of Top Level Forms".
1001                     (multiple-value-bind (ct lt e)
1002                         (parse-eval-when-situations magic)
1003                       (let ((new-compile-time-too (or ct
1004                                                       (and compile-time-too
1005                                                            e))))
1006                         (cond (lt (process-top-level-progn
1007                                    body path new-compile-time-too))
1008                               (new-compile-time-too (eval
1009                                                      `(progn ,@body)))))))
1010                    ((macrolet)
1011                     (funcall-in-macrolet-lexenv
1012                      magic
1013                      (lambda ()
1014                        (process-top-level-locally body
1015                                                   path
1016                                                   compile-time-too))))
1017                    ((symbol-macrolet)
1018                     (funcall-in-symbol-macrolet-lexenv
1019                      magic
1020                      (lambda ()
1021                        (process-top-level-locally body
1022                                                   path
1023                                                   compile-time-too)))))))
1024               ((locally)
1025                (process-top-level-locally (rest form) path compile-time-too))
1026               ((progn)
1027                (process-top-level-progn (rest form) path compile-time-too))
1028               ;; When we're cross-compiling, consider: what should we
1029               ;; do when we hit e.g.
1030               ;;   (EVAL-WHEN (:COMPILE-TOPLEVEL)
1031               ;;     (DEFUN FOO (X) (+ 7 X)))?
1032               ;; DEFUN has a macro definition in the cross-compiler,
1033               ;; and a different macro definition in the target
1034               ;; compiler. The only sensible thing is to use the
1035               ;; target compiler's macro definition, since the
1036               ;; cross-compiler's macro is in general into target
1037               ;; functions which can't meaningfully be executed at
1038               ;; cross-compilation time. So make sure we do the EVAL
1039               ;; here, before we macroexpand.
1040               ;;
1041               ;; Then things get even dicier with something like
1042               ;;   (DEFCONSTANT-EQX SB!XC:LAMBDA-LIST-KEYWORDS ..)
1043               ;; where we have to make sure that we don't uncross
1044               ;; the SB!XC: prefix before we do EVAL, because otherwise
1045               ;; we'd be trying to redefine the cross-compilation host's
1046               ;; constants.
1047               ;;
1048               ;; (Isn't it fun to cross-compile Common Lisp?:-)
1049               #+sb-xc-host
1050               (t
1051                (when compile-time-too
1052                  (eval form)) ; letting xc host EVAL do its own macroexpansion
1053                (let* (;; (We uncross the operator name because things
1054                       ;; like SB!XC:DEFCONSTANT and SB!XC:DEFTYPE
1055                       ;; should be equivalent to their CL: counterparts
1056                       ;; when being compiled as target code. We leave
1057                       ;; the rest of the form uncrossed because macros
1058                       ;; might yet expand into EVAL-WHEN stuff, and
1059                       ;; things inside EVAL-WHEN can't be uncrossed
1060                       ;; until after we've EVALed them in the
1061                       ;; cross-compilation host.)
1062                       (slightly-uncrossed (cons (uncross (first form))
1063                                                 (rest form)))
1064                       (expanded (preprocessor-macroexpand slightly-uncrossed)))
1065                  (if (eq expanded slightly-uncrossed)
1066                      ;; (Now that we're no longer processing toplevel
1067                      ;; forms, and hence no longer need to worry about
1068                      ;; EVAL-WHEN, we can uncross everything.)
1069                      (convert-and-maybe-compile expanded path)
1070                      ;; (We have to demote COMPILE-TIME-TOO to NIL
1071                      ;; here, no matter what it was before, since
1072                      ;; otherwise we'd tend to EVAL subforms more than
1073                      ;; once, because of WHEN COMPILE-TIME-TOO form
1074                      ;; above.)
1075                      (process-top-level-form expanded path nil))))
1076               ;; When we're not cross-compiling, we only need to
1077               ;; macroexpand once, so we can follow the 1-thru-6
1078               ;; sequence of steps in ANSI's "3.2.3.1 Processing of
1079               ;; Top Level Forms".
1080               #-sb-xc-host
1081               (t
1082                (let ((expanded (preprocessor-macroexpand form)))
1083                  (cond ((eq expanded form)
1084                         (when compile-time-too
1085                           (eval form))
1086                         (convert-and-maybe-compile form path))
1087                        (t
1088                         (process-top-level-form expanded
1089                                                 path
1090                                                 compile-time-too))))))))))
1091
1092   (values))
1093 \f
1094 ;;;; load time value support
1095 ;;;;
1096 ;;;; (See EMIT-MAKE-LOAD-FORM.)
1097
1098 ;;; Return T if we are currently producing a fasl file and hence
1099 ;;; constants need to be dumped carefully.
1100 (defun producing-fasl-file ()
1101   (fasl-output-p *compile-object*))
1102
1103 ;;; Compile FORM and arrange for it to be called at load-time. Return
1104 ;;; the dumper handle and our best guess at the type of the object.
1105 (defun compile-load-time-value
1106        (form &optional
1107              (name (let ((*print-level* 2) (*print-length* 3))
1108                      (format nil "load time value of ~S"
1109                              (if (and (listp form)
1110                                       (eq (car form) 'make-value-cell))
1111                                  (second form)
1112                                  form)))))
1113   (let ((lambda (compile-load-time-stuff form name t)))
1114     (values
1115      (fasl-dump-load-time-value-lambda lambda *compile-object*)
1116      (let ((type (leaf-type lambda)))
1117        (if (fun-type-p type)
1118            (single-value-type (fun-type-returns type))
1119            *wild-type*)))))
1120
1121 ;;; Compile the FORMS and arrange for them to be called (for effect,
1122 ;;; not value) at load time.
1123 (defun compile-make-load-form-init-forms (forms name)
1124   (let ((lambda (compile-load-time-stuff `(progn ,@forms) name nil)))
1125     (fasl-dump-top-level-lambda-call lambda *compile-object*)))
1126
1127 ;;; Does the actual work of COMPILE-LOAD-TIME-VALUE or
1128 ;;; COMPILE-MAKE-LOAD-FORM- INIT-FORMS.
1129 (defun compile-load-time-stuff (form name for-value)
1130   (with-ir1-namespace
1131    (let* ((*lexenv* (make-null-lexenv))
1132           (lambda (ir1-top-level form *current-path* for-value)))
1133      (setf (leaf-name lambda) name)
1134      (compile-top-level (list lambda) t)
1135      lambda)))
1136
1137 ;;; This is called by COMPILE-TOP-LEVEL when it was passed T for
1138 ;;; LOAD-TIME-VALUE-P (which happens in COMPILE-LOAD-TIME-STUFF). We
1139 ;;; don't try to combine this component with anything else and frob
1140 ;;; the name. If not in a :TOP-LEVEL component, then don't bother
1141 ;;; compiling, because it was merged with a run-time component.
1142 (defun compile-load-time-value-lambda (lambdas)
1143   (aver (null (cdr lambdas)))
1144   (let* ((lambda (car lambdas))
1145          (component (block-component (node-block (lambda-bind lambda)))))
1146     (when (eql (component-kind component) :top-level)
1147       (setf (component-name component) (leaf-name lambda))
1148       (compile-component component)
1149       (clear-ir1-info component))))
1150 \f
1151 ;;;; COMPILE-FILE
1152
1153 ;;; We build a list of top-level lambdas, and then periodically smash
1154 ;;; them together into a single component and compile it.
1155 (defvar *pending-top-level-lambdas*)
1156
1157 ;;; The maximum number of top-level lambdas we put in a single
1158 ;;; top-level component.
1159 ;;;
1160 ;;; CMU CL 18b used this nontrivially by default (setting it to 10)
1161 ;;; but consequently suffered from the inability to execute some
1162 ;;; troublesome constructs correctly, e.g. inability to load a fasl
1163 ;;; file compiled from the source file
1164 ;;;   (defpackage "FOO" (:use "CL"))
1165 ;;;   (print 'foo::bar)
1166 ;;; because it would dump data-setup fops (including a FOP-PACKAGE for
1167 ;;; "FOO") for the second form before dumping the the code in the
1168 ;;; first form, or the fop to execute the code in the first form. By
1169 ;;; setting this value to 0 by default, we avoid this badness. This
1170 ;;; increases the number of toplevel form functions, and so increases
1171 ;;; the size of object files.
1172 ;;;
1173 ;;; The variable is still supported because when we are compiling the
1174 ;;; SBCL system itself, which is known not contain any troublesome
1175 ;;; constructs, we can set it to a nonzero value, which reduces the
1176 ;;; number of toplevel form objects, reducing the peak memory usage in
1177 ;;; GENESIS, which is desirable, since at least for SBCL version
1178 ;;; 0.6.7, this is the high water mark for memory usage during system
1179 ;;; construction.
1180 (defparameter *top-level-lambda-max* 0)
1181
1182 (defun object-call-top-level-lambda (tll)
1183   (declare (type functional tll))
1184   (let ((object *compile-object*))
1185     (etypecase object
1186       (fasl-output
1187        (fasl-dump-top-level-lambda-call tll object))
1188       (core-object
1189        (core-call-top-level-lambda tll object))
1190       (null))))
1191
1192 ;;; Add LAMBDAS to the pending lambdas. If this leaves more than
1193 ;;; *TOP-LEVEL-LAMBDA-MAX* lambdas in the list, or if FORCE-P is true,
1194 ;;; then smash the lambdas into a single component, compile it, and
1195 ;;; call the resulting function.
1196 (defun sub-compile-top-level-lambdas (lambdas force-p)
1197   (declare (list lambdas))
1198   (setq *pending-top-level-lambdas*
1199         (append *pending-top-level-lambdas* lambdas))
1200   (let ((pending *pending-top-level-lambdas*))
1201     (when (and pending
1202                (or (> (length pending) *top-level-lambda-max*)
1203                    force-p))
1204       (multiple-value-bind (component tll) (merge-top-level-lambdas pending)
1205         (setq *pending-top-level-lambdas* ())
1206         (compile-component component)
1207         (clear-ir1-info component)
1208         (object-call-top-level-lambda tll))))
1209   (values))
1210
1211 ;;; Compile top-level code and call the top-level lambdas. We pick off
1212 ;;; top-level lambdas in non-top-level components here, calling
1213 ;;; SUB-c-t-l-l on each subsequence of normal top-level lambdas.
1214 (defun compile-top-level-lambdas (lambdas force-p)
1215   (declare (list lambdas))
1216   (let ((len (length lambdas)))
1217     (flet ((loser (start)
1218              (or (position-if (lambda (x)
1219                                 (not (eq (component-kind
1220                                           (block-component
1221                                            (node-block
1222                                             (lambda-bind x))))
1223                                          :top-level)))
1224                               lambdas
1225                               :start start)
1226                  len)))
1227       (do* ((start 0 (1+ loser))
1228             (loser (loser start) (loser start)))
1229            ((>= start len)
1230             (when force-p
1231               (sub-compile-top-level-lambdas nil t)))
1232         (sub-compile-top-level-lambdas (subseq lambdas start loser)
1233                                        (or force-p (/= loser len)))
1234         (unless (= loser len)
1235           (object-call-top-level-lambda (elt lambdas loser))))))
1236   (values))
1237
1238 ;;; Compile LAMBDAS (a list of CLAMBDAs for top-level forms) into the
1239 ;;; object file.
1240 ;;;
1241 ;;; LOAD-TIME-VALUE-P seems to control whether it's MAKE-LOAD-FORM and
1242 ;;; COMPILE-LOAD-TIME-VALUE stuff. -- WHN 20000201
1243 (defun compile-top-level (lambdas load-time-value-p)
1244   (declare (list lambdas))
1245
1246   (maybe-mumble "locall ")
1247   (local-call-analyze-until-done lambdas)
1248
1249   (maybe-mumble "IDFO ")
1250   (multiple-value-bind (components top-components hairy-top)
1251       (find-initial-dfo lambdas)
1252     (let ((*all-components* (append components top-components))
1253           (top-level-closure nil))
1254       (when *check-consistency*
1255         (maybe-mumble "[check]~%")
1256         (check-ir1-consistency *all-components*))
1257
1258       (dolist (component (append hairy-top top-components))
1259         (when (pre-physenv-analyze-top-level component)
1260           (setq top-level-closure t)))
1261
1262       (dolist (component components)
1263         (compile-component component)
1264         (when (replace-top-level-xeps component)
1265           (setq top-level-closure t)))
1266
1267       (when *check-consistency*
1268         (maybe-mumble "[check]~%")
1269         (check-ir1-consistency *all-components*))
1270
1271       (if load-time-value-p
1272           (compile-load-time-value-lambda lambdas)
1273           (compile-top-level-lambdas lambdas top-level-closure))
1274
1275       (mapc #'clear-ir1-info components)
1276       (clear-stuff)))
1277   (values))
1278
1279 ;;; Actually compile any stuff that has been queued up for block
1280 ;;; compilation.
1281 (defun finish-block-compilation ()
1282   (when *block-compile*
1283     (when *top-level-lambdas*
1284       (compile-top-level (nreverse *top-level-lambdas*) nil)
1285       (setq *top-level-lambdas* ()))
1286     (setq *block-compile* nil)
1287     (setq *entry-points* nil)))
1288
1289 ;;; Read all forms from INFO and compile them, with output to OBJECT.
1290 ;;; Return (VALUES NIL WARNINGS-P FAILURE-P).
1291 (defun sub-compile-file (info)
1292   (declare (type source-info info))
1293   (let* ((*block-compile* *block-compile-argument*)
1294          (*package* (sane-package))
1295          (*policy* *policy*)
1296          (*lexenv* (make-null-lexenv))
1297          (*source-info* info)
1298          (sb!xc:*compile-file-pathname* nil)
1299          (sb!xc:*compile-file-truename* nil)
1300          (*top-level-lambdas* ())
1301          (*pending-top-level-lambdas* ())
1302          (*compiler-error-bailout*
1303           (lambda ()
1304             (compiler-mumble "~2&; fatal error, aborting compilation~%")
1305             (return-from sub-compile-file (values nil t t))))
1306          (*current-path* nil)
1307          (*last-source-context* nil)
1308          (*last-original-source* nil)
1309          (*last-source-form* nil)
1310          (*last-format-string* nil)
1311          (*last-format-args* nil)
1312          (*last-message-count* 0)
1313          ;; FIXME: Do we need this rebinding here? It's a literal
1314          ;; translation of the old CMU CL rebinding to
1315          ;; (OR *BACKEND-INFO-ENVIRONMENT* *INFO-ENVIRONMENT*),
1316          ;; and it's not obvious whether the rebinding to itself is
1317          ;; needed that SBCL doesn't need *BACKEND-INFO-ENVIRONMENT*.
1318          (*info-environment* *info-environment*)
1319          (*gensym-counter* 0))
1320     (handler-case
1321         (with-compilation-values
1322          (sb!xc:with-compilation-unit ()
1323            (clear-stuff)
1324
1325            (sub-sub-compile-file info)
1326
1327            (finish-block-compilation)
1328            (compile-top-level-lambdas () t)
1329            (let ((object *compile-object*))
1330              (etypecase object
1331                (fasl-output (fasl-dump-source-info info object))
1332                (core-object (fix-core-source-info info object))
1333                (null)))
1334            nil))
1335       ;; Some errors are sufficiently bewildering that we just fail
1336       ;; immediately, without trying to recover and compile more of
1337       ;; the input file.
1338       (input-error-in-compile-file (condition)
1339        (format *error-output*
1340                "~@<compilation aborted because of input error: ~2I~_~A~:>"
1341                condition)
1342        (values nil t t)))))
1343
1344 ;;; Return a pathname for the named file. The file must exist.
1345 (defun verify-source-file (pathname-designator)
1346   (let* ((pathname (pathname pathname-designator))
1347          (default-host (make-pathname :host (pathname-host pathname))))
1348     (flet ((try-with-type (path type error-p)
1349              (let ((new (merge-pathnames
1350                          path (make-pathname :type type
1351                                              :defaults default-host))))
1352                (if (probe-file new)
1353                    new
1354                    (and error-p (truename new))))))
1355       (cond ((typep pathname 'logical-pathname)
1356              (try-with-type pathname "LISP" t))
1357             ((probe-file pathname) pathname)
1358             ((try-with-type pathname "lisp"  nil))
1359             ((try-with-type pathname "lisp"  t))))))
1360
1361 (defun elapsed-time-to-string (tsec)
1362   (multiple-value-bind (tmin sec) (truncate tsec 60)
1363     (multiple-value-bind (thr min) (truncate tmin 60)
1364       (format nil "~D:~2,'0D:~2,'0D" thr min sec))))
1365
1366 ;;; Print some junk at the beginning and end of compilation.
1367 (defun start-error-output (source-info)
1368   (declare (type source-info source-info))
1369   (let ((file-info (source-info-file-info source-info)))
1370     (compiler-mumble "~&; compiling file ~S (written ~A):~%"
1371                      (namestring (file-info-name file-info))
1372                      (sb!int:format-universal-time nil
1373                                                    (file-info-write-date
1374                                                     file-info)
1375                                                    :style :government
1376                                                    :print-weekday nil
1377                                                    :print-timezone nil)))
1378   (values))
1379 (defun finish-error-output (source-info won)
1380   (declare (type source-info source-info))
1381   (compiler-mumble "~&; compilation ~:[aborted after~;finished in~] ~A~&"
1382                    won
1383                    (elapsed-time-to-string
1384                     (- (get-universal-time)
1385                        (source-info-start-time source-info))))
1386   (values))
1387
1388 ;;; Open some files and call SUB-COMPILE-FILE. If something unwinds
1389 ;;; out of the compile, then abort the writing of the output file, so
1390 ;;; that we don't overwrite it with known garbage.
1391 (defun sb!xc:compile-file
1392     (input-file
1393      &key
1394
1395      ;; ANSI options
1396      (output-file (cfp-output-file-default input-file))
1397      ;; FIXME: ANSI doesn't seem to say anything about
1398      ;; *COMPILE-VERBOSE* and *COMPILE-PRINT* being rebound by this
1399      ;; function..
1400      ((:verbose sb!xc:*compile-verbose*) sb!xc:*compile-verbose*)
1401      ((:print sb!xc:*compile-print*) sb!xc:*compile-print*)
1402      (external-format :default)
1403
1404      ;; extensions
1405      (trace-file nil)
1406      ((:block-compile *block-compile-argument*) nil))
1407
1408   #!+sb-doc
1409   "Compile INPUT-FILE, producing a corresponding fasl file and returning
1410    its filename. Besides the ANSI &KEY arguments :OUTPUT-FILE, :VERBOSE,
1411    :PRINT, and :EXTERNAL-FORMAT,the following extensions are supported:
1412      :TRACE-FILE
1413         If given, internal data structures are dumped to the specified
1414         file, or if a value of T is given, to a file of *.trace type
1415         derived from the input file name.
1416    Also, as a workaround for vaguely-non-ANSI behavior, the :BLOCK-COMPILE
1417    argument is quasi-supported, to determine whether multiple
1418    functions are compiled together as a unit, resolving function
1419    references at compile time. NIL means that global function names
1420    are never resolved at compilation time. Currently NIL is the
1421    default behavior, because although section 3.2.2.3, \"Semantic
1422    Constraints\", of the ANSI spec allows this behavior under all
1423    circumstances, the compiler's runtime scales badly when it
1424    tries to do this for large files. If/when this performance
1425    problem is fixed, the block compilation default behavior will
1426    probably be made dependent on the SPEED and COMPILATION-SPEED
1427    optimization values, and the :BLOCK-COMPILE argument will probably
1428    become deprecated."
1429
1430   (unless (eq external-format :default)
1431     (error "Non-:DEFAULT EXTERNAL-FORMAT values are not supported."))
1432   (let* ((fasl-output nil)
1433          (output-file-name nil)
1434          (compile-won nil)
1435          (warnings-p nil)
1436          (failure-p t) ; T in case error keeps this from being set later
1437          (input-pathname (verify-source-file input-file))
1438          (source-info (make-file-source-info input-pathname))
1439          (*compiler-trace-output* nil)) ; might be modified below
1440
1441     (unwind-protect
1442         (progn
1443           (when output-file
1444             (setq output-file-name
1445                   (sb!xc:compile-file-pathname input-file
1446                                                :output-file output-file))
1447             (setq fasl-output
1448                   (open-fasl-output output-file-name
1449                                     (namestring input-pathname))))
1450           (when trace-file
1451             (let* ((default-trace-file-pathname
1452                      (make-pathname :type "trace" :defaults input-pathname))
1453                    (trace-file-pathname
1454                     (if (eql trace-file t)
1455                         default-trace-file-pathname
1456                         (merge-pathnames trace-file
1457                                          default-trace-file-pathname))))
1458               (setf *compiler-trace-output*
1459                     (open trace-file-pathname
1460                           :if-exists :supersede
1461                           :direction :output))))
1462
1463           (when sb!xc:*compile-verbose*
1464             (start-error-output source-info))
1465           (let ((*compile-object* fasl-output)
1466                 dummy)
1467             (multiple-value-setq (dummy warnings-p failure-p)
1468               (sub-compile-file source-info)))
1469           (setq compile-won t))
1470
1471       (close-source-info source-info)
1472
1473       (when fasl-output
1474         (close-fasl-output fasl-output (not compile-won))
1475         (setq output-file-name
1476               (pathname (fasl-output-stream fasl-output)))
1477         (when (and compile-won sb!xc:*compile-verbose*)
1478           (compiler-mumble "~2&; ~A written~%" (namestring output-file-name))))
1479
1480       (when sb!xc:*compile-verbose*
1481         (finish-error-output source-info compile-won))
1482
1483       (when *compiler-trace-output*
1484         (close *compiler-trace-output*)))
1485
1486     (values (if output-file
1487                 ;; Hack around filesystem race condition...
1488                 (or (probe-file output-file-name) output-file-name)
1489                 nil)
1490             warnings-p
1491             failure-p)))
1492 \f
1493 ;;; a helper function for COMPILE-FILE-PATHNAME: the default for
1494 ;;; the OUTPUT-FILE argument
1495 ;;;
1496 ;;; ANSI: The defaults for the OUTPUT-FILE are taken from the pathname
1497 ;;; that results from merging the INPUT-FILE with the value of
1498 ;;; *DEFAULT-PATHNAME-DEFAULTS*, except that the type component should
1499 ;;; default to the appropriate implementation-defined default type for
1500 ;;; compiled files.
1501 (defun cfp-output-file-default (input-file)
1502   (let* ((defaults (merge-pathnames input-file *default-pathname-defaults*))
1503          (retyped (make-pathname :type *fasl-file-type* :defaults defaults)))
1504     retyped))
1505
1506 ;;; KLUDGE: Part of the ANSI spec for this seems contradictory:
1507 ;;;   If INPUT-FILE is a logical pathname and OUTPUT-FILE is unsupplied,
1508 ;;;   the result is a logical pathname. If INPUT-FILE is a logical
1509 ;;;   pathname, it is translated into a physical pathname as if by
1510 ;;;   calling TRANSLATE-LOGICAL-PATHNAME.
1511 ;;; So I haven't really tried to make this precisely ANSI-compatible
1512 ;;; at the level of e.g. whether it returns logical pathname or a
1513 ;;; physical pathname. Patches to make it more correct are welcome.
1514 ;;; -- WHN 2000-12-09
1515 (defun sb!xc:compile-file-pathname (input-file
1516                                     &key
1517                                     (output-file (cfp-output-file-default
1518                                                   input-file))
1519                                     &allow-other-keys)
1520   #!+sb-doc
1521   "Return a pathname describing what file COMPILE-FILE would write to given
1522    these arguments."
1523   (pathname output-file))
1524 \f
1525 ;;;; MAKE-LOAD-FORM stuff
1526
1527 ;;; The entry point for MAKE-LOAD-FORM support. When IR1 conversion
1528 ;;; finds a constant structure, it invokes this to arrange for proper
1529 ;;; dumping. If it turns out that the constant has already been
1530 ;;; dumped, then we don't need to do anything.
1531 ;;;
1532 ;;; If the constant hasn't been dumped, then we check to see whether
1533 ;;; we are in the process of creating it. We detect this by
1534 ;;; maintaining the special *CONSTANTS-BEING-CREATED* as a list of all
1535 ;;; the constants we are in the process of creating. Actually, each
1536 ;;; entry is a list of the constant and any init forms that need to be
1537 ;;; processed on behalf of that constant.
1538 ;;;
1539 ;;; It's not necessarily an error for this to happen. If we are
1540 ;;; processing the init form for some object that showed up *after*
1541 ;;; the original reference to this constant, then we just need to
1542 ;;; defer the processing of that init form. To detect this, we
1543 ;;; maintain *CONSTANTS-CREATED-SINCE-LAST-INIT* as a list of the
1544 ;;; constants created since the last time we started processing an
1545 ;;; init form. If the constant passed to emit-make-load-form shows up
1546 ;;; in this list, then there is a circular chain through creation
1547 ;;; forms, which is an error.
1548 ;;;
1549 ;;; If there is some intervening init form, then we blow out of
1550 ;;; processing it by throwing to the tag PENDING-INIT. The value we
1551 ;;; throw is the entry from *CONSTANTS-BEING-CREATED*. This is so the
1552 ;;; offending init form can be tacked onto the init forms for the
1553 ;;; circular object.
1554 ;;;
1555 ;;; If the constant doesn't show up in *CONSTANTS-BEING-CREATED*, then
1556 ;;; we have to create it. We call MAKE-LOAD-FORM and check to see
1557 ;;; whether the creation form is the magic value
1558 ;;; :JUST-DUMP-IT-NORMALLY. If it is, then we don't do anything. The
1559 ;;; dumper will eventually get its hands on the object and use the
1560 ;;; normal structure dumping noise on it.
1561 ;;;
1562 ;;; Otherwise, we bind *CONSTANTS-BEING-CREATED* and
1563 ;;; *CONSTANTS-CREATED-SINCE- LAST-INIT* and compile the creation form
1564 ;;; much the way LOAD-TIME-VALUE does. When this finishes, we tell the
1565 ;;; dumper to use that result instead whenever it sees this constant.
1566 ;;;
1567 ;;; Now we try to compile the init form. We bind
1568 ;;; *CONSTANTS-CREATED-SINCE-LAST-INIT* to NIL and compile the init
1569 ;;; form (and any init forms that were added because of circularity
1570 ;;; detection). If this works, great. If not, we add the init forms to
1571 ;;; the init forms for the object that caused the problems and let it
1572 ;;; deal with it.
1573 (defvar *constants-being-created* nil)
1574 (defvar *constants-created-since-last-init* nil)
1575 ;;; FIXME: Shouldn't these^ variables be bound in LET forms?
1576 (defun emit-make-load-form (constant)
1577   (aver (fasl-output-p *compile-object*))
1578   (unless (or (fasl-constant-already-dumped-p constant *compile-object*)
1579               ;; KLUDGE: This special hack is because I was too lazy
1580               ;; to rework DEF!STRUCT so that the MAKE-LOAD-FORM
1581               ;; function of LAYOUT returns nontrivial forms when
1582               ;; building the cross-compiler but :IGNORE-IT when
1583               ;; cross-compiling or running under the target Lisp. --
1584               ;; WHN 19990914
1585               #+sb-xc-host (typep constant 'layout))
1586     (let ((circular-ref (assoc constant *constants-being-created* :test #'eq)))
1587       (when circular-ref
1588         (when (find constant *constants-created-since-last-init* :test #'eq)
1589           (throw constant t))
1590         (throw 'pending-init circular-ref)))
1591     (multiple-value-bind (creation-form init-form)
1592         (handler-case
1593             (sb!xc:make-load-form constant (make-null-lexenv))
1594           (error (condition)
1595                  (compiler-error "(while making load form for ~S)~%~A"
1596                                  constant
1597                                  condition)))
1598       (case creation-form
1599         (:just-dump-it-normally
1600          (fasl-validate-structure constant *compile-object*)
1601          t)
1602         (:ignore-it
1603          nil)
1604         (t
1605          (compile-top-level-lambdas () t)
1606          (when (fasl-constant-already-dumped-p constant *compile-object*)
1607            (return-from emit-make-load-form nil))
1608          (let* ((name (let ((*print-level* 1) (*print-length* 2))
1609                         (with-output-to-string (stream)
1610                           (write constant :stream stream))))
1611                 (info (if init-form
1612                           (list constant name init-form)
1613                           (list constant))))
1614            (let ((*constants-being-created*
1615                   (cons info *constants-being-created*))
1616                  (*constants-created-since-last-init*
1617                   (cons constant *constants-created-since-last-init*)))
1618              (when
1619                  (catch constant
1620                    (fasl-note-handle-for-constant
1621                     constant
1622                     (compile-load-time-value
1623                      creation-form
1624                      (format nil "creation form for ~A" name))
1625                     *compile-object*)
1626                    nil)
1627                (compiler-error "circular references in creation form for ~S"
1628                                constant)))
1629            (when (cdr info)
1630              (let* ((*constants-created-since-last-init* nil)
1631                     (circular-ref
1632                      (catch 'pending-init
1633                        (loop for (name form) on (cdr info) by #'cddr
1634                          collect name into names
1635                          collect form into forms
1636                          finally
1637                          (compile-make-load-form-init-forms
1638                           forms
1639                           (format nil "init form~:[~;s~] for ~{~A~^, ~}"
1640                                   (cdr forms) names)))
1641                        nil)))
1642                (when circular-ref
1643                  (setf (cdr circular-ref)
1644                        (append (cdr circular-ref) (cdr info))))))))))))