src/compiler/ppc/static-fn.lisp

   1 ;;;; VOPs and macro magic for calling static functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13
  14 (define-vop (static-fun-template)
  15   (:save-p t)
  16   (:policy :safe)
  17   (:variant-vars symbol)
  18   (:vop-var vop)
  19   (:temporary (:scs (non-descriptor-reg)) temp)
  20   (:temporary (:scs (descriptor-reg)) move-temp)
  21   (:temporary (:sc descriptor-reg :offset lra-offset) lra)
  22   (:temporary (:sc interior-reg :offset lip-offset) entry-point)
  23   (:temporary (:sc any-reg :offset nargs-offset) nargs)
  24   (:temporary (:sc any-reg :offset ocfp-offset) old-fp)
  25   (:temporary (:sc control-stack :offset nfp-save-offset) nfp-save))
  26
  27
  28 (eval-when (:compile-toplevel :load-toplevel :execute)
  29
  30
  31 (defun static-fun-template-name (num-args num-results)
  32   (intern (format nil "~:@(~R-arg-~R-result-static-fun~)"
  33                   num-args num-results)))
  34
  35
  36 (defun moves (dst src)
  37   (collect ((moves))
  38     (do ((dst dst (cdr dst))
  39          (src src (cdr src)))
  40         ((or (null dst) (null src)))
  41       (moves `(move ,(car dst) ,(car src))))
  42     (moves)))
  43
  44 (defun static-fun-template-vop (num-args num-results)
  45   (assert (and (<= num-args register-arg-count)
  46                (<= num-results register-arg-count))
  47           (num-args num-results)
  48           "Either too many args (~W) or too many results (~W).  Max = ~W"
  49           num-args num-results register-arg-count)
  50   (let ((num-temps (max num-args num-results)))
  51     (collect ((temp-names) (temps) (arg-names) (args) (result-names) (results))
  52       (dotimes (i num-results)
  53         (let ((result-name (intern (format nil "RESULT-~D" i))))
  54           (result-names result-name)
  55           (results `(,result-name :scs (any-reg descriptor-reg)))))
  56       (dotimes (i num-temps)
  57         (let ((temp-name (intern (format nil "TEMP-~D" i))))
  58           (temp-names temp-name)
  59           (temps `(:temporary (:sc descriptor-reg
  60                                :offset ,(nth i *register-arg-offsets*)
  61                                ,@(when (< i num-args)
  62                                    `(:from (:argument ,i)))
  63                                ,@(when (< i num-results)
  64                                    `(:to (:result ,i)
  65                                      :target ,(nth i (result-names)))))
  66                               ,temp-name))))
  67       (dotimes (i num-args)
  68         (let ((arg-name (intern (format nil "ARG-~D" i))))
  69           (arg-names arg-name)
  70           (args `(,arg-name
  71                   :scs (any-reg descriptor-reg)
  72                   :target ,(nth i (temp-names))))))
  73       `(define-vop (,(static-fun-template-name num-args num-results)
  74                     static-fun-template)
  75          (:args ,@(args))
  76          ,@(temps)
  77          (:results ,@(results))
  78          (:generator ,(+ 50 num-args num-results)
  79            (let ((lra-label (gen-label))
  80                  (cur-nfp (current-nfp-tn vop)))
  81              ,@(moves (temp-names) (arg-names))
  82              (inst lwz entry-point null-tn (static-fun-offset symbol))
  83              (inst lr nargs (fixnumize ,num-args))
  84              (when cur-nfp
  85                (store-stack-tn nfp-save cur-nfp))
  86              (inst mr old-fp cfp-tn)
  87              (inst mr cfp-tn csp-tn)
  88              (inst compute-lra-from-code lra code-tn lra-label temp)
  89              (note-this-location vop :call-site)
  90              ;(inst mr code-tn func)
  91              (inst mtctr entry-point)
  92              (inst bctr)
  93              (emit-return-pc lra-label)
  94              ,(collect ((bindings) (links))
  95                 (do ((temp (temp-names) (cdr temp))
  96                      (name 'values (gensym))
  97                      (prev nil name)
  98                      (i 0 (1+ i)))
  99                     ((= i num-results))
 100                   (bindings `(,name
 101                               (make-tn-ref ,(car temp) nil)))
 102                   (when prev
 103                     (links `(setf (tn-ref-across ,prev) ,name))))
 104                 `(let ,(bindings)
 105                    ,@(links)
 106                    (default-unknown-values vop
 107                        ,(if (zerop num-results) nil 'values)
 108                        ,num-results move-temp temp lra-label)))
 109              (when cur-nfp
 110                (load-stack-tn cur-nfp nfp-save))
 111              ,@(moves (result-names) (temp-names))))))))
 112
 113
 114 ) ; EVAL-WHEN
 115
 116 (macrolet ((frob (num-args num-res)
 117              (static-fun-template-vop (eval num-args) (eval num-res))))
 118   (frob 0 1)
 119   (frob 1 1)
 120   (frob 2 1)
 121   (frob 3 1)
 122   (frob 4 1)
 123   #|(frob 5 1)|#)
 124
 125 (defmacro define-static-fun (name args &key (results '(x)) translate
 126                                        policy cost arg-types result-types)
 127   `(define-vop (,name
 128                 ,(static-fun-template-name (length args)
 129                                                 (length results)))
 130      (:variant ',name)
 131      (:note ,(format nil "static-fun ~@(~S~)" name))
 132      ,@(when translate
 133          `((:translate ,translate)))
 134      ,@(when policy
 135          `((:policy ,policy)))
 136      ,@(when cost
 137          `((:generator-cost ,cost)))
 138      ,@(when arg-types
 139          `((:arg-types ,@arg-types)))
 140      ,@(when result-types
 141          `((:result-types ,@result-types)))))