src/compiler/physenvanal.lisp

   1 ;;;; This file implements the environment analysis phase for the
   2 ;;;; compiler. This phase annotates IR1 with a hierarchy environment
   3 ;;;; structures, determining the physical environment that each LAMBDA
   4 ;;;; allocates its variables and finding what values are closed over
   5 ;;;; by each physical environment.
   6
   7 ;;;; This software is part of the SBCL system. See the README file for
   8 ;;;; more information.
   9 ;;;;
  10 ;;;; This software is derived from the CMU CL system, which was
  11 ;;;; written at Carnegie Mellon University and released into the
  12 ;;;; public domain. The software is in the public domain and is
  13 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  14 ;;;; files for more information.
  15
  16 (in-package "SB!C")
  17
  18 ;;; Do environment analysis on the code in COMPONENT. This involves
  19 ;;; various things:
  20 ;;;  1. Make a PHYSENV structure for each non-LET LAMBDA, assigning
  21 ;;;     the LAMBDA-PHYSENV for all LAMBDAs.
  22 ;;;  2. Find all values that need to be closed over by each
  23 ;;;     physical environment.
  24 ;;;  3. Scan the blocks in the component closing over non-local-exit
  25 ;;;     continuations.
  26 ;;;  4. Delete all non-top-level functions with no references. This
  27 ;;;     should only get functions with non-NULL kinds, since normal
  28 ;;;     functions are deleted when their references go to zero.
  29 (defun physenv-analyze (component)
  30   (declare (type component component))
  31   (aver (every (lambda (x)
  32                  (eq (functional-kind x) :deleted))
  33                (component-new-functionals component)))
  34   (setf (component-new-functionals component) ())
  35   (dolist (clambda (component-lambdas component))
  36     (reinit-lambda-physenv clambda))
  37   (mapc #'add-lambda-vars-and-let-vars-to-closures
  38         (component-lambdas component))
  39
  40   (find-non-local-exits component)
  41   (recheck-dynamic-extent-lvars component)
  42   (find-cleanup-points component)
  43   (tail-annotate component)
  44   (analyze-indirect-lambda-vars component)
  45
  46   (dolist (fun (component-lambdas component))
  47     (when (null (leaf-refs fun))
  48       (let ((kind (functional-kind fun)))
  49         (unless (or (eq kind :toplevel)
  50                     (functional-has-external-references-p fun))
  51           (aver (member kind '(:optional :cleanup :escape)))
  52           (setf (functional-kind fun) nil)
  53           (delete-functional fun)))))
  54
  55   (setf (component-nlx-info-generated-p component) t)
  56   (values))
  57
  58 ;;; This is to be called on a COMPONENT with top level LAMBDAs before
  59 ;;; the compilation of the associated non-top-level code to detect
  60 ;;; closed over top level variables. We just do COMPUTE-CLOSURE on all
  61 ;;; the lambdas. This will pre-allocate environments for all the
  62 ;;; functions with closed-over top level variables. The post-pass will
  63 ;;; use the existing structure, rather than allocating a new one. We
  64 ;;; return true if we discover any possible closure vars.
  65 (defun pre-physenv-analyze-toplevel (component)
  66   (declare (type component component))
  67   (let ((found-it nil))
  68     (dolist (lambda (component-lambdas component))
  69       (when (add-lambda-vars-and-let-vars-to-closures lambda)
  70         (setq found-it t)))
  71     found-it))
  72
  73 ;;; If CLAMBDA has a PHYSENV, return it, otherwise assign an empty one
  74 ;;; and return that.
  75 (defun get-lambda-physenv (clambda)
  76   (declare (type clambda clambda))
  77   (let ((homefun (lambda-home clambda)))
  78     (or (lambda-physenv homefun)
  79         (let ((res (make-physenv :lambda homefun)))
  80           (setf (lambda-physenv homefun) res)
  81           ;; All the LETLAMBDAs belong to HOMEFUN, and share the same
  82           ;; PHYSENV. Thus, (1) since HOMEFUN's PHYSENV was NIL,
  83           ;; theirs should be NIL too, and (2) since we're modifying
  84           ;; HOMEFUN's PHYSENV, we should modify theirs, too.
  85           (dolist (letlambda (lambda-lets homefun))
  86             (aver (eql (lambda-home letlambda) homefun))
  87             (aver (null (lambda-physenv letlambda)))
  88             (setf (lambda-physenv letlambda) res))
  89           res))))
  90
  91 ;;; If FUN has no physical environment, assign one, otherwise clean up
  92 ;;; the old physical environment and the INDIRECT flag on LAMBDA-VARs.
  93 ;;; This is necessary because pre-analysis is done before
  94 ;;; optimization.
  95 (defun reinit-lambda-physenv (fun)
  96   (let ((old (lambda-physenv (lambda-home fun))))
  97     (cond (old
  98            (setf (physenv-closure old) nil)
  99            (flet ((clear (fun)
 100                     (dolist (var (lambda-vars fun))
 101                       (setf (lambda-var-indirect var) nil))))
 102              (clear fun)
 103              (map nil #'clear (lambda-lets fun))))
 104           (t
 105            (get-lambda-physenv fun))))
 106   (values))
 107
 108 ;;; Get NODE's environment, assigning one if necessary.
 109 (defun get-node-physenv (node)
 110   (declare (type node node))
 111   (get-lambda-physenv (node-home-lambda node)))
 112
 113 ;;; private guts of ADD-LAMBDA-VARS-AND-LET-VARS-TO-CLOSURES
 114 ;;;
 115 ;;; This is the old CMU CL COMPUTE-CLOSURE, which only works on
 116 ;;; LAMBDA-VARS directly, not on the LAMBDA-VARS of LAMBDA-LETS. It
 117 ;;; seems never to be valid to use this operation alone, so in SBCL,
 118 ;;; it's private, and the public interface,
 119 ;;; ADD-LAMBDA-VARS-AND-LET-VARS-TO-CLOSURES, always runs over all the
 120 ;;; variables, not only the LAMBDA-VARS of CLAMBDA itself but also
 121 ;;; the LAMBDA-VARS of CLAMBDA's LAMBDA-LETS.
 122 (defun %add-lambda-vars-to-closures (clambda)
 123   (let ((physenv (get-lambda-physenv clambda))
 124         (did-something nil))
 125     (note-unreferenced-vars clambda)
 126     (dolist (var (lambda-vars clambda))
 127       (dolist (ref (leaf-refs var))
 128         (let ((ref-physenv (get-node-physenv ref)))
 129           (unless (eq ref-physenv physenv)
 130             (when (lambda-var-sets var)
 131               (setf (lambda-var-indirect var) t))
 132             (setq did-something t)
 133             (close-over var ref-physenv physenv))))
 134       (dolist (set (basic-var-sets var))
 135
 136         ;; Variables which are set but never referenced can be
 137         ;; optimized away, and closing over them here would just
 138         ;; interfere with that. (In bug 147, it *did* interfere with
 139         ;; that, causing confusion later. This UNLESS solves that
 140         ;; problem, but I (WHN) am not 100% sure it's best to solve
 141         ;; the problem this way instead of somehow solving it
 142         ;; somewhere upstream and just doing (AVER (LEAF-REFS VAR))
 143         ;; here.)
 144         (unless (null (leaf-refs var))
 145
 146           (let ((set-physenv (get-node-physenv set)))
 147             (unless (eq set-physenv physenv)
 148               (setf did-something t
 149                     (lambda-var-indirect var) t)
 150               (close-over var set-physenv physenv))))))
 151     did-something))
 152
 153 ;;; Find any variables in CLAMBDA -- either directly in LAMBDA-VARS or
 154 ;;; in the LAMBDA-VARS of elements of LAMBDA-LETS -- with references
 155 ;;; outside of the home environment and close over them. If a
 156 ;;; closed-over variable is set, then we set the INDIRECT flag so that
 157 ;;; we will know the closed over value is really a pointer to the
 158 ;;; value cell. We also warn about unreferenced variables here, just
 159 ;;; because it's a convenient place to do it. We return true if we
 160 ;;; close over anything.
 161 (defun add-lambda-vars-and-let-vars-to-closures (clambda)
 162   (declare (type clambda clambda))
 163   (let ((did-something nil))
 164     (when (%add-lambda-vars-to-closures clambda)
 165       (setf did-something t))
 166     (dolist (lambda-let (lambda-lets clambda))
 167       ;; There's no need to recurse through full COMPUTE-CLOSURE
 168       ;; here, since LETS only go one layer deep.
 169       (aver (null (lambda-lets lambda-let)))
 170       (when (%add-lambda-vars-to-closures lambda-let)
 171         (setf did-something t)))
 172     did-something))
 173
 174 (defun xep-allocator (xep)
 175   (let ((entry (functional-entry-fun xep)))
 176     (functional-allocator entry)))
 177
 178 ;;; Make sure that THING is closed over in REF-PHYSENV and in all
 179 ;;; PHYSENVs for the functions that reference REF-PHYSENV's function
 180 ;;; (not just calls). HOME-PHYSENV is THING's home environment. When we
 181 ;;; reach the home environment, we stop propagating the closure.
 182 (defun close-over (thing ref-physenv home-physenv)
 183   (declare (type physenv ref-physenv home-physenv))
 184   (let ((flooded-physenvs nil))
 185     (labels ((flood (flooded-physenv)
 186                (unless (or (eql flooded-physenv home-physenv)
 187                            (member flooded-physenv flooded-physenvs))
 188                  (push flooded-physenv flooded-physenvs)
 189                  (unless (memq thing (physenv-closure flooded-physenv))
 190                    (push thing (physenv-closure flooded-physenv))
 191                    (let ((lambda (physenv-lambda flooded-physenv)))
 192                      (cond ((eq (functional-kind lambda) :external)
 193                             (let* ((alloc-node (xep-allocator lambda))
 194                                    (alloc-lambda (node-home-lambda alloc-node))
 195                                    (alloc-physenv (get-lambda-physenv alloc-lambda)))
 196                               (flood alloc-physenv)
 197                               (dolist (ref (leaf-refs lambda))
 198                                 (close-over lambda
 199                                             (get-node-physenv ref) alloc-physenv))))
 200                            (t (dolist (ref (leaf-refs lambda))
 201                                 ;; FIXME: This assertion looks
 202                                 ;; reasonable, but does not work for
 203                                 ;; :CLEANUPs.
 204                                 #+nil
 205                                 (let ((dest (node-dest ref)))
 206                                   (aver (basic-combination-p dest))
 207                                   (aver (eq (basic-combination-kind dest) :local)))
 208                                 (flood (get-node-physenv ref))))))))))
 209       (flood ref-physenv)))
 210   (values))
 211
 212 ;;; Find LAMBDA-VARs that are marked as needing to support indirect
 213 ;;; access (SET at some point after initial creation) that are present
 214 ;;; in CLAMBDAs not marked as being DYNAMIC-EXTENT (meaning that the
 215 ;;; value-cell involved must be able to survive past the extent of the
 216 ;;; allocating frame), and mark them (the LAMBDA-VARs) as needing
 217 ;;; explicit value-cells.  Because they are already closed-over, the
 218 ;;; LAMBDA-VARs already appear in the closures of all of the CLAMBDAs
 219 ;;; that need checking.
 220 (defun analyze-indirect-lambda-vars (component)
 221   (dolist (fun (component-lambdas component))
 222     (let ((entry-fun (functional-entry-fun fun)))
 223       ;; We also check the ENTRY-FUN, as XEPs for LABELS or FLET
 224       ;; functions aren't set to be DX even if their underlying
 225       ;; CLAMBDAs are, and if we ever get LET-bound anonymous function
 226       ;; DX working, it would mark the XEP as being DX but not the
 227       ;; "real" CLAMBDA.  This works because a FUNCTIONAL-ENTRY-FUN is
 228       ;; either NULL, a self-pointer (for :TOPLEVEL functions), a
 229       ;; pointer from an XEP to its underlying function (for :EXTERNAL
 230       ;; functions), or a pointer from an underlying function to its
 231       ;; XEP (for non-:TOPLEVEL functions with XEPs).
 232       (unless (or (leaf-dynamic-extent fun)
 233                   ;; Functions without XEPs can be treated as if they
 234                   ;; are DYNAMIC-EXTENT, even without being so
 235                   ;; declared, as any escaping closure which /isn't/
 236                   ;; DYNAMIC-EXTENT but calls one of these functions
 237                   ;; will also close over the required variables, thus
 238                   ;; forcing the allocation of value cells.  Since the
 239                   ;; XEP is stored in the ENTRY-FUN slot, we can pick
 240                   ;; off the non-XEP case here.
 241                   (not entry-fun)
 242                   (leaf-dynamic-extent entry-fun))
 243         (let ((closure (physenv-closure (lambda-physenv fun))))
 244           (dolist (var closure)
 245             (when (and (lambda-var-p var)
 246                        (lambda-var-indirect var))
 247               (setf (lambda-var-explicit-value-cell var) t))))))))
 248 \f
 249 ;;;; non-local exit
 250
 251 (defvar *functional-escape-info*)
 252
 253 (defun functional-may-escape-p (functional)
 254   (let ((table *functional-escape-info*))
 255     (unless table
 256       ;; Many components never need the table since they have no escapes -- so
 257       ;; we allocate it lazily.
 258       (setf table (make-hash-table)
 259             *functional-escape-info* table))
 260     (multiple-value-bind (bool ok) (gethash functional table)
 261       (if ok
 262           bool
 263           (let ((entry (functional-entry-fun functional)))
 264             ;; First stick a NIL in there: break cycles.
 265             (setf (gethash functional table) nil)
 266             ;; Then compute the real value.
 267             (setf (gethash functional table)
 268                   (or
 269                    ;; If the functional has a XEP, it's kind is :EXTERNAL --
 270                    ;; which means it may escape. ...but if it
 271                    ;; HAS-EXTERNAL-REFERENCES-P, then that XEP is actually a
 272                    ;; TL-XEP, which means it's a toplevel function -- which in
 273                    ;; turn means our search has bottomed out without an escape
 274                    ;; path. AVER just to make sure, though.
 275                    (and (eq :external (functional-kind functional))
 276                         (if (functional-has-external-references-p functional)
 277                             (aver (eq 'tl-xep (car (functional-debug-name functional))))
 278                             t))
 279                    ;; If it has an entry point that may escape, that just as bad.
 280                    (and entry (functional-may-escape-p entry))
 281                    ;; If it has references to it in functions that may escape, that's bad
 282                    ;; too.
 283                    (dolist (ref (functional-refs functional) nil)
 284                      (let* ((lvar (ref-lvar ref))
 285                             (dest (when lvar (lvar-dest lvar))))
 286                        (when (functional-may-escape-p (node-home-lambda dest))
 287                          (return t)))))))))))
 288
 289 (defun exit-should-check-tag-p (exit)
 290   (declare (type exit exit))
 291   (let ((exit-lambda (lexenv-lambda (node-lexenv exit))))
 292     (unless (or
 293              ;; Unsafe but fast...
 294              (policy exit (zerop check-tag-existence))
 295              ;; Dynamic extent is a promise things won't escape --
 296              ;; and an explicit request to avoid heap consing.
 297              (member (lambda-extent exit-lambda) '(:always-dynamic :maybe-dynamic))
 298              ;; If the exit lambda cannot escape, then we should be safe.
 299              ;; ...since the escape analysis is kinda new, and not particularly
 300              ;; exhaustively tested, let alone proven, disable it for SAFETY 3.
 301              (and (policy exit (< safety 3))
 302                   (not (functional-may-escape-p exit-lambda))))
 303       (when (policy exit (> speed safety))
 304         (let ((*compiler-error-context* (exit-entry exit)))
 305           (compiler-notify "~@<Allocating a value-cell at runtime for ~
 306                             checking possibly out of extent exit via ~S. Use ~
 307                             GO/RETURN-FROM with SAFETY 0, or declare the exit ~
 308                             function DYNAMIC-EXTENT to avoid.~:@>"
 309                            (node-source-form exit))))
 310       t)))
 311
 312 ;;; Insert the entry stub before the original exit target, and add a
 313 ;;; new entry to the PHYSENV-NLX-INFO. The %NLX-ENTRY call in the
 314 ;;; stub is passed the NLX-INFO as an argument so that the back end
 315 ;;; knows what entry is being done.
 316 ;;;
 317 ;;; The link from the EXIT block to the entry stub is changed to be a
 318 ;;; link from the component head. Similarly, the EXIT block is linked
 319 ;;; to the component tail. This leaves the entry stub reachable, but
 320 ;;; makes the flow graph less confusing to flow analysis.
 321 ;;;
 322 ;;; If a CATCH or an UNWIND-protect, then we set the LEXENV for the
 323 ;;; last node in the cleanup code to be the enclosing environment, to
 324 ;;; represent the fact that the binding was undone as a side effect of
 325 ;;; the exit. This will cause a lexical exit to be broken up if we are
 326 ;;; actually exiting the scope (i.e. a BLOCK), and will also do any
 327 ;;; other cleanups that may have to be done on the way.
 328 (defun insert-nlx-entry-stub (exit env)
 329   (declare (type physenv env) (type exit exit))
 330   (let* ((exit-block (node-block exit))
 331          (next-block (first (block-succ exit-block)))
 332          (entry (exit-entry exit))
 333          (cleanup (entry-cleanup entry))
 334          (info (make-nlx-info cleanup exit))
 335          (new-block (insert-cleanup-code exit-block next-block
 336                                          entry
 337                                          `(%nlx-entry ',info)
 338                                          cleanup))
 339          (component (block-component new-block)))
 340     (unlink-blocks exit-block new-block)
 341     (link-blocks exit-block (component-tail component))
 342     (link-blocks (component-head component) new-block)
 343
 344     (setf (exit-nlx-info exit) info)
 345     (setf (nlx-info-target info) new-block)
 346     (setf (nlx-info-safe-p info) (exit-should-check-tag-p exit))
 347     (push info (physenv-nlx-info env))
 348     (push info (cleanup-info cleanup))
 349     (when (member (cleanup-kind cleanup) '(:catch :unwind-protect))
 350       (setf (node-lexenv (block-last new-block))
 351             (node-lexenv entry))))
 352
 353   (values))
 354
 355 ;;; Do stuff necessary to represent a non-local exit from the node
 356 ;;; EXIT into ENV. This is called for each non-local exit node, of
 357 ;;; which there may be several per exit continuation. This is what we
 358 ;;; do:
 359 ;;; -- If there isn't any NLX-INFO entry in the environment, make
 360 ;;;    an entry stub, otherwise just move the exit block link to
 361 ;;;    the component tail.
 362 ;;; -- Close over the NLX-INFO in the exit environment.
 363 ;;; -- If the exit is from an :ESCAPE function, then substitute a
 364 ;;;    constant reference to NLX-INFO structure for the escape
 365 ;;;    function reference. This will cause the escape function to
 366 ;;;    be deleted (although not removed from the DFO.)  The escape
 367 ;;;    function is no longer needed, and we don't want to emit code
 368 ;;;    for it.
 369 ;;; -- Change the %NLX-ENTRY call to use the NLX lvar so that 1) there
 370 ;;;    will be a use to represent the NLX use; 2) make life easier for
 371 ;;;    the stack analysis.
 372 (defun note-non-local-exit (env exit)
 373   (declare (type physenv env) (type exit exit))
 374   (let ((lvar (node-lvar exit))
 375         (exit-fun (node-home-lambda exit))
 376         (info (find-nlx-info exit)))
 377     (cond (info
 378            (let ((block (node-block exit)))
 379              (aver (= (length (block-succ block)) 1))
 380              (unlink-blocks block (first (block-succ block)))
 381              (link-blocks block (component-tail (block-component block)))
 382              (setf (exit-nlx-info exit) info)
 383              (unless (nlx-info-safe-p info)
 384                (setf (nlx-info-safe-p info)
 385                      (exit-should-check-tag-p exit)))))
 386           (t
 387            (insert-nlx-entry-stub exit env)
 388            (setq info (exit-nlx-info exit))
 389            (aver info)))
 390     (close-over info (node-physenv exit) env)
 391     (when (eq (functional-kind exit-fun) :escape)
 392       (mapc (lambda (x)
 393               (setf (node-derived-type x) *wild-type*))
 394             (leaf-refs exit-fun))
 395       (substitute-leaf (find-constant info) exit-fun))
 396     (when lvar
 397       (let ((node (block-last (nlx-info-target info))))
 398         (unless (node-lvar node)
 399           (aver (eq lvar (node-lvar exit)))
 400           (setf (node-derived-type node) (lvar-derived-type lvar))
 401           (add-lvar-use node lvar)))))
 402   (values))
 403
 404 ;;; Iterate over the EXITs in COMPONENT, calling NOTE-NON-LOCAL-EXIT
 405 ;;; when we find a block that ends in a non-local EXIT node. We also
 406 ;;; ensure that all EXIT nodes are either non-local or degenerate by
 407 ;;; calling IR1-OPTIMIZE-EXIT on local exits. This makes life simpler
 408 ;;; for later phases.
 409 (defun find-non-local-exits (component)
 410   (declare (type component component))
 411   (let ((*functional-escape-info* nil))
 412     (dolist (lambda (component-lambdas component))
 413       (dolist (entry (lambda-entries lambda))
 414         (dolist (exit (entry-exits entry))
 415           (let ((target-physenv (node-physenv entry)))
 416             (if (eq (node-physenv exit) target-physenv)
 417                 (maybe-delete-exit exit)
 418                 (note-non-local-exit target-physenv exit)))))))
 419   (values))
 420 \f
 421 ;;;; final decision on stack allocation of dynamic-extent structures
 422 (defun recheck-dynamic-extent-lvars (component)
 423   (declare (type component component))
 424   (dolist (lambda (component-lambdas component))
 425     (loop for entry in (lambda-entries lambda)
 426           for cleanup = (entry-cleanup entry)
 427           do (when (eq (cleanup-kind cleanup) :dynamic-extent)
 428                (collect ((real-dx-lvars))
 429                  (loop for what in (cleanup-info cleanup)
 430                        do (etypecase what
 431                             (cons
 432                              (let ((dx (car what))
 433                                    (lvar (cdr what)))
 434                                (cond ((lvar-good-for-dx-p lvar dx component)
 435                                       ;; Since the above check does deep
 436                                       ;; checks. we need to deal with the deep
 437                                       ;; results in here as well.
 438                                       (dolist (cell (handle-nested-dynamic-extent-lvars
 439                                                      dx lvar component))
 440                                         (let ((real (principal-lvar (cdr cell))))
 441                                           (setf (lvar-dynamic-extent real) cleanup)
 442                                           (real-dx-lvars real))))
 443                                      (t
 444                                       (note-no-stack-allocation lvar)
 445                                       (setf (lvar-dynamic-extent lvar) nil)))))
 446                             (node       ; DX closure
 447                              (let* ((call what)
 448                                     (arg (first (basic-combination-args call)))
 449                                     (funs (lvar-value arg))
 450                                     (dx nil))
 451                                (dolist (fun funs)
 452                                  (binding* ((() (leaf-dynamic-extent fun)
 453                                              :exit-if-null)
 454                                             (xep (functional-entry-fun fun)
 455                                                  :exit-if-null)
 456                                             (closure (physenv-closure
 457                                                       (get-lambda-physenv xep))))
 458                                    (cond (closure
 459                                           (setq dx t))
 460                                          (t
 461                                           (setf (leaf-extent fun) nil)))))
 462                                (when dx
 463                                  (setf (lvar-dynamic-extent arg) cleanup)
 464                                  (real-dx-lvars arg))))))
 465                  (let ((real-dx-lvars (delete-duplicates (real-dx-lvars))))
 466                    (setf (cleanup-info cleanup) real-dx-lvars)
 467                    (setf (component-dx-lvars component)
 468                          (append real-dx-lvars (component-dx-lvars component))))))))
 469   (values))
 470 \f
 471 ;;;; cleanup emission
 472
 473 ;;; Zoom up the cleanup nesting until we hit CLEANUP1, accumulating
 474 ;;; cleanup code as we go. When we are done, convert the cleanup code
 475 ;;; in an implicit MV-PROG1. We have to force local call analysis of
 476 ;;; new references to UNWIND-PROTECT cleanup functions. If we don't
 477 ;;; actually have to do anything, then we don't insert any cleanup
 478 ;;; code. (FIXME: There's some confusion here, left over from CMU CL
 479 ;;; comments. CLEANUP1 isn't mentioned in the code of this function.
 480 ;;; It is in code elsewhere, but if the comments for this function
 481 ;;; mention it they should explain the relationship to the other code.)
 482 ;;;
 483 ;;; If we do insert cleanup code, we check that BLOCK1 doesn't end in
 484 ;;; a "tail" local call.
 485 ;;;
 486 ;;; We don't need to adjust the ending cleanup of the cleanup block,
 487 ;;; since the cleanup blocks are inserted at the start of the DFO, and
 488 ;;; are thus never scanned.
 489 (defun emit-cleanups (block1 block2)
 490   (declare (type cblock block1 block2))
 491   (collect ((code)
 492             (reanalyze-funs))
 493     (let ((cleanup2 (block-start-cleanup block2)))
 494       (do ((cleanup (block-end-cleanup block1)
 495                     (node-enclosing-cleanup (cleanup-mess-up cleanup))))
 496           ((eq cleanup cleanup2))
 497         (let* ((node (cleanup-mess-up cleanup))
 498                (args (when (basic-combination-p node)
 499                        (basic-combination-args node))))
 500           (ecase (cleanup-kind cleanup)
 501             (:special-bind
 502              (code `(%special-unbind ',(lvar-value (first args)))))
 503             (:catch
 504              (code `(%catch-breakup)))
 505             (:unwind-protect
 506              (code `(%unwind-protect-breakup))
 507              (let ((fun (ref-leaf (lvar-uses (second args)))))
 508                (reanalyze-funs fun)
 509                (code `(%funcall ,fun))))
 510             ((:block :tagbody)
 511              (dolist (nlx (cleanup-info cleanup))
 512                (code `(%lexical-exit-breakup ',nlx))))
 513             (:dynamic-extent
 514              (when (not (null (cleanup-info cleanup)))
 515                (code `(%cleanup-point)))))))
 516
 517       (when (code)
 518         (aver (not (node-tail-p (block-last block1))))
 519         (insert-cleanup-code block1 block2
 520                              (block-last block1)
 521                              `(progn ,@(code)))
 522         (dolist (fun (reanalyze-funs))
 523           (locall-analyze-fun-1 fun)))))
 524
 525   (values))
 526
 527 ;;; Loop over the blocks in COMPONENT, calling EMIT-CLEANUPS when we
 528 ;;; see a successor in the same environment with a different cleanup.
 529 ;;; We ignore the cleanup transition if it is to a cleanup enclosed by
 530 ;;; the current cleanup, since in that case we are just messing up the
 531 ;;; environment, hence this is not the place to clean it.
 532 (defun find-cleanup-points (component)
 533   (declare (type component component))
 534   (do-blocks (block1 component)
 535     (let ((env1 (block-physenv block1))
 536           (cleanup1 (block-end-cleanup block1)))
 537       (dolist (block2 (block-succ block1))
 538         (when (block-start block2)
 539           (let ((env2 (block-physenv block2))
 540                 (cleanup2 (block-start-cleanup block2)))
 541             (unless (or (not (eq env2 env1))
 542                         (eq cleanup1 cleanup2)
 543                         (and cleanup2
 544                              (eq (node-enclosing-cleanup
 545                                   (cleanup-mess-up cleanup2))
 546                                  cleanup1)))
 547               (emit-cleanups block1 block2)))))))
 548   (values))
 549
 550 ;;; Mark optimizable tail-recursive uses of function result
 551 ;;; continuations with the corresponding TAIL-SET.
 552 (defun tail-annotate (component)
 553   (declare (type component component))
 554   (dolist (fun (component-lambdas component))
 555     (let ((ret (lambda-return fun)))
 556       (when ret
 557         (let ((result (return-result ret)))
 558           (do-uses (use result)
 559             (when (and (basic-combination-p use)
 560                        (immediately-used-p result use)
 561                        (or (eq (basic-combination-kind use) :local)
 562                            ;; Nodes whose type is NIL (i.e. don't return) such
 563                            ;; as calls to ERROR are never annotated as TAIL-P,
 564                            ;; in order to preserve debugging information, so that
 565                            ;;
 566                            ;; We spread this net wide enough to catch
 567                            ;; untrusted NIL return types as well, so that
 568                            ;; frames calling functions such as FOO-ERROR are
 569                            ;; kept in backtraces:
 570                            ;;
 571                            ;;  (defun foo-error (x) (error "oops: ~S" x))
 572                            ;;
 573                            (not (or (eq *empty-type* (node-derived-type use))
 574                                     (eq *empty-type* (combination-defined-type use))))))
 575               (setf (node-tail-p use) t)))))))
 576   (values))