src/compiler/mips/alloc.lisp

   1 ;;;; allocation VOPs for Mips
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13
  14 \f
  15 ;;;; LIST and LIST*
  16
  17 (define-vop (list-or-list*)
  18   (:args (things :more t))
  19   (:temporary (:scs (descriptor-reg) :type list) ptr)
  20   (:temporary (:scs (descriptor-reg)) temp)
  21   (:temporary (:scs (descriptor-reg) :type list :to (:result 0) :target result)
  22               res)
  23   (:temporary (:sc non-descriptor-reg :offset nl4-offset) pa-flag)
  24   (:info num)
  25   (:results (result :scs (descriptor-reg)))
  26   (:variant-vars star)
  27   (:policy :safe)
  28   (:generator 0
  29     (cond ((zerop num)
  30            (move result null-tn))
  31           ((and star (= num 1))
  32            (move result (tn-ref-tn things)))
  33           (t
  34            (macrolet
  35                ((store-car (tn list &optional (slot cons-car-slot))
  36                   `(let ((reg
  37                           (sc-case ,tn
  38                             ((any-reg descriptor-reg) ,tn)
  39                             (zero zero-tn)
  40                             (null null-tn)
  41                             (control-stack
  42                              (load-stack-tn temp ,tn)
  43                              temp))))
  44                      (storew reg ,list ,slot list-pointer-lowtag))))
  45              (let ((cons-cells (if star (1- num) num)))
  46                (pseudo-atomic (pa-flag
  47                                :extra (* (pad-data-block cons-size)
  48                                          cons-cells))
  49                  (inst or res alloc-tn list-pointer-lowtag)
  50                  (move ptr res)
  51                  (dotimes (i (1- cons-cells))
  52                    (store-car (tn-ref-tn things) ptr)
  53                    (setf things (tn-ref-across things))
  54                    (inst addu ptr ptr (pad-data-block cons-size))
  55                    (storew ptr ptr
  56                            (- cons-cdr-slot cons-size)
  57                            list-pointer-lowtag))
  58                  (store-car (tn-ref-tn things) ptr)
  59                  (cond (star
  60                         (setf things (tn-ref-across things))
  61                         (store-car (tn-ref-tn things) ptr cons-cdr-slot))
  62                        (t
  63                         (storew null-tn ptr
  64                                 cons-cdr-slot list-pointer-lowtag)))
  65                  (aver (null (tn-ref-across things)))
  66                  (move result res))))))))
  67
  68 (define-vop (list list-or-list*)
  69   (:variant nil))
  70
  71 (define-vop (list* list-or-list*)
  72   (:variant t))
  73
  74 \f
  75 ;;;; Special purpose inline allocators.
  76
  77 (define-vop (allocate-code-object)
  78   (:args (boxed-arg :scs (any-reg))
  79          (unboxed-arg :scs (any-reg)))
  80   (:results (result :scs (descriptor-reg)))
  81   (:temporary (:scs (non-descriptor-reg)) ndescr)
  82   (:temporary (:scs (any-reg) :from (:argument 0)) boxed)
  83   (:temporary (:scs (non-descriptor-reg) :from (:argument 1)) unboxed)
  84   (:temporary (:sc non-descriptor-reg :offset nl4-offset) pa-flag)
  85   (:generator 100
  86     (inst li ndescr (lognot lowtag-mask))
  87     (inst addu boxed boxed-arg
  88           (fixnumize (1+ code-trace-table-offset-slot)))
  89     (inst and boxed ndescr)
  90     (inst srl unboxed unboxed-arg word-shift)
  91     (inst addu unboxed unboxed lowtag-mask)
  92     (inst and unboxed ndescr)
  93     (inst sll ndescr boxed (- n-widetag-bits word-shift))
  94     (inst or ndescr code-header-widetag)
  95
  96     (pseudo-atomic (pa-flag)
  97       (inst or result alloc-tn other-pointer-lowtag)
  98       (inst addu alloc-tn boxed)
  99       (storew ndescr result 0 other-pointer-lowtag)
 100       (storew unboxed result code-code-size-slot other-pointer-lowtag)
 101       (inst addu alloc-tn unboxed)
 102       (storew null-tn result code-entry-points-slot other-pointer-lowtag)
 103       (storew null-tn result code-debug-info-slot other-pointer-lowtag))))
 104
 105 (define-vop (make-fdefn)
 106   (:policy :fast-safe)
 107   (:translate make-fdefn)
 108   (:args (name :scs (descriptor-reg) :to :eval))
 109   (:temporary (:scs (non-descriptor-reg)) temp)
 110   (:temporary (:sc non-descriptor-reg :offset nl4-offset) pa-flag)
 111   (:results (result :scs (descriptor-reg) :from :argument))
 112   (:generator 37
 113     (with-fixed-allocation (result pa-flag temp fdefn-widetag fdefn-size)
 114       (inst li temp (make-fixup "undefined_tramp" :foreign))
 115       (storew name result fdefn-name-slot other-pointer-lowtag)
 116       (storew null-tn result fdefn-fun-slot other-pointer-lowtag)
 117       (storew temp result fdefn-raw-addr-slot other-pointer-lowtag))))
 118
 119 (define-vop (make-closure)
 120   (:args (function :to :save :scs (descriptor-reg)))
 121   (:info length stack-allocate-p)
 122   (:temporary (:scs (non-descriptor-reg)) temp)
 123   (:temporary (:sc non-descriptor-reg :offset nl4-offset) pa-flag)
 124   (:results (result :scs (descriptor-reg)))
 125   (:generator 10
 126     (let* ((size (+ length closure-info-offset))
 127            (alloc-size (pad-data-block size)))
 128       (pseudo-atomic (pa-flag :extra (if stack-allocate-p 0 alloc-size))
 129         (cond (stack-allocate-p
 130                (align-csp result)
 131                (inst srl result csp-tn n-lowtag-bits)
 132                (inst addu csp-tn alloc-size))
 133               (t
 134                (inst srl result alloc-tn n-lowtag-bits)))
 135         (inst sll result n-lowtag-bits)
 136         (inst or result fun-pointer-lowtag)
 137         (inst li temp (logior (ash (1- size) n-widetag-bits)
 138                               closure-header-widetag))
 139         (storew temp result 0 fun-pointer-lowtag))
 140       (storew result result closure-self-slot fun-pointer-lowtag)
 141       (storew function result closure-fun-slot fun-pointer-lowtag))))
 142
 143 ;;; The compiler likes to be able to directly make value cells.
 144 ;;;
 145 (define-vop (make-value-cell)
 146   (:args (value :to :save :scs (descriptor-reg any-reg null zero)))
 147   (:temporary (:scs (non-descriptor-reg)) temp)
 148   (:temporary (:sc non-descriptor-reg :offset nl4-offset) pa-flag)
 149   (:results (result :scs (descriptor-reg)))
 150   (:generator 10
 151     (with-fixed-allocation (result pa-flag temp value-cell-header-widetag value-cell-size)
 152       (storew value result value-cell-value-slot other-pointer-lowtag))))
 153
 154 \f
 155 ;;;; Automatic allocators for primitive objects.
 156
 157 (define-vop (make-unbound-marker)
 158   (:args)
 159   (:results (result :scs (any-reg)))
 160   (:generator 1
 161     (inst li result unbound-marker-widetag)))
 162
 163 (define-vop (fixed-alloc)
 164   (:args)
 165   (:info name words type lowtag)
 166   (:ignore name)
 167   (:results (result :scs (descriptor-reg)))
 168   (:temporary (:scs (non-descriptor-reg)) temp)
 169   (:temporary (:sc non-descriptor-reg :offset nl4-offset) pa-flag)
 170   (:generator 4
 171     (pseudo-atomic (pa-flag :extra (pad-data-block words))
 172       (inst or result alloc-tn lowtag)
 173       (when type
 174         (inst li temp (logior (ash (1- words) n-widetag-bits) type))
 175         (storew temp result 0 lowtag)))))
 176
 177 (define-vop (var-alloc)
 178   (:args (extra :scs (any-reg)))
 179   (:arg-types positive-fixnum)
 180   (:info name words type lowtag)
 181   (:ignore name)
 182   (:results (result :scs (descriptor-reg)))
 183   (:temporary (:scs (any-reg)) bytes)
 184   (:temporary (:scs (non-descriptor-reg)) header)
 185   (:temporary (:sc non-descriptor-reg :offset nl4-offset) pa-flag)
 186   (:generator 6
 187     (inst addu bytes extra (* (1+ words) n-word-bytes))
 188     (inst sll header bytes (- n-widetag-bits 2))
 189     (inst addu header header (+ (ash -2 n-widetag-bits) type))
 190     (inst srl bytes bytes n-lowtag-bits)
 191     (inst sll bytes bytes n-lowtag-bits)
 192     (pseudo-atomic (pa-flag)
 193       (inst or result alloc-tn lowtag)
 194       (storew header result 0 lowtag)
 195       (inst addu alloc-tn alloc-tn bytes))))
 196