src/compiler/main.lisp

   1 ;;;; the top level interfaces to the compiler, plus some other
   2 ;;;; compiler-related stuff (e.g. CL:CALL-ARGUMENTS-LIMIT) which
   3 ;;;; doesn't obviously belong anywhere else
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15
  16 ;;; FIXME: Doesn't this belong somewhere else, like early-c.lisp?
  17 (declaim (special *constants* *free-vars* *component-being-compiled*
  18                   *code-vector* *next-location* *result-fixups*
  19                   *free-funs* *source-paths*
  20                   *seen-blocks* *seen-funs* *list-conflicts-table*
  21                   *continuation-number* *continuation-numbers*
  22                   *number-continuations* *tn-id* *tn-ids* *id-tns*
  23                   *label-ids* *label-id* *id-labels*
  24                   *undefined-warnings* *compiler-error-count*
  25                   *compiler-warning-count* *compiler-style-warning-count*
  26                   *compiler-note-count*
  27                   *compiler-error-bailout*
  28                   #!+sb-show *compiler-trace-output*
  29                   *last-source-context* *last-original-source*
  30                   *last-source-form* *last-format-string* *last-format-args*
  31                   *last-message-count* *lexenv* *fun-names-in-this-file*))
  32
  33 ;;; Whether call of a function which cannot be defined causes a full
  34 ;;; warning.
  35 (defvar *flame-on-necessarily-undefined-function* nil)
  36
  37 (defvar *check-consistency* nil)
  38 (defvar *all-components*)
  39
  40 ;;; Bind this to a stream to capture various internal debugging output.
  41 (defvar *compiler-trace-output* nil)
  42
  43 ;;; The current block compilation state. These are initialized to the
  44 ;;; :BLOCK-COMPILE and :ENTRY-POINTS arguments that COMPILE-FILE was
  45 ;;; called with.
  46 ;;;
  47 ;;; *BLOCK-COMPILE-ARG* holds the original value of the :BLOCK-COMPILE
  48 ;;; argument, which overrides any internal declarations.
  49 (defvar *block-compile*)
  50 (defvar *block-compile-arg*)
  51 (declaim (type (member nil t :specified) *block-compile* *block-compile-arg*))
  52 (defvar *entry-points*)
  53 (declaim (list *entry-points*))
  54
  55 ;;; When block compiling, used by PROCESS-FORM to accumulate top level
  56 ;;; lambdas resulting from compiling subforms. (In reverse order.)
  57 (defvar *toplevel-lambdas*)
  58 (declaim (list *toplevel-lambdas*))
  59
  60 (defvar sb!xc:*compile-verbose* t
  61   #!+sb-doc
  62   "The default for the :VERBOSE argument to COMPILE-FILE.")
  63 (defvar sb!xc:*compile-print* t
  64   #!+sb-doc
  65   "The default for the :PRINT argument to COMPILE-FILE.")
  66 (defvar *compile-progress* nil
  67   #!+sb-doc
  68   "When this is true, the compiler prints to *ERROR-OUTPUT* progress
  69   information about the phases of compilation of each function. (This
  70   is useful mainly in large block compilations.)")
  71
  72 (defvar sb!xc:*compile-file-pathname* nil
  73   #!+sb-doc
  74   "The defaulted pathname of the file currently being compiled, or NIL if not
  75   compiling.")
  76 (defvar sb!xc:*compile-file-truename* nil
  77   #!+sb-doc
  78   "The TRUENAME of the file currently being compiled, or NIL if not
  79   compiling.")
  80
  81 (declaim (type (or pathname null)
  82                sb!xc:*compile-file-pathname*
  83                sb!xc:*compile-file-truename*))
  84
  85 ;;; the SOURCE-INFO structure for the current compilation. This is
  86 ;;; null globally to indicate that we aren't currently in any
  87 ;;; identifiable compilation.
  88 (defvar *source-info* nil)
  89
  90 ;;; This is true if we are within a WITH-COMPILATION-UNIT form (which
  91 ;;; normally causes nested uses to be no-ops).
  92 (defvar *in-compilation-unit* nil)
  93
  94 ;;; This lock is siezed in the same situation: the compiler is not
  95 ;;; presently thread-safe
  96 (defvar *big-compiler-lock*
  97   (sb!thread:make-mutex :name "big compiler lock"))
  98
  99 ;;; Count of the number of compilation units dynamically enclosed by
 100 ;;; the current active WITH-COMPILATION-UNIT that were unwound out of.
 101 (defvar *aborted-compilation-unit-count*)
 102
 103 ;;; Mumble conditional on *COMPILE-PROGRESS*.
 104 (defun maybe-mumble (&rest foo)
 105   (when *compile-progress*
 106     (compiler-mumble "~&")
 107     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 108        (apply #'compiler-mumble foo))))
 109
 110 (deftype object () '(or fasl-output core-object null))
 111
 112 (defvar *compile-object* nil)
 113 (declaim (type object *compile-object*))
 114 \f
 115 ;;;; WITH-COMPILATION-UNIT and WITH-COMPILATION-VALUES
 116
 117 (defmacro sb!xc:with-compilation-unit (options &body body)
 118   #!+sb-doc
 119   "WITH-COMPILATION-UNIT ({Key Value}*) Form*
 120   This form affects compilations that take place within its dynamic extent. It
 121   is intended to be wrapped around the compilation of all files in the same
 122   system. These keywords are defined:
 123     :OVERRIDE Boolean-Form
 124         One of the effects of this form is to delay undefined warnings
 125         until the end of the form, instead of giving them at the end of each
 126         compilation. If OVERRIDE is NIL (the default), then the outermost
 127         WITH-COMPILATION-UNIT form grabs the undefined warnings. Specifying
 128         OVERRIDE true causes that form to grab any enclosed warnings, even if
 129         it is enclosed by another WITH-COMPILATION-UNIT."
 130   `(%with-compilation-unit (lambda () ,@body) ,@options))
 131
 132 (defun %with-compilation-unit (fn &key override)
 133   (declare (type function fn))
 134   (let ((succeeded-p nil))
 135     (if (and *in-compilation-unit* (not override))
 136         ;; Inside another WITH-COMPILATION-UNIT, a WITH-COMPILATION-UNIT is
 137         ;; ordinarily (unless OVERRIDE) basically a no-op.
 138         (unwind-protect
 139              (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 140           (unless succeeded-p
 141             (incf *aborted-compilation-unit-count*)))
 142         (let ((*aborted-compilation-unit-count* 0)
 143               (*compiler-error-count* 0)
 144               (*compiler-warning-count* 0)
 145               (*compiler-style-warning-count* 0)
 146               (*compiler-note-count* 0)
 147               (*undefined-warnings* nil)
 148               (*in-compilation-unit* t))
 149           (sb!thread:with-recursive-lock (*big-compiler-lock*)
 150             (handler-bind ((parse-unknown-type
 151                             (lambda (c)
 152                               (note-undefined-reference
 153                                (parse-unknown-type-specifier c)
 154                                :type))))
 155               (unwind-protect
 156                    (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 157                 (unless succeeded-p
 158                   (incf *aborted-compilation-unit-count*))
 159                 (summarize-compilation-unit (not succeeded-p)))))))))
 160
 161 ;;; Is FUN-NAME something that no conforming program can rely on
 162 ;;; defining as a function?
 163 (defun fun-name-reserved-by-ansi-p (fun-name)
 164   (eq (symbol-package (fun-name-block-name fun-name))
 165       *cl-package*))
 166
 167 ;;; This is to be called at the end of a compilation unit. It signals
 168 ;;; any residual warnings about unknown stuff, then prints the total
 169 ;;; error counts. ABORT-P should be true when the compilation unit was
 170 ;;; aborted by throwing out. ABORT-COUNT is the number of dynamically
 171 ;;; enclosed nested compilation units that were aborted.
 172 (defun summarize-compilation-unit (abort-p)
 173   (unless abort-p
 174     (handler-bind ((style-warning #'compiler-style-warning-handler)
 175                    (warning #'compiler-warning-handler))
 176
 177       (let ((undefs (sort *undefined-warnings* #'string<
 178                           :key (lambda (x)
 179                                  (let ((x (undefined-warning-name x)))
 180                                    (if (symbolp x)
 181                                        (symbol-name x)
 182                                        (prin1-to-string x)))))))
 183         (dolist (undef undefs)
 184           (let ((name (undefined-warning-name undef))
 185                 (kind (undefined-warning-kind undef))
 186                 (warnings (undefined-warning-warnings undef))
 187                 (undefined-warning-count (undefined-warning-count undef)))
 188             (dolist (*compiler-error-context* warnings)
 189               (if #-sb-xc-host (and (eq kind :function)
 190                                     (fun-name-reserved-by-ansi-p name)
 191                                     *flame-on-necessarily-undefined-function*)
 192                   #+sb-xc-host nil
 193                   (case name
 194                     ((declare)
 195                      (compiler-warn
 196                       "~@<There is no function named ~S. References to ~S in ~
 197                        some contexts (like starts of blocks) have special ~
 198                        meaning, but here it would have to be a function, ~
 199                        and that shouldn't be right.~:@>"
 200                       name name))
 201                     (t
 202                      (compiler-warn
 203                       "~@<The ~(~A~) ~S is undefined, and its name is ~
 204                        reserved by ANSI CL so that even if it it were ~
 205                        defined later, the code doing so would not be ~
 206                        portable.~:@>"
 207                       kind name)))
 208                   (compiler-style-warn "undefined ~(~A~): ~S" kind name)))
 209             (let ((warn-count (length warnings)))
 210               (when (and warnings (> undefined-warning-count warn-count))
 211                 (let ((more (- undefined-warning-count warn-count)))
 212                   (compiler-style-warn
 213                    "~W more use~:P of undefined ~(~A~) ~S"
 214                    more kind name))))))
 215
 216         (dolist (kind '(:variable :function :type))
 217           (let ((summary (mapcar #'undefined-warning-name
 218                                  (remove kind undefs :test-not #'eq
 219                                          :key #'undefined-warning-kind))))
 220             (when summary
 221               (compiler-style-warn
 222                "~:[This ~(~A~) is~;These ~(~A~)s are~] undefined:~
 223                 ~%  ~{~<~%  ~1:;~S~>~^ ~}"
 224                (cdr summary) kind summary)))))))
 225
 226   (unless (and (not abort-p)
 227                (zerop *aborted-compilation-unit-count*)
 228                (zerop *compiler-error-count*)
 229                (zerop *compiler-warning-count*)
 230                (zerop *compiler-style-warning-count*)
 231                (zerop *compiler-note-count*))
 232     (format *error-output* "~&")
 233     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 234       (compiler-mumble "compilation unit ~:[finished~;aborted~]~
 235                        ~[~:;~:*~&  caught ~W fatal ERROR condition~:P~]~
 236                        ~[~:;~:*~&  caught ~W ERROR condition~:P~]~
 237                        ~[~:;~:*~&  caught ~W WARNING condition~:P~]~
 238                        ~[~:;~:*~&  caught ~W STYLE-WARNING condition~:P~]~
 239                        ~[~:;~:*~&  printed ~W note~:P~]"
 240                        abort-p
 241                        *aborted-compilation-unit-count*
 242                        *compiler-error-count*
 243                        *compiler-warning-count*
 244                        *compiler-style-warning-count*
 245                        *compiler-note-count*)))
 246   (format *error-output* "~&"))
 247
 248 ;;; Evaluate BODY, then return (VALUES BODY-VALUE WARNINGS-P
 249 ;;; FAILURE-P), where BODY-VALUE is the first value of the body, and
 250 ;;; WARNINGS-P and FAILURE-P are as in CL:COMPILE or CL:COMPILE-FILE.
 251 ;;; This also wraps up WITH-IR1-NAMESPACE functionality.
 252 (defmacro with-compilation-values (&body body)
 253   `(with-ir1-namespace
 254     (let ((*warnings-p* nil)
 255           (*failure-p* nil))
 256       (values (progn ,@body)
 257               *warnings-p*
 258               *failure-p*))))
 259 \f
 260 ;;;; component compilation
 261
 262 (defparameter *max-optimize-iterations* 3 ; ARB
 263   #!+sb-doc
 264   "The upper limit on the number of times that we will consecutively do IR1
 265   optimization that doesn't introduce any new code. A finite limit is
 266   necessary, since type inference may take arbitrarily long to converge.")
 267
 268 (defevent ir1-optimize-until-done "IR1-OPTIMIZE-UNTIL-DONE called")
 269 (defevent ir1-optimize-maxed-out "hit *MAX-OPTIMIZE-ITERATIONS* limit")
 270
 271 ;;; Repeatedly optimize COMPONENT until no further optimizations can
 272 ;;; be found or we hit our iteration limit. When we hit the limit, we
 273 ;;; clear the component and block REOPTIMIZE flags to discourage the
 274 ;;; next optimization attempt from pounding on the same code.
 275 (defun ir1-optimize-until-done (component)
 276   (declare (type component component))
 277   (maybe-mumble "opt")
 278   (event ir1-optimize-until-done)
 279   (let ((count 0)
 280         (cleared-reanalyze nil))
 281     (loop
 282       (when (component-reanalyze component)
 283         (setq count 0)
 284         (setq cleared-reanalyze t)
 285         (setf (component-reanalyze component) nil))
 286       (setf (component-reoptimize component) nil)
 287       (ir1-optimize component)
 288       (cond ((component-reoptimize component)
 289              (incf count)
 290              (when (= count *max-optimize-iterations*)
 291                (maybe-mumble "*")
 292                (cond ((retry-delayed-ir1-transforms :optimize)
 293                       (maybe-mumble "+")
 294                       (setq count 0))
 295                      (t
 296                       (event ir1-optimize-maxed-out)
 297                       (setf (component-reoptimize component) nil)
 298                       (do-blocks (block component)
 299                         (setf (block-reoptimize block) nil))
 300                       (return)))))
 301             ((retry-delayed-ir1-transforms :optimize)
 302              (setf count 0)
 303              (maybe-mumble "+"))
 304             (t
 305              (maybe-mumble " ")
 306              (return)))
 307       (maybe-mumble "."))
 308     (when cleared-reanalyze
 309       (setf (component-reanalyze component) t)))
 310   (values))
 311
 312 (defparameter *constraint-propagate* t)
 313
 314 ;;; KLUDGE: This was bumped from 5 to 10 in a DTC patch ported by MNA
 315 ;;; from CMU CL into sbcl-0.6.11.44, the same one which allowed IR1
 316 ;;; transforms to be delayed. Either DTC or MNA or both didn't explain
 317 ;;; why, and I don't know what the rationale was. -- WHN 2001-04-28
 318 ;;;
 319 ;;; FIXME: It would be good to document why it's important to have a
 320 ;;; large value here, and what the drawbacks of an excessively large
 321 ;;; value are; and it might also be good to make it depend on
 322 ;;; optimization policy.
 323 (defparameter *reoptimize-after-type-check-max* 10)
 324
 325 (defevent reoptimize-maxed-out
 326   "*REOPTIMIZE-AFTER-TYPE-CHECK-MAX* exceeded.")
 327
 328 ;;; Iterate doing FIND-DFO until no new dead code is discovered.
 329 (defun dfo-as-needed (component)
 330   (declare (type component component))
 331   (when (component-reanalyze component)
 332     (maybe-mumble "DFO")
 333     (loop
 334       (find-dfo component)
 335       (unless (component-reanalyze component)
 336         (maybe-mumble " ")
 337         (return))
 338       (maybe-mumble ".")))
 339   (values))
 340
 341 ;;; Do all the IR1 phases for a non-top-level component.
 342 (defun ir1-phases (component)
 343   (declare (type component component))
 344   (aver-live-component component)
 345   (let ((*constraint-number* 0)
 346         (loop-count 1)
 347         (*delayed-ir1-transforms* nil))
 348     (declare (special *constraint-number* *delayed-ir1-transforms*))
 349     (loop
 350       (ir1-optimize-until-done component)
 351       (when (or (component-new-functionals component)
 352                 (component-reanalyze-functionals component))
 353         (maybe-mumble "locall ")
 354         (locall-analyze-component component))
 355       (dfo-as-needed component)
 356       (when *constraint-propagate*
 357         (maybe-mumble "constraint ")
 358         (constraint-propagate component))
 359       (when (retry-delayed-ir1-transforms :constraint)
 360         (maybe-mumble "Rtran "))
 361       (flet ((want-reoptimization-p ()
 362                (or (component-reoptimize component)
 363                    (component-reanalyze component)
 364                    (component-new-functionals component)
 365                    (component-reanalyze-functionals component))))
 366         (unless (and (want-reoptimization-p)
 367                      ;; We delay the generation of type checks until
 368                      ;; the type constraints have had time to
 369                      ;; propagate, else the compiler can confuse itself.
 370                      (< loop-count (- *reoptimize-after-type-check-max* 4)))
 371           (maybe-mumble "type ")
 372           (generate-type-checks component)
 373           (unless (want-reoptimization-p)
 374             (return))))
 375       (when (>= loop-count *reoptimize-after-type-check-max*)
 376         (maybe-mumble "[reoptimize limit]")
 377         (event reoptimize-maxed-out)
 378         (return))
 379       (incf loop-count)))
 380
 381   (ir1-finalize component)
 382   (values))
 383
 384 (defun %compile-component (component)
 385   (let ((*code-segment* nil)
 386         (*elsewhere* nil))
 387     (maybe-mumble "GTN ")
 388     (gtn-analyze component)
 389     (maybe-mumble "LTN ")
 390     (ltn-analyze component)
 391     (dfo-as-needed component)
 392     (maybe-mumble "control ")
 393     (control-analyze component #'make-ir2-block)
 394
 395     (when (ir2-component-values-receivers (component-info component))
 396       (maybe-mumble "stack ")
 397       (stack-analyze component)
 398       ;; Assign BLOCK-NUMBER for any cleanup blocks introduced by
 399       ;; stack analysis. There shouldn't be any unreachable code after
 400       ;; control, so this won't delete anything.
 401       (dfo-as-needed component))
 402
 403     (unwind-protect
 404         (progn
 405           (maybe-mumble "IR2tran ")
 406           (init-assembler)
 407           (entry-analyze component)
 408           (ir2-convert component)
 409
 410           (when (policy *lexenv* (>= speed compilation-speed))
 411             (maybe-mumble "copy ")
 412             (copy-propagate component))
 413
 414           (select-representations component)
 415
 416           (when *check-consistency*
 417             (maybe-mumble "check2 ")
 418             (check-ir2-consistency component))
 419
 420           (delete-unreferenced-tns component)
 421
 422           (maybe-mumble "life ")
 423           (lifetime-analyze component)
 424
 425           (when *compile-progress*
 426             (compiler-mumble "") ; Sync before doing more output.
 427             (pre-pack-tn-stats component *error-output*))
 428
 429           (when *check-consistency*
 430             (maybe-mumble "check-life ")
 431             (check-life-consistency component))
 432
 433           (maybe-mumble "pack ")
 434           (pack component)
 435
 436           (when *check-consistency*
 437             (maybe-mumble "check-pack ")
 438             (check-pack-consistency component))
 439
 440           (when *compiler-trace-output*
 441             (describe-component component *compiler-trace-output*)
 442             (describe-ir2-component component *compiler-trace-output*))
 443
 444           (maybe-mumble "code ")
 445           (multiple-value-bind (code-length trace-table fixups)
 446               (generate-code component)
 447
 448             (when *compiler-trace-output*
 449               (format *compiler-trace-output*
 450                       "~|~%disassembly of code for ~S~2%" component)
 451               (sb!disassem:disassemble-assem-segment *code-segment*
 452                                                      *compiler-trace-output*))
 453
 454             (etypecase *compile-object*
 455               (fasl-output
 456                (maybe-mumble "fasl")
 457                (fasl-dump-component component
 458                                     *code-segment*
 459                                     code-length
 460                                     trace-table
 461                                     fixups
 462                                     *compile-object*))
 463               (core-object
 464                (maybe-mumble "core")
 465                (make-core-component component
 466                                     *code-segment*
 467                                     code-length
 468                                     trace-table
 469                                     fixups
 470                                     *compile-object*))
 471               (null))))))
 472
 473   ;; We're done, so don't bother keeping anything around.
 474   (setf (component-info component) :dead)
 475
 476   (values))
 477
 478 ;;; Delete components with no external entry points before we try to
 479 ;;; generate code. Unreachable closures can cause IR2 conversion to
 480 ;;; puke on itself, since it is the reference to the closure which
 481 ;;; normally causes the components to be combined.
 482 (defun delete-if-no-entries (component)
 483   (dolist (fun (component-lambdas component) (delete-component component))
 484     (when (functional-has-external-references-p fun)
 485       (return))
 486     (case (functional-kind fun)
 487       (:toplevel (return))
 488       (:external
 489        (unless (every (lambda (ref)
 490                         (eq (node-component ref) component))
 491                       (leaf-refs fun))
 492          (return))))))
 493
 494 (defun compile-component (component)
 495
 496   ;; miscellaneous sanity checks
 497   ;;
 498   ;; FIXME: These are basically pretty wimpy compared to the checks done
 499   ;; by the old CHECK-IR1-CONSISTENCY code. It would be really nice to
 500   ;; make those internal consistency checks work again and use them.
 501   (aver-live-component component)
 502   (do-blocks (block component)
 503     (aver (eql (block-component block) component)))
 504   (dolist (lambda (component-lambdas component))
 505     ;; sanity check to prevent weirdness from propagating insidiously as
 506     ;; far from its root cause as it did in bug 138: Make sure that
 507     ;; thing-to-COMPONENT links are consistent.
 508     (aver (eql (lambda-component lambda) component))
 509     (aver (eql (node-component (lambda-bind lambda)) component)))
 510
 511   (let* ((*component-being-compiled* component))
 512     (when sb!xc:*compile-print*
 513       (compiler-mumble "~&; compiling ~A: " (component-name component)))
 514
 515     (ir1-phases component)
 516
 517     ;; FIXME: What is MAYBE-MUMBLE for? Do we need it any more?
 518     (maybe-mumble "env ")
 519     (physenv-analyze component)
 520     (dfo-as-needed component)
 521
 522     (delete-if-no-entries component)
 523
 524     (unless (eq (block-next (component-head component))
 525                 (component-tail component))
 526       (%compile-component component)))
 527
 528   (clear-constant-info)
 529
 530   (when sb!xc:*compile-print*
 531     (compiler-mumble "~&"))
 532
 533   (values))
 534 \f
 535 ;;;; clearing global data structures
 536 ;;;;
 537 ;;;; FIXME: Is it possible to get rid of this stuff, getting rid of
 538 ;;;; global data structures entirely when possible and consing up the
 539 ;;;; others from scratch instead of clearing and reusing them?
 540
 541 ;;; Clear the INFO in constants in the *FREE-VARS*, etc. In
 542 ;;; addition to allowing stuff to be reclaimed, this is required for
 543 ;;; correct assignment of constant offsets, since we need to assign a
 544 ;;; new offset for each component. We don't clear the FUNCTIONAL-INFO
 545 ;;; slots, since they are used to keep track of functions across
 546 ;;; component boundaries.
 547 (defun clear-constant-info ()
 548   (maphash (lambda (k v)
 549              (declare (ignore k))
 550              (setf (leaf-info v) nil))
 551            *constants*)
 552   (maphash (lambda (k v)
 553              (declare (ignore k))
 554              (when (constant-p v)
 555                (setf (leaf-info v) nil)))
 556            *free-vars*)
 557   (values))
 558
 559 ;;; Blow away the REFS for all global variables, and let COMPONENT
 560 ;;; be recycled.
 561 (defun clear-ir1-info (component)
 562   (declare (type component component))
 563   (labels ((blast (x)
 564              (maphash (lambda (k v)
 565                         (declare (ignore k))
 566                         (when (leaf-p v)
 567                           (setf (leaf-refs v)
 568                                 (delete-if #'here-p (leaf-refs v)))
 569                           (when (basic-var-p v)
 570                             (setf (basic-var-sets v)
 571                                   (delete-if #'here-p (basic-var-sets v))))))
 572                       x))
 573            (here-p (x)
 574              (eq (node-component x) component)))
 575     (blast *free-vars*)
 576     (blast *free-funs*)
 577     (blast *constants*))
 578   (values))
 579
 580 ;;; Clear global variables used by the compiler.
 581 ;;;
 582 ;;; FIXME: It seems kinda nasty and unmaintainable to have to do this,
 583 ;;; and it adds overhead even when people aren't using the compiler.
 584 ;;; Perhaps we could make these global vars unbound except when
 585 ;;; actually in use, so that this function could go away.
 586 (defun clear-stuff (&optional (debug-too t))
 587
 588   ;; Clear global tables.
 589   (when (boundp '*free-funs*)
 590     (clrhash *free-funs*)
 591     (clrhash *free-vars*)
 592     (clrhash *constants*))
 593
 594   ;; Clear debug counters and tables.
 595   (clrhash *seen-blocks*)
 596   (clrhash *seen-funs*)
 597   (clrhash *list-conflicts-table*)
 598
 599   (when debug-too
 600     (clrhash *continuation-numbers*)
 601     (clrhash *number-continuations*)
 602     (setq *continuation-number* 0)
 603     (clrhash *tn-ids*)
 604     (clrhash *id-tns*)
 605     (setq *tn-id* 0)
 606     (clrhash *label-ids*)
 607     (clrhash *id-labels*)
 608     (setq *label-id* 0)
 609
 610     ;; Clear some PACK data structures (for GC purposes only).
 611     (aver (not *in-pack*))
 612     (dolist (sb *backend-sb-list*)
 613       (when (finite-sb-p sb)
 614         (fill (finite-sb-live-tns sb) nil))))
 615
 616   ;; (Note: The CMU CL code used to set CL::*GENSYM-COUNTER* to zero here.
 617   ;; Superficially, this seemed harmful -- the user could reasonably be
 618   ;; surprised if *GENSYM-COUNTER* turned back to zero when something was
 619   ;; compiled. A closer inspection showed that this actually turned out to be
 620   ;; harmless in practice, because CLEAR-STUFF was only called from within
 621   ;; forms which bound CL::*GENSYM-COUNTER* to zero. However, this means that
 622   ;; even though zeroing CL::*GENSYM-COUNTER* here turned out to be harmless in
 623   ;; practice, it was also useless in practice. So we don't do it any more.)
 624
 625   (values))
 626 \f
 627 ;;;; trace output
 628
 629 ;;; Print out some useful info about COMPONENT to STREAM.
 630 (defun describe-component (component *standard-output*)
 631   (declare (type component component))
 632   (format t "~|~%;;;; component: ~S~2%" (component-name component))
 633   (print-blocks component)
 634   (values))
 635
 636 (defun describe-ir2-component (component *standard-output*)
 637   (format t "~%~|~%;;;; IR2 component: ~S~2%" (component-name component))
 638   (format t "entries:~%")
 639   (dolist (entry (ir2-component-entries (component-info component)))
 640     (format t "~4TL~D: ~S~:[~; [closure]~]~%"
 641             (label-id (entry-info-offset entry))
 642             (entry-info-name entry)
 643             (entry-info-closure-p entry)))
 644   (terpri)
 645   (pre-pack-tn-stats component *standard-output*)
 646   (terpri)
 647   (print-ir2-blocks component)
 648   (terpri)
 649   (values))
 650 \f
 651 ;;;; file reading
 652 ;;;;
 653 ;;;; When reading from a file, we have to keep track of some source
 654 ;;;; information. We also exploit our ability to back up for printing
 655 ;;;; the error context and for recovering from errors.
 656 ;;;;
 657 ;;;; The interface we provide to this stuff is the stream-oid
 658 ;;;; SOURCE-INFO structure. The bookkeeping is done as a side effect
 659 ;;;; of getting the next source form.
 660
 661 ;;; A FILE-INFO structure holds all the source information for a
 662 ;;; given file.
 663 (defstruct (file-info (:copier nil))
 664   ;; If a file, the truename of the corresponding source file. If from
 665   ;; a Lisp form, :LISP. If from a stream, :STREAM.
 666   (name (missing-arg) :type (or pathname (member :lisp :stream)))
 667   ;; the defaulted, but not necessarily absolute file name (i.e. prior
 668   ;; to TRUENAME call.) Null if not a file. This is used to set
 669   ;; *COMPILE-FILE-PATHNAME*, and if absolute, is dumped in the
 670   ;; debug-info.
 671   (untruename nil :type (or pathname null))
 672   ;; the file's write date (if relevant)
 673   (write-date nil :type (or unsigned-byte null))
 674   ;; the source path root number of the first form in this file (i.e.
 675   ;; the total number of forms converted previously in this
 676   ;; compilation)
 677   (source-root 0 :type unsigned-byte)
 678   ;; parallel vectors containing the forms read out of the file and
 679   ;; the file positions that reading of each form started at (i.e. the
 680   ;; end of the previous form)
 681   (forms (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t))
 682   (positions (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t)))
 683
 684 ;;; The SOURCE-INFO structure provides a handle on all the source
 685 ;;; information for an entire compilation.
 686 (defstruct (source-info
 687             #-no-ansi-print-object
 688             (:print-object (lambda (s stream)
 689                              (print-unreadable-object (s stream :type t))))
 690             (:copier nil))
 691   ;; the UT that compilation started at
 692   (start-time (get-universal-time) :type unsigned-byte)
 693   ;; the FILE-INFO structure for this compilation
 694   (file-info nil :type (or file-info null))
 695   ;; the stream that we are using to read the FILE-INFO, or NIL if
 696   ;; no stream has been opened yet
 697   (stream nil :type (or stream null)))
 698
 699 ;;; Given a pathname, return a SOURCE-INFO structure.
 700 (defun make-file-source-info (file)
 701   (let ((file-info (make-file-info :name (truename file)
 702                                    :untruename file
 703                                    :write-date (file-write-date file))))
 704
 705     (make-source-info :file-info file-info)))
 706
 707 ;;; Return a SOURCE-INFO to describe the incremental compilation of FORM.
 708 (defun make-lisp-source-info (form)
 709   (make-source-info :start-time (get-universal-time)
 710                     :file-info (make-file-info :name :lisp
 711                                                :forms (vector form)
 712                                                :positions '#(0))))
 713
 714 ;;; Return a SOURCE-INFO which will read from STREAM.
 715 (defun make-stream-source-info (stream)
 716   (let ((file-info (make-file-info :name :stream)))
 717     (make-source-info :file-info file-info
 718                       :stream stream)))
 719
 720 ;;; Return a form read from STREAM; or for EOF use the trick,
 721 ;;; popularized by Kent Pitman, of returning STREAM itself. If an
 722 ;;; error happens, then convert it to standard abort-the-compilation
 723 ;;; error condition (possibly recording some extra location
 724 ;;; information).
 725 (defun read-for-compile-file (stream position)
 726   (handler-case (read stream nil stream)
 727     (reader-error (condition)
 728      (error 'input-error-in-compile-file
 729             :error condition
 730             ;; We don't need to supply :POSITION here because
 731             ;; READER-ERRORs already know their position in the file.
 732             ))
 733     ;; ANSI, in its wisdom, says that READ should return END-OF-FILE
 734     ;; (and that this is not a READER-ERROR) when it encounters end of
 735     ;; file in the middle of something it's trying to read.
 736     (end-of-file (condition)
 737      (error 'input-error-in-compile-file
 738             :error condition
 739             ;; We need to supply :POSITION here because the END-OF-FILE
 740             ;; condition doesn't carry the position that the user
 741             ;; probably cares about, where the failed READ began.
 742             :position position))))
 743
 744 ;;; If STREAM is present, return it, otherwise open a stream to the
 745 ;;; current file. There must be a current file.
 746 ;;;
 747 ;;; FIXME: This is probably an unnecessarily roundabout way to do
 748 ;;; things now that we process a single file in COMPILE-FILE (unlike
 749 ;;; the old CMU CL code, which accepted multiple files). Also, the old
 750 ;;; comment said
 751 ;;;   When we open a new file, we also reset *PACKAGE* and policy.
 752 ;;;   This gives the effect of rebinding around each file.
 753 ;;; which doesn't seem to be true now. Check to make sure that if
 754 ;;; such rebinding is necessary, it's still done somewhere.
 755 (defun get-source-stream (info)
 756   (declare (type source-info info))
 757   (or (source-info-stream info)
 758       (let* ((file-info (source-info-file-info info))
 759              (name (file-info-name file-info)))
 760         (setf sb!xc:*compile-file-truename* name
 761               sb!xc:*compile-file-pathname* (file-info-untruename file-info)
 762               (source-info-stream info) (open name :direction :input)))))
 763
 764 ;;; Close the stream in INFO if it is open.
 765 (defun close-source-info (info)
 766   (declare (type source-info info))
 767   (let ((stream (source-info-stream info)))
 768     (when stream (close stream)))
 769   (setf (source-info-stream info) nil)
 770   (values))
 771
 772 ;;; Read and compile the source file.
 773 (defun sub-sub-compile-file (info)
 774   (let* ((file-info (source-info-file-info info))
 775          (stream (get-source-stream info)))
 776     (loop
 777      (let* ((pos (file-position stream))
 778             (form (read-for-compile-file stream pos)))
 779        (if (eq form stream) ; i.e., if EOF
 780            (return)
 781            (let* ((forms (file-info-forms file-info))
 782                   (current-idx (+ (fill-pointer forms)
 783                                   (file-info-source-root file-info))))
 784              (vector-push-extend form forms)
 785              (vector-push-extend pos (file-info-positions file-info))
 786              (find-source-paths form current-idx)
 787              (process-toplevel-form form
 788                                     `(original-source-start 0 ,current-idx)
 789                                     nil)))))))
 790
 791 ;;; Return the INDEX'th source form read from INFO and the position
 792 ;;; where it was read.
 793 (defun find-source-root (index info)
 794   (declare (type index index) (type source-info info))
 795   (let ((file-info (source-info-file-info info)))
 796     (values (aref (file-info-forms file-info) index)
 797             (aref (file-info-positions file-info) index))))
 798 \f
 799 ;;;; processing of top level forms
 800
 801 ;;; This is called by top level form processing when we are ready to
 802 ;;; actually compile something. If *BLOCK-COMPILE* is T, then we still
 803 ;;; convert the form, but delay compilation, pushing the result on
 804 ;;; *TOPLEVEL-LAMBDAS* instead.
 805 (defun convert-and-maybe-compile (form path)
 806   (declare (list path))
 807   (let* ((*lexenv* (make-lexenv :policy *policy*))
 808          (tll (ir1-toplevel form path nil)))
 809     (cond ((eq *block-compile* t) (push tll *toplevel-lambdas*))
 810           (t (compile-toplevel (list tll) nil)))))
 811
 812 ;;; Macroexpand FORM in the current environment with an error handler.
 813 ;;; We only expand one level, so that we retain all the intervening
 814 ;;; forms in the source path.
 815 (defun preprocessor-macroexpand-1 (form)
 816   (handler-case (sb!xc:macroexpand-1 form *lexenv*)
 817     (error (condition)
 818       (compiler-error "(during macroexpansion of ~A)~%~A"
 819                       (let ((*print-level* 1)
 820                             (*print-length* 2))
 821                         (format nil "~S" form))
 822                       condition))))
 823
 824 ;;; Process a PROGN-like portion of a top level form. FORMS is a list of
 825 ;;; the forms, and PATH is the source path of the FORM they came out of.
 826 ;;; COMPILE-TIME-TOO is as in ANSI "3.2.3.1 Processing of Top Level Forms".
 827 (defun process-toplevel-progn (forms path compile-time-too)
 828   (declare (list forms) (list path))
 829   (dolist (form forms)
 830     (process-toplevel-form form path compile-time-too)))
 831
 832 ;;; Process a top level use of LOCALLY, or anything else (e.g.
 833 ;;; MACROLET) at top level which has declarations and ordinary forms.
 834 ;;; We parse declarations and then recursively process the body.
 835 (defun process-toplevel-locally (body path compile-time-too &key vars funs)
 836   (declare (list path))
 837   (multiple-value-bind (forms decls) (parse-body body nil)
 838     (let* ((*lexenv*
 839             (process-decls decls vars funs (make-continuation)))
 840            ;; Binding *POLICY* is pretty much of a hack, since it
 841            ;; causes LOCALLY to "capture" enclosed proclamations. It
 842            ;; is necessary because CONVERT-AND-MAYBE-COMPILE uses the
 843            ;; value of *POLICY* as the policy. The need for this hack
 844            ;; is due to the quirk that there is no way to represent in
 845            ;; a POLICY that an optimize quality came from the default.
 846            ;;
 847            ;; FIXME: Ideally, something should be done so that DECLAIM
 848            ;; inside LOCALLY works OK. Failing that, at least we could
 849            ;; issue a warning instead of silently screwing up.
 850            (*policy* (lexenv-policy *lexenv*)))
 851       (process-toplevel-progn forms path compile-time-too))))
 852
 853 ;;; Parse an EVAL-WHEN situations list, returning three flags,
 854 ;;; (VALUES COMPILE-TOPLEVEL LOAD-TOPLEVEL EXECUTE), indicating
 855 ;;; the types of situations present in the list.
 856 (defun parse-eval-when-situations (situations)
 857   (when (or (not (listp situations))
 858             (set-difference situations
 859                             '(:compile-toplevel
 860                               compile
 861                               :load-toplevel
 862                               load
 863                               :execute
 864                               eval)))
 865     (compiler-error "bad EVAL-WHEN situation list: ~S" situations))
 866   (let ((deprecated-names (intersection situations '(compile load eval))))
 867     (when deprecated-names
 868       (style-warn "using deprecated EVAL-WHEN situation names~{ ~S~}"
 869                   deprecated-names)))
 870   (values (intersection '(:compile-toplevel compile)
 871                         situations)
 872           (intersection '(:load-toplevel load) situations)
 873           (intersection '(:execute eval) situations)))
 874
 875
 876 ;;; utilities for extracting COMPONENTs of FUNCTIONALs
 877 (defun functional-components (f)
 878   (declare (type functional f))
 879   (etypecase f
 880     (clambda (list (lambda-component f)))
 881     (optional-dispatch (let ((result nil))
 882                          (flet ((maybe-frob (maybe-clambda)
 883                                   (when (and maybe-clambda
 884                                              (promise-ready-p maybe-clambda))
 885                                     (pushnew (lambda-component
 886                                               (force maybe-clambda))
 887                                              result))))
 888                            (map nil #'maybe-frob (optional-dispatch-entry-points f))
 889                            (maybe-frob (optional-dispatch-more-entry f))
 890                            (maybe-frob (optional-dispatch-main-entry f)))
 891                          result))))
 892
 893 (defun make-functional-from-toplevel-lambda (definition
 894                                              &key
 895                                              name
 896                                              (path
 897                                               ;; I'd thought NIL should
 898                                               ;; work, but it doesn't.
 899                                               ;; -- WHN 2001-09-20
 900                                               (missing-arg)))
 901   (let* ((*current-path* path)
 902          (component (make-empty-component))
 903          (*current-component* component))
 904     (setf (component-name component)
 905           (debug-namify "~S initial component" name))
 906     (setf (component-kind component) :initial)
 907     (let* ((locall-fun (ir1-convert-lambdalike
 908                         definition
 909                         :debug-name (debug-namify "top level local call ~S"
 910                                                   name)
 911                         ;; KLUDGE: we do this so that we get to have
 912                         ;; nice debug returnness in functions defined
 913                         ;; from the REPL
 914                         :allow-debug-catch-tag t))
 915            (fun (ir1-convert-lambda (make-xep-lambda-expression locall-fun)
 916                                     :source-name (or name '.anonymous.)
 917                                     :debug-name (unless name
 918                                                   "top level form"))))
 919       (when name
 920         (assert-global-function-definition-type name locall-fun))
 921       (setf (functional-entry-fun fun) locall-fun
 922             (functional-kind fun) :external
 923             (functional-has-external-references-p fun) t)
 924       fun)))
 925
 926 ;;; Compile LAMBDA-EXPRESSION into *COMPILE-OBJECT*, returning a
 927 ;;; description of the result.
 928 ;;;   * If *COMPILE-OBJECT* is a CORE-OBJECT, then write the function
 929 ;;;     into core and return the compiled FUNCTION value.
 930 ;;;   * If *COMPILE-OBJECT* is a fasl file, then write the function
 931 ;;;     into the fasl file and return a dump handle.
 932 ;;;
 933 ;;; If NAME is provided, then we try to use it as the name of the
 934 ;;; function for debugging/diagnostic information.
 935 (defun %compile (lambda-expression
 936                  *compile-object*
 937                  &key
 938                  name
 939                  (path
 940                   ;; This magical idiom seems to be the appropriate
 941                   ;; path for compiling standalone LAMBDAs, judging
 942                   ;; from the CMU CL code and experiment, so it's a
 943                   ;; nice default for things where we don't have a
 944                   ;; real source path (as in e.g. inside CL:COMPILE).
 945                   '(original-source-start 0 0)))
 946   (when name
 947     (legal-fun-name-or-type-error name))
 948   (let* ((*lexenv* (make-lexenv :policy *policy*))
 949          (fun (make-functional-from-toplevel-lambda lambda-expression
 950                                                     :name name
 951                                                     :path path)))
 952
 953     ;; FIXME: The compile-it code from here on is sort of a
 954     ;; twisted version of the code in COMPILE-TOPLEVEL. It'd be
 955     ;; better to find a way to share the code there; or
 956     ;; alternatively, to use this code to replace the code there.
 957     ;; (The second alternative might be pretty easy if we used
 958     ;; the :LOCALL-ONLY option to IR1-FOR-LAMBDA. Then maybe the
 959     ;; whole FUNCTIONAL-KIND=:TOPLEVEL case could go away..)
 960
 961     (locall-analyze-clambdas-until-done (list fun))
 962
 963     (multiple-value-bind (components-from-dfo top-components hairy-top)
 964         (find-initial-dfo (list fun))
 965
 966       (let ((*all-components* (append components-from-dfo top-components)))
 967         ;; FIXME: This is more monkey see monkey do based on CMU CL
 968         ;; code. If anyone figures out why to only prescan HAIRY-TOP
 969         ;; and TOP-COMPONENTS here, instead of *ALL-COMPONENTS* or
 970         ;; some other combination of results from FIND-INITIAL-VALUES,
 971         ;; it'd be good to explain it.
 972         (mapc #'preallocate-physenvs-for-toplevelish-lambdas hairy-top)
 973         (mapc #'preallocate-physenvs-for-toplevelish-lambdas top-components)
 974         (dolist (component-from-dfo components-from-dfo)
 975           (compile-component component-from-dfo)
 976           (replace-toplevel-xeps component-from-dfo)))
 977
 978       (let ((entry-table (etypecase *compile-object*
 979                            (fasl-output (fasl-output-entry-table
 980                                          *compile-object*))
 981                            (core-object (core-object-entry-table
 982                                          *compile-object*)))))
 983         (multiple-value-bind (result found-p)
 984             (gethash (leaf-info fun) entry-table)
 985           (aver found-p)
 986           (prog1
 987               result
 988             ;; KLUDGE: This code duplicates some other code in this
 989             ;; file. In the great reorganzation, the flow of program
 990             ;; logic changed from the original CMUCL model, and that
 991             ;; path (as of sbcl-0.7.5 in SUB-COMPILE-FILE) was no
 992             ;; longer followed for CORE-OBJECTS, leading to BUG
 993             ;; 156. This place is transparently not the right one for
 994             ;; this code, but I don't have a clear enough overview of
 995             ;; the compiler to know how to rearrange it all so that
 996             ;; this operation fits in nicely, and it was blocking
 997             ;; reimplementation of (DECLAIM (INLINE FOO)) (MACROLET
 998             ;; ((..)) (DEFUN FOO ...))
 999             ;;
1000             ;; FIXME: This KLUDGE doesn't solve all the problem in an
1001             ;; ideal way, as (1) definitions typed in at the REPL
1002             ;; without an INLINE declaration will give a NULL
1003             ;; FUNCTION-LAMBDA-EXPRESSION (allowable, but not ideal)
1004             ;; and (2) INLINE declarations will yield a
1005             ;; FUNCTION-LAMBDA-EXPRESSION headed by
1006             ;; SB-C:LAMBDA-WITH-LEXENV, even for null LEXENV.  -- CSR,
1007             ;; 2002-07-02
1008             ;;
1009             ;; (2) is probably fairly easy to fix -- it is, after all,
1010             ;; a matter of list manipulation (or possibly of teaching
1011             ;; CL:FUNCTION about SB-C:LAMBDA-WITH-LEXENV).  (1) is
1012             ;; significantly harder, as the association between
1013             ;; function object and source is a tricky one.
1014             ;;
1015             ;; FUNCTION-LAMBDA-EXPRESSION "works" (i.e. returns a
1016             ;; non-NULL list) when the function in question has been
1017             ;; compiled by (COMPILE <x> '(LAMBDA ...)); it does not
1018             ;; work when it has been compiled as part of the top-level
1019             ;; EVAL strategy of compiling everything inside (LAMBDA ()
1020             ;; ...).  -- CSR, 2002-11-02
1021             (when (core-object-p *compile-object*)
1022               (fix-core-source-info *source-info* *compile-object* result))
1023
1024             (mapc #'clear-ir1-info components-from-dfo)
1025             (clear-stuff)))))))
1026
1027 (defun process-toplevel-cold-fset (name lambda-expression path)
1028   (unless (producing-fasl-file)
1029     (error "can't COLD-FSET except in a fasl file"))
1030   (legal-fun-name-or-type-error name)
1031   (fasl-dump-cold-fset name
1032                        (%compile lambda-expression
1033                                  *compile-object*
1034                                  :name name
1035                                  :path path)
1036                        *compile-object*)
1037   (values))
1038
1039 ;;; Process a top level FORM with the specified source PATH.
1040 ;;;  * If this is a magic top level form, then do stuff.
1041 ;;;  * If this is a macro, then expand it.
1042 ;;;  * Otherwise, just compile it.
1043 ;;;
1044 ;;; COMPILE-TIME-TOO is as defined in ANSI
1045 ;;; "3.2.3.1 Processing of Top Level Forms".
1046 (defun process-toplevel-form (form path compile-time-too)
1047
1048   (declare (list path))
1049
1050   (catch 'process-toplevel-form-error-abort
1051     (let* ((path (or (gethash form *source-paths*) (cons form path)))
1052            (*compiler-error-bailout*
1053             (lambda ()
1054               (convert-and-maybe-compile
1055                `(error 'simple-program-error
1056                  :format-control "execution of a form compiled with errors:~% ~S"
1057                  :format-arguments (list ',form))
1058                path)
1059               (throw 'process-toplevel-form-error-abort nil))))
1060
1061       (flet ((default-processor (form)
1062                ;; When we're cross-compiling, consider: what should we
1063                ;; do when we hit e.g.
1064                ;;   (EVAL-WHEN (:COMPILE-TOPLEVEL)
1065                ;;     (DEFUN FOO (X) (+ 7 X)))?
1066                ;; DEFUN has a macro definition in the cross-compiler,
1067                ;; and a different macro definition in the target
1068                ;; compiler. The only sensible thing is to use the
1069                ;; target compiler's macro definition, since the
1070                ;; cross-compiler's macro is in general into target
1071                ;; functions which can't meaningfully be executed at
1072                ;; cross-compilation time. So make sure we do the EVAL
1073                ;; here, before we macroexpand.
1074                ;;
1075                ;; Then things get even dicier with something like
1076                ;;   (DEFCONSTANT-EQX SB!XC:LAMBDA-LIST-KEYWORDS ..)
1077                ;; where we have to make sure that we don't uncross
1078                ;; the SB!XC: prefix before we do EVAL, because otherwise
1079                ;; we'd be trying to redefine the cross-compilation host's
1080                ;; constants.
1081                ;;
1082                ;; (Isn't it fun to cross-compile Common Lisp?:-)
1083                #+sb-xc-host
1084                (progn
1085                  (when compile-time-too
1086                    (eval form)) ; letting xc host EVAL do its own macroexpansion
1087                  (let* (;; (We uncross the operator name because things
1088                         ;; like SB!XC:DEFCONSTANT and SB!XC:DEFTYPE
1089                         ;; should be equivalent to their CL: counterparts
1090                         ;; when being compiled as target code. We leave
1091                         ;; the rest of the form uncrossed because macros
1092                         ;; might yet expand into EVAL-WHEN stuff, and
1093                         ;; things inside EVAL-WHEN can't be uncrossed
1094                         ;; until after we've EVALed them in the
1095                         ;; cross-compilation host.)
1096                         (slightly-uncrossed (cons (uncross (first form))
1097                                                   (rest form)))
1098                         (expanded (preprocessor-macroexpand-1
1099                                    slightly-uncrossed)))
1100                    (if (eq expanded slightly-uncrossed)
1101                        ;; (Now that we're no longer processing toplevel
1102                        ;; forms, and hence no longer need to worry about
1103                        ;; EVAL-WHEN, we can uncross everything.)
1104                        (convert-and-maybe-compile expanded path)
1105                        ;; (We have to demote COMPILE-TIME-TOO to NIL
1106                        ;; here, no matter what it was before, since
1107                        ;; otherwise we'd tend to EVAL subforms more than
1108                        ;; once, because of WHEN COMPILE-TIME-TOO form
1109                        ;; above.)
1110                        (process-toplevel-form expanded path nil))))
1111                ;; When we're not cross-compiling, we only need to
1112                ;; macroexpand once, so we can follow the 1-thru-6
1113                ;; sequence of steps in ANSI's "3.2.3.1 Processing of
1114                ;; Top Level Forms".
1115                #-sb-xc-host
1116                (let ((expanded (preprocessor-macroexpand-1 form)))
1117                  (cond ((eq expanded form)
1118                         (when compile-time-too
1119                           (eval-in-lexenv form *lexenv*))
1120                         (convert-and-maybe-compile form path))
1121                        (t
1122                         (process-toplevel-form expanded
1123                                                path
1124                                                compile-time-too))))))
1125         (if (atom form)
1126             #+sb-xc-host
1127             ;; (There are no xc EVAL-WHEN issues in the ATOM case until
1128             ;; (1) SBCL gets smart enough to handle global
1129             ;; DEFINE-SYMBOL-MACRO or SYMBOL-MACROLET and (2) SBCL
1130             ;; implementors start using symbol macros in a way which
1131             ;; interacts with SB-XC/CL distinction.)
1132             (convert-and-maybe-compile form path)
1133             #-sb-xc-host
1134             (default-processor form)
1135             (flet ((need-at-least-one-arg (form)
1136                      (unless (cdr form)
1137                        (compiler-error "~S form is too short: ~S"
1138                                        (car form)
1139                                        form))))
1140               (case (car form)
1141                 ;; In the cross-compiler, top level COLD-FSET arranges
1142                 ;; for static linking at cold init time.
1143                 #+sb-xc-host
1144                 ((cold-fset)
1145                  (aver (not compile-time-too))
1146                  (destructuring-bind (cold-fset fun-name lambda-expression) form
1147                    (declare (ignore cold-fset))
1148                    (process-toplevel-cold-fset fun-name
1149                                                lambda-expression
1150                                                path)))
1151                 ((eval-when macrolet symbol-macrolet);things w/ 1 arg before body
1152                  (need-at-least-one-arg form)
1153                  (destructuring-bind (special-operator magic &rest body) form
1154                    (ecase special-operator
1155                      ((eval-when)
1156                       ;; CT, LT, and E here are as in Figure 3-7 of ANSI
1157                       ;; "3.2.3.1 Processing of Top Level Forms".
1158                       (multiple-value-bind (ct lt e)
1159                           (parse-eval-when-situations magic)
1160                         (let ((new-compile-time-too (or ct
1161                                                         (and compile-time-too
1162                                                              e))))
1163                           (cond (lt (process-toplevel-progn
1164                                      body path new-compile-time-too))
1165                                 (new-compile-time-too (eval-in-lexenv
1166                                                        `(progn ,@body)
1167                                                        *lexenv*))))))
1168                      ((macrolet)
1169                       (funcall-in-macrolet-lexenv
1170                        magic
1171                        (lambda (&key funs)
1172                          (declare (ignore funs))
1173                          (process-toplevel-locally body
1174                                                    path
1175                                                    compile-time-too))
1176                        :compile))
1177                      ((symbol-macrolet)
1178                       (funcall-in-symbol-macrolet-lexenv
1179                        magic
1180                        (lambda (&key vars)
1181                          (process-toplevel-locally body
1182                                                    path
1183                                                    compile-time-too
1184                                                    :vars vars))
1185                        :compile)))))
1186                 ((locally)
1187                  (process-toplevel-locally (rest form) path compile-time-too))
1188                 ((progn)
1189                  (process-toplevel-progn (rest form) path compile-time-too))
1190                 (t (default-processor form))))))))
1191
1192   (values))
1193 \f
1194 ;;;; load time value support
1195 ;;;;
1196 ;;;; (See EMIT-MAKE-LOAD-FORM.)
1197
1198 ;;; Return T if we are currently producing a fasl file and hence
1199 ;;; constants need to be dumped carefully.
1200 (defun producing-fasl-file ()
1201   (fasl-output-p *compile-object*))
1202
1203 ;;; Compile FORM and arrange for it to be called at load-time. Return
1204 ;;; the dumper handle and our best guess at the type of the object.
1205 (defun compile-load-time-value (form)
1206   (let ((lambda (compile-load-time-stuff form t)))
1207     (values
1208      (fasl-dump-load-time-value-lambda lambda *compile-object*)
1209      (let ((type (leaf-type lambda)))
1210        (if (fun-type-p type)
1211            (single-value-type (fun-type-returns type))
1212            *wild-type*)))))
1213
1214 ;;; Compile the FORMS and arrange for them to be called (for effect,
1215 ;;; not value) at load time.
1216 (defun compile-make-load-form-init-forms (forms)
1217   (let ((lambda (compile-load-time-stuff `(progn ,@forms) nil)))
1218     (fasl-dump-toplevel-lambda-call lambda *compile-object*)))
1219
1220 ;;; Do the actual work of COMPILE-LOAD-TIME-VALUE or
1221 ;;; COMPILE-MAKE-LOAD-FORM-INIT-FORMS.
1222 (defun compile-load-time-stuff (form for-value)
1223   (with-ir1-namespace
1224    (let* ((*lexenv* (make-null-lexenv))
1225           (lambda (ir1-toplevel form *current-path* for-value)))
1226      (compile-toplevel (list lambda) t)
1227      lambda)))
1228
1229 ;;; This is called by COMPILE-TOPLEVEL when it was passed T for
1230 ;;; LOAD-TIME-VALUE-P (which happens in COMPILE-LOAD-TIME-STUFF). We
1231 ;;; don't try to combine this component with anything else and frob
1232 ;;; the name. If not in a :TOPLEVEL component, then don't bother
1233 ;;; compiling, because it was merged with a run-time component.
1234 (defun compile-load-time-value-lambda (lambdas)
1235   (aver (null (cdr lambdas)))
1236   (let* ((lambda (car lambdas))
1237          (component (lambda-component lambda)))
1238     (when (eql (component-kind component) :toplevel)
1239       (setf (component-name component) (leaf-debug-name lambda))
1240       (compile-component component)
1241       (clear-ir1-info component))))
1242 \f
1243 ;;;; COMPILE-FILE
1244
1245 (defun object-call-toplevel-lambda (tll)
1246   (declare (type functional tll))
1247   (let ((object *compile-object*))
1248     (etypecase object
1249       (fasl-output (fasl-dump-toplevel-lambda-call tll object))
1250       (core-object (core-call-toplevel-lambda      tll object))
1251       (null))))
1252
1253 ;;; Smash LAMBDAS into a single component, compile it, and arrange for
1254 ;;; the resulting function to be called.
1255 (defun sub-compile-toplevel-lambdas (lambdas)
1256   (declare (list lambdas))
1257   (when lambdas
1258     (multiple-value-bind (component tll) (merge-toplevel-lambdas lambdas)
1259       (compile-component component)
1260       (clear-ir1-info component)
1261       (object-call-toplevel-lambda tll)))
1262   (values))
1263
1264 ;;; Compile top level code and call the top level lambdas. We pick off
1265 ;;; top level lambdas in non-top-level components here, calling
1266 ;;; SUB-c-t-l-l on each subsequence of normal top level lambdas.
1267 (defun compile-toplevel-lambdas (lambdas)
1268   (declare (list lambdas))
1269   (let ((len (length lambdas)))
1270     (flet ((loser (start)
1271              (or (position-if (lambda (x)
1272                                 (not (eq (component-kind
1273                                           (node-component (lambda-bind x)))
1274                                          :toplevel)))
1275                               lambdas
1276                               ;; this used to read ":start start", but
1277                               ;; start can be greater than len, which
1278                               ;; is an error according to ANSI - CSR,
1279                               ;; 2002-04-25
1280                               :start (min start len))
1281                  len)))
1282       (do* ((start 0 (1+ loser))
1283             (loser (loser start) (loser start)))
1284            ((>= start len))
1285         (sub-compile-toplevel-lambdas (subseq lambdas start loser))
1286         (unless (= loser len)
1287           (object-call-toplevel-lambda (elt lambdas loser))))))
1288   (values))
1289
1290 ;;; Compile LAMBDAS (a list of CLAMBDAs for top level forms) into the
1291 ;;; object file.
1292 ;;;
1293 ;;; LOAD-TIME-VALUE-P seems to control whether it's MAKE-LOAD-FORM and
1294 ;;; COMPILE-LOAD-TIME-VALUE stuff. -- WHN 20000201
1295 (defun compile-toplevel (lambdas load-time-value-p)
1296   (declare (list lambdas))
1297
1298   (maybe-mumble "locall ")
1299   (locall-analyze-clambdas-until-done lambdas)
1300
1301   (maybe-mumble "IDFO ")
1302   (multiple-value-bind (components top-components hairy-top)
1303       (find-initial-dfo lambdas)
1304     (let ((*all-components* (append components top-components)))
1305       (when *check-consistency*
1306         (maybe-mumble "[check]~%")
1307         (check-ir1-consistency *all-components*))
1308
1309       (dolist (component (append hairy-top top-components))
1310         (pre-physenv-analyze-toplevel component))
1311
1312       (dolist (component components)
1313         (compile-component component)
1314         (replace-toplevel-xeps component))
1315
1316       (when *check-consistency*
1317         (maybe-mumble "[check]~%")
1318         (check-ir1-consistency *all-components*))
1319
1320       (if load-time-value-p
1321           (compile-load-time-value-lambda lambdas)
1322           (compile-toplevel-lambdas lambdas))
1323
1324       (mapc #'clear-ir1-info components)
1325       (clear-stuff)))
1326   (values))
1327
1328 ;;; Actually compile any stuff that has been queued up for block
1329 ;;; compilation.
1330 (defun finish-block-compilation ()
1331   (when *block-compile*
1332     (when *toplevel-lambdas*
1333       (compile-toplevel (nreverse *toplevel-lambdas*) nil)
1334       (setq *toplevel-lambdas* ()))
1335     (setq *block-compile* nil)
1336     (setq *entry-points* nil)))
1337
1338 ;;; Read all forms from INFO and compile them, with output to OBJECT.
1339 ;;; Return (VALUES NIL WARNINGS-P FAILURE-P).
1340 (defun sub-compile-file (info)
1341   (declare (type source-info info))
1342   (let* ((*block-compile* *block-compile-arg*)
1343          (*package* (sane-package))
1344          (*policy* *policy*)
1345          (*lexenv* (make-null-lexenv))
1346          (*source-info* info)
1347          (sb!xc:*compile-file-pathname* nil)
1348          (sb!xc:*compile-file-truename* nil)
1349          (*toplevel-lambdas* ())
1350          (*fun-names-in-this-file* ())
1351          (*compiler-error-bailout*
1352           (lambda ()
1353             (compiler-mumble "~2&; fatal error, aborting compilation~%")
1354             (return-from sub-compile-file (values nil t t))))
1355          (*current-path* nil)
1356          (*last-source-context* nil)
1357          (*last-original-source* nil)
1358          (*last-source-form* nil)
1359          (*last-format-string* nil)
1360          (*last-format-args* nil)
1361          (*last-message-count* 0)
1362          ;; FIXME: Do we need this rebinding here? It's a literal
1363          ;; translation of the old CMU CL rebinding to
1364          ;; (OR *BACKEND-INFO-ENVIRONMENT* *INFO-ENVIRONMENT*),
1365          ;; and it's not obvious whether the rebinding to itself is
1366          ;; needed that SBCL doesn't need *BACKEND-INFO-ENVIRONMENT*.
1367          (*info-environment* *info-environment*)
1368          (*gensym-counter* 0))
1369     (handler-case
1370         (with-compilation-values
1371          (sb!xc:with-compilation-unit ()
1372            (clear-stuff)
1373
1374            (sub-sub-compile-file info)
1375
1376            (finish-block-compilation)
1377            (let ((object *compile-object*))
1378              (etypecase object
1379                (fasl-output (fasl-dump-source-info info object))
1380                (core-object (fix-core-source-info info object))
1381                (null)))
1382            nil))
1383       ;; Some errors are sufficiently bewildering that we just fail
1384       ;; immediately, without trying to recover and compile more of
1385       ;; the input file.
1386       (input-error-in-compile-file (condition)
1387        (format *error-output*
1388                "~@<compilation aborted because of input error: ~2I~_~A~:>"
1389                condition)
1390        (values nil t t)))))
1391
1392 ;;; Return a pathname for the named file. The file must exist.
1393 (defun verify-source-file (pathname-designator)
1394   (let* ((pathname (pathname pathname-designator))
1395          (default-host (make-pathname :host (pathname-host pathname))))
1396     (flet ((try-with-type (path type error-p)
1397              (let ((new (merge-pathnames
1398                          path (make-pathname :type type
1399                                              :defaults default-host))))
1400                (if (probe-file new)
1401                    new
1402                    (and error-p (truename new))))))
1403       (cond ((typep pathname 'logical-pathname)
1404              (try-with-type pathname "LISP" t))
1405             ((probe-file pathname) pathname)
1406             ((try-with-type pathname "lisp"  nil))
1407             ((try-with-type pathname "lisp"  t))))))
1408
1409 (defun elapsed-time-to-string (tsec)
1410   (multiple-value-bind (tmin sec) (truncate tsec 60)
1411     (multiple-value-bind (thr min) (truncate tmin 60)
1412       (format nil "~D:~2,'0D:~2,'0D" thr min sec))))
1413
1414 ;;; Print some junk at the beginning and end of compilation.
1415 (defun start-error-output (source-info)
1416   (declare (type source-info source-info))
1417   (let ((file-info (source-info-file-info source-info)))
1418     (compiler-mumble "~&; compiling file ~S (written ~A):~%"
1419                      (namestring (file-info-name file-info))
1420                      (sb!int:format-universal-time nil
1421                                                    (file-info-write-date
1422                                                     file-info)
1423                                                    :style :government
1424                                                    :print-weekday nil
1425                                                    :print-timezone nil)))
1426   (values))
1427 (defun finish-error-output (source-info won)
1428   (declare (type source-info source-info))
1429   (compiler-mumble "~&; compilation ~:[aborted after~;finished in~] ~A~&"
1430                    won
1431                    (elapsed-time-to-string
1432                     (- (get-universal-time)
1433                        (source-info-start-time source-info))))
1434   (values))
1435
1436 ;;; Open some files and call SUB-COMPILE-FILE. If something unwinds
1437 ;;; out of the compile, then abort the writing of the output file, so
1438 ;;; that we don't overwrite it with known garbage.
1439 (defun sb!xc:compile-file
1440     (input-file
1441      &key
1442
1443      ;; ANSI options
1444      (output-file (cfp-output-file-default input-file))
1445      ;; FIXME: ANSI doesn't seem to say anything about
1446      ;; *COMPILE-VERBOSE* and *COMPILE-PRINT* being rebound by this
1447      ;; function..
1448      ((:verbose sb!xc:*compile-verbose*) sb!xc:*compile-verbose*)
1449      ((:print sb!xc:*compile-print*) sb!xc:*compile-print*)
1450      (external-format :default)
1451
1452      ;; extensions
1453      (trace-file nil)
1454      ((:block-compile *block-compile-arg*) nil))
1455
1456   #!+sb-doc
1457   "Compile INPUT-FILE, producing a corresponding fasl file and returning
1458    its filename. Besides the ANSI &KEY arguments :OUTPUT-FILE, :VERBOSE,
1459    :PRINT, and :EXTERNAL-FORMAT,the following extensions are supported:
1460      :TRACE-FILE
1461         If given, internal data structures are dumped to the specified
1462         file, or if a value of T is given, to a file of *.trace type
1463         derived from the input file name.
1464    Also, as a workaround for vaguely-non-ANSI behavior, the :BLOCK-COMPILE
1465    argument is quasi-supported, to determine whether multiple
1466    functions are compiled together as a unit, resolving function
1467    references at compile time. NIL means that global function names
1468    are never resolved at compilation time. Currently NIL is the
1469    default behavior, because although section 3.2.2.3, \"Semantic
1470    Constraints\", of the ANSI spec allows this behavior under all
1471    circumstances, the compiler's runtime scales badly when it
1472    tries to do this for large files. If/when this performance
1473    problem is fixed, the block compilation default behavior will
1474    probably be made dependent on the SPEED and COMPILATION-SPEED
1475    optimization values, and the :BLOCK-COMPILE argument will probably
1476    become deprecated."
1477
1478   (unless (eq external-format :default)
1479     (error "Non-:DEFAULT EXTERNAL-FORMAT values are not supported."))
1480   (let* ((fasl-output nil)
1481          (output-file-name nil)
1482          (compile-won nil)
1483          (warnings-p nil)
1484          (failure-p t) ; T in case error keeps this from being set later
1485          (input-pathname (verify-source-file input-file))
1486          (source-info (make-file-source-info input-pathname))
1487          (*compiler-trace-output* nil)) ; might be modified below
1488
1489     (unwind-protect
1490         (progn
1491           (when output-file
1492             (setq output-file-name
1493                   (sb!xc:compile-file-pathname input-file
1494                                                :output-file output-file))
1495             (setq fasl-output
1496                   (open-fasl-output output-file-name
1497                                     (namestring input-pathname))))
1498           (when trace-file
1499             (let* ((default-trace-file-pathname
1500                      (make-pathname :type "trace" :defaults input-pathname))
1501                    (trace-file-pathname
1502                     (if (eql trace-file t)
1503                         default-trace-file-pathname
1504                         (merge-pathnames trace-file
1505                                          default-trace-file-pathname))))
1506               (setf *compiler-trace-output*
1507                     (open trace-file-pathname
1508                           :if-exists :supersede
1509                           :direction :output))))
1510
1511           (when sb!xc:*compile-verbose*
1512             (start-error-output source-info))
1513           (let ((*compile-object* fasl-output)
1514                 dummy)
1515             (multiple-value-setq (dummy warnings-p failure-p)
1516               (sub-compile-file source-info)))
1517           (setq compile-won t))
1518
1519       (close-source-info source-info)
1520
1521       (when fasl-output
1522         (close-fasl-output fasl-output (not compile-won))
1523         (setq output-file-name
1524               (pathname (fasl-output-stream fasl-output)))
1525         (when (and compile-won sb!xc:*compile-verbose*)
1526           (compiler-mumble "~2&; ~A written~%" (namestring output-file-name))))
1527
1528       (when sb!xc:*compile-verbose*
1529         (finish-error-output source-info compile-won))
1530
1531       (when *compiler-trace-output*
1532         (close *compiler-trace-output*)))
1533
1534     (values (if output-file
1535                 ;; Hack around filesystem race condition...
1536                 (or (probe-file output-file-name) output-file-name)
1537                 nil)
1538             warnings-p
1539             failure-p)))
1540 \f
1541 ;;; a helper function for COMPILE-FILE-PATHNAME: the default for
1542 ;;; the OUTPUT-FILE argument
1543 ;;;
1544 ;;; ANSI: The defaults for the OUTPUT-FILE are taken from the pathname
1545 ;;; that results from merging the INPUT-FILE with the value of
1546 ;;; *DEFAULT-PATHNAME-DEFAULTS*, except that the type component should
1547 ;;; default to the appropriate implementation-defined default type for
1548 ;;; compiled files.
1549 (defun cfp-output-file-default (input-file)
1550   (let* ((defaults (merge-pathnames input-file *default-pathname-defaults*))
1551          (retyped (make-pathname :type *fasl-file-type* :defaults defaults)))
1552     retyped))
1553
1554 ;;; KLUDGE: Part of the ANSI spec for this seems contradictory:
1555 ;;;   If INPUT-FILE is a logical pathname and OUTPUT-FILE is unsupplied,
1556 ;;;   the result is a logical pathname. If INPUT-FILE is a logical
1557 ;;;   pathname, it is translated into a physical pathname as if by
1558 ;;;   calling TRANSLATE-LOGICAL-PATHNAME.
1559 ;;; So I haven't really tried to make this precisely ANSI-compatible
1560 ;;; at the level of e.g. whether it returns logical pathname or a
1561 ;;; physical pathname. Patches to make it more correct are welcome.
1562 ;;; -- WHN 2000-12-09
1563 (defun sb!xc:compile-file-pathname (input-file
1564                                     &key
1565                                     (output-file (cfp-output-file-default
1566                                                   input-file))
1567                                     &allow-other-keys)
1568   #!+sb-doc
1569   "Return a pathname describing what file COMPILE-FILE would write to given
1570    these arguments."
1571   (merge-pathnames output-file (merge-pathnames input-file)))
1572 \f
1573 ;;;; MAKE-LOAD-FORM stuff
1574
1575 ;;; The entry point for MAKE-LOAD-FORM support. When IR1 conversion
1576 ;;; finds a constant structure, it invokes this to arrange for proper
1577 ;;; dumping. If it turns out that the constant has already been
1578 ;;; dumped, then we don't need to do anything.
1579 ;;;
1580 ;;; If the constant hasn't been dumped, then we check to see whether
1581 ;;; we are in the process of creating it. We detect this by
1582 ;;; maintaining the special *CONSTANTS-BEING-CREATED* as a list of all
1583 ;;; the constants we are in the process of creating. Actually, each
1584 ;;; entry is a list of the constant and any init forms that need to be
1585 ;;; processed on behalf of that constant.
1586 ;;;
1587 ;;; It's not necessarily an error for this to happen. If we are
1588 ;;; processing the init form for some object that showed up *after*
1589 ;;; the original reference to this constant, then we just need to
1590 ;;; defer the processing of that init form. To detect this, we
1591 ;;; maintain *CONSTANTS-CREATED-SINCE-LAST-INIT* as a list of the
1592 ;;; constants created since the last time we started processing an
1593 ;;; init form. If the constant passed to emit-make-load-form shows up
1594 ;;; in this list, then there is a circular chain through creation
1595 ;;; forms, which is an error.
1596 ;;;
1597 ;;; If there is some intervening init form, then we blow out of
1598 ;;; processing it by throwing to the tag PENDING-INIT. The value we
1599 ;;; throw is the entry from *CONSTANTS-BEING-CREATED*. This is so the
1600 ;;; offending init form can be tacked onto the init forms for the
1601 ;;; circular object.
1602 ;;;
1603 ;;; If the constant doesn't show up in *CONSTANTS-BEING-CREATED*, then
1604 ;;; we have to create it. We call MAKE-LOAD-FORM and check to see
1605 ;;; whether the creation form is the magic value
1606 ;;; :SB-JUST-DUMP-IT-NORMALLY. If it is, then we don't do anything. The
1607 ;;; dumper will eventually get its hands on the object and use the
1608 ;;; normal structure dumping noise on it.
1609 ;;;
1610 ;;; Otherwise, we bind *CONSTANTS-BEING-CREATED* and
1611 ;;; *CONSTANTS-CREATED-SINCE- LAST-INIT* and compile the creation form
1612 ;;; much the way LOAD-TIME-VALUE does. When this finishes, we tell the
1613 ;;; dumper to use that result instead whenever it sees this constant.
1614 ;;;
1615 ;;; Now we try to compile the init form. We bind
1616 ;;; *CONSTANTS-CREATED-SINCE-LAST-INIT* to NIL and compile the init
1617 ;;; form (and any init forms that were added because of circularity
1618 ;;; detection). If this works, great. If not, we add the init forms to
1619 ;;; the init forms for the object that caused the problems and let it
1620 ;;; deal with it.
1621 (defvar *constants-being-created* nil)
1622 (defvar *constants-created-since-last-init* nil)
1623 ;;; FIXME: Shouldn't these^ variables be unbound outside LET forms?
1624 (defun emit-make-load-form (constant)
1625   (aver (fasl-output-p *compile-object*))
1626   (unless (or (fasl-constant-already-dumped-p constant *compile-object*)
1627               ;; KLUDGE: This special hack is because I was too lazy
1628               ;; to rework DEF!STRUCT so that the MAKE-LOAD-FORM
1629               ;; function of LAYOUT returns nontrivial forms when
1630               ;; building the cross-compiler but :IGNORE-IT when
1631               ;; cross-compiling or running under the target Lisp. --
1632               ;; WHN 19990914
1633               #+sb-xc-host (typep constant 'layout))
1634     (let ((circular-ref (assoc constant *constants-being-created* :test #'eq)))
1635       (when circular-ref
1636         (when (find constant *constants-created-since-last-init* :test #'eq)
1637           (throw constant t))
1638         (throw 'pending-init circular-ref)))
1639     (multiple-value-bind (creation-form init-form)
1640         (handler-case
1641             (sb!xc:make-load-form constant (make-null-lexenv))
1642           (error (condition)
1643                  (compiler-error "(while making load form for ~S)~%~A"
1644                                  constant
1645                                  condition)))
1646       (case creation-form
1647         (:sb-just-dump-it-normally
1648          (fasl-validate-structure constant *compile-object*)
1649          t)
1650         (:ignore-it
1651          nil)
1652         (t
1653          (when (fasl-constant-already-dumped-p constant *compile-object*)
1654            (return-from emit-make-load-form nil))
1655          (let* ((name (let ((*print-level* 1) (*print-length* 2))
1656                         (with-output-to-string (stream)
1657                           (write constant :stream stream))))
1658                 (info (if init-form
1659                           (list constant name init-form)
1660                           (list constant))))
1661            (let ((*constants-being-created*
1662                   (cons info *constants-being-created*))
1663                  (*constants-created-since-last-init*
1664                   (cons constant *constants-created-since-last-init*)))
1665              (when
1666                  (catch constant
1667                    (fasl-note-handle-for-constant
1668                     constant
1669                     (compile-load-time-value
1670                      creation-form)
1671                     *compile-object*)
1672                    nil)
1673                (compiler-error "circular references in creation form for ~S"
1674                                constant)))
1675            (when (cdr info)
1676              (let* ((*constants-created-since-last-init* nil)
1677                     (circular-ref
1678                      (catch 'pending-init
1679                        (loop for (name form) on (cdr info) by #'cddr
1680                          collect name into names
1681                          collect form into forms
1682                          finally (compile-make-load-form-init-forms forms))
1683                        nil)))
1684                (when circular-ref
1685                  (setf (cdr circular-ref)
1686                        (append (cdr circular-ref) (cdr info))))))))))))
1687
1688 \f
1689 ;;;; Host compile time definitions
1690 #+sb-xc-host
1691 (defun compile-in-lexenv (name lambda lexenv)
1692   (declare (ignore lexenv))
1693   (compile name lambda))
1694
1695 #+sb-xc-host
1696 (defun eval-in-lexenv (form lexenv)
1697   (declare (ignore lexenv))
1698   (eval form))