src/compiler/proclaim.lisp

   1 ;;;; This file contains load-time support for declaration processing.
   2 ;;;; In CMU CL it was split off from the compiler so that the compiler
   3 ;;;; doesn't have to be in the cold load, but in SBCL the compiler is
   4 ;;;; in the cold load again, so this might not be valuable.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!C")
  16
  17 ;;; A list of UNDEFINED-WARNING structures representing references to unknown
  18 ;;; stuff which came up in a compilation unit.
  19 (defvar *undefined-warnings*)
  20 (declaim (list *undefined-warnings*))
  21
  22 ;;; Look up some symbols in *FREE-VARS*, returning the var
  23 ;;; structures for any which exist. If any of the names aren't
  24 ;;; symbols, we complain.
  25 (declaim (ftype (function (list) list) get-old-vars))
  26 (defun get-old-vars (names)
  27   (collect ((vars))
  28     (dolist (name names (vars))
  29       (unless (symbolp name)
  30         (compiler-error "The name ~S is not a symbol." name))
  31       (let ((old (gethash name *free-vars*)))
  32         (when old (vars old))))))
  33
  34 ;;; Return a new POLICY containing the policy information represented
  35 ;;; by the optimize declaration SPEC. Any parameters not specified are
  36 ;;; defaulted from the POLICY argument.
  37 (declaim (ftype (function (list policy) policy) process-optimize-decl))
  38 (defun process-optimize-decl (spec policy)
  39   (let ((result nil))
  40     ;; Add new entries from SPEC.
  41     (dolist (q-and-v-or-just-q (cdr spec))
  42       (multiple-value-bind (quality raw-value)
  43           (if (atom q-and-v-or-just-q)
  44               (values q-and-v-or-just-q 3)
  45               (destructuring-bind (quality raw-value) q-and-v-or-just-q
  46                 (values quality raw-value)))
  47         (cond ((not (policy-quality-name-p quality))
  48                (compiler-warn "ignoring unknown optimization quality ~
  49                                ~S in ~S"
  50                                quality spec))
  51               ((not (typep raw-value 'policy-quality))
  52                (compiler-warn "ignoring bad optimization value ~S in ~S"
  53                               raw-value spec))
  54               (t
  55                ;; we can't do this yet, because CLOS macros expand
  56                ;; into code containing INHIBIT-WARNINGS.
  57                #+nil
  58                (when (eql quality 'sb!ext:inhibit-warnings)
  59                  (compiler-style-warn "~S is deprecated: use ~S instead"
  60                                       quality 'sb!ext:muffle-conditions))
  61                (push (cons quality raw-value)
  62                      result)))))
  63     ;; Add any nonredundant entries from old POLICY.
  64     (dolist (old-entry policy)
  65       (unless (assq (car old-entry) result)
  66         (push old-entry result)))
  67     ;; Voila.
  68     result))
  69
  70 (declaim (ftype (function (list list) list)
  71                 process-handle-conditions-decl))
  72 (defun process-handle-conditions-decl (spec list)
  73   (let ((new (copy-alist list)))
  74     (dolist (clause (cdr spec))
  75       (destructuring-bind (typespec restart-name) clause
  76         (let ((ospec (rassoc restart-name new :test #'eq)))
  77           (if ospec
  78               (setf (car ospec)
  79                     (type-specifier
  80                      (type-union (specifier-type (car ospec))
  81                                  (specifier-type typespec))))
  82               (push (cons (type-specifier (specifier-type typespec))
  83                           restart-name)
  84                     new)))))
  85     new))
  86 (declaim (ftype (function (list list) list)
  87                 process-muffle-conditions-decl))
  88 (defun process-muffle-conditions-decl (spec list)
  89   (process-handle-conditions-decl
  90    (cons 'handle-conditions
  91          (mapcar (lambda (x) (list x 'muffle-warning)) (cdr spec)))
  92    list))
  93
  94 (declaim (ftype (function (list list) list)
  95                 process-unhandle-conditions-decl))
  96 (defun process-unhandle-conditions-decl (spec list)
  97   (let ((new (copy-alist list)))
  98     (dolist (clause (cdr spec))
  99       (destructuring-bind (typespec restart-name) clause
 100         (let ((ospec (rassoc restart-name new :test #'eq)))
 101           (if ospec
 102               (let ((type-specifier
 103                      (type-specifier
 104                       (type-intersection
 105                        (specifier-type (car ospec))
 106                        (specifier-type `(not ,typespec))))))
 107                 (if type-specifier
 108                     (setf (car ospec) type-specifier)
 109                     (setq new
 110                           (delete restart-name new :test #'eq :key #'cdr))))
 111               ;; do nothing?
 112               nil))))
 113     new))
 114 (declaim (ftype (function (list list) list)
 115                 process-unmuffle-conditions-decl))
 116 (defun process-unmuffle-conditions-decl (spec list)
 117   (process-unhandle-conditions-decl
 118    (cons 'unhandle-conditions
 119          (mapcar (lambda (x) (list x 'muffle-warning)) (cdr spec)))
 120    list))
 121
 122 (declaim (ftype (function (list list) list)
 123                 process-package-lock-decl))
 124 (defun process-package-lock-decl (spec old)
 125   (let ((decl (car spec))
 126         (list (cdr spec)))
 127     (ecase decl
 128       (disable-package-locks
 129        (union old list :test #'equal))
 130       (enable-package-locks
 131        (set-difference old list :test #'equal)))))
 132
 133 ;;; ANSI defines the declaration (FOO X Y) to be equivalent to
 134 ;;; (TYPE FOO X Y) when FOO is a type specifier. This function
 135 ;;; implements that by converting (FOO X Y) to (TYPE FOO X Y).
 136 (defun canonized-decl-spec (decl-spec)
 137   (let ((id (first decl-spec)))
 138     (let ((id-is-type (if (symbolp id)
 139                           (info :type :kind id)
 140                           ;; A cons might not be a valid type specifier,
 141                           ;; but it can't be a declaration either.
 142                           (or (consp id)
 143                               (typep id 'class))))
 144           (id-is-declared-decl (info :declaration :recognized id)))
 145       ;; FIXME: Checking ID-IS-DECLARED is probably useless these days,
 146       ;; since we refuse to use the same symbol as both a type name and
 147       ;; recognized declaration name.
 148       (cond ((and id-is-type id-is-declared-decl)
 149              (compiler-error
 150               "ambiguous declaration ~S:~%  ~
 151               ~S was declared as a DECLARATION, but is also a type name."
 152               decl-spec id))
 153             (id-is-type
 154              (cons 'type decl-spec))
 155             (t
 156              decl-spec)))))
 157
 158 (defvar *queued-proclaims*) ; initialized in !COLD-INIT-FORMS
 159
 160 (!begin-collecting-cold-init-forms)
 161 (!cold-init-forms (setf *queued-proclaims* nil))
 162 (!defun-from-collected-cold-init-forms !early-proclaim-cold-init)
 163
 164 (defun sb!xc:proclaim (raw-form)
 165   #+sb-xc (/show0 "entering PROCLAIM, RAW-FORM=..")
 166   #+sb-xc (/hexstr raw-form)
 167   (let* ((form (canonized-decl-spec raw-form))
 168          (kind (first form))
 169          (args (rest form)))
 170     (case kind
 171       (special
 172        (dolist (name args)
 173          (unless (symbolp name)
 174            (error "can't declare a non-symbol as SPECIAL: ~S" name))
 175          (with-single-package-locked-error
 176              (:symbol name "globally declaring ~A special")
 177            (about-to-modify-symbol-value name "proclaim ~S as SPECIAL")
 178            (setf (info :variable :kind name) :special))))
 179       (type
 180        (if *type-system-initialized*
 181            (let ((type (specifier-type (first args))))
 182              (dolist (name (rest args))
 183                (unless (symbolp name)
 184                  (error "can't declare TYPE of a non-symbol: ~S" name))
 185                (with-single-package-locked-error
 186                    (:symbol name "globally declaring the type of ~A"))
 187                (when (eq (info :variable :where-from name) :declared)
 188                  (let ((old-type (info :variable :type name)))
 189                    (when (type/= type old-type)
 190                      (style-warn "The new TYPE proclamation~%  ~S~@
 191                                   for ~S does not match the old TYPE~@
 192                                   proclamation ~S"
 193                                  type name old-type))))
 194                (setf (info :variable :type name) type)
 195                (setf (info :variable :where-from name) :declared)))
 196            (push raw-form *queued-proclaims*)))
 197       (ftype
 198        (if *type-system-initialized*
 199            (let ((ctype (specifier-type (first args))))
 200              (unless (csubtypep ctype (specifier-type 'function))
 201                (error "not a function type: ~S" (first args)))
 202              (dolist (name (rest args))
 203                (with-single-package-locked-error
 204                    (:symbol name "globally declaring the ftype of ~A"))
 205                (when (eq (info :function :where-from name) :declared)
 206                  (let ((old-type (info :function :type name)))
 207                    (when (type/= ctype old-type)
 208                      (style-warn
 209                       "new FTYPE proclamation~@
 210                        ~S~@
 211                        for ~S does not match old FTYPE proclamation~@
 212                        ~S"
 213                       ctype name old-type))))
 214
 215                ;; Now references to this function shouldn't be warned
 216                ;; about as undefined, since even if we haven't seen a
 217                ;; definition yet, we know one is planned.
 218                ;;
 219                ;; Other consequences of we-know-you're-a-function-now
 220                ;; are appropriate too, e.g. any MACRO-FUNCTION goes away.
 221                (proclaim-as-fun-name name)
 222                (note-name-defined name :function)
 223
 224                ;; the actual type declaration
 225                (setf (info :function :type name) ctype
 226                      (info :function :where-from name) :declared)))
 227            (push raw-form *queued-proclaims*)))
 228       (freeze-type
 229        (dolist (type args)
 230          (let ((class (specifier-type type)))
 231            (when (typep class 'classoid)
 232              (setf (classoid-state class) :sealed)
 233              (let ((subclasses (classoid-subclasses class)))
 234                (when subclasses
 235                  (dohash ((subclass layout) subclasses :locked t)
 236                    (declare (ignore layout))
 237                    (setf (classoid-state subclass) :sealed))))))))
 238       (optimize
 239        (setq *policy* (process-optimize-decl form *policy*)))
 240       (muffle-conditions
 241        (setq *handled-conditions*
 242              (process-muffle-conditions-decl form *handled-conditions*)))
 243       (unmuffle-conditions
 244        (setq *handled-conditions*
 245              (process-unmuffle-conditions-decl form *handled-conditions*)))
 246       ((disable-package-locks enable-package-locks)
 247          (setq *disabled-package-locks*
 248                (process-package-lock-decl form *disabled-package-locks*)))
 249       ((inline notinline maybe-inline)
 250        (dolist (name args)
 251          (proclaim-as-fun-name name) ; since implicitly it is a function
 252          (setf (info :function :inlinep name)
 253                (ecase kind
 254                  (inline :inline)
 255                  (notinline :notinline)
 256                  (maybe-inline :maybe-inline)))))
 257       (declaration
 258        (dolist (decl args)
 259          (unless (symbolp decl)
 260            (error "In~%  ~S~%the declaration to be recognized is not a ~
 261                   symbol:~%  ~S"
 262                   form decl))
 263          (with-single-package-locked-error
 264              (:symbol decl "globally declaring ~A as a declaration proclamation"))
 265          (setf (info :declaration :recognized decl) t)))
 266       (t
 267        (unless (info :declaration :recognized kind)
 268          (compiler-warn "unrecognized declaration ~S" raw-form)))))
 269   #+sb-xc (/show0 "returning from PROCLAIM")
 270   (values))