src/compiler/physenvanal.lisp

   1 ;;;; This file implements the environment analysis phase for the
   2 ;;;; compiler. This phase annotates IR1 with a hierarchy environment
   3 ;;;; structures, determining the physical environment that each LAMBDA
   4 ;;;; allocates its variables and finding what values are closed over
   5 ;;;; by each physical environment.
   6
   7 ;;;; This software is part of the SBCL system. See the README file for
   8 ;;;; more information.
   9 ;;;;
  10 ;;;; This software is derived from the CMU CL system, which was
  11 ;;;; written at Carnegie Mellon University and released into the
  12 ;;;; public domain. The software is in the public domain and is
  13 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  14 ;;;; files for more information.
  15
  16 (in-package "SB!C")
  17
  18 ;;; Do environment analysis on the code in COMPONENT. This involves
  19 ;;; various things:
  20 ;;;  1. Make a PHYSENV structure for each non-LET LAMBDA, assigning
  21 ;;;     the LAMBDA-PHYSENV for all LAMBDAs.
  22 ;;;  2. Find all values that need to be closed over by each
  23 ;;;     physical environment.
  24 ;;;  3. Scan the blocks in the component closing over non-local-exit
  25 ;;;     continuations.
  26 ;;;  4. Delete all non-top-level functions with no references. This
  27 ;;;     should only get functions with non-NULL kinds, since normal
  28 ;;;     functions are deleted when their references go to zero.
  29 (defun physenv-analyze (component)
  30   (declare (type component component))
  31   (aver (every (lambda (x)
  32                  (eq (functional-kind x) :deleted))
  33                (component-new-functionals component)))
  34   (setf (component-new-functionals component) ())
  35   (dolist (clambda (component-lambdas component))
  36     (reinit-lambda-physenv clambda))
  37   (mapc #'add-lambda-vars-and-let-vars-to-closures
  38         (component-lambdas component))
  39
  40   (find-non-local-exits component)
  41   (recheck-dynamic-extent-lvars component)
  42   (find-cleanup-points component)
  43   (tail-annotate component)
  44
  45   (dolist (fun (component-lambdas component))
  46     (when (null (leaf-refs fun))
  47       (let ((kind (functional-kind fun)))
  48         (unless (or (eq kind :toplevel)
  49                     (functional-has-external-references-p fun))
  50           (aver (member kind '(:optional :cleanup :escape)))
  51           (setf (functional-kind fun) nil)
  52           (delete-functional fun)))))
  53
  54   (setf (component-nlx-info-generated-p component) t)
  55   (values))
  56
  57 ;;; This is to be called on a COMPONENT with top level LAMBDAs before
  58 ;;; the compilation of the associated non-top-level code to detect
  59 ;;; closed over top level variables. We just do COMPUTE-CLOSURE on all
  60 ;;; the lambdas. This will pre-allocate environments for all the
  61 ;;; functions with closed-over top level variables. The post-pass will
  62 ;;; use the existing structure, rather than allocating a new one. We
  63 ;;; return true if we discover any possible closure vars.
  64 (defun pre-physenv-analyze-toplevel (component)
  65   (declare (type component component))
  66   (let ((found-it nil))
  67     (dolist (lambda (component-lambdas component))
  68       (when (add-lambda-vars-and-let-vars-to-closures lambda)
  69         (setq found-it t)))
  70     found-it))
  71
  72 ;;; This is like old CMU CL PRE-ENVIRONMENT-ANALYZE-TOPLEVEL, except
  73 ;;;   (1) It's been brought into the post-0.7.0 world where the property
  74 ;;;       HAS-EXTERNAL-REFERENCES-P is orthogonal to the property of
  75 ;;;       being specialized/optimized for locall at top level.
  76 ;;;   (2) There's no return value, since we don't care whether we
  77 ;;;       find any possible closure variables.
  78 ;;;
  79 ;;; I wish I could find an explanation of why
  80 ;;; PRE-ENVIRONMENT-ANALYZE-TOPLEVEL is important. The old CMU CL
  81 ;;; comments said
  82 ;;;     Called on component with top level lambdas before the
  83 ;;;     compilation of the associated non-top-level code to detect
  84 ;;;     closed over top level variables. We just do COMPUTE-CLOSURE on
  85 ;;;     all the lambdas. This will pre-allocate environments for all
  86 ;;;     the functions with closed-over top level variables. The
  87 ;;;     post-pass will use the existing structure, rather than
  88 ;;;     allocating a new one. We return true if we discover any
  89 ;;;     possible closure vars.
  90 ;;; But that doesn't seem to explain either why it's important to do
  91 ;;; this for top level lambdas, or why it's important to do it only
  92 ;;; for top level lambdas instead of just doing it indiscriminately
  93 ;;; for all lambdas. I do observe that when it's not done, compiler
  94 ;;; assertions occasionally fail. My tentative hypothesis for why it's
  95 ;;; important to do it is that other environment analysis expects to
  96 ;;; bottom out on the outermost enclosing thing, and (insert
  97 ;;; mysterious reason here) it's important to set up bottomed-out-here
  98 ;;; environments before anything else. I haven't been able to guess
  99 ;;; why it's important to do it selectively instead of
 100 ;;; indiscriminately. -- WHN 2001-11-10
 101 (defun preallocate-physenvs-for-toplevelish-lambdas (component)
 102   (dolist (clambda (component-lambdas component))
 103     (when (lambda-toplevelish-p clambda)
 104       (add-lambda-vars-and-let-vars-to-closures clambda)))
 105   (values))
 106
 107 ;;; If CLAMBDA has a PHYSENV, return it, otherwise assign an empty one
 108 ;;; and return that.
 109 (defun get-lambda-physenv (clambda)
 110   (declare (type clambda clambda))
 111   (let ((homefun (lambda-home clambda)))
 112     (or (lambda-physenv homefun)
 113         (let ((res (make-physenv :lambda homefun)))
 114           (setf (lambda-physenv homefun) res)
 115           ;; All the LETLAMBDAs belong to HOMEFUN, and share the same
 116           ;; PHYSENV. Thus, (1) since HOMEFUN's PHYSENV was NIL,
 117           ;; theirs should be NIL too, and (2) since we're modifying
 118           ;; HOMEFUN's PHYSENV, we should modify theirs, too.
 119           (dolist (letlambda (lambda-lets homefun))
 120             (aver (eql (lambda-home letlambda) homefun))
 121             (aver (null (lambda-physenv letlambda)))
 122             (setf (lambda-physenv letlambda) res))
 123           res))))
 124
 125 ;;; If FUN has no physical environment, assign one, otherwise clean up
 126 ;;; the old physical environment, removing/flagging variables that
 127 ;;; have no sets or refs. If a var has no references, we remove it
 128 ;;; from the closure. We always clear the INDIRECT flag. This is
 129 ;;; necessary because pre-analysis is done before optimization.
 130 (defun reinit-lambda-physenv (fun)
 131   (let ((old (lambda-physenv (lambda-home fun))))
 132     (cond (old
 133            (setf (physenv-closure old)
 134                  (delete-if (lambda (x)
 135                               (and (lambda-var-p x)
 136                                    (null (leaf-refs x))))
 137                             (physenv-closure old)))
 138            (flet ((clear (fun)
 139                     (dolist (var (lambda-vars fun))
 140                       (setf (lambda-var-indirect var) nil))))
 141              (clear fun)
 142              (map nil #'clear (lambda-lets fun))))
 143           (t
 144            (get-lambda-physenv fun))))
 145   (values))
 146
 147 ;;; Get NODE's environment, assigning one if necessary.
 148 (defun get-node-physenv (node)
 149   (declare (type node node))
 150   (get-lambda-physenv (node-home-lambda node)))
 151
 152 ;;; private guts of ADD-LAMBDA-VARS-AND-LET-VARS-TO-CLOSURES
 153 ;;;
 154 ;;; This is the old CMU CL COMPUTE-CLOSURE, which only works on
 155 ;;; LAMBDA-VARS directly, not on the LAMBDA-VARS of LAMBDA-LETS. It
 156 ;;; seems never to be valid to use this operation alone, so in SBCL,
 157 ;;; it's private, and the public interface,
 158 ;;; ADD-LAMBDA-VARS-AND-LET-VARS-TO-CLOSURES, always runs over all the
 159 ;;; variables, not only the LAMBDA-VARS of CLAMBDA itself but also
 160 ;;; the LAMBDA-VARS of CLAMBDA's LAMBDA-LETS.
 161 (defun %add-lambda-vars-to-closures (clambda)
 162   (let ((physenv (get-lambda-physenv clambda))
 163         (did-something nil))
 164     (note-unreferenced-vars clambda)
 165     (dolist (var (lambda-vars clambda))
 166       (dolist (ref (leaf-refs var))
 167         (let ((ref-physenv (get-node-physenv ref)))
 168           (unless (eq ref-physenv physenv)
 169             (when (lambda-var-sets var)
 170               (setf (lambda-var-indirect var) t))
 171             (setq did-something t)
 172             (close-over var ref-physenv physenv))))
 173       (dolist (set (basic-var-sets var))
 174
 175         ;; Variables which are set but never referenced can be
 176         ;; optimized away, and closing over them here would just
 177         ;; interfere with that. (In bug 147, it *did* interfere with
 178         ;; that, causing confusion later. This UNLESS solves that
 179         ;; problem, but I (WHN) am not 100% sure it's best to solve
 180         ;; the problem this way instead of somehow solving it
 181         ;; somewhere upstream and just doing (AVER (LEAF-REFS VAR))
 182         ;; here.)
 183         (unless (null (leaf-refs var))
 184
 185           (let ((set-physenv (get-node-physenv set)))
 186             (unless (eq set-physenv physenv)
 187               (setf did-something t
 188                     (lambda-var-indirect var) t)
 189               (close-over var set-physenv physenv))))))
 190     did-something))
 191
 192 ;;; Find any variables in CLAMBDA -- either directly in LAMBDA-VARS or
 193 ;;; in the LAMBDA-VARS of elements of LAMBDA-LETS -- with references
 194 ;;; outside of the home environment and close over them. If a
 195 ;;; closed-over variable is set, then we set the INDIRECT flag so that
 196 ;;; we will know the closed over value is really a pointer to the
 197 ;;; value cell. We also warn about unreferenced variables here, just
 198 ;;; because it's a convenient place to do it. We return true if we
 199 ;;; close over anything.
 200 (defun add-lambda-vars-and-let-vars-to-closures (clambda)
 201   (declare (type clambda clambda))
 202   (let ((did-something nil))
 203     (when (%add-lambda-vars-to-closures clambda)
 204       (setf did-something t))
 205     (dolist (lambda-let (lambda-lets clambda))
 206       ;; There's no need to recurse through full COMPUTE-CLOSURE
 207       ;; here, since LETS only go one layer deep.
 208       (aver (null (lambda-lets lambda-let)))
 209       (when (%add-lambda-vars-to-closures lambda-let)
 210         (setf did-something t)))
 211     did-something))
 212
 213 ;;; Make sure that THING is closed over in REF-PHYSENV and in all
 214 ;;; PHYSENVs for the functions that reference REF-PHYSENV's function
 215 ;;; (not just calls). HOME-PHYSENV is THING's home environment. When we
 216 ;;; reach the home environment, we stop propagating the closure.
 217 (defun close-over (thing ref-physenv home-physenv)
 218   (declare (type physenv ref-physenv home-physenv))
 219   (let ((flooded-physenvs nil))
 220     (named-let flood ((flooded-physenv ref-physenv))
 221       (unless (or (eql flooded-physenv home-physenv)
 222                   (member flooded-physenv flooded-physenvs))
 223         (push flooded-physenv flooded-physenvs)
 224         (pushnew thing (physenv-closure flooded-physenv))
 225         (dolist (ref (leaf-refs (physenv-lambda flooded-physenv)))
 226           (flood (get-node-physenv ref))))))
 227   (values))
 228 \f
 229 ;;;; non-local exit
 230
 231 ;;; Insert the entry stub before the original exit target, and add a
 232 ;;; new entry to the PHYSENV-NLX-INFO. The %NLX-ENTRY call in the
 233 ;;; stub is passed the NLX-INFO as an argument so that the back end
 234 ;;; knows what entry is being done.
 235 ;;;
 236 ;;; The link from the EXIT block to the entry stub is changed to be a
 237 ;;; link from the component head. Similarly, the EXIT block is linked
 238 ;;; to the component tail. This leaves the entry stub reachable, but
 239 ;;; makes the flow graph less confusing to flow analysis.
 240 ;;;
 241 ;;; If a CATCH or an UNWIND-protect, then we set the LEXENV for the
 242 ;;; last node in the cleanup code to be the enclosing environment, to
 243 ;;; represent the fact that the binding was undone as a side effect of
 244 ;;; the exit. This will cause a lexical exit to be broken up if we are
 245 ;;; actually exiting the scope (i.e. a BLOCK), and will also do any
 246 ;;; other cleanups that may have to be done on the way.
 247 (defun insert-nlx-entry-stub (exit env)
 248   (declare (type physenv env) (type exit exit))
 249   (let* ((exit-block (node-block exit))
 250          (next-block (first (block-succ exit-block)))
 251          (entry (exit-entry exit))
 252          (cleanup (entry-cleanup entry))
 253          (info (make-nlx-info cleanup exit))
 254          (new-block (insert-cleanup-code exit-block next-block
 255                                          entry
 256                                          `(%nlx-entry ',info)
 257                                          cleanup))
 258          (component (block-component new-block)))
 259     (unlink-blocks exit-block new-block)
 260     (link-blocks exit-block (component-tail component))
 261     (link-blocks (component-head component) new-block)
 262
 263     (setf (nlx-info-target info) new-block)
 264     (push info (physenv-nlx-info env))
 265     (push info (cleanup-nlx-info cleanup))
 266     (when (member (cleanup-kind cleanup) '(:catch :unwind-protect))
 267       (setf (node-lexenv (block-last new-block))
 268             (node-lexenv entry))))
 269
 270   (values))
 271
 272 ;;; Do stuff necessary to represent a non-local exit from the node
 273 ;;; EXIT into ENV. This is called for each non-local exit node, of
 274 ;;; which there may be several per exit continuation. This is what we
 275 ;;; do:
 276 ;;; -- If there isn't any NLX-INFO entry in the environment, make
 277 ;;;    an entry stub, otherwise just move the exit block link to
 278 ;;;    the component tail.
 279 ;;; -- Close over the NLX-INFO in the exit environment.
 280 ;;; -- If the exit is from an :ESCAPE function, then substitute a
 281 ;;;    constant reference to NLX-INFO structure for the escape
 282 ;;;    function reference. This will cause the escape function to
 283 ;;;    be deleted (although not removed from the DFO.)  The escape
 284 ;;;    function is no longer needed, and we don't want to emit code
 285 ;;;    for it.
 286 ;;; -- Change the %NLX-ENTRY call to use the NLX lvar so that 1) there
 287 ;;;    will be a use to represent the NLX use; 2) make life easier for
 288 ;;;    the stack analysis.
 289 (defun note-non-local-exit (env exit)
 290   (declare (type physenv env) (type exit exit))
 291   (let ((lvar (node-lvar exit))
 292         (exit-fun (node-home-lambda exit)))
 293     (if (find-nlx-info exit)
 294         (let ((block (node-block exit)))
 295           (aver (= (length (block-succ block)) 1))
 296           (unlink-blocks block (first (block-succ block)))
 297           (link-blocks block (component-tail (block-component block))))
 298         (insert-nlx-entry-stub exit env))
 299     (let ((info (find-nlx-info exit)))
 300       (aver info)
 301       (close-over info (node-physenv exit) env)
 302       (when (eq (functional-kind exit-fun) :escape)
 303         (mapc (lambda (x)
 304                 (setf (node-derived-type x) *wild-type*))
 305               (leaf-refs exit-fun))
 306         (substitute-leaf (find-constant info) exit-fun))
 307       (when lvar
 308         (let ((node (block-last (nlx-info-target info))))
 309           (unless (node-lvar node)
 310             (aver (eq lvar (node-lvar exit)))
 311             (setf (node-derived-type node) (lvar-derived-type lvar))
 312             (add-lvar-use node lvar))))))
 313   (values))
 314
 315 ;;; Iterate over the EXITs in COMPONENT, calling NOTE-NON-LOCAL-EXIT
 316 ;;; when we find a block that ends in a non-local EXIT node. We also
 317 ;;; ensure that all EXIT nodes are either non-local or degenerate by
 318 ;;; calling IR1-OPTIMIZE-EXIT on local exits. This makes life simpler
 319 ;;; for later phases.
 320 (defun find-non-local-exits (component)
 321   (declare (type component component))
 322   (dolist (lambda (component-lambdas component))
 323     (dolist (entry (lambda-entries lambda))
 324       (dolist (exit (entry-exits entry))
 325         (let ((target-physenv (node-physenv entry)))
 326           (if (eq (node-physenv exit) target-physenv)
 327               (maybe-delete-exit exit)
 328               (note-non-local-exit target-physenv exit))))))
 329   (values))
 330 \f
 331 ;;;; final decision on stack allocation of dynamic-extent structores
 332 (defun recheck-dynamic-extent-lvars (component)
 333   (declare (type component component))
 334   (dolist (lambda (component-lambdas component))
 335     (loop for entry in (lambda-entries lambda)
 336             for cleanup = (entry-cleanup entry)
 337             do (when (eq (cleanup-kind cleanup) :dynamic-extent)
 338                  (collect ((real-dx-lvars))
 339                    (loop for lvar in (cleanup-info cleanup)
 340                          do (let ((use (lvar-uses lvar)))
 341                               (if (and (combination-p use)
 342                                        (eq (basic-combination-kind use) :known)
 343                                        (awhen (fun-info-stack-allocate-result
 344                                                (basic-combination-fun-info use))
 345                                          (funcall it use)))
 346                                   (real-dx-lvars lvar)
 347                                   (setf (lvar-dynamic-extent lvar) nil))))
 348                    (setf (cleanup-info cleanup) (real-dx-lvars))
 349                    (setf (component-dx-lvars component)
 350                          (append (real-dx-lvars) (component-dx-lvars component)))))))
 351   (values))
 352 \f
 353 ;;;; cleanup emission
 354
 355 ;;; Zoom up the cleanup nesting until we hit CLEANUP1, accumulating
 356 ;;; cleanup code as we go. When we are done, convert the cleanup code
 357 ;;; in an implicit MV-PROG1. We have to force local call analysis of
 358 ;;; new references to UNWIND-PROTECT cleanup functions. If we don't
 359 ;;; actually have to do anything, then we don't insert any cleanup
 360 ;;; code. (FIXME: There's some confusion here, left over from CMU CL
 361 ;;; comments. CLEANUP1 isn't mentioned in the code of this function.
 362 ;;; It is in code elsewhere, but if the comments for this function
 363 ;;; mention it they should explain the relationship to the other code.)
 364 ;;;
 365 ;;; If we do insert cleanup code, we check that BLOCK1 doesn't end in
 366 ;;; a "tail" local call.
 367 ;;;
 368 ;;; We don't need to adjust the ending cleanup of the cleanup block,
 369 ;;; since the cleanup blocks are inserted at the start of the DFO, and
 370 ;;; are thus never scanned.
 371 (defun emit-cleanups (block1 block2)
 372   (declare (type cblock block1 block2))
 373   (collect ((code)
 374             (reanalyze-funs))
 375     (let ((cleanup2 (block-start-cleanup block2)))
 376       (do ((cleanup (block-end-cleanup block1)
 377                     (node-enclosing-cleanup (cleanup-mess-up cleanup))))
 378           ((eq cleanup cleanup2))
 379         (let* ((node (cleanup-mess-up cleanup))
 380                (args (when (basic-combination-p node)
 381                        (basic-combination-args node))))
 382           (ecase (cleanup-kind cleanup)
 383             (:special-bind
 384              (code `(%special-unbind ',(lvar-value (first args)))))
 385             (:catch
 386              (code `(%catch-breakup)))
 387             (:unwind-protect
 388              (code `(%unwind-protect-breakup))
 389              (let ((fun (ref-leaf (lvar-uses (second args)))))
 390                (reanalyze-funs fun)
 391                (code `(%funcall ,fun))))
 392             ((:block :tagbody)
 393              (dolist (nlx (cleanup-nlx-info cleanup))
 394                (code `(%lexical-exit-breakup ',nlx))))
 395             (:dynamic-extent
 396              (when (not (null (cleanup-info cleanup)))
 397                (code `(%cleanup-point)))))))
 398
 399       (when (code)
 400         (aver (not (node-tail-p (block-last block1))))
 401         (insert-cleanup-code block1 block2
 402                              (block-last block1)
 403                              `(progn ,@(code)))
 404         (dolist (fun (reanalyze-funs))
 405           (locall-analyze-fun-1 fun)))))
 406
 407   (values))
 408
 409 ;;; Loop over the blocks in COMPONENT, calling EMIT-CLEANUPS when we
 410 ;;; see a successor in the same environment with a different cleanup.
 411 ;;; We ignore the cleanup transition if it is to a cleanup enclosed by
 412 ;;; the current cleanup, since in that case we are just messing up the
 413 ;;; environment, hence this is not the place to clean it.
 414 (defun find-cleanup-points (component)
 415   (declare (type component component))
 416   (do-blocks (block1 component)
 417     (let ((env1 (block-physenv block1))
 418           (cleanup1 (block-end-cleanup block1)))
 419       (dolist (block2 (block-succ block1))
 420         (when (block-start block2)
 421           (let ((env2 (block-physenv block2))
 422                 (cleanup2 (block-start-cleanup block2)))
 423             (unless (or (not (eq env2 env1))
 424                         (eq cleanup1 cleanup2)
 425                         (and cleanup2
 426                              (eq (node-enclosing-cleanup
 427                                   (cleanup-mess-up cleanup2))
 428                                  cleanup1)))
 429               (emit-cleanups block1 block2)))))))
 430   (values))
 431
 432 ;;; Mark optimizable tail-recursive uses of function result
 433 ;;; continuations with the corresponding TAIL-SET.
 434 (defun tail-annotate (component)
 435   (declare (type component component))
 436   (dolist (fun (component-lambdas component))
 437     (let ((ret (lambda-return fun)))
 438       ;; Nodes whose type is NIL (i.e. don't return) such as calls to
 439       ;; ERROR are never annotated as TAIL-P, in order to preserve
 440       ;; debugging information.
 441       ;;
 442       ;; FIXME: It might be better to add another DEFKNOWN property
 443       ;; (e.g. NO-TAIL-RECURSION) and use it for error-handling
 444       ;; functions like ERROR, instead of spreading this special case
 445       ;; net so widely.
 446       (when ret
 447         (let ((result (return-result ret)))
 448           (do-uses (use result)
 449             (when (and (policy use merge-tail-calls)
 450                        (basic-combination-p use)
 451                        (immediately-used-p result use)
 452                        (or (not (eq (node-derived-type use) *empty-type*))
 453                            (eq (basic-combination-kind use) :local)))
 454               (setf (node-tail-p use) t)))))))
 455   (values))