src/compiler/main.lisp

   1 ;;;; the top level interfaces to the compiler, plus some other
   2 ;;;; compiler-related stuff (e.g. CL:CALL-ARGUMENTS-LIMIT) which
   3 ;;;; doesn't obviously belong anywhere else
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15
  16 ;;; FIXME: Doesn't this belong somewhere else, like early-c.lisp?
  17 (declaim (special *constants* *free-vars* *component-being-compiled*
  18                   *code-vector* *next-location* *result-fixups*
  19                   *free-funs* *source-paths*
  20                   *seen-blocks* *seen-funs* *list-conflicts-table*
  21                   *continuation-number* *continuation-numbers*
  22                   *number-continuations* *tn-id* *tn-ids* *id-tns*
  23                   *label-ids* *label-id* *id-labels*
  24                   *undefined-warnings* *compiler-error-count*
  25                   *compiler-warning-count* *compiler-style-warning-count*
  26                   *compiler-note-count*
  27                   *compiler-error-bailout*
  28                   #!+sb-show *compiler-trace-output*
  29                   *last-source-context* *last-original-source*
  30                   *last-source-form* *last-format-string* *last-format-args*
  31                   *last-message-count* *lexenv* *fun-names-in-this-file*))
  32
  33 ;;; Whether call of a function which cannot be defined causes a full
  34 ;;; warning.
  35 (defvar *flame-on-necessarily-undefined-function* nil)
  36
  37 (defvar *check-consistency* nil)
  38 (defvar *all-components*)
  39
  40 ;;; Bind this to a stream to capture various internal debugging output.
  41 (defvar *compiler-trace-output* nil)
  42
  43 ;;; The current block compilation state. These are initialized to the
  44 ;;; :BLOCK-COMPILE and :ENTRY-POINTS arguments that COMPILE-FILE was
  45 ;;; called with.
  46 ;;;
  47 ;;; *BLOCK-COMPILE-ARG* holds the original value of the :BLOCK-COMPILE
  48 ;;; argument, which overrides any internal declarations.
  49 (defvar *block-compile*)
  50 (defvar *block-compile-arg*)
  51 (declaim (type (member nil t :specified) *block-compile* *block-compile-arg*))
  52 (defvar *entry-points*)
  53 (declaim (list *entry-points*))
  54
  55 ;;; When block compiling, used by PROCESS-FORM to accumulate top level
  56 ;;; lambdas resulting from compiling subforms. (In reverse order.)
  57 (defvar *toplevel-lambdas*)
  58 (declaim (list *toplevel-lambdas*))
  59
  60 (defvar sb!xc:*compile-verbose* t
  61   #!+sb-doc
  62   "The default for the :VERBOSE argument to COMPILE-FILE.")
  63 (defvar sb!xc:*compile-print* t
  64   #!+sb-doc
  65   "The default for the :PRINT argument to COMPILE-FILE.")
  66 (defvar *compile-progress* nil
  67   #!+sb-doc
  68   "When this is true, the compiler prints to *ERROR-OUTPUT* progress
  69   information about the phases of compilation of each function. (This
  70   is useful mainly in large block compilations.)")
  71
  72 (defvar sb!xc:*compile-file-pathname* nil
  73   #!+sb-doc
  74   "The defaulted pathname of the file currently being compiled, or NIL if not
  75   compiling.")
  76 (defvar sb!xc:*compile-file-truename* nil
  77   #!+sb-doc
  78   "The TRUENAME of the file currently being compiled, or NIL if not
  79   compiling.")
  80
  81 (declaim (type (or pathname null)
  82                sb!xc:*compile-file-pathname*
  83                sb!xc:*compile-file-truename*))
  84
  85 ;;; the SOURCE-INFO structure for the current compilation. This is
  86 ;;; null globally to indicate that we aren't currently in any
  87 ;;; identifiable compilation.
  88 (defvar *source-info* nil)
  89
  90 ;;; This is true if we are within a WITH-COMPILATION-UNIT form (which
  91 ;;; normally causes nested uses to be no-ops).
  92 (defvar *in-compilation-unit* nil)
  93
  94 ;;; Count of the number of compilation units dynamically enclosed by
  95 ;;; the current active WITH-COMPILATION-UNIT that were unwound out of.
  96 (defvar *aborted-compilation-unit-count*)
  97
  98 ;;; Mumble conditional on *COMPILE-PROGRESS*.
  99 (defun maybe-mumble (&rest foo)
 100   (when *compile-progress*
 101     (compiler-mumble "~&")
 102     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 103        (apply #'compiler-mumble foo))))
 104
 105 (deftype object () '(or fasl-output core-object null))
 106
 107 (defvar *compile-object* nil)
 108 (declaim (type object *compile-object*))
 109 \f
 110 ;;;; WITH-COMPILATION-UNIT and WITH-COMPILATION-VALUES
 111
 112 (defmacro sb!xc:with-compilation-unit (options &body body)
 113   #!+sb-doc
 114   "WITH-COMPILATION-UNIT ({Key Value}*) Form*
 115   This form affects compilations that take place within its dynamic extent. It
 116   is intended to be wrapped around the compilation of all files in the same
 117   system. These keywords are defined:
 118     :OVERRIDE Boolean-Form
 119         One of the effects of this form is to delay undefined warnings
 120         until the end of the form, instead of giving them at the end of each
 121         compilation. If OVERRIDE is NIL (the default), then the outermost
 122         WITH-COMPILATION-UNIT form grabs the undefined warnings. Specifying
 123         OVERRIDE true causes that form to grab any enclosed warnings, even if
 124         it is enclosed by another WITH-COMPILATION-UNIT."
 125   `(%with-compilation-unit (lambda () ,@body) ,@options))
 126
 127 (defun %with-compilation-unit (fn &key override)
 128   (declare (type function fn))
 129   (let ((succeeded-p nil))
 130     (if (and *in-compilation-unit* (not override))
 131         ;; Inside another WITH-COMPILATION-UNIT, a WITH-COMPILATION-UNIT is
 132         ;; ordinarily (unless OVERRIDE) basically a no-op.
 133         (unwind-protect
 134              (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 135           (unless succeeded-p
 136             (incf *aborted-compilation-unit-count*)))
 137         (let ((*aborted-compilation-unit-count* 0)
 138               (*compiler-error-count* 0)
 139               (*compiler-warning-count* 0)
 140               (*compiler-style-warning-count* 0)
 141               (*compiler-note-count* 0)
 142               (*undefined-warnings* nil)
 143               (*in-compilation-unit* t))
 144           (sb!thread:with-recursive-lock (*big-compiler-lock*)
 145             (handler-bind ((parse-unknown-type
 146                             (lambda (c)
 147                               (note-undefined-reference
 148                                (parse-unknown-type-specifier c)
 149                                :type))))
 150               (unwind-protect
 151                    (multiple-value-prog1 (funcall fn) (setf succeeded-p t))
 152                 (unless succeeded-p
 153                   (incf *aborted-compilation-unit-count*))
 154                 (summarize-compilation-unit (not succeeded-p)))))))))
 155
 156 ;;; Is FUN-NAME something that no conforming program can rely on
 157 ;;; defining as a function?
 158 (defun fun-name-reserved-by-ansi-p (fun-name)
 159   (eq (symbol-package (fun-name-block-name fun-name))
 160       *cl-package*))
 161
 162 ;;; This is to be called at the end of a compilation unit. It signals
 163 ;;; any residual warnings about unknown stuff, then prints the total
 164 ;;; error counts. ABORT-P should be true when the compilation unit was
 165 ;;; aborted by throwing out. ABORT-COUNT is the number of dynamically
 166 ;;; enclosed nested compilation units that were aborted.
 167 (defun summarize-compilation-unit (abort-p)
 168   (unless abort-p
 169     (handler-bind ((style-warning #'compiler-style-warning-handler)
 170                    (warning #'compiler-warning-handler))
 171
 172       (let ((undefs (sort *undefined-warnings* #'string<
 173                           :key (lambda (x)
 174                                  (let ((x (undefined-warning-name x)))
 175                                    (if (symbolp x)
 176                                        (symbol-name x)
 177                                        (prin1-to-string x)))))))
 178         (dolist (undef undefs)
 179           (let ((name (undefined-warning-name undef))
 180                 (kind (undefined-warning-kind undef))
 181                 (warnings (undefined-warning-warnings undef))
 182                 (undefined-warning-count (undefined-warning-count undef)))
 183             (dolist (*compiler-error-context* warnings)
 184               (if #-sb-xc-host (and (eq kind :function)
 185                                     (fun-name-reserved-by-ansi-p name)
 186                                     *flame-on-necessarily-undefined-function*)
 187                   #+sb-xc-host nil
 188                   (case name
 189                     ((declare)
 190                      (compiler-warn
 191                       "~@<There is no function named ~S. References to ~S in ~
 192                        some contexts (like starts of blocks) have special ~
 193                        meaning, but here it would have to be a function, ~
 194                        and that shouldn't be right.~:@>"
 195                       name name))
 196                     (t
 197                      (compiler-warn
 198                       "~@<The ~(~A~) ~S is undefined, and its name is ~
 199                        reserved by ANSI CL so that even if it it were ~
 200                        defined later, the code doing so would not be ~
 201                        portable.~:@>"
 202                       kind name)))
 203                   (if (eq kind :variable)
 204                       (compiler-warn "undefined ~(~A~): ~S" kind name)
 205                       (compiler-style-warn "undefined ~(~A~): ~S" kind name))))
 206             (let ((warn-count (length warnings)))
 207               (when (and warnings (> undefined-warning-count warn-count))
 208                 (let ((more (- undefined-warning-count warn-count)))
 209                   (if (eq kind :variable)
 210                       (compiler-warn
 211                        "~W more use~:P of undefined ~(~A~) ~S"
 212                        more kind name)
 213                       (compiler-style-warn
 214                        "~W more use~:P of undefined ~(~A~) ~S"
 215                        more kind name)))))))
 216
 217         (dolist (kind '(:variable :function :type))
 218           (let ((summary (mapcar #'undefined-warning-name
 219                                  (remove kind undefs :test #'neq
 220                                          :key #'undefined-warning-kind))))
 221             (when summary
 222               (if (eq kind :variable)
 223                   (compiler-warn
 224                    "~:[This ~(~A~) is~;These ~(~A~)s are~] undefined:~
 225                     ~%  ~{~<~%  ~1:;~S~>~^ ~}"
 226                    (cdr summary) kind summary)
 227                   (compiler-style-warn
 228                    "~:[This ~(~A~) is~;These ~(~A~)s are~] undefined:~
 229                    ~%  ~{~<~%  ~1:;~S~>~^ ~}"
 230                    (cdr summary) kind summary))))))))
 231
 232   (unless (and (not abort-p)
 233                (zerop *aborted-compilation-unit-count*)
 234                (zerop *compiler-error-count*)
 235                (zerop *compiler-warning-count*)
 236                (zerop *compiler-style-warning-count*)
 237                (zerop *compiler-note-count*))
 238     (format *error-output* "~&")
 239     (pprint-logical-block (*error-output* nil :per-line-prefix "; ")
 240       (compiler-mumble "compilation unit ~:[finished~;aborted~]~
 241                        ~[~:;~:*~&  caught ~W fatal ERROR condition~:P~]~
 242                        ~[~:;~:*~&  caught ~W ERROR condition~:P~]~
 243                        ~[~:;~:*~&  caught ~W WARNING condition~:P~]~
 244                        ~[~:;~:*~&  caught ~W STYLE-WARNING condition~:P~]~
 245                        ~[~:;~:*~&  printed ~W note~:P~]"
 246                        abort-p
 247                        *aborted-compilation-unit-count*
 248                        *compiler-error-count*
 249                        *compiler-warning-count*
 250                        *compiler-style-warning-count*
 251                        *compiler-note-count*)))
 252   (format *error-output* "~&"))
 253
 254 ;;; Evaluate BODY, then return (VALUES BODY-VALUE WARNINGS-P
 255 ;;; FAILURE-P), where BODY-VALUE is the first value of the body, and
 256 ;;; WARNINGS-P and FAILURE-P are as in CL:COMPILE or CL:COMPILE-FILE.
 257 ;;; This also wraps up WITH-IR1-NAMESPACE functionality.
 258 (defmacro with-compilation-values (&body body)
 259   `(with-ir1-namespace
 260     (let ((*warnings-p* nil)
 261           (*failure-p* nil))
 262       (values (progn ,@body)
 263               *warnings-p*
 264               *failure-p*))))
 265 \f
 266 ;;;; component compilation
 267
 268 (defparameter *max-optimize-iterations* 3 ; ARB
 269   #!+sb-doc
 270   "The upper limit on the number of times that we will consecutively do IR1
 271   optimization that doesn't introduce any new code. A finite limit is
 272   necessary, since type inference may take arbitrarily long to converge.")
 273
 274 (defevent ir1-optimize-until-done "IR1-OPTIMIZE-UNTIL-DONE called")
 275 (defevent ir1-optimize-maxed-out "hit *MAX-OPTIMIZE-ITERATIONS* limit")
 276
 277 ;;; Repeatedly optimize COMPONENT until no further optimizations can
 278 ;;; be found or we hit our iteration limit. When we hit the limit, we
 279 ;;; clear the component and block REOPTIMIZE flags to discourage the
 280 ;;; next optimization attempt from pounding on the same code.
 281 (defun ir1-optimize-until-done (component)
 282   (declare (type component component))
 283   (maybe-mumble "opt")
 284   (event ir1-optimize-until-done)
 285   (let ((count 0)
 286         (cleared-reanalyze nil))
 287     (loop
 288       (when (component-reanalyze component)
 289         (setq count 0)
 290         (setq cleared-reanalyze t)
 291         (setf (component-reanalyze component) nil))
 292       (setf (component-reoptimize component) nil)
 293       (ir1-optimize component)
 294       (cond ((component-reoptimize component)
 295              (incf count)
 296              (when (= count *max-optimize-iterations*)
 297                (maybe-mumble "*")
 298                (cond ((retry-delayed-ir1-transforms :optimize)
 299                       (maybe-mumble "+")
 300                       (setq count 0))
 301                      (t
 302                       (event ir1-optimize-maxed-out)
 303                       (setf (component-reoptimize component) nil)
 304                       (do-blocks (block component)
 305                         (setf (block-reoptimize block) nil))
 306                       (return)))))
 307             ((retry-delayed-ir1-transforms :optimize)
 308              (setf count 0)
 309              (maybe-mumble "+"))
 310             (t
 311              (maybe-mumble " ")
 312              (return)))
 313       (maybe-mumble "."))
 314     (when cleared-reanalyze
 315       (setf (component-reanalyze component) t)))
 316   (values))
 317
 318 (defparameter *constraint-propagate* t)
 319
 320 ;;; KLUDGE: This was bumped from 5 to 10 in a DTC patch ported by MNA
 321 ;;; from CMU CL into sbcl-0.6.11.44, the same one which allowed IR1
 322 ;;; transforms to be delayed. Either DTC or MNA or both didn't explain
 323 ;;; why, and I don't know what the rationale was. -- WHN 2001-04-28
 324 ;;;
 325 ;;; FIXME: It would be good to document why it's important to have a
 326 ;;; large value here, and what the drawbacks of an excessively large
 327 ;;; value are; and it might also be good to make it depend on
 328 ;;; optimization policy.
 329 (defparameter *reoptimize-after-type-check-max* 10)
 330
 331 (defevent reoptimize-maxed-out
 332   "*REOPTIMIZE-AFTER-TYPE-CHECK-MAX* exceeded.")
 333
 334 ;;; Iterate doing FIND-DFO until no new dead code is discovered.
 335 (defun dfo-as-needed (component)
 336   (declare (type component component))
 337   (when (component-reanalyze component)
 338     (maybe-mumble "DFO")
 339     (loop
 340       (find-dfo component)
 341       (unless (component-reanalyze component)
 342         (maybe-mumble " ")
 343         (return))
 344       (maybe-mumble ".")))
 345   (values))
 346
 347 ;;; Do all the IR1 phases for a non-top-level component.
 348 (defun ir1-phases (component)
 349   (declare (type component component))
 350   (aver-live-component component)
 351   (let ((*constraint-number* 0)
 352         (loop-count 1)
 353         (*delayed-ir1-transforms* nil))
 354     (declare (special *constraint-number* *delayed-ir1-transforms*))
 355     (loop
 356       (ir1-optimize-until-done component)
 357       (when (or (component-new-functionals component)
 358                 (component-reanalyze-functionals component))
 359         (maybe-mumble "locall ")
 360         (locall-analyze-component component))
 361       (dfo-as-needed component)
 362       (when *constraint-propagate*
 363         (maybe-mumble "constraint ")
 364         (constraint-propagate component))
 365       (when (retry-delayed-ir1-transforms :constraint)
 366         (maybe-mumble "Rtran "))
 367       (flet ((want-reoptimization-p ()
 368                (or (component-reoptimize component)
 369                    (component-reanalyze component)
 370                    (component-new-functionals component)
 371                    (component-reanalyze-functionals component))))
 372         (unless (and (want-reoptimization-p)
 373                      ;; We delay the generation of type checks until
 374                      ;; the type constraints have had time to
 375                      ;; propagate, else the compiler can confuse itself.
 376                      (< loop-count (- *reoptimize-after-type-check-max* 4)))
 377           (maybe-mumble "type ")
 378           (generate-type-checks component)
 379           (unless (want-reoptimization-p)
 380             (return))))
 381       (when (>= loop-count *reoptimize-after-type-check-max*)
 382         (maybe-mumble "[reoptimize limit]")
 383         (event reoptimize-maxed-out)
 384         (return))
 385       (incf loop-count)))
 386
 387   (ir1-finalize component)
 388   (values))
 389
 390 (defun %compile-component (component)
 391   (let ((*code-segment* nil)
 392         (*elsewhere* nil))
 393     (maybe-mumble "GTN ")
 394     (gtn-analyze component)
 395     (maybe-mumble "LTN ")
 396     (ltn-analyze component)
 397     (dfo-as-needed component)
 398     (maybe-mumble "control ")
 399     (control-analyze component #'make-ir2-block)
 400
 401     (when (ir2-component-values-receivers (component-info component))
 402       (maybe-mumble "stack ")
 403       (stack-analyze component)
 404       ;; Assign BLOCK-NUMBER for any cleanup blocks introduced by
 405       ;; stack analysis. There shouldn't be any unreachable code after
 406       ;; control, so this won't delete anything.
 407       (dfo-as-needed component))
 408
 409     (unwind-protect
 410         (progn
 411           (maybe-mumble "IR2tran ")
 412           (init-assembler)
 413           (entry-analyze component)
 414           (ir2-convert component)
 415
 416           (when (policy *lexenv* (>= speed compilation-speed))
 417             (maybe-mumble "copy ")
 418             (copy-propagate component))
 419
 420           (select-representations component)
 421
 422           (when *check-consistency*
 423             (maybe-mumble "check2 ")
 424             (check-ir2-consistency component))
 425
 426           (delete-unreferenced-tns component)
 427
 428           (maybe-mumble "life ")
 429           (lifetime-analyze component)
 430
 431           (when *compile-progress*
 432             (compiler-mumble "") ; Sync before doing more output.
 433             (pre-pack-tn-stats component *error-output*))
 434
 435           (when *check-consistency*
 436             (maybe-mumble "check-life ")
 437             (check-life-consistency component))
 438
 439           (maybe-mumble "pack ")
 440           (pack component)
 441
 442           (when *check-consistency*
 443             (maybe-mumble "check-pack ")
 444             (check-pack-consistency component))
 445
 446           (when *compiler-trace-output*
 447             (describe-component component *compiler-trace-output*)
 448             (describe-ir2-component component *compiler-trace-output*))
 449
 450           (maybe-mumble "code ")
 451           (multiple-value-bind (code-length trace-table fixup-notes)
 452               (generate-code component)
 453
 454             #-sb-xc-host
 455             (when *compiler-trace-output*
 456               (format *compiler-trace-output*
 457                       "~|~%disassembly of code for ~S~2%" component)
 458               (sb!disassem:disassemble-assem-segment *code-segment*
 459                                                      *compiler-trace-output*))
 460
 461             (etypecase *compile-object*
 462               (fasl-output
 463                (maybe-mumble "fasl")
 464                (fasl-dump-component component
 465                                     *code-segment*
 466                                     code-length
 467                                     trace-table
 468                                     fixup-notes
 469                                     *compile-object*))
 470               (core-object
 471                (maybe-mumble "core")
 472                (make-core-component component
 473                                     *code-segment*
 474                                     code-length
 475                                     trace-table
 476                                     fixup-notes
 477                                     *compile-object*))
 478               (null))))))
 479
 480   ;; We're done, so don't bother keeping anything around.
 481   (setf (component-info component) :dead)
 482
 483   (values))
 484
 485 ;;; Delete components with no external entry points before we try to
 486 ;;; generate code. Unreachable closures can cause IR2 conversion to
 487 ;;; puke on itself, since it is the reference to the closure which
 488 ;;; normally causes the components to be combined.
 489 (defun delete-if-no-entries (component)
 490   (dolist (fun (component-lambdas component) (delete-component component))
 491     (when (functional-has-external-references-p fun)
 492       (return))
 493     (case (functional-kind fun)
 494       (:toplevel (return))
 495       (:external
 496        (unless (every (lambda (ref)
 497                         (eq (node-component ref) component))
 498                       (leaf-refs fun))
 499          (return))))))
 500
 501 (defun compile-component (component)
 502
 503   ;; miscellaneous sanity checks
 504   ;;
 505   ;; FIXME: These are basically pretty wimpy compared to the checks done
 506   ;; by the old CHECK-IR1-CONSISTENCY code. It would be really nice to
 507   ;; make those internal consistency checks work again and use them.
 508   (aver-live-component component)
 509   (do-blocks (block component)
 510     (aver (eql (block-component block) component)))
 511   (dolist (lambda (component-lambdas component))
 512     ;; sanity check to prevent weirdness from propagating insidiously as
 513     ;; far from its root cause as it did in bug 138: Make sure that
 514     ;; thing-to-COMPONENT links are consistent.
 515     (aver (eql (lambda-component lambda) component))
 516     (aver (eql (node-component (lambda-bind lambda)) component)))
 517
 518   (let* ((*component-being-compiled* component))
 519     (when sb!xc:*compile-print*
 520       (compiler-mumble "~&; compiling ~A: " (component-name component)))
 521
 522     (ir1-phases component)
 523
 524     ;; FIXME: What is MAYBE-MUMBLE for? Do we need it any more?
 525     (maybe-mumble "env ")
 526     (physenv-analyze component)
 527     (dfo-as-needed component)
 528
 529     (delete-if-no-entries component)
 530
 531     (unless (eq (block-next (component-head component))
 532                 (component-tail component))
 533       (%compile-component component)))
 534
 535   (clear-constant-info)
 536
 537   (when sb!xc:*compile-print*
 538     (compiler-mumble "~&"))
 539
 540   (values))
 541 \f
 542 ;;;; clearing global data structures
 543 ;;;;
 544 ;;;; FIXME: Is it possible to get rid of this stuff, getting rid of
 545 ;;;; global data structures entirely when possible and consing up the
 546 ;;;; others from scratch instead of clearing and reusing them?
 547
 548 ;;; Clear the INFO in constants in the *FREE-VARS*, etc. In
 549 ;;; addition to allowing stuff to be reclaimed, this is required for
 550 ;;; correct assignment of constant offsets, since we need to assign a
 551 ;;; new offset for each component. We don't clear the FUNCTIONAL-INFO
 552 ;;; slots, since they are used to keep track of functions across
 553 ;;; component boundaries.
 554 (defun clear-constant-info ()
 555   (maphash (lambda (k v)
 556              (declare (ignore k))
 557              (setf (leaf-info v) nil))
 558            *constants*)
 559   (maphash (lambda (k v)
 560              (declare (ignore k))
 561              (when (constant-p v)
 562                (setf (leaf-info v) nil)))
 563            *free-vars*)
 564   (values))
 565
 566 ;;; Blow away the REFS for all global variables, and let COMPONENT
 567 ;;; be recycled.
 568 (defun clear-ir1-info (component)
 569   (declare (type component component))
 570   (labels ((blast (x)
 571              (maphash (lambda (k v)
 572                         (declare (ignore k))
 573                         (when (leaf-p v)
 574                           (setf (leaf-refs v)
 575                                 (delete-if #'here-p (leaf-refs v)))
 576                           (when (basic-var-p v)
 577                             (setf (basic-var-sets v)
 578                                   (delete-if #'here-p (basic-var-sets v))))))
 579                       x))
 580            (here-p (x)
 581              (eq (node-component x) component)))
 582     (blast *free-vars*)
 583     (blast *free-funs*)
 584     (blast *constants*))
 585   (values))
 586
 587 ;;; Clear global variables used by the compiler.
 588 ;;;
 589 ;;; FIXME: It seems kinda nasty and unmaintainable to have to do this,
 590 ;;; and it adds overhead even when people aren't using the compiler.
 591 ;;; Perhaps we could make these global vars unbound except when
 592 ;;; actually in use, so that this function could go away.
 593 (defun clear-stuff (&optional (debug-too t))
 594
 595   ;; Clear global tables.
 596   (when (boundp '*free-funs*)
 597     (clrhash *free-funs*)
 598     (clrhash *free-vars*)
 599     (clrhash *constants*))
 600
 601   ;; Clear debug counters and tables.
 602   (clrhash *seen-blocks*)
 603   (clrhash *seen-funs*)
 604   (clrhash *list-conflicts-table*)
 605
 606   (when debug-too
 607     (clrhash *continuation-numbers*)
 608     (clrhash *number-continuations*)
 609     (setq *continuation-number* 0)
 610     (clrhash *tn-ids*)
 611     (clrhash *id-tns*)
 612     (setq *tn-id* 0)
 613     (clrhash *label-ids*)
 614     (clrhash *id-labels*)
 615     (setq *label-id* 0))
 616
 617   ;; (Note: The CMU CL code used to set CL::*GENSYM-COUNTER* to zero here.
 618   ;; Superficially, this seemed harmful -- the user could reasonably be
 619   ;; surprised if *GENSYM-COUNTER* turned back to zero when something was
 620   ;; compiled. A closer inspection showed that this actually turned out to be
 621   ;; harmless in practice, because CLEAR-STUFF was only called from within
 622   ;; forms which bound CL::*GENSYM-COUNTER* to zero. However, this means that
 623   ;; even though zeroing CL::*GENSYM-COUNTER* here turned out to be harmless in
 624   ;; practice, it was also useless in practice. So we don't do it any more.)
 625
 626   (values))
 627 \f
 628 ;;;; trace output
 629
 630 ;;; Print out some useful info about COMPONENT to STREAM.
 631 (defun describe-component (component *standard-output*)
 632   (declare (type component component))
 633   (format t "~|~%;;;; component: ~S~2%" (component-name component))
 634   (print-all-blocks component)
 635   (values))
 636
 637 (defun describe-ir2-component (component *standard-output*)
 638   (format t "~%~|~%;;;; IR2 component: ~S~2%" (component-name component))
 639   (format t "entries:~%")
 640   (dolist (entry (ir2-component-entries (component-info component)))
 641     (format t "~4TL~D: ~S~:[~; [closure]~]~%"
 642             (label-id (entry-info-offset entry))
 643             (entry-info-name entry)
 644             (entry-info-closure-p entry)))
 645   (terpri)
 646   (pre-pack-tn-stats component *standard-output*)
 647   (terpri)
 648   (print-ir2-blocks component)
 649   (terpri)
 650   (values))
 651 \f
 652 ;;;; file reading
 653 ;;;;
 654 ;;;; When reading from a file, we have to keep track of some source
 655 ;;;; information. We also exploit our ability to back up for printing
 656 ;;;; the error context and for recovering from errors.
 657 ;;;;
 658 ;;;; The interface we provide to this stuff is the stream-oid
 659 ;;;; SOURCE-INFO structure. The bookkeeping is done as a side effect
 660 ;;;; of getting the next source form.
 661
 662 ;;; A FILE-INFO structure holds all the source information for a
 663 ;;; given file.
 664 (defstruct (file-info (:copier nil))
 665   ;; If a file, the truename of the corresponding source file. If from
 666   ;; a Lisp form, :LISP. If from a stream, :STREAM.
 667   (name (missing-arg) :type (or pathname (member :lisp :stream)))
 668   ;; the defaulted, but not necessarily absolute file name (i.e. prior
 669   ;; to TRUENAME call.) Null if not a file. This is used to set
 670   ;; *COMPILE-FILE-PATHNAME*, and if absolute, is dumped in the
 671   ;; debug-info.
 672   (untruename nil :type (or pathname null))
 673   ;; the file's write date (if relevant)
 674   (write-date nil :type (or unsigned-byte null))
 675   ;; the source path root number of the first form in this file (i.e.
 676   ;; the total number of forms converted previously in this
 677   ;; compilation)
 678   (source-root 0 :type unsigned-byte)
 679   ;; parallel vectors containing the forms read out of the file and
 680   ;; the file positions that reading of each form started at (i.e. the
 681   ;; end of the previous form)
 682   (forms (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t))
 683   (positions (make-array 10 :fill-pointer 0 :adjustable t) :type (vector t)))
 684
 685 ;;; The SOURCE-INFO structure provides a handle on all the source
 686 ;;; information for an entire compilation.
 687 (defstruct (source-info
 688             #-no-ansi-print-object
 689             (:print-object (lambda (s stream)
 690                              (print-unreadable-object (s stream :type t))))
 691             (:copier nil))
 692   ;; the UT that compilation started at
 693   (start-time (get-universal-time) :type unsigned-byte)
 694   ;; the FILE-INFO structure for this compilation
 695   (file-info nil :type (or file-info null))
 696   ;; the stream that we are using to read the FILE-INFO, or NIL if
 697   ;; no stream has been opened yet
 698   (stream nil :type (or stream null)))
 699
 700 ;;; Given a pathname, return a SOURCE-INFO structure.
 701 (defun make-file-source-info (file)
 702   (let ((file-info (make-file-info :name (truename file)
 703                                    :untruename file
 704                                    :write-date (file-write-date file))))
 705
 706     (make-source-info :file-info file-info)))
 707
 708 ;;; Return a SOURCE-INFO to describe the incremental compilation of FORM.
 709 (defun make-lisp-source-info (form)
 710   (make-source-info :start-time (get-universal-time)
 711                     :file-info (make-file-info :name :lisp
 712                                                :forms (vector form)
 713                                                :positions '#(0))))
 714
 715 ;;; Return a SOURCE-INFO which will read from STREAM.
 716 (defun make-stream-source-info (stream)
 717   (let ((file-info (make-file-info :name :stream)))
 718     (make-source-info :file-info file-info
 719                       :stream stream)))
 720
 721 ;;; Return a form read from STREAM; or for EOF use the trick,
 722 ;;; popularized by Kent Pitman, of returning STREAM itself. If an
 723 ;;; error happens, then convert it to standard abort-the-compilation
 724 ;;; error condition (possibly recording some extra location
 725 ;;; information).
 726 (defun read-for-compile-file (stream position)
 727   (handler-case (read stream nil stream)
 728     (reader-error (condition)
 729      (error 'input-error-in-compile-file
 730             :error condition
 731             ;; We don't need to supply :POSITION here because
 732             ;; READER-ERRORs already know their position in the file.
 733             ))
 734     ;; ANSI, in its wisdom, says that READ should return END-OF-FILE
 735     ;; (and that this is not a READER-ERROR) when it encounters end of
 736     ;; file in the middle of something it's trying to read.
 737     (end-of-file (condition)
 738      (error 'input-error-in-compile-file
 739             :error condition
 740             ;; We need to supply :POSITION here because the END-OF-FILE
 741             ;; condition doesn't carry the position that the user
 742             ;; probably cares about, where the failed READ began.
 743             :position position))))
 744
 745 ;;; If STREAM is present, return it, otherwise open a stream to the
 746 ;;; current file. There must be a current file.
 747 ;;;
 748 ;;; FIXME: This is probably an unnecessarily roundabout way to do
 749 ;;; things now that we process a single file in COMPILE-FILE (unlike
 750 ;;; the old CMU CL code, which accepted multiple files). Also, the old
 751 ;;; comment said
 752 ;;;   When we open a new file, we also reset *PACKAGE* and policy.
 753 ;;;   This gives the effect of rebinding around each file.
 754 ;;; which doesn't seem to be true now. Check to make sure that if
 755 ;;; such rebinding is necessary, it's still done somewhere.
 756 (defun get-source-stream (info)
 757   (declare (type source-info info))
 758   (or (source-info-stream info)
 759       (let* ((file-info (source-info-file-info info))
 760              (name (file-info-name file-info)))
 761         (setf sb!xc:*compile-file-truename* name
 762               sb!xc:*compile-file-pathname* (file-info-untruename file-info)
 763               (source-info-stream info) (open name :direction :input)))))
 764
 765 ;;; Close the stream in INFO if it is open.
 766 (defun close-source-info (info)
 767   (declare (type source-info info))
 768   (let ((stream (source-info-stream info)))
 769     (when stream (close stream)))
 770   (setf (source-info-stream info) nil)
 771   (values))
 772
 773 ;;; Read and compile the source file.
 774 (defun sub-sub-compile-file (info)
 775   (let* ((file-info (source-info-file-info info))
 776          (stream (get-source-stream info)))
 777     (loop
 778      (let* ((pos (file-position stream))
 779             (form (read-for-compile-file stream pos)))
 780        (if (eq form stream) ; i.e., if EOF
 781            (return)
 782            (let* ((forms (file-info-forms file-info))
 783                   (current-idx (+ (fill-pointer forms)
 784                                   (file-info-source-root file-info))))
 785              (vector-push-extend form forms)
 786              (vector-push-extend pos (file-info-positions file-info))
 787              (find-source-paths form current-idx)
 788              (process-toplevel-form form
 789                                     `(original-source-start 0 ,current-idx)
 790                                     nil)))))))
 791
 792 ;;; Return the INDEX'th source form read from INFO and the position
 793 ;;; where it was read.
 794 (defun find-source-root (index info)
 795   (declare (type index index) (type source-info info))
 796   (let ((file-info (source-info-file-info info)))
 797     (values (aref (file-info-forms file-info) index)
 798             (aref (file-info-positions file-info) index))))
 799 \f
 800 ;;;; processing of top level forms
 801
 802 ;;; This is called by top level form processing when we are ready to
 803 ;;; actually compile something. If *BLOCK-COMPILE* is T, then we still
 804 ;;; convert the form, but delay compilation, pushing the result on
 805 ;;; *TOPLEVEL-LAMBDAS* instead.
 806 (defun convert-and-maybe-compile (form path)
 807   (declare (list path))
 808   (let* ((*lexenv* (make-lexenv :policy *policy*
 809                                 :handled-conditions *handled-conditions*
 810                                 :disabled-package-locks *disabled-package-locks*))
 811          (tll (ir1-toplevel form path nil)))
 812     (cond ((eq *block-compile* t) (push tll *toplevel-lambdas*))
 813           (t (compile-toplevel (list tll) nil)))))
 814
 815 ;;; Macroexpand FORM in the current environment with an error handler.
 816 ;;; We only expand one level, so that we retain all the intervening
 817 ;;; forms in the source path.
 818 (defun preprocessor-macroexpand-1 (form)
 819   (handler-case (sb!xc:macroexpand-1 form *lexenv*)
 820     (error (condition)
 821       (compiler-error "(during macroexpansion of ~A)~%~A"
 822                       (let ((*print-level* 1)
 823                             (*print-length* 2))
 824                         (format nil "~S" form))
 825                       condition))))
 826
 827 ;;; Process a PROGN-like portion of a top level form. FORMS is a list of
 828 ;;; the forms, and PATH is the source path of the FORM they came out of.
 829 ;;; COMPILE-TIME-TOO is as in ANSI "3.2.3.1 Processing of Top Level Forms".
 830 (defun process-toplevel-progn (forms path compile-time-too)
 831   (declare (list forms) (list path))
 832   (dolist (form forms)
 833     (process-toplevel-form form path compile-time-too)))
 834
 835 ;;; Process a top level use of LOCALLY, or anything else (e.g.
 836 ;;; MACROLET) at top level which has declarations and ordinary forms.
 837 ;;; We parse declarations and then recursively process the body.
 838 (defun process-toplevel-locally (body path compile-time-too &key vars funs)
 839   (declare (list path))
 840   (multiple-value-bind (forms decls)
 841       (parse-body body :doc-string-allowed nil :toplevel t)
 842     (let* ((*lexenv* (process-decls decls vars funs))
 843            ;; FIXME: VALUES declaration
 844            ;;
 845            ;; Binding *POLICY* is pretty much of a hack, since it
 846            ;; causes LOCALLY to "capture" enclosed proclamations. It
 847            ;; is necessary because CONVERT-AND-MAYBE-COMPILE uses the
 848            ;; value of *POLICY* as the policy. The need for this hack
 849            ;; is due to the quirk that there is no way to represent in
 850            ;; a POLICY that an optimize quality came from the default.
 851            ;;
 852            ;; FIXME: Ideally, something should be done so that DECLAIM
 853            ;; inside LOCALLY works OK. Failing that, at least we could
 854            ;; issue a warning instead of silently screwing up.
 855            (*policy* (lexenv-policy *lexenv*))
 856            ;; This is probably also a hack
 857            (*handled-conditions* (lexenv-handled-conditions *lexenv*))
 858            ;; ditto
 859            (*disabled-package-locks* (lexenv-disabled-package-locks *lexenv*)))
 860       (process-toplevel-progn forms path compile-time-too))))
 861
 862 ;;; Parse an EVAL-WHEN situations list, returning three flags,
 863 ;;; (VALUES COMPILE-TOPLEVEL LOAD-TOPLEVEL EXECUTE), indicating
 864 ;;; the types of situations present in the list.
 865 (defun parse-eval-when-situations (situations)
 866   (when (or (not (listp situations))
 867             (set-difference situations
 868                             '(:compile-toplevel
 869                               compile
 870                               :load-toplevel
 871                               load
 872                               :execute
 873                               eval)))
 874     (compiler-error "bad EVAL-WHEN situation list: ~S" situations))
 875   (let ((deprecated-names (intersection situations '(compile load eval))))
 876     (when deprecated-names
 877       (style-warn "using deprecated EVAL-WHEN situation names~{ ~S~}"
 878                   deprecated-names)))
 879   (values (intersection '(:compile-toplevel compile)
 880                         situations)
 881           (intersection '(:load-toplevel load) situations)
 882           (intersection '(:execute eval) situations)))
 883
 884
 885 ;;; utilities for extracting COMPONENTs of FUNCTIONALs
 886 (defun functional-components (f)
 887   (declare (type functional f))
 888   (etypecase f
 889     (clambda (list (lambda-component f)))
 890     (optional-dispatch (let ((result nil))
 891                          (flet ((maybe-frob (maybe-clambda)
 892                                   (when (and maybe-clambda
 893                                              (promise-ready-p maybe-clambda))
 894                                     (pushnew (lambda-component
 895                                               (force maybe-clambda))
 896                                              result))))
 897                            (map nil #'maybe-frob (optional-dispatch-entry-points f))
 898                            (maybe-frob (optional-dispatch-more-entry f))
 899                            (maybe-frob (optional-dispatch-main-entry f)))
 900                          result))))
 901
 902 (defun make-functional-from-toplevel-lambda (definition
 903                                              &key
 904                                              name
 905                                              (path
 906                                               ;; I'd thought NIL should
 907                                               ;; work, but it doesn't.
 908                                               ;; -- WHN 2001-09-20
 909                                               (missing-arg)))
 910   (let* ((*current-path* path)
 911          (component (make-empty-component))
 912          (*current-component* component))
 913     (setf (component-name component)
 914           (debug-namify "~S initial component" name))
 915     (setf (component-kind component) :initial)
 916     (let* ((locall-fun (ir1-convert-lambdalike
 917                         definition
 918                         :debug-name (debug-namify "top level local call "
 919                                                   name)
 920                         ;; KLUDGE: we do this so that we get to have
 921                         ;; nice debug returnness in functions defined
 922                         ;; from the REPL
 923                         :allow-debug-catch-tag t))
 924            (fun (ir1-convert-lambda (make-xep-lambda-expression locall-fun)
 925                                     :source-name (or name '.anonymous.)
 926                                     :debug-name (unless name
 927                                                   "top level form"))))
 928       (when name
 929         (assert-global-function-definition-type name locall-fun))
 930       (setf (functional-entry-fun fun) locall-fun
 931             (functional-kind fun) :external
 932             (functional-has-external-references-p fun) t)
 933       fun)))
 934
 935 ;;; Compile LAMBDA-EXPRESSION into *COMPILE-OBJECT*, returning a
 936 ;;; description of the result.
 937 ;;;   * If *COMPILE-OBJECT* is a CORE-OBJECT, then write the function
 938 ;;;     into core and return the compiled FUNCTION value.
 939 ;;;   * If *COMPILE-OBJECT* is a fasl file, then write the function
 940 ;;;     into the fasl file and return a dump handle.
 941 ;;;
 942 ;;; If NAME is provided, then we try to use it as the name of the
 943 ;;; function for debugging/diagnostic information.
 944 (defun %compile (lambda-expression
 945                  *compile-object*
 946                  &key
 947                  name
 948                  (path
 949                   ;; This magical idiom seems to be the appropriate
 950                   ;; path for compiling standalone LAMBDAs, judging
 951                   ;; from the CMU CL code and experiment, so it's a
 952                   ;; nice default for things where we don't have a
 953                   ;; real source path (as in e.g. inside CL:COMPILE).
 954                   '(original-source-start 0 0)))
 955   (when name
 956     (legal-fun-name-or-type-error name))
 957   (let* ((*lexenv* (make-lexenv :policy *policy*
 958                                 :handled-conditions *handled-conditions*
 959                                 :disabled-package-locks *disabled-package-locks*))
 960          (fun (make-functional-from-toplevel-lambda lambda-expression
 961                                                     :name name
 962                                                     :path path)))
 963
 964     ;; FIXME: The compile-it code from here on is sort of a
 965     ;; twisted version of the code in COMPILE-TOPLEVEL. It'd be
 966     ;; better to find a way to share the code there; or
 967     ;; alternatively, to use this code to replace the code there.
 968     ;; (The second alternative might be pretty easy if we used
 969     ;; the :LOCALL-ONLY option to IR1-FOR-LAMBDA. Then maybe the
 970     ;; whole FUNCTIONAL-KIND=:TOPLEVEL case could go away..)
 971
 972     (locall-analyze-clambdas-until-done (list fun))
 973
 974     (multiple-value-bind (components-from-dfo top-components hairy-top)
 975         (find-initial-dfo (list fun))
 976
 977       (let ((*all-components* (append components-from-dfo top-components)))
 978         ;; FIXME: This is more monkey see monkey do based on CMU CL
 979         ;; code. If anyone figures out why to only prescan HAIRY-TOP
 980         ;; and TOP-COMPONENTS here, instead of *ALL-COMPONENTS* or
 981         ;; some other combination of results from FIND-INITIAL-VALUES,
 982         ;; it'd be good to explain it.
 983         (mapc #'preallocate-physenvs-for-toplevelish-lambdas hairy-top)
 984         (mapc #'preallocate-physenvs-for-toplevelish-lambdas top-components)
 985         (dolist (component-from-dfo components-from-dfo)
 986           (compile-component component-from-dfo)
 987           (replace-toplevel-xeps component-from-dfo)))
 988
 989       (let ((entry-table (etypecase *compile-object*
 990                            (fasl-output (fasl-output-entry-table
 991                                          *compile-object*))
 992                            (core-object (core-object-entry-table
 993                                          *compile-object*)))))
 994         (multiple-value-bind (result found-p)
 995             (gethash (leaf-info fun) entry-table)
 996           (aver found-p)
 997           (prog1
 998               result
 999             ;; KLUDGE: This code duplicates some other code in this
1000             ;; file. In the great reorganzation, the flow of program
1001             ;; logic changed from the original CMUCL model, and that
1002             ;; path (as of sbcl-0.7.5 in SUB-COMPILE-FILE) was no
1003             ;; longer followed for CORE-OBJECTS, leading to BUG
1004             ;; 156. This place is transparently not the right one for
1005             ;; this code, but I don't have a clear enough overview of
1006             ;; the compiler to know how to rearrange it all so that
1007             ;; this operation fits in nicely, and it was blocking
1008             ;; reimplementation of (DECLAIM (INLINE FOO)) (MACROLET
1009             ;; ((..)) (DEFUN FOO ...))
1010             ;;
1011             ;; FIXME: This KLUDGE doesn't solve all the problem in an
1012             ;; ideal way, as (1) definitions typed in at the REPL
1013             ;; without an INLINE declaration will give a NULL
1014             ;; FUNCTION-LAMBDA-EXPRESSION (allowable, but not ideal)
1015             ;; and (2) INLINE declarations will yield a
1016             ;; FUNCTION-LAMBDA-EXPRESSION headed by
1017             ;; SB-C:LAMBDA-WITH-LEXENV, even for null LEXENV.  -- CSR,
1018             ;; 2002-07-02
1019             ;;
1020             ;; (2) is probably fairly easy to fix -- it is, after all,
1021             ;; a matter of list manipulation (or possibly of teaching
1022             ;; CL:FUNCTION about SB-C:LAMBDA-WITH-LEXENV).  (1) is
1023             ;; significantly harder, as the association between
1024             ;; function object and source is a tricky one.
1025             ;;
1026             ;; FUNCTION-LAMBDA-EXPRESSION "works" (i.e. returns a
1027             ;; non-NULL list) when the function in question has been
1028             ;; compiled by (COMPILE <x> '(LAMBDA ...)); it does not
1029             ;; work when it has been compiled as part of the top-level
1030             ;; EVAL strategy of compiling everything inside (LAMBDA ()
1031             ;; ...).  -- CSR, 2002-11-02
1032             (when (core-object-p *compile-object*)
1033               (fix-core-source-info *source-info* *compile-object* result))
1034
1035             (mapc #'clear-ir1-info components-from-dfo)
1036             (clear-stuff)))))))
1037
1038 (defun process-toplevel-cold-fset (name lambda-expression path)
1039   (unless (producing-fasl-file)
1040     (error "can't COLD-FSET except in a fasl file"))
1041   (legal-fun-name-or-type-error name)
1042   (fasl-dump-cold-fset name
1043                        (%compile lambda-expression
1044                                  *compile-object*
1045                                  :name name
1046                                  :path path)
1047                        *compile-object*)
1048   (values))
1049
1050 ;;; Process a top level FORM with the specified source PATH.
1051 ;;;  * If this is a magic top level form, then do stuff.
1052 ;;;  * If this is a macro, then expand it.
1053 ;;;  * Otherwise, just compile it.
1054 ;;;
1055 ;;; COMPILE-TIME-TOO is as defined in ANSI
1056 ;;; "3.2.3.1 Processing of Top Level Forms".
1057 (defun process-toplevel-form (form path compile-time-too)
1058
1059   (declare (list path))
1060
1061   (catch 'process-toplevel-form-error-abort
1062     (let* ((path (or (gethash form *source-paths*) (cons form path)))
1063            (*compiler-error-bailout*
1064             (lambda ()
1065               (convert-and-maybe-compile
1066                `(error 'simple-program-error
1067                  :format-control "execution of a form compiled with errors:~% ~S"
1068                  :format-arguments (list ',form))
1069                path)
1070               (throw 'process-toplevel-form-error-abort nil))))
1071
1072       (flet ((default-processor (form)
1073                ;; When we're cross-compiling, consider: what should we
1074                ;; do when we hit e.g.
1075                ;;   (EVAL-WHEN (:COMPILE-TOPLEVEL)
1076                ;;     (DEFUN FOO (X) (+ 7 X)))?
1077                ;; DEFUN has a macro definition in the cross-compiler,
1078                ;; and a different macro definition in the target
1079                ;; compiler. The only sensible thing is to use the
1080                ;; target compiler's macro definition, since the
1081                ;; cross-compiler's macro is in general into target
1082                ;; functions which can't meaningfully be executed at
1083                ;; cross-compilation time. So make sure we do the EVAL
1084                ;; here, before we macroexpand.
1085                ;;
1086                ;; Then things get even dicier with something like
1087                ;;   (DEFCONSTANT-EQX SB!XC:LAMBDA-LIST-KEYWORDS ..)
1088                ;; where we have to make sure that we don't uncross
1089                ;; the SB!XC: prefix before we do EVAL, because otherwise
1090                ;; we'd be trying to redefine the cross-compilation host's
1091                ;; constants.
1092                ;;
1093                ;; (Isn't it fun to cross-compile Common Lisp?:-)
1094                #+sb-xc-host
1095                (progn
1096                  (when compile-time-too
1097                    (eval form)) ; letting xc host EVAL do its own macroexpansion
1098                  (let* (;; (We uncross the operator name because things
1099                         ;; like SB!XC:DEFCONSTANT and SB!XC:DEFTYPE
1100                         ;; should be equivalent to their CL: counterparts
1101                         ;; when being compiled as target code. We leave
1102                         ;; the rest of the form uncrossed because macros
1103                         ;; might yet expand into EVAL-WHEN stuff, and
1104                         ;; things inside EVAL-WHEN can't be uncrossed
1105                         ;; until after we've EVALed them in the
1106                         ;; cross-compilation host.)
1107                         (slightly-uncrossed (cons (uncross (first form))
1108                                                   (rest form)))
1109                         (expanded (preprocessor-macroexpand-1
1110                                    slightly-uncrossed)))
1111                    (if (eq expanded slightly-uncrossed)
1112                        ;; (Now that we're no longer processing toplevel
1113                        ;; forms, and hence no longer need to worry about
1114                        ;; EVAL-WHEN, we can uncross everything.)
1115                        (convert-and-maybe-compile expanded path)
1116                        ;; (We have to demote COMPILE-TIME-TOO to NIL
1117                        ;; here, no matter what it was before, since
1118                        ;; otherwise we'd tend to EVAL subforms more than
1119                        ;; once, because of WHEN COMPILE-TIME-TOO form
1120                        ;; above.)
1121                        (process-toplevel-form expanded path nil))))
1122                ;; When we're not cross-compiling, we only need to
1123                ;; macroexpand once, so we can follow the 1-thru-6
1124                ;; sequence of steps in ANSI's "3.2.3.1 Processing of
1125                ;; Top Level Forms".
1126                #-sb-xc-host
1127                (let ((expanded (preprocessor-macroexpand-1 form)))
1128                  (cond ((eq expanded form)
1129                         (when compile-time-too
1130                           (eval-in-lexenv form *lexenv*))
1131                         (convert-and-maybe-compile form path))
1132                        (t
1133                         (process-toplevel-form expanded
1134                                                path
1135                                                compile-time-too))))))
1136         (if (atom form)
1137             #+sb-xc-host
1138             ;; (There are no xc EVAL-WHEN issues in the ATOM case until
1139             ;; (1) SBCL gets smart enough to handle global
1140             ;; DEFINE-SYMBOL-MACRO or SYMBOL-MACROLET and (2) SBCL
1141             ;; implementors start using symbol macros in a way which
1142             ;; interacts with SB-XC/CL distinction.)
1143             (convert-and-maybe-compile form path)
1144             #-sb-xc-host
1145             (default-processor form)
1146             (flet ((need-at-least-one-arg (form)
1147                      (unless (cdr form)
1148                        (compiler-error "~S form is too short: ~S"
1149                                        (car form)
1150                                        form))))
1151               (case (car form)
1152                 ;; In the cross-compiler, top level COLD-FSET arranges
1153                 ;; for static linking at cold init time.
1154                 #+sb-xc-host
1155                 ((cold-fset)
1156                  (aver (not compile-time-too))
1157                  (destructuring-bind (cold-fset fun-name lambda-expression) form
1158                    (declare (ignore cold-fset))
1159                    (process-toplevel-cold-fset fun-name
1160                                                lambda-expression
1161                                                path)))
1162                 ((eval-when macrolet symbol-macrolet);things w/ 1 arg before body
1163                  (need-at-least-one-arg form)
1164                  (destructuring-bind (special-operator magic &rest body) form
1165                    (ecase special-operator
1166                      ((eval-when)
1167                       ;; CT, LT, and E here are as in Figure 3-7 of ANSI
1168                       ;; "3.2.3.1 Processing of Top Level Forms".
1169                       (multiple-value-bind (ct lt e)
1170                           (parse-eval-when-situations magic)
1171                         (let ((new-compile-time-too (or ct
1172                                                         (and compile-time-too
1173                                                              e))))
1174                           (cond (lt (process-toplevel-progn
1175                                      body path new-compile-time-too))
1176                                 (new-compile-time-too (eval-in-lexenv
1177                                                        `(progn ,@body)
1178                                                        *lexenv*))))))
1179                      ((macrolet)
1180                       (funcall-in-macrolet-lexenv
1181                        magic
1182                        (lambda (&key funs prepend)
1183                          (declare (ignore funs))
1184                          (aver (null prepend))
1185                          (process-toplevel-locally body
1186                                                    path
1187                                                    compile-time-too))
1188                        :compile))
1189                      ((symbol-macrolet)
1190                       (funcall-in-symbol-macrolet-lexenv
1191                        magic
1192                        (lambda (&key vars prepend)
1193                          (aver (null prepend))
1194                          (process-toplevel-locally body
1195                                                    path
1196                                                    compile-time-too
1197                                                    :vars vars))
1198                        :compile)))))
1199                 ((locally)
1200                  (process-toplevel-locally (rest form) path compile-time-too))
1201                 ((progn)
1202                  (process-toplevel-progn (rest form) path compile-time-too))
1203                 (t (default-processor form))))))))
1204
1205   (values))
1206 \f
1207 ;;;; load time value support
1208 ;;;;
1209 ;;;; (See EMIT-MAKE-LOAD-FORM.)
1210
1211 ;;; Return T if we are currently producing a fasl file and hence
1212 ;;; constants need to be dumped carefully.
1213 (defun producing-fasl-file ()
1214   (fasl-output-p *compile-object*))
1215
1216 ;;; Compile FORM and arrange for it to be called at load-time. Return
1217 ;;; the dumper handle and our best guess at the type of the object.
1218 (defun compile-load-time-value (form)
1219   (let ((lambda (compile-load-time-stuff form t)))
1220     (values
1221      (fasl-dump-load-time-value-lambda lambda *compile-object*)
1222      (let ((type (leaf-type lambda)))
1223        (if (fun-type-p type)
1224            (single-value-type (fun-type-returns type))
1225            *wild-type*)))))
1226
1227 ;;; Compile the FORMS and arrange for them to be called (for effect,
1228 ;;; not value) at load time.
1229 (defun compile-make-load-form-init-forms (forms)
1230   (let ((lambda (compile-load-time-stuff `(progn ,@forms) nil)))
1231     (fasl-dump-toplevel-lambda-call lambda *compile-object*)))
1232
1233 ;;; Do the actual work of COMPILE-LOAD-TIME-VALUE or
1234 ;;; COMPILE-MAKE-LOAD-FORM-INIT-FORMS.
1235 (defun compile-load-time-stuff (form for-value)
1236   (with-ir1-namespace
1237    (let* ((*lexenv* (make-null-lexenv))
1238           (lambda (ir1-toplevel form *current-path* for-value)))
1239      (compile-toplevel (list lambda) t)
1240      lambda)))
1241
1242 ;;; This is called by COMPILE-TOPLEVEL when it was passed T for
1243 ;;; LOAD-TIME-VALUE-P (which happens in COMPILE-LOAD-TIME-STUFF). We
1244 ;;; don't try to combine this component with anything else and frob
1245 ;;; the name. If not in a :TOPLEVEL component, then don't bother
1246 ;;; compiling, because it was merged with a run-time component.
1247 (defun compile-load-time-value-lambda (lambdas)
1248   (aver (null (cdr lambdas)))
1249   (let* ((lambda (car lambdas))
1250          (component (lambda-component lambda)))
1251     (when (eql (component-kind component) :toplevel)
1252       (setf (component-name component) (leaf-debug-name lambda))
1253       (compile-component component)
1254       (clear-ir1-info component))))
1255 \f
1256 ;;;; COMPILE-FILE
1257
1258 (defun object-call-toplevel-lambda (tll)
1259   (declare (type functional tll))
1260   (let ((object *compile-object*))
1261     (etypecase object
1262       (fasl-output (fasl-dump-toplevel-lambda-call tll object))
1263       (core-object (core-call-toplevel-lambda      tll object))
1264       (null))))
1265
1266 ;;; Smash LAMBDAS into a single component, compile it, and arrange for
1267 ;;; the resulting function to be called.
1268 (defun sub-compile-toplevel-lambdas (lambdas)
1269   (declare (list lambdas))
1270   (when lambdas
1271     (multiple-value-bind (component tll) (merge-toplevel-lambdas lambdas)
1272       (compile-component component)
1273       (clear-ir1-info component)
1274       (object-call-toplevel-lambda tll)))
1275   (values))
1276
1277 ;;; Compile top level code and call the top level lambdas. We pick off
1278 ;;; top level lambdas in non-top-level components here, calling
1279 ;;; SUB-c-t-l-l on each subsequence of normal top level lambdas.
1280 (defun compile-toplevel-lambdas (lambdas)
1281   (declare (list lambdas))
1282   (let ((len (length lambdas)))
1283     (flet ((loser (start)
1284              (or (position-if (lambda (x)
1285                                 (not (eq (component-kind
1286                                           (node-component (lambda-bind x)))
1287                                          :toplevel)))
1288                               lambdas
1289                               ;; this used to read ":start start", but
1290                               ;; start can be greater than len, which
1291                               ;; is an error according to ANSI - CSR,
1292                               ;; 2002-04-25
1293                               :start (min start len))
1294                  len)))
1295       (do* ((start 0 (1+ loser))
1296             (loser (loser start) (loser start)))
1297            ((>= start len))
1298         (sub-compile-toplevel-lambdas (subseq lambdas start loser))
1299         (unless (= loser len)
1300           (object-call-toplevel-lambda (elt lambdas loser))))))
1301   (values))
1302
1303 ;;; Compile LAMBDAS (a list of CLAMBDAs for top level forms) into the
1304 ;;; object file.
1305 ;;;
1306 ;;; LOAD-TIME-VALUE-P seems to control whether it's MAKE-LOAD-FORM and
1307 ;;; COMPILE-LOAD-TIME-VALUE stuff. -- WHN 20000201
1308 (defun compile-toplevel (lambdas load-time-value-p)
1309   (declare (list lambdas))
1310
1311   (maybe-mumble "locall ")
1312   (locall-analyze-clambdas-until-done lambdas)
1313
1314   (maybe-mumble "IDFO ")
1315   (multiple-value-bind (components top-components hairy-top)
1316       (find-initial-dfo lambdas)
1317     (let ((*all-components* (append components top-components)))
1318       (when *check-consistency*
1319         (maybe-mumble "[check]~%")
1320         (check-ir1-consistency *all-components*))
1321
1322       (dolist (component (append hairy-top top-components))
1323         (pre-physenv-analyze-toplevel component))
1324
1325       (dolist (component components)
1326         (compile-component component)
1327         (replace-toplevel-xeps component))
1328
1329       (when *check-consistency*
1330         (maybe-mumble "[check]~%")
1331         (check-ir1-consistency *all-components*))
1332
1333       (if load-time-value-p
1334           (compile-load-time-value-lambda lambdas)
1335           (compile-toplevel-lambdas lambdas))
1336
1337       (mapc #'clear-ir1-info components)
1338       (clear-stuff)))
1339   (values))
1340
1341 ;;; Actually compile any stuff that has been queued up for block
1342 ;;; compilation.
1343 (defun finish-block-compilation ()
1344   (when *block-compile*
1345     (when *toplevel-lambdas*
1346       (compile-toplevel (nreverse *toplevel-lambdas*) nil)
1347       (setq *toplevel-lambdas* ()))
1348     (setq *block-compile* nil)
1349     (setq *entry-points* nil)))
1350
1351 (defun handle-condition-p (condition)
1352   (let ((lexenv
1353          (etypecase *compiler-error-context*
1354            (node
1355             (node-lexenv *compiler-error-context*))
1356            (compiler-error-context
1357             (let ((lexenv (compiler-error-context-lexenv
1358                            *compiler-error-context*)))
1359               (aver lexenv)
1360               lexenv))
1361            (null *lexenv*))))
1362     (let ((muffles (lexenv-handled-conditions lexenv)))
1363       (if (null muffles) ; common case
1364           nil
1365           (dolist (muffle muffles nil)
1366             (destructuring-bind (typespec . restart-name) muffle
1367               (when (and (typep condition typespec)
1368                          (find-restart restart-name condition))
1369                 (return t))))))))
1370
1371 (defun handle-condition-handler (condition)
1372   (let ((lexenv
1373          (etypecase *compiler-error-context*
1374            (node
1375             (node-lexenv *compiler-error-context*))
1376            (compiler-error-context
1377             (let ((lexenv (compiler-error-context-lexenv
1378                            *compiler-error-context*)))
1379               (aver lexenv)
1380               lexenv))
1381            (null *lexenv*))))
1382     (let ((muffles (lexenv-handled-conditions lexenv)))
1383       (aver muffles)
1384       (dolist (muffle muffles (bug "fell through"))
1385         (destructuring-bind (typespec . restart-name) muffle
1386           (when (typep condition typespec)
1387             (awhen (find-restart restart-name condition)
1388               (invoke-restart it))))))))
1389
1390 ;;; Read all forms from INFO and compile them, with output to OBJECT.
1391 ;;; Return (VALUES NIL WARNINGS-P FAILURE-P).
1392 (defun sub-compile-file (info)
1393   (declare (type source-info info))
1394   (let ((*package* (sane-package))
1395         (*readtable* *readtable*)
1396         (sb!xc:*compile-file-pathname* nil) ; really bound in
1397         (sb!xc:*compile-file-truename* nil) ; SUB-SUB-COMPILE-FILE
1398
1399         (*policy* *policy*)
1400         (*handled-conditions* *handled-conditions*)
1401         (*disabled-package-locks* *disabled-package-locks*)
1402         (*lexenv* (make-null-lexenv))
1403         (*block-compile* *block-compile-arg*)
1404         (*source-info* info)
1405         (*toplevel-lambdas* ())
1406         (*fun-names-in-this-file* ())
1407         (*compiler-error-bailout*
1408          (lambda ()
1409            (compiler-mumble "~2&; fatal error, aborting compilation~%")
1410            (return-from sub-compile-file (values nil t t))))
1411         (*current-path* nil)
1412         (*last-source-context* nil)
1413         (*last-original-source* nil)
1414         (*last-source-form* nil)
1415         (*last-format-string* nil)
1416         (*last-format-args* nil)
1417         (*last-message-count* 0)
1418         ;; FIXME: Do we need this rebinding here? It's a literal
1419         ;; translation of the old CMU CL rebinding to
1420         ;; (OR *BACKEND-INFO-ENVIRONMENT* *INFO-ENVIRONMENT*),
1421         ;; and it's not obvious whether the rebinding to itself is
1422         ;; needed that SBCL doesn't need *BACKEND-INFO-ENVIRONMENT*.
1423         (*info-environment* *info-environment*)
1424         (*gensym-counter* 0))
1425     (handler-case
1426         (handler-bind (((satisfies handle-condition-p) #'handle-condition-handler))
1427           (with-compilation-values
1428               (sb!xc:with-compilation-unit ()
1429                 (clear-stuff)
1430
1431                 (sub-sub-compile-file info)
1432
1433                 (finish-block-compilation)
1434                 (let ((object *compile-object*))
1435                   (etypecase object
1436                     (fasl-output (fasl-dump-source-info info object))
1437                     (core-object (fix-core-source-info info object))
1438                     (null)))
1439                 nil)))
1440       ;; Some errors are sufficiently bewildering that we just fail
1441       ;; immediately, without trying to recover and compile more of
1442       ;; the input file.
1443       (input-error-in-compile-file (condition)
1444        (format *error-output*
1445                "~@<compilation aborted because of input error: ~2I~_~A~:>"
1446                condition)
1447        (values nil t t)))))
1448
1449 ;;; Return a pathname for the named file. The file must exist.
1450 (defun verify-source-file (pathname-designator)
1451   (let* ((pathname (pathname pathname-designator))
1452          (default-host (make-pathname :host (pathname-host pathname))))
1453     (flet ((try-with-type (path type error-p)
1454              (let ((new (merge-pathnames
1455                          path (make-pathname :type type
1456                                              :defaults default-host))))
1457                (if (probe-file new)
1458                    new
1459                    (and error-p (truename new))))))
1460       (cond ((typep pathname 'logical-pathname)
1461              (try-with-type pathname "LISP" t))
1462             ((probe-file pathname) pathname)
1463             ((try-with-type pathname "lisp"  nil))
1464             ((try-with-type pathname "lisp"  t))))))
1465
1466 (defun elapsed-time-to-string (tsec)
1467   (multiple-value-bind (tmin sec) (truncate tsec 60)
1468     (multiple-value-bind (thr min) (truncate tmin 60)
1469       (format nil "~D:~2,'0D:~2,'0D" thr min sec))))
1470
1471 ;;; Print some junk at the beginning and end of compilation.
1472 (defun start-error-output (source-info)
1473   (declare (type source-info source-info))
1474   (let ((file-info (source-info-file-info source-info)))
1475     (compiler-mumble "~&; compiling file ~S (written ~A):~%"
1476                      (namestring (file-info-name file-info))
1477                      (sb!int:format-universal-time nil
1478                                                    (file-info-write-date
1479                                                     file-info)
1480                                                    :style :government
1481                                                    :print-weekday nil
1482                                                    :print-timezone nil)))
1483   (values))
1484 (defun finish-error-output (source-info won)
1485   (declare (type source-info source-info))
1486   (compiler-mumble "~&; compilation ~:[aborted after~;finished in~] ~A~&"
1487                    won
1488                    (elapsed-time-to-string
1489                     (- (get-universal-time)
1490                        (source-info-start-time source-info))))
1491   (values))
1492
1493 ;;; Open some files and call SUB-COMPILE-FILE. If something unwinds
1494 ;;; out of the compile, then abort the writing of the output file, so
1495 ;;; that we don't overwrite it with known garbage.
1496 (defun sb!xc:compile-file
1497     (input-file
1498      &key
1499
1500      ;; ANSI options
1501      (output-file (cfp-output-file-default input-file))
1502      ;; FIXME: ANSI doesn't seem to say anything about
1503      ;; *COMPILE-VERBOSE* and *COMPILE-PRINT* being rebound by this
1504      ;; function..
1505      ((:verbose sb!xc:*compile-verbose*) sb!xc:*compile-verbose*)
1506      ((:print sb!xc:*compile-print*) sb!xc:*compile-print*)
1507      (external-format :default)
1508
1509      ;; extensions
1510      (trace-file nil)
1511      ((:block-compile *block-compile-arg*) nil))
1512
1513   #!+sb-doc
1514   "Compile INPUT-FILE, producing a corresponding fasl file and returning
1515    its filename. Besides the ANSI &KEY arguments :OUTPUT-FILE, :VERBOSE,
1516    :PRINT, and :EXTERNAL-FORMAT,the following extensions are supported:
1517      :TRACE-FILE
1518         If given, internal data structures are dumped to the specified
1519         file, or if a value of T is given, to a file of *.trace type
1520         derived from the input file name.
1521    Also, as a workaround for vaguely-non-ANSI behavior, the :BLOCK-COMPILE
1522    argument is quasi-supported, to determine whether multiple
1523    functions are compiled together as a unit, resolving function
1524    references at compile time. NIL means that global function names
1525    are never resolved at compilation time. Currently NIL is the
1526    default behavior, because although section 3.2.2.3, \"Semantic
1527    Constraints\", of the ANSI spec allows this behavior under all
1528    circumstances, the compiler's runtime scales badly when it
1529    tries to do this for large files. If/when this performance
1530    problem is fixed, the block compilation default behavior will
1531    probably be made dependent on the SPEED and COMPILATION-SPEED
1532    optimization values, and the :BLOCK-COMPILE argument will probably
1533    become deprecated."
1534
1535   (unless (eq external-format :default)
1536     (error "Non-:DEFAULT EXTERNAL-FORMAT values are not supported."))
1537   (let* ((fasl-output nil)
1538          (output-file-name nil)
1539          (compile-won nil)
1540          (warnings-p nil)
1541          (failure-p t) ; T in case error keeps this from being set later
1542          (input-pathname (verify-source-file input-file))
1543          (source-info (make-file-source-info input-pathname))
1544          (*compiler-trace-output* nil)) ; might be modified below
1545
1546     (unwind-protect
1547         (progn
1548           (when output-file
1549             (setq output-file-name
1550                   (sb!xc:compile-file-pathname input-file
1551                                                :output-file output-file))
1552             (setq fasl-output
1553                   (open-fasl-output output-file-name
1554                                     (namestring input-pathname))))
1555           (when trace-file
1556             (let* ((default-trace-file-pathname
1557                      (make-pathname :type "trace" :defaults input-pathname))
1558                    (trace-file-pathname
1559                     (if (eql trace-file t)
1560                         default-trace-file-pathname
1561                         (merge-pathnames trace-file
1562                                          default-trace-file-pathname))))
1563               (setf *compiler-trace-output*
1564                     (open trace-file-pathname
1565                           :if-exists :supersede
1566                           :direction :output))))
1567
1568           (when sb!xc:*compile-verbose*
1569             (start-error-output source-info))
1570           (let ((*compile-object* fasl-output)
1571                 dummy)
1572             (multiple-value-setq (dummy warnings-p failure-p)
1573               (sub-compile-file source-info)))
1574           (setq compile-won t))
1575
1576       (close-source-info source-info)
1577
1578       (when fasl-output
1579         (close-fasl-output fasl-output (not compile-won))
1580         (setq output-file-name
1581               (pathname (fasl-output-stream fasl-output)))
1582         (when (and compile-won sb!xc:*compile-verbose*)
1583           (compiler-mumble "~2&; ~A written~%" (namestring output-file-name))))
1584
1585       (when sb!xc:*compile-verbose*
1586         (finish-error-output source-info compile-won))
1587
1588       (when *compiler-trace-output*
1589         (close *compiler-trace-output*)))
1590
1591     (values (if output-file
1592                 ;; Hack around filesystem race condition...
1593                 (or (probe-file output-file-name) output-file-name)
1594                 nil)
1595             warnings-p
1596             failure-p)))
1597 \f
1598 ;;; a helper function for COMPILE-FILE-PATHNAME: the default for
1599 ;;; the OUTPUT-FILE argument
1600 ;;;
1601 ;;; ANSI: The defaults for the OUTPUT-FILE are taken from the pathname
1602 ;;; that results from merging the INPUT-FILE with the value of
1603 ;;; *DEFAULT-PATHNAME-DEFAULTS*, except that the type component should
1604 ;;; default to the appropriate implementation-defined default type for
1605 ;;; compiled files.
1606 (defun cfp-output-file-default (input-file)
1607   (let* ((defaults (merge-pathnames input-file *default-pathname-defaults*))
1608          (retyped (make-pathname :type *fasl-file-type* :defaults defaults)))
1609     retyped))
1610
1611 ;;; KLUDGE: Part of the ANSI spec for this seems contradictory:
1612 ;;;   If INPUT-FILE is a logical pathname and OUTPUT-FILE is unsupplied,
1613 ;;;   the result is a logical pathname. If INPUT-FILE is a logical
1614 ;;;   pathname, it is translated into a physical pathname as if by
1615 ;;;   calling TRANSLATE-LOGICAL-PATHNAME.
1616 ;;; So I haven't really tried to make this precisely ANSI-compatible
1617 ;;; at the level of e.g. whether it returns logical pathname or a
1618 ;;; physical pathname. Patches to make it more correct are welcome.
1619 ;;; -- WHN 2000-12-09
1620 (defun sb!xc:compile-file-pathname (input-file
1621                                     &key
1622                                     (output-file (cfp-output-file-default
1623                                                   input-file))
1624                                     &allow-other-keys)
1625   #!+sb-doc
1626   "Return a pathname describing what file COMPILE-FILE would write to given
1627    these arguments."
1628   (merge-pathnames output-file (merge-pathnames input-file)))
1629 \f
1630 ;;;; MAKE-LOAD-FORM stuff
1631
1632 ;;; The entry point for MAKE-LOAD-FORM support. When IR1 conversion
1633 ;;; finds a constant structure, it invokes this to arrange for proper
1634 ;;; dumping. If it turns out that the constant has already been
1635 ;;; dumped, then we don't need to do anything.
1636 ;;;
1637 ;;; If the constant hasn't been dumped, then we check to see whether
1638 ;;; we are in the process of creating it. We detect this by
1639 ;;; maintaining the special *CONSTANTS-BEING-CREATED* as a list of all
1640 ;;; the constants we are in the process of creating. Actually, each
1641 ;;; entry is a list of the constant and any init forms that need to be
1642 ;;; processed on behalf of that constant.
1643 ;;;
1644 ;;; It's not necessarily an error for this to happen. If we are
1645 ;;; processing the init form for some object that showed up *after*
1646 ;;; the original reference to this constant, then we just need to
1647 ;;; defer the processing of that init form. To detect this, we
1648 ;;; maintain *CONSTANTS-CREATED-SINCE-LAST-INIT* as a list of the
1649 ;;; constants created since the last time we started processing an
1650 ;;; init form. If the constant passed to emit-make-load-form shows up
1651 ;;; in this list, then there is a circular chain through creation
1652 ;;; forms, which is an error.
1653 ;;;
1654 ;;; If there is some intervening init form, then we blow out of
1655 ;;; processing it by throwing to the tag PENDING-INIT. The value we
1656 ;;; throw is the entry from *CONSTANTS-BEING-CREATED*. This is so the
1657 ;;; offending init form can be tacked onto the init forms for the
1658 ;;; circular object.
1659 ;;;
1660 ;;; If the constant doesn't show up in *CONSTANTS-BEING-CREATED*, then
1661 ;;; we have to create it. We call MAKE-LOAD-FORM and check to see
1662 ;;; whether the creation form is the magic value
1663 ;;; :SB-JUST-DUMP-IT-NORMALLY. If it is, then we don't do anything. The
1664 ;;; dumper will eventually get its hands on the object and use the
1665 ;;; normal structure dumping noise on it.
1666 ;;;
1667 ;;; Otherwise, we bind *CONSTANTS-BEING-CREATED* and
1668 ;;; *CONSTANTS-CREATED-SINCE- LAST-INIT* and compile the creation form
1669 ;;; much the way LOAD-TIME-VALUE does. When this finishes, we tell the
1670 ;;; dumper to use that result instead whenever it sees this constant.
1671 ;;;
1672 ;;; Now we try to compile the init form. We bind
1673 ;;; *CONSTANTS-CREATED-SINCE-LAST-INIT* to NIL and compile the init
1674 ;;; form (and any init forms that were added because of circularity
1675 ;;; detection). If this works, great. If not, we add the init forms to
1676 ;;; the init forms for the object that caused the problems and let it
1677 ;;; deal with it.
1678 (defvar *constants-being-created* nil)
1679 (defvar *constants-created-since-last-init* nil)
1680 ;;; FIXME: Shouldn't these^ variables be unbound outside LET forms?
1681 (defun emit-make-load-form (constant)
1682   (aver (fasl-output-p *compile-object*))
1683   (unless (or (fasl-constant-already-dumped-p constant *compile-object*)
1684               ;; KLUDGE: This special hack is because I was too lazy
1685               ;; to rework DEF!STRUCT so that the MAKE-LOAD-FORM
1686               ;; function of LAYOUT returns nontrivial forms when
1687               ;; building the cross-compiler but :IGNORE-IT when
1688               ;; cross-compiling or running under the target Lisp. --
1689               ;; WHN 19990914
1690               #+sb-xc-host (typep constant 'layout))
1691     (let ((circular-ref (assoc constant *constants-being-created* :test #'eq)))
1692       (when circular-ref
1693         (when (find constant *constants-created-since-last-init* :test #'eq)
1694           (throw constant t))
1695         (throw 'pending-init circular-ref)))
1696     (multiple-value-bind (creation-form init-form)
1697         (handler-case
1698             (sb!xc:make-load-form constant (make-null-lexenv))
1699           (error (condition)
1700                  (compiler-error "(while making load form for ~S)~%~A"
1701                                  constant
1702                                  condition)))
1703       (case creation-form
1704         (:sb-just-dump-it-normally
1705          (fasl-validate-structure constant *compile-object*)
1706          t)
1707         (:ignore-it
1708          nil)
1709         (t
1710          (when (fasl-constant-already-dumped-p constant *compile-object*)
1711            (return-from emit-make-load-form nil))
1712          (let* ((name (let ((*print-level* 1) (*print-length* 2))
1713                         (with-output-to-string (stream)
1714                           (write constant :stream stream))))
1715                 (info (if init-form
1716                           (list constant name init-form)
1717                           (list constant))))
1718            (let ((*constants-being-created*
1719                   (cons info *constants-being-created*))
1720                  (*constants-created-since-last-init*
1721                   (cons constant *constants-created-since-last-init*)))
1722              (when
1723                  (catch constant
1724                    (fasl-note-handle-for-constant
1725                     constant
1726                     (compile-load-time-value
1727                      creation-form)
1728                     *compile-object*)
1729                    nil)
1730                (compiler-error "circular references in creation form for ~S"
1731                                constant)))
1732            (when (cdr info)
1733              (let* ((*constants-created-since-last-init* nil)
1734                     (circular-ref
1735                      (catch 'pending-init
1736                        (loop for (name form) on (cdr info) by #'cddr
1737                          collect name into names
1738                          collect form into forms
1739                          finally (compile-make-load-form-init-forms forms))
1740                        nil)))
1741                (when circular-ref
1742                  (setf (cdr circular-ref)
1743                        (append (cdr circular-ref) (cdr info))))))))))))
1744
1745 \f
1746 ;;;; Host compile time definitions
1747 #+sb-xc-host
1748 (defun compile-in-lexenv (name lambda lexenv)
1749   (declare (ignore lexenv))
1750   (compile name lambda))
1751
1752 #+sb-xc-host
1753 (defun eval-in-lexenv (form lexenv)
1754   (declare (ignore lexenv))
1755   (eval form))