src/compiler/main.lisp

   1 ;;;; the top level interfaces to the compiler, plus some other
   2 ;;;; compiler-related stuff (e.g. CL:CALL-ARGUMENTS-LIMIT) which
   3 ;;;; doesn't obviously belong anywhere else
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15
  16 ;;; FIXME: Doesn't this belong somewhere else, like early-c.lisp?
  17 (declaim (special *constants* *free-vars* *component-being-compiled*
  18                   *code-vector* *next-location* *result-fixups*
  19                   *free-funs* *source-paths*
  20                   *seen-blocks* *seen-funs* *list-conflicts-table*
  21                   *continuation-number* *continuation-numbers*
  22                   *number-continuations* *tn-id* *tn-ids* *id-tns*
  23                   *label-ids* *label-id* *id-labels*
  24                   *undefined-warnings* *compiler-error-count*
  25                   *compiler-warning-count* *compiler-style-warning-count*
  26                   *compiler-note-count*
  27                   *compiler-error-bailout*
  28                   #!+sb-show *compiler-trace-output*
  29                   *last-source-context* *last-original-source*
  30                   *last-source-form* *last-format-string* *last-format-args*
  31                   *last-message-count* *lexenv* *fun-names-in-this-file*
  32                   *allow-instrumenting*))
  33
  34 ;;; Whether call of a function which cannot be defined causes a full
  35 ;;; warning.
  36 (defvar *flame-on-necessarily-undefined-function* nil)
  37
  38 (defvar *check-consistency* nil)
  39 (defvar *all-components*)
  40
  41 ;;; Set to NIL to disable loop analysis for register allocation.
  42 (defvar *loop-analyze* t)
  43
  44 ;;; Bind this to a stream to capture various internal debugging output.
  45 (defvar *compiler-trace-output* nil)
  46
  47 ;;; The current block compilation state. These are initialized to the
  48 ;;; :BLOCK-COMPILE and :ENTRY-POINTS arguments that COMPILE-FILE was
  49 ;;; called with.
  50 ;;;
  51 ;;; *BLOCK-COMPILE-ARG* holds the original value of the :BLOCK-COMPILE
  52 ;;; argument, which overrides any internal declarations.
  53 (defvar *block-compile*)
  54 (defvar *block-compile-arg*)
  55 (declaim (type (member nil t :specified) *block-compile* *block-compile-arg*))
  56 (defvar *entry-points*)
  57 (declaim (list *entry-points*))
  58
  59 ;;; When block compiling, used by PROCESS-FORM to accumulate top level
  60 ;;; lambdas resulting from compiling subforms. (In reverse order.)
  61 (defvar *toplevel-lambdas*)
  62 (declaim (list *toplevel-lambdas*))
  63
  64 (defvar sb!xc:*compile-verbose* t
  65   #!+sb-doc
  66   "The default for the :VERBOSE argument to COMPILE-FILE.")
  67 (defvar sb!xc:*compile-print* t
  68   #!+sb-doc
  69   "The default for the :PRINT argument to COMPILE-FILE.")
  70 (defvar *compile-progress* nil
  71   #!+sb-doc
  72   "When this is true, the compiler prints to *ERROR-OUTPUT* progress
  73   information about the phases of compilation of each function. (This
  74   is useful mainly in large block compilations.)")
  75
  76 (defvar sb!xc:*compile-file-pathname* nil
  77   #!+sb-doc
  78   "The defaulted pathname of the file currently being compiled, or NIL if not
  79   compiling.")
  80 (defvar sb!xc:*compile-file-truename* nil
  81   #!+sb-doc
  82   "The TRUENAME of the file currently being compiled, or NIL if not
  83   compiling.")
  84
  85 (declaim (type (or pathname null)
  86                sb!xc:*compile-file-pathname*
  87                sb!xc:*compile-file-truename*))
  88
  89 ;;; the SOURCE-INFO structure for the current compilation. This is
  90 ;;; null globally to indicate that we aren't currently in any
  91 ;;; identifiable compilation.
  92 (defvar *source-info* nil)
  93
  94 ;;; This is true if we are within a WITH-COMPILATION-UNIT form (which
  95 ;;; normally causes nested uses to be no-ops).
  96 (defvar *in-compilation-unit* nil)
  97
  98 ;;; Count of the number of compilation units dynamically enclosed by
  99 ;;; the current active WITH-COMPILATION-UNIT that were unwound out of.
 100 (defvar *aborted-compilation-unit-count*)
 101
 102 ;;; Mumble conditional on *COMPILE-PROGRESS*.
 103 (defun maybe-mumble (&rest foo)
 104   (when *compile-progress*
 105     (compiler-mumble "~&")
 106     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 107        (apply #'compiler-mumble foo))))
 108
 109 (deftype object () '(or fasl-output core-object null))
 110
 111 (defvar *compile-object* nil)
 112 (declaim (type object *compile-object*))
 113 \f
 114 ;;;; WITH-COMPILATION-UNIT and WITH-COMPILATION-VALUES
 115
 116 (defmacro sb!xc:with-compilation-unit (options &body body)
 117   #!+sb-doc
 118   "WITH-COMPILATION-UNIT ({Key Value}*) Form*
 119   This form affects compilations that take place within its dynamic extent. It
 120   is intended to be wrapped around the compilation of all files in the same
 121   system. These keywords are defined:
 122     :OVERRIDE Boolean-Form
 123         One of the effects of this form is to delay undefined warnings
 124         until the end of the form, instead of giving them at the end of each
 125         compilation. If OVERRIDE is NIL (the default), then the outermost
 126         WITH-COMPILATION-UNIT form grabs the undefined warnings. Specifying
 127         OVERRIDE true causes that form to grab any enclosed warnings, even if
 128         it is enclosed by another WITH-COMPILATION-UNIT."
 129   `(%with-compilation-unit (lambda () ,@body) ,@options))
 130
 131 (defun %with-compilation-unit (fn &key override)
 132   (declare (type function fn))
 133   (let ((succeeded-p nil))
 134     (if (and *in-compilation-unit* (not override))
 135         ;; Inside another WITH-COMPILATION-UNIT, a WITH-COMPILATION-UNIT is
 136         ;; ordinarily (unless OVERRIDE) basically a no-op.
 137         (unwind-protect
 138              (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 139           (unless succeeded-p
 140             (incf *aborted-compilation-unit-count*)))
 141         (let ((*aborted-compilation-unit-count* 0)
 142               (*compiler-error-count* 0)
 143               (*compiler-warning-count* 0)
 144               (*compiler-style-warning-count* 0)
 145               (*compiler-note-count* 0)
 146               (*undefined-warnings* nil)
 147               (*in-compilation-unit* t))
 148           (sb!thread:with-recursive-lock (*big-compiler-lock*)
 149             (handler-bind ((parse-unknown-type
 150                             (lambda (c)
 151                               (note-undefined-reference
 152                                (parse-unknown-type-specifier c)
 153                                :type))))
 154               (unwind-protect
 155                    (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 156                 (unless succeeded-p
 157                   (incf *aborted-compilation-unit-count*))
 158                 (summarize-compilation-unit (not succeeded-p)))))))))
 159
 160 ;;; Is FUN-NAME something that no conforming program can rely on
 161 ;;; defining as a function?
 162 (defun fun-name-reserved-by-ansi-p (fun-name)
 163   (eq (symbol-package (fun-name-block-name fun-name))
 164       *cl-package*))
 165
 166 ;;; This is to be called at the end of a compilation unit. It signals
 167 ;;; any residual warnings about unknown stuff, then prints the total
 168 ;;; error counts. ABORT-P should be true when the compilation unit was
 169 ;;; aborted by throwing out. ABORT-COUNT is the number of dynamically
 170 ;;; enclosed nested compilation units that were aborted.
 171 (defun summarize-compilation-unit (abort-p)
 172   (unless abort-p
 173     (handler-bind ((style-warning #'compiler-style-warning-handler)
 174                    (warning #'compiler-warning-handler))
 175
 176       (let ((undefs (sort *undefined-warnings* #'string<
 177                           :key (lambda (x)
 178                                  (let ((x (undefined-warning-name x)))
 179                                    (if (symbolp x)
 180                                        (symbol-name x)
 181                                        (prin1-to-string x)))))))
 182         (dolist (undef undefs)
 183           (let ((name (undefined-warning-name undef))
 184                 (kind (undefined-warning-kind undef))
 185                 (warnings (undefined-warning-warnings undef))
 186                 (undefined-warning-count (undefined-warning-count undef)))
 187             (dolist (*compiler-error-context* warnings)
 188               (if #-sb-xc-host (and (eq kind :function)
 189                                     (fun-name-reserved-by-ansi-p name)
 190                                     *flame-on-necessarily-undefined-function*)
 191                   #+sb-xc-host nil
 192                   (case name
 193                     ((declare)
 194                      (compiler-warn
 195                       "~@<There is no function named ~S. References to ~S in ~
 196                        some contexts (like starts of blocks) have special ~
 197                        meaning, but here it would have to be a function, ~
 198                        and that shouldn't be right.~:@>"
 199                       name name))
 200                     (t
 201                      (compiler-warn
 202                       "~@<The ~(~A~) ~S is undefined, and its name is ~
 203                        reserved by ANSI CL so that even if it were ~
 204                        defined later, the code doing so would not be ~
 205                        portable.~:@>"
 206                       kind name)))
 207                   (if (eq kind :variable)
 208                       (compiler-warn "undefined ~(~A~): ~S" kind name)
 209                       (compiler-style-warn "undefined ~(~A~): ~S" kind name))))
 210             (let ((warn-count (length warnings)))
 211               (when (and warnings (> undefined-warning-count warn-count))
 212                 (let ((more (- undefined-warning-count warn-count)))
 213                   (if (eq kind :variable)
 214                       (compiler-warn
 215                        "~W more use~:P of undefined ~(~A~) ~S"
 216                        more kind name)
 217                       (compiler-style-warn
 218                        "~W more use~:P of undefined ~(~A~) ~S"
 219                        more kind name)))))))
 220
 221         (dolist (kind '(:variable :function :type))
 222           (let ((summary (mapcar #'undefined-warning-name
 223                                  (remove kind undefs :test #'neq
 224                                          :key #'undefined-warning-kind))))
 225             (when summary
 226               (if (eq kind :variable)
 227                   (compiler-warn
 228                    "~:[This ~(~A~) is~;These ~(~A~)s are~] undefined:~
 229                     ~%  ~{~<~%  ~1:;~S~>~^ ~}"
 230                    (cdr summary) kind summary)
 231                   (compiler-style-warn
 232                    "~:[This ~(~A~) is~;These ~(~A~)s are~] undefined:~
 233                    ~%  ~{~<~%  ~1:;~S~>~^ ~}"
 234                    (cdr summary) kind summary))))))))
 235
 236   (unless (and (not abort-p)
 237                (zerop *aborted-compilation-unit-count*)
 238                (zerop *compiler-error-count*)
 239                (zerop *compiler-warning-count*)
 240                (zerop *compiler-style-warning-count*)
 241                (zerop *compiler-note-count*))
 242     (format *error-output* "~&")
 243     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 244       (compiler-mumble "compilation unit ~:[finished~;aborted~]~
 245                        ~[~:;~:*~&  caught ~W fatal ERROR condition~:P~]~
 246                        ~[~:;~:*~&  caught ~W ERROR condition~:P~]~
 247                        ~[~:;~:*~&  caught ~W WARNING condition~:P~]~
 248                        ~[~:;~:*~&  caught ~W STYLE-WARNING condition~:P~]~
 249                        ~[~:;~:*~&  printed ~W note~:P~]"
 250                        abort-p
 251                        *aborted-compilation-unit-count*
 252                        *compiler-error-count*
 253                        *compiler-warning-count*
 254                        *compiler-style-warning-count*
 255                        *compiler-note-count*)))
 256   (format *error-output* "~&"))
 257
 258 ;;; Evaluate BODY, then return (VALUES BODY-VALUE WARNINGS-P
 259 ;;; FAILURE-P), where BODY-VALUE is the first value of the body, and
 260 ;;; WARNINGS-P and FAILURE-P are as in CL:COMPILE or CL:COMPILE-FILE.
 261 ;;; This also wraps up WITH-IR1-NAMESPACE functionality.
 262 (defmacro with-compilation-values (&body body)
 263   `(with-ir1-namespace
 264     (let ((*warnings-p* nil)
 265           (*failure-p* nil))
 266       (values (progn ,@body)
 267               *warnings-p*
 268               *failure-p*))))
 269 \f
 270 ;;;; component compilation
 271
 272 (defparameter *max-optimize-iterations* 3 ; ARB
 273   #!+sb-doc
 274   "The upper limit on the number of times that we will consecutively do IR1
 275   optimization that doesn't introduce any new code. A finite limit is
 276   necessary, since type inference may take arbitrarily long to converge.")
 277
 278 (defevent ir1-optimize-until-done "IR1-OPTIMIZE-UNTIL-DONE called")
 279 (defevent ir1-optimize-maxed-out "hit *MAX-OPTIMIZE-ITERATIONS* limit")
 280
 281 ;;; Repeatedly optimize COMPONENT until no further optimizations can
 282 ;;; be found or we hit our iteration limit. When we hit the limit, we
 283 ;;; clear the component and block REOPTIMIZE flags to discourage the
 284 ;;; next optimization attempt from pounding on the same code.
 285 (defun ir1-optimize-until-done (component)
 286   (declare (type component component))
 287   (maybe-mumble "opt")
 288   (event ir1-optimize-until-done)
 289   (let ((count 0)
 290         (cleared-reanalyze nil)
 291         (fastp nil))
 292     (loop
 293       (when (component-reanalyze component)
 294         (setq count 0)
 295         (setq cleared-reanalyze t)
 296         (setf (component-reanalyze component) nil))
 297       (setf (component-reoptimize component) nil)
 298       (ir1-optimize component fastp)
 299       (cond ((component-reoptimize component)
 300              (incf count)
 301              (when (and (>= count *max-optimize-iterations*)
 302                         (not (component-reanalyze component))
 303                         (eq (component-reoptimize component) :maybe))
 304                (maybe-mumble "*")
 305                (cond ((retry-delayed-ir1-transforms :optimize)
 306                       (maybe-mumble "+")
 307                       (setq count 0))
 308                      (t
 309                       (event ir1-optimize-maxed-out)
 310                       (setf (component-reoptimize component) nil)
 311                       (do-blocks (block component)
 312                         (setf (block-reoptimize block) nil))
 313                       (return)))))
 314             ((retry-delayed-ir1-transforms :optimize)
 315              (setf count 0)
 316              (maybe-mumble "+"))
 317             (t
 318              (maybe-mumble " ")
 319              (return)))
 320       (setq fastp (>= count *max-optimize-iterations*))
 321       (maybe-mumble (if fastp "-" ".")))
 322     (when cleared-reanalyze
 323       (setf (component-reanalyze component) t)))
 324   (values))
 325
 326 (defparameter *constraint-propagate* t)
 327
 328 ;;; KLUDGE: This was bumped from 5 to 10 in a DTC patch ported by MNA
 329 ;;; from CMU CL into sbcl-0.6.11.44, the same one which allowed IR1
 330 ;;; transforms to be delayed. Either DTC or MNA or both didn't explain
 331 ;;; why, and I don't know what the rationale was. -- WHN 2001-04-28
 332 ;;;
 333 ;;; FIXME: It would be good to document why it's important to have a
 334 ;;; large value here, and what the drawbacks of an excessively large
 335 ;;; value are; and it might also be good to make it depend on
 336 ;;; optimization policy.
 337 (defparameter *reoptimize-after-type-check-max* 10)
 338
 339 (defevent reoptimize-maxed-out
 340   "*REOPTIMIZE-AFTER-TYPE-CHECK-MAX* exceeded.")
 341
 342 ;;; Iterate doing FIND-DFO until no new dead code is discovered.
 343 (defun dfo-as-needed (component)
 344   (declare (type component component))
 345   (when (component-reanalyze component)
 346     (maybe-mumble "DFO")
 347     (loop
 348       (find-dfo component)
 349       (unless (component-reanalyze component)
 350         (maybe-mumble " ")
 351         (return))
 352       (maybe-mumble ".")))
 353   (values))
 354
 355 ;;; Do all the IR1 phases for a non-top-level component.
 356 (defun ir1-phases (component)
 357   (declare (type component component))
 358   (aver-live-component component)
 359   (let ((*constraint-number* 0)
 360         (loop-count 1)
 361         (*delayed-ir1-transforms* nil))
 362     (declare (special *constraint-number* *delayed-ir1-transforms*))
 363     (loop
 364       (ir1-optimize-until-done component)
 365       (when (or (component-new-functionals component)
 366                 (component-reanalyze-functionals component))
 367         (maybe-mumble "locall ")
 368         (locall-analyze-component component))
 369       (dfo-as-needed component)
 370       (when *constraint-propagate*
 371         (maybe-mumble "constraint ")
 372         (constraint-propagate component))
 373       (when (retry-delayed-ir1-transforms :constraint)
 374         (maybe-mumble "Rtran "))
 375       (flet ((want-reoptimization-p ()
 376                (or (component-reoptimize component)
 377                    (component-reanalyze component)
 378                    (component-new-functionals component)
 379                    (component-reanalyze-functionals component))))
 380         (unless (and (want-reoptimization-p)
 381                      ;; We delay the generation of type checks until
 382                      ;; the type constraints have had time to
 383                      ;; propagate, else the compiler can confuse itself.
 384                      (< loop-count (- *reoptimize-after-type-check-max* 4)))
 385           (maybe-mumble "type ")
 386           (generate-type-checks component)
 387           (unless (want-reoptimization-p)
 388             (return))))
 389       (when (>= loop-count *reoptimize-after-type-check-max*)
 390         (maybe-mumble "[reoptimize limit]")
 391         (event reoptimize-maxed-out)
 392         (return))
 393       (incf loop-count)))
 394
 395   (ir1-finalize component)
 396   (values))
 397
 398 (defun %compile-component (component)
 399   (let ((*code-segment* nil)
 400         (*elsewhere* nil))
 401     (maybe-mumble "GTN ")
 402     (gtn-analyze component)
 403     (maybe-mumble "LTN ")
 404     (ltn-analyze component)
 405     (dfo-as-needed component)
 406     (maybe-mumble "control ")
 407     (control-analyze component #'make-ir2-block)
 408
 409     (when (or (ir2-component-values-receivers (component-info component))
 410               (component-dx-lvars component))
 411       (maybe-mumble "stack ")
 412       (stack-analyze component)
 413       ;; Assign BLOCK-NUMBER for any cleanup blocks introduced by
 414       ;; stack analysis. There shouldn't be any unreachable code after
 415       ;; control, so this won't delete anything.
 416       (dfo-as-needed component))
 417
 418     (unwind-protect
 419         (progn
 420           (maybe-mumble "IR2tran ")
 421           (init-assembler)
 422           (entry-analyze component)
 423           (ir2-convert component)
 424
 425           (when (policy *lexenv* (>= speed compilation-speed))
 426             (maybe-mumble "copy ")
 427             (copy-propagate component))
 428
 429           (select-representations component)
 430
 431           (when *check-consistency*
 432             (maybe-mumble "check2 ")
 433             (check-ir2-consistency component))
 434
 435           (delete-unreferenced-tns component)
 436
 437           (maybe-mumble "life ")
 438           (lifetime-analyze component)
 439
 440           (when *compile-progress*
 441             (compiler-mumble "") ; Sync before doing more output.
 442             (pre-pack-tn-stats component *error-output*))
 443
 444           (when *check-consistency*
 445             (maybe-mumble "check-life ")
 446             (check-life-consistency component))
 447
 448           (maybe-mumble "pack ")
 449           (pack component)
 450
 451           (when *check-consistency*
 452             (maybe-mumble "check-pack ")
 453             (check-pack-consistency component))
 454
 455           (when *compiler-trace-output*
 456             (describe-component component *compiler-trace-output*)
 457             (describe-ir2-component component *compiler-trace-output*))
 458
 459           (maybe-mumble "code ")
 460           (multiple-value-bind (code-length trace-table fixup-notes)
 461               (generate-code component)
 462
 463             #-sb-xc-host
 464             (when *compiler-trace-output*
 465               (format *compiler-trace-output*
 466                       "~|~%disassembly of code for ~S~2%" component)
 467               (sb!disassem:disassemble-assem-segment *code-segment*
 468                                                      *compiler-trace-output*))
 469
 470             (etypecase *compile-object*
 471               (fasl-output
 472                (maybe-mumble "fasl")
 473                (fasl-dump-component component
 474                                     *code-segment*
 475                                     code-length
 476                                     trace-table
 477                                     fixup-notes
 478                                     *compile-object*))
 479               (core-object
 480                (maybe-mumble "core")
 481                (make-core-component component
 482                                     *code-segment*
 483                                     code-length
 484                                     trace-table
 485                                     fixup-notes
 486                                     *compile-object*))
 487               (null))))))
 488
 489   ;; We're done, so don't bother keeping anything around.
 490   (setf (component-info component) :dead)
 491
 492   (values))
 493
 494 ;;; Delete components with no external entry points before we try to
 495 ;;; generate code. Unreachable closures can cause IR2 conversion to
 496 ;;; puke on itself, since it is the reference to the closure which
 497 ;;; normally causes the components to be combined.
 498 (defun delete-if-no-entries (component)
 499   (dolist (fun (component-lambdas component) (delete-component component))
 500     (when (functional-has-external-references-p fun)
 501       (return))
 502     (case (functional-kind fun)
 503       (:toplevel (return))
 504       (:external
 505        (unless (every (lambda (ref)
 506                         (eq (node-component ref) component))
 507                       (leaf-refs fun))
 508          (return))))))
 509
 510 (defun compile-component (component)
 511
 512   ;; miscellaneous sanity checks
 513   ;;
 514   ;; FIXME: These are basically pretty wimpy compared to the checks done
 515   ;; by the old CHECK-IR1-CONSISTENCY code. It would be really nice to
 516   ;; make those internal consistency checks work again and use them.
 517   (aver-live-component component)
 518   (do-blocks (block component)
 519     (aver (eql (block-component block) component)))
 520   (dolist (lambda (component-lambdas component))
 521     ;; sanity check to prevent weirdness from propagating insidiously as
 522     ;; far from its root cause as it did in bug 138: Make sure that
 523     ;; thing-to-COMPONENT links are consistent.
 524     (aver (eql (lambda-component lambda) component))
 525     (aver (eql (node-component (lambda-bind lambda)) component)))
 526
 527   (let* ((*component-being-compiled* component))
 528     (when sb!xc:*compile-print*
 529       (compiler-mumble "~&; compiling ~A: " (component-name component)))
 530
 531     (ir1-phases component)
 532
 533     (when *loop-analyze*
 534       (dfo-as-needed component)
 535       (find-dominators component)
 536       (loop-analyze component))
 537
 538     #|
 539     (when (and *loop-analyze* *compiler-trace-output*)
 540       (labels ((print-blocks (block)
 541                  (format *compiler-trace-output* "    ~A~%" block)
 542                  (when (block-loop-next block)
 543                    (print-blocks (block-loop-next block))))
 544                (print-loop (loop)
 545                  (format *compiler-trace-output* "loop=~A~%" loop)
 546                  (print-blocks (loop-blocks loop))
 547                  (dolist (l (loop-inferiors loop))
 548                    (print-loop l))))
 549         (print-loop (component-outer-loop component))))
 550     |#
 551
 552     ;; FIXME: What is MAYBE-MUMBLE for? Do we need it any more?
 553     (maybe-mumble "env ")
 554     (physenv-analyze component)
 555     (dfo-as-needed component)
 556
 557     (delete-if-no-entries component)
 558
 559     (unless (eq (block-next (component-head component))
 560                 (component-tail component))
 561       (%compile-component component)))
 562
 563   (clear-constant-info)
 564
 565   (when sb!xc:*compile-print*
 566     (compiler-mumble "~&"))
 567
 568   (values))
 569 \f
 570 ;;;; clearing global data structures
 571 ;;;;
 572 ;;;; FIXME: Is it possible to get rid of this stuff, getting rid of
 573 ;;;; global data structures entirely when possible and consing up the
 574 ;;;; others from scratch instead of clearing and reusing them?
 575
 576 ;;; Clear the INFO in constants in the *FREE-VARS*, etc. In
 577 ;;; addition to allowing stuff to be reclaimed, this is required for
 578 ;;; correct assignment of constant offsets, since we need to assign a
 579 ;;; new offset for each component. We don't clear the FUNCTIONAL-INFO
 580 ;;; slots, since they are used to keep track of functions across
 581 ;;; component boundaries.
 582 (defun clear-constant-info ()
 583   (maphash (lambda (k v)
 584              (declare (ignore k))
 585              (setf (leaf-info v) nil))
 586            *constants*)
 587   (maphash (lambda (k v)
 588              (declare (ignore k))
 589              (when (constant-p v)
 590                (setf (leaf-info v) nil)))
 591            *free-vars*)
 592   (values))
 593
 594 ;;; Blow away the REFS for all global variables, and let COMPONENT
 595 ;;; be recycled.
 596 (defun clear-ir1-info (component)
 597   (declare (type component component))
 598   (labels ((blast (x)
 599              (maphash (lambda (k v)
 600                         (declare (ignore k))
 601                         (when (leaf-p v)
 602                           (setf (leaf-refs v)
 603                                 (delete-if #'here-p (leaf-refs v)))
 604                           (when (basic-var-p v)
 605                             (setf (basic-var-sets v)
 606                                   (delete-if #'here-p (basic-var-sets v))))))
 607                       x))
 608            (here-p (x)
 609              (eq (node-component x) component)))
 610     (blast *free-vars*)
 611     (blast *free-funs*)
 612     (blast *constants*))
 613   (values))
 614
 615 ;;; Clear global variables used by the compiler.
 616 ;;;
 617 ;;; FIXME: It seems kinda nasty and unmaintainable to have to do this,
 618 ;;; and it adds overhead even when people aren't using the compiler.
 619 ;;; Perhaps we could make these global vars unbound except when
 620 ;;; actually in use, so that this function could go away.
 621 (defun clear-stuff (&optional (debug-too t))
 622
 623   ;; Clear global tables.
 624   (when (boundp '*free-funs*)
 625     (clrhash *free-funs*)
 626     (clrhash *free-vars*)
 627     (clrhash *constants*))
 628
 629   ;; Clear debug counters and tables.
 630   (clrhash *seen-blocks*)
 631   (clrhash *seen-funs*)
 632   (clrhash *list-conflicts-table*)
 633
 634   (when debug-too
 635     (clrhash *continuation-numbers*)
 636     (clrhash *number-continuations*)
 637     (setq *continuation-number* 0)
 638     (clrhash *tn-ids*)
 639     (clrhash *id-tns*)
 640     (setq *tn-id* 0)
 641     (clrhash *label-ids*)
 642     (clrhash *id-labels*)
 643     (setq *label-id* 0))
 644
 645   ;; (Note: The CMU CL code used to set CL::*GENSYM-COUNTER* to zero here.
 646   ;; Superficially, this seemed harmful -- the user could reasonably be
 647   ;; surprised if *GENSYM-COUNTER* turned back to zero when something was
 648   ;; compiled. A closer inspection showed that this actually turned out to be
 649   ;; harmless in practice, because CLEAR-STUFF was only called from within
 650   ;; forms which bound CL::*GENSYM-COUNTER* to zero. However, this means that
 651   ;; even though zeroing CL::*GENSYM-COUNTER* here turned out to be harmless in
 652   ;; practice, it was also useless in practice. So we don't do it any more.)
 653
 654   (values))
 655 \f
 656 ;;;; trace output
 657
 658 ;;; Print out some useful info about COMPONENT to STREAM.
 659 (defun describe-component (component *standard-output*)
 660   (declare (type component component))
 661   (format t "~|~%;;;; component: ~S~2%" (component-name component))
 662   (print-all-blocks component)
 663   (values))
 664
 665 (defun describe-ir2-component (component *standard-output*)
 666   (format t "~%~|~%;;;; IR2 component: ~S~2%" (component-name component))
 667   (format t "entries:~%")
 668   (dolist (entry (ir2-component-entries (component-info component)))
 669     (format t "~4TL~D: ~S~:[~; [closure]~]~%"
 670             (label-id (entry-info-offset entry))
 671             (entry-info-name entry)
 672             (entry-info-closure-tn entry)))
 673   (terpri)
 674   (pre-pack-tn-stats component *standard-output*)
 675   (terpri)
 676   (print-ir2-blocks component)
 677   (terpri)
 678   (values))
 679 \f
 680 ;;;; file reading
 681 ;;;;
 682 ;;;; When reading from a file, we have to keep track of some source
 683 ;;;; information. We also exploit our ability to back up for printing
 684 ;;;; the error context and for recovering from errors.
 685 ;;;;
 686 ;;;; The interface we provide to this stuff is the stream-oid
 687 ;;;; SOURCE-INFO structure. The bookkeeping is done as a side effect
 688 ;;;; of getting the next source form.
 689
 690 ;;; A FILE-INFO structure holds all the source information for a
 691 ;;; given file.
 692 (def!struct (file-info (:copier nil))
 693   ;; If a file, the truename of the corresponding source file. If from
 694   ;; a Lisp form, :LISP. If from a stream, :STREAM.
 695   (name (missing-arg) :type (or pathname (member :lisp :stream)))
 696   ;; the external format that we'll call OPEN with, if NAME is a file.
 697   (external-format nil)
 698   ;; the defaulted, but not necessarily absolute file name (i.e. prior
 699   ;; to TRUENAME call.) Null if not a file. This is used to set
 700   ;; *COMPILE-FILE-PATHNAME*, and if absolute, is dumped in the
 701   ;; debug-info.
 702   (untruename nil :type (or pathname null))
 703   ;; the file's write date (if relevant)
 704   (write-date nil :type (or unsigned-byte null))
 705   ;; the source path root number of the first form in this file (i.e.
 706   ;; the total number of forms converted previously in this
 707   ;; compilation)
 708   (source-root 0 :type unsigned-byte)
 709   ;; parallel vectors containing the forms read out of the file and
 710   ;; the file positions that reading of each form started at (i.e. the
 711   ;; end of the previous form)
 712   (forms (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t))
 713   (positions (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t)))
 714
 715 ;;; The SOURCE-INFO structure provides a handle on all the source
 716 ;;; information for an entire compilation.
 717 (def!struct (source-info
 718              #-no-ansi-print-object
 719              (:print-object (lambda (s stream)
 720                               (print-unreadable-object (s stream :type t))))
 721              (:copier nil))
 722   ;; the UT that compilation started at
 723   (start-time (get-universal-time) :type unsigned-byte)
 724   ;; the FILE-INFO structure for this compilation
 725   (file-info nil :type (or file-info null))
 726   ;; the stream that we are using to read the FILE-INFO, or NIL if
 727   ;; no stream has been opened yet
 728   (stream nil :type (or stream null)))
 729
 730 ;;; Given a pathname, return a SOURCE-INFO structure.
 731 (defun make-file-source-info (file external-format)
 732   (let ((file-info (make-file-info :name (truename file)
 733                                    :untruename file
 734                                    :external-format external-format
 735                                    :write-date (file-write-date file))))
 736
 737     (make-source-info :file-info file-info)))
 738
 739 ;;; Return a SOURCE-INFO to describe the incremental compilation of FORM.
 740 (defun make-lisp-source-info (form)
 741   (make-source-info :start-time (get-universal-time)
 742                     :file-info (make-file-info :name :lisp
 743                                                :forms (vector form)
 744                                                :positions '#(0))))
 745
 746 ;;; Return a SOURCE-INFO which will read from STREAM.
 747 (defun make-stream-source-info (stream)
 748   (let ((file-info (make-file-info :name :stream)))
 749     (make-source-info :file-info file-info
 750                       :stream stream)))
 751
 752 ;;; Return a form read from STREAM; or for EOF use the trick,
 753 ;;; popularized by Kent Pitman, of returning STREAM itself. If an
 754 ;;; error happens, then convert it to standard abort-the-compilation
 755 ;;; error condition (possibly recording some extra location
 756 ;;; information).
 757 (defun read-for-compile-file (stream position)
 758   (handler-case (read stream nil stream)
 759     (reader-error (condition)
 760      (error 'input-error-in-compile-file
 761             :condition condition
 762             ;; We don't need to supply :POSITION here because
 763             ;; READER-ERRORs already know their position in the file.
 764             ))
 765     ;; ANSI, in its wisdom, says that READ should return END-OF-FILE
 766     ;; (and that this is not a READER-ERROR) when it encounters end of
 767     ;; file in the middle of something it's trying to read.
 768     (end-of-file (condition)
 769      (error 'input-error-in-compile-file
 770             :condition condition
 771             ;; We need to supply :POSITION here because the END-OF-FILE
 772             ;; condition doesn't carry the position that the user
 773             ;; probably cares about, where the failed READ began.
 774             :position position))))
 775
 776 ;;; If STREAM is present, return it, otherwise open a stream to the
 777 ;;; current file. There must be a current file.
 778 ;;;
 779 ;;; FIXME: This is probably an unnecessarily roundabout way to do
 780 ;;; things now that we process a single file in COMPILE-FILE (unlike
 781 ;;; the old CMU CL code, which accepted multiple files). Also, the old
 782 ;;; comment said
 783 ;;;   When we open a new file, we also reset *PACKAGE* and policy.
 784 ;;;   This gives the effect of rebinding around each file.
 785 ;;; which doesn't seem to be true now. Check to make sure that if
 786 ;;; such rebinding is necessary, it's still done somewhere.
 787 (defun get-source-stream (info)
 788   (declare (type source-info info))
 789   (or (source-info-stream info)
 790       (let* ((file-info (source-info-file-info info))
 791              (name (file-info-name file-info))
 792              (external-format (file-info-external-format file-info)))
 793         (setf sb!xc:*compile-file-truename* name
 794               sb!xc:*compile-file-pathname* (file-info-untruename file-info)
 795               (source-info-stream info)
 796               (open name :direction :input
 797                     :external-format external-format)))))
 798
 799 ;;; Close the stream in INFO if it is open.
 800 (defun close-source-info (info)
 801   (declare (type source-info info))
 802   (let ((stream (source-info-stream info)))
 803     (when stream (close stream)))
 804   (setf (source-info-stream info) nil)
 805   (values))
 806
 807 ;;; Read and compile the source file.
 808 (defun sub-sub-compile-file (info)
 809   (let* ((file-info (source-info-file-info info))
 810          (stream (get-source-stream info)))
 811     (loop
 812      (let* ((pos (file-position stream))
 813             (form (read-for-compile-file stream pos)))
 814        (if (eq form stream) ; i.e., if EOF
 815            (return)
 816            (let* ((forms (file-info-forms file-info))
 817                   (current-idx (+ (fill-pointer forms)
 818                                   (file-info-source-root file-info))))
 819              (vector-push-extend form forms)
 820              (vector-push-extend pos (file-info-positions file-info))
 821              (find-source-paths form current-idx)
 822              (process-toplevel-form form
 823                                     `(original-source-start 0 ,current-idx)
 824                                     nil)))))))
 825
 826 ;;; Return the INDEX'th source form read from INFO and the position
 827 ;;; where it was read.
 828 (defun find-source-root (index info)
 829   (declare (type index index) (type source-info info))
 830   (let ((file-info (source-info-file-info info)))
 831     (values (aref (file-info-forms file-info) index)
 832             (aref (file-info-positions file-info) index))))
 833 \f
 834 ;;;; processing of top level forms
 835
 836 ;;; This is called by top level form processing when we are ready to
 837 ;;; actually compile something. If *BLOCK-COMPILE* is T, then we still
 838 ;;; convert the form, but delay compilation, pushing the result on
 839 ;;; *TOPLEVEL-LAMBDAS* instead.
 840 (defun convert-and-maybe-compile (form path)
 841   (declare (list path))
 842   (let* ((*lexenv* (make-lexenv :policy *policy*
 843                                 :handled-conditions *handled-conditions*
 844                                 :disabled-package-locks *disabled-package-locks*))
 845          (tll (ir1-toplevel form path nil)))
 846     (cond ((eq *block-compile* t) (push tll *toplevel-lambdas*))
 847           (t (compile-toplevel (list tll) nil)))))
 848
 849 ;;; Macroexpand FORM in the current environment with an error handler.
 850 ;;; We only expand one level, so that we retain all the intervening
 851 ;;; forms in the source path.
 852 (defun preprocessor-macroexpand-1 (form)
 853   (handler-case (sb!xc:macroexpand-1 form *lexenv*)
 854     (error (condition)
 855       (compiler-error "(during macroexpansion of ~A)~%~A"
 856                       (let ((*print-level* 1)
 857                             (*print-length* 2))
 858                         (format nil "~S" form))
 859                       condition))))
 860
 861 ;;; Process a PROGN-like portion of a top level form. FORMS is a list of
 862 ;;; the forms, and PATH is the source path of the FORM they came out of.
 863 ;;; COMPILE-TIME-TOO is as in ANSI "3.2.3.1 Processing of Top Level Forms".
 864 (defun process-toplevel-progn (forms path compile-time-too)
 865   (declare (list forms) (list path))
 866   (dolist (form forms)
 867     (process-toplevel-form form path compile-time-too)))
 868
 869 ;;; Process a top level use of LOCALLY, or anything else (e.g.
 870 ;;; MACROLET) at top level which has declarations and ordinary forms.
 871 ;;; We parse declarations and then recursively process the body.
 872 (defun process-toplevel-locally (body path compile-time-too &key vars funs)
 873   (declare (list path))
 874   (multiple-value-bind (forms decls)
 875       (parse-body body :doc-string-allowed nil :toplevel t)
 876     (let* ((*lexenv* (process-decls decls vars funs))
 877            ;; FIXME: VALUES declaration
 878            ;;
 879            ;; Binding *POLICY* is pretty much of a hack, since it
 880            ;; causes LOCALLY to "capture" enclosed proclamations. It
 881            ;; is necessary because CONVERT-AND-MAYBE-COMPILE uses the
 882            ;; value of *POLICY* as the policy. The need for this hack
 883            ;; is due to the quirk that there is no way to represent in
 884            ;; a POLICY that an optimize quality came from the default.
 885            ;;
 886            ;; FIXME: Ideally, something should be done so that DECLAIM
 887            ;; inside LOCALLY works OK. Failing that, at least we could
 888            ;; issue a warning instead of silently screwing up.
 889            (*policy* (lexenv-policy *lexenv*))
 890            ;; This is probably also a hack
 891            (*handled-conditions* (lexenv-handled-conditions *lexenv*))
 892            ;; ditto
 893            (*disabled-package-locks* (lexenv-disabled-package-locks *lexenv*)))
 894       (process-toplevel-progn forms path compile-time-too))))
 895
 896 ;;; Parse an EVAL-WHEN situations list, returning three flags,
 897 ;;; (VALUES COMPILE-TOPLEVEL LOAD-TOPLEVEL EXECUTE), indicating
 898 ;;; the types of situations present in the list.
 899 (defun parse-eval-when-situations (situations)
 900   (when (or (not (listp situations))
 901             (set-difference situations
 902                             '(:compile-toplevel
 903                               compile
 904                               :load-toplevel
 905                               load
 906                               :execute
 907                               eval)))
 908     (compiler-error "bad EVAL-WHEN situation list: ~S" situations))
 909   (let ((deprecated-names (intersection situations '(compile load eval))))
 910     (when deprecated-names
 911       (style-warn "using deprecated EVAL-WHEN situation names~{ ~S~}"
 912                   deprecated-names)))
 913   (values (intersection '(:compile-toplevel compile)
 914                         situations)
 915           (intersection '(:load-toplevel load) situations)
 916           (intersection '(:execute eval) situations)))
 917
 918
 919 ;;; utilities for extracting COMPONENTs of FUNCTIONALs
 920 (defun functional-components (f)
 921   (declare (type functional f))
 922   (etypecase f
 923     (clambda (list (lambda-component f)))
 924     (optional-dispatch (let ((result nil))
 925                          (flet ((maybe-frob (maybe-clambda)
 926                                   (when (and maybe-clambda
 927                                              (promise-ready-p maybe-clambda))
 928                                     (pushnew (lambda-component
 929                                               (force maybe-clambda))
 930                                              result))))
 931                            (map nil #'maybe-frob (optional-dispatch-entry-points f))
 932                            (maybe-frob (optional-dispatch-more-entry f))
 933                            (maybe-frob (optional-dispatch-main-entry f)))
 934                          result))))
 935
 936 (defun make-functional-from-toplevel-lambda (definition
 937                                              &key
 938                                              name
 939                                              (path
 940                                               ;; I'd thought NIL should
 941                                               ;; work, but it doesn't.
 942                                               ;; -- WHN 2001-09-20
 943                                               (missing-arg)))
 944   (let* ((*current-path* path)
 945          (component (make-empty-component))
 946          (*current-component* component))
 947     (setf (component-name component)
 948           (debug-namify "~S initial component" name))
 949     (setf (component-kind component) :initial)
 950     (let* ((locall-fun (let ((*allow-instrumenting* t))
 951                          (ir1-convert-lambdalike
 952                           definition
 953                           :debug-name (debug-namify "top level local call "
 954                                                     name))))
 955            (fun (ir1-convert-lambda (make-xep-lambda-expression locall-fun)
 956                                     :source-name (or name '.anonymous.)
 957                                     :debug-name (unless name
 958                                                   "top level form"))))
 959       (when name
 960         (assert-global-function-definition-type name locall-fun))
 961       (setf (functional-entry-fun fun) locall-fun
 962             (functional-kind fun) :external
 963             (functional-has-external-references-p fun) t)
 964       fun)))
 965
 966 ;;; Compile LAMBDA-EXPRESSION into *COMPILE-OBJECT*, returning a
 967 ;;; description of the result.
 968 ;;;   * If *COMPILE-OBJECT* is a CORE-OBJECT, then write the function
 969 ;;;     into core and return the compiled FUNCTION value.
 970 ;;;   * If *COMPILE-OBJECT* is a fasl file, then write the function
 971 ;;;     into the fasl file and return a dump handle.
 972 ;;;
 973 ;;; If NAME is provided, then we try to use it as the name of the
 974 ;;; function for debugging/diagnostic information.
 975 (defun %compile (lambda-expression
 976                  *compile-object*
 977                  &key
 978                  name
 979                  (path
 980                   ;; This magical idiom seems to be the appropriate
 981                   ;; path for compiling standalone LAMBDAs, judging
 982                   ;; from the CMU CL code and experiment, so it's a
 983                   ;; nice default for things where we don't have a
 984                   ;; real source path (as in e.g. inside CL:COMPILE).
 985                   '(original-source-start 0 0)))
 986   (when name
 987     (legal-fun-name-or-type-error name))
 988   (let* (
 989          (*lexenv* (make-lexenv :policy *policy*
 990                                 :handled-conditions *handled-conditions*
 991                                 :disabled-package-locks *disabled-package-locks*))
 992          (fun (make-functional-from-toplevel-lambda lambda-expression
 993                                                     :name name
 994                                                     :path path)))
 995
 996     ;; FIXME: The compile-it code from here on is sort of a
 997     ;; twisted version of the code in COMPILE-TOPLEVEL. It'd be
 998     ;; better to find a way to share the code there; or
 999     ;; alternatively, to use this code to replace the code there.
1000     ;; (The second alternative might be pretty easy if we used
1001     ;; the :LOCALL-ONLY option to IR1-FOR-LAMBDA. Then maybe the
1002     ;; whole FUNCTIONAL-KIND=:TOPLEVEL case could go away..)
1003
1004     (locall-analyze-clambdas-until-done (list fun))
1005
1006     (multiple-value-bind (components-from-dfo top-components hairy-top)
1007         (find-initial-dfo (list fun))
1008       (declare (ignore hairy-top))
1009
1010       (let ((*all-components* (append components-from-dfo top-components)))
1011         (dolist (component-from-dfo components-from-dfo)
1012           (compile-component component-from-dfo)
1013           (replace-toplevel-xeps component-from-dfo)))
1014
1015       (let ((entry-table (etypecase *compile-object*
1016                            (fasl-output (fasl-output-entry-table
1017                                          *compile-object*))
1018                            (core-object (core-object-entry-table
1019                                          *compile-object*)))))
1020         (multiple-value-bind (result found-p)
1021             (gethash (leaf-info fun) entry-table)
1022           (aver found-p)
1023           (prog1
1024               result
1025             ;; KLUDGE: This code duplicates some other code in this
1026             ;; file. In the great reorganzation, the flow of program
1027             ;; logic changed from the original CMUCL model, and that
1028             ;; path (as of sbcl-0.7.5 in SUB-COMPILE-FILE) was no
1029             ;; longer followed for CORE-OBJECTS, leading to BUG
1030             ;; 156. This place is transparently not the right one for
1031             ;; this code, but I don't have a clear enough overview of
1032             ;; the compiler to know how to rearrange it all so that
1033             ;; this operation fits in nicely, and it was blocking
1034             ;; reimplementation of (DECLAIM (INLINE FOO)) (MACROLET
1035             ;; ((..)) (DEFUN FOO ...))
1036             ;;
1037             ;; FIXME: This KLUDGE doesn't solve all the problem in an
1038             ;; ideal way, as (1) definitions typed in at the REPL
1039             ;; without an INLINE declaration will give a NULL
1040             ;; FUNCTION-LAMBDA-EXPRESSION (allowable, but not ideal)
1041             ;; and (2) INLINE declarations will yield a
1042             ;; FUNCTION-LAMBDA-EXPRESSION headed by
1043             ;; SB-C:LAMBDA-WITH-LEXENV, even for null LEXENV.  -- CSR,
1044             ;; 2002-07-02
1045             ;;
1046             ;; (2) is probably fairly easy to fix -- it is, after all,
1047             ;; a matter of list manipulation (or possibly of teaching
1048             ;; CL:FUNCTION about SB-C:LAMBDA-WITH-LEXENV).  (1) is
1049             ;; significantly harder, as the association between
1050             ;; function object and source is a tricky one.
1051             ;;
1052             ;; FUNCTION-LAMBDA-EXPRESSION "works" (i.e. returns a
1053             ;; non-NULL list) when the function in question has been
1054             ;; compiled by (COMPILE <x> '(LAMBDA ...)); it does not
1055             ;; work when it has been compiled as part of the top-level
1056             ;; EVAL strategy of compiling everything inside (LAMBDA ()
1057             ;; ...).  -- CSR, 2002-11-02
1058             (when (core-object-p *compile-object*)
1059               (fix-core-source-info *source-info* *compile-object* result))
1060
1061             (mapc #'clear-ir1-info components-from-dfo)
1062             (clear-stuff)))))))
1063
1064 (defun process-toplevel-cold-fset (name lambda-expression path)
1065   (unless (producing-fasl-file)
1066     (error "can't COLD-FSET except in a fasl file"))
1067   (legal-fun-name-or-type-error name)
1068   (fasl-dump-cold-fset name
1069                        (%compile lambda-expression
1070                                  *compile-object*
1071                                  :name name
1072                                  :path path)
1073                        *compile-object*)
1074   (values))
1075
1076 ;;; Process a top level FORM with the specified source PATH.
1077 ;;;  * If this is a magic top level form, then do stuff.
1078 ;;;  * If this is a macro, then expand it.
1079 ;;;  * Otherwise, just compile it.
1080 ;;;
1081 ;;; COMPILE-TIME-TOO is as defined in ANSI
1082 ;;; "3.2.3.1 Processing of Top Level Forms".
1083 (defun process-toplevel-form (form path compile-time-too)
1084
1085   (declare (list path))
1086
1087   (catch 'process-toplevel-form-error-abort
1088     (let* ((path (or (gethash form *source-paths*) (cons form path)))
1089            (*compiler-error-bailout*
1090             (lambda (&optional condition)
1091               (convert-and-maybe-compile
1092                (make-compiler-error-form condition form)
1093                path)
1094               (throw 'process-toplevel-form-error-abort nil))))
1095
1096       (flet ((default-processor (form)
1097                ;; When we're cross-compiling, consider: what should we
1098                ;; do when we hit e.g.
1099                ;;   (EVAL-WHEN (:COMPILE-TOPLEVEL)
1100                ;;     (DEFUN FOO (X) (+ 7 X)))?
1101                ;; DEFUN has a macro definition in the cross-compiler,
1102                ;; and a different macro definition in the target
1103                ;; compiler. The only sensible thing is to use the
1104                ;; target compiler's macro definition, since the
1105                ;; cross-compiler's macro is in general into target
1106                ;; functions which can't meaningfully be executed at
1107                ;; cross-compilation time. So make sure we do the EVAL
1108                ;; here, before we macroexpand.
1109                ;;
1110                ;; Then things get even dicier with something like
1111                ;;   (DEFCONSTANT-EQX SB!XC:LAMBDA-LIST-KEYWORDS ..)
1112                ;; where we have to make sure that we don't uncross
1113                ;; the SB!XC: prefix before we do EVAL, because otherwise
1114                ;; we'd be trying to redefine the cross-compilation host's
1115                ;; constants.
1116                ;;
1117                ;; (Isn't it fun to cross-compile Common Lisp?:-)
1118                #+sb-xc-host
1119                (progn
1120                  (when compile-time-too
1121                    (eval form)) ; letting xc host EVAL do its own macroexpansion
1122                  (let* (;; (We uncross the operator name because things
1123                         ;; like SB!XC:DEFCONSTANT and SB!XC:DEFTYPE
1124                         ;; should be equivalent to their CL: counterparts
1125                         ;; when being compiled as target code. We leave
1126                         ;; the rest of the form uncrossed because macros
1127                         ;; might yet expand into EVAL-WHEN stuff, and
1128                         ;; things inside EVAL-WHEN can't be uncrossed
1129                         ;; until after we've EVALed them in the
1130                         ;; cross-compilation host.)
1131                         (slightly-uncrossed (cons (uncross (first form))
1132                                                   (rest form)))
1133                         (expanded (preprocessor-macroexpand-1
1134                                    slightly-uncrossed)))
1135                    (if (eq expanded slightly-uncrossed)
1136                        ;; (Now that we're no longer processing toplevel
1137                        ;; forms, and hence no longer need to worry about
1138                        ;; EVAL-WHEN, we can uncross everything.)
1139                        (convert-and-maybe-compile expanded path)
1140                        ;; (We have to demote COMPILE-TIME-TOO to NIL
1141                        ;; here, no matter what it was before, since
1142                        ;; otherwise we'd tend to EVAL subforms more than
1143                        ;; once, because of WHEN COMPILE-TIME-TOO form
1144                        ;; above.)
1145                        (process-toplevel-form expanded path nil))))
1146                ;; When we're not cross-compiling, we only need to
1147                ;; macroexpand once, so we can follow the 1-thru-6
1148                ;; sequence of steps in ANSI's "3.2.3.1 Processing of
1149                ;; Top Level Forms".
1150                #-sb-xc-host
1151                (let ((expanded (preprocessor-macroexpand-1 form)))
1152                  (cond ((eq expanded form)
1153                         (when compile-time-too
1154                           (eval-in-lexenv form *lexenv*))
1155                         (convert-and-maybe-compile form path))
1156                        (t
1157                         (process-toplevel-form expanded
1158                                                path
1159                                                compile-time-too))))))
1160         (if (atom form)
1161             #+sb-xc-host
1162             ;; (There are no xc EVAL-WHEN issues in the ATOM case until
1163             ;; (1) SBCL gets smart enough to handle global
1164             ;; DEFINE-SYMBOL-MACRO or SYMBOL-MACROLET and (2) SBCL
1165             ;; implementors start using symbol macros in a way which
1166             ;; interacts with SB-XC/CL distinction.)
1167             (convert-and-maybe-compile form path)
1168             #-sb-xc-host
1169             (default-processor form)
1170             (flet ((need-at-least-one-arg (form)
1171                      (unless (cdr form)
1172                        (compiler-error "~S form is too short: ~S"
1173                                        (car form)
1174                                        form))))
1175               (case (car form)
1176                 ;; In the cross-compiler, top level COLD-FSET arranges
1177                 ;; for static linking at cold init time.
1178                 #+sb-xc-host
1179                 ((cold-fset)
1180                  (aver (not compile-time-too))
1181                  (destructuring-bind (cold-fset fun-name lambda-expression) form
1182                    (declare (ignore cold-fset))
1183                    (process-toplevel-cold-fset fun-name
1184                                                lambda-expression
1185                                                path)))
1186                 ((eval-when macrolet symbol-macrolet);things w/ 1 arg before body
1187                  (need-at-least-one-arg form)
1188                  (destructuring-bind (special-operator magic &rest body) form
1189                    (ecase special-operator
1190                      ((eval-when)
1191                       ;; CT, LT, and E here are as in Figure 3-7 of ANSI
1192                       ;; "3.2.3.1 Processing of Top Level Forms".
1193                       (multiple-value-bind (ct lt e)
1194                           (parse-eval-when-situations magic)
1195                         (let ((new-compile-time-too (or ct
1196                                                         (and compile-time-too
1197                                                              e))))
1198                           (cond (lt (process-toplevel-progn
1199                                      body path new-compile-time-too))
1200                                 (new-compile-time-too (eval-in-lexenv
1201                                                        `(progn ,@body)
1202                                                        *lexenv*))))))
1203                      ((macrolet)
1204                       (funcall-in-macrolet-lexenv
1205                        magic
1206                        (lambda (&key funs prepend)
1207                          (declare (ignore funs))
1208                          (aver (null prepend))
1209                          (process-toplevel-locally body
1210                                                    path
1211                                                    compile-time-too))
1212                        :compile))
1213                      ((symbol-macrolet)
1214                       (funcall-in-symbol-macrolet-lexenv
1215                        magic
1216                        (lambda (&key vars prepend)
1217                          (aver (null prepend))
1218                          (process-toplevel-locally body
1219                                                    path
1220                                                    compile-time-too
1221                                                    :vars vars))
1222                        :compile)))))
1223                 ((locally)
1224                  (process-toplevel-locally (rest form) path compile-time-too))
1225                 ((progn)
1226                  (process-toplevel-progn (rest form) path compile-time-too))
1227                 (t (default-processor form))))))))
1228
1229   (values))
1230 \f
1231 ;;;; load time value support
1232 ;;;;
1233 ;;;; (See EMIT-MAKE-LOAD-FORM.)
1234
1235 ;;; Return T if we are currently producing a fasl file and hence
1236 ;;; constants need to be dumped carefully.
1237 (defun producing-fasl-file ()
1238   (fasl-output-p *compile-object*))
1239
1240 ;;; Compile FORM and arrange for it to be called at load-time. Return
1241 ;;; the dumper handle and our best guess at the type of the object.
1242 (defun compile-load-time-value (form)
1243   (let ((lambda (compile-load-time-stuff form t)))
1244     (values
1245      (fasl-dump-load-time-value-lambda lambda *compile-object*)
1246      (let ((type (leaf-type lambda)))
1247        (if (fun-type-p type)
1248            (single-value-type (fun-type-returns type))
1249            *wild-type*)))))
1250
1251 ;;; Compile the FORMS and arrange for them to be called (for effect,
1252 ;;; not value) at load time.
1253 (defun compile-make-load-form-init-forms (forms)
1254   (let ((lambda (compile-load-time-stuff `(progn ,@forms) nil)))
1255     (fasl-dump-toplevel-lambda-call lambda *compile-object*)))
1256
1257 ;;; Do the actual work of COMPILE-LOAD-TIME-VALUE or
1258 ;;; COMPILE-MAKE-LOAD-FORM-INIT-FORMS.
1259 (defun compile-load-time-stuff (form for-value)
1260   (with-ir1-namespace
1261    (let* ((*lexenv* (make-null-lexenv))
1262           (lambda (ir1-toplevel form *current-path* for-value)))
1263      (compile-toplevel (list lambda) t)
1264      lambda)))
1265
1266 ;;; This is called by COMPILE-TOPLEVEL when it was passed T for
1267 ;;; LOAD-TIME-VALUE-P (which happens in COMPILE-LOAD-TIME-STUFF). We
1268 ;;; don't try to combine this component with anything else and frob
1269 ;;; the name. If not in a :TOPLEVEL component, then don't bother
1270 ;;; compiling, because it was merged with a run-time component.
1271 (defun compile-load-time-value-lambda (lambdas)
1272   (aver (null (cdr lambdas)))
1273   (let* ((lambda (car lambdas))
1274          (component (lambda-component lambda)))
1275     (when (eql (component-kind component) :toplevel)
1276       (setf (component-name component) (leaf-debug-name lambda))
1277       (compile-component component)
1278       (clear-ir1-info component))))
1279 \f
1280 ;;;; COMPILE-FILE
1281
1282 (defun object-call-toplevel-lambda (tll)
1283   (declare (type functional tll))
1284   (let ((object *compile-object*))
1285     (etypecase object
1286       (fasl-output (fasl-dump-toplevel-lambda-call tll object))
1287       (core-object (core-call-toplevel-lambda      tll object))
1288       (null))))
1289
1290 ;;; Smash LAMBDAS into a single component, compile it, and arrange for
1291 ;;; the resulting function to be called.
1292 (defun sub-compile-toplevel-lambdas (lambdas)
1293   (declare (list lambdas))
1294   (when lambdas
1295     (multiple-value-bind (component tll) (merge-toplevel-lambdas lambdas)
1296       (compile-component component)
1297       (clear-ir1-info component)
1298       (object-call-toplevel-lambda tll)))
1299   (values))
1300
1301 ;;; Compile top level code and call the top level lambdas. We pick off
1302 ;;; top level lambdas in non-top-level components here, calling
1303 ;;; SUB-c-t-l-l on each subsequence of normal top level lambdas.
1304 (defun compile-toplevel-lambdas (lambdas)
1305   (declare (list lambdas))
1306   (let ((len (length lambdas)))
1307     (flet ((loser (start)
1308              (or (position-if (lambda (x)
1309                                 (not (eq (component-kind
1310                                           (node-component (lambda-bind x)))
1311                                          :toplevel)))
1312                               lambdas
1313                               ;; this used to read ":start start", but
1314                               ;; start can be greater than len, which
1315                               ;; is an error according to ANSI - CSR,
1316                               ;; 2002-04-25
1317                               :start (min start len))
1318                  len)))
1319       (do* ((start 0 (1+ loser))
1320             (loser (loser start) (loser start)))
1321            ((>= start len))
1322         (sub-compile-toplevel-lambdas (subseq lambdas start loser))
1323         (unless (= loser len)
1324           (object-call-toplevel-lambda (elt lambdas loser))))))
1325   (values))
1326
1327 ;;; Compile LAMBDAS (a list of CLAMBDAs for top level forms) into the
1328 ;;; object file.
1329 ;;;
1330 ;;; LOAD-TIME-VALUE-P seems to control whether it's MAKE-LOAD-FORM and
1331 ;;; COMPILE-LOAD-TIME-VALUE stuff. -- WHN 20000201
1332 (defun compile-toplevel (lambdas load-time-value-p)
1333   (declare (list lambdas))
1334
1335   (maybe-mumble "locall ")
1336   (locall-analyze-clambdas-until-done lambdas)
1337
1338   (maybe-mumble "IDFO ")
1339   (multiple-value-bind (components top-components hairy-top)
1340       (find-initial-dfo lambdas)
1341     (let ((*all-components* (append components top-components)))
1342       (when *check-consistency*
1343         (maybe-mumble "[check]~%")
1344         (check-ir1-consistency *all-components*))
1345
1346       (dolist (component (append hairy-top top-components))
1347         (pre-physenv-analyze-toplevel component))
1348
1349       (dolist (component components)
1350         (compile-component component)
1351         (replace-toplevel-xeps component))
1352
1353       (when *check-consistency*
1354         (maybe-mumble "[check]~%")
1355         (check-ir1-consistency *all-components*))
1356
1357       (if load-time-value-p
1358           (compile-load-time-value-lambda lambdas)
1359           (compile-toplevel-lambdas lambdas))
1360
1361       (mapc #'clear-ir1-info components)
1362       (clear-stuff)))
1363   (values))
1364
1365 ;;; Actually compile any stuff that has been queued up for block
1366 ;;; compilation.
1367 (defun finish-block-compilation ()
1368   (when *block-compile*
1369     (when *toplevel-lambdas*
1370       (compile-toplevel (nreverse *toplevel-lambdas*) nil)
1371       (setq *toplevel-lambdas* ()))
1372     (setq *block-compile* nil)
1373     (setq *entry-points* nil)))
1374
1375 (defun handle-condition-p (condition)
1376   (let ((lexenv
1377          (etypecase *compiler-error-context*
1378            (node
1379             (node-lexenv *compiler-error-context*))
1380            (compiler-error-context
1381             (let ((lexenv (compiler-error-context-lexenv
1382                            *compiler-error-context*)))
1383               (aver lexenv)
1384               lexenv))
1385            (null *lexenv*))))
1386     (let ((muffles (lexenv-handled-conditions lexenv)))
1387       (if (null muffles) ; common case
1388           nil
1389           (dolist (muffle muffles nil)
1390             (destructuring-bind (typespec . restart-name) muffle
1391               (when (and (typep condition typespec)
1392                          (find-restart restart-name condition))
1393                 (return t))))))))
1394
1395 (defun handle-condition-handler (condition)
1396   (let ((lexenv
1397          (etypecase *compiler-error-context*
1398            (node
1399             (node-lexenv *compiler-error-context*))
1400            (compiler-error-context
1401             (let ((lexenv (compiler-error-context-lexenv
1402                            *compiler-error-context*)))
1403               (aver lexenv)
1404               lexenv))
1405            (null *lexenv*))))
1406     (let ((muffles (lexenv-handled-conditions lexenv)))
1407       (aver muffles)
1408       (dolist (muffle muffles (bug "fell through"))
1409         (destructuring-bind (typespec . restart-name) muffle
1410           (when (typep condition typespec)
1411             (awhen (find-restart restart-name condition)
1412               (invoke-restart it))))))))
1413
1414 ;;; Read all forms from INFO and compile them, with output to OBJECT.
1415 ;;; Return (VALUES NIL WARNINGS-P FAILURE-P).
1416 (defun sub-compile-file (info)
1417   (declare (type source-info info))
1418   (let ((*package* (sane-package))
1419         (*readtable* *readtable*)
1420         (sb!xc:*compile-file-pathname* nil) ; really bound in
1421         (sb!xc:*compile-file-truename* nil) ; SUB-SUB-COMPILE-FILE
1422
1423         (*policy* *policy*)
1424         (*handled-conditions* *handled-conditions*)
1425         (*disabled-package-locks* *disabled-package-locks*)
1426         (*lexenv* (make-null-lexenv))
1427         (*block-compile* *block-compile-arg*)
1428         (*source-info* info)
1429         (*toplevel-lambdas* ())
1430         (*fun-names-in-this-file* ())
1431         (*allow-instrumenting* nil)
1432         (*compiler-error-bailout*
1433          (lambda ()
1434            (compiler-mumble "~2&; fatal error, aborting compilation~%")
1435            (return-from sub-compile-file (values nil t t))))
1436         (*current-path* nil)
1437         (*last-source-context* nil)
1438         (*last-original-source* nil)
1439         (*last-source-form* nil)
1440         (*last-format-string* nil)
1441         (*last-format-args* nil)
1442         (*last-message-count* 0)
1443         ;; FIXME: Do we need this rebinding here? It's a literal
1444         ;; translation of the old CMU CL rebinding to
1445         ;; (OR *BACKEND-INFO-ENVIRONMENT* *INFO-ENVIRONMENT*),
1446         ;; and it's not obvious whether the rebinding to itself is
1447         ;; needed that SBCL doesn't need *BACKEND-INFO-ENVIRONMENT*.
1448         (*info-environment* *info-environment*)
1449         (*gensym-counter* 0))
1450     (handler-case
1451         (handler-bind (((satisfies handle-condition-p) #'handle-condition-handler))
1452           (with-compilation-values
1453               (sb!xc:with-compilation-unit ()
1454                 (clear-stuff)
1455
1456                 (sub-sub-compile-file info)
1457
1458                 (finish-block-compilation)
1459                 (let ((object *compile-object*))
1460                   (etypecase object
1461                     (fasl-output (fasl-dump-source-info info object))
1462                     (core-object (fix-core-source-info info object))
1463                     (null)))
1464                 nil)))
1465       ;; Some errors are sufficiently bewildering that we just fail
1466       ;; immediately, without trying to recover and compile more of
1467       ;; the input file.
1468       (fatal-compiler-error (condition)
1469        (signal condition)
1470        (format *error-output*
1471                "~@<compilation aborted because of fatal error: ~2I~_~A~:>"
1472                condition)
1473        (values nil t t)))))
1474
1475 ;;; Return a pathname for the named file. The file must exist.
1476 (defun verify-source-file (pathname-designator)
1477   (let* ((pathname (pathname pathname-designator))
1478          (default-host (make-pathname :host (pathname-host pathname))))
1479     (flet ((try-with-type (path type error-p)
1480              (let ((new (merge-pathnames
1481                          path (make-pathname :type type
1482                                              :defaults default-host))))
1483                (if (probe-file new)
1484                    new
1485                    (and error-p (truename new))))))
1486       (cond ((typep pathname 'logical-pathname)
1487              (try-with-type pathname "LISP" t))
1488             ((probe-file pathname) pathname)
1489             ((try-with-type pathname "lisp"  nil))
1490             ((try-with-type pathname "lisp"  t))))))
1491
1492 (defun elapsed-time-to-string (tsec)
1493   (multiple-value-bind (tmin sec) (truncate tsec 60)
1494     (multiple-value-bind (thr min) (truncate tmin 60)
1495       (format nil "~D:~2,'0D:~2,'0D" thr min sec))))
1496
1497 ;;; Print some junk at the beginning and end of compilation.
1498 (defun start-error-output (source-info)
1499   (declare (type source-info source-info))
1500   (let ((file-info (source-info-file-info source-info)))
1501     (compiler-mumble "~&; compiling file ~S (written ~A):~%"
1502                      (namestring (file-info-name file-info))
1503                      (sb!int:format-universal-time nil
1504                                                    (file-info-write-date
1505                                                     file-info)
1506                                                    :style :government
1507                                                    :print-weekday nil
1508                                                    :print-timezone nil)))
1509   (values))
1510 (defun finish-error-output (source-info won)
1511   (declare (type source-info source-info))
1512   (compiler-mumble "~&; compilation ~:[aborted after~;finished in~] ~A~&"
1513                    won
1514                    (elapsed-time-to-string
1515                     (- (get-universal-time)
1516                        (source-info-start-time source-info))))
1517   (values))
1518
1519 ;;; Open some files and call SUB-COMPILE-FILE. If something unwinds
1520 ;;; out of the compile, then abort the writing of the output file, so
1521 ;;; that we don't overwrite it with known garbage.
1522 (defun sb!xc:compile-file
1523     (input-file
1524      &key
1525
1526      ;; ANSI options
1527      (output-file (cfp-output-file-default input-file))
1528      ;; FIXME: ANSI doesn't seem to say anything about
1529      ;; *COMPILE-VERBOSE* and *COMPILE-PRINT* being rebound by this
1530      ;; function..
1531      ((:verbose sb!xc:*compile-verbose*) sb!xc:*compile-verbose*)
1532      ((:print sb!xc:*compile-print*) sb!xc:*compile-print*)
1533      (external-format :default)
1534
1535      ;; extensions
1536      (trace-file nil)
1537      ((:block-compile *block-compile-arg*) nil))
1538
1539   #!+sb-doc
1540   "Compile INPUT-FILE, producing a corresponding fasl file and returning
1541    its filename. Besides the ANSI &KEY arguments :OUTPUT-FILE, :VERBOSE,
1542    :PRINT, and :EXTERNAL-FORMAT, the following extensions are supported:
1543      :TRACE-FILE
1544         If given, internal data structures are dumped to the specified
1545         file, or if a value of T is given, to a file of *.trace type
1546         derived from the input file name.
1547    Also, as a workaround for vaguely-non-ANSI behavior, the :BLOCK-COMPILE
1548    argument is quasi-supported, to determine whether multiple
1549    functions are compiled together as a unit, resolving function
1550    references at compile time. NIL means that global function names
1551    are never resolved at compilation time. Currently NIL is the
1552    default behavior, because although section 3.2.2.3, \"Semantic
1553    Constraints\", of the ANSI spec allows this behavior under all
1554    circumstances, the compiler's runtime scales badly when it
1555    tries to do this for large files. If/when this performance
1556    problem is fixed, the block compilation default behavior will
1557    probably be made dependent on the SPEED and COMPILATION-SPEED
1558    optimization values, and the :BLOCK-COMPILE argument will probably
1559    become deprecated."
1560
1561   (let* ((fasl-output nil)
1562          (output-file-name nil)
1563          (compile-won nil)
1564          (warnings-p nil)
1565          (failure-p t) ; T in case error keeps this from being set later
1566          (input-pathname (verify-source-file input-file))
1567          (source-info (make-file-source-info input-pathname external-format))
1568          (*compiler-trace-output* nil)) ; might be modified below
1569
1570     (unwind-protect
1571         (progn
1572           (when output-file
1573             (setq output-file-name
1574                   (sb!xc:compile-file-pathname input-file
1575                                                :output-file output-file))
1576             (setq fasl-output
1577                   (open-fasl-output output-file-name
1578                                     (namestring input-pathname))))
1579           (when trace-file
1580             (let* ((default-trace-file-pathname
1581                      (make-pathname :type "trace" :defaults input-pathname))
1582                    (trace-file-pathname
1583                     (if (eql trace-file t)
1584                         default-trace-file-pathname
1585                         (merge-pathnames trace-file
1586                                          default-trace-file-pathname))))
1587               (setf *compiler-trace-output*
1588                     (open trace-file-pathname
1589                           :if-exists :supersede
1590                           :direction :output))))
1591
1592           (when sb!xc:*compile-verbose*
1593             (start-error-output source-info))
1594           (let ((*compile-object* fasl-output)
1595                 dummy)
1596             (multiple-value-setq (dummy warnings-p failure-p)
1597               (sub-compile-file source-info)))
1598           (setq compile-won t))
1599
1600       (close-source-info source-info)
1601
1602       (when fasl-output
1603         (close-fasl-output fasl-output (not compile-won))
1604         (setq output-file-name
1605               (pathname (fasl-output-stream fasl-output)))
1606         (when (and compile-won sb!xc:*compile-verbose*)
1607           (compiler-mumble "~2&; ~A written~%" (namestring output-file-name))))
1608
1609       (when sb!xc:*compile-verbose*
1610         (finish-error-output source-info compile-won))
1611
1612       (when *compiler-trace-output*
1613         (close *compiler-trace-output*)))
1614
1615     (values (if output-file
1616                 ;; Hack around filesystem race condition...
1617                 (or (probe-file output-file-name) output-file-name)
1618                 nil)
1619             warnings-p
1620             failure-p)))
1621 \f
1622 ;;; a helper function for COMPILE-FILE-PATHNAME: the default for
1623 ;;; the OUTPUT-FILE argument
1624 ;;;
1625 ;;; ANSI: The defaults for the OUTPUT-FILE are taken from the pathname
1626 ;;; that results from merging the INPUT-FILE with the value of
1627 ;;; *DEFAULT-PATHNAME-DEFAULTS*, except that the type component should
1628 ;;; default to the appropriate implementation-defined default type for
1629 ;;; compiled files.
1630 (defun cfp-output-file-default (input-file)
1631   (let* ((defaults (merge-pathnames input-file *default-pathname-defaults*))
1632          (retyped (make-pathname :type *fasl-file-type* :defaults defaults)))
1633     retyped))
1634
1635 ;;; KLUDGE: Part of the ANSI spec for this seems contradictory:
1636 ;;;   If INPUT-FILE is a logical pathname and OUTPUT-FILE is unsupplied,
1637 ;;;   the result is a logical pathname. If INPUT-FILE is a logical
1638 ;;;   pathname, it is translated into a physical pathname as if by
1639 ;;;   calling TRANSLATE-LOGICAL-PATHNAME.
1640 ;;; So I haven't really tried to make this precisely ANSI-compatible
1641 ;;; at the level of e.g. whether it returns logical pathname or a
1642 ;;; physical pathname. Patches to make it more correct are welcome.
1643 ;;; -- WHN 2000-12-09
1644 (defun sb!xc:compile-file-pathname (input-file
1645                                     &key
1646                                     (output-file (cfp-output-file-default
1647                                                   input-file))
1648                                     &allow-other-keys)
1649   #!+sb-doc
1650   "Return a pathname describing what file COMPILE-FILE would write to given
1651    these arguments."
1652   (merge-pathnames output-file (merge-pathnames input-file)))
1653 \f
1654 ;;;; MAKE-LOAD-FORM stuff
1655
1656 ;;; The entry point for MAKE-LOAD-FORM support. When IR1 conversion
1657 ;;; finds a constant structure, it invokes this to arrange for proper
1658 ;;; dumping. If it turns out that the constant has already been
1659 ;;; dumped, then we don't need to do anything.
1660 ;;;
1661 ;;; If the constant hasn't been dumped, then we check to see whether
1662 ;;; we are in the process of creating it. We detect this by
1663 ;;; maintaining the special *CONSTANTS-BEING-CREATED* as a list of all
1664 ;;; the constants we are in the process of creating. Actually, each
1665 ;;; entry is a list of the constant and any init forms that need to be
1666 ;;; processed on behalf of that constant.
1667 ;;;
1668 ;;; It's not necessarily an error for this to happen. If we are
1669 ;;; processing the init form for some object that showed up *after*
1670 ;;; the original reference to this constant, then we just need to
1671 ;;; defer the processing of that init form. To detect this, we
1672 ;;; maintain *CONSTANTS-CREATED-SINCE-LAST-INIT* as a list of the
1673 ;;; constants created since the last time we started processing an
1674 ;;; init form. If the constant passed to emit-make-load-form shows up
1675 ;;; in this list, then there is a circular chain through creation
1676 ;;; forms, which is an error.
1677 ;;;
1678 ;;; If there is some intervening init form, then we blow out of
1679 ;;; processing it by throwing to the tag PENDING-INIT. The value we
1680 ;;; throw is the entry from *CONSTANTS-BEING-CREATED*. This is so the
1681 ;;; offending init form can be tacked onto the init forms for the
1682 ;;; circular object.
1683 ;;;
1684 ;;; If the constant doesn't show up in *CONSTANTS-BEING-CREATED*, then
1685 ;;; we have to create it. We call MAKE-LOAD-FORM and check to see
1686 ;;; whether the creation form is the magic value
1687 ;;; :SB-JUST-DUMP-IT-NORMALLY. If it is, then we don't do anything. The
1688 ;;; dumper will eventually get its hands on the object and use the
1689 ;;; normal structure dumping noise on it.
1690 ;;;
1691 ;;; Otherwise, we bind *CONSTANTS-BEING-CREATED* and
1692 ;;; *CONSTANTS-CREATED-SINCE- LAST-INIT* and compile the creation form
1693 ;;; much the way LOAD-TIME-VALUE does. When this finishes, we tell the
1694 ;;; dumper to use that result instead whenever it sees this constant.
1695 ;;;
1696 ;;; Now we try to compile the init form. We bind
1697 ;;; *CONSTANTS-CREATED-SINCE-LAST-INIT* to NIL and compile the init
1698 ;;; form (and any init forms that were added because of circularity
1699 ;;; detection). If this works, great. If not, we add the init forms to
1700 ;;; the init forms for the object that caused the problems and let it
1701 ;;; deal with it.
1702 (defvar *constants-being-created* nil)
1703 (defvar *constants-created-since-last-init* nil)
1704 ;;; FIXME: Shouldn't these^ variables be unbound outside LET forms?
1705 (defun emit-make-load-form (constant)
1706   (aver (fasl-output-p *compile-object*))
1707   (unless (or (fasl-constant-already-dumped-p constant *compile-object*)
1708               ;; KLUDGE: This special hack is because I was too lazy
1709               ;; to rework DEF!STRUCT so that the MAKE-LOAD-FORM
1710               ;; function of LAYOUT returns nontrivial forms when
1711               ;; building the cross-compiler but :IGNORE-IT when
1712               ;; cross-compiling or running under the target Lisp. --
1713               ;; WHN 19990914
1714               #+sb-xc-host (typep constant 'layout))
1715     (let ((circular-ref (assoc constant *constants-being-created* :test #'eq)))
1716       (when circular-ref
1717         (when (find constant *constants-created-since-last-init* :test #'eq)
1718           (throw constant t))
1719         (throw 'pending-init circular-ref)))
1720     (multiple-value-bind (creation-form init-form)
1721         (handler-case
1722             (sb!xc:make-load-form constant (make-null-lexenv))
1723           (error (condition)
1724             (compiler-error condition)))
1725       (case creation-form
1726         (:sb-just-dump-it-normally
1727          (fasl-validate-structure constant *compile-object*)
1728          t)
1729         (:ignore-it
1730          nil)
1731         (t
1732          (when (fasl-constant-already-dumped-p constant *compile-object*)
1733            (return-from emit-make-load-form nil))
1734          (let* ((name (let ((*print-level* 1) (*print-length* 2))
1735                         (with-output-to-string (stream)
1736                           (write constant :stream stream))))
1737                 (info (if init-form
1738                           (list constant name init-form)
1739                           (list constant))))
1740            (let ((*constants-being-created*
1741                   (cons info *constants-being-created*))
1742                  (*constants-created-since-last-init*
1743                   (cons constant *constants-created-since-last-init*)))
1744              (when
1745                  (catch constant
1746                    (fasl-note-handle-for-constant
1747                     constant
1748                     (compile-load-time-value
1749                      creation-form)
1750                     *compile-object*)
1751                    nil)
1752                (compiler-error "circular references in creation form for ~S"
1753                                constant)))
1754            (when (cdr info)
1755              (let* ((*constants-created-since-last-init* nil)
1756                     (circular-ref
1757                      (catch 'pending-init
1758                        (loop for (name form) on (cdr info) by #'cddr
1759                          collect name into names
1760                          collect form into forms
1761                          finally (compile-make-load-form-init-forms forms))
1762                        nil)))
1763                (when circular-ref
1764                  (setf (cdr circular-ref)
1765                        (append (cdr circular-ref) (cdr info))))))))))))
1766
1767 \f
1768 ;;;; Host compile time definitions
1769 #+sb-xc-host
1770 (defun compile-in-lexenv (name lambda lexenv)
1771   (declare (ignore lexenv))
1772   (compile name lambda))
1773
1774 #+sb-xc-host
1775 (defun eval-in-lexenv (form lexenv)
1776   (declare (ignore lexenv))
1777   (eval form))