src/compiler/main.lisp

   1 ;;;; the top level interfaces to the compiler, plus some other
   2 ;;;; compiler-related stuff (e.g. CL:CALL-ARGUMENTS-LIMIT) which
   3 ;;;; doesn't obviously belong anywhere else
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15
  16 ;;; FIXME: Doesn't this belong somewhere else, like early-c.lisp?
  17 (declaim (special *constants* *free-vars* *component-being-compiled*
  18                   *code-vector* *next-location* *result-fixups*
  19                   *free-funs* *source-paths*
  20                   *seen-blocks* *seen-funs* *list-conflicts-table*
  21                   *continuation-number* *continuation-numbers*
  22                   *number-continuations* *tn-id* *tn-ids* *id-tns*
  23                   *label-ids* *label-id* *id-labels*
  24                   *undefined-warnings* *compiler-error-count*
  25                   *compiler-warning-count* *compiler-style-warning-count*
  26                   *compiler-note-count*
  27                   *compiler-error-bailout*
  28                   #!+sb-show *compiler-trace-output*
  29                   *last-source-context* *last-original-source*
  30                   *last-source-form* *last-format-string* *last-format-args*
  31                   *last-message-count* *lexenv* *fun-names-in-this-file*))
  32
  33 ;;; Whether call of a function which cannot be defined causes a full
  34 ;;; warning.
  35 (defvar *flame-on-necessarily-undefined-function* nil)
  36
  37 (defvar *check-consistency* nil)
  38 (defvar *all-components*)
  39
  40 ;;; Bind this to a stream to capture various internal debugging output.
  41 (defvar *compiler-trace-output* nil)
  42
  43 ;;; The current block compilation state. These are initialized to the
  44 ;;; :BLOCK-COMPILE and :ENTRY-POINTS arguments that COMPILE-FILE was
  45 ;;; called with.
  46 ;;;
  47 ;;; *BLOCK-COMPILE-ARG* holds the original value of the :BLOCK-COMPILE
  48 ;;; argument, which overrides any internal declarations.
  49 (defvar *block-compile*)
  50 (defvar *block-compile-arg*)
  51 (declaim (type (member nil t :specified) *block-compile* *block-compile-arg*))
  52 (defvar *entry-points*)
  53 (declaim (list *entry-points*))
  54
  55 ;;; When block compiling, used by PROCESS-FORM to accumulate top level
  56 ;;; lambdas resulting from compiling subforms. (In reverse order.)
  57 (defvar *toplevel-lambdas*)
  58 (declaim (list *toplevel-lambdas*))
  59
  60 (defvar sb!xc:*compile-verbose* t
  61   #!+sb-doc
  62   "The default for the :VERBOSE argument to COMPILE-FILE.")
  63 (defvar sb!xc:*compile-print* t
  64   #!+sb-doc
  65   "The default for the :PRINT argument to COMPILE-FILE.")
  66 (defvar *compile-progress* nil
  67   #!+sb-doc
  68   "When this is true, the compiler prints to *ERROR-OUTPUT* progress
  69   information about the phases of compilation of each function. (This
  70   is useful mainly in large block compilations.)")
  71
  72 (defvar sb!xc:*compile-file-pathname* nil
  73   #!+sb-doc
  74   "The defaulted pathname of the file currently being compiled, or NIL if not
  75   compiling.")
  76 (defvar sb!xc:*compile-file-truename* nil
  77   #!+sb-doc
  78   "The TRUENAME of the file currently being compiled, or NIL if not
  79   compiling.")
  80
  81 (declaim (type (or pathname null)
  82                sb!xc:*compile-file-pathname*
  83                sb!xc:*compile-file-truename*))
  84
  85 ;;; the SOURCE-INFO structure for the current compilation. This is
  86 ;;; null globally to indicate that we aren't currently in any
  87 ;;; identifiable compilation.
  88 (defvar *source-info* nil)
  89
  90 ;;; This is true if we are within a WITH-COMPILATION-UNIT form (which
  91 ;;; normally causes nested uses to be no-ops).
  92 (defvar *in-compilation-unit* nil)
  93
  94 ;;; This lock is siezed in the same situation: the compiler is not
  95 ;;; presently thread-safe
  96 (defvar *big-compiler-lock*
  97   (sb!thread:make-mutex :name "big compiler lock"))
  98
  99 ;;; Count of the number of compilation units dynamically enclosed by
 100 ;;; the current active WITH-COMPILATION-UNIT that were unwound out of.
 101 (defvar *aborted-compilation-unit-count*)
 102
 103 ;;; Mumble conditional on *COMPILE-PROGRESS*.
 104 (defun maybe-mumble (&rest foo)
 105   (when *compile-progress*
 106     (compiler-mumble "~&")
 107     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 108        (apply #'compiler-mumble foo))))
 109
 110 (deftype object () '(or fasl-output core-object null))
 111
 112 (defvar *compile-object* nil)
 113 (declaim (type object *compile-object*))
 114 \f
 115 ;;;; WITH-COMPILATION-UNIT and WITH-COMPILATION-VALUES
 116
 117 (defmacro sb!xc:with-compilation-unit (options &body body)
 118   #!+sb-doc
 119   "WITH-COMPILATION-UNIT ({Key Value}*) Form*
 120   This form affects compilations that take place within its dynamic extent. It
 121   is intended to be wrapped around the compilation of all files in the same
 122   system. These keywords are defined:
 123     :OVERRIDE Boolean-Form
 124         One of the effects of this form is to delay undefined warnings
 125         until the end of the form, instead of giving them at the end of each
 126         compilation. If OVERRIDE is NIL (the default), then the outermost
 127         WITH-COMPILATION-UNIT form grabs the undefined warnings. Specifying
 128         OVERRIDE true causes that form to grab any enclosed warnings, even if
 129         it is enclosed by another WITH-COMPILATION-UNIT."
 130   `(%with-compilation-unit (lambda () ,@body) ,@options))
 131
 132 (defun %with-compilation-unit (fn &key override)
 133   (declare (type function fn))
 134   (let ((succeeded-p nil))
 135     (if (and *in-compilation-unit* (not override))
 136         ;; Inside another WITH-COMPILATION-UNIT, a WITH-COMPILATION-UNIT is
 137         ;; ordinarily (unless OVERRIDE) basically a no-op.
 138         (unwind-protect
 139              (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 140           (unless succeeded-p
 141             (incf *aborted-compilation-unit-count*)))
 142         (let ((*aborted-compilation-unit-count* 0)
 143               (*compiler-error-count* 0)
 144               (*compiler-warning-count* 0)
 145               (*compiler-style-warning-count* 0)
 146               (*compiler-note-count* 0)
 147               (*undefined-warnings* nil)
 148               (*in-compilation-unit* t))
 149           (sb!thread:with-recursive-lock (*big-compiler-lock*)
 150             (handler-bind ((parse-unknown-type
 151                             (lambda (c)
 152                               (note-undefined-reference
 153                                (parse-unknown-type-specifier c)
 154                                :type))))
 155               (unwind-protect
 156                    (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 157                 (unless succeeded-p
 158                   (incf *aborted-compilation-unit-count*))
 159                 (summarize-compilation-unit (not succeeded-p)))))))))
 160
 161 ;;; Is FUN-NAME something that no conforming program can rely on
 162 ;;; defining as a function?
 163 (defun fun-name-reserved-by-ansi-p (fun-name)
 164   (eq (symbol-package (fun-name-block-name fun-name))
 165       *cl-package*))
 166
 167 ;;; This is to be called at the end of a compilation unit. It signals
 168 ;;; any residual warnings about unknown stuff, then prints the total
 169 ;;; error counts. ABORT-P should be true when the compilation unit was
 170 ;;; aborted by throwing out. ABORT-COUNT is the number of dynamically
 171 ;;; enclosed nested compilation units that were aborted.
 172 (defun summarize-compilation-unit (abort-p)
 173   (unless abort-p
 174     (handler-bind ((style-warning #'compiler-style-warning-handler)
 175                    (warning #'compiler-warning-handler))
 176
 177       (let ((undefs (sort *undefined-warnings* #'string<
 178                           :key (lambda (x)
 179                                  (let ((x (undefined-warning-name x)))
 180                                    (if (symbolp x)
 181                                        (symbol-name x)
 182                                        (prin1-to-string x)))))))
 183         (dolist (undef undefs)
 184           (let ((name (undefined-warning-name undef))
 185                 (kind (undefined-warning-kind undef))
 186                 (warnings (undefined-warning-warnings undef))
 187                 (undefined-warning-count (undefined-warning-count undef)))
 188             (dolist (*compiler-error-context* warnings)
 189               (if #-sb-xc-host (and (eq kind :function)
 190                                     (fun-name-reserved-by-ansi-p name)
 191                                     *flame-on-necessarily-undefined-function*)
 192                   #+sb-xc-host nil
 193                   (case name
 194                     ((declare)
 195                      (compiler-warn
 196                       "~@<There is no function named ~S. References to ~S in ~
 197                        some contexts (like starts of blocks) have special ~
 198                        meaning, but here it would have to be a function, ~
 199                        and that shouldn't be right.~:@>"
 200                       name name))
 201                     (t
 202                      (compiler-warn
 203                       "~@<The ~(~A~) ~S is undefined, and its name is ~
 204                        reserved by ANSI CL so that even if it it were ~
 205                        defined later, the code doing so would not be ~
 206                        portable.~:@>"
 207                       kind name)))
 208                   (compiler-style-warn "undefined ~(~A~): ~S" kind name)))
 209             (let ((warn-count (length warnings)))
 210               (when (and warnings (> undefined-warning-count warn-count))
 211                 (let ((more (- undefined-warning-count warn-count)))
 212                   (compiler-style-warn
 213                    "~W more use~:P of undefined ~(~A~) ~S"
 214                    more kind name))))))
 215
 216         (dolist (kind '(:variable :function :type))
 217           (let ((summary (mapcar #'undefined-warning-name
 218                                  (remove kind undefs :test-not #'eq
 219                                          :key #'undefined-warning-kind))))
 220             (when summary
 221               (compiler-style-warn
 222                "~:[This ~(~A~) is~;These ~(~A~)s are~] undefined:~
 223                 ~%  ~{~<~%  ~1:;~S~>~^ ~}"
 224                (cdr summary) kind summary)))))))
 225
 226   (unless (and (not abort-p)
 227                (zerop *aborted-compilation-unit-count*)
 228                (zerop *compiler-error-count*)
 229                (zerop *compiler-warning-count*)
 230                (zerop *compiler-style-warning-count*)
 231                (zerop *compiler-note-count*))
 232     (format *error-output* "~&")
 233     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 234       (compiler-mumble "compilation unit ~:[finished~;aborted~]~
 235                        ~[~:;~:*~&  caught ~W fatal ERROR condition~:P~]~
 236                        ~[~:;~:*~&  caught ~W ERROR condition~:P~]~
 237                        ~[~:;~:*~&  caught ~W WARNING condition~:P~]~
 238                        ~[~:;~:*~&  caught ~W STYLE-WARNING condition~:P~]~
 239                        ~[~:;~:*~&  printed ~W note~:P~]"
 240                        abort-p
 241                        *aborted-compilation-unit-count*
 242                        *compiler-error-count*
 243                        *compiler-warning-count*
 244                        *compiler-style-warning-count*
 245                        *compiler-note-count*)))
 246   (format *error-output* "~&"))
 247
 248 ;;; Evaluate BODY, then return (VALUES BODY-VALUE WARNINGS-P
 249 ;;; FAILURE-P), where BODY-VALUE is the first value of the body, and
 250 ;;; WARNINGS-P and FAILURE-P are as in CL:COMPILE or CL:COMPILE-FILE.
 251 ;;; This also wraps up WITH-IR1-NAMESPACE functionality.
 252 (defmacro with-compilation-values (&body body)
 253   `(with-ir1-namespace
 254     (let ((*warnings-p* nil)
 255           (*failure-p* nil))
 256       (values (progn ,@body)
 257               *warnings-p*
 258               *failure-p*))))
 259 \f
 260 ;;;; component compilation
 261
 262 (defparameter *max-optimize-iterations* 3 ; ARB
 263   #!+sb-doc
 264   "The upper limit on the number of times that we will consecutively do IR1
 265   optimization that doesn't introduce any new code. A finite limit is
 266   necessary, since type inference may take arbitrarily long to converge.")
 267
 268 (defevent ir1-optimize-until-done "IR1-OPTIMIZE-UNTIL-DONE called")
 269 (defevent ir1-optimize-maxed-out "hit *MAX-OPTIMIZE-ITERATIONS* limit")
 270
 271 ;;; Repeatedly optimize COMPONENT until no further optimizations can
 272 ;;; be found or we hit our iteration limit. When we hit the limit, we
 273 ;;; clear the component and block REOPTIMIZE flags to discourage the
 274 ;;; next optimization attempt from pounding on the same code.
 275 (defun ir1-optimize-until-done (component)
 276   (declare (type component component))
 277   (maybe-mumble "opt")
 278   (event ir1-optimize-until-done)
 279   (let ((count 0)
 280         (cleared-reanalyze nil))
 281     (loop
 282       (when (component-reanalyze component)
 283         (setq count 0)
 284         (setq cleared-reanalyze t)
 285         (setf (component-reanalyze component) nil))
 286       (setf (component-reoptimize component) nil)
 287       (ir1-optimize component)
 288       (cond ((component-reoptimize component)
 289              (incf count)
 290              (when (= count *max-optimize-iterations*)
 291                (maybe-mumble "*")
 292                (cond ((retry-delayed-ir1-transforms :optimize)
 293                       (maybe-mumble "+")
 294                       (setq count 0))
 295                      (t
 296                       (event ir1-optimize-maxed-out)
 297                       (setf (component-reoptimize component) nil)
 298                       (do-blocks (block component)
 299                         (setf (block-reoptimize block) nil))
 300                       (return)))))
 301             ((retry-delayed-ir1-transforms :optimize)
 302              (setf count 0)
 303              (maybe-mumble "+"))
 304             (t
 305              (maybe-mumble " ")
 306              (return)))
 307       (maybe-mumble "."))
 308     (when cleared-reanalyze
 309       (setf (component-reanalyze component) t)))
 310   (values))
 311
 312 (defparameter *constraint-propagate* t)
 313
 314 ;;; KLUDGE: This was bumped from 5 to 10 in a DTC patch ported by MNA
 315 ;;; from CMU CL into sbcl-0.6.11.44, the same one which allowed IR1
 316 ;;; transforms to be delayed. Either DTC or MNA or both didn't explain
 317 ;;; why, and I don't know what the rationale was. -- WHN 2001-04-28
 318 ;;;
 319 ;;; FIXME: It would be good to document why it's important to have a
 320 ;;; large value here, and what the drawbacks of an excessively large
 321 ;;; value are; and it might also be good to make it depend on
 322 ;;; optimization policy.
 323 (defparameter *reoptimize-after-type-check-max* 10)
 324
 325 (defevent reoptimize-maxed-out
 326   "*REOPTIMIZE-AFTER-TYPE-CHECK-MAX* exceeded.")
 327
 328 ;;; Iterate doing FIND-DFO until no new dead code is discovered.
 329 (defun dfo-as-needed (component)
 330   (declare (type component component))
 331   (when (component-reanalyze component)
 332     (maybe-mumble "DFO")
 333     (loop
 334       (find-dfo component)
 335       (unless (component-reanalyze component)
 336         (maybe-mumble " ")
 337         (return))
 338       (maybe-mumble ".")))
 339   (values))
 340
 341 ;;; Do all the IR1 phases for a non-top-level component.
 342 (defun ir1-phases (component)
 343   (declare (type component component))
 344   (aver-live-component component)
 345   (let ((*constraint-number* 0)
 346         (loop-count 1)
 347         (*delayed-ir1-transforms* nil))
 348     (declare (special *constraint-number* *delayed-ir1-transforms*))
 349     (loop
 350       (ir1-optimize-until-done component)
 351       (when (or (component-new-functionals component)
 352                 (component-reanalyze-functionals component))
 353         (maybe-mumble "locall ")
 354         (locall-analyze-component component))
 355       (dfo-as-needed component)
 356       (when *constraint-propagate*
 357         (maybe-mumble "constraint ")
 358         (constraint-propagate component))
 359       (when (retry-delayed-ir1-transforms :constraint)
 360         (maybe-mumble "Rtran "))
 361       (flet ((want-reoptimization-p ()
 362                (or (component-reoptimize component)
 363                    (component-reanalyze component)
 364                    (component-new-functionals component)
 365                    (component-reanalyze-functionals component))))
 366         (unless (and (want-reoptimization-p)
 367                      ;; We delay the generation of type checks until
 368                      ;; the type constraints have had time to
 369                      ;; propagate, else the compiler can confuse itself.
 370                      (< loop-count (- *reoptimize-after-type-check-max* 4)))
 371           (maybe-mumble "type ")
 372           (generate-type-checks component)
 373           (unless (want-reoptimization-p)
 374             (return))))
 375       (when (>= loop-count *reoptimize-after-type-check-max*)
 376         (maybe-mumble "[reoptimize limit]")
 377         (event reoptimize-maxed-out)
 378         (return))
 379       (incf loop-count)))
 380
 381   (ir1-finalize component)
 382   (values))
 383
 384 (defun %compile-component (component)
 385   (let ((*code-segment* nil)
 386         (*elsewhere* nil))
 387     (maybe-mumble "GTN ")
 388     (gtn-analyze component)
 389     (maybe-mumble "LTN ")
 390     (ltn-analyze component)
 391     (dfo-as-needed component)
 392     (maybe-mumble "control ")
 393     (control-analyze component #'make-ir2-block)
 394
 395     (when (ir2-component-values-receivers (component-info component))
 396       (maybe-mumble "stack ")
 397       (stack-analyze component)
 398       ;; Assign BLOCK-NUMBER for any cleanup blocks introduced by
 399       ;; stack analysis. There shouldn't be any unreachable code after
 400       ;; control, so this won't delete anything.
 401       (dfo-as-needed component))
 402
 403     (unwind-protect
 404         (progn
 405           (maybe-mumble "IR2tran ")
 406           (init-assembler)
 407           (entry-analyze component)
 408           (ir2-convert component)
 409
 410           (when (policy *lexenv* (>= speed compilation-speed))
 411             (maybe-mumble "copy ")
 412             (copy-propagate component))
 413
 414           (select-representations component)
 415
 416           (when *check-consistency*
 417             (maybe-mumble "check2 ")
 418             (check-ir2-consistency component))
 419
 420           (delete-unreferenced-tns component)
 421
 422           (maybe-mumble "life ")
 423           (lifetime-analyze component)
 424
 425           (when *compile-progress*
 426             (compiler-mumble "") ; Sync before doing more output.
 427             (pre-pack-tn-stats component *error-output*))
 428
 429           (when *check-consistency*
 430             (maybe-mumble "check-life ")
 431             (check-life-consistency component))
 432
 433           (maybe-mumble "pack ")
 434           (pack component)
 435
 436           (when *check-consistency*
 437             (maybe-mumble "check-pack ")
 438             (check-pack-consistency component))
 439
 440           (when *compiler-trace-output*
 441             (describe-component component *compiler-trace-output*)
 442             (describe-ir2-component component *compiler-trace-output*))
 443
 444           (maybe-mumble "code ")
 445           (multiple-value-bind (code-length trace-table fixups)
 446               (generate-code component)
 447
 448             #-sb-xc-host
 449             (when *compiler-trace-output*
 450               (format *compiler-trace-output*
 451                       "~|~%disassembly of code for ~S~2%" component)
 452               (sb!disassem:disassemble-assem-segment *code-segment*
 453                                                      *compiler-trace-output*))
 454
 455             (etypecase *compile-object*
 456               (fasl-output
 457                (maybe-mumble "fasl")
 458                (fasl-dump-component component
 459                                     *code-segment*
 460                                     code-length
 461                                     trace-table
 462                                     fixups
 463                                     *compile-object*))
 464               (core-object
 465                (maybe-mumble "core")
 466                (make-core-component component
 467                                     *code-segment*
 468                                     code-length
 469                                     trace-table
 470                                     fixups
 471                                     *compile-object*))
 472               (null))))))
 473
 474   ;; We're done, so don't bother keeping anything around.
 475   (setf (component-info component) :dead)
 476
 477   (values))
 478
 479 ;;; Delete components with no external entry points before we try to
 480 ;;; generate code. Unreachable closures can cause IR2 conversion to
 481 ;;; puke on itself, since it is the reference to the closure which
 482 ;;; normally causes the components to be combined.
 483 (defun delete-if-no-entries (component)
 484   (dolist (fun (component-lambdas component) (delete-component component))
 485     (when (functional-has-external-references-p fun)
 486       (return))
 487     (case (functional-kind fun)
 488       (:toplevel (return))
 489       (:external
 490        (unless (every (lambda (ref)
 491                         (eq (node-component ref) component))
 492                       (leaf-refs fun))
 493          (return))))))
 494
 495 (defun compile-component (component)
 496
 497   ;; miscellaneous sanity checks
 498   ;;
 499   ;; FIXME: These are basically pretty wimpy compared to the checks done
 500   ;; by the old CHECK-IR1-CONSISTENCY code. It would be really nice to
 501   ;; make those internal consistency checks work again and use them.
 502   (aver-live-component component)
 503   (do-blocks (block component)
 504     (aver (eql (block-component block) component)))
 505   (dolist (lambda (component-lambdas component))
 506     ;; sanity check to prevent weirdness from propagating insidiously as
 507     ;; far from its root cause as it did in bug 138: Make sure that
 508     ;; thing-to-COMPONENT links are consistent.
 509     (aver (eql (lambda-component lambda) component))
 510     (aver (eql (node-component (lambda-bind lambda)) component)))
 511
 512   (let* ((*component-being-compiled* component))
 513     (when sb!xc:*compile-print*
 514       (compiler-mumble "~&; compiling ~A: " (component-name component)))
 515
 516     (ir1-phases component)
 517
 518     ;; FIXME: What is MAYBE-MUMBLE for? Do we need it any more?
 519     (maybe-mumble "env ")
 520     (physenv-analyze component)
 521     (dfo-as-needed component)
 522
 523     (delete-if-no-entries component)
 524
 525     (unless (eq (block-next (component-head component))
 526                 (component-tail component))
 527       (%compile-component component)))
 528
 529   (clear-constant-info)
 530
 531   (when sb!xc:*compile-print*
 532     (compiler-mumble "~&"))
 533
 534   (values))
 535 \f
 536 ;;;; clearing global data structures
 537 ;;;;
 538 ;;;; FIXME: Is it possible to get rid of this stuff, getting rid of
 539 ;;;; global data structures entirely when possible and consing up the
 540 ;;;; others from scratch instead of clearing and reusing them?
 541
 542 ;;; Clear the INFO in constants in the *FREE-VARS*, etc. In
 543 ;;; addition to allowing stuff to be reclaimed, this is required for
 544 ;;; correct assignment of constant offsets, since we need to assign a
 545 ;;; new offset for each component. We don't clear the FUNCTIONAL-INFO
 546 ;;; slots, since they are used to keep track of functions across
 547 ;;; component boundaries.
 548 (defun clear-constant-info ()
 549   (maphash (lambda (k v)
 550              (declare (ignore k))
 551              (setf (leaf-info v) nil))
 552            *constants*)
 553   (maphash (lambda (k v)
 554              (declare (ignore k))
 555              (when (constant-p v)
 556                (setf (leaf-info v) nil)))
 557            *free-vars*)
 558   (values))
 559
 560 ;;; Blow away the REFS for all global variables, and let COMPONENT
 561 ;;; be recycled.
 562 (defun clear-ir1-info (component)
 563   (declare (type component component))
 564   (labels ((blast (x)
 565              (maphash (lambda (k v)
 566                         (declare (ignore k))
 567                         (when (leaf-p v)
 568                           (setf (leaf-refs v)
 569                                 (delete-if #'here-p (leaf-refs v)))
 570                           (when (basic-var-p v)
 571                             (setf (basic-var-sets v)
 572                                   (delete-if #'here-p (basic-var-sets v))))))
 573                       x))
 574            (here-p (x)
 575              (eq (node-component x) component)))
 576     (blast *free-vars*)
 577     (blast *free-funs*)
 578     (blast *constants*))
 579   (values))
 580
 581 ;;; Clear global variables used by the compiler.
 582 ;;;
 583 ;;; FIXME: It seems kinda nasty and unmaintainable to have to do this,
 584 ;;; and it adds overhead even when people aren't using the compiler.
 585 ;;; Perhaps we could make these global vars unbound except when
 586 ;;; actually in use, so that this function could go away.
 587 (defun clear-stuff (&optional (debug-too t))
 588
 589   ;; Clear global tables.
 590   (when (boundp '*free-funs*)
 591     (clrhash *free-funs*)
 592     (clrhash *free-vars*)
 593     (clrhash *constants*))
 594
 595   ;; Clear debug counters and tables.
 596   (clrhash *seen-blocks*)
 597   (clrhash *seen-funs*)
 598   (clrhash *list-conflicts-table*)
 599
 600   (when debug-too
 601     (clrhash *continuation-numbers*)
 602     (clrhash *number-continuations*)
 603     (setq *continuation-number* 0)
 604     (clrhash *tn-ids*)
 605     (clrhash *id-tns*)
 606     (setq *tn-id* 0)
 607     (clrhash *label-ids*)
 608     (clrhash *id-labels*)
 609     (setq *label-id* 0)
 610
 611     ;; Clear some PACK data structures (for GC purposes only).
 612     (aver (not *in-pack*))
 613     (dolist (sb *backend-sb-list*)
 614       (when (finite-sb-p sb)
 615         (fill (finite-sb-live-tns sb) nil))))
 616
 617   ;; (Note: The CMU CL code used to set CL::*GENSYM-COUNTER* to zero here.
 618   ;; Superficially, this seemed harmful -- the user could reasonably be
 619   ;; surprised if *GENSYM-COUNTER* turned back to zero when something was
 620   ;; compiled. A closer inspection showed that this actually turned out to be
 621   ;; harmless in practice, because CLEAR-STUFF was only called from within
 622   ;; forms which bound CL::*GENSYM-COUNTER* to zero. However, this means that
 623   ;; even though zeroing CL::*GENSYM-COUNTER* here turned out to be harmless in
 624   ;; practice, it was also useless in practice. So we don't do it any more.)
 625
 626   (values))
 627 \f
 628 ;;;; trace output
 629
 630 ;;; Print out some useful info about COMPONENT to STREAM.
 631 (defun describe-component (component *standard-output*)
 632   (declare (type component component))
 633   (format t "~|~%;;;; component: ~S~2%" (component-name component))
 634   (print-all-blocks component)
 635   (values))
 636
 637 (defun describe-ir2-component (component *standard-output*)
 638   (format t "~%~|~%;;;; IR2 component: ~S~2%" (component-name component))
 639   (format t "entries:~%")
 640   (dolist (entry (ir2-component-entries (component-info component)))
 641     (format t "~4TL~D: ~S~:[~; [closure]~]~%"
 642             (label-id (entry-info-offset entry))
 643             (entry-info-name entry)
 644             (entry-info-closure-p entry)))
 645   (terpri)
 646   (pre-pack-tn-stats component *standard-output*)
 647   (terpri)
 648   (print-ir2-blocks component)
 649   (terpri)
 650   (values))
 651 \f
 652 ;;;; file reading
 653 ;;;;
 654 ;;;; When reading from a file, we have to keep track of some source
 655 ;;;; information. We also exploit our ability to back up for printing
 656 ;;;; the error context and for recovering from errors.
 657 ;;;;
 658 ;;;; The interface we provide to this stuff is the stream-oid
 659 ;;;; SOURCE-INFO structure. The bookkeeping is done as a side effect
 660 ;;;; of getting the next source form.
 661
 662 ;;; A FILE-INFO structure holds all the source information for a
 663 ;;; given file.
 664 (defstruct (file-info (:copier nil))
 665   ;; If a file, the truename of the corresponding source file. If from
 666   ;; a Lisp form, :LISP. If from a stream, :STREAM.
 667   (name (missing-arg) :type (or pathname (member :lisp :stream)))
 668   ;; the defaulted, but not necessarily absolute file name (i.e. prior
 669   ;; to TRUENAME call.) Null if not a file. This is used to set
 670   ;; *COMPILE-FILE-PATHNAME*, and if absolute, is dumped in the
 671   ;; debug-info.
 672   (untruename nil :type (or pathname null))
 673   ;; the file's write date (if relevant)
 674   (write-date nil :type (or unsigned-byte null))
 675   ;; the source path root number of the first form in this file (i.e.
 676   ;; the total number of forms converted previously in this
 677   ;; compilation)
 678   (source-root 0 :type unsigned-byte)
 679   ;; parallel vectors containing the forms read out of the file and
 680   ;; the file positions that reading of each form started at (i.e. the
 681   ;; end of the previous form)
 682   (forms (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t))
 683   (positions (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t)))
 684
 685 ;;; The SOURCE-INFO structure provides a handle on all the source
 686 ;;; information for an entire compilation.
 687 (defstruct (source-info
 688             #-no-ansi-print-object
 689             (:print-object (lambda (s stream)
 690                              (print-unreadable-object (s stream :type t))))
 691             (:copier nil))
 692   ;; the UT that compilation started at
 693   (start-time (get-universal-time) :type unsigned-byte)
 694   ;; the FILE-INFO structure for this compilation
 695   (file-info nil :type (or file-info null))
 696   ;; the stream that we are using to read the FILE-INFO, or NIL if
 697   ;; no stream has been opened yet
 698   (stream nil :type (or stream null)))
 699
 700 ;;; Given a pathname, return a SOURCE-INFO structure.
 701 (defun make-file-source-info (file)
 702   (let ((file-info (make-file-info :name (truename file)
 703                                    :untruename file
 704                                    :write-date (file-write-date file))))
 705
 706     (make-source-info :file-info file-info)))
 707
 708 ;;; Return a SOURCE-INFO to describe the incremental compilation of FORM.
 709 (defun make-lisp-source-info (form)
 710   (make-source-info :start-time (get-universal-time)
 711                     :file-info (make-file-info :name :lisp
 712                                                :forms (vector form)
 713                                                :positions '#(0))))
 714
 715 ;;; Return a SOURCE-INFO which will read from STREAM.
 716 (defun make-stream-source-info (stream)
 717   (let ((file-info (make-file-info :name :stream)))
 718     (make-source-info :file-info file-info
 719                       :stream stream)))
 720
 721 ;;; Return a form read from STREAM; or for EOF use the trick,
 722 ;;; popularized by Kent Pitman, of returning STREAM itself. If an
 723 ;;; error happens, then convert it to standard abort-the-compilation
 724 ;;; error condition (possibly recording some extra location
 725 ;;; information).
 726 (defun read-for-compile-file (stream position)
 727   (handler-case (read stream nil stream)
 728     (reader-error (condition)
 729      (error 'input-error-in-compile-file
 730             :error condition
 731             ;; We don't need to supply :POSITION here because
 732             ;; READER-ERRORs already know their position in the file.
 733             ))
 734     ;; ANSI, in its wisdom, says that READ should return END-OF-FILE
 735     ;; (and that this is not a READER-ERROR) when it encounters end of
 736     ;; file in the middle of something it's trying to read.
 737     (end-of-file (condition)
 738      (error 'input-error-in-compile-file
 739             :error condition
 740             ;; We need to supply :POSITION here because the END-OF-FILE
 741             ;; condition doesn't carry the position that the user
 742             ;; probably cares about, where the failed READ began.
 743             :position position))))
 744
 745 ;;; If STREAM is present, return it, otherwise open a stream to the
 746 ;;; current file. There must be a current file.
 747 ;;;
 748 ;;; FIXME: This is probably an unnecessarily roundabout way to do
 749 ;;; things now that we process a single file in COMPILE-FILE (unlike
 750 ;;; the old CMU CL code, which accepted multiple files). Also, the old
 751 ;;; comment said
 752 ;;;   When we open a new file, we also reset *PACKAGE* and policy.
 753 ;;;   This gives the effect of rebinding around each file.
 754 ;;; which doesn't seem to be true now. Check to make sure that if
 755 ;;; such rebinding is necessary, it's still done somewhere.
 756 (defun get-source-stream (info)
 757   (declare (type source-info info))
 758   (or (source-info-stream info)
 759       (let* ((file-info (source-info-file-info info))
 760              (name (file-info-name file-info)))
 761         (setf sb!xc:*compile-file-truename* name
 762               sb!xc:*compile-file-pathname* (file-info-untruename file-info)
 763               (source-info-stream info) (open name :direction :input)))))
 764
 765 ;;; Close the stream in INFO if it is open.
 766 (defun close-source-info (info)
 767   (declare (type source-info info))
 768   (let ((stream (source-info-stream info)))
 769     (when stream (close stream)))
 770   (setf (source-info-stream info) nil)
 771   (values))
 772
 773 ;;; Read and compile the source file.
 774 (defun sub-sub-compile-file (info)
 775   (let* ((file-info (source-info-file-info info))
 776          (stream (get-source-stream info)))
 777     (loop
 778      (let* ((pos (file-position stream))
 779             (form (read-for-compile-file stream pos)))
 780        (if (eq form stream) ; i.e., if EOF
 781            (return)
 782            (let* ((forms (file-info-forms file-info))
 783                   (current-idx (+ (fill-pointer forms)
 784                                   (file-info-source-root file-info))))
 785              (vector-push-extend form forms)
 786              (vector-push-extend pos (file-info-positions file-info))
 787              (find-source-paths form current-idx)
 788              (process-toplevel-form form
 789                                     `(original-source-start 0 ,current-idx)
 790                                     nil)))))))
 791
 792 ;;; Return the INDEX'th source form read from INFO and the position
 793 ;;; where it was read.
 794 (defun find-source-root (index info)
 795   (declare (type index index) (type source-info info))
 796   (let ((file-info (source-info-file-info info)))
 797     (values (aref (file-info-forms file-info) index)
 798             (aref (file-info-positions file-info) index))))
 799 \f
 800 ;;;; processing of top level forms
 801
 802 ;;; This is called by top level form processing when we are ready to
 803 ;;; actually compile something. If *BLOCK-COMPILE* is T, then we still
 804 ;;; convert the form, but delay compilation, pushing the result on
 805 ;;; *TOPLEVEL-LAMBDAS* instead.
 806 (defun convert-and-maybe-compile (form path)
 807   (declare (list path))
 808   (let* ((*lexenv* (make-lexenv :policy *policy*))
 809          (tll (ir1-toplevel form path nil)))
 810     (cond ((eq *block-compile* t) (push tll *toplevel-lambdas*))
 811           (t (compile-toplevel (list tll) nil)))))
 812
 813 ;;; Macroexpand FORM in the current environment with an error handler.
 814 ;;; We only expand one level, so that we retain all the intervening
 815 ;;; forms in the source path.
 816 (defun preprocessor-macroexpand-1 (form)
 817   (handler-case (sb!xc:macroexpand-1 form *lexenv*)
 818     (error (condition)
 819       (compiler-error "(during macroexpansion of ~A)~%~A"
 820                       (let ((*print-level* 1)
 821                             (*print-length* 2))
 822                         (format nil "~S" form))
 823                       condition))))
 824
 825 ;;; Process a PROGN-like portion of a top level form. FORMS is a list of
 826 ;;; the forms, and PATH is the source path of the FORM they came out of.
 827 ;;; COMPILE-TIME-TOO is as in ANSI "3.2.3.1 Processing of Top Level Forms".
 828 (defun process-toplevel-progn (forms path compile-time-too)
 829   (declare (list forms) (list path))
 830   (dolist (form forms)
 831     (process-toplevel-form form path compile-time-too)))
 832
 833 ;;; Process a top level use of LOCALLY, or anything else (e.g.
 834 ;;; MACROLET) at top level which has declarations and ordinary forms.
 835 ;;; We parse declarations and then recursively process the body.
 836 (defun process-toplevel-locally (body path compile-time-too &key vars funs)
 837   (declare (list path))
 838   (multiple-value-bind (forms decls) (parse-body body nil)
 839     (let* ((*lexenv* (process-decls decls vars funs))
 840            ;; FIXME: VALUES declaration
 841            ;;
 842            ;; Binding *POLICY* is pretty much of a hack, since it
 843            ;; causes LOCALLY to "capture" enclosed proclamations. It
 844            ;; is necessary because CONVERT-AND-MAYBE-COMPILE uses the
 845            ;; value of *POLICY* as the policy. The need for this hack
 846            ;; is due to the quirk that there is no way to represent in
 847            ;; a POLICY that an optimize quality came from the default.
 848            ;;
 849            ;; FIXME: Ideally, something should be done so that DECLAIM
 850            ;; inside LOCALLY works OK. Failing that, at least we could
 851            ;; issue a warning instead of silently screwing up.
 852            (*policy* (lexenv-policy *lexenv*)))
 853       (process-toplevel-progn forms path compile-time-too))))
 854
 855 ;;; Parse an EVAL-WHEN situations list, returning three flags,
 856 ;;; (VALUES COMPILE-TOPLEVEL LOAD-TOPLEVEL EXECUTE), indicating
 857 ;;; the types of situations present in the list.
 858 (defun parse-eval-when-situations (situations)
 859   (when (or (not (listp situations))
 860             (set-difference situations
 861                             '(:compile-toplevel
 862                               compile
 863                               :load-toplevel
 864                               load
 865                               :execute
 866                               eval)))
 867     (compiler-error "bad EVAL-WHEN situation list: ~S" situations))
 868   (let ((deprecated-names (intersection situations '(compile load eval))))
 869     (when deprecated-names
 870       (style-warn "using deprecated EVAL-WHEN situation names~{ ~S~}"
 871                   deprecated-names)))
 872   (values (intersection '(:compile-toplevel compile)
 873                         situations)
 874           (intersection '(:load-toplevel load) situations)
 875           (intersection '(:execute eval) situations)))
 876
 877
 878 ;;; utilities for extracting COMPONENTs of FUNCTIONALs
 879 (defun functional-components (f)
 880   (declare (type functional f))
 881   (etypecase f
 882     (clambda (list (lambda-component f)))
 883     (optional-dispatch (let ((result nil))
 884                          (flet ((maybe-frob (maybe-clambda)
 885                                   (when (and maybe-clambda
 886                                              (promise-ready-p maybe-clambda))
 887                                     (pushnew (lambda-component
 888                                               (force maybe-clambda))
 889                                              result))))
 890                            (map nil #'maybe-frob (optional-dispatch-entry-points f))
 891                            (maybe-frob (optional-dispatch-more-entry f))
 892                            (maybe-frob (optional-dispatch-main-entry f)))
 893                          result))))
 894
 895 (defun make-functional-from-toplevel-lambda (definition
 896                                              &key
 897                                              name
 898                                              (path
 899                                               ;; I'd thought NIL should
 900                                               ;; work, but it doesn't.
 901                                               ;; -- WHN 2001-09-20
 902                                               (missing-arg)))
 903   (let* ((*current-path* path)
 904          (component (make-empty-component))
 905          (*current-component* component))
 906     (setf (component-name component)
 907           (debug-namify "~S initial component" name))
 908     (setf (component-kind component) :initial)
 909     (let* ((locall-fun (ir1-convert-lambdalike
 910                         definition
 911                         :debug-name (debug-namify "top level local call ~S"
 912                                                   name)
 913                         ;; KLUDGE: we do this so that we get to have
 914                         ;; nice debug returnness in functions defined
 915                         ;; from the REPL
 916                         :allow-debug-catch-tag t))
 917            (fun (ir1-convert-lambda (make-xep-lambda-expression locall-fun)
 918                                     :source-name (or name '.anonymous.)
 919                                     :debug-name (unless name
 920                                                   "top level form"))))
 921       (when name
 922         (assert-global-function-definition-type name locall-fun))
 923       (setf (functional-entry-fun fun) locall-fun
 924             (functional-kind fun) :external
 925             (functional-has-external-references-p fun) t)
 926       fun)))
 927
 928 ;;; Compile LAMBDA-EXPRESSION into *COMPILE-OBJECT*, returning a
 929 ;;; description of the result.
 930 ;;;   * If *COMPILE-OBJECT* is a CORE-OBJECT, then write the function
 931 ;;;     into core and return the compiled FUNCTION value.
 932 ;;;   * If *COMPILE-OBJECT* is a fasl file, then write the function
 933 ;;;     into the fasl file and return a dump handle.
 934 ;;;
 935 ;;; If NAME is provided, then we try to use it as the name of the
 936 ;;; function for debugging/diagnostic information.
 937 (defun %compile (lambda-expression
 938                  *compile-object*
 939                  &key
 940                  name
 941                  (path
 942                   ;; This magical idiom seems to be the appropriate
 943                   ;; path for compiling standalone LAMBDAs, judging
 944                   ;; from the CMU CL code and experiment, so it's a
 945                   ;; nice default for things where we don't have a
 946                   ;; real source path (as in e.g. inside CL:COMPILE).
 947                   '(original-source-start 0 0)))
 948   (when name
 949     (legal-fun-name-or-type-error name))
 950   (let* ((*lexenv* (make-lexenv :policy *policy*))
 951          (fun (make-functional-from-toplevel-lambda lambda-expression
 952                                                     :name name
 953                                                     :path path)))
 954
 955     ;; FIXME: The compile-it code from here on is sort of a
 956     ;; twisted version of the code in COMPILE-TOPLEVEL. It'd be
 957     ;; better to find a way to share the code there; or
 958     ;; alternatively, to use this code to replace the code there.
 959     ;; (The second alternative might be pretty easy if we used
 960     ;; the :LOCALL-ONLY option to IR1-FOR-LAMBDA. Then maybe the
 961     ;; whole FUNCTIONAL-KIND=:TOPLEVEL case could go away..)
 962
 963     (locall-analyze-clambdas-until-done (list fun))
 964
 965     (multiple-value-bind (components-from-dfo top-components hairy-top)
 966         (find-initial-dfo (list fun))
 967
 968       (let ((*all-components* (append components-from-dfo top-components)))
 969         ;; FIXME: This is more monkey see monkey do based on CMU CL
 970         ;; code. If anyone figures out why to only prescan HAIRY-TOP
 971         ;; and TOP-COMPONENTS here, instead of *ALL-COMPONENTS* or
 972         ;; some other combination of results from FIND-INITIAL-VALUES,
 973         ;; it'd be good to explain it.
 974         (mapc #'preallocate-physenvs-for-toplevelish-lambdas hairy-top)
 975         (mapc #'preallocate-physenvs-for-toplevelish-lambdas top-components)
 976         (dolist (component-from-dfo components-from-dfo)
 977           (compile-component component-from-dfo)
 978           (replace-toplevel-xeps component-from-dfo)))
 979
 980       (let ((entry-table (etypecase *compile-object*
 981                            (fasl-output (fasl-output-entry-table
 982                                          *compile-object*))
 983                            (core-object (core-object-entry-table
 984                                          *compile-object*)))))
 985         (multiple-value-bind (result found-p)
 986             (gethash (leaf-info fun) entry-table)
 987           (aver found-p)
 988           (prog1
 989               result
 990             ;; KLUDGE: This code duplicates some other code in this
 991             ;; file. In the great reorganzation, the flow of program
 992             ;; logic changed from the original CMUCL model, and that
 993             ;; path (as of sbcl-0.7.5 in SUB-COMPILE-FILE) was no
 994             ;; longer followed for CORE-OBJECTS, leading to BUG
 995             ;; 156. This place is transparently not the right one for
 996             ;; this code, but I don't have a clear enough overview of
 997             ;; the compiler to know how to rearrange it all so that
 998             ;; this operation fits in nicely, and it was blocking
 999             ;; reimplementation of (DECLAIM (INLINE FOO)) (MACROLET
1000             ;; ((..)) (DEFUN FOO ...))
1001             ;;
1002             ;; FIXME: This KLUDGE doesn't solve all the problem in an
1003             ;; ideal way, as (1) definitions typed in at the REPL
1004             ;; without an INLINE declaration will give a NULL
1005             ;; FUNCTION-LAMBDA-EXPRESSION (allowable, but not ideal)
1006             ;; and (2) INLINE declarations will yield a
1007             ;; FUNCTION-LAMBDA-EXPRESSION headed by
1008             ;; SB-C:LAMBDA-WITH-LEXENV, even for null LEXENV.  -- CSR,
1009             ;; 2002-07-02
1010             ;;
1011             ;; (2) is probably fairly easy to fix -- it is, after all,
1012             ;; a matter of list manipulation (or possibly of teaching
1013             ;; CL:FUNCTION about SB-C:LAMBDA-WITH-LEXENV).  (1) is
1014             ;; significantly harder, as the association between
1015             ;; function object and source is a tricky one.
1016             ;;
1017             ;; FUNCTION-LAMBDA-EXPRESSION "works" (i.e. returns a
1018             ;; non-NULL list) when the function in question has been
1019             ;; compiled by (COMPILE <x> '(LAMBDA ...)); it does not
1020             ;; work when it has been compiled as part of the top-level
1021             ;; EVAL strategy of compiling everything inside (LAMBDA ()
1022             ;; ...).  -- CSR, 2002-11-02
1023             (when (core-object-p *compile-object*)
1024               (fix-core-source-info *source-info* *compile-object* result))
1025
1026             (mapc #'clear-ir1-info components-from-dfo)
1027             (clear-stuff)))))))
1028
1029 (defun process-toplevel-cold-fset (name lambda-expression path)
1030   (unless (producing-fasl-file)
1031     (error "can't COLD-FSET except in a fasl file"))
1032   (legal-fun-name-or-type-error name)
1033   (fasl-dump-cold-fset name
1034                        (%compile lambda-expression
1035                                  *compile-object*
1036                                  :name name
1037                                  :path path)
1038                        *compile-object*)
1039   (values))
1040
1041 ;;; Process a top level FORM with the specified source PATH.
1042 ;;;  * If this is a magic top level form, then do stuff.
1043 ;;;  * If this is a macro, then expand it.
1044 ;;;  * Otherwise, just compile it.
1045 ;;;
1046 ;;; COMPILE-TIME-TOO is as defined in ANSI
1047 ;;; "3.2.3.1 Processing of Top Level Forms".
1048 (defun process-toplevel-form (form path compile-time-too)
1049
1050   (declare (list path))
1051
1052   (catch 'process-toplevel-form-error-abort
1053     (let* ((path (or (gethash form *source-paths*) (cons form path)))
1054            (*compiler-error-bailout*
1055             (lambda ()
1056               (convert-and-maybe-compile
1057                `(error 'simple-program-error
1058                  :format-control "execution of a form compiled with errors:~% ~S"
1059                  :format-arguments (list ',form))
1060                path)
1061               (throw 'process-toplevel-form-error-abort nil))))
1062
1063       (flet ((default-processor (form)
1064                ;; When we're cross-compiling, consider: what should we
1065                ;; do when we hit e.g.
1066                ;;   (EVAL-WHEN (:COMPILE-TOPLEVEL)
1067                ;;     (DEFUN FOO (X) (+ 7 X)))?
1068                ;; DEFUN has a macro definition in the cross-compiler,
1069                ;; and a different macro definition in the target
1070                ;; compiler. The only sensible thing is to use the
1071                ;; target compiler's macro definition, since the
1072                ;; cross-compiler's macro is in general into target
1073                ;; functions which can't meaningfully be executed at
1074                ;; cross-compilation time. So make sure we do the EVAL
1075                ;; here, before we macroexpand.
1076                ;;
1077                ;; Then things get even dicier with something like
1078                ;;   (DEFCONSTANT-EQX SB!XC:LAMBDA-LIST-KEYWORDS ..)
1079                ;; where we have to make sure that we don't uncross
1080                ;; the SB!XC: prefix before we do EVAL, because otherwise
1081                ;; we'd be trying to redefine the cross-compilation host's
1082                ;; constants.
1083                ;;
1084                ;; (Isn't it fun to cross-compile Common Lisp?:-)
1085                #+sb-xc-host
1086                (progn
1087                  (when compile-time-too
1088                    (eval form)) ; letting xc host EVAL do its own macroexpansion
1089                  (let* (;; (We uncross the operator name because things
1090                         ;; like SB!XC:DEFCONSTANT and SB!XC:DEFTYPE
1091                         ;; should be equivalent to their CL: counterparts
1092                         ;; when being compiled as target code. We leave
1093                         ;; the rest of the form uncrossed because macros
1094                         ;; might yet expand into EVAL-WHEN stuff, and
1095                         ;; things inside EVAL-WHEN can't be uncrossed
1096                         ;; until after we've EVALed them in the
1097                         ;; cross-compilation host.)
1098                         (slightly-uncrossed (cons (uncross (first form))
1099                                                   (rest form)))
1100                         (expanded (preprocessor-macroexpand-1
1101                                    slightly-uncrossed)))
1102                    (if (eq expanded slightly-uncrossed)
1103                        ;; (Now that we're no longer processing toplevel
1104                        ;; forms, and hence no longer need to worry about
1105                        ;; EVAL-WHEN, we can uncross everything.)
1106                        (convert-and-maybe-compile expanded path)
1107                        ;; (We have to demote COMPILE-TIME-TOO to NIL
1108                        ;; here, no matter what it was before, since
1109                        ;; otherwise we'd tend to EVAL subforms more than
1110                        ;; once, because of WHEN COMPILE-TIME-TOO form
1111                        ;; above.)
1112                        (process-toplevel-form expanded path nil))))
1113                ;; When we're not cross-compiling, we only need to
1114                ;; macroexpand once, so we can follow the 1-thru-6
1115                ;; sequence of steps in ANSI's "3.2.3.1 Processing of
1116                ;; Top Level Forms".
1117                #-sb-xc-host
1118                (let ((expanded (preprocessor-macroexpand-1 form)))
1119                  (cond ((eq expanded form)
1120                         (when compile-time-too
1121                           (eval-in-lexenv form *lexenv*))
1122                         (convert-and-maybe-compile form path))
1123                        (t
1124                         (process-toplevel-form expanded
1125                                                path
1126                                                compile-time-too))))))
1127         (if (atom form)
1128             #+sb-xc-host
1129             ;; (There are no xc EVAL-WHEN issues in the ATOM case until
1130             ;; (1) SBCL gets smart enough to handle global
1131             ;; DEFINE-SYMBOL-MACRO or SYMBOL-MACROLET and (2) SBCL
1132             ;; implementors start using symbol macros in a way which
1133             ;; interacts with SB-XC/CL distinction.)
1134             (convert-and-maybe-compile form path)
1135             #-sb-xc-host
1136             (default-processor form)
1137             (flet ((need-at-least-one-arg (form)
1138                      (unless (cdr form)
1139                        (compiler-error "~S form is too short: ~S"
1140                                        (car form)
1141                                        form))))
1142               (case (car form)
1143                 ;; In the cross-compiler, top level COLD-FSET arranges
1144                 ;; for static linking at cold init time.
1145                 #+sb-xc-host
1146                 ((cold-fset)
1147                  (aver (not compile-time-too))
1148                  (destructuring-bind (cold-fset fun-name lambda-expression) form
1149                    (declare (ignore cold-fset))
1150                    (process-toplevel-cold-fset fun-name
1151                                                lambda-expression
1152                                                path)))
1153                 ((eval-when macrolet symbol-macrolet);things w/ 1 arg before body
1154                  (need-at-least-one-arg form)
1155                  (destructuring-bind (special-operator magic &rest body) form
1156                    (ecase special-operator
1157                      ((eval-when)
1158                       ;; CT, LT, and E here are as in Figure 3-7 of ANSI
1159                       ;; "3.2.3.1 Processing of Top Level Forms".
1160                       (multiple-value-bind (ct lt e)
1161                           (parse-eval-when-situations magic)
1162                         (let ((new-compile-time-too (or ct
1163                                                         (and compile-time-too
1164                                                              e))))
1165                           (cond (lt (process-toplevel-progn
1166                                      body path new-compile-time-too))
1167                                 (new-compile-time-too (eval-in-lexenv
1168                                                        `(progn ,@body)
1169                                                        *lexenv*))))))
1170                      ((macrolet)
1171                       (funcall-in-macrolet-lexenv
1172                        magic
1173                        (lambda (&key funs)
1174                          (declare (ignore funs))
1175                          (process-toplevel-locally body
1176                                                    path
1177                                                    compile-time-too))
1178                        :compile))
1179                      ((symbol-macrolet)
1180                       (funcall-in-symbol-macrolet-lexenv
1181                        magic
1182                        (lambda (&key vars)
1183                          (process-toplevel-locally body
1184                                                    path
1185                                                    compile-time-too
1186                                                    :vars vars))
1187                        :compile)))))
1188                 ((locally)
1189                  (process-toplevel-locally (rest form) path compile-time-too))
1190                 ((progn)
1191                  (process-toplevel-progn (rest form) path compile-time-too))
1192                 (t (default-processor form))))))))
1193
1194   (values))
1195 \f
1196 ;;;; load time value support
1197 ;;;;
1198 ;;;; (See EMIT-MAKE-LOAD-FORM.)
1199
1200 ;;; Return T if we are currently producing a fasl file and hence
1201 ;;; constants need to be dumped carefully.
1202 (defun producing-fasl-file ()
1203   (fasl-output-p *compile-object*))
1204
1205 ;;; Compile FORM and arrange for it to be called at load-time. Return
1206 ;;; the dumper handle and our best guess at the type of the object.
1207 (defun compile-load-time-value (form)
1208   (let ((lambda (compile-load-time-stuff form t)))
1209     (values
1210      (fasl-dump-load-time-value-lambda lambda *compile-object*)
1211      (let ((type (leaf-type lambda)))
1212        (if (fun-type-p type)
1213            (single-value-type (fun-type-returns type))
1214            *wild-type*)))))
1215
1216 ;;; Compile the FORMS and arrange for them to be called (for effect,
1217 ;;; not value) at load time.
1218 (defun compile-make-load-form-init-forms (forms)
1219   (let ((lambda (compile-load-time-stuff `(progn ,@forms) nil)))
1220     (fasl-dump-toplevel-lambda-call lambda *compile-object*)))
1221
1222 ;;; Do the actual work of COMPILE-LOAD-TIME-VALUE or
1223 ;;; COMPILE-MAKE-LOAD-FORM-INIT-FORMS.
1224 (defun compile-load-time-stuff (form for-value)
1225   (with-ir1-namespace
1226    (let* ((*lexenv* (make-null-lexenv))
1227           (lambda (ir1-toplevel form *current-path* for-value)))
1228      (compile-toplevel (list lambda) t)
1229      lambda)))
1230
1231 ;;; This is called by COMPILE-TOPLEVEL when it was passed T for
1232 ;;; LOAD-TIME-VALUE-P (which happens in COMPILE-LOAD-TIME-STUFF). We
1233 ;;; don't try to combine this component with anything else and frob
1234 ;;; the name. If not in a :TOPLEVEL component, then don't bother
1235 ;;; compiling, because it was merged with a run-time component.
1236 (defun compile-load-time-value-lambda (lambdas)
1237   (aver (null (cdr lambdas)))
1238   (let* ((lambda (car lambdas))
1239          (component (lambda-component lambda)))
1240     (when (eql (component-kind component) :toplevel)
1241       (setf (component-name component) (leaf-debug-name lambda))
1242       (compile-component component)
1243       (clear-ir1-info component))))
1244 \f
1245 ;;;; COMPILE-FILE
1246
1247 (defun object-call-toplevel-lambda (tll)
1248   (declare (type functional tll))
1249   (let ((object *compile-object*))
1250     (etypecase object
1251       (fasl-output (fasl-dump-toplevel-lambda-call tll object))
1252       (core-object (core-call-toplevel-lambda      tll object))
1253       (null))))
1254
1255 ;;; Smash LAMBDAS into a single component, compile it, and arrange for
1256 ;;; the resulting function to be called.
1257 (defun sub-compile-toplevel-lambdas (lambdas)
1258   (declare (list lambdas))
1259   (when lambdas
1260     (multiple-value-bind (component tll) (merge-toplevel-lambdas lambdas)
1261       (compile-component component)
1262       (clear-ir1-info component)
1263       (object-call-toplevel-lambda tll)))
1264   (values))
1265
1266 ;;; Compile top level code and call the top level lambdas. We pick off
1267 ;;; top level lambdas in non-top-level components here, calling
1268 ;;; SUB-c-t-l-l on each subsequence of normal top level lambdas.
1269 (defun compile-toplevel-lambdas (lambdas)
1270   (declare (list lambdas))
1271   (let ((len (length lambdas)))
1272     (flet ((loser (start)
1273              (or (position-if (lambda (x)
1274                                 (not (eq (component-kind
1275                                           (node-component (lambda-bind x)))
1276                                          :toplevel)))
1277                               lambdas
1278                               ;; this used to read ":start start", but
1279                               ;; start can be greater than len, which
1280                               ;; is an error according to ANSI - CSR,
1281                               ;; 2002-04-25
1282                               :start (min start len))
1283                  len)))
1284       (do* ((start 0 (1+ loser))
1285             (loser (loser start) (loser start)))
1286            ((>= start len))
1287         (sub-compile-toplevel-lambdas (subseq lambdas start loser))
1288         (unless (= loser len)
1289           (object-call-toplevel-lambda (elt lambdas loser))))))
1290   (values))
1291
1292 ;;; Compile LAMBDAS (a list of CLAMBDAs for top level forms) into the
1293 ;;; object file.
1294 ;;;
1295 ;;; LOAD-TIME-VALUE-P seems to control whether it's MAKE-LOAD-FORM and
1296 ;;; COMPILE-LOAD-TIME-VALUE stuff. -- WHN 20000201
1297 (defun compile-toplevel (lambdas load-time-value-p)
1298   (declare (list lambdas))
1299
1300   (maybe-mumble "locall ")
1301   (locall-analyze-clambdas-until-done lambdas)
1302
1303   (maybe-mumble "IDFO ")
1304   (multiple-value-bind (components top-components hairy-top)
1305       (find-initial-dfo lambdas)
1306     (let ((*all-components* (append components top-components)))
1307       (when *check-consistency*
1308         (maybe-mumble "[check]~%")
1309         (check-ir1-consistency *all-components*))
1310
1311       (dolist (component (append hairy-top top-components))
1312         (pre-physenv-analyze-toplevel component))
1313
1314       (dolist (component components)
1315         (compile-component component)
1316         (replace-toplevel-xeps component))
1317
1318       (when *check-consistency*
1319         (maybe-mumble "[check]~%")
1320         (check-ir1-consistency *all-components*))
1321
1322       (if load-time-value-p
1323           (compile-load-time-value-lambda lambdas)
1324           (compile-toplevel-lambdas lambdas))
1325
1326       (mapc #'clear-ir1-info components)
1327       (clear-stuff)))
1328   (values))
1329
1330 ;;; Actually compile any stuff that has been queued up for block
1331 ;;; compilation.
1332 (defun finish-block-compilation ()
1333   (when *block-compile*
1334     (when *toplevel-lambdas*
1335       (compile-toplevel (nreverse *toplevel-lambdas*) nil)
1336       (setq *toplevel-lambdas* ()))
1337     (setq *block-compile* nil)
1338     (setq *entry-points* nil)))
1339
1340 ;;; Read all forms from INFO and compile them, with output to OBJECT.
1341 ;;; Return (VALUES NIL WARNINGS-P FAILURE-P).
1342 (defun sub-compile-file (info)
1343   (declare (type source-info info))
1344   (let* ((*block-compile* *block-compile-arg*)
1345          (*package* (sane-package))
1346          (*policy* *policy*)
1347          (*lexenv* (make-null-lexenv))
1348          (*source-info* info)
1349          (sb!xc:*compile-file-pathname* nil)
1350          (sb!xc:*compile-file-truename* nil)
1351          (*toplevel-lambdas* ())
1352          (*fun-names-in-this-file* ())
1353          (*compiler-error-bailout*
1354           (lambda ()
1355             (compiler-mumble "~2&; fatal error, aborting compilation~%")
1356             (return-from sub-compile-file (values nil t t))))
1357          (*current-path* nil)
1358          (*last-source-context* nil)
1359          (*last-original-source* nil)
1360          (*last-source-form* nil)
1361          (*last-format-string* nil)
1362          (*last-format-args* nil)
1363          (*last-message-count* 0)
1364          ;; FIXME: Do we need this rebinding here? It's a literal
1365          ;; translation of the old CMU CL rebinding to
1366          ;; (OR *BACKEND-INFO-ENVIRONMENT* *INFO-ENVIRONMENT*),
1367          ;; and it's not obvious whether the rebinding to itself is
1368          ;; needed that SBCL doesn't need *BACKEND-INFO-ENVIRONMENT*.
1369          (*info-environment* *info-environment*)
1370          (*gensym-counter* 0))
1371     (handler-case
1372         (with-compilation-values
1373          (sb!xc:with-compilation-unit ()
1374            (clear-stuff)
1375
1376            (sub-sub-compile-file info)
1377
1378            (finish-block-compilation)
1379            (let ((object *compile-object*))
1380              (etypecase object
1381                (fasl-output (fasl-dump-source-info info object))
1382                (core-object (fix-core-source-info info object))
1383                (null)))
1384            nil))
1385       ;; Some errors are sufficiently bewildering that we just fail
1386       ;; immediately, without trying to recover and compile more of
1387       ;; the input file.
1388       (input-error-in-compile-file (condition)
1389        (format *error-output*
1390                "~@<compilation aborted because of input error: ~2I~_~A~:>"
1391                condition)
1392        (values nil t t)))))
1393
1394 ;;; Return a pathname for the named file. The file must exist.
1395 (defun verify-source-file (pathname-designator)
1396   (let* ((pathname (pathname pathname-designator))
1397          (default-host (make-pathname :host (pathname-host pathname))))
1398     (flet ((try-with-type (path type error-p)
1399              (let ((new (merge-pathnames
1400                          path (make-pathname :type type
1401                                              :defaults default-host))))
1402                (if (probe-file new)
1403                    new
1404                    (and error-p (truename new))))))
1405       (cond ((typep pathname 'logical-pathname)
1406              (try-with-type pathname "LISP" t))
1407             ((probe-file pathname) pathname)
1408             ((try-with-type pathname "lisp"  nil))
1409             ((try-with-type pathname "lisp"  t))))))
1410
1411 (defun elapsed-time-to-string (tsec)
1412   (multiple-value-bind (tmin sec) (truncate tsec 60)
1413     (multiple-value-bind (thr min) (truncate tmin 60)
1414       (format nil "~D:~2,'0D:~2,'0D" thr min sec))))
1415
1416 ;;; Print some junk at the beginning and end of compilation.
1417 (defun start-error-output (source-info)
1418   (declare (type source-info source-info))
1419   (let ((file-info (source-info-file-info source-info)))
1420     (compiler-mumble "~&; compiling file ~S (written ~A):~%"
1421                      (namestring (file-info-name file-info))
1422                      (sb!int:format-universal-time nil
1423                                                    (file-info-write-date
1424                                                     file-info)
1425                                                    :style :government
1426                                                    :print-weekday nil
1427                                                    :print-timezone nil)))
1428   (values))
1429 (defun finish-error-output (source-info won)
1430   (declare (type source-info source-info))
1431   (compiler-mumble "~&; compilation ~:[aborted after~;finished in~] ~A~&"
1432                    won
1433                    (elapsed-time-to-string
1434                     (- (get-universal-time)
1435                        (source-info-start-time source-info))))
1436   (values))
1437
1438 ;;; Open some files and call SUB-COMPILE-FILE. If something unwinds
1439 ;;; out of the compile, then abort the writing of the output file, so
1440 ;;; that we don't overwrite it with known garbage.
1441 (defun sb!xc:compile-file
1442     (input-file
1443      &key
1444
1445      ;; ANSI options
1446      (output-file (cfp-output-file-default input-file))
1447      ;; FIXME: ANSI doesn't seem to say anything about
1448      ;; *COMPILE-VERBOSE* and *COMPILE-PRINT* being rebound by this
1449      ;; function..
1450      ((:verbose sb!xc:*compile-verbose*) sb!xc:*compile-verbose*)
1451      ((:print sb!xc:*compile-print*) sb!xc:*compile-print*)
1452      (external-format :default)
1453
1454      ;; extensions
1455      (trace-file nil)
1456      ((:block-compile *block-compile-arg*) nil))
1457
1458   #!+sb-doc
1459   "Compile INPUT-FILE, producing a corresponding fasl file and returning
1460    its filename. Besides the ANSI &KEY arguments :OUTPUT-FILE, :VERBOSE,
1461    :PRINT, and :EXTERNAL-FORMAT,the following extensions are supported:
1462      :TRACE-FILE
1463         If given, internal data structures are dumped to the specified
1464         file, or if a value of T is given, to a file of *.trace type
1465         derived from the input file name.
1466    Also, as a workaround for vaguely-non-ANSI behavior, the :BLOCK-COMPILE
1467    argument is quasi-supported, to determine whether multiple
1468    functions are compiled together as a unit, resolving function
1469    references at compile time. NIL means that global function names
1470    are never resolved at compilation time. Currently NIL is the
1471    default behavior, because although section 3.2.2.3, \"Semantic
1472    Constraints\", of the ANSI spec allows this behavior under all
1473    circumstances, the compiler's runtime scales badly when it
1474    tries to do this for large files. If/when this performance
1475    problem is fixed, the block compilation default behavior will
1476    probably be made dependent on the SPEED and COMPILATION-SPEED
1477    optimization values, and the :BLOCK-COMPILE argument will probably
1478    become deprecated."
1479
1480   (unless (eq external-format :default)
1481     (error "Non-:DEFAULT EXTERNAL-FORMAT values are not supported."))
1482   (let* ((fasl-output nil)
1483          (output-file-name nil)
1484          (compile-won nil)
1485          (warnings-p nil)
1486          (failure-p t) ; T in case error keeps this from being set later
1487          (input-pathname (verify-source-file input-file))
1488          (source-info (make-file-source-info input-pathname))
1489          (*compiler-trace-output* nil)) ; might be modified below
1490
1491     (unwind-protect
1492         (progn
1493           (when output-file
1494             (setq output-file-name
1495                   (sb!xc:compile-file-pathname input-file
1496                                                :output-file output-file))
1497             (setq fasl-output
1498                   (open-fasl-output output-file-name
1499                                     (namestring input-pathname))))
1500           (when trace-file
1501             (let* ((default-trace-file-pathname
1502                      (make-pathname :type "trace" :defaults input-pathname))
1503                    (trace-file-pathname
1504                     (if (eql trace-file t)
1505                         default-trace-file-pathname
1506                         (merge-pathnames trace-file
1507                                          default-trace-file-pathname))))
1508               (setf *compiler-trace-output*
1509                     (open trace-file-pathname
1510                           :if-exists :supersede
1511                           :direction :output))))
1512
1513           (when sb!xc:*compile-verbose*
1514             (start-error-output source-info))
1515           (let ((*compile-object* fasl-output)
1516                 dummy)
1517             (multiple-value-setq (dummy warnings-p failure-p)
1518               (sub-compile-file source-info)))
1519           (setq compile-won t))
1520
1521       (close-source-info source-info)
1522
1523       (when fasl-output
1524         (close-fasl-output fasl-output (not compile-won))
1525         (setq output-file-name
1526               (pathname (fasl-output-stream fasl-output)))
1527         (when (and compile-won sb!xc:*compile-verbose*)
1528           (compiler-mumble "~2&; ~A written~%" (namestring output-file-name))))
1529
1530       (when sb!xc:*compile-verbose*
1531         (finish-error-output source-info compile-won))
1532
1533       (when *compiler-trace-output*
1534         (close *compiler-trace-output*)))
1535
1536     (values (if output-file
1537                 ;; Hack around filesystem race condition...
1538                 (or (probe-file output-file-name) output-file-name)
1539                 nil)
1540             warnings-p
1541             failure-p)))
1542 \f
1543 ;;; a helper function for COMPILE-FILE-PATHNAME: the default for
1544 ;;; the OUTPUT-FILE argument
1545 ;;;
1546 ;;; ANSI: The defaults for the OUTPUT-FILE are taken from the pathname
1547 ;;; that results from merging the INPUT-FILE with the value of
1548 ;;; *DEFAULT-PATHNAME-DEFAULTS*, except that the type component should
1549 ;;; default to the appropriate implementation-defined default type for
1550 ;;; compiled files.
1551 (defun cfp-output-file-default (input-file)
1552   (let* ((defaults (merge-pathnames input-file *default-pathname-defaults*))
1553          (retyped (make-pathname :type *fasl-file-type* :defaults defaults)))
1554     retyped))
1555
1556 ;;; KLUDGE: Part of the ANSI spec for this seems contradictory:
1557 ;;;   If INPUT-FILE is a logical pathname and OUTPUT-FILE is unsupplied,
1558 ;;;   the result is a logical pathname. If INPUT-FILE is a logical
1559 ;;;   pathname, it is translated into a physical pathname as if by
1560 ;;;   calling TRANSLATE-LOGICAL-PATHNAME.
1561 ;;; So I haven't really tried to make this precisely ANSI-compatible
1562 ;;; at the level of e.g. whether it returns logical pathname or a
1563 ;;; physical pathname. Patches to make it more correct are welcome.
1564 ;;; -- WHN 2000-12-09
1565 (defun sb!xc:compile-file-pathname (input-file
1566                                     &key
1567                                     (output-file (cfp-output-file-default
1568                                                   input-file))
1569                                     &allow-other-keys)
1570   #!+sb-doc
1571   "Return a pathname describing what file COMPILE-FILE would write to given
1572    these arguments."
1573   (merge-pathnames output-file (merge-pathnames input-file)))
1574 \f
1575 ;;;; MAKE-LOAD-FORM stuff
1576
1577 ;;; The entry point for MAKE-LOAD-FORM support. When IR1 conversion
1578 ;;; finds a constant structure, it invokes this to arrange for proper
1579 ;;; dumping. If it turns out that the constant has already been
1580 ;;; dumped, then we don't need to do anything.
1581 ;;;
1582 ;;; If the constant hasn't been dumped, then we check to see whether
1583 ;;; we are in the process of creating it. We detect this by
1584 ;;; maintaining the special *CONSTANTS-BEING-CREATED* as a list of all
1585 ;;; the constants we are in the process of creating. Actually, each
1586 ;;; entry is a list of the constant and any init forms that need to be
1587 ;;; processed on behalf of that constant.
1588 ;;;
1589 ;;; It's not necessarily an error for this to happen. If we are
1590 ;;; processing the init form for some object that showed up *after*
1591 ;;; the original reference to this constant, then we just need to
1592 ;;; defer the processing of that init form. To detect this, we
1593 ;;; maintain *CONSTANTS-CREATED-SINCE-LAST-INIT* as a list of the
1594 ;;; constants created since the last time we started processing an
1595 ;;; init form. If the constant passed to emit-make-load-form shows up
1596 ;;; in this list, then there is a circular chain through creation
1597 ;;; forms, which is an error.
1598 ;;;
1599 ;;; If there is some intervening init form, then we blow out of
1600 ;;; processing it by throwing to the tag PENDING-INIT. The value we
1601 ;;; throw is the entry from *CONSTANTS-BEING-CREATED*. This is so the
1602 ;;; offending init form can be tacked onto the init forms for the
1603 ;;; circular object.
1604 ;;;
1605 ;;; If the constant doesn't show up in *CONSTANTS-BEING-CREATED*, then
1606 ;;; we have to create it. We call MAKE-LOAD-FORM and check to see
1607 ;;; whether the creation form is the magic value
1608 ;;; :SB-JUST-DUMP-IT-NORMALLY. If it is, then we don't do anything. The
1609 ;;; dumper will eventually get its hands on the object and use the
1610 ;;; normal structure dumping noise on it.
1611 ;;;
1612 ;;; Otherwise, we bind *CONSTANTS-BEING-CREATED* and
1613 ;;; *CONSTANTS-CREATED-SINCE- LAST-INIT* and compile the creation form
1614 ;;; much the way LOAD-TIME-VALUE does. When this finishes, we tell the
1615 ;;; dumper to use that result instead whenever it sees this constant.
1616 ;;;
1617 ;;; Now we try to compile the init form. We bind
1618 ;;; *CONSTANTS-CREATED-SINCE-LAST-INIT* to NIL and compile the init
1619 ;;; form (and any init forms that were added because of circularity
1620 ;;; detection). If this works, great. If not, we add the init forms to
1621 ;;; the init forms for the object that caused the problems and let it
1622 ;;; deal with it.
1623 (defvar *constants-being-created* nil)
1624 (defvar *constants-created-since-last-init* nil)
1625 ;;; FIXME: Shouldn't these^ variables be unbound outside LET forms?
1626 (defun emit-make-load-form (constant)
1627   (aver (fasl-output-p *compile-object*))
1628   (unless (or (fasl-constant-already-dumped-p constant *compile-object*)
1629               ;; KLUDGE: This special hack is because I was too lazy
1630               ;; to rework DEF!STRUCT so that the MAKE-LOAD-FORM
1631               ;; function of LAYOUT returns nontrivial forms when
1632               ;; building the cross-compiler but :IGNORE-IT when
1633               ;; cross-compiling or running under the target Lisp. --
1634               ;; WHN 19990914
1635               #+sb-xc-host (typep constant 'layout))
1636     (let ((circular-ref (assoc constant *constants-being-created* :test #'eq)))
1637       (when circular-ref
1638         (when (find constant *constants-created-since-last-init* :test #'eq)
1639           (throw constant t))
1640         (throw 'pending-init circular-ref)))
1641     (multiple-value-bind (creation-form init-form)
1642         (handler-case
1643             (sb!xc:make-load-form constant (make-null-lexenv))
1644           (error (condition)
1645                  (compiler-error "(while making load form for ~S)~%~A"
1646                                  constant
1647                                  condition)))
1648       (case creation-form
1649         (:sb-just-dump-it-normally
1650          (fasl-validate-structure constant *compile-object*)
1651          t)
1652         (:ignore-it
1653          nil)
1654         (t
1655          (when (fasl-constant-already-dumped-p constant *compile-object*)
1656            (return-from emit-make-load-form nil))
1657          (let* ((name (let ((*print-level* 1) (*print-length* 2))
1658                         (with-output-to-string (stream)
1659                           (write constant :stream stream))))
1660                 (info (if init-form
1661                           (list constant name init-form)
1662                           (list constant))))
1663            (let ((*constants-being-created*
1664                   (cons info *constants-being-created*))
1665                  (*constants-created-since-last-init*
1666                   (cons constant *constants-created-since-last-init*)))
1667              (when
1668                  (catch constant
1669                    (fasl-note-handle-for-constant
1670                     constant
1671                     (compile-load-time-value
1672                      creation-form)
1673                     *compile-object*)
1674                    nil)
1675                (compiler-error "circular references in creation form for ~S"
1676                                constant)))
1677            (when (cdr info)
1678              (let* ((*constants-created-since-last-init* nil)
1679                     (circular-ref
1680                      (catch 'pending-init
1681                        (loop for (name form) on (cdr info) by #'cddr
1682                          collect name into names
1683                          collect form into forms
1684                          finally (compile-make-load-form-init-forms forms))
1685                        nil)))
1686                (when circular-ref
1687                  (setf (cdr circular-ref)
1688                        (append (cdr circular-ref) (cdr info))))))))))))
1689
1690 \f
1691 ;;;; Host compile time definitions
1692 #+sb-xc-host
1693 (defun compile-in-lexenv (name lambda lexenv)
1694   (declare (ignore lexenv))
1695   (compile name lambda))
1696
1697 #+sb-xc-host
1698 (defun eval-in-lexenv (form lexenv)
1699   (declare (ignore lexenv))
1700   (eval form))