src/compiler/main.lisp

   1 ;;;; the top level interfaces to the compiler, plus some other
   2 ;;;; compiler-related stuff (e.g. CL:CALL-ARGUMENTS-LIMIT) which
   3 ;;;; doesn't obviously belong anywhere else
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15
  16 ;;; FIXME: Doesn't this belong somewhere else, like early-c.lisp?
  17 (declaim (special *constants* *free-vars* *component-being-compiled*
  18                   *code-vector* *next-location* *result-fixups*
  19                   *free-funs* *source-paths*
  20                   *seen-blocks* *seen-funs* *list-conflicts-table*
  21                   *continuation-number* *continuation-numbers*
  22                   *number-continuations* *tn-id* *tn-ids* *id-tns*
  23                   *label-ids* *label-id* *id-labels*
  24                   *undefined-warnings* *compiler-error-count*
  25                   *compiler-warning-count* *compiler-style-warning-count*
  26                   *compiler-note-count*
  27                   *compiler-error-bailout*
  28                   #!+sb-show *compiler-trace-output*
  29                   *last-source-context* *last-original-source*
  30                   *last-source-form* *last-format-string* *last-format-args*
  31                   *last-message-count* *lexenv* *fun-names-in-this-file*))
  32
  33 ;;; Whether call of a function which cannot be defined causes a full
  34 ;;; warning.
  35 (defvar *flame-on-necessarily-undefined-function* nil)
  36
  37 (defvar *check-consistency* nil)
  38 (defvar *all-components*)
  39
  40 ;;; Bind this to a stream to capture various internal debugging output.
  41 (defvar *compiler-trace-output* nil)
  42
  43 ;;; The current block compilation state. These are initialized to the
  44 ;;; :BLOCK-COMPILE and :ENTRY-POINTS arguments that COMPILE-FILE was
  45 ;;; called with.
  46 ;;;
  47 ;;; *BLOCK-COMPILE-ARG* holds the original value of the :BLOCK-COMPILE
  48 ;;; argument, which overrides any internal declarations.
  49 (defvar *block-compile*)
  50 (defvar *block-compile-arg*)
  51 (declaim (type (member nil t :specified) *block-compile* *block-compile-arg*))
  52 (defvar *entry-points*)
  53 (declaim (list *entry-points*))
  54
  55 ;;; When block compiling, used by PROCESS-FORM to accumulate top level
  56 ;;; lambdas resulting from compiling subforms. (In reverse order.)
  57 (defvar *toplevel-lambdas*)
  58 (declaim (list *toplevel-lambdas*))
  59
  60 (defvar sb!xc:*compile-verbose* t
  61   #!+sb-doc
  62   "The default for the :VERBOSE argument to COMPILE-FILE.")
  63 (defvar sb!xc:*compile-print* t
  64   #!+sb-doc
  65   "The default for the :PRINT argument to COMPILE-FILE.")
  66 (defvar *compile-progress* nil
  67   #!+sb-doc
  68   "When this is true, the compiler prints to *ERROR-OUTPUT* progress
  69   information about the phases of compilation of each function. (This
  70   is useful mainly in large block compilations.)")
  71
  72 (defvar sb!xc:*compile-file-pathname* nil
  73   #!+sb-doc
  74   "The defaulted pathname of the file currently being compiled, or NIL if not
  75   compiling.")
  76 (defvar sb!xc:*compile-file-truename* nil
  77   #!+sb-doc
  78   "The TRUENAME of the file currently being compiled, or NIL if not
  79   compiling.")
  80
  81 (declaim (type (or pathname null)
  82                sb!xc:*compile-file-pathname*
  83                sb!xc:*compile-file-truename*))
  84
  85 ;;; the SOURCE-INFO structure for the current compilation. This is
  86 ;;; null globally to indicate that we aren't currently in any
  87 ;;; identifiable compilation.
  88 (defvar *source-info* nil)
  89
  90 ;;; This is true if we are within a WITH-COMPILATION-UNIT form (which
  91 ;;; normally causes nested uses to be no-ops).
  92 (defvar *in-compilation-unit* nil)
  93
  94 ;;; Count of the number of compilation units dynamically enclosed by
  95 ;;; the current active WITH-COMPILATION-UNIT that were unwound out of.
  96 (defvar *aborted-compilation-unit-count*)
  97
  98 ;;; Mumble conditional on *COMPILE-PROGRESS*.
  99 (defun maybe-mumble (&rest foo)
 100   (when *compile-progress*
 101     (compiler-mumble "~&")
 102     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 103        (apply #'compiler-mumble foo))))
 104
 105 (deftype object () '(or fasl-output core-object null))
 106
 107 (defvar *compile-object* nil)
 108 (declaim (type object *compile-object*))
 109 \f
 110 ;;;; WITH-COMPILATION-UNIT and WITH-COMPILATION-VALUES
 111
 112 (defmacro sb!xc:with-compilation-unit (options &body body)
 113   #!+sb-doc
 114   "WITH-COMPILATION-UNIT ({Key Value}*) Form*
 115   This form affects compilations that take place within its dynamic extent. It
 116   is intended to be wrapped around the compilation of all files in the same
 117   system. These keywords are defined:
 118     :OVERRIDE Boolean-Form
 119         One of the effects of this form is to delay undefined warnings
 120         until the end of the form, instead of giving them at the end of each
 121         compilation. If OVERRIDE is NIL (the default), then the outermost
 122         WITH-COMPILATION-UNIT form grabs the undefined warnings. Specifying
 123         OVERRIDE true causes that form to grab any enclosed warnings, even if
 124         it is enclosed by another WITH-COMPILATION-UNIT."
 125   `(%with-compilation-unit (lambda () ,@body) ,@options))
 126
 127 (defun %with-compilation-unit (fn &key override)
 128   (declare (type function fn))
 129   (let ((succeeded-p nil))
 130     (if (and *in-compilation-unit* (not override))
 131         ;; Inside another WITH-COMPILATION-UNIT, a WITH-COMPILATION-UNIT is
 132         ;; ordinarily (unless OVERRIDE) basically a no-op.
 133         (unwind-protect
 134              (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 135           (unless succeeded-p
 136             (incf *aborted-compilation-unit-count*)))
 137         (let ((*aborted-compilation-unit-count* 0)
 138               (*compiler-error-count* 0)
 139               (*compiler-warning-count* 0)
 140               (*compiler-style-warning-count* 0)
 141               (*compiler-note-count* 0)
 142               (*undefined-warnings* nil)
 143               (*in-compilation-unit* t))
 144           (sb!thread:with-recursive-lock (*big-compiler-lock*)
 145             (handler-bind ((parse-unknown-type
 146                             (lambda (c)
 147                               (note-undefined-reference
 148                                (parse-unknown-type-specifier c)
 149                                :type))))
 150               (unwind-protect
 151                    (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 152                 (unless succeeded-p
 153                   (incf *aborted-compilation-unit-count*))
 154                 (summarize-compilation-unit (not succeeded-p)))))))))
 155
 156 ;;; Is FUN-NAME something that no conforming program can rely on
 157 ;;; defining as a function?
 158 (defun fun-name-reserved-by-ansi-p (fun-name)
 159   (eq (symbol-package (fun-name-block-name fun-name))
 160       *cl-package*))
 161
 162 ;;; This is to be called at the end of a compilation unit. It signals
 163 ;;; any residual warnings about unknown stuff, then prints the total
 164 ;;; error counts. ABORT-P should be true when the compilation unit was
 165 ;;; aborted by throwing out. ABORT-COUNT is the number of dynamically
 166 ;;; enclosed nested compilation units that were aborted.
 167 (defun summarize-compilation-unit (abort-p)
 168   (unless abort-p
 169     (handler-bind ((style-warning #'compiler-style-warning-handler)
 170                    (warning #'compiler-warning-handler))
 171
 172       (let ((undefs (sort *undefined-warnings* #'string<
 173                           :key (lambda (x)
 174                                  (let ((x (undefined-warning-name x)))
 175                                    (if (symbolp x)
 176                                        (symbol-name x)
 177                                        (prin1-to-string x)))))))
 178         (dolist (undef undefs)
 179           (let ((name (undefined-warning-name undef))
 180                 (kind (undefined-warning-kind undef))
 181                 (warnings (undefined-warning-warnings undef))
 182                 (undefined-warning-count (undefined-warning-count undef)))
 183             (dolist (*compiler-error-context* warnings)
 184               (if #-sb-xc-host (and (eq kind :function)
 185                                     (fun-name-reserved-by-ansi-p name)
 186                                     *flame-on-necessarily-undefined-function*)
 187                   #+sb-xc-host nil
 188                   (case name
 189                     ((declare)
 190                      (compiler-warn
 191                       "~@<There is no function named ~S. References to ~S in ~
 192                        some contexts (like starts of blocks) have special ~
 193                        meaning, but here it would have to be a function, ~
 194                        and that shouldn't be right.~:@>"
 195                       name name))
 196                     (t
 197                      (compiler-warn
 198                       "~@<The ~(~A~) ~S is undefined, and its name is ~
 199                        reserved by ANSI CL so that even if it it were ~
 200                        defined later, the code doing so would not be ~
 201                        portable.~:@>"
 202                       kind name)))
 203                   (if (eq kind :variable)
 204                       (compiler-warn "undefined ~(~A~): ~S" kind name)
 205                       (compiler-style-warn "undefined ~(~A~): ~S" kind name))))
 206             (let ((warn-count (length warnings)))
 207               (when (and warnings (> undefined-warning-count warn-count))
 208                 (let ((more (- undefined-warning-count warn-count)))
 209                   (if (eq kind :variable)
 210                       (compiler-warn
 211                        "~W more use~:P of undefined ~(~A~) ~S"
 212                        more kind name)
 213                       (compiler-style-warn
 214                        "~W more use~:P of undefined ~(~A~) ~S"
 215                        more kind name)))))))
 216
 217         (dolist (kind '(:variable :function :type))
 218           (let ((summary (mapcar #'undefined-warning-name
 219                                  (remove kind undefs :test-not #'eq
 220                                          :key #'undefined-warning-kind))))
 221             (when summary
 222               (if (eq kind :variable)
 223                   (compiler-warn
 224                    "~:[This ~(~A~) is~;These ~(~A~)s are~] undefined:~
 225                     ~%  ~{~<~%  ~1:;~S~>~^ ~}"
 226                    (cdr summary) kind summary)
 227                   (compiler-style-warn
 228                    "~:[This ~(~A~) is~;These ~(~A~)s are~] undefined:~
 229                    ~%  ~{~<~%  ~1:;~S~>~^ ~}"
 230                    (cdr summary) kind summary))))))))
 231
 232   (unless (and (not abort-p)
 233                (zerop *aborted-compilation-unit-count*)
 234                (zerop *compiler-error-count*)
 235                (zerop *compiler-warning-count*)
 236                (zerop *compiler-style-warning-count*)
 237                (zerop *compiler-note-count*))
 238     (format *error-output* "~&")
 239     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 240       (compiler-mumble "compilation unit ~:[finished~;aborted~]~
 241                        ~[~:;~:*~&  caught ~W fatal ERROR condition~:P~]~
 242                        ~[~:;~:*~&  caught ~W ERROR condition~:P~]~
 243                        ~[~:;~:*~&  caught ~W WARNING condition~:P~]~
 244                        ~[~:;~:*~&  caught ~W STYLE-WARNING condition~:P~]~
 245                        ~[~:;~:*~&  printed ~W note~:P~]"
 246                        abort-p
 247                        *aborted-compilation-unit-count*
 248                        *compiler-error-count*
 249                        *compiler-warning-count*
 250                        *compiler-style-warning-count*
 251                        *compiler-note-count*)))
 252   (format *error-output* "~&"))
 253
 254 ;;; Evaluate BODY, then return (VALUES BODY-VALUE WARNINGS-P
 255 ;;; FAILURE-P), where BODY-VALUE is the first value of the body, and
 256 ;;; WARNINGS-P and FAILURE-P are as in CL:COMPILE or CL:COMPILE-FILE.
 257 ;;; This also wraps up WITH-IR1-NAMESPACE functionality.
 258 (defmacro with-compilation-values (&body body)
 259   `(with-ir1-namespace
 260     (let ((*warnings-p* nil)
 261           (*failure-p* nil))
 262       (values (progn ,@body)
 263               *warnings-p*
 264               *failure-p*))))
 265 \f
 266 ;;;; component compilation
 267
 268 (defparameter *max-optimize-iterations* 3 ; ARB
 269   #!+sb-doc
 270   "The upper limit on the number of times that we will consecutively do IR1
 271   optimization that doesn't introduce any new code. A finite limit is
 272   necessary, since type inference may take arbitrarily long to converge.")
 273
 274 (defevent ir1-optimize-until-done "IR1-OPTIMIZE-UNTIL-DONE called")
 275 (defevent ir1-optimize-maxed-out "hit *MAX-OPTIMIZE-ITERATIONS* limit")
 276
 277 ;;; Repeatedly optimize COMPONENT until no further optimizations can
 278 ;;; be found or we hit our iteration limit. When we hit the limit, we
 279 ;;; clear the component and block REOPTIMIZE flags to discourage the
 280 ;;; next optimization attempt from pounding on the same code.
 281 (defun ir1-optimize-until-done (component)
 282   (declare (type component component))
 283   (maybe-mumble "opt")
 284   (event ir1-optimize-until-done)
 285   (let ((count 0)
 286         (cleared-reanalyze nil))
 287     (loop
 288       (when (component-reanalyze component)
 289         (setq count 0)
 290         (setq cleared-reanalyze t)
 291         (setf (component-reanalyze component) nil))
 292       (setf (component-reoptimize component) nil)
 293       (ir1-optimize component)
 294       (cond ((component-reoptimize component)
 295              (incf count)
 296              (when (= count *max-optimize-iterations*)
 297                (maybe-mumble "*")
 298                (cond ((retry-delayed-ir1-transforms :optimize)
 299                       (maybe-mumble "+")
 300                       (setq count 0))
 301                      (t
 302                       (event ir1-optimize-maxed-out)
 303                       (setf (component-reoptimize component) nil)
 304                       (do-blocks (block component)
 305                         (setf (block-reoptimize block) nil))
 306                       (return)))))
 307             ((retry-delayed-ir1-transforms :optimize)
 308              (setf count 0)
 309              (maybe-mumble "+"))
 310             (t
 311              (maybe-mumble " ")
 312              (return)))
 313       (maybe-mumble "."))
 314     (when cleared-reanalyze
 315       (setf (component-reanalyze component) t)))
 316   (values))
 317
 318 (defparameter *constraint-propagate* t)
 319
 320 ;;; KLUDGE: This was bumped from 5 to 10 in a DTC patch ported by MNA
 321 ;;; from CMU CL into sbcl-0.6.11.44, the same one which allowed IR1
 322 ;;; transforms to be delayed. Either DTC or MNA or both didn't explain
 323 ;;; why, and I don't know what the rationale was. -- WHN 2001-04-28
 324 ;;;
 325 ;;; FIXME: It would be good to document why it's important to have a
 326 ;;; large value here, and what the drawbacks of an excessively large
 327 ;;; value are; and it might also be good to make it depend on
 328 ;;; optimization policy.
 329 (defparameter *reoptimize-after-type-check-max* 10)
 330
 331 (defevent reoptimize-maxed-out
 332   "*REOPTIMIZE-AFTER-TYPE-CHECK-MAX* exceeded.")
 333
 334 ;;; Iterate doing FIND-DFO until no new dead code is discovered.
 335 (defun dfo-as-needed (component)
 336   (declare (type component component))
 337   (when (component-reanalyze component)
 338     (maybe-mumble "DFO")
 339     (loop
 340       (find-dfo component)
 341       (unless (component-reanalyze component)
 342         (maybe-mumble " ")
 343         (return))
 344       (maybe-mumble ".")))
 345   (values))
 346
 347 ;;; Do all the IR1 phases for a non-top-level component.
 348 (defun ir1-phases (component)
 349   (declare (type component component))
 350   (aver-live-component component)
 351   (let ((*constraint-number* 0)
 352         (loop-count 1)
 353         (*delayed-ir1-transforms* nil))
 354     (declare (special *constraint-number* *delayed-ir1-transforms*))
 355     (loop
 356       (ir1-optimize-until-done component)
 357       (when (or (component-new-functionals component)
 358                 (component-reanalyze-functionals component))
 359         (maybe-mumble "locall ")
 360         (locall-analyze-component component))
 361       (dfo-as-needed component)
 362       (when *constraint-propagate*
 363         (maybe-mumble "constraint ")
 364         (constraint-propagate component))
 365       (when (retry-delayed-ir1-transforms :constraint)
 366         (maybe-mumble "Rtran "))
 367       (flet ((want-reoptimization-p ()
 368                (or (component-reoptimize component)
 369                    (component-reanalyze component)
 370                    (component-new-functionals component)
 371                    (component-reanalyze-functionals component))))
 372         (unless (and (want-reoptimization-p)
 373                      ;; We delay the generation of type checks until
 374                      ;; the type constraints have had time to
 375                      ;; propagate, else the compiler can confuse itself.
 376                      (< loop-count (- *reoptimize-after-type-check-max* 4)))
 377           (maybe-mumble "type ")
 378           (generate-type-checks component)
 379           (unless (want-reoptimization-p)
 380             (return))))
 381       (when (>= loop-count *reoptimize-after-type-check-max*)
 382         (maybe-mumble "[reoptimize limit]")
 383         (event reoptimize-maxed-out)
 384         (return))
 385       (incf loop-count)))
 386
 387   (ir1-finalize component)
 388   (values))
 389
 390 (defun %compile-component (component)
 391   (let ((*code-segment* nil)
 392         (*elsewhere* nil))
 393     (maybe-mumble "GTN ")
 394     (gtn-analyze component)
 395     (maybe-mumble "LTN ")
 396     (ltn-analyze component)
 397     (dfo-as-needed component)
 398     (maybe-mumble "control ")
 399     (control-analyze component #'make-ir2-block)
 400
 401     (when (ir2-component-values-receivers (component-info component))
 402       (maybe-mumble "stack ")
 403       (stack-analyze component)
 404       ;; Assign BLOCK-NUMBER for any cleanup blocks introduced by
 405       ;; stack analysis. There shouldn't be any unreachable code after
 406       ;; control, so this won't delete anything.
 407       (dfo-as-needed component))
 408
 409     (unwind-protect
 410         (progn
 411           (maybe-mumble "IR2tran ")
 412           (init-assembler)
 413           (entry-analyze component)
 414           (ir2-convert component)
 415
 416           (when (policy *lexenv* (>= speed compilation-speed))
 417             (maybe-mumble "copy ")
 418             (copy-propagate component))
 419
 420           (select-representations component)
 421
 422           (when *check-consistency*
 423             (maybe-mumble "check2 ")
 424             (check-ir2-consistency component))
 425
 426           (delete-unreferenced-tns component)
 427
 428           (maybe-mumble "life ")
 429           (lifetime-analyze component)
 430
 431           (when *compile-progress*
 432             (compiler-mumble "") ; Sync before doing more output.
 433             (pre-pack-tn-stats component *error-output*))
 434
 435           (when *check-consistency*
 436             (maybe-mumble "check-life ")
 437             (check-life-consistency component))
 438
 439           (maybe-mumble "pack ")
 440           (pack component)
 441
 442           (when *check-consistency*
 443             (maybe-mumble "check-pack ")
 444             (check-pack-consistency component))
 445
 446           (when *compiler-trace-output*
 447             (describe-component component *compiler-trace-output*)
 448             (describe-ir2-component component *compiler-trace-output*))
 449
 450           (maybe-mumble "code ")
 451           (multiple-value-bind (code-length trace-table fixup-notes)
 452               (generate-code component)
 453
 454             #-sb-xc-host
 455             (when *compiler-trace-output*
 456               (format *compiler-trace-output*
 457                       "~|~%disassembly of code for ~S~2%" component)
 458               (sb!disassem:disassemble-assem-segment *code-segment*
 459                                                      *compiler-trace-output*))
 460
 461             (etypecase *compile-object*
 462               (fasl-output
 463                (maybe-mumble "fasl")
 464                (fasl-dump-component component
 465                                     *code-segment*
 466                                     code-length
 467                                     trace-table
 468                                     fixup-notes
 469                                     *compile-object*))
 470               (core-object
 471                (maybe-mumble "core")
 472                (make-core-component component
 473                                     *code-segment*
 474                                     code-length
 475                                     trace-table
 476                                     fixup-notes
 477                                     *compile-object*))
 478               (null))))))
 479
 480   ;; We're done, so don't bother keeping anything around.
 481   (setf (component-info component) :dead)
 482
 483   (values))
 484
 485 ;;; Delete components with no external entry points before we try to
 486 ;;; generate code. Unreachable closures can cause IR2 conversion to
 487 ;;; puke on itself, since it is the reference to the closure which
 488 ;;; normally causes the components to be combined.
 489 (defun delete-if-no-entries (component)
 490   (dolist (fun (component-lambdas component) (delete-component component))
 491     (when (functional-has-external-references-p fun)
 492       (return))
 493     (case (functional-kind fun)
 494       (:toplevel (return))
 495       (:external
 496        (unless (every (lambda (ref)
 497                         (eq (node-component ref) component))
 498                       (leaf-refs fun))
 499          (return))))))
 500
 501 (defun compile-component (component)
 502
 503   ;; miscellaneous sanity checks
 504   ;;
 505   ;; FIXME: These are basically pretty wimpy compared to the checks done
 506   ;; by the old CHECK-IR1-CONSISTENCY code. It would be really nice to
 507   ;; make those internal consistency checks work again and use them.
 508   (aver-live-component component)
 509   (do-blocks (block component)
 510     (aver (eql (block-component block) component)))
 511   (dolist (lambda (component-lambdas component))
 512     ;; sanity check to prevent weirdness from propagating insidiously as
 513     ;; far from its root cause as it did in bug 138: Make sure that
 514     ;; thing-to-COMPONENT links are consistent.
 515     (aver (eql (lambda-component lambda) component))
 516     (aver (eql (node-component (lambda-bind lambda)) component)))
 517
 518   (let* ((*component-being-compiled* component))
 519     (when sb!xc:*compile-print*
 520       (compiler-mumble "~&; compiling ~A: " (component-name component)))
 521
 522     (ir1-phases component)
 523
 524     ;; FIXME: What is MAYBE-MUMBLE for? Do we need it any more?
 525     (maybe-mumble "env ")
 526     (physenv-analyze component)
 527     (dfo-as-needed component)
 528
 529     (delete-if-no-entries component)
 530
 531     (unless (eq (block-next (component-head component))
 532                 (component-tail component))
 533       (%compile-component component)))
 534
 535   (clear-constant-info)
 536
 537   (when sb!xc:*compile-print*
 538     (compiler-mumble "~&"))
 539
 540   (values))
 541 \f
 542 ;;;; clearing global data structures
 543 ;;;;
 544 ;;;; FIXME: Is it possible to get rid of this stuff, getting rid of
 545 ;;;; global data structures entirely when possible and consing up the
 546 ;;;; others from scratch instead of clearing and reusing them?
 547
 548 ;;; Clear the INFO in constants in the *FREE-VARS*, etc. In
 549 ;;; addition to allowing stuff to be reclaimed, this is required for
 550 ;;; correct assignment of constant offsets, since we need to assign a
 551 ;;; new offset for each component. We don't clear the FUNCTIONAL-INFO
 552 ;;; slots, since they are used to keep track of functions across
 553 ;;; component boundaries.
 554 (defun clear-constant-info ()
 555   (maphash (lambda (k v)
 556              (declare (ignore k))
 557              (setf (leaf-info v) nil))
 558            *constants*)
 559   (maphash (lambda (k v)
 560              (declare (ignore k))
 561              (when (constant-p v)
 562                (setf (leaf-info v) nil)))
 563            *free-vars*)
 564   (values))
 565
 566 ;;; Blow away the REFS for all global variables, and let COMPONENT
 567 ;;; be recycled.
 568 (defun clear-ir1-info (component)
 569   (declare (type component component))
 570   (labels ((blast (x)
 571              (maphash (lambda (k v)
 572                         (declare (ignore k))
 573                         (when (leaf-p v)
 574                           (setf (leaf-refs v)
 575                                 (delete-if #'here-p (leaf-refs v)))
 576                           (when (basic-var-p v)
 577                             (setf (basic-var-sets v)
 578                                   (delete-if #'here-p (basic-var-sets v))))))
 579                       x))
 580            (here-p (x)
 581              (eq (node-component x) component)))
 582     (blast *free-vars*)
 583     (blast *free-funs*)
 584     (blast *constants*))
 585   (values))
 586
 587 ;;; Clear global variables used by the compiler.
 588 ;;;
 589 ;;; FIXME: It seems kinda nasty and unmaintainable to have to do this,
 590 ;;; and it adds overhead even when people aren't using the compiler.
 591 ;;; Perhaps we could make these global vars unbound except when
 592 ;;; actually in use, so that this function could go away.
 593 (defun clear-stuff (&optional (debug-too t))
 594
 595   ;; Clear global tables.
 596   (when (boundp '*free-funs*)
 597     (clrhash *free-funs*)
 598     (clrhash *free-vars*)
 599     (clrhash *constants*))
 600
 601   ;; Clear debug counters and tables.
 602   (clrhash *seen-blocks*)
 603   (clrhash *seen-funs*)
 604   (clrhash *list-conflicts-table*)
 605
 606   (when debug-too
 607     (clrhash *continuation-numbers*)
 608     (clrhash *number-continuations*)
 609     (setq *continuation-number* 0)
 610     (clrhash *tn-ids*)
 611     (clrhash *id-tns*)
 612     (setq *tn-id* 0)
 613     (clrhash *label-ids*)
 614     (clrhash *id-labels*)
 615     (setq *label-id* 0)
 616
 617     ;; Clear some PACK data structures (for GC purposes only).
 618     (aver (not *in-pack*))
 619     (dolist (sb *backend-sb-list*)
 620       (when (finite-sb-p sb)
 621         (fill (finite-sb-live-tns sb) nil))))
 622
 623   ;; (Note: The CMU CL code used to set CL::*GENSYM-COUNTER* to zero here.
 624   ;; Superficially, this seemed harmful -- the user could reasonably be
 625   ;; surprised if *GENSYM-COUNTER* turned back to zero when something was
 626   ;; compiled. A closer inspection showed that this actually turned out to be
 627   ;; harmless in practice, because CLEAR-STUFF was only called from within
 628   ;; forms which bound CL::*GENSYM-COUNTER* to zero. However, this means that
 629   ;; even though zeroing CL::*GENSYM-COUNTER* here turned out to be harmless in
 630   ;; practice, it was also useless in practice. So we don't do it any more.)
 631
 632   (values))
 633 \f
 634 ;;;; trace output
 635
 636 ;;; Print out some useful info about COMPONENT to STREAM.
 637 (defun describe-component (component *standard-output*)
 638   (declare (type component component))
 639   (format t "~|~%;;;; component: ~S~2%" (component-name component))
 640   (print-all-blocks component)
 641   (values))
 642
 643 (defun describe-ir2-component (component *standard-output*)
 644   (format t "~%~|~%;;;; IR2 component: ~S~2%" (component-name component))
 645   (format t "entries:~%")
 646   (dolist (entry (ir2-component-entries (component-info component)))
 647     (format t "~4TL~D: ~S~:[~; [closure]~]~%"
 648             (label-id (entry-info-offset entry))
 649             (entry-info-name entry)
 650             (entry-info-closure-p entry)))
 651   (terpri)
 652   (pre-pack-tn-stats component *standard-output*)
 653   (terpri)
 654   (print-ir2-blocks component)
 655   (terpri)
 656   (values))
 657 \f
 658 ;;;; file reading
 659 ;;;;
 660 ;;;; When reading from a file, we have to keep track of some source
 661 ;;;; information. We also exploit our ability to back up for printing
 662 ;;;; the error context and for recovering from errors.
 663 ;;;;
 664 ;;;; The interface we provide to this stuff is the stream-oid
 665 ;;;; SOURCE-INFO structure. The bookkeeping is done as a side effect
 666 ;;;; of getting the next source form.
 667
 668 ;;; A FILE-INFO structure holds all the source information for a
 669 ;;; given file.
 670 (defstruct (file-info (:copier nil))
 671   ;; If a file, the truename of the corresponding source file. If from
 672   ;; a Lisp form, :LISP. If from a stream, :STREAM.
 673   (name (missing-arg) :type (or pathname (member :lisp :stream)))
 674   ;; the defaulted, but not necessarily absolute file name (i.e. prior
 675   ;; to TRUENAME call.) Null if not a file. This is used to set
 676   ;; *COMPILE-FILE-PATHNAME*, and if absolute, is dumped in the
 677   ;; debug-info.
 678   (untruename nil :type (or pathname null))
 679   ;; the file's write date (if relevant)
 680   (write-date nil :type (or unsigned-byte null))
 681   ;; the source path root number of the first form in this file (i.e.
 682   ;; the total number of forms converted previously in this
 683   ;; compilation)
 684   (source-root 0 :type unsigned-byte)
 685   ;; parallel vectors containing the forms read out of the file and
 686   ;; the file positions that reading of each form started at (i.e. the
 687   ;; end of the previous form)
 688   (forms (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t))
 689   (positions (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t)))
 690
 691 ;;; The SOURCE-INFO structure provides a handle on all the source
 692 ;;; information for an entire compilation.
 693 (defstruct (source-info
 694             #-no-ansi-print-object
 695             (:print-object (lambda (s stream)
 696                              (print-unreadable-object (s stream :type t))))
 697             (:copier nil))
 698   ;; the UT that compilation started at
 699   (start-time (get-universal-time) :type unsigned-byte)
 700   ;; the FILE-INFO structure for this compilation
 701   (file-info nil :type (or file-info null))
 702   ;; the stream that we are using to read the FILE-INFO, or NIL if
 703   ;; no stream has been opened yet
 704   (stream nil :type (or stream null)))
 705
 706 ;;; Given a pathname, return a SOURCE-INFO structure.
 707 (defun make-file-source-info (file)
 708   (let ((file-info (make-file-info :name (truename file)
 709                                    :untruename file
 710                                    :write-date (file-write-date file))))
 711
 712     (make-source-info :file-info file-info)))
 713
 714 ;;; Return a SOURCE-INFO to describe the incremental compilation of FORM.
 715 (defun make-lisp-source-info (form)
 716   (make-source-info :start-time (get-universal-time)
 717                     :file-info (make-file-info :name :lisp
 718                                                :forms (vector form)
 719                                                :positions '#(0))))
 720
 721 ;;; Return a SOURCE-INFO which will read from STREAM.
 722 (defun make-stream-source-info (stream)
 723   (let ((file-info (make-file-info :name :stream)))
 724     (make-source-info :file-info file-info
 725                       :stream stream)))
 726
 727 ;;; Return a form read from STREAM; or for EOF use the trick,
 728 ;;; popularized by Kent Pitman, of returning STREAM itself. If an
 729 ;;; error happens, then convert it to standard abort-the-compilation
 730 ;;; error condition (possibly recording some extra location
 731 ;;; information).
 732 (defun read-for-compile-file (stream position)
 733   (handler-case (read stream nil stream)
 734     (reader-error (condition)
 735      (error 'input-error-in-compile-file
 736             :error condition
 737             ;; We don't need to supply :POSITION here because
 738             ;; READER-ERRORs already know their position in the file.
 739             ))
 740     ;; ANSI, in its wisdom, says that READ should return END-OF-FILE
 741     ;; (and that this is not a READER-ERROR) when it encounters end of
 742     ;; file in the middle of something it's trying to read.
 743     (end-of-file (condition)
 744      (error 'input-error-in-compile-file
 745             :error condition
 746             ;; We need to supply :POSITION here because the END-OF-FILE
 747             ;; condition doesn't carry the position that the user
 748             ;; probably cares about, where the failed READ began.
 749             :position position))))
 750
 751 ;;; If STREAM is present, return it, otherwise open a stream to the
 752 ;;; current file. There must be a current file.
 753 ;;;
 754 ;;; FIXME: This is probably an unnecessarily roundabout way to do
 755 ;;; things now that we process a single file in COMPILE-FILE (unlike
 756 ;;; the old CMU CL code, which accepted multiple files). Also, the old
 757 ;;; comment said
 758 ;;;   When we open a new file, we also reset *PACKAGE* and policy.
 759 ;;;   This gives the effect of rebinding around each file.
 760 ;;; which doesn't seem to be true now. Check to make sure that if
 761 ;;; such rebinding is necessary, it's still done somewhere.
 762 (defun get-source-stream (info)
 763   (declare (type source-info info))
 764   (or (source-info-stream info)
 765       (let* ((file-info (source-info-file-info info))
 766              (name (file-info-name file-info)))
 767         (setf sb!xc:*compile-file-truename* name
 768               sb!xc:*compile-file-pathname* (file-info-untruename file-info)
 769               (source-info-stream info) (open name :direction :input)))))
 770
 771 ;;; Close the stream in INFO if it is open.
 772 (defun close-source-info (info)
 773   (declare (type source-info info))
 774   (let ((stream (source-info-stream info)))
 775     (when stream (close stream)))
 776   (setf (source-info-stream info) nil)
 777   (values))
 778
 779 ;;; Read and compile the source file.
 780 (defun sub-sub-compile-file (info)
 781   (let* ((file-info (source-info-file-info info))
 782          (stream (get-source-stream info)))
 783     (loop
 784      (let* ((pos (file-position stream))
 785             (form (read-for-compile-file stream pos)))
 786        (if (eq form stream) ; i.e., if EOF
 787            (return)
 788            (let* ((forms (file-info-forms file-info))
 789                   (current-idx (+ (fill-pointer forms)
 790                                   (file-info-source-root file-info))))
 791              (vector-push-extend form forms)
 792              (vector-push-extend pos (file-info-positions file-info))
 793              (find-source-paths form current-idx)
 794              (process-toplevel-form form
 795                                     `(original-source-start 0 ,current-idx)
 796                                     nil)))))))
 797
 798 ;;; Return the INDEX'th source form read from INFO and the position
 799 ;;; where it was read.
 800 (defun find-source-root (index info)
 801   (declare (type index index) (type source-info info))
 802   (let ((file-info (source-info-file-info info)))
 803     (values (aref (file-info-forms file-info) index)
 804             (aref (file-info-positions file-info) index))))
 805 \f
 806 ;;;; processing of top level forms
 807
 808 ;;; This is called by top level form processing when we are ready to
 809 ;;; actually compile something. If *BLOCK-COMPILE* is T, then we still
 810 ;;; convert the form, but delay compilation, pushing the result on
 811 ;;; *TOPLEVEL-LAMBDAS* instead.
 812 (defun convert-and-maybe-compile (form path)
 813   (declare (list path))
 814   (let* ((*lexenv* (make-lexenv :policy *policy*))
 815          (tll (ir1-toplevel form path nil)))
 816     (cond ((eq *block-compile* t) (push tll *toplevel-lambdas*))
 817           (t (compile-toplevel (list tll) nil)))))
 818
 819 ;;; Macroexpand FORM in the current environment with an error handler.
 820 ;;; We only expand one level, so that we retain all the intervening
 821 ;;; forms in the source path.
 822 (defun preprocessor-macroexpand-1 (form)
 823   (handler-case (sb!xc:macroexpand-1 form *lexenv*)
 824     (error (condition)
 825       (compiler-error "(during macroexpansion of ~A)~%~A"
 826                       (let ((*print-level* 1)
 827                             (*print-length* 2))
 828                         (format nil "~S" form))
 829                       condition))))
 830
 831 ;;; Process a PROGN-like portion of a top level form. FORMS is a list of
 832 ;;; the forms, and PATH is the source path of the FORM they came out of.
 833 ;;; COMPILE-TIME-TOO is as in ANSI "3.2.3.1 Processing of Top Level Forms".
 834 (defun process-toplevel-progn (forms path compile-time-too)
 835   (declare (list forms) (list path))
 836   (dolist (form forms)
 837     (process-toplevel-form form path compile-time-too)))
 838
 839 ;;; Process a top level use of LOCALLY, or anything else (e.g.
 840 ;;; MACROLET) at top level which has declarations and ordinary forms.
 841 ;;; We parse declarations and then recursively process the body.
 842 (defun process-toplevel-locally (body path compile-time-too &key vars funs)
 843   (declare (list path))
 844   (multiple-value-bind (forms decls)
 845       (parse-body body :doc-string-allowed nil :toplevel t)
 846     (let* ((*lexenv* (process-decls decls vars funs))
 847            ;; FIXME: VALUES declaration
 848            ;;
 849            ;; Binding *POLICY* is pretty much of a hack, since it
 850            ;; causes LOCALLY to "capture" enclosed proclamations. It
 851            ;; is necessary because CONVERT-AND-MAYBE-COMPILE uses the
 852            ;; value of *POLICY* as the policy. The need for this hack
 853            ;; is due to the quirk that there is no way to represent in
 854            ;; a POLICY that an optimize quality came from the default.
 855            ;;
 856            ;; FIXME: Ideally, something should be done so that DECLAIM
 857            ;; inside LOCALLY works OK. Failing that, at least we could
 858            ;; issue a warning instead of silently screwing up.
 859            (*policy* (lexenv-policy *lexenv*)))
 860       (process-toplevel-progn forms path compile-time-too))))
 861
 862 ;;; Parse an EVAL-WHEN situations list, returning three flags,
 863 ;;; (VALUES COMPILE-TOPLEVEL LOAD-TOPLEVEL EXECUTE), indicating
 864 ;;; the types of situations present in the list.
 865 (defun parse-eval-when-situations (situations)
 866   (when (or (not (listp situations))
 867             (set-difference situations
 868                             '(:compile-toplevel
 869                               compile
 870                               :load-toplevel
 871                               load
 872                               :execute
 873                               eval)))
 874     (compiler-error "bad EVAL-WHEN situation list: ~S" situations))
 875   (let ((deprecated-names (intersection situations '(compile load eval))))
 876     (when deprecated-names
 877       (style-warn "using deprecated EVAL-WHEN situation names~{ ~S~}"
 878                   deprecated-names)))
 879   (values (intersection '(:compile-toplevel compile)
 880                         situations)
 881           (intersection '(:load-toplevel load) situations)
 882           (intersection '(:execute eval) situations)))
 883
 884
 885 ;;; utilities for extracting COMPONENTs of FUNCTIONALs
 886 (defun functional-components (f)
 887   (declare (type functional f))
 888   (etypecase f
 889     (clambda (list (lambda-component f)))
 890     (optional-dispatch (let ((result nil))
 891                          (flet ((maybe-frob (maybe-clambda)
 892                                   (when (and maybe-clambda
 893                                              (promise-ready-p maybe-clambda))
 894                                     (pushnew (lambda-component
 895                                               (force maybe-clambda))
 896                                              result))))
 897                            (map nil #'maybe-frob (optional-dispatch-entry-points f))
 898                            (maybe-frob (optional-dispatch-more-entry f))
 899                            (maybe-frob (optional-dispatch-main-entry f)))
 900                          result))))
 901
 902 (defun make-functional-from-toplevel-lambda (definition
 903                                              &key
 904                                              name
 905                                              (path
 906                                               ;; I'd thought NIL should
 907                                               ;; work, but it doesn't.
 908                                               ;; -- WHN 2001-09-20
 909                                               (missing-arg)))
 910   (let* ((*current-path* path)
 911          (component (make-empty-component))
 912          (*current-component* component))
 913     (setf (component-name component)
 914           (debug-namify "~S initial component" name))
 915     (setf (component-kind component) :initial)
 916     (let* ((locall-fun (ir1-convert-lambdalike
 917                         definition
 918                         :debug-name (debug-namify "top level local call ~S"
 919                                                   name)
 920                         ;; KLUDGE: we do this so that we get to have
 921                         ;; nice debug returnness in functions defined
 922                         ;; from the REPL
 923                         :allow-debug-catch-tag t))
 924            (fun (ir1-convert-lambda (make-xep-lambda-expression locall-fun)
 925                                     :source-name (or name '.anonymous.)
 926                                     :debug-name (unless name
 927                                                   "top level form"))))
 928       (when name
 929         (assert-global-function-definition-type name locall-fun))
 930       (setf (functional-entry-fun fun) locall-fun
 931             (functional-kind fun) :external
 932             (functional-has-external-references-p fun) t)
 933       fun)))
 934
 935 ;;; Compile LAMBDA-EXPRESSION into *COMPILE-OBJECT*, returning a
 936 ;;; description of the result.
 937 ;;;   * If *COMPILE-OBJECT* is a CORE-OBJECT, then write the function
 938 ;;;     into core and return the compiled FUNCTION value.
 939 ;;;   * If *COMPILE-OBJECT* is a fasl file, then write the function
 940 ;;;     into the fasl file and return a dump handle.
 941 ;;;
 942 ;;; If NAME is provided, then we try to use it as the name of the
 943 ;;; function for debugging/diagnostic information.
 944 (defun %compile (lambda-expression
 945                  *compile-object*
 946                  &key
 947                  name
 948                  (path
 949                   ;; This magical idiom seems to be the appropriate
 950                   ;; path for compiling standalone LAMBDAs, judging
 951                   ;; from the CMU CL code and experiment, so it's a
 952                   ;; nice default for things where we don't have a
 953                   ;; real source path (as in e.g. inside CL:COMPILE).
 954                   '(original-source-start 0 0)))
 955   (when name
 956     (legal-fun-name-or-type-error name))
 957   (let* ((*lexenv* (make-lexenv :policy *policy*))
 958          (fun (make-functional-from-toplevel-lambda lambda-expression
 959                                                     :name name
 960                                                     :path path)))
 961
 962     ;; FIXME: The compile-it code from here on is sort of a
 963     ;; twisted version of the code in COMPILE-TOPLEVEL. It'd be
 964     ;; better to find a way to share the code there; or
 965     ;; alternatively, to use this code to replace the code there.
 966     ;; (The second alternative might be pretty easy if we used
 967     ;; the :LOCALL-ONLY option to IR1-FOR-LAMBDA. Then maybe the
 968     ;; whole FUNCTIONAL-KIND=:TOPLEVEL case could go away..)
 969
 970     (locall-analyze-clambdas-until-done (list fun))
 971
 972     (multiple-value-bind (components-from-dfo top-components hairy-top)
 973         (find-initial-dfo (list fun))
 974
 975       (let ((*all-components* (append components-from-dfo top-components)))
 976         ;; FIXME: This is more monkey see monkey do based on CMU CL
 977         ;; code. If anyone figures out why to only prescan HAIRY-TOP
 978         ;; and TOP-COMPONENTS here, instead of *ALL-COMPONENTS* or
 979         ;; some other combination of results from FIND-INITIAL-VALUES,
 980         ;; it'd be good to explain it.
 981         (mapc #'preallocate-physenvs-for-toplevelish-lambdas hairy-top)
 982         (mapc #'preallocate-physenvs-for-toplevelish-lambdas top-components)
 983         (dolist (component-from-dfo components-from-dfo)
 984           (compile-component component-from-dfo)
 985           (replace-toplevel-xeps component-from-dfo)))
 986
 987       (let ((entry-table (etypecase *compile-object*
 988                            (fasl-output (fasl-output-entry-table
 989                                          *compile-object*))
 990                            (core-object (core-object-entry-table
 991                                          *compile-object*)))))
 992         (multiple-value-bind (result found-p)
 993             (gethash (leaf-info fun) entry-table)
 994           (aver found-p)
 995           (prog1
 996               result
 997             ;; KLUDGE: This code duplicates some other code in this
 998             ;; file. In the great reorganzation, the flow of program
 999             ;; logic changed from the original CMUCL model, and that
1000             ;; path (as of sbcl-0.7.5 in SUB-COMPILE-FILE) was no
1001             ;; longer followed for CORE-OBJECTS, leading to BUG
1002             ;; 156. This place is transparently not the right one for
1003             ;; this code, but I don't have a clear enough overview of
1004             ;; the compiler to know how to rearrange it all so that
1005             ;; this operation fits in nicely, and it was blocking
1006             ;; reimplementation of (DECLAIM (INLINE FOO)) (MACROLET
1007             ;; ((..)) (DEFUN FOO ...))
1008             ;;
1009             ;; FIXME: This KLUDGE doesn't solve all the problem in an
1010             ;; ideal way, as (1) definitions typed in at the REPL
1011             ;; without an INLINE declaration will give a NULL
1012             ;; FUNCTION-LAMBDA-EXPRESSION (allowable, but not ideal)
1013             ;; and (2) INLINE declarations will yield a
1014             ;; FUNCTION-LAMBDA-EXPRESSION headed by
1015             ;; SB-C:LAMBDA-WITH-LEXENV, even for null LEXENV.  -- CSR,
1016             ;; 2002-07-02
1017             ;;
1018             ;; (2) is probably fairly easy to fix -- it is, after all,
1019             ;; a matter of list manipulation (or possibly of teaching
1020             ;; CL:FUNCTION about SB-C:LAMBDA-WITH-LEXENV).  (1) is
1021             ;; significantly harder, as the association between
1022             ;; function object and source is a tricky one.
1023             ;;
1024             ;; FUNCTION-LAMBDA-EXPRESSION "works" (i.e. returns a
1025             ;; non-NULL list) when the function in question has been
1026             ;; compiled by (COMPILE <x> '(LAMBDA ...)); it does not
1027             ;; work when it has been compiled as part of the top-level
1028             ;; EVAL strategy of compiling everything inside (LAMBDA ()
1029             ;; ...).  -- CSR, 2002-11-02
1030             (when (core-object-p *compile-object*)
1031               (fix-core-source-info *source-info* *compile-object* result))
1032
1033             (mapc #'clear-ir1-info components-from-dfo)
1034             (clear-stuff)))))))
1035
1036 (defun process-toplevel-cold-fset (name lambda-expression path)
1037   (unless (producing-fasl-file)
1038     (error "can't COLD-FSET except in a fasl file"))
1039   (legal-fun-name-or-type-error name)
1040   (fasl-dump-cold-fset name
1041                        (%compile lambda-expression
1042                                  *compile-object*
1043                                  :name name
1044                                  :path path)
1045                        *compile-object*)
1046   (values))
1047
1048 ;;; Process a top level FORM with the specified source PATH.
1049 ;;;  * If this is a magic top level form, then do stuff.
1050 ;;;  * If this is a macro, then expand it.
1051 ;;;  * Otherwise, just compile it.
1052 ;;;
1053 ;;; COMPILE-TIME-TOO is as defined in ANSI
1054 ;;; "3.2.3.1 Processing of Top Level Forms".
1055 (defun process-toplevel-form (form path compile-time-too)
1056
1057   (declare (list path))
1058
1059   (catch 'process-toplevel-form-error-abort
1060     (let* ((path (or (gethash form *source-paths*) (cons form path)))
1061            (*compiler-error-bailout*
1062             (lambda ()
1063               (convert-and-maybe-compile
1064                `(error 'simple-program-error
1065                  :format-control "execution of a form compiled with errors:~% ~S"
1066                  :format-arguments (list ',form))
1067                path)
1068               (throw 'process-toplevel-form-error-abort nil))))
1069
1070       (flet ((default-processor (form)
1071                ;; When we're cross-compiling, consider: what should we
1072                ;; do when we hit e.g.
1073                ;;   (EVAL-WHEN (:COMPILE-TOPLEVEL)
1074                ;;     (DEFUN FOO (X) (+ 7 X)))?
1075                ;; DEFUN has a macro definition in the cross-compiler,
1076                ;; and a different macro definition in the target
1077                ;; compiler. The only sensible thing is to use the
1078                ;; target compiler's macro definition, since the
1079                ;; cross-compiler's macro is in general into target
1080                ;; functions which can't meaningfully be executed at
1081                ;; cross-compilation time. So make sure we do the EVAL
1082                ;; here, before we macroexpand.
1083                ;;
1084                ;; Then things get even dicier with something like
1085                ;;   (DEFCONSTANT-EQX SB!XC:LAMBDA-LIST-KEYWORDS ..)
1086                ;; where we have to make sure that we don't uncross
1087                ;; the SB!XC: prefix before we do EVAL, because otherwise
1088                ;; we'd be trying to redefine the cross-compilation host's
1089                ;; constants.
1090                ;;
1091                ;; (Isn't it fun to cross-compile Common Lisp?:-)
1092                #+sb-xc-host
1093                (progn
1094                  (when compile-time-too
1095                    (eval form)) ; letting xc host EVAL do its own macroexpansion
1096                  (let* (;; (We uncross the operator name because things
1097                         ;; like SB!XC:DEFCONSTANT and SB!XC:DEFTYPE
1098                         ;; should be equivalent to their CL: counterparts
1099                         ;; when being compiled as target code. We leave
1100                         ;; the rest of the form uncrossed because macros
1101                         ;; might yet expand into EVAL-WHEN stuff, and
1102                         ;; things inside EVAL-WHEN can't be uncrossed
1103                         ;; until after we've EVALed them in the
1104                         ;; cross-compilation host.)
1105                         (slightly-uncrossed (cons (uncross (first form))
1106                                                   (rest form)))
1107                         (expanded (preprocessor-macroexpand-1
1108                                    slightly-uncrossed)))
1109                    (if (eq expanded slightly-uncrossed)
1110                        ;; (Now that we're no longer processing toplevel
1111                        ;; forms, and hence no longer need to worry about
1112                        ;; EVAL-WHEN, we can uncross everything.)
1113                        (convert-and-maybe-compile expanded path)
1114                        ;; (We have to demote COMPILE-TIME-TOO to NIL
1115                        ;; here, no matter what it was before, since
1116                        ;; otherwise we'd tend to EVAL subforms more than
1117                        ;; once, because of WHEN COMPILE-TIME-TOO form
1118                        ;; above.)
1119                        (process-toplevel-form expanded path nil))))
1120                ;; When we're not cross-compiling, we only need to
1121                ;; macroexpand once, so we can follow the 1-thru-6
1122                ;; sequence of steps in ANSI's "3.2.3.1 Processing of
1123                ;; Top Level Forms".
1124                #-sb-xc-host
1125                (let ((expanded (preprocessor-macroexpand-1 form)))
1126                  (cond ((eq expanded form)
1127                         (when compile-time-too
1128                           (eval-in-lexenv form *lexenv*))
1129                         (convert-and-maybe-compile form path))
1130                        (t
1131                         (process-toplevel-form expanded
1132                                                path
1133                                                compile-time-too))))))
1134         (if (atom form)
1135             #+sb-xc-host
1136             ;; (There are no xc EVAL-WHEN issues in the ATOM case until
1137             ;; (1) SBCL gets smart enough to handle global
1138             ;; DEFINE-SYMBOL-MACRO or SYMBOL-MACROLET and (2) SBCL
1139             ;; implementors start using symbol macros in a way which
1140             ;; interacts with SB-XC/CL distinction.)
1141             (convert-and-maybe-compile form path)
1142             #-sb-xc-host
1143             (default-processor form)
1144             (flet ((need-at-least-one-arg (form)
1145                      (unless (cdr form)
1146                        (compiler-error "~S form is too short: ~S"
1147                                        (car form)
1148                                        form))))
1149               (case (car form)
1150                 ;; In the cross-compiler, top level COLD-FSET arranges
1151                 ;; for static linking at cold init time.
1152                 #+sb-xc-host
1153                 ((cold-fset)
1154                  (aver (not compile-time-too))
1155                  (destructuring-bind (cold-fset fun-name lambda-expression) form
1156                    (declare (ignore cold-fset))
1157                    (process-toplevel-cold-fset fun-name
1158                                                lambda-expression
1159                                                path)))
1160                 ((eval-when macrolet symbol-macrolet);things w/ 1 arg before body
1161                  (need-at-least-one-arg form)
1162                  (destructuring-bind (special-operator magic &rest body) form
1163                    (ecase special-operator
1164                      ((eval-when)
1165                       ;; CT, LT, and E here are as in Figure 3-7 of ANSI
1166                       ;; "3.2.3.1 Processing of Top Level Forms".
1167                       (multiple-value-bind (ct lt e)
1168                           (parse-eval-when-situations magic)
1169                         (let ((new-compile-time-too (or ct
1170                                                         (and compile-time-too
1171                                                              e))))
1172                           (cond (lt (process-toplevel-progn
1173                                      body path new-compile-time-too))
1174                                 (new-compile-time-too (eval-in-lexenv
1175                                                        `(progn ,@body)
1176                                                        *lexenv*))))))
1177                      ((macrolet)
1178                       (funcall-in-macrolet-lexenv
1179                        magic
1180                        (lambda (&key funs)
1181                          (declare (ignore funs))
1182                          (process-toplevel-locally body
1183                                                    path
1184                                                    compile-time-too))
1185                        :compile))
1186                      ((symbol-macrolet)
1187                       (funcall-in-symbol-macrolet-lexenv
1188                        magic
1189                        (lambda (&key vars)
1190                          (process-toplevel-locally body
1191                                                    path
1192                                                    compile-time-too
1193                                                    :vars vars))
1194                        :compile)))))
1195                 ((locally)
1196                  (process-toplevel-locally (rest form) path compile-time-too))
1197                 ((progn)
1198                  (process-toplevel-progn (rest form) path compile-time-too))
1199                 (t (default-processor form))))))))
1200
1201   (values))
1202 \f
1203 ;;;; load time value support
1204 ;;;;
1205 ;;;; (See EMIT-MAKE-LOAD-FORM.)
1206
1207 ;;; Return T if we are currently producing a fasl file and hence
1208 ;;; constants need to be dumped carefully.
1209 (defun producing-fasl-file ()
1210   (fasl-output-p *compile-object*))
1211
1212 ;;; Compile FORM and arrange for it to be called at load-time. Return
1213 ;;; the dumper handle and our best guess at the type of the object.
1214 (defun compile-load-time-value (form)
1215   (let ((lambda (compile-load-time-stuff form t)))
1216     (values
1217      (fasl-dump-load-time-value-lambda lambda *compile-object*)
1218      (let ((type (leaf-type lambda)))
1219        (if (fun-type-p type)
1220            (single-value-type (fun-type-returns type))
1221            *wild-type*)))))
1222
1223 ;;; Compile the FORMS and arrange for them to be called (for effect,
1224 ;;; not value) at load time.
1225 (defun compile-make-load-form-init-forms (forms)
1226   (let ((lambda (compile-load-time-stuff `(progn ,@forms) nil)))
1227     (fasl-dump-toplevel-lambda-call lambda *compile-object*)))
1228
1229 ;;; Do the actual work of COMPILE-LOAD-TIME-VALUE or
1230 ;;; COMPILE-MAKE-LOAD-FORM-INIT-FORMS.
1231 (defun compile-load-time-stuff (form for-value)
1232   (with-ir1-namespace
1233    (let* ((*lexenv* (make-null-lexenv))
1234           (lambda (ir1-toplevel form *current-path* for-value)))
1235      (compile-toplevel (list lambda) t)
1236      lambda)))
1237
1238 ;;; This is called by COMPILE-TOPLEVEL when it was passed T for
1239 ;;; LOAD-TIME-VALUE-P (which happens in COMPILE-LOAD-TIME-STUFF). We
1240 ;;; don't try to combine this component with anything else and frob
1241 ;;; the name. If not in a :TOPLEVEL component, then don't bother
1242 ;;; compiling, because it was merged with a run-time component.
1243 (defun compile-load-time-value-lambda (lambdas)
1244   (aver (null (cdr lambdas)))
1245   (let* ((lambda (car lambdas))
1246          (component (lambda-component lambda)))
1247     (when (eql (component-kind component) :toplevel)
1248       (setf (component-name component) (leaf-debug-name lambda))
1249       (compile-component component)
1250       (clear-ir1-info component))))
1251 \f
1252 ;;;; COMPILE-FILE
1253
1254 (defun object-call-toplevel-lambda (tll)
1255   (declare (type functional tll))
1256   (let ((object *compile-object*))
1257     (etypecase object
1258       (fasl-output (fasl-dump-toplevel-lambda-call tll object))
1259       (core-object (core-call-toplevel-lambda      tll object))
1260       (null))))
1261
1262 ;;; Smash LAMBDAS into a single component, compile it, and arrange for
1263 ;;; the resulting function to be called.
1264 (defun sub-compile-toplevel-lambdas (lambdas)
1265   (declare (list lambdas))
1266   (when lambdas
1267     (multiple-value-bind (component tll) (merge-toplevel-lambdas lambdas)
1268       (compile-component component)
1269       (clear-ir1-info component)
1270       (object-call-toplevel-lambda tll)))
1271   (values))
1272
1273 ;;; Compile top level code and call the top level lambdas. We pick off
1274 ;;; top level lambdas in non-top-level components here, calling
1275 ;;; SUB-c-t-l-l on each subsequence of normal top level lambdas.
1276 (defun compile-toplevel-lambdas (lambdas)
1277   (declare (list lambdas))
1278   (let ((len (length lambdas)))
1279     (flet ((loser (start)
1280              (or (position-if (lambda (x)
1281                                 (not (eq (component-kind
1282                                           (node-component (lambda-bind x)))
1283                                          :toplevel)))
1284                               lambdas
1285                               ;; this used to read ":start start", but
1286                               ;; start can be greater than len, which
1287                               ;; is an error according to ANSI - CSR,
1288                               ;; 2002-04-25
1289                               :start (min start len))
1290                  len)))
1291       (do* ((start 0 (1+ loser))
1292             (loser (loser start) (loser start)))
1293            ((>= start len))
1294         (sub-compile-toplevel-lambdas (subseq lambdas start loser))
1295         (unless (= loser len)
1296           (object-call-toplevel-lambda (elt lambdas loser))))))
1297   (values))
1298
1299 ;;; Compile LAMBDAS (a list of CLAMBDAs for top level forms) into the
1300 ;;; object file.
1301 ;;;
1302 ;;; LOAD-TIME-VALUE-P seems to control whether it's MAKE-LOAD-FORM and
1303 ;;; COMPILE-LOAD-TIME-VALUE stuff. -- WHN 20000201
1304 (defun compile-toplevel (lambdas load-time-value-p)
1305   (declare (list lambdas))
1306
1307   (maybe-mumble "locall ")
1308   (locall-analyze-clambdas-until-done lambdas)
1309
1310   (maybe-mumble "IDFO ")
1311   (multiple-value-bind (components top-components hairy-top)
1312       (find-initial-dfo lambdas)
1313     (let ((*all-components* (append components top-components)))
1314       (when *check-consistency*
1315         (maybe-mumble "[check]~%")
1316         (check-ir1-consistency *all-components*))
1317
1318       (dolist (component (append hairy-top top-components))
1319         (pre-physenv-analyze-toplevel component))
1320
1321       (dolist (component components)
1322         (compile-component component)
1323         (replace-toplevel-xeps component))
1324
1325       (when *check-consistency*
1326         (maybe-mumble "[check]~%")
1327         (check-ir1-consistency *all-components*))
1328
1329       (if load-time-value-p
1330           (compile-load-time-value-lambda lambdas)
1331           (compile-toplevel-lambdas lambdas))
1332
1333       (mapc #'clear-ir1-info components)
1334       (clear-stuff)))
1335   (values))
1336
1337 ;;; Actually compile any stuff that has been queued up for block
1338 ;;; compilation.
1339 (defun finish-block-compilation ()
1340   (when *block-compile*
1341     (when *toplevel-lambdas*
1342       (compile-toplevel (nreverse *toplevel-lambdas*) nil)
1343       (setq *toplevel-lambdas* ()))
1344     (setq *block-compile* nil)
1345     (setq *entry-points* nil)))
1346
1347 ;;; Read all forms from INFO and compile them, with output to OBJECT.
1348 ;;; Return (VALUES NIL WARNINGS-P FAILURE-P).
1349 (defun sub-compile-file (info)
1350   (declare (type source-info info))
1351   (let ((*package* (sane-package))
1352         (*readtable* *readtable*)
1353         (sb!xc:*compile-file-pathname* nil) ; really bound in
1354         (sb!xc:*compile-file-truename* nil) ; SUB-SUB-COMPILE-FILE
1355
1356         (*policy* *policy*)
1357         (*lexenv* (make-null-lexenv))
1358         (*block-compile* *block-compile-arg*)
1359         (*source-info* info)
1360         (*toplevel-lambdas* ())
1361         (*fun-names-in-this-file* ())
1362         (*compiler-error-bailout*
1363          (lambda ()
1364            (compiler-mumble "~2&; fatal error, aborting compilation~%")
1365            (return-from sub-compile-file (values nil t t))))
1366         (*current-path* nil)
1367         (*last-source-context* nil)
1368         (*last-original-source* nil)
1369         (*last-source-form* nil)
1370         (*last-format-string* nil)
1371         (*last-format-args* nil)
1372         (*last-message-count* 0)
1373         ;; FIXME: Do we need this rebinding here? It's a literal
1374         ;; translation of the old CMU CL rebinding to
1375         ;; (OR *BACKEND-INFO-ENVIRONMENT* *INFO-ENVIRONMENT*),
1376         ;; and it's not obvious whether the rebinding to itself is
1377         ;; needed that SBCL doesn't need *BACKEND-INFO-ENVIRONMENT*.
1378         (*info-environment* *info-environment*)
1379         (*gensym-counter* 0))
1380     (handler-case
1381         (with-compilation-values
1382          (sb!xc:with-compilation-unit ()
1383            (clear-stuff)
1384
1385            (sub-sub-compile-file info)
1386
1387            (finish-block-compilation)
1388            (let ((object *compile-object*))
1389              (etypecase object
1390                (fasl-output (fasl-dump-source-info info object))
1391                (core-object (fix-core-source-info info object))
1392                (null)))
1393            nil))
1394       ;; Some errors are sufficiently bewildering that we just fail
1395       ;; immediately, without trying to recover and compile more of
1396       ;; the input file.
1397       (input-error-in-compile-file (condition)
1398        (format *error-output*
1399                "~@<compilation aborted because of input error: ~2I~_~A~:>"
1400                condition)
1401        (values nil t t)))))
1402
1403 ;;; Return a pathname for the named file. The file must exist.
1404 (defun verify-source-file (pathname-designator)
1405   (let* ((pathname (pathname pathname-designator))
1406          (default-host (make-pathname :host (pathname-host pathname))))
1407     (flet ((try-with-type (path type error-p)
1408              (let ((new (merge-pathnames
1409                          path (make-pathname :type type
1410                                              :defaults default-host))))
1411                (if (probe-file new)
1412                    new
1413                    (and error-p (truename new))))))
1414       (cond ((typep pathname 'logical-pathname)
1415              (try-with-type pathname "LISP" t))
1416             ((probe-file pathname) pathname)
1417             ((try-with-type pathname "lisp"  nil))
1418             ((try-with-type pathname "lisp"  t))))))
1419
1420 (defun elapsed-time-to-string (tsec)
1421   (multiple-value-bind (tmin sec) (truncate tsec 60)
1422     (multiple-value-bind (thr min) (truncate tmin 60)
1423       (format nil "~D:~2,'0D:~2,'0D" thr min sec))))
1424
1425 ;;; Print some junk at the beginning and end of compilation.
1426 (defun start-error-output (source-info)
1427   (declare (type source-info source-info))
1428   (let ((file-info (source-info-file-info source-info)))
1429     (compiler-mumble "~&; compiling file ~S (written ~A):~%"
1430                      (namestring (file-info-name file-info))
1431                      (sb!int:format-universal-time nil
1432                                                    (file-info-write-date
1433                                                     file-info)
1434                                                    :style :government
1435                                                    :print-weekday nil
1436                                                    :print-timezone nil)))
1437   (values))
1438 (defun finish-error-output (source-info won)
1439   (declare (type source-info source-info))
1440   (compiler-mumble "~&; compilation ~:[aborted after~;finished in~] ~A~&"
1441                    won
1442                    (elapsed-time-to-string
1443                     (- (get-universal-time)
1444                        (source-info-start-time source-info))))
1445   (values))
1446
1447 ;;; Open some files and call SUB-COMPILE-FILE. If something unwinds
1448 ;;; out of the compile, then abort the writing of the output file, so
1449 ;;; that we don't overwrite it with known garbage.
1450 (defun sb!xc:compile-file
1451     (input-file
1452      &key
1453
1454      ;; ANSI options
1455      (output-file (cfp-output-file-default input-file))
1456      ;; FIXME: ANSI doesn't seem to say anything about
1457      ;; *COMPILE-VERBOSE* and *COMPILE-PRINT* being rebound by this
1458      ;; function..
1459      ((:verbose sb!xc:*compile-verbose*) sb!xc:*compile-verbose*)
1460      ((:print sb!xc:*compile-print*) sb!xc:*compile-print*)
1461      (external-format :default)
1462
1463      ;; extensions
1464      (trace-file nil)
1465      ((:block-compile *block-compile-arg*) nil))
1466
1467   #!+sb-doc
1468   "Compile INPUT-FILE, producing a corresponding fasl file and returning
1469    its filename. Besides the ANSI &KEY arguments :OUTPUT-FILE, :VERBOSE,
1470    :PRINT, and :EXTERNAL-FORMAT,the following extensions are supported:
1471      :TRACE-FILE
1472         If given, internal data structures are dumped to the specified
1473         file, or if a value of T is given, to a file of *.trace type
1474         derived from the input file name.
1475    Also, as a workaround for vaguely-non-ANSI behavior, the :BLOCK-COMPILE
1476    argument is quasi-supported, to determine whether multiple
1477    functions are compiled together as a unit, resolving function
1478    references at compile time. NIL means that global function names
1479    are never resolved at compilation time. Currently NIL is the
1480    default behavior, because although section 3.2.2.3, \"Semantic
1481    Constraints\", of the ANSI spec allows this behavior under all
1482    circumstances, the compiler's runtime scales badly when it
1483    tries to do this for large files. If/when this performance
1484    problem is fixed, the block compilation default behavior will
1485    probably be made dependent on the SPEED and COMPILATION-SPEED
1486    optimization values, and the :BLOCK-COMPILE argument will probably
1487    become deprecated."
1488
1489   (unless (eq external-format :default)
1490     (error "Non-:DEFAULT EXTERNAL-FORMAT values are not supported."))
1491   (let* ((fasl-output nil)
1492          (output-file-name nil)
1493          (compile-won nil)
1494          (warnings-p nil)
1495          (failure-p t) ; T in case error keeps this from being set later
1496          (input-pathname (verify-source-file input-file))
1497          (source-info (make-file-source-info input-pathname))
1498          (*compiler-trace-output* nil)) ; might be modified below
1499
1500     (unwind-protect
1501         (progn
1502           (when output-file
1503             (setq output-file-name
1504                   (sb!xc:compile-file-pathname input-file
1505                                                :output-file output-file))
1506             (setq fasl-output
1507                   (open-fasl-output output-file-name
1508                                     (namestring input-pathname))))
1509           (when trace-file
1510             (let* ((default-trace-file-pathname
1511                      (make-pathname :type "trace" :defaults input-pathname))
1512                    (trace-file-pathname
1513                     (if (eql trace-file t)
1514                         default-trace-file-pathname
1515                         (merge-pathnames trace-file
1516                                          default-trace-file-pathname))))
1517               (setf *compiler-trace-output*
1518                     (open trace-file-pathname
1519                           :if-exists :supersede
1520                           :direction :output))))
1521
1522           (when sb!xc:*compile-verbose*
1523             (start-error-output source-info))
1524           (let ((*compile-object* fasl-output)
1525                 dummy)
1526             (multiple-value-setq (dummy warnings-p failure-p)
1527               (sub-compile-file source-info)))
1528           (setq compile-won t))
1529
1530       (close-source-info source-info)
1531
1532       (when fasl-output
1533         (close-fasl-output fasl-output (not compile-won))
1534         (setq output-file-name
1535               (pathname (fasl-output-stream fasl-output)))
1536         (when (and compile-won sb!xc:*compile-verbose*)
1537           (compiler-mumble "~2&; ~A written~%" (namestring output-file-name))))
1538
1539       (when sb!xc:*compile-verbose*
1540         (finish-error-output source-info compile-won))
1541
1542       (when *compiler-trace-output*
1543         (close *compiler-trace-output*)))
1544
1545     (values (if output-file
1546                 ;; Hack around filesystem race condition...
1547                 (or (probe-file output-file-name) output-file-name)
1548                 nil)
1549             warnings-p
1550             failure-p)))
1551 \f
1552 ;;; a helper function for COMPILE-FILE-PATHNAME: the default for
1553 ;;; the OUTPUT-FILE argument
1554 ;;;
1555 ;;; ANSI: The defaults for the OUTPUT-FILE are taken from the pathname
1556 ;;; that results from merging the INPUT-FILE with the value of
1557 ;;; *DEFAULT-PATHNAME-DEFAULTS*, except that the type component should
1558 ;;; default to the appropriate implementation-defined default type for
1559 ;;; compiled files.
1560 (defun cfp-output-file-default (input-file)
1561   (let* ((defaults (merge-pathnames input-file *default-pathname-defaults*))
1562          (retyped (make-pathname :type *fasl-file-type* :defaults defaults)))
1563     retyped))
1564
1565 ;;; KLUDGE: Part of the ANSI spec for this seems contradictory:
1566 ;;;   If INPUT-FILE is a logical pathname and OUTPUT-FILE is unsupplied,
1567 ;;;   the result is a logical pathname. If INPUT-FILE is a logical
1568 ;;;   pathname, it is translated into a physical pathname as if by
1569 ;;;   calling TRANSLATE-LOGICAL-PATHNAME.
1570 ;;; So I haven't really tried to make this precisely ANSI-compatible
1571 ;;; at the level of e.g. whether it returns logical pathname or a
1572 ;;; physical pathname. Patches to make it more correct are welcome.
1573 ;;; -- WHN 2000-12-09
1574 (defun sb!xc:compile-file-pathname (input-file
1575                                     &key
1576                                     (output-file (cfp-output-file-default
1577                                                   input-file))
1578                                     &allow-other-keys)
1579   #!+sb-doc
1580   "Return a pathname describing what file COMPILE-FILE would write to given
1581    these arguments."
1582   (merge-pathnames output-file (merge-pathnames input-file)))
1583 \f
1584 ;;;; MAKE-LOAD-FORM stuff
1585
1586 ;;; The entry point for MAKE-LOAD-FORM support. When IR1 conversion
1587 ;;; finds a constant structure, it invokes this to arrange for proper
1588 ;;; dumping. If it turns out that the constant has already been
1589 ;;; dumped, then we don't need to do anything.
1590 ;;;
1591 ;;; If the constant hasn't been dumped, then we check to see whether
1592 ;;; we are in the process of creating it. We detect this by
1593 ;;; maintaining the special *CONSTANTS-BEING-CREATED* as a list of all
1594 ;;; the constants we are in the process of creating. Actually, each
1595 ;;; entry is a list of the constant and any init forms that need to be
1596 ;;; processed on behalf of that constant.
1597 ;;;
1598 ;;; It's not necessarily an error for this to happen. If we are
1599 ;;; processing the init form for some object that showed up *after*
1600 ;;; the original reference to this constant, then we just need to
1601 ;;; defer the processing of that init form. To detect this, we
1602 ;;; maintain *CONSTANTS-CREATED-SINCE-LAST-INIT* as a list of the
1603 ;;; constants created since the last time we started processing an
1604 ;;; init form. If the constant passed to emit-make-load-form shows up
1605 ;;; in this list, then there is a circular chain through creation
1606 ;;; forms, which is an error.
1607 ;;;
1608 ;;; If there is some intervening init form, then we blow out of
1609 ;;; processing it by throwing to the tag PENDING-INIT. The value we
1610 ;;; throw is the entry from *CONSTANTS-BEING-CREATED*. This is so the
1611 ;;; offending init form can be tacked onto the init forms for the
1612 ;;; circular object.
1613 ;;;
1614 ;;; If the constant doesn't show up in *CONSTANTS-BEING-CREATED*, then
1615 ;;; we have to create it. We call MAKE-LOAD-FORM and check to see
1616 ;;; whether the creation form is the magic value
1617 ;;; :SB-JUST-DUMP-IT-NORMALLY. If it is, then we don't do anything. The
1618 ;;; dumper will eventually get its hands on the object and use the
1619 ;;; normal structure dumping noise on it.
1620 ;;;
1621 ;;; Otherwise, we bind *CONSTANTS-BEING-CREATED* and
1622 ;;; *CONSTANTS-CREATED-SINCE- LAST-INIT* and compile the creation form
1623 ;;; much the way LOAD-TIME-VALUE does. When this finishes, we tell the
1624 ;;; dumper to use that result instead whenever it sees this constant.
1625 ;;;
1626 ;;; Now we try to compile the init form. We bind
1627 ;;; *CONSTANTS-CREATED-SINCE-LAST-INIT* to NIL and compile the init
1628 ;;; form (and any init forms that were added because of circularity
1629 ;;; detection). If this works, great. If not, we add the init forms to
1630 ;;; the init forms for the object that caused the problems and let it
1631 ;;; deal with it.
1632 (defvar *constants-being-created* nil)
1633 (defvar *constants-created-since-last-init* nil)
1634 ;;; FIXME: Shouldn't these^ variables be unbound outside LET forms?
1635 (defun emit-make-load-form (constant)
1636   (aver (fasl-output-p *compile-object*))
1637   (unless (or (fasl-constant-already-dumped-p constant *compile-object*)
1638               ;; KLUDGE: This special hack is because I was too lazy
1639               ;; to rework DEF!STRUCT so that the MAKE-LOAD-FORM
1640               ;; function of LAYOUT returns nontrivial forms when
1641               ;; building the cross-compiler but :IGNORE-IT when
1642               ;; cross-compiling or running under the target Lisp. --
1643               ;; WHN 19990914
1644               #+sb-xc-host (typep constant 'layout))
1645     (let ((circular-ref (assoc constant *constants-being-created* :test #'eq)))
1646       (when circular-ref
1647         (when (find constant *constants-created-since-last-init* :test #'eq)
1648           (throw constant t))
1649         (throw 'pending-init circular-ref)))
1650     (multiple-value-bind (creation-form init-form)
1651         (handler-case
1652             (sb!xc:make-load-form constant (make-null-lexenv))
1653           (error (condition)
1654                  (compiler-error "(while making load form for ~S)~%~A"
1655                                  constant
1656                                  condition)))
1657       (case creation-form
1658         (:sb-just-dump-it-normally
1659          (fasl-validate-structure constant *compile-object*)
1660          t)
1661         (:ignore-it
1662          nil)
1663         (t
1664          (when (fasl-constant-already-dumped-p constant *compile-object*)
1665            (return-from emit-make-load-form nil))
1666          (let* ((name (let ((*print-level* 1) (*print-length* 2))
1667                         (with-output-to-string (stream)
1668                           (write constant :stream stream))))
1669                 (info (if init-form
1670                           (list constant name init-form)
1671                           (list constant))))
1672            (let ((*constants-being-created*
1673                   (cons info *constants-being-created*))
1674                  (*constants-created-since-last-init*
1675                   (cons constant *constants-created-since-last-init*)))
1676              (when
1677                  (catch constant
1678                    (fasl-note-handle-for-constant
1679                     constant
1680                     (compile-load-time-value
1681                      creation-form)
1682                     *compile-object*)
1683                    nil)
1684                (compiler-error "circular references in creation form for ~S"
1685                                constant)))
1686            (when (cdr info)
1687              (let* ((*constants-created-since-last-init* nil)
1688                     (circular-ref
1689                      (catch 'pending-init
1690                        (loop for (name form) on (cdr info) by #'cddr
1691                          collect name into names
1692                          collect form into forms
1693                          finally (compile-make-load-form-init-forms forms))
1694                        nil)))
1695                (when circular-ref
1696                  (setf (cdr circular-ref)
1697                        (append (cdr circular-ref) (cdr info))))))))))))
1698
1699 \f
1700 ;;;; Host compile time definitions
1701 #+sb-xc-host
1702 (defun compile-in-lexenv (name lambda lexenv)
1703   (declare (ignore lexenv))
1704   (compile name lambda))
1705
1706 #+sb-xc-host
1707 (defun eval-in-lexenv (form lexenv)
1708   (declare (ignore lexenv))
1709   (eval form))