src/compiler/main.lisp

   1 ;;;; the top-level interfaces to the compiler
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13
  14 ;;; FIXME: Doesn't this belong somewhere else, like early-c.lisp?
  15 (declaim (special *constants* *free-variables* *component-being-compiled*
  16                   *code-vector* *next-location* *result-fixups*
  17                   *free-functions* *source-paths*
  18                   *seen-blocks* *seen-functions* *list-conflicts-table*
  19                   *continuation-number* *continuation-numbers*
  20                   *number-continuations* *tn-id* *tn-ids* *id-tns*
  21                   *label-ids* *label-id* *id-labels*
  22                   *undefined-warnings* *compiler-error-count*
  23                   *compiler-warning-count* *compiler-style-warning-count*
  24                   *compiler-note-count*
  25                   *compiler-error-bailout*
  26                   #!+sb-show *compiler-trace-output*
  27                   *last-source-context* *last-original-source*
  28                   *last-source-form* *last-format-string* *last-format-args*
  29                   *last-message-count* *lexenv*))
  30
  31 (defvar *byte-compile-default* :maybe
  32   #!+sb-doc
  33   "the default value for the :BYTE-COMPILE argument to COMPILE-FILE")
  34
  35 (defvar *byte-compile-top-level*
  36   #-sb-xc-host t
  37   #+sb-xc-host nil ; since the byte compiler isn't supported in cross-compiler
  38   #!+sb-doc
  39   "Similar to *BYTE-COMPILE-DEFAULT*, but controls the compilation of top-level
  40    forms (evaluated at load-time) when the :BYTE-COMPILE argument is :MAYBE
  41    (the default.)  When true, we decide to byte-compile.")
  42
  43 ;;; default value of the :BYTE-COMPILE argument to the compiler
  44 (defvar *byte-compile* :maybe)
  45
  46 ;;; Bound by COMPILE-COMPONENT to T when byte-compiling, and NIL when
  47 ;;; native compiling. During IR1 conversion this can also be :MAYBE,
  48 ;;; in which case we must look at the policy, see (byte-compiling).
  49 (defvar *byte-compiling* :maybe)
  50 (declaim (type (member t nil :maybe) *byte-compile* *byte-compiling*
  51                *byte-compile-default*))
  52
  53 (defvar *check-consistency* nil)
  54 (defvar *all-components*)
  55
  56 ;;; Bind this to a stream to capture various internal debugging output.
  57 #!+sb-show
  58 (defvar *compiler-trace-output* nil)
  59
  60 ;;; The current block compilation state. These are initialized to the
  61 ;;; :BLOCK-COMPILE and :ENTRY-POINTS arguments that COMPILE-FILE was
  62 ;;; called with.
  63 ;;;
  64 ;;; *BLOCK-COMPILE-ARGUMENT* holds the original value of the
  65 ;;; :BLOCK-COMPILE argument, which overrides any internal
  66 ;;; declarations.
  67 (defvar *block-compile*)
  68 (defvar *block-compile-argument*)
  69 (declaim (type (member nil t :specified)
  70                *block-compile* *block-compile-argument*))
  71 (defvar *entry-points*)
  72 (declaim (list *entry-points*))
  73
  74 ;;; When block compiling, used by PROCESS-FORM to accumulate top-level
  75 ;;; lambdas resulting from compiling subforms. (In reverse order.)
  76 (defvar *top-level-lambdas*)
  77 (declaim (list *top-level-lambdas*))
  78
  79 (defvar sb!xc:*compile-verbose* t
  80   #!+sb-doc
  81   "The default for the :VERBOSE argument to COMPILE-FILE.")
  82 (defvar sb!xc:*compile-print* t
  83   #!+sb-doc
  84   "The default for the :PRINT argument to COMPILE-FILE.")
  85 (defvar *compile-progress* nil
  86   #!+sb-doc
  87   "When this is true, the compiler prints to *ERROR-OUTPUT* progress
  88   information about the phases of compilation of each function. (This
  89   is useful mainly in large block compilations.)")
  90
  91 (defvar sb!xc:*compile-file-pathname* nil
  92   #!+sb-doc
  93   "The defaulted pathname of the file currently being compiled, or NIL if not
  94   compiling.")
  95 (defvar sb!xc:*compile-file-truename* nil
  96   #!+sb-doc
  97   "The TRUENAME of the file currently being compiled, or NIL if not
  98   compiling.")
  99
 100 (declaim (type (or pathname null)
 101                sb!xc:*compile-file-pathname*
 102                sb!xc:*compile-file-truename*))
 103
 104 ;;; the values of *PACKAGE* and policy when compilation started
 105 (defvar *initial-package*)
 106 (defvar *initial-cookie*)
 107 (defvar *initial-interface-cookie*)
 108
 109 ;;; The source-info structure for the current compilation. This is null
 110 ;;; globally to indicate that we aren't currently in any identifiable
 111 ;;; compilation.
 112 (defvar *source-info* nil)
 113
 114 ;;; True if we are within a WITH-COMPILATION-UNIT form (which normally
 115 ;;; causes nested uses to be no-ops).
 116 (defvar *in-compilation-unit* nil)
 117
 118 ;;; Count of the number of compilation units dynamically enclosed by
 119 ;;; the current active WITH-COMPILATION-UNIT that were unwound out of.
 120 (defvar *aborted-compilation-unit-count*)
 121
 122 ;;; Mumble conditional on *COMPILE-PROGRESS*.
 123 (defun maybe-mumble (&rest foo)
 124   (when *compile-progress*
 125     (compiler-mumble "~&")
 126     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 127        (apply #'compiler-mumble foo))))
 128
 129 (deftype object () '(or fasl-file core-object null))
 130
 131 (defvar *compile-object* nil)
 132 (declaim (type object *compile-object*))
 133 \f
 134 ;;;; WITH-COMPILATION-UNIT and WITH-COMPILATION-VALUES
 135
 136 (defmacro sb!xc:with-compilation-unit (options &body body)
 137   #!+sb-doc
 138   "WITH-COMPILATION-UNIT ({Key Value}*) Form*
 139   This form affects compilations that take place within its dynamic extent. It
 140   is intended to be wrapped around the compilation of all files in the same
 141   system. These keywords are defined:
 142     :OVERRIDE Boolean-Form
 143         One of the effects of this form is to delay undefined warnings
 144         until the end of the form, instead of giving them at the end of each
 145         compilation. If OVERRIDE is NIL (the default), then the outermost
 146         WITH-COMPILATION-UNIT form grabs the undefined warnings. Specifying
 147         OVERRIDE true causes that form to grab any enclosed warnings, even if
 148         it is enclosed by another WITH-COMPILATION-UNIT."
 149   `(%with-compilation-unit (lambda () ,@body) ,@options))
 150
 151 (defun %with-compilation-unit (fn &key override)
 152   (let ((succeeded-p nil))
 153     (if (and *in-compilation-unit* (not override))
 154         ;; Inside another WITH-COMPILATION-UNIT, a WITH-COMPILATION-UNIT is
 155         ;; ordinarily (unless OVERRIDE) basically a no-op.
 156         (unwind-protect
 157             (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 158           (unless succeeded-p
 159             (incf *aborted-compilation-unit-count*)))
 160         ;; FIXME: Now *COMPILER-FOO-COUNT* stuff is bound in more than
 161         ;; one place. If we can get rid of the IR1 interpreter, this
 162         ;; should be easier to clean up.
 163         (let ((*aborted-compilation-unit-count* 0)
 164               (*compiler-error-count* 0)
 165               (*compiler-warning-count* 0)
 166               (*compiler-style-warning-count* 0)
 167               (*compiler-note-count* 0)
 168               (*undefined-warnings* nil)
 169               (*in-compilation-unit* t))
 170           (handler-bind ((parse-unknown-type
 171                           (lambda (c)
 172                             (note-undefined-reference
 173                              (parse-unknown-type-specifier c)
 174                              :type))))
 175             (unwind-protect
 176                 (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 177               (unless succeeded-p
 178                 (incf *aborted-compilation-unit-count*))
 179               (summarize-compilation-unit (not succeeded-p))))))))
 180
 181 ;;; This is to be called at the end of a compilation unit. It signals
 182 ;;; any residual warnings about unknown stuff, then prints the total
 183 ;;; error counts. ABORT-P should be true when the compilation unit was
 184 ;;; aborted by throwing out. ABORT-COUNT is the number of dynamically
 185 ;;; enclosed nested compilation units that were aborted.
 186 (defun summarize-compilation-unit (abort-p)
 187   (unless abort-p
 188     (handler-bind ((style-warning #'compiler-style-warning-handler)
 189                    (warning #'compiler-warning-handler))
 190
 191       (let ((undefs (sort *undefined-warnings* #'string<
 192                           :key #'(lambda (x)
 193                                    (let ((x (undefined-warning-name x)))
 194                                      (if (symbolp x)
 195                                          (symbol-name x)
 196                                          (prin1-to-string x)))))))
 197         (unless *converting-for-interpreter*
 198           (dolist (undef undefs)
 199             (let ((name (undefined-warning-name undef))
 200                   (kind (undefined-warning-kind undef))
 201                   (warnings (undefined-warning-warnings undef))
 202                   (undefined-warning-count (undefined-warning-count undef)))
 203               (dolist (*compiler-error-context* warnings)
 204                 (compiler-style-warning "undefined ~(~A~): ~S" kind name))
 205
 206               (let ((warn-count (length warnings)))
 207                 (when (and warnings (> undefined-warning-count warn-count))
 208                   (let ((more (- undefined-warning-count warn-count)))
 209                     (compiler-style-warning
 210                      "~D more use~:P of undefined ~(~A~) ~S"
 211                      more kind name)))))))
 212
 213         (dolist (kind '(:variable :function :type))
 214           (let ((summary (mapcar #'undefined-warning-name
 215                                  (remove kind undefs :test-not #'eq
 216                                          :key #'undefined-warning-kind))))
 217             (when summary
 218               (compiler-style-warning
 219                "~:[This ~(~A~) is~;These ~(~A~)s are~] undefined:~
 220                 ~%  ~{~<~%  ~1:;~S~>~^ ~}"
 221                (cdr summary) kind summary)))))))
 222
 223   (unless (or *converting-for-interpreter*
 224               (and (not abort-p)
 225                    (zerop *aborted-compilation-unit-count*)
 226                    (zerop *compiler-error-count*)
 227                    (zerop *compiler-warning-count*)
 228                    (zerop *compiler-style-warning-count*)
 229                    (zerop *compiler-note-count*)))
 230     (format *error-output* "~&")
 231     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 232     (compiler-mumble
 233                            "compilation unit ~:[finished~;aborted~]~
 234       ~[~:;~:*~&  caught ~D fatal ERROR condition~:P~]~
 235       ~[~:;~:*~&  caught ~D ERROR condition~:P~]~
 236       ~[~:;~:*~&  caught ~D WARNING condition~:P~]~
 237       ~[~:;~:*~&  caught ~D STYLE-WARNING condition~:P~]~
 238       ~[~:;~:*~&  printed ~D note~:P~]"
 239      abort-p
 240      *aborted-compilation-unit-count*
 241      *compiler-error-count*
 242      *compiler-warning-count*
 243      *compiler-style-warning-count*
 244                            *compiler-note-count*))))
 245
 246 ;;; Evaluate BODY, then return (VALUES BODY-VALUE WARNINGS-P
 247 ;;; FAILURE-P), where BODY-VALUE is the first value of the body, and
 248 ;;; WARNINGS-P and FAILURE-P are as in CL:COMPILE or CL:COMPILE-FILE.
 249 ;;; This also wraps up WITH-IR1-NAMESPACE functionality.
 250 (defmacro with-compilation-values (&body body)
 251   `(with-ir1-namespace
 252     (let ((*warnings-p* nil)
 253           (*failure-p* nil))
 254       (values (progn ,@body)
 255               *warnings-p*
 256               *failure-p*))))
 257 \f
 258 ;;;; component compilation
 259
 260 (defparameter *max-optimize-iterations* 3 ; ARB
 261   #!+sb-doc
 262   "The upper limit on the number of times that we will consecutively do IR1
 263   optimization that doesn't introduce any new code. A finite limit is
 264   necessary, since type inference may take arbitrarily long to converge.")
 265
 266 (defevent ir1-optimize-until-done "IR1-OPTIMIZE-UNTIL-DONE called")
 267 (defevent ir1-optimize-maxed-out "hit *MAX-OPTIMIZE-ITERATIONS* limit")
 268
 269 ;;; Repeatedly optimize COMPONENT until no further optimizations can
 270 ;;; be found or we hit our iteration limit. When we hit the limit, we
 271 ;;; clear the component and block REOPTIMIZE flags to discourage the
 272 ;;; next optimization attempt from pounding on the same code.
 273 (defun ir1-optimize-until-done (component)
 274   (declare (type component component))
 275   (maybe-mumble "opt")
 276   (event ir1-optimize-until-done)
 277   (let ((count 0)
 278         (cleared-reanalyze nil))
 279     (loop
 280       (when (component-reanalyze component)
 281         (setq count 0)
 282         (setq cleared-reanalyze t)
 283         (setf (component-reanalyze component) nil))
 284       (setf (component-reoptimize component) nil)
 285       (ir1-optimize component)
 286       (unless (component-reoptimize component)
 287         (maybe-mumble " ")
 288         (return))
 289       (incf count)
 290       (when (= count *max-optimize-iterations*)
 291         (event ir1-optimize-maxed-out)
 292         (maybe-mumble "* ")
 293         (setf (component-reoptimize component) nil)
 294         (do-blocks (block component)
 295           (setf (block-reoptimize block) nil))
 296         (return))
 297       (maybe-mumble "."))
 298     (when cleared-reanalyze
 299       (setf (component-reanalyze component) t)))
 300   (values))
 301
 302 (defparameter *constraint-propagate* t)
 303 (defparameter *reoptimize-after-type-check-max* 5)
 304
 305 (defevent reoptimize-maxed-out
 306   "*REOPTIMIZE-AFTER-TYPE-CHECK-MAX* exceeded.")
 307
 308 ;;; Iterate doing FIND-DFO until no new dead code is discovered.
 309 (defun dfo-as-needed (component)
 310   (declare (type component component))
 311   (when (component-reanalyze component)
 312     (maybe-mumble "DFO")
 313     (loop
 314       (find-dfo component)
 315       (unless (component-reanalyze component)
 316         (maybe-mumble " ")
 317         (return))
 318       (maybe-mumble ".")))
 319   (values))
 320
 321 ;;; Do all the IR1 phases for a non-top-level component.
 322 (defun ir1-phases (component)
 323   (declare (type component component))
 324   (let ((*constraint-number* 0)
 325         (loop-count 1))
 326     (declare (special *constraint-number*))
 327     (loop
 328       (ir1-optimize-until-done component)
 329       (when (or (component-new-functions component)
 330                 (component-reanalyze-functions component))
 331         (maybe-mumble "locall ")
 332         (local-call-analyze component))
 333       (dfo-as-needed component)
 334       (when *constraint-propagate*
 335         (maybe-mumble "constraint ")
 336         (constraint-propagate component))
 337       (maybe-mumble "type ")
 338       ;; Delay the generation of type checks until the type
 339       ;; constraints have had time to propagate, else the compiler can
 340       ;; confuse itself.
 341       (unless (and (or (component-reoptimize component)
 342                        (component-reanalyze component)
 343                        (component-new-functions component)
 344                        (component-reanalyze-functions component))
 345                    (< loop-count (- *reoptimize-after-type-check-max* 2)))
 346         (generate-type-checks component)
 347         (unless (or (component-reoptimize component)
 348                     (component-reanalyze component)
 349                     (component-new-functions component)
 350                     (component-reanalyze-functions component))
 351           (return)))
 352       (when (>= loop-count *reoptimize-after-type-check-max*)
 353         (maybe-mumble "[reoptimize limit]")
 354         (event reoptimize-maxed-out)
 355         (return))
 356       (incf loop-count)))
 357
 358   (ir1-finalize component)
 359   (values))
 360
 361 (defun native-compile-component (component)
 362   (let ((*code-segment* nil)
 363         (*elsewhere* nil))
 364     (maybe-mumble "GTN ")
 365     (gtn-analyze component)
 366     (maybe-mumble "LTN ")
 367     (ltn-analyze component)
 368     (dfo-as-needed component)
 369     (maybe-mumble "control ")
 370     (control-analyze component #'make-ir2-block)
 371
 372     (when (ir2-component-values-receivers (component-info component))
 373       (maybe-mumble "stack ")
 374       (stack-analyze component)
 375       ;; Assign BLOCK-NUMBER for any cleanup blocks introduced by
 376       ;; stack analysis. There shouldn't be any unreachable code after
 377       ;; control, so this won't delete anything.
 378       (dfo-as-needed component))
 379
 380     (unwind-protect
 381         (progn
 382           (maybe-mumble "IR2tran ")
 383           (init-assembler)
 384           (entry-analyze component)
 385           (ir2-convert component)
 386
 387           (when (policy nil (>= speed cspeed))
 388             (maybe-mumble "copy ")
 389             (copy-propagate component))
 390
 391           (select-representations component)
 392
 393           (when *check-consistency*
 394             (maybe-mumble "check2 ")
 395             (check-ir2-consistency component))
 396
 397           (delete-unreferenced-tns component)
 398
 399           (maybe-mumble "life ")
 400           (lifetime-analyze component)
 401
 402           (when *compile-progress*
 403             (compiler-mumble "") ; Sync before doing more output.
 404             (pre-pack-tn-stats component *error-output*))
 405
 406           (when *check-consistency*
 407             (maybe-mumble "check-life ")
 408             (check-life-consistency component))
 409
 410           (maybe-mumble "pack ")
 411           (pack component)
 412
 413           (when *check-consistency*
 414             (maybe-mumble "check-pack ")
 415             (check-pack-consistency component))
 416
 417           #!+sb-show
 418           (when *compiler-trace-output*
 419             (describe-component component *compiler-trace-output*)
 420             (describe-ir2-component component *compiler-trace-output*))
 421
 422           (maybe-mumble "code ")
 423           (multiple-value-bind (code-length trace-table fixups)
 424               (generate-code component)
 425
 426             #!+sb-show
 427             (when *compiler-trace-output*
 428               (format *compiler-trace-output*
 429                       "~|~%disassembly of code for ~S~2%" component)
 430               (sb!disassem:disassemble-assem-segment *code-segment*
 431                                                      *compiler-trace-output*))
 432
 433             (etypecase *compile-object*
 434               (fasl-file
 435                (maybe-mumble "fasl")
 436                (fasl-dump-component component
 437                                     *code-segment*
 438                                     code-length
 439                                     trace-table
 440                                     fixups
 441                                     *compile-object*))
 442               (core-object
 443                (maybe-mumble "core")
 444                (make-core-component component
 445                                     *code-segment*
 446                                     code-length
 447                                     trace-table
 448                                     fixups
 449                                     *compile-object*))
 450               (null))))))
 451
 452   ;; We are done, so don't bother keeping anything around.
 453   (setf (component-info component) nil)
 454
 455   (values))
 456
 457 ;;; Return our best guess for whether we will byte compile code
 458 ;;; currently being IR1 converted. This is only a guess because the
 459 ;;; decision is made on a per-component basis.
 460 ;;;
 461 ;;; FIXME: This should be called something more mnemonic, e.g.
 462 ;;; PROBABLY-BYTE-COMPILING
 463 (defun byte-compiling ()
 464   (if (eq *byte-compiling* :maybe)
 465       (or (eq *byte-compile* t)
 466           (policy nil (zerop speed) (<= debug 1)))
 467       (and *byte-compile* *byte-compiling*)))
 468
 469 ;;; Delete components with no external entry points before we try to
 470 ;;; generate code. Unreachable closures can cause IR2 conversion to puke on
 471 ;;; itself, since it is the reference to the closure which normally causes the
 472 ;;; components to be combined. This doesn't really cover all cases...
 473 (defun delete-if-no-entries (component)
 474   (dolist (fun (component-lambdas component)
 475                (delete-component component))
 476     (case (functional-kind fun)
 477       (:top-level (return))
 478       (:external
 479        (unless (every #'(lambda (ref)
 480                           (eq (block-component (node-block ref))
 481                               component))
 482                       (leaf-refs fun))
 483          (return))))))
 484
 485 (defun compile-component (component)
 486   (let* ((*component-being-compiled* component)
 487          (*byte-compiling*
 488           (ecase *byte-compile*
 489             ((t) t)
 490             ((nil) nil)
 491             (:maybe
 492              (dolist (fun (component-lambdas component) t)
 493                (unless (policy (lambda-bind fun)
 494                                (zerop speed) (<= debug 1))
 495                  (return nil)))))))
 496
 497     (when sb!xc:*compile-print*
 498       (compiler-mumble "~&; ~:[~;byte ~]compiling ~A: "
 499                        *byte-compiling*
 500                        (component-name component)))
 501
 502     (ir1-phases component)
 503
 504     ;; FIXME: What is MAYBE-MUMBLE for? Do we need it any more?
 505     (maybe-mumble "env ")
 506     (environment-analyze component)
 507     (dfo-as-needed component)
 508
 509     (delete-if-no-entries component)
 510
 511     (unless (eq (block-next (component-head component))
 512                 (component-tail component))
 513       (if *byte-compiling*
 514           (byte-compile-component component)
 515           (native-compile-component component))))
 516
 517   (clear-constant-info)
 518
 519   (when sb!xc:*compile-print*
 520     (compiler-mumble "~&"))
 521
 522   (values))
 523 \f
 524 ;;;; clearing global data structures
 525 ;;;;
 526 ;;;; FIXME: Is it possible to get rid of this stuff, getting rid of
 527 ;;;; global data structures entirely when possible and consing up the
 528 ;;;; others from scratch instead of clearing and reusing them?
 529
 530 ;;; Clear the INFO in constants in the *FREE-VARIABLES*, etc. In
 531 ;;; addition to allowing stuff to be reclaimed, this is required for
 532 ;;; correct assignment of constant offsets, since we need to assign a
 533 ;;; new offset for each component. We don't clear the FUNCTIONAL-INFO
 534 ;;; slots, since they are used to keep track of functions across
 535 ;;; component boundaries.
 536 (defun clear-constant-info ()
 537   (maphash #'(lambda (k v)
 538                (declare (ignore k))
 539                (setf (leaf-info v) nil))
 540            *constants*)
 541   (maphash #'(lambda (k v)
 542                (declare (ignore k))
 543                (when (constant-p v)
 544                  (setf (leaf-info v) nil)))
 545            *free-variables*)
 546   (values))
 547
 548 ;;; Blow away the REFS for all global variables, and let COMPONENT
 549 ;;; be recycled.
 550 (defun clear-ir1-info (component)
 551   (declare (type component component))
 552   (labels ((blast (x)
 553              (maphash #'(lambda (k v)
 554                           (declare (ignore k))
 555                           (when (leaf-p v)
 556                             (setf (leaf-refs v)
 557                                   (delete-if #'here-p (leaf-refs v)))
 558                             (when (basic-var-p v)
 559                               (setf (basic-var-sets v)
 560                                     (delete-if #'here-p (basic-var-sets v))))))
 561                       x))
 562            (here-p (x)
 563              (eq (block-component (node-block x)) component)))
 564     (blast *free-variables*)
 565     (blast *free-functions*)
 566     (blast *constants*))
 567   (values))
 568
 569 ;;; Clear global variables used by the compiler.
 570 ;;;
 571 ;;; FIXME: It seems kinda nasty and unmaintainable to have to do this,
 572 ;;; and it adds overhead even when people aren't using the compiler.
 573 ;;; Perhaps we could make these global vars unbound except when
 574 ;;; actually in use, so that this function could go away.
 575 (defun clear-stuff (&optional (debug-too t))
 576
 577   ;; Clear global tables.
 578   (when (boundp '*free-functions*)
 579     (clrhash *free-functions*)
 580     (clrhash *free-variables*)
 581     (clrhash *constants*))
 582
 583   ;; Clear debug counters and tables.
 584   (clrhash *seen-blocks*)
 585   (clrhash *seen-functions*)
 586   (clrhash *list-conflicts-table*)
 587
 588   (when debug-too
 589     (clrhash *continuation-numbers*)
 590     (clrhash *number-continuations*)
 591     (setq *continuation-number* 0)
 592     (clrhash *tn-ids*)
 593     (clrhash *id-tns*)
 594     (setq *tn-id* 0)
 595     (clrhash *label-ids*)
 596     (clrhash *id-labels*)
 597     (setq *label-id* 0)
 598
 599     ;; Clear some Pack data structures (for GC purposes only).
 600     (assert (not *in-pack*))
 601     (dolist (sb *backend-sb-list*)
 602       (when (finite-sb-p sb)
 603         (fill (finite-sb-live-tns sb) nil))))
 604
 605   ;; (Note: The CMU CL code used to set CL::*GENSYM-COUNTER* to zero here.
 606   ;; Superficially, this seemed harmful -- the user could reasonably be
 607   ;; surprised if *GENSYM-COUNTER* turned back to zero when something was
 608   ;; compiled. A closer inspection showed that this actually turned out to be
 609   ;; harmless in practice, because CLEAR-STUFF was only called from within
 610   ;; forms which bound CL::*GENSYM-COUNTER* to zero. However, this means that
 611   ;; even though zeroing CL::*GENSYM-COUNTER* here turned out to be harmless in
 612   ;; practice, it was also useless in practice. So we don't do it any more.)
 613
 614   (values))
 615 \f
 616 ;;;; trace output
 617
 618 ;;; Print out some useful info about Component to Stream.
 619 (defun describe-component (component *standard-output*)
 620   (declare (type component component))
 621   (format t "~|~%;;;; component: ~S~2%" (component-name component))
 622   (print-blocks component)
 623   (values))
 624
 625 (defun describe-ir2-component (component *standard-output*)
 626   (format t "~%~|~%;;;; IR2 component: ~S~2%" (component-name component))
 627   (format t "entries:~%")
 628   (dolist (entry (ir2-component-entries (component-info component)))
 629     (format t "~4TL~D: ~S~:[~; [closure]~]~%"
 630             (label-id (entry-info-offset entry))
 631             (entry-info-name entry)
 632             (entry-info-closure-p entry)))
 633   (terpri)
 634   (pre-pack-tn-stats component *standard-output*)
 635   (terpri)
 636   (print-ir2-blocks component)
 637   (terpri)
 638   (values))
 639 \f
 640 ;;;; file reading
 641 ;;;;
 642 ;;;; When reading from a file, we have to keep track of some source
 643 ;;;; information. We also exploit our ability to back up for printing
 644 ;;;; the error context and for recovering from errors.
 645 ;;;;
 646 ;;;; The interface we provide to this stuff is the stream-oid
 647 ;;;; Source-Info structure. The bookkeeping is done as a side-effect
 648 ;;;; of getting the next source form.
 649
 650 ;;; The File-Info structure holds all the source information for a
 651 ;;; given file.
 652 (defstruct file-info
 653   ;; If a file, the truename of the corresponding source file. If from a Lisp
 654   ;; form, :LISP, if from a stream, :STREAM.
 655   (name (required-argument) :type (or pathname (member :lisp :stream)))
 656   ;; The defaulted, but not necessarily absolute file name (i.e. prior to
 657   ;; TRUENAME call.)  Null if not a file. This is used to set
 658   ;; *COMPILE-FILE-PATHNAME*, and if absolute, is dumped in the debug-info.
 659   (untruename nil :type (or pathname null))
 660   ;; The file's write date (if relevant.)
 661   (write-date nil :type (or unsigned-byte null))
 662   ;; The source path root number of the first form in this file (i.e. the
 663   ;; total number of forms converted previously in this compilation.)
 664   (source-root 0 :type unsigned-byte)
 665   ;; Parallel vectors containing the forms read out of the file and the file
 666   ;; positions that reading of each form started at (i.e. the end of the
 667   ;; previous form.)
 668   (forms (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t))
 669   (positions (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t)))
 670
 671 ;;; The SOURCE-INFO structure provides a handle on all the source
 672 ;;; information for an entire compilation.
 673 (defstruct (source-info
 674             #-no-ansi-print-object
 675             (:print-object (lambda (s stream)
 676                              (print-unreadable-object (s stream :type t)))))
 677   ;; the UT that compilation started at
 678   (start-time (get-universal-time) :type unsigned-byte)
 679   ;; a list of the FILE-INFO structures for this compilation
 680   (files nil :type list)
 681   ;; the tail of the FILES for the file we are currently reading
 682   (current-file nil :type list)
 683   ;; the stream that we are using to read the CURRENT-FILE, or NIL if
 684   ;; no stream has been opened yet
 685   (stream nil :type (or stream null)))
 686
 687 ;;; Given a list of pathnames, return a SOURCE-INFO structure.
 688 (defun make-file-source-info (files)
 689   (declare (list files))
 690   (let ((file-info
 691          (mapcar (lambda (x)
 692                    (make-file-info :name (truename x)
 693                                    :untruename x
 694                                    :write-date (file-write-date x)))
 695                  files)))
 696
 697     (make-source-info :files file-info
 698                       :current-file file-info)))
 699
 700 ;;; Return a SOURCE-INFO to describe the incremental compilation of
 701 ;;; FORM. Also used by SB!EVAL:INTERNAL-EVAL.
 702 (defun make-lisp-source-info (form)
 703   (make-source-info
 704    :start-time (get-universal-time)
 705    :files (list (make-file-info :name :lisp
 706                                 :forms (vector form)
 707                                 :positions '#(0)))))
 708
 709 ;;; Return a SOURCE-INFO which will read from Stream.
 710 (defun make-stream-source-info (stream)
 711   (let ((files (list (make-file-info :name :stream))))
 712     (make-source-info
 713      :files files
 714      :current-file files
 715      :stream stream)))
 716
 717 ;;; Print an error message for a non-EOF error on STREAM. OLD-POS is a
 718 ;;; preceding file position that hopefully comes before the beginning
 719 ;;; of the line. Of course, this only works on streams that support
 720 ;;; the file-position operation.
 721 (defun normal-read-error (stream old-pos condition)
 722   (declare (type stream stream) (type unsigned-byte old-pos))
 723   (let ((pos (file-position stream)))
 724     (file-position stream old-pos)
 725     (let ((start old-pos))
 726       (loop
 727         (let ((line (read-line stream nil))
 728               (end (file-position stream)))
 729           (when (>= end pos)
 730             ;; FIXME: READER-ERROR also prints the file position. Do we really
 731             ;; need to try to give position information here?
 732             (compiler-abort "read error at ~D:~% \"~A/\\~A\"~%~A"
 733                             pos
 734                             (string-left-trim "         "
 735                                               (subseq line 0 (- pos start)))
 736                             (subseq line (- pos start))
 737                             condition)
 738             (return))
 739           (setq start end)))))
 740   (values))
 741
 742 ;;; Back STREAM up to the position Pos, then read a form with
 743 ;;; *READ-SUPPRESS* on, discarding the result. If an error happens
 744 ;;; during this read, then bail out using COMPILER-ERROR (fatal in
 745 ;;; this context).
 746 (defun ignore-error-form (stream pos)
 747   (declare (type stream stream) (type unsigned-byte pos))
 748   (file-position stream pos)
 749   (handler-case (let ((*read-suppress* t))
 750                   (read stream))
 751     (error (condition)
 752       (declare (ignore condition))
 753       (compiler-error "unable to recover from read error"))))
 754
 755 ;;; Print an error message giving some context for an EOF error. We
 756 ;;; print the first line after POS that contains #\" or #\(, or
 757 ;;; lacking that, the first non-empty line.
 758 (defun unexpected-eof-error (stream pos condition)
 759   (declare (type stream stream) (type unsigned-byte pos))
 760   (let ((res nil))
 761     (file-position stream pos)
 762     (loop
 763       (let ((line (read-line stream nil nil)))
 764         (unless line (return))
 765         (when (or (find #\" line) (find #\( line))
 766           (setq res line)
 767           (return))
 768         (unless (or res (zerop (length line)))
 769           (setq res line))))
 770     (compiler-abort "read error in form starting at ~D:~%~@[ \"~A\"~%~]~A"
 771                     pos
 772                     res
 773                     condition))
 774   (file-position stream (file-length stream))
 775   (values))
 776
 777 ;;; Read a form from STREAM, returning EOF at EOF. If a read error
 778 ;;; happens, then attempt to recover if possible, returning a proxy
 779 ;;; error form.
 780 ;;;
 781 ;;; FIXME: This seems like quite a lot of complexity, and it seems
 782 ;;; impossible to get it quite right. (E.g. the `(CERROR ..) form
 783 ;;; returned here won't do the right thing if it's not in a position
 784 ;;; for an executable form.) I think it might be better to just stop
 785 ;;; trying to recover from read errors, punting all this noise
 786 ;;; (including UNEXPECTED-EOF-ERROR and IGNORE-ERROR-FORM) and doing a
 787 ;;; COMPILER-ABORT instead.
 788 (defun careful-read (stream eof pos)
 789   (handler-case (read stream nil eof)
 790     (error (condition)
 791       (let ((new-pos (file-position stream)))
 792         (cond ((= new-pos (file-length stream))
 793                (unexpected-eof-error stream pos condition))
 794               (t
 795                (normal-read-error stream pos condition)
 796                (ignore-error-form stream pos))))
 797       '(cerror "Skip this form."
 798                "compile-time read error"))))
 799
 800 ;;; If Stream is present, return it, otherwise open a stream to the
 801 ;;; current file. There must be a current file. When we open a new
 802 ;;; file, we also reset *PACKAGE* and policy. This gives the effect of
 803 ;;; rebinding around each file.
 804 ;;;
 805 ;;; FIXME: Since we now do the standard ANSI thing of only one file
 806 ;;; per compile (unlike the CMU CL extended COMPILE-FILE) can't this
 807 ;;; complexity (including ADVANCE-SOURCE-FILE) go away?
 808 (defun get-source-stream (info)
 809   (declare (type source-info info))
 810   (cond ((source-info-stream info))
 811         (t
 812          (setq *package* *initial-package*)
 813          (setq *default-cookie* (copy-cookie *initial-cookie*))
 814          (setq *default-interface-cookie*
 815                (copy-cookie *initial-interface-cookie*))
 816          (let* ((finfo (first (source-info-current-file info)))
 817                 (name (file-info-name finfo)))
 818            (setq sb!xc:*compile-file-truename* name)
 819            (setq sb!xc:*compile-file-pathname* (file-info-untruename finfo))
 820            (setf (source-info-stream info)
 821                  (open name :direction :input))))))
 822
 823 ;;; Close the stream in INFO if it is open.
 824 (defun close-source-info (info)
 825   (declare (type source-info info))
 826   (let ((stream (source-info-stream info)))
 827     (when stream (close stream)))
 828   (setf (source-info-stream info) nil)
 829   (values))
 830
 831 ;;; Advance INFO to the next source file. If there is no next source
 832 ;;; file, return NIL, otherwise T.
 833 (defun advance-source-file (info)
 834   (declare (type source-info info))
 835   (close-source-info info)
 836   (let ((prev (pop (source-info-current-file info))))
 837     (if (source-info-current-file info)
 838         (let ((current (first (source-info-current-file info))))
 839           (setf (file-info-source-root current)
 840                 (+ (file-info-source-root prev)
 841                    (length (file-info-forms prev))))
 842           t)
 843         nil)))
 844
 845 ;;; Read the sources from the source files and process them.
 846 (defun process-sources (info)
 847   (let* ((file (first (source-info-current-file info)))
 848          (stream (get-source-stream info)))
 849     (loop
 850      (let* ((pos (file-position stream))
 851             (eof '(*eof*))
 852             (form (careful-read stream eof pos)))
 853        (if (eq form eof)
 854          (return)
 855          (let* ((forms (file-info-forms file))
 856                 (current-idx (+ (fill-pointer forms)
 857                                 (file-info-source-root file))))
 858            (vector-push-extend form forms)
 859            (vector-push-extend pos (file-info-positions file))
 860            (clrhash *source-paths*)
 861            (find-source-paths form current-idx)
 862            (process-top-level-form form
 863                                    `(original-source-start 0 ,current-idx))))))
 864     (when (advance-source-file info)
 865       (process-sources info))))
 866
 867 ;;; Return the FILE-INFO describing the INDEX'th form.
 868 (defun find-file-info (index info)
 869   (declare (type index index) (type source-info info))
 870   (dolist (file (source-info-files info))
 871     (when (> (+ (length (file-info-forms file))
 872                 (file-info-source-root file))
 873              index)
 874       (return file))))
 875
 876 ;;; Return the INDEX'th source form read from INFO and the position
 877 ;;; where it was read.
 878 (defun find-source-root (index info)
 879   (declare (type source-info info) (type index index))
 880   (let* ((file (find-file-info index info))
 881          (idx (- index (file-info-source-root file))))
 882     (values (aref (file-info-forms file) idx)
 883             (aref (file-info-positions file) idx))))
 884 \f
 885 ;;;; top-level form processing
 886
 887 ;;; This is called by top-level form processing when we are ready to
 888 ;;; actually compile something. If *BLOCK-COMPILE* is T, then we still
 889 ;;; convert the form, but delay compilation, pushing the result on
 890 ;;; *TOP-LEVEL-LAMBDAS* instead.
 891 (defun convert-and-maybe-compile (form path)
 892   (declare (list path))
 893   (let* ((*lexenv* (make-lexenv :cookie *default-cookie*
 894                                 :interface-cookie *default-interface-cookie*))
 895          (tll (ir1-top-level form path nil)))
 896     (cond ((eq *block-compile* t) (push tll *top-level-lambdas*))
 897           (t (compile-top-level (list tll) nil)))))
 898
 899 ;;; Process a PROGN-like portion of a top-level form. Forms is a list of
 900 ;;; the forms, and Path is source path of the form they came out of.
 901 (defun process-top-level-progn (forms path)
 902   (declare (list forms) (list path))
 903   (dolist (form forms)
 904     (process-top-level-form form path)))
 905
 906 ;;; Macroexpand form in the current environment with an error handler.
 907 ;;; We only expand one level, so that we retain all the intervening
 908 ;;; forms in the source path.
 909 (defun preprocessor-macroexpand (form)
 910   (handler-case (sb!xc:macroexpand-1 form *lexenv*)
 911     (error (condition)
 912        (compiler-error "(during macroexpansion)~%~A" condition))))
 913
 914 ;;; Process a top-level use of LOCALLY. We parse declarations and then
 915 ;;; recursively process the body.
 916 ;;;
 917 ;;; Binding *DEFAULT-xxx-COOKIE* is pretty much of a hack, since it
 918 ;;; causes LOCALLY to "capture" enclosed proclamations. It is
 919 ;;; necessary because CONVERT-AND-MAYBE-COMPILE uses the value of
 920 ;;; *DEFAULT-COOKIE* as the policy. The need for this hack is due to
 921 ;;; the quirk that there is no way to represent in a cookie that an
 922 ;;; optimize quality came from the default.
 923 (defun process-top-level-locally (form path)
 924   (declare (list path))
 925   (multiple-value-bind (forms decls) (sb!sys:parse-body (cdr form) nil)
 926     (let* ((*lexenv*
 927             (process-decls decls nil nil (make-continuation)))
 928            (*default-cookie* (lexenv-cookie *lexenv*))
 929            (*default-interface-cookie* (lexenv-interface-cookie *lexenv*)))
 930       (process-top-level-progn forms path))))
 931
 932 ;;; Force any pending top-level forms to be compiled and dumped so
 933 ;;; that they will be evaluated in the correct package environment.
 934 ;;; Dump the form to be evaled at (cold) load time, and if EVAL is
 935 ;;; true, eval the form immediately.
 936 (defun process-cold-load-form (form path eval)
 937   (let ((object *compile-object*))
 938     (etypecase object
 939       (fasl-file
 940        (compile-top-level-lambdas () t)
 941        (fasl-dump-cold-load-form form object))
 942       ((or null core-object)
 943        (convert-and-maybe-compile form path)))
 944     (when eval
 945       (eval form))))
 946
 947 (declaim (special *compiler-error-bailout*))
 948
 949 ;;; Process a top-level FORM with the specified source PATH.
 950 ;;;  * If this is a magic top-level form, then do stuff.
 951 ;;;  * If this is a macro, then expand it.
 952 ;;;  * Otherwise, just compile it.
 953 (defun process-top-level-form (form path)
 954
 955   (declare (list path))
 956
 957   (catch 'process-top-level-form-error-abort
 958     (let* ((path (or (gethash form *source-paths*) (cons form path)))
 959            (*compiler-error-bailout*
 960             #'(lambda ()
 961                 (convert-and-maybe-compile
 962                  `(error "execution of a form compiled with errors:~% ~S"
 963                          ',form)
 964                  path)
 965                 (throw 'process-top-level-form-error-abort nil))))
 966       (if (atom form)
 967           (convert-and-maybe-compile form path)
 968           (case (car form)
 969             ;; FIXME: It's not clear to me why we would want this
 970             ;; special case; it might have been needed for some
 971             ;; variation of the old GENESIS system, but it certainly
 972             ;; doesn't seem to be needed for ours. Sometime after the
 973             ;; system is running I'd like to remove it tentatively and
 974             ;; see whether anything breaks, and if nothing does break,
 975             ;; remove it permanently. (And if we *do* want special
 976             ;; treatment of all these, we probably want to treat WARN
 977             ;; the same way..)
 978             ((error cerror break signal)
 979              (process-cold-load-form form path nil))
 980             ;; FIXME: ANSI seems to encourage things like DEFSTRUCT to
 981             ;; be done with EVAL-WHEN, without this kind of one-off
 982             ;; compiler magic.
 983             (sb!kernel:%compiler-defstruct
 984              (convert-and-maybe-compile form path)
 985              (compile-top-level-lambdas () t))
 986             ((eval-when)
 987              (unless (>= (length form) 2)
 988                (compiler-error "EVAL-WHEN form is too short: ~S" form))
 989              (do-eval-when-stuff
 990               (cadr form) (cddr form)
 991               #'(lambda (forms)
 992                   (process-top-level-progn forms path))))
 993             ((macrolet)
 994              (unless (>= (length form) 2)
 995                (compiler-error "MACROLET form is too short: ~S" form))
 996              (do-macrolet-stuff
 997               (cadr form)
 998               #'(lambda ()
 999                   (process-top-level-progn (cddr form) path))))
1000             (locally (process-top-level-locally form path))
1001             (progn (process-top-level-progn (cdr form) path))
1002             (t
1003              (let* ((uform (uncross form))
1004                     (exp (preprocessor-macroexpand uform)))
1005                (if (eq exp uform)
1006                    (convert-and-maybe-compile uform path)
1007                    (process-top-level-form exp path))))))))
1008
1009   (values))
1010 \f
1011 ;;;; load time value support
1012 ;;;;
1013 ;;;; (See EMIT-MAKE-LOAD-FORM.)
1014
1015 ;;; Returns T iff we are currently producing a fasl-file and hence
1016 ;;; constants need to be dumped carefully.
1017 (defun producing-fasl-file ()
1018   (unless *converting-for-interpreter*
1019     (fasl-file-p *compile-object*)))
1020
1021 ;;; Compile FORM and arrange for it to be called at load-time. Return
1022 ;;; the dumper handle and our best guess at the type of the object.
1023 (defun compile-load-time-value
1024        (form &optional
1025              (name (let ((*print-level* 2) (*print-length* 3))
1026                      (format nil "load time value of ~S"
1027                              (if (and (listp form)
1028                                       (eq (car form) 'make-value-cell))
1029                                  (second form)
1030                                  form)))))
1031   (let ((lambda (compile-load-time-stuff form name t)))
1032     (values
1033      (fasl-dump-load-time-value-lambda lambda *compile-object*)
1034      (let ((type (leaf-type lambda)))
1035        (if (function-type-p type)
1036            (single-value-type (function-type-returns type))
1037            *wild-type*)))))
1038
1039 ;;; Compile the FORMS and arrange for them to be called (for effect,
1040 ;;; not value) at load time.
1041 (defun compile-make-load-form-init-forms (forms name)
1042   (let ((lambda (compile-load-time-stuff `(progn ,@forms) name nil)))
1043     (fasl-dump-top-level-lambda-call lambda *compile-object*)))
1044
1045 ;;; Does the actual work of COMPILE-LOAD-TIME-VALUE or
1046 ;;; COMPILE-MAKE-LOAD-FORM- INIT-FORMS.
1047 (defun compile-load-time-stuff (form name for-value)
1048   (with-ir1-namespace
1049    (let* ((*lexenv* (make-null-lexenv))
1050           (lambda (ir1-top-level form *current-path* for-value)))
1051      (setf (leaf-name lambda) name)
1052      (compile-top-level (list lambda) t)
1053      lambda)))
1054
1055 ;;; Called by COMPILE-TOP-LEVEL when it was pased T for
1056 ;;; LOAD-TIME-VALUE-P (which happens in COMPILE-LOAD-TIME-STUFF). We
1057 ;;; don't try to combine this component with anything else and frob
1058 ;;; the name. If not in a :TOP-LEVEL component, then don't bother
1059 ;;; compiling, because it was merged with a run-time component.
1060 (defun compile-load-time-value-lambda (lambdas)
1061   (assert (null (cdr lambdas)))
1062   (let* ((lambda (car lambdas))
1063          (component (block-component (node-block (lambda-bind lambda)))))
1064     (when (eq (component-kind component) :top-level)
1065       (setf (component-name component) (leaf-name lambda))
1066       (compile-component component)
1067       (clear-ir1-info component))))
1068
1069 ;;; The entry point for MAKE-LOAD-FORM support. When IR1 conversion
1070 ;;; finds a constant structure, it invokes this to arrange for proper
1071 ;;; dumping. If it turns out that the constant has already been
1072 ;;; dumped, then we don't need to do anything.
1073 ;;;
1074 ;;; If the constant hasn't been dumped, then we check to see whether
1075 ;;; we are in the process of creating it. We detect this by
1076 ;;; maintaining the special *CONSTANTS-BEING-CREATED* as a list of all
1077 ;;; the constants we are in the process of creating. Actually, each
1078 ;;; entry is a list of the constant and any init forms that need to be
1079 ;;; processed on behalf of that constant.
1080 ;;;
1081 ;;; It's not necessarily an error for this to happen. If we are
1082 ;;; processing the init form for some object that showed up *after*
1083 ;;; the original reference to this constant, then we just need to
1084 ;;; defer the processing of that init form. To detect this, we
1085 ;;; maintain *CONSTANTS-CREATED-SINCE-LAST-INIT* as a list of the
1086 ;;; constants created since the last time we started processing an
1087 ;;; init form. If the constant passed to emit-make-load-form shows up
1088 ;;; in this list, then there is a circular chain through creation
1089 ;;; forms, which is an error.
1090 ;;;
1091 ;;; If there is some intervening init form, then we blow out of
1092 ;;; processing it by throwing to the tag PENDING-INIT. The value we
1093 ;;; throw is the entry from *CONSTANTS-BEING-CREATED*. This is so the
1094 ;;; offending init form can be tacked onto the init forms for the
1095 ;;; circular object.
1096 ;;;
1097 ;;; If the constant doesn't show up in *CONSTANTS-BEING-CREATED*, then
1098 ;;; we have to create it. We call MAKE-LOAD-FORM and check to see
1099 ;;; whether the creation form is the magic value
1100 ;;; :JUST-DUMP-IT-NORMALLY. If it is, then we don't do anything. The
1101 ;;; dumper will eventually get its hands on the object and use the
1102 ;;; normal structure dumping noise on it.
1103 ;;;
1104 ;;; Otherwise, we bind *CONSTANTS-BEING-CREATED* and
1105 ;;; *CONSTANTS-CREATED-SINCE- LAST-INIT* and compile the creation form
1106 ;;; much the way LOAD-TIME-VALUE does. When this finishes, we tell the
1107 ;;; dumper to use that result instead whenever it sees this constant.
1108 ;;;
1109 ;;; Now we try to compile the init form. We bind
1110 ;;; *CONSTANTS-CREATED-SINCE- LAST-INIT* to NIL and compile the init
1111 ;;; form (and any init forms that were added because of circularity
1112 ;;; detection). If this works, great. If not, we add the init forms to
1113 ;;; the init forms for the object that caused the problems and let it
1114 ;;; deal with it.
1115 (defvar *constants-being-created* nil)
1116 (defvar *constants-created-since-last-init* nil)
1117 ;;; FIXME: Shouldn't these^ variables be bound in LET forms?
1118 (defun emit-make-load-form (constant)
1119   (assert (fasl-file-p *compile-object*))
1120   (unless (or (fasl-constant-already-dumped constant *compile-object*)
1121               ;; KLUDGE: This special hack is because I was too lazy
1122               ;; to rework DEF!STRUCT so that the MAKE-LOAD-FORM
1123               ;; function of LAYOUT returns nontrivial forms when
1124               ;; building the cross-compiler but :IGNORE-IT when
1125               ;; cross-compiling or running under the target Lisp. --
1126               ;; WHN 19990914
1127               #+sb-xc-host (typep constant 'layout))
1128     (let ((circular-ref (assoc constant *constants-being-created* :test #'eq)))
1129       (when circular-ref
1130         (when (find constant *constants-created-since-last-init* :test #'eq)
1131           (throw constant t))
1132         (throw 'pending-init circular-ref)))
1133     (multiple-value-bind (creation-form init-form)
1134         (handler-case
1135             (sb!xc:make-load-form constant (make-null-lexenv))
1136           (error (condition)
1137                  (compiler-error "(while making load form for ~S)~%~A"
1138                                  constant
1139                                  condition)))
1140       (case creation-form
1141         (:just-dump-it-normally
1142          (fasl-validate-structure constant *compile-object*)
1143          t)
1144         (:ignore-it
1145          nil)
1146         (t
1147          (compile-top-level-lambdas () t)
1148          (when (fasl-constant-already-dumped constant *compile-object*)
1149            (return-from emit-make-load-form nil))
1150          (let* ((name (let ((*print-level* 1) (*print-length* 2))
1151                         (with-output-to-string (stream)
1152                           (write constant :stream stream))))
1153                 (info (if init-form
1154                           (list constant name init-form)
1155                           (list constant))))
1156            (let ((*constants-being-created*
1157                   (cons info *constants-being-created*))
1158                  (*constants-created-since-last-init*
1159                   (cons constant *constants-created-since-last-init*)))
1160              (when
1161                  (catch constant
1162                    (fasl-note-handle-for-constant
1163                     constant
1164                     (compile-load-time-value
1165                      creation-form
1166                      (format nil "creation form for ~A" name))
1167                     *compile-object*)
1168                    nil)
1169                (compiler-error "circular references in creation form for ~S"
1170                                constant)))
1171            (when (cdr info)
1172              (let* ((*constants-created-since-last-init* nil)
1173                     (circular-ref
1174                      (catch 'pending-init
1175                        (loop for (name form) on (cdr info) by #'cddr
1176                          collect name into names
1177                          collect form into forms
1178                          finally
1179                          (compile-make-load-form-init-forms
1180                           forms
1181                           (format nil "init form~:[~;s~] for ~{~A~^, ~}"
1182                                   (cdr forms) names)))
1183                        nil)))
1184                (when circular-ref
1185                  (setf (cdr circular-ref)
1186                        (append (cdr circular-ref) (cdr info))))))))))))
1187 \f
1188 ;;;; COMPILE-FILE
1189
1190 ;;; We build a list of top-level lambdas, and then periodically smash
1191 ;;; them together into a single component and compile it.
1192 (defvar *pending-top-level-lambdas*)
1193
1194 ;;; The maximum number of top-level lambdas we put in a single
1195 ;;; top-level component.
1196 ;;;
1197 ;;; CMU CL 18b used this nontrivially by default (setting it to 10)
1198 ;;; but consequently suffered from the inability to execute some
1199 ;;; troublesome constructs correctly, e.g. inability to load a fasl
1200 ;;; file compiled from the source file
1201 ;;;   (defpackage "FOO" (:use "CL"))
1202 ;;;   (print 'foo::bar)
1203 ;;; because it would dump data-setup fops (including a FOP-PACKAGE for
1204 ;;; "FOO") for the second form before dumping the the code in the
1205 ;;; first form, or the fop to execute the code in the first form. By
1206 ;;; setting this value to 0 by default, we avoid this badness. This
1207 ;;; increases the number of toplevel form functions, and so increases
1208 ;;; the size of object files.
1209 ;;;
1210 ;;; The variable is still supported because when we are compiling the
1211 ;;; SBCL system itself, which is known not contain any troublesome
1212 ;;; constructs, we can set it to a nonzero value, which reduces the
1213 ;;; number of toplevel form objects, reducing the peak memory usage in
1214 ;;; GENESIS, which is desirable, since at least for SBCL version
1215 ;;; 0.6.7, this is the high water mark for memory usage during system
1216 ;;; construction.
1217 (defparameter *top-level-lambda-max* 0)
1218
1219 (defun object-call-top-level-lambda (tll)
1220   (declare (type functional tll))
1221   (let ((object *compile-object*))
1222     (etypecase object
1223       (fasl-file
1224        (fasl-dump-top-level-lambda-call tll object))
1225       (core-object
1226        (core-call-top-level-lambda tll object))
1227       (null))))
1228
1229 ;;; Add LAMBDAS to the pending lambdas. If this leaves more than
1230 ;;; *TOP-LEVEL-LAMBDA-MAX* lambdas in the list, or if FORCE-P is true,
1231 ;;; then smash the lambdas into a single component, compile it, and
1232 ;;; call the resulting function.
1233 (defun sub-compile-top-level-lambdas (lambdas force-p)
1234   (declare (list lambdas))
1235   (setq *pending-top-level-lambdas*
1236         (append *pending-top-level-lambdas* lambdas))
1237   (let ((pending *pending-top-level-lambdas*))
1238     (when (and pending
1239                (or (> (length pending) *top-level-lambda-max*)
1240                    force-p))
1241       (multiple-value-bind (component tll) (merge-top-level-lambdas pending)
1242         (setq *pending-top-level-lambdas* ())
1243         (let ((*byte-compile* (if (eq *byte-compile* :maybe)
1244                                   *byte-compile-top-level*
1245                                   *byte-compile*)))
1246           (compile-component component))
1247         (clear-ir1-info component)
1248         (object-call-top-level-lambda tll))))
1249   (values))
1250
1251 ;;; Compile top-level code and call the top-level lambdas. We pick off
1252 ;;; top-level lambdas in non-top-level components here, calling
1253 ;;; SUB-c-t-l-l on each subsequence of normal top-level lambdas.
1254 (defun compile-top-level-lambdas (lambdas force-p)
1255   (declare (list lambdas))
1256   (let ((len (length lambdas)))
1257     (flet ((loser (start)
1258              (or (position-if #'(lambda (x)
1259                                   (not (eq (component-kind
1260                                             (block-component
1261                                              (node-block
1262                                               (lambda-bind x))))
1263                                            :top-level)))
1264                               lambdas
1265                               :start start)
1266                  len)))
1267       (do* ((start 0 (1+ loser))
1268             (loser (loser start) (loser start)))
1269            ((>= start len)
1270             (when force-p
1271               (sub-compile-top-level-lambdas nil t)))
1272         (sub-compile-top-level-lambdas (subseq lambdas start loser)
1273                                        (or force-p (/= loser len)))
1274         (unless (= loser len)
1275           (object-call-top-level-lambda (elt lambdas loser))))))
1276   (values))
1277
1278 ;;; Compile LAMBDAS (a list of the lambdas for top-level forms) into
1279 ;;; the object file. We loop doing local call analysis until it
1280 ;;; converges, since a single pass might miss something due to
1281 ;;; components being joined by LET conversion.
1282 ;;;
1283 ;;; LOAD-TIME-VALUE-P seems to control whether it's MAKE-LOAD-FORM and
1284 ;;; COMPILE-LOAD-TIME-VALUE stuff. -- WHN 20000201
1285 (defun compile-top-level (lambdas load-time-value-p)
1286   (declare (list lambdas))
1287   (maybe-mumble "locall ")
1288   (loop
1289     (let ((did-something nil))
1290       (dolist (lambda lambdas)
1291         (let* ((component (block-component (node-block (lambda-bind lambda))))
1292                (*all-components* (list component)))
1293           (when (component-new-functions component)
1294             (setq did-something t)
1295             (local-call-analyze component))))
1296       (unless did-something (return))))
1297
1298   (maybe-mumble "IDFO ")
1299   (multiple-value-bind (components top-components hairy-top)
1300       (find-initial-dfo lambdas)
1301     (let ((*all-components* (append components top-components))
1302           (top-level-closure nil))
1303       (when *check-consistency*
1304         (maybe-mumble "[check]~%")
1305         (check-ir1-consistency *all-components*))
1306
1307       (dolist (component (append hairy-top top-components))
1308         (when (pre-environment-analyze-top-level component)
1309           (setq top-level-closure t)))
1310
1311       (let ((*byte-compile*
1312              (if (and top-level-closure (eq *byte-compile* :maybe))
1313                  nil
1314                  *byte-compile*)))
1315         (dolist (component components)
1316           (compile-component component)
1317           (when (replace-top-level-xeps component)
1318             (setq top-level-closure t)))
1319
1320         (when *check-consistency*
1321           (maybe-mumble "[check]~%")
1322           (check-ir1-consistency *all-components*))
1323
1324         (if load-time-value-p
1325             (compile-load-time-value-lambda lambdas)
1326             (compile-top-level-lambdas lambdas top-level-closure)))
1327
1328       (dolist (component components)
1329         (clear-ir1-info component))
1330       (clear-stuff)))
1331   (values))
1332
1333 ;;; Actually compile any stuff that has been queued up for block
1334 ;;; compilation.
1335 (defun finish-block-compilation ()
1336   (when *block-compile*
1337     (when *top-level-lambdas*
1338       (compile-top-level (nreverse *top-level-lambdas*) nil)
1339       (setq *top-level-lambdas* ()))
1340     (setq *block-compile* nil)
1341     (setq *entry-points* nil)))
1342
1343 ;;; Read all forms from INFO and compile them, with output to OBJECT.
1344 ;;; Return (VALUES NIL WARNINGS-P FAILURE-P).
1345 (defun sub-compile-file (info &optional d-s-info)
1346   (declare (type source-info info))
1347   (let* (;; These are bound in WITH-COMPILATION-UNIT now. -- WHN 20000308
1348          #+nil (*compiler-error-count* 0)
1349          #+nil (*compiler-warning-count* 0)
1350          #+nil (*compiler-style-warning-count* 0)
1351          #+nil (*compiler-note-count* 0)
1352          (*block-compile* *block-compile-argument*)
1353          (*package* (sane-package))
1354          (*initial-package* (sane-package))
1355          (*initial-cookie* *default-cookie*)
1356          (*initial-interface-cookie* *default-interface-cookie*)
1357          (*default-cookie* (copy-cookie *initial-cookie*))
1358          (*default-interface-cookie*
1359           (copy-cookie *initial-interface-cookie*))
1360          (*lexenv* (make-null-lexenv))
1361          (*converting-for-interpreter* nil)
1362          (*source-info* info)
1363          (sb!xc:*compile-file-pathname* nil)
1364          (sb!xc:*compile-file-truename* nil)
1365          (*top-level-lambdas* ())
1366          (*pending-top-level-lambdas* ())
1367          (*compiler-error-bailout*
1368           (lambda ()
1369             (compiler-mumble "~2&; fatal error, aborting compilation~%")
1370             (return-from sub-compile-file (values nil t t))))
1371          (*current-path* nil)
1372          (*last-source-context* nil)
1373          (*last-original-source* nil)
1374          (*last-source-form* nil)
1375          (*last-format-string* nil)
1376          (*last-format-args* nil)
1377          (*last-message-count* 0)
1378          (*info-environment* (or *backend-info-environment*
1379                                  *info-environment*))
1380          (*gensym-counter* 0))
1381     (with-compilation-values
1382       (sb!xc:with-compilation-unit ()
1383         (clear-stuff)
1384
1385         (process-sources info)
1386
1387         (finish-block-compilation)
1388         (compile-top-level-lambdas () t)
1389         (let ((object *compile-object*))
1390           (etypecase object
1391             (fasl-file (fasl-dump-source-info info object))
1392             (core-object (fix-core-source-info info object d-s-info))
1393             (null)))
1394         nil))))
1395
1396 ;;; Return a list of pathnames for the named files. All the files must
1397 ;;; exist.
1398 (defun verify-source-files (stuff)
1399   (let* ((stuff (if (listp stuff) stuff (list stuff)))
1400          (default-host (make-pathname
1401                         :host (pathname-host (pathname (first stuff))))))
1402     (flet ((try-with-type (path type error-p)
1403              (let ((new (merge-pathnames
1404                          path (make-pathname :type type
1405                                              :defaults default-host))))
1406                (if (probe-file new)
1407                    new
1408                    (and error-p (truename new))))))
1409       (unless stuff
1410         (error "can't compile with no source files"))
1411       (mapcar #'(lambda (x)
1412                   (let ((x (pathname x)))
1413                     (cond ((typep x 'logical-pathname)
1414                            (try-with-type x "LISP" t))
1415                           ((probe-file x) x)
1416                           ((try-with-type x "lisp"  nil))
1417                           ((try-with-type x "lisp"  t)))))
1418               stuff))))
1419
1420 (defun elapsed-time-to-string (tsec)
1421   (multiple-value-bind (tmin sec) (truncate tsec 60)
1422     (multiple-value-bind (thr min) (truncate tmin 60)
1423       (format nil "~D:~2,'0D:~2,'0D" thr min sec))))
1424
1425 ;;; Print some junk at the beginning and end of compilation.
1426 (defun start-error-output (source-info)
1427   (declare (type source-info source-info))
1428   (dolist (x (source-info-files source-info))
1429     (compiler-mumble "~&; compiling file ~S (written ~A):~%"
1430                      (namestring (file-info-name x))
1431                      (sb!int:format-universal-time nil
1432                                                    (file-info-write-date x)
1433                                                    :style :government
1434                                                    :print-weekday nil
1435                                                    :print-timezone nil)))
1436   (values))
1437
1438 (defun finish-error-output (source-info won)
1439   (declare (type source-info source-info))
1440   (compiler-mumble "~&; compilation ~:[aborted after~;finished in~] ~A~&"
1441                    won
1442                    (elapsed-time-to-string
1443                     (- (get-universal-time)
1444                        (source-info-start-time source-info))))
1445   (values))
1446
1447 ;;; Open some files and call SUB-COMPILE-FILE. If something unwinds
1448 ;;; out of the compile, then abort the writing of the output file, so
1449 ;;; we don't overwrite it with known garbage.
1450 (defun sb!xc:compile-file
1451     (source
1452      &key
1453      (output-file t) ; FIXME: ANSI says this should be a pathname designator.
1454      ;; FIXME: ANSI doesn't seem to say anything about
1455      ;; *COMPILE-VERBOSE* and *COMPILE-PRINT* being rebound by this
1456      ;; function..
1457      ((:verbose sb!xc:*compile-verbose*) sb!xc:*compile-verbose*)
1458      ((:print sb!xc:*compile-print*) sb!xc:*compile-print*)
1459      (external-format :default)
1460      ((:block-compile *block-compile-argument*) nil)
1461      ((:entry-points *entry-points*) nil)
1462      ((:byte-compile *byte-compile*) *byte-compile-default*))
1463   #!+sb-doc
1464   "Compile SOURCE, producing a corresponding FASL file.
1465    :Output-File
1466       The name of the fasl to output, NIL for none, T for the default.
1467    :Block-Compile
1468       Determines whether multiple functions are compiled together as a unit,
1469       resolving function references at compile time. NIL means that global
1470       function names are never resolved at compilation time.
1471    :Entry-Points
1472       This specifies a list of function names for functions in the file(s) that
1473       must be given global definitions. This only applies to block
1474       compilation. If the value is NIL (the default) then all functions
1475       will be globally defined.
1476    :Byte-Compile {T | NIL | :MAYBE}
1477       Determines whether to compile into interpreted byte code instead of
1478       machine instructions. Byte code is several times smaller, but much
1479       slower. If :MAYBE, then only byte-compile when SPEED is 0 and
1480       DEBUG <= 1. The default is the value of SB-EXT:*BYTE-COMPILE-DEFAULT*,
1481       which is initially :MAYBE."
1482   (unless (eq external-format :default)
1483     (error "Non-:DEFAULT EXTERNAL-FORMAT values are not supported."))
1484   (let* ((fasl-file nil)
1485          (output-file-name nil)
1486          (compile-won nil)
1487          (warnings-p nil)
1488          (failure-p t) ; T in case error keeps this from being set later
1489
1490          ;; KLUDGE: The listifying and unlistifying in the next calls
1491          ;; is to interface to old CMU CL code which accepted and
1492          ;; returned lists of multiple source files. It would be
1493          ;; cleaner to redo VERIFY-SOURCE-FILES and as
1494          ;; VERIFY-SOURCE-FILE, accepting a single source file, and
1495          ;; do a similar transformation on MAKE-FILE-SOURCE-INFO too.
1496          ;; -- WHN 20000201
1497          (source (first (verify-source-files (list source))))
1498          (source-info (make-file-source-info (list source))))
1499     (unwind-protect
1500         (progn
1501           (when output-file
1502             (setq output-file-name
1503                   (sb!xc:compile-file-pathname source
1504                                                :output-file output-file
1505                                                :byte-compile *byte-compile*))
1506             (setq fasl-file
1507                   (open-fasl-file output-file-name
1508                                   (namestring source)
1509                                   (eq *byte-compile* t))))
1510
1511           (when sb!xc:*compile-verbose*
1512             (start-error-output source-info))
1513           (let ((*compile-object* fasl-file)
1514                 dummy)
1515             (multiple-value-setq (dummy warnings-p failure-p)
1516               (sub-compile-file source-info)))
1517           (setq compile-won t))
1518
1519       (close-source-info source-info)
1520
1521       (when fasl-file
1522         (close-fasl-file fasl-file (not compile-won))
1523         (setq output-file-name (pathname (fasl-file-stream fasl-file)))
1524         (when (and compile-won sb!xc:*compile-verbose*)
1525           (compiler-mumble "~2&; ~A written~%" (namestring output-file-name))))
1526
1527       (when sb!xc:*compile-verbose*
1528         (finish-error-output source-info compile-won)))
1529
1530     (values (if output-file
1531                 ;; Hack around filesystem race condition...
1532                 (or (probe-file output-file-name) output-file-name)
1533                 nil)
1534             warnings-p
1535             failure-p)))
1536 \f
1537 (defun sb!xc:compile-file-pathname (file-path
1538                                     &key (output-file t) byte-compile
1539                                     &allow-other-keys)
1540   #!+sb-doc
1541   "Return a pathname describing what file COMPILE-FILE would write to given
1542    these arguments."
1543   (declare (values (or null pathname)))
1544   (let ((pathname (pathname file-path)))
1545     (cond ((not (eq output-file t))
1546            (when output-file
1547              (translate-logical-pathname (pathname output-file))))
1548           ((and (typep pathname 'logical-pathname) (not (eq byte-compile t)))
1549            (make-pathname :type "FASL" :defaults pathname
1550                           :case :common))
1551           (t
1552            (make-pathname :defaults (translate-logical-pathname pathname)
1553                           :type (if (eq byte-compile t)
1554                                     (backend-byte-fasl-file-type)
1555                                     *backend-fasl-file-type*))))))