src/compiler/parse-lambda-list.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3 ;;;;
   4 ;;;; This software is derived from the CMU CL system, which was
   5 ;;;; written at Carnegie Mellon University and released into the
   6 ;;;; public domain. The software is in the public domain and is
   7 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
   8 ;;;; files for more information.
   9
  10 (in-package "SB!C")
  11
  12 (/show0 "parse-lambda-list.lisp 12")
  13
  14 ;;; Break something like a lambda list (but not necessarily actually a
  15 ;;; lambda list, e.g. the representation of argument types which is
  16 ;;; used within an FTYPE specification) into its component parts. We
  17 ;;; return twelve values:
  18 ;;;  1. a list of the required args;
  19 ;;;  2. a list of the &OPTIONAL arg specs;
  20 ;;;  3. true if a &REST arg was specified;
  21 ;;;  4. the &REST arg;
  22 ;;;  5. true if &KEY args are present;
  23 ;;;  6. a list of the &KEY arg specs;
  24 ;;;  7. true if &ALLOW-OTHER-KEYS was specified.;
  25 ;;;  8. true if any &AUX is present (new in SBCL vs. CMU CL);
  26 ;;;  9. a list of the &AUX specifiers;
  27 ;;; 10. true if a &MORE arg was specified;
  28 ;;; 11. the &MORE context var;
  29 ;;; 12. the &MORE count var;
  30 ;;; 13. true if any lambda list keyword is present (only for
  31 ;;;     PARSE-LAMBDA-LIST-LIKE-THING).
  32 ;;;
  33 ;;; The top level lambda list syntax is checked for validity, but the
  34 ;;; arg specifiers are just passed through untouched. If something is
  35 ;;; wrong, we use COMPILER-ERROR, aborting compilation to the last
  36 ;;; recovery point.
  37 (declaim (ftype (sfunction (list)
  38                            (values list list boolean t boolean list boolean
  39                                    boolean list boolean t t boolean))
  40                 parse-lambda-list-like-thing))
  41 (declaim (ftype (sfunction (list)
  42                            (values list list boolean t boolean list boolean
  43                                    boolean list boolean t t))
  44                 parse-lambda-list))
  45 (defun parse-lambda-list-like-thing (list)
  46   (collect ((required)
  47             (optional)
  48             (keys)
  49             (aux))
  50     (let ((restp nil)
  51           (rest nil)
  52           (morep nil)
  53           (more-context nil)
  54           (more-count nil)
  55           (keyp nil)
  56           (auxp nil)
  57           (allowp nil)
  58           (state :required))
  59       (declare (type (member :allow-other-keys :aux
  60                              :key
  61                              :more-context :more-count
  62                              :optional
  63                              :post-more :post-rest
  64                              :required :rest)
  65                      state))
  66       (dolist (arg list)
  67         (if (member arg sb!xc:lambda-list-keywords)
  68             (case arg
  69               (&optional
  70                (unless (eq state :required)
  71                  (compiler-error "misplaced &OPTIONAL in lambda list: ~S"
  72                                  list))
  73                (setq state :optional))
  74               (&rest
  75                (unless (member state '(:required :optional))
  76                  (compiler-error "misplaced &REST in lambda list: ~S" list))
  77                (setq state :rest))
  78               (&more
  79                (unless (member state '(:required :optional))
  80                  (compiler-error "misplaced &MORE in lambda list: ~S" list))
  81                (setq morep t
  82                      state :more-context))
  83               (&key
  84                (unless (member state
  85                                '(:required :optional :post-rest :post-more))
  86                  (compiler-error "misplaced &KEY in lambda list: ~S" list))
  87                (when (optional)
  88                  (style-warn
  89                   "&OPTIONAL and &KEY found in the same lambda list: ~S" list))
  90                (setq keyp t
  91                      state :key))
  92               (&allow-other-keys
  93                (unless (eq state ':key)
  94                  (compiler-error "misplaced &ALLOW-OTHER-KEYS in ~
  95                                   lambda list: ~S"
  96                                  list))
  97                (setq allowp t
  98                      state :allow-other-keys))
  99               (&aux
 100                (when (member state '(:rest :more-context :more-count))
 101                  (compiler-error "misplaced &AUX in lambda list: ~S" list))
 102                (setq auxp t
 103                      state :aux))
 104               (t (bug "unknown LAMBDA-LIST-KEYWORD in lambda list: ~S." arg)))
 105             (progn
 106               (when (symbolp arg)
 107                 (let ((name (symbol-name arg)))
 108                   (when (and (plusp (length name))
 109                              (char= (char name 0) #\&))
 110                     (style-warn
 111                      "suspicious variable in lambda list: ~S." arg))))
 112               (case state
 113                 (:required (required arg))
 114                 (:optional (optional arg))
 115                 (:rest
 116                  (setq restp t
 117                        rest arg
 118                        state :post-rest))
 119                 (:more-context
 120                  (setq more-context arg
 121                        state :more-count))
 122                 (:more-count
 123                  (setq more-count arg
 124                        state :post-more))
 125                 (:key (keys arg))
 126                 (:aux (aux arg))
 127                 (t
 128                  (compiler-error "found garbage in lambda list when expecting ~
 129                                   a keyword: ~S"
 130                                  arg))))))
 131       (when (eq state :rest)
 132         (compiler-error "&REST without rest variable"))
 133
 134       (values (required) (optional) restp rest keyp (keys) allowp auxp (aux)
 135               morep more-context more-count
 136               (neq state :required)))))
 137
 138 ;;; like PARSE-LAMBDA-LIST-LIKE-THING, except our LAMBDA-LIST argument
 139 ;;; really *is* a lambda list, not just a "lambda-list-like thing", so
 140 ;;; can barf on things which're illegal as arguments in lambda lists
 141 ;;; even if they could conceivably be legal in not-quite-a-lambda-list
 142 ;;; weirdosities
 143 (defun parse-lambda-list (lambda-list)
 144
 145   ;; Classify parameters without checking their validity individually.
 146   (multiple-value-bind (required optional restp rest keyp keys allowp auxp aux
 147                         morep more-context more-count)
 148       (parse-lambda-list-like-thing lambda-list)
 149
 150     ;; Check validity of parameters.
 151     (flet ((need-symbol (x why)
 152              (unless (symbolp x)
 153                (compiler-error "~A is not a symbol: ~S" why x))))
 154       (dolist (i required)
 155         (need-symbol i "Required argument"))
 156       (dolist (i optional)
 157         (typecase i
 158           (symbol)
 159           (cons
 160            (destructuring-bind (var &optional init-form supplied-p) i
 161              (declare (ignore init-form supplied-p))
 162              (need-symbol var "&OPTIONAL parameter name")))
 163           (t
 164            (compiler-error "&OPTIONAL parameter is not a symbol or cons: ~S"
 165                            i))))
 166       (when restp
 167         (need-symbol rest "&REST argument"))
 168       (when keyp
 169         (dolist (i keys)
 170           (typecase i
 171             (symbol)
 172             (cons
 173              (destructuring-bind (var-or-kv &optional init-form supplied-p) i
 174                (declare (ignore init-form supplied-p))
 175                (if (consp var-or-kv)
 176                    (destructuring-bind (keyword-name var) var-or-kv
 177                      (declare (ignore keyword-name))
 178                      (need-symbol var "&KEY parameter name"))
 179                    (need-symbol var-or-kv "&KEY parameter name"))))
 180             (t
 181              (compiler-error "&KEY parameter is not a symbol or cons: ~S"
 182                              i))))))
 183
 184     ;; Voila.
 185     (values required optional restp rest keyp keys allowp auxp aux
 186             morep more-context more-count)))
 187
 188 (/show0 "parse-lambda-list.lisp end of file")