src/compiler/main.lisp

   1 ;;;; the top-level interfaces to the compiler
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13
  14 ;;; FIXME: Doesn't this belong somewhere else, like early-c.lisp?
  15 (declaim (special *constants* *free-variables* *component-being-compiled*
  16                   *code-vector* *next-location* *result-fixups*
  17                   *free-functions* *source-paths*
  18                   *seen-blocks* *seen-functions* *list-conflicts-table*
  19                   *continuation-number* *continuation-numbers*
  20                   *number-continuations* *tn-id* *tn-ids* *id-tns*
  21                   *label-ids* *label-id* *id-labels*
  22                   *undefined-warnings* *compiler-error-count*
  23                   *compiler-warning-count* *compiler-style-warning-count*
  24                   *compiler-note-count*
  25                   *compiler-error-bailout*
  26                   #!+sb-show *compiler-trace-output*
  27                   *last-source-context* *last-original-source*
  28                   *last-source-form* *last-format-string* *last-format-args*
  29                   *last-message-count* *lexenv*))
  30
  31 (defvar *byte-compile-default* :maybe
  32   #!+sb-doc
  33   "the default value for the :BYTE-COMPILE argument to COMPILE-FILE")
  34
  35 (defvar *byte-compile-top-level*
  36   #-sb-xc-host t
  37   #+sb-xc-host nil ; since the byte compiler isn't supported in cross-compiler
  38   #!+sb-doc
  39   "Similar to *BYTE-COMPILE-DEFAULT*, but controls the compilation of top-level
  40    forms (evaluated at load-time) when the :BYTE-COMPILE argument is :MAYBE
  41    (the default.)  When true, we decide to byte-compile.")
  42
  43 ;;; default value of the :BYTE-COMPILE argument to the compiler
  44 (defvar *byte-compile* :maybe)
  45
  46 ;;; Bound by COMPILE-COMPONENT to T when byte-compiling, and NIL when
  47 ;;; native compiling. During IR1 conversion this can also be :MAYBE,
  48 ;;; in which case we must look at the policy, see (byte-compiling).
  49 (defvar *byte-compiling* :maybe)
  50 (declaim (type (member t nil :maybe) *byte-compile* *byte-compiling*
  51                *byte-compile-default*))
  52
  53 (defvar *check-consistency* nil)
  54 (defvar *all-components*)
  55
  56 ;;; Bind this to a stream to capture various internal debugging output.
  57 #!+sb-show
  58 (defvar *compiler-trace-output* nil)
  59
  60 ;;; The current block compilation state. These are initialized to the
  61 ;;; :BLOCK-COMPILE and :ENTRY-POINTS arguments that COMPILE-FILE was
  62 ;;; called with.
  63 ;;;
  64 ;;; *BLOCK-COMPILE-ARGUMENT* holds the original value of the
  65 ;;; :BLOCK-COMPILE argument, which overrides any internal
  66 ;;; declarations.
  67 (defvar *block-compile*)
  68 (defvar *block-compile-argument*)
  69 (declaim (type (member nil t :specified)
  70                *block-compile* *block-compile-argument*))
  71 (defvar *entry-points*)
  72 (declaim (list *entry-points*))
  73
  74 ;;; When block compiling, used by PROCESS-FORM to accumulate top-level
  75 ;;; lambdas resulting from compiling subforms. (In reverse order.)
  76 (defvar *top-level-lambdas*)
  77 (declaim (list *top-level-lambdas*))
  78
  79 (defvar sb!xc:*compile-verbose* t
  80   #!+sb-doc
  81   "The default for the :VERBOSE argument to COMPILE-FILE.")
  82 (defvar sb!xc:*compile-print* t
  83   #!+sb-doc
  84   "The default for the :PRINT argument to COMPILE-FILE.")
  85 (defvar *compile-progress* nil
  86   #!+sb-doc
  87   "When this is true, the compiler prints to *ERROR-OUTPUT* progress
  88   information about the phases of compilation of each function. (This
  89   is useful mainly in large block compilations.)")
  90
  91 (defvar sb!xc:*compile-file-pathname* nil
  92   #!+sb-doc
  93   "The defaulted pathname of the file currently being compiled, or NIL if not
  94   compiling.")
  95 (defvar sb!xc:*compile-file-truename* nil
  96   #!+sb-doc
  97   "The TRUENAME of the file currently being compiled, or NIL if not
  98   compiling.")
  99
 100 (declaim (type (or pathname null)
 101                sb!xc:*compile-file-pathname*
 102                sb!xc:*compile-file-truename*))
 103
 104 ;;; the values of *PACKAGE* and policy when compilation started
 105 (defvar *initial-package*)
 106 (defvar *initial-cookie*)
 107 (defvar *initial-interface-cookie*)
 108
 109 ;;; The source-info structure for the current compilation. This is null
 110 ;;; globally to indicate that we aren't currently in any identifiable
 111 ;;; compilation.
 112 (defvar *source-info* nil)
 113
 114 ;;; True if we are within a WITH-COMPILATION-UNIT form (which normally
 115 ;;; causes nested uses to be no-ops).
 116 (defvar *in-compilation-unit* nil)
 117
 118 ;;; Count of the number of compilation units dynamically enclosed by
 119 ;;; the current active WITH-COMPILATION-UNIT that were unwound out of.
 120 (defvar *aborted-compilation-unit-count*)
 121
 122 ;;; Mumble conditional on *COMPILE-PROGRESS*.
 123 (defun maybe-mumble (&rest foo)
 124   (when *compile-progress*
 125     ;; MNA: compiler message patch
 126     (compiler-mumble "~&")
 127     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 128        (apply #'compiler-mumble foo))))
 129
 130 (deftype object () '(or fasl-file core-object null))
 131
 132 (defvar *compile-object* nil)
 133 (declaim (type object *compile-object*))
 134 \f
 135 ;;;; WITH-COMPILATION-UNIT and WITH-COMPILATION-VALUES
 136
 137 (defmacro sb!xc:with-compilation-unit (options &body body)
 138   #!+sb-doc
 139   "WITH-COMPILATION-UNIT ({Key Value}*) Form*
 140   This form affects compilations that take place within its dynamic extent. It
 141   is intended to be wrapped around the compilation of all files in the same
 142   system. These keywords are defined:
 143     :OVERRIDE Boolean-Form
 144         One of the effects of this form is to delay undefined warnings
 145         until the end of the form, instead of giving them at the end of each
 146         compilation. If OVERRIDE is NIL (the default), then the outermost
 147         WITH-COMPILATION-UNIT form grabs the undefined warnings. Specifying
 148         OVERRIDE true causes that form to grab any enclosed warnings, even if
 149         it is enclosed by another WITH-COMPILATION-UNIT."
 150   `(%with-compilation-unit (lambda () ,@body) ,@options))
 151
 152 (defun %with-compilation-unit (fn &key override)
 153   (let ((succeeded-p nil))
 154     (if (and *in-compilation-unit* (not override))
 155         ;; Inside another WITH-COMPILATION-UNIT, a WITH-COMPILATION-UNIT is
 156         ;; ordinarily (unless OVERRIDE) basically a no-op.
 157         (unwind-protect
 158             (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 159           (unless succeeded-p
 160             (incf *aborted-compilation-unit-count*)))
 161         ;; FIXME: Now *COMPILER-FOO-COUNT* stuff is bound in more than
 162         ;; one place. If we can get rid of the IR1 interpreter, this
 163         ;; should be easier to clean up.
 164         (let ((*aborted-compilation-unit-count* 0)
 165               (*compiler-error-count* 0)
 166               (*compiler-warning-count* 0)
 167               (*compiler-style-warning-count* 0)
 168               (*compiler-note-count* 0)
 169               (*undefined-warnings* nil)
 170               (*in-compilation-unit* t))
 171           (handler-bind ((parse-unknown-type
 172                           (lambda (c)
 173                             (note-undefined-reference
 174                              (parse-unknown-type-specifier c)
 175                              :type))))
 176             (unwind-protect
 177                 (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 178               (unless succeeded-p
 179                 (incf *aborted-compilation-unit-count*))
 180               (summarize-compilation-unit (not succeeded-p))))))))
 181
 182 ;;; This is to be called at the end of a compilation unit. It signals
 183 ;;; any residual warnings about unknown stuff, then prints the total
 184 ;;; error counts. ABORT-P should be true when the compilation unit was
 185 ;;; aborted by throwing out. ABORT-COUNT is the number of dynamically
 186 ;;; enclosed nested compilation units that were aborted.
 187 (defun summarize-compilation-unit (abort-p)
 188   (unless abort-p
 189     (handler-bind ((style-warning #'compiler-style-warning-handler)
 190                    (warning #'compiler-warning-handler))
 191
 192       (let ((undefs (sort *undefined-warnings* #'string<
 193                           :key #'(lambda (x)
 194                                    (let ((x (undefined-warning-name x)))
 195                                      (if (symbolp x)
 196                                          (symbol-name x)
 197                                          (prin1-to-string x)))))))
 198         (unless *converting-for-interpreter*
 199           (dolist (undef undefs)
 200             (let ((name (undefined-warning-name undef))
 201                   (kind (undefined-warning-kind undef))
 202                   (warnings (undefined-warning-warnings undef))
 203                   (undefined-warning-count (undefined-warning-count undef)))
 204               (dolist (*compiler-error-context* warnings)
 205                 (compiler-style-warning "undefined ~(~A~): ~S" kind name))
 206
 207               (let ((warn-count (length warnings)))
 208                 (when (and warnings (> undefined-warning-count warn-count))
 209                   (let ((more (- undefined-warning-count warn-count)))
 210                     (compiler-style-warning
 211                      "~D more use~:P of undefined ~(~A~) ~S"
 212                      more kind name)))))))
 213
 214         (dolist (kind '(:variable :function :type))
 215           (let ((summary (mapcar #'undefined-warning-name
 216                                  (remove kind undefs :test-not #'eq
 217                                          :key #'undefined-warning-kind))))
 218             (when summary
 219               (compiler-style-warning
 220                "~:[This ~(~A~) is~;These ~(~A~)s are~] undefined:~
 221                 ~%  ~{~<~%  ~1:;~S~>~^ ~}"
 222                (cdr summary) kind summary)))))))
 223
 224   (unless (or *converting-for-interpreter*
 225               (and (not abort-p)
 226                    (zerop *aborted-compilation-unit-count*)
 227                    (zerop *compiler-error-count*)
 228                    (zerop *compiler-warning-count*)
 229                    (zerop *compiler-style-warning-count*)
 230                    (zerop *compiler-note-count*)))
 231     ;; MNA: compiler message patch
 232     (format *error-output* "~&")
 233     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 234     (compiler-mumble
 235                            "compilation unit ~:[finished~;aborted~]~
 236       ~[~:;~:*~&  caught ~D fatal ERROR condition~:P~]~
 237       ~[~:;~:*~&  caught ~D ERROR condition~:P~]~
 238       ~[~:;~:*~&  caught ~D WARNING condition~:P~]~
 239       ~[~:;~:*~&  caught ~D STYLE-WARNING condition~:P~]~
 240       ~[~:;~:*~&  printed ~D note~:P~]"
 241      abort-p
 242      *aborted-compilation-unit-count*
 243      *compiler-error-count*
 244      *compiler-warning-count*
 245      *compiler-style-warning-count*
 246                            *compiler-note-count*))))
 247
 248 ;;; Evaluate BODY, then return (VALUES BODY-VALUE WARNINGS-P
 249 ;;; FAILURE-P), where BODY-VALUE is the first value of the body, and
 250 ;;; WARNINGS-P and FAILURE-P are as in CL:COMPILE or CL:COMPILE-FILE.
 251 ;;; This also wraps up WITH-IR1-NAMESPACE functionality.
 252 (defmacro with-compilation-values (&body body)
 253   `(with-ir1-namespace
 254     (let ((*warnings-p* nil)
 255           (*failure-p* nil))
 256       (values (progn ,@body)
 257               *warnings-p*
 258               *failure-p*))))
 259 \f
 260 ;;;; component compilation
 261
 262 (defparameter *max-optimize-iterations* 3 ; ARB
 263   #!+sb-doc
 264   "The upper limit on the number of times that we will consecutively do IR1
 265   optimization that doesn't introduce any new code. A finite limit is
 266   necessary, since type inference may take arbitrarily long to converge.")
 267
 268 (defevent ir1-optimize-until-done "IR1-OPTIMIZE-UNTIL-DONE called")
 269 (defevent ir1-optimize-maxed-out "hit *MAX-OPTIMIZE-ITERATIONS* limit")
 270
 271 ;;; Repeatedly optimize COMPONENT until no further optimizations can
 272 ;;; be found or we hit our iteration limit. When we hit the limit, we
 273 ;;; clear the component and block REOPTIMIZE flags to discourage the
 274 ;;; next optimization attempt from pounding on the same code.
 275 (defun ir1-optimize-until-done (component)
 276   (declare (type component component))
 277   (maybe-mumble "opt")
 278   (event ir1-optimize-until-done)
 279   (let ((count 0)
 280         (cleared-reanalyze nil))
 281     (loop
 282       (when (component-reanalyze component)
 283         (setq count 0)
 284         (setq cleared-reanalyze t)
 285         (setf (component-reanalyze component) nil))
 286       (setf (component-reoptimize component) nil)
 287       (ir1-optimize component)
 288       (unless (component-reoptimize component)
 289         (maybe-mumble " ")
 290         (return))
 291       (incf count)
 292       (when (= count *max-optimize-iterations*)
 293         (event ir1-optimize-maxed-out)
 294         (maybe-mumble "* ")
 295         (setf (component-reoptimize component) nil)
 296         (do-blocks (block component)
 297           (setf (block-reoptimize block) nil))
 298         (return))
 299       (maybe-mumble "."))
 300     (when cleared-reanalyze
 301       (setf (component-reanalyze component) t)))
 302   (values))
 303
 304 (defparameter *constraint-propagate* t)
 305 (defparameter *reoptimize-after-type-check-max* 5)
 306
 307 (defevent reoptimize-maxed-out
 308   "*REOPTIMIZE-AFTER-TYPE-CHECK-MAX* exceeded.")
 309
 310 ;;; Iterate doing FIND-DFO until no new dead code is discovered.
 311 (defun dfo-as-needed (component)
 312   (declare (type component component))
 313   (when (component-reanalyze component)
 314     (maybe-mumble "DFO")
 315     (loop
 316       (find-dfo component)
 317       (unless (component-reanalyze component)
 318         (maybe-mumble " ")
 319         (return))
 320       (maybe-mumble ".")))
 321   (values))
 322
 323 ;;; Do all the IR1 phases for a non-top-level component.
 324 (defun ir1-phases (component)
 325   (declare (type component component))
 326   (let ((*constraint-number* 0)
 327         (loop-count 1))
 328     (declare (special *constraint-number*))
 329     (loop
 330       (ir1-optimize-until-done component)
 331       (when (or (component-new-functions component)
 332                 (component-reanalyze-functions component))
 333         (maybe-mumble "locall ")
 334         (local-call-analyze component))
 335       (dfo-as-needed component)
 336       (when *constraint-propagate*
 337         (maybe-mumble "constraint ")
 338         (constraint-propagate component))
 339       (maybe-mumble "type ")
 340       ;; Delay the generation of type checks until the type
 341       ;; constraints have had time to propagate, else the compiler can
 342       ;; confuse itself.
 343       (unless (and (or (component-reoptimize component)
 344                        (component-reanalyze component)
 345                        (component-new-functions component)
 346                        (component-reanalyze-functions component))
 347                    (< loop-count (- *reoptimize-after-type-check-max* 2)))
 348         (generate-type-checks component)
 349         (unless (or (component-reoptimize component)
 350                     (component-reanalyze component)
 351                     (component-new-functions component)
 352                     (component-reanalyze-functions component))
 353           (return)))
 354       (when (>= loop-count *reoptimize-after-type-check-max*)
 355         (maybe-mumble "[reoptimize limit]")
 356         (event reoptimize-maxed-out)
 357         (return))
 358       (incf loop-count)))
 359
 360   (ir1-finalize component)
 361   (values))
 362
 363 (defun native-compile-component (component)
 364   (let ((*code-segment* nil)
 365         (*elsewhere* nil))
 366     (maybe-mumble "GTN ")
 367     (gtn-analyze component)
 368     (maybe-mumble "LTN ")
 369     (ltn-analyze component)
 370     (dfo-as-needed component)
 371     (maybe-mumble "control ")
 372     (control-analyze component #'make-ir2-block)
 373
 374     (when (ir2-component-values-receivers (component-info component))
 375       (maybe-mumble "stack ")
 376       (stack-analyze component)
 377       ;; Assign BLOCK-NUMBER for any cleanup blocks introduced by
 378       ;; stack analysis. There shouldn't be any unreachable code after
 379       ;; control, so this won't delete anything.
 380       (dfo-as-needed component))
 381
 382     (unwind-protect
 383         (progn
 384           (maybe-mumble "IR2tran ")
 385           (init-assembler)
 386           (entry-analyze component)
 387           (ir2-convert component)
 388
 389           (when (policy nil (>= speed cspeed))
 390             (maybe-mumble "copy ")
 391             (copy-propagate component))
 392
 393           (select-representations component)
 394
 395           (when *check-consistency*
 396             (maybe-mumble "check2 ")
 397             (check-ir2-consistency component))
 398
 399           (delete-unreferenced-tns component)
 400
 401           (maybe-mumble "life ")
 402           (lifetime-analyze component)
 403
 404           (when *compile-progress*
 405             (compiler-mumble "") ; Sync before doing more output.
 406             (pre-pack-tn-stats component *error-output*))
 407
 408           (when *check-consistency*
 409             (maybe-mumble "check-life ")
 410             (check-life-consistency component))
 411
 412           (maybe-mumble "pack ")
 413           (pack component)
 414
 415           (when *check-consistency*
 416             (maybe-mumble "check-pack ")
 417             (check-pack-consistency component))
 418
 419           #!+sb-show
 420           (when *compiler-trace-output*
 421             (describe-component component *compiler-trace-output*)
 422             (describe-ir2-component component *compiler-trace-output*))
 423
 424           (maybe-mumble "code ")
 425           (multiple-value-bind (code-length trace-table fixups)
 426               (generate-code component)
 427
 428             #!+sb-show
 429             (when *compiler-trace-output*
 430               (format *compiler-trace-output*
 431                       "~|~%disassembly of code for ~S~2%" component)
 432               (sb!disassem:disassemble-assem-segment *code-segment*
 433                                                      *compiler-trace-output*))
 434
 435             (etypecase *compile-object*
 436               (fasl-file
 437                (maybe-mumble "fasl")
 438                (fasl-dump-component component
 439                                     *code-segment*
 440                                     code-length
 441                                     trace-table
 442                                     fixups
 443                                     *compile-object*))
 444               (core-object
 445                (maybe-mumble "core")
 446                (make-core-component component
 447                                     *code-segment*
 448                                     code-length
 449                                     trace-table
 450                                     fixups
 451                                     *compile-object*))
 452               (null))))))
 453
 454   ;; We are done, so don't bother keeping anything around.
 455   (setf (component-info component) nil)
 456
 457   (values))
 458
 459 ;;; Return our best guess for whether we will byte compile code
 460 ;;; currently being IR1 converted. This is only a guess because the
 461 ;;; decision is made on a per-component basis.
 462 ;;;
 463 ;;; FIXME: This should be called something more mnemonic, e.g.
 464 ;;; PROBABLY-BYTE-COMPILING
 465 (defun byte-compiling ()
 466   (if (eq *byte-compiling* :maybe)
 467       (or (eq *byte-compile* t)
 468           (policy nil (zerop speed) (<= debug 1)))
 469       (and *byte-compile* *byte-compiling*)))
 470
 471 ;;; Delete components with no external entry points before we try to
 472 ;;; generate code. Unreachable closures can cause IR2 conversion to puke on
 473 ;;; itself, since it is the reference to the closure which normally causes the
 474 ;;; components to be combined. This doesn't really cover all cases...
 475 (defun delete-if-no-entries (component)
 476   (dolist (fun (component-lambdas component)
 477                (delete-component component))
 478     (case (functional-kind fun)
 479       (:top-level (return))
 480       (:external
 481        (unless (every #'(lambda (ref)
 482                           (eq (block-component (node-block ref))
 483                               component))
 484                       (leaf-refs fun))
 485          (return))))))
 486
 487 (defun compile-component (component)
 488   (let* ((*component-being-compiled* component)
 489          (*byte-compiling*
 490           (ecase *byte-compile*
 491             ((t) t)
 492             ((nil) nil)
 493             (:maybe
 494              (dolist (fun (component-lambdas component) t)
 495                (unless (policy (lambda-bind fun)
 496                                (zerop speed) (<= debug 1))
 497                  (return nil)))))))
 498
 499     (when sb!xc:*compile-print*
 500       ;; MNA: compiler message patch
 501       (compiler-mumble "~&; ~:[~;byte ~]compiling ~A: "
 502                        *byte-compiling*
 503                        (component-name component)))
 504
 505     (ir1-phases component)
 506
 507     ;; FIXME: What is MAYBE-MUMBLE for? Do we need it any more?
 508     (maybe-mumble "env ")
 509     (environment-analyze component)
 510     (dfo-as-needed component)
 511
 512     (delete-if-no-entries component)
 513
 514     (unless (eq (block-next (component-head component))
 515                 (component-tail component))
 516       (if *byte-compiling*
 517           (byte-compile-component component)
 518           (native-compile-component component))))
 519
 520   (clear-constant-info)
 521
 522   (when sb!xc:*compile-print*
 523     (compiler-mumble "~&"))
 524
 525   (values))
 526 \f
 527 ;;;; clearing global data structures
 528 ;;;;
 529 ;;;; FIXME: Is it possible to get rid of this stuff, getting rid of
 530 ;;;; global data structures entirely when possible and consing up the
 531 ;;;; others from scratch instead of clearing and reusing them?
 532
 533 ;;; Clear the INFO in constants in the *FREE-VARIABLES*, etc. In
 534 ;;; addition to allowing stuff to be reclaimed, this is required for
 535 ;;; correct assignment of constant offsets, since we need to assign a
 536 ;;; new offset for each component. We don't clear the FUNCTIONAL-INFO
 537 ;;; slots, since they are used to keep track of functions across
 538 ;;; component boundaries.
 539 (defun clear-constant-info ()
 540   (maphash #'(lambda (k v)
 541                (declare (ignore k))
 542                (setf (leaf-info v) nil))
 543            *constants*)
 544   (maphash #'(lambda (k v)
 545                (declare (ignore k))
 546                (when (constant-p v)
 547                  (setf (leaf-info v) nil)))
 548            *free-variables*)
 549   (values))
 550
 551 ;;; Blow away the REFS for all global variables, and let COMPONENT
 552 ;;; be recycled.
 553 (defun clear-ir1-info (component)
 554   (declare (type component component))
 555   (labels ((blast (x)
 556              (maphash #'(lambda (k v)
 557                           (declare (ignore k))
 558                           (when (leaf-p v)
 559                             (setf (leaf-refs v)
 560                                   (delete-if #'here-p (leaf-refs v)))
 561                             (when (basic-var-p v)
 562                               (setf (basic-var-sets v)
 563                                     (delete-if #'here-p (basic-var-sets v))))))
 564                       x))
 565            (here-p (x)
 566              (eq (block-component (node-block x)) component)))
 567     (blast *free-variables*)
 568     (blast *free-functions*)
 569     (blast *constants*))
 570   (values))
 571
 572 ;;; Clear global variables used by the compiler.
 573 ;;;
 574 ;;; FIXME: It seems kinda nasty and unmaintainable to have to do this,
 575 ;;; and it adds overhead even when people aren't using the compiler.
 576 ;;; Perhaps we could make these global vars unbound except when
 577 ;;; actually in use, so that this function could go away.
 578 (defun clear-stuff (&optional (debug-too t))
 579
 580   ;; Clear global tables.
 581   (when (boundp '*free-functions*)
 582     (clrhash *free-functions*)
 583     (clrhash *free-variables*)
 584     (clrhash *constants*))
 585
 586   ;; Clear debug counters and tables.
 587   (clrhash *seen-blocks*)
 588   (clrhash *seen-functions*)
 589   (clrhash *list-conflicts-table*)
 590
 591   (when debug-too
 592     (clrhash *continuation-numbers*)
 593     (clrhash *number-continuations*)
 594     (setq *continuation-number* 0)
 595     (clrhash *tn-ids*)
 596     (clrhash *id-tns*)
 597     (setq *tn-id* 0)
 598     (clrhash *label-ids*)
 599     (clrhash *id-labels*)
 600     (setq *label-id* 0)
 601
 602     ;; Clear some Pack data structures (for GC purposes only).
 603     (assert (not *in-pack*))
 604     (dolist (sb *backend-sb-list*)
 605       (when (finite-sb-p sb)
 606         (fill (finite-sb-live-tns sb) nil))))
 607
 608   ;; (Note: The CMU CL code used to set CL::*GENSYM-COUNTER* to zero here.
 609   ;; Superficially, this seemed harmful -- the user could reasonably be
 610   ;; surprised if *GENSYM-COUNTER* turned back to zero when something was
 611   ;; compiled. A closer inspection showed that this actually turned out to be
 612   ;; harmless in practice, because CLEAR-STUFF was only called from within
 613   ;; forms which bound CL::*GENSYM-COUNTER* to zero. However, this means that
 614   ;; even though zeroing CL::*GENSYM-COUNTER* here turned out to be harmless in
 615   ;; practice, it was also useless in practice. So we don't do it any more.)
 616
 617   (values))
 618 \f
 619 ;;;; trace output
 620
 621 ;;; Print out some useful info about Component to Stream.
 622 (defun describe-component (component *standard-output*)
 623   (declare (type component component))
 624   (format t "~|~%;;;; component: ~S~2%" (component-name component))
 625   (print-blocks component)
 626   (values))
 627
 628 (defun describe-ir2-component (component *standard-output*)
 629   (format t "~%~|~%;;;; IR2 component: ~S~2%" (component-name component))
 630   (format t "entries:~%")
 631   (dolist (entry (ir2-component-entries (component-info component)))
 632     (format t "~4TL~D: ~S~:[~; [closure]~]~%"
 633             (label-id (entry-info-offset entry))
 634             (entry-info-name entry)
 635             (entry-info-closure-p entry)))
 636   (terpri)
 637   (pre-pack-tn-stats component *standard-output*)
 638   (terpri)
 639   (print-ir2-blocks component)
 640   (terpri)
 641   (values))
 642 \f
 643 ;;;; file reading
 644 ;;;;
 645 ;;;; When reading from a file, we have to keep track of some source
 646 ;;;; information. We also exploit our ability to back up for printing
 647 ;;;; the error context and for recovering from errors.
 648 ;;;;
 649 ;;;; The interface we provide to this stuff is the stream-oid
 650 ;;;; Source-Info structure. The bookkeeping is done as a side-effect
 651 ;;;; of getting the next source form.
 652
 653 ;;; The File-Info structure holds all the source information for a
 654 ;;; given file.
 655 (defstruct file-info
 656   ;; If a file, the truename of the corresponding source file. If from a Lisp
 657   ;; form, :LISP, if from a stream, :STREAM.
 658   (name (required-argument) :type (or pathname (member :lisp :stream)))
 659   ;; The defaulted, but not necessarily absolute file name (i.e. prior to
 660   ;; TRUENAME call.)  Null if not a file. This is used to set
 661   ;; *COMPILE-FILE-PATHNAME*, and if absolute, is dumped in the debug-info.
 662   (untruename nil :type (or pathname null))
 663   ;; The file's write date (if relevant.)
 664   (write-date nil :type (or unsigned-byte null))
 665   ;; The source path root number of the first form in this file (i.e. the
 666   ;; total number of forms converted previously in this compilation.)
 667   (source-root 0 :type unsigned-byte)
 668   ;; Parallel vectors containing the forms read out of the file and the file
 669   ;; positions that reading of each form started at (i.e. the end of the
 670   ;; previous form.)
 671   (forms (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t))
 672   (positions (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t)))
 673
 674 ;;; The SOURCE-INFO structure provides a handle on all the source
 675 ;;; information for an entire compilation.
 676 (defstruct (source-info
 677             #-no-ansi-print-object
 678             (:print-object (lambda (s stream)
 679                              (print-unreadable-object (s stream :type t)))))
 680   ;; the UT that compilation started at
 681   (start-time (get-universal-time) :type unsigned-byte)
 682   ;; a list of the FILE-INFO structures for this compilation
 683   (files nil :type list)
 684   ;; the tail of the FILES for the file we are currently reading
 685   (current-file nil :type list)
 686   ;; the stream that we are using to read the CURRENT-FILE, or NIL if
 687   ;; no stream has been opened yet
 688   (stream nil :type (or stream null)))
 689
 690 ;;; Given a list of pathnames, return a SOURCE-INFO structure.
 691 (defun make-file-source-info (files)
 692   (declare (list files))
 693   (let ((file-info
 694          (mapcar (lambda (x)
 695                    (make-file-info :name (truename x)
 696                                    :untruename x
 697                                    :write-date (file-write-date x)))
 698                  files)))
 699
 700     (make-source-info :files file-info
 701                       :current-file file-info)))
 702
 703 ;;; Return a SOURCE-INFO to describe the incremental compilation of
 704 ;;; FORM. Also used by SB!EVAL:INTERNAL-EVAL.
 705 (defun make-lisp-source-info (form)
 706   (make-source-info
 707    :start-time (get-universal-time)
 708    :files (list (make-file-info :name :lisp
 709                                 :forms (vector form)
 710                                 :positions '#(0)))))
 711
 712 ;;; Return a SOURCE-INFO which will read from Stream.
 713 (defun make-stream-source-info (stream)
 714   (let ((files (list (make-file-info :name :stream))))
 715     (make-source-info
 716      :files files
 717      :current-file files
 718      :stream stream)))
 719
 720 ;;; Print an error message for a non-EOF error on STREAM. OLD-POS is a
 721 ;;; preceding file position that hopefully comes before the beginning
 722 ;;; of the line. Of course, this only works on streams that support
 723 ;;; the file-position operation.
 724 (defun normal-read-error (stream old-pos condition)
 725   (declare (type stream stream) (type unsigned-byte old-pos))
 726   (let ((pos (file-position stream)))
 727     (file-position stream old-pos)
 728     (let ((start old-pos))
 729       (loop
 730         (let ((line (read-line stream nil))
 731               (end (file-position stream)))
 732           (when (>= end pos)
 733             ;; FIXME: READER-ERROR also prints the file position. Do we really
 734             ;; need to try to give position information here?
 735             (compiler-abort "read error at ~D:~% \"~A/\\~A\"~%~A"
 736                             pos
 737                             (string-left-trim "         "
 738                                               (subseq line 0 (- pos start)))
 739                             (subseq line (- pos start))
 740                             condition)
 741             (return))
 742           (setq start end)))))
 743   (values))
 744
 745 ;;; Back STREAM up to the position Pos, then read a form with
 746 ;;; *READ-SUPPRESS* on, discarding the result. If an error happens
 747 ;;; during this read, then bail out using COMPILER-ERROR (fatal in
 748 ;;; this context).
 749 (defun ignore-error-form (stream pos)
 750   (declare (type stream stream) (type unsigned-byte pos))
 751   (file-position stream pos)
 752   (handler-case (let ((*read-suppress* t))
 753                   (read stream))
 754     (error (condition)
 755       (declare (ignore condition))
 756       (compiler-error "unable to recover from read error"))))
 757
 758 ;;; Print an error message giving some context for an EOF error. We
 759 ;;; print the first line after POS that contains #\" or #\(, or
 760 ;;; lacking that, the first non-empty line.
 761 (defun unexpected-eof-error (stream pos condition)
 762   (declare (type stream stream) (type unsigned-byte pos))
 763   (let ((res nil))
 764     (file-position stream pos)
 765     (loop
 766       (let ((line (read-line stream nil nil)))
 767         (unless line (return))
 768         (when (or (find #\" line) (find #\( line))
 769           (setq res line)
 770           (return))
 771         (unless (or res (zerop (length line)))
 772           (setq res line))))
 773     (compiler-abort "read error in form starting at ~D:~%~@[ \"~A\"~%~]~A"
 774                     pos
 775                     res
 776                     condition))
 777   (file-position stream (file-length stream))
 778   (values))
 779
 780 ;;; Read a form from STREAM, returning EOF at EOF. If a read error
 781 ;;; happens, then attempt to recover if possible, returning a proxy
 782 ;;; error form.
 783 ;;;
 784 ;;; FIXME: This seems like quite a lot of complexity, and it seems
 785 ;;; impossible to get it quite right. (E.g. the `(CERROR ..) form
 786 ;;; returned here won't do the right thing if it's not in a position
 787 ;;; for an executable form.) I think it might be better to just stop
 788 ;;; trying to recover from read errors, punting all this noise
 789 ;;; (including UNEXPECTED-EOF-ERROR and IGNORE-ERROR-FORM) and doing a
 790 ;;; COMPILER-ABORT instead.
 791 (defun careful-read (stream eof pos)
 792   (handler-case (read stream nil eof)
 793     (error (condition)
 794       (let ((new-pos (file-position stream)))
 795         (cond ((= new-pos (file-length stream))
 796                (unexpected-eof-error stream pos condition))
 797               (t
 798                (normal-read-error stream pos condition)
 799                (ignore-error-form stream pos))))
 800       '(cerror "Skip this form."
 801                "compile-time read error"))))
 802
 803 ;;; If Stream is present, return it, otherwise open a stream to the
 804 ;;; current file. There must be a current file. When we open a new
 805 ;;; file, we also reset *PACKAGE* and policy. This gives the effect of
 806 ;;; rebinding around each file.
 807 ;;;
 808 ;;; FIXME: Since we now do the standard ANSI thing of only one file
 809 ;;; per compile (unlike the CMU CL extended COMPILE-FILE) can't this
 810 ;;; complexity (including ADVANCE-SOURCE-FILE) go away?
 811 (defun get-source-stream (info)
 812   (declare (type source-info info))
 813   (cond ((source-info-stream info))
 814         (t
 815          (setq *package* *initial-package*)
 816          (setq *default-cookie* (copy-cookie *initial-cookie*))
 817          (setq *default-interface-cookie*
 818                (copy-cookie *initial-interface-cookie*))
 819          (let* ((finfo (first (source-info-current-file info)))
 820                 (name (file-info-name finfo)))
 821            (setq sb!xc:*compile-file-truename* name)
 822            (setq sb!xc:*compile-file-pathname* (file-info-untruename finfo))
 823            (setf (source-info-stream info)
 824                  (open name :direction :input))))))
 825
 826 ;;; Close the stream in INFO if it is open.
 827 (defun close-source-info (info)
 828   (declare (type source-info info))
 829   (let ((stream (source-info-stream info)))
 830     (when stream (close stream)))
 831   (setf (source-info-stream info) nil)
 832   (values))
 833
 834 ;;; Advance INFO to the next source file. If there is no next source
 835 ;;; file, return NIL, otherwise T.
 836 (defun advance-source-file (info)
 837   (declare (type source-info info))
 838   (close-source-info info)
 839   (let ((prev (pop (source-info-current-file info))))
 840     (if (source-info-current-file info)
 841         (let ((current (first (source-info-current-file info))))
 842           (setf (file-info-source-root current)
 843                 (+ (file-info-source-root prev)
 844                    (length (file-info-forms prev))))
 845           t)
 846         nil)))
 847
 848 ;;; Read the sources from the source files and process them.
 849 (defun process-sources (info)
 850   (let* ((file (first (source-info-current-file info)))
 851          (stream (get-source-stream info)))
 852     (loop
 853      (let* ((pos (file-position stream))
 854             (eof '(*eof*))
 855             (form (careful-read stream eof pos)))
 856        (if (eq form eof)
 857          (return)
 858          (let* ((forms (file-info-forms file))
 859                 (current-idx (+ (fill-pointer forms)
 860                                 (file-info-source-root file))))
 861            (vector-push-extend form forms)
 862            (vector-push-extend pos (file-info-positions file))
 863            (clrhash *source-paths*)
 864            (find-source-paths form current-idx)
 865            (process-top-level-form form
 866                                    `(original-source-start 0 ,current-idx))))))
 867     (when (advance-source-file info)
 868       (process-sources info))))
 869
 870 ;;; Return the FILE-INFO describing the INDEX'th form.
 871 (defun find-file-info (index info)
 872   (declare (type index index) (type source-info info))
 873   (dolist (file (source-info-files info))
 874     (when (> (+ (length (file-info-forms file))
 875                 (file-info-source-root file))
 876              index)
 877       (return file))))
 878
 879 ;;; Return the INDEX'th source form read from INFO and the position
 880 ;;; where it was read.
 881 (defun find-source-root (index info)
 882   (declare (type source-info info) (type index index))
 883   (let* ((file (find-file-info index info))
 884          (idx (- index (file-info-source-root file))))
 885     (values (aref (file-info-forms file) idx)
 886             (aref (file-info-positions file) idx))))
 887 \f
 888 ;;;; top-level form processing
 889
 890 ;;; This is called by top-level form processing when we are ready to
 891 ;;; actually compile something. If *BLOCK-COMPILE* is T, then we still
 892 ;;; convert the form, but delay compilation, pushing the result on
 893 ;;; *TOP-LEVEL-LAMBDAS* instead.
 894 (defun convert-and-maybe-compile (form path)
 895   (declare (list path))
 896   (let* ((*lexenv* (make-lexenv :cookie *default-cookie*
 897                                 :interface-cookie *default-interface-cookie*))
 898          (tll (ir1-top-level form path nil)))
 899     (cond ((eq *block-compile* t) (push tll *top-level-lambdas*))
 900           (t (compile-top-level (list tll) nil)))))
 901
 902 ;;; Process a PROGN-like portion of a top-level form. Forms is a list of
 903 ;;; the forms, and Path is source path of the form they came out of.
 904 (defun process-top-level-progn (forms path)
 905   (declare (list forms) (list path))
 906   (dolist (form forms)
 907     (process-top-level-form form path)))
 908
 909 ;;; Macroexpand form in the current environment with an error handler.
 910 ;;; We only expand one level, so that we retain all the intervening
 911 ;;; forms in the source path.
 912 (defun preprocessor-macroexpand (form)
 913   (handler-case (sb!xc:macroexpand-1 form *lexenv*)
 914     (error (condition)
 915        (compiler-error "(during macroexpansion)~%~A" condition))))
 916
 917 ;;; Process a top-level use of LOCALLY. We parse declarations and then
 918 ;;; recursively process the body.
 919 ;;;
 920 ;;; Binding *DEFAULT-xxx-COOKIE* is pretty much of a hack, since it
 921 ;;; causes LOCALLY to "capture" enclosed proclamations. It is
 922 ;;; necessary because CONVERT-AND-MAYBE-COMPILE uses the value of
 923 ;;; *DEFAULT-COOKIE* as the policy. The need for this hack is due to
 924 ;;; the quirk that there is no way to represent in a cookie that an
 925 ;;; optimize quality came from the default.
 926 (defun process-top-level-locally (form path)
 927   (declare (list path))
 928   (multiple-value-bind (forms decls) (sb!sys:parse-body (cdr form) nil)
 929     (let* ((*lexenv*
 930             (process-decls decls nil nil (make-continuation)))
 931            (*default-cookie* (lexenv-cookie *lexenv*))
 932            (*default-interface-cookie* (lexenv-interface-cookie *lexenv*)))
 933       (process-top-level-progn forms path))))
 934
 935 ;;; Force any pending top-level forms to be compiled and dumped so
 936 ;;; that they will be evaluated in the correct package environment.
 937 ;;; Dump the form to be evaled at (cold) load time, and if EVAL is
 938 ;;; true, eval the form immediately.
 939 (defun process-cold-load-form (form path eval)
 940   (let ((object *compile-object*))
 941     (etypecase object
 942       (fasl-file
 943        (compile-top-level-lambdas () t)
 944        (fasl-dump-cold-load-form form object))
 945       ((or null core-object)
 946        (convert-and-maybe-compile form path)))
 947     (when eval
 948       (eval form))))
 949
 950 (declaim (special *compiler-error-bailout*))
 951
 952 ;;; Process a top-level FORM with the specified source PATH.
 953 ;;;  * If this is a magic top-level form, then do stuff.
 954 ;;;  * If this is a macro, then expand it.
 955 ;;;  * Otherwise, just compile it.
 956 (defun process-top-level-form (form path)
 957
 958   (declare (list path))
 959
 960   (catch 'process-top-level-form-error-abort
 961     (let* ((path (or (gethash form *source-paths*) (cons form path)))
 962            (*compiler-error-bailout*
 963             #'(lambda ()
 964                 (convert-and-maybe-compile
 965                  `(error "execution of a form compiled with errors:~% ~S"
 966                          ',form)
 967                  path)
 968                 (throw 'process-top-level-form-error-abort nil))))
 969       (if (atom form)
 970           (convert-and-maybe-compile form path)
 971           (case (car form)
 972             ;; FIXME: It's not clear to me why we would want this
 973             ;; special case; it might have been needed for some
 974             ;; variation of the old GENESIS system, but it certainly
 975             ;; doesn't seem to be needed for ours. Sometime after the
 976             ;; system is running I'd like to remove it tentatively and
 977             ;; see whether anything breaks, and if nothing does break,
 978             ;; remove it permanently. (And if we *do* want special
 979             ;; treatment of all these, we probably want to treat WARN
 980             ;; the same way..)
 981             ((error cerror break signal)
 982              (process-cold-load-form form path nil))
 983             ;; FIXME: ANSI seems to encourage things like DEFSTRUCT to
 984             ;; be done with EVAL-WHEN, without this kind of one-off
 985             ;; compiler magic.
 986             (sb!kernel:%compiler-defstruct
 987              (convert-and-maybe-compile form path)
 988              (compile-top-level-lambdas () t))
 989             ((eval-when)
 990              (unless (>= (length form) 2)
 991                (compiler-error "EVAL-WHEN form is too short: ~S" form))
 992              (do-eval-when-stuff
 993               (cadr form) (cddr form)
 994               #'(lambda (forms)
 995                   (process-top-level-progn forms path))))
 996             ((macrolet)
 997              (unless (>= (length form) 2)
 998                (compiler-error "MACROLET form is too short: ~S" form))
 999              (do-macrolet-stuff
1000               (cadr form)
1001               #'(lambda ()
1002                   (process-top-level-progn (cddr form) path))))
1003             (locally (process-top-level-locally form path))
1004             (progn (process-top-level-progn (cdr form) path))
1005             (t
1006              (let* ((uform (uncross form))
1007                     (exp (preprocessor-macroexpand uform)))
1008                (if (eq exp uform)
1009                    (convert-and-maybe-compile uform path)
1010                    (process-top-level-form exp path))))))))
1011
1012   (values))
1013 \f
1014 ;;;; load time value support
1015 ;;;;
1016 ;;;; (See EMIT-MAKE-LOAD-FORM.)
1017
1018 ;;; Returns T iff we are currently producing a fasl-file and hence
1019 ;;; constants need to be dumped carefully.
1020 (defun producing-fasl-file ()
1021   (unless *converting-for-interpreter*
1022     (fasl-file-p *compile-object*)))
1023
1024 ;;; Compile FORM and arrange for it to be called at load-time. Return
1025 ;;; the dumper handle and our best guess at the type of the object.
1026 (defun compile-load-time-value
1027        (form &optional
1028              (name (let ((*print-level* 2) (*print-length* 3))
1029                      (format nil "load time value of ~S"
1030                              (if (and (listp form)
1031                                       (eq (car form) 'make-value-cell))
1032                                  (second form)
1033                                  form)))))
1034   (let ((lambda (compile-load-time-stuff form name t)))
1035     (values
1036      (fasl-dump-load-time-value-lambda lambda *compile-object*)
1037      (let ((type (leaf-type lambda)))
1038        (if (function-type-p type)
1039            (single-value-type (function-type-returns type))
1040            *wild-type*)))))
1041
1042 ;;; Compile the FORMS and arrange for them to be called (for effect,
1043 ;;; not value) at load time.
1044 (defun compile-make-load-form-init-forms (forms name)
1045   (let ((lambda (compile-load-time-stuff `(progn ,@forms) name nil)))
1046     (fasl-dump-top-level-lambda-call lambda *compile-object*)))
1047
1048 ;;; Does the actual work of COMPILE-LOAD-TIME-VALUE or
1049 ;;; COMPILE-MAKE-LOAD-FORM- INIT-FORMS.
1050 (defun compile-load-time-stuff (form name for-value)
1051   (with-ir1-namespace
1052    (let* ((*lexenv* (make-null-lexenv))
1053           (lambda (ir1-top-level form *current-path* for-value)))
1054      (setf (leaf-name lambda) name)
1055      (compile-top-level (list lambda) t)
1056      lambda)))
1057
1058 ;;; Called by COMPILE-TOP-LEVEL when it was pased T for
1059 ;;; LOAD-TIME-VALUE-P (which happens in COMPILE-LOAD-TIME-STUFF). We
1060 ;;; don't try to combine this component with anything else and frob
1061 ;;; the name. If not in a :TOP-LEVEL component, then don't bother
1062 ;;; compiling, because it was merged with a run-time component.
1063 (defun compile-load-time-value-lambda (lambdas)
1064   (assert (null (cdr lambdas)))
1065   (let* ((lambda (car lambdas))
1066          (component (block-component (node-block (lambda-bind lambda)))))
1067     (when (eq (component-kind component) :top-level)
1068       (setf (component-name component) (leaf-name lambda))
1069       (compile-component component)
1070       (clear-ir1-info component))))
1071
1072 ;;; The entry point for MAKE-LOAD-FORM support. When IR1 conversion
1073 ;;; finds a constant structure, it invokes this to arrange for proper
1074 ;;; dumping. If it turns out that the constant has already been
1075 ;;; dumped, then we don't need to do anything.
1076 ;;;
1077 ;;; If the constant hasn't been dumped, then we check to see whether
1078 ;;; we are in the process of creating it. We detect this by
1079 ;;; maintaining the special *CONSTANTS-BEING-CREATED* as a list of all
1080 ;;; the constants we are in the process of creating. Actually, each
1081 ;;; entry is a list of the constant and any init forms that need to be
1082 ;;; processed on behalf of that constant.
1083 ;;;
1084 ;;; It's not necessarily an error for this to happen. If we are
1085 ;;; processing the init form for some object that showed up *after*
1086 ;;; the original reference to this constant, then we just need to
1087 ;;; defer the processing of that init form. To detect this, we
1088 ;;; maintain *CONSTANTS-CREATED-SINCE-LAST-INIT* as a list of the
1089 ;;; constants created since the last time we started processing an
1090 ;;; init form. If the constant passed to emit-make-load-form shows up
1091 ;;; in this list, then there is a circular chain through creation
1092 ;;; forms, which is an error.
1093 ;;;
1094 ;;; If there is some intervening init form, then we blow out of
1095 ;;; processing it by throwing to the tag PENDING-INIT. The value we
1096 ;;; throw is the entry from *CONSTANTS-BEING-CREATED*. This is so the
1097 ;;; offending init form can be tacked onto the init forms for the
1098 ;;; circular object.
1099 ;;;
1100 ;;; If the constant doesn't show up in *CONSTANTS-BEING-CREATED*, then
1101 ;;; we have to create it. We call MAKE-LOAD-FORM and check to see
1102 ;;; whether the creation form is the magic value
1103 ;;; :JUST-DUMP-IT-NORMALLY. If it is, then we don't do anything. The
1104 ;;; dumper will eventually get its hands on the object and use the
1105 ;;; normal structure dumping noise on it.
1106 ;;;
1107 ;;; Otherwise, we bind *CONSTANTS-BEING-CREATED* and
1108 ;;; *CONSTANTS-CREATED-SINCE- LAST-INIT* and compile the creation form
1109 ;;; much the way LOAD-TIME-VALUE does. When this finishes, we tell the
1110 ;;; dumper to use that result instead whenever it sees this constant.
1111 ;;;
1112 ;;; Now we try to compile the init form. We bind
1113 ;;; *CONSTANTS-CREATED-SINCE- LAST-INIT* to NIL and compile the init
1114 ;;; form (and any init forms that were added because of circularity
1115 ;;; detection). If this works, great. If not, we add the init forms to
1116 ;;; the init forms for the object that caused the problems and let it
1117 ;;; deal with it.
1118 (defvar *constants-being-created* nil)
1119 (defvar *constants-created-since-last-init* nil)
1120 ;;; FIXME: Shouldn't these^ variables be bound in LET forms?
1121 (defun emit-make-load-form (constant)
1122   (assert (fasl-file-p *compile-object*))
1123   (unless (or (fasl-constant-already-dumped constant *compile-object*)
1124               ;; KLUDGE: This special hack is because I was too lazy
1125               ;; to rework DEF!STRUCT so that the MAKE-LOAD-FORM
1126               ;; function of LAYOUT returns nontrivial forms when
1127               ;; building the cross-compiler but :IGNORE-IT when
1128               ;; cross-compiling or running under the target Lisp. --
1129               ;; WHN 19990914
1130               #+sb-xc-host (typep constant 'layout))
1131     (let ((circular-ref (assoc constant *constants-being-created* :test #'eq)))
1132       (when circular-ref
1133         (when (find constant *constants-created-since-last-init* :test #'eq)
1134           (throw constant t))
1135         (throw 'pending-init circular-ref)))
1136     (multiple-value-bind (creation-form init-form)
1137         (handler-case
1138             (sb!xc:make-load-form constant (make-null-lexenv))
1139           (error (condition)
1140                  (compiler-error "(while making load form for ~S)~%~A"
1141                                  constant
1142                                  condition)))
1143       (case creation-form
1144         (:just-dump-it-normally
1145          (fasl-validate-structure constant *compile-object*)
1146          t)
1147         (:ignore-it
1148          nil)
1149         (t
1150          (compile-top-level-lambdas () t)
1151          (when (fasl-constant-already-dumped constant *compile-object*)
1152            (return-from emit-make-load-form nil))
1153          (let* ((name (let ((*print-level* 1) (*print-length* 2))
1154                         (with-output-to-string (stream)
1155                           (write constant :stream stream))))
1156                 (info (if init-form
1157                           (list constant name init-form)
1158                           (list constant))))
1159            (let ((*constants-being-created*
1160                   (cons info *constants-being-created*))
1161                  (*constants-created-since-last-init*
1162                   (cons constant *constants-created-since-last-init*)))
1163              (when
1164                  (catch constant
1165                    (fasl-note-handle-for-constant
1166                     constant
1167                     (compile-load-time-value
1168                      creation-form
1169                      (format nil "creation form for ~A" name))
1170                     *compile-object*)
1171                    nil)
1172                (compiler-error "circular references in creation form for ~S"
1173                                constant)))
1174            (when (cdr info)
1175              (let* ((*constants-created-since-last-init* nil)
1176                     (circular-ref
1177                      (catch 'pending-init
1178                        (loop for (name form) on (cdr info) by #'cddr
1179                          collect name into names
1180                          collect form into forms
1181                          finally
1182                          (compile-make-load-form-init-forms
1183                           forms
1184                           (format nil "init form~:[~;s~] for ~{~A~^, ~}"
1185                                   (cdr forms) names)))
1186                        nil)))
1187                (when circular-ref
1188                  (setf (cdr circular-ref)
1189                        (append (cdr circular-ref) (cdr info))))))))))))
1190 \f
1191 ;;;; COMPILE-FILE
1192
1193 ;;; We build a list of top-level lambdas, and then periodically smash
1194 ;;; them together into a single component and compile it.
1195 (defvar *pending-top-level-lambdas*)
1196
1197 ;;; The maximum number of top-level lambdas we put in a single
1198 ;;; top-level component.
1199 ;;;
1200 ;;; CMU CL 18b used this nontrivially by default (setting it to 10)
1201 ;;; but consequently suffered from the inability to execute some
1202 ;;; troublesome constructs correctly, e.g. inability to load a fasl
1203 ;;; file compiled from the source file
1204 ;;;   (defpackage "FOO" (:use "CL"))
1205 ;;;   (print 'foo::bar)
1206 ;;; because it would dump data-setup fops (including a FOP-PACKAGE for
1207 ;;; "FOO") for the second form before dumping the the code in the
1208 ;;; first form, or the fop to execute the code in the first form. By
1209 ;;; setting this value to 0 by default, we avoid this badness. This
1210 ;;; increases the number of toplevel form functions, and so increases
1211 ;;; the size of object files.
1212 ;;;
1213 ;;; The variable is still supported because when we are compiling the
1214 ;;; SBCL system itself, which is known not contain any troublesome
1215 ;;; constructs, we can set it to a nonzero value, which reduces the
1216 ;;; number of toplevel form objects, reducing the peak memory usage in
1217 ;;; GENESIS, which is desirable, since at least for SBCL version
1218 ;;; 0.6.7, this is the high water mark for memory usage during system
1219 ;;; construction.
1220 (defparameter *top-level-lambda-max* 0)
1221
1222 (defun object-call-top-level-lambda (tll)
1223   (declare (type functional tll))
1224   (let ((object *compile-object*))
1225     (etypecase object
1226       (fasl-file
1227        (fasl-dump-top-level-lambda-call tll object))
1228       (core-object
1229        (core-call-top-level-lambda tll object))
1230       (null))))
1231
1232 ;;; Add LAMBDAS to the pending lambdas. If this leaves more than
1233 ;;; *TOP-LEVEL-LAMBDA-MAX* lambdas in the list, or if FORCE-P is true,
1234 ;;; then smash the lambdas into a single component, compile it, and
1235 ;;; call the resulting function.
1236 (defun sub-compile-top-level-lambdas (lambdas force-p)
1237   (declare (list lambdas))
1238   (setq *pending-top-level-lambdas*
1239         (append *pending-top-level-lambdas* lambdas))
1240   (let ((pending *pending-top-level-lambdas*))
1241     (when (and pending
1242                (or (> (length pending) *top-level-lambda-max*)
1243                    force-p))
1244       (multiple-value-bind (component tll) (merge-top-level-lambdas pending)
1245         (setq *pending-top-level-lambdas* ())
1246         (let ((*byte-compile* (if (eq *byte-compile* :maybe)
1247                                   *byte-compile-top-level*
1248                                   *byte-compile*)))
1249           (compile-component component))
1250         (clear-ir1-info component)
1251         (object-call-top-level-lambda tll))))
1252   (values))
1253
1254 ;;; Compile top-level code and call the top-level lambdas. We pick off
1255 ;;; top-level lambdas in non-top-level components here, calling
1256 ;;; SUB-c-t-l-l on each subsequence of normal top-level lambdas.
1257 (defun compile-top-level-lambdas (lambdas force-p)
1258   (declare (list lambdas))
1259   (let ((len (length lambdas)))
1260     (flet ((loser (start)
1261              (or (position-if #'(lambda (x)
1262                                   (not (eq (component-kind
1263                                             (block-component
1264                                              (node-block
1265                                               (lambda-bind x))))
1266                                            :top-level)))
1267                               lambdas
1268                               :start start)
1269                  len)))
1270       (do* ((start 0 (1+ loser))
1271             (loser (loser start) (loser start)))
1272            ((>= start len)
1273             (when force-p
1274               (sub-compile-top-level-lambdas nil t)))
1275         (sub-compile-top-level-lambdas (subseq lambdas start loser)
1276                                        (or force-p (/= loser len)))
1277         (unless (= loser len)
1278           (object-call-top-level-lambda (elt lambdas loser))))))
1279   (values))
1280
1281 ;;; Compile LAMBDAS (a list of the lambdas for top-level forms) into
1282 ;;; the object file. We loop doing local call analysis until it
1283 ;;; converges, since a single pass might miss something due to
1284 ;;; components being joined by LET conversion.
1285 ;;;
1286 ;;; LOAD-TIME-VALUE-P seems to control whether it's MAKE-LOAD-FORM and
1287 ;;; COMPILE-LOAD-TIME-VALUE stuff. -- WHN 20000201
1288 (defun compile-top-level (lambdas load-time-value-p)
1289   (declare (list lambdas))
1290   (maybe-mumble "locall ")
1291   (loop
1292     (let ((did-something nil))
1293       (dolist (lambda lambdas)
1294         (let* ((component (block-component (node-block (lambda-bind lambda))))
1295                (*all-components* (list component)))
1296           (when (component-new-functions component)
1297             (setq did-something t)
1298             (local-call-analyze component))))
1299       (unless did-something (return))))
1300
1301   (maybe-mumble "IDFO ")
1302   (multiple-value-bind (components top-components hairy-top)
1303       (find-initial-dfo lambdas)
1304     (let ((*all-components* (append components top-components))
1305           (top-level-closure nil))
1306       (when *check-consistency*
1307         (maybe-mumble "[check]~%")
1308         (check-ir1-consistency *all-components*))
1309
1310       (dolist (component (append hairy-top top-components))
1311         (when (pre-environment-analyze-top-level component)
1312           (setq top-level-closure t)))
1313
1314       (let ((*byte-compile*
1315              (if (and top-level-closure (eq *byte-compile* :maybe))
1316                  nil
1317                  *byte-compile*)))
1318         (dolist (component components)
1319           (compile-component component)
1320           (when (replace-top-level-xeps component)
1321             (setq top-level-closure t)))
1322
1323         (when *check-consistency*
1324           (maybe-mumble "[check]~%")
1325           (check-ir1-consistency *all-components*))
1326
1327         (if load-time-value-p
1328             (compile-load-time-value-lambda lambdas)
1329             (compile-top-level-lambdas lambdas top-level-closure)))
1330
1331       (dolist (component components)
1332         (clear-ir1-info component))
1333       (clear-stuff)))
1334   (values))
1335
1336 ;;; Actually compile any stuff that has been queued up for block
1337 ;;; compilation.
1338 (defun finish-block-compilation ()
1339   (when *block-compile*
1340     (when *top-level-lambdas*
1341       (compile-top-level (nreverse *top-level-lambdas*) nil)
1342       (setq *top-level-lambdas* ()))
1343     (setq *block-compile* nil)
1344     (setq *entry-points* nil)))
1345
1346 ;;; Read all forms from INFO and compile them, with output to OBJECT.
1347 ;;; Return (VALUES NIL WARNINGS-P FAILURE-P).
1348 (defun sub-compile-file (info &optional d-s-info)
1349   (declare (type source-info info))
1350   (let* (;; These are bound in WITH-COMPILATION-UNIT now. -- WHN 20000308
1351          #+nil (*compiler-error-count* 0)
1352          #+nil (*compiler-warning-count* 0)
1353          #+nil (*compiler-style-warning-count* 0)
1354          #+nil (*compiler-note-count* 0)
1355          (*block-compile* *block-compile-argument*)
1356          (*package* (sane-package))
1357          (*initial-package* (sane-package))
1358          (*initial-cookie* *default-cookie*)
1359          (*initial-interface-cookie* *default-interface-cookie*)
1360          (*default-cookie* (copy-cookie *initial-cookie*))
1361          (*default-interface-cookie*
1362           (copy-cookie *initial-interface-cookie*))
1363          (*lexenv* (make-null-lexenv))
1364          (*converting-for-interpreter* nil)
1365          (*source-info* info)
1366          (sb!xc:*compile-file-pathname* nil)
1367          (sb!xc:*compile-file-truename* nil)
1368          (*top-level-lambdas* ())
1369          (*pending-top-level-lambdas* ())
1370          (*compiler-error-bailout*
1371           #'(lambda ()
1372               (compiler-mumble
1373                ;; MNA: compiler message patch
1374                "~2&; fatal error, aborting compilation~%")
1375               (return-from sub-compile-file (values nil t t))))
1376          (*current-path* nil)
1377          (*last-source-context* nil)
1378          (*last-original-source* nil)
1379          (*last-source-form* nil)
1380          (*last-format-string* nil)
1381          (*last-format-args* nil)
1382          (*last-message-count* 0)
1383          (*info-environment* (or *backend-info-environment*
1384                                  *info-environment*))
1385          (*gensym-counter* 0))
1386     (with-compilation-values
1387       (sb!xc:with-compilation-unit ()
1388         (clear-stuff)
1389
1390         (process-sources info)
1391
1392         (finish-block-compilation)
1393         (compile-top-level-lambdas () t)
1394         (let ((object *compile-object*))
1395           (etypecase object
1396             (fasl-file (fasl-dump-source-info info object))
1397             (core-object (fix-core-source-info info object d-s-info))
1398             (null)))
1399         nil))))
1400
1401 ;;; Return a list of pathnames for the named files. All the files must
1402 ;;; exist.
1403 (defun verify-source-files (stuff)
1404   (let* ((stuff (if (listp stuff) stuff (list stuff)))
1405          (default-host (make-pathname
1406                         :host (pathname-host (pathname (first stuff))))))
1407     (flet ((try-with-type (path type error-p)
1408              (let ((new (merge-pathnames
1409                          path (make-pathname :type type
1410                                              :defaults default-host))))
1411                (if (probe-file new)
1412                    new
1413                    (and error-p (truename new))))))
1414       (unless stuff
1415         (error "can't compile with no source files"))
1416       (mapcar #'(lambda (x)
1417                   (let ((x (pathname x)))
1418                     (cond ((typep x 'logical-pathname)
1419                            (try-with-type x "LISP" t))
1420                           ((probe-file x) x)
1421                           ((try-with-type x "lisp"  nil))
1422                           ((try-with-type x "lisp"  t)))))
1423               stuff))))
1424
1425 (defun elapsed-time-to-string (tsec)
1426   (multiple-value-bind (tmin sec) (truncate tsec 60)
1427     (multiple-value-bind (thr min) (truncate tmin 60)
1428       (format nil "~D:~2,'0D:~2,'0D" thr min sec))))
1429
1430 ;;; Print some junk at the beginning and end of compilation.
1431 (defun start-error-output (source-info)
1432   (declare (type source-info source-info))
1433   (dolist (x (source-info-files source-info))
1434     ;; MNA: compiler message patch
1435     (compiler-mumble "~&; compiling file ~S (written ~A):~%"
1436                      (namestring (file-info-name x))
1437                      (sb!int:format-universal-time nil
1438                                                    (file-info-write-date x)
1439                                                    :style :government
1440                                                    :print-weekday nil
1441                                                    :print-timezone nil)))
1442   (values))
1443
1444 (defun finish-error-output (source-info won)
1445   (declare (type source-info source-info))
1446   ;; MNA: compiler message patch
1447   (compiler-mumble "~&; compilation ~:[aborted after~;finished in~] ~A~&"
1448                    won
1449                    (elapsed-time-to-string
1450                     (- (get-universal-time)
1451                        (source-info-start-time source-info))))
1452   (values))
1453
1454 ;;; Open some files and call SUB-COMPILE-FILE. If something unwinds
1455 ;;; out of the compile, then abort the writing of the output file, so
1456 ;;; we don't overwrite it with known garbage.
1457 (defun sb!xc:compile-file
1458     (source
1459      &key
1460      (output-file t) ; FIXME: ANSI says this should be a pathname designator.
1461      ;; FIXME: ANSI doesn't seem to say anything about
1462      ;; *COMPILE-VERBOSE* and *COMPILE-PRINT* being rebound by this
1463      ;; function..
1464      ((:verbose sb!xc:*compile-verbose*) sb!xc:*compile-verbose*)
1465      ((:print sb!xc:*compile-print*) sb!xc:*compile-print*)
1466      (external-format :default)
1467      ((:block-compile *block-compile-argument*) nil)
1468      ((:entry-points *entry-points*) nil)
1469      ((:byte-compile *byte-compile*) *byte-compile-default*))
1470   #!+sb-doc
1471   "Compile SOURCE, producing a corresponding FASL file.
1472    :Output-File
1473       The name of the fasl to output, NIL for none, T for the default.
1474    :Block-Compile
1475       Determines whether multiple functions are compiled together as a unit,
1476       resolving function references at compile time. NIL means that global
1477       function names are never resolved at compilation time.
1478    :Entry-Points
1479       This specifies a list of function names for functions in the file(s) that
1480       must be given global definitions. This only applies to block
1481       compilation. If the value is NIL (the default) then all functions
1482       will be globally defined.
1483    :Byte-Compile {T | NIL | :MAYBE}
1484       Determines whether to compile into interpreted byte code instead of
1485       machine instructions. Byte code is several times smaller, but much
1486       slower. If :MAYBE, then only byte-compile when SPEED is 0 and
1487       DEBUG <= 1. The default is the value of SB-EXT:*BYTE-COMPILE-DEFAULT*,
1488       which is initially :MAYBE."
1489   (unless (eq external-format :default)
1490     (error "Non-:DEFAULT EXTERNAL-FORMAT values are not supported."))
1491   (let* ((fasl-file nil)
1492          (output-file-name nil)
1493          (compile-won nil)
1494          (warnings-p nil)
1495          (failure-p t) ; T in case error keeps this from being set later
1496
1497          ;; KLUDGE: The listifying and unlistifying in the next calls
1498          ;; is to interface to old CMU CL code which accepted and
1499          ;; returned lists of multiple source files. It would be
1500          ;; cleaner to redo VERIFY-SOURCE-FILES and as
1501          ;; VERIFY-SOURCE-FILE, accepting a single source file, and
1502          ;; do a similar transformation on MAKE-FILE-SOURCE-INFO too.
1503          ;; -- WHN 20000201
1504          (source (first (verify-source-files (list source))))
1505          (source-info (make-file-source-info (list source))))
1506     (unwind-protect
1507         (progn
1508           (when output-file
1509             (setq output-file-name
1510                   (sb!xc:compile-file-pathname source
1511                                                :output-file output-file
1512                                                :byte-compile *byte-compile*))
1513             (setq fasl-file
1514                   (open-fasl-file output-file-name
1515                                   (namestring source)
1516                                   (eq *byte-compile* t))))
1517
1518           (when sb!xc:*compile-verbose*
1519             (start-error-output source-info))
1520           (let ((*compile-object* fasl-file)
1521                 dummy)
1522             (multiple-value-setq (dummy warnings-p failure-p)
1523               (sub-compile-file source-info)))
1524           (setq compile-won t))
1525
1526       (close-source-info source-info)
1527
1528       (when fasl-file
1529         (close-fasl-file fasl-file (not compile-won))
1530         (setq output-file-name (pathname (fasl-file-stream fasl-file)))
1531         (when (and compile-won sb!xc:*compile-verbose*)
1532           ;; MNA: compiler message patch
1533           (compiler-mumble "~2&; ~A written~%" (namestring output-file-name))))
1534
1535       (when sb!xc:*compile-verbose*
1536         (finish-error-output source-info compile-won)))
1537
1538     (values (if output-file
1539                 ;; Hack around filesystem race condition...
1540                 (or (probe-file output-file-name) output-file-name)
1541                 nil)
1542             warnings-p
1543             failure-p)))
1544 \f
1545 (defun sb!xc:compile-file-pathname (file-path
1546                                     &key (output-file t) byte-compile
1547                                     &allow-other-keys)
1548   #!+sb-doc
1549   "Return a pathname describing what file COMPILE-FILE would write to given
1550    these arguments."
1551   (declare (values (or null pathname)))
1552   (let ((pathname (pathname file-path)))
1553     (cond ((not (eq output-file t))
1554            (when output-file
1555              (translate-logical-pathname (pathname output-file))))
1556           ((and (typep pathname 'logical-pathname) (not (eq byte-compile t)))
1557            (make-pathname :type "FASL" :defaults pathname
1558                           :case :common))
1559           (t
1560            (make-pathname :defaults (translate-logical-pathname pathname)
1561                           :type (if (eq byte-compile t)
1562                                     (backend-byte-fasl-file-type)
1563                                     *backend-fasl-file-type*))))))