src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places))
 137     (let ((found-vector-p nil))
 138       (flet ((process-vector (length)
 139                (unless found-vector-p
 140                  (setq found-vector-p t)
 141                  (bindings `(index 0 (1+ index)))
 142                  (declarations `(type index index)))
 143                (vector-lengths length)))
 144         (loop for seq of-type lvar in seqs
 145            for seq-name in seq-names
 146            for type = (lvar-type seq)
 147            do (cond ((csubtypep type (specifier-type 'list))
 148                      (with-unique-names (index)
 149                        (bindings `(,index ,seq-name (cdr ,index)))
 150                        (declarations `(type list ,index))
 151                        (places `(car ,index))
 152                        (tests `(endp ,index))))
 153                     ((csubtypep type (specifier-type 'vector))
 154                      (process-vector `(length ,seq-name))
 155                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 156                                 (aref ,seq-name index))))
 157                     (t
 158                      (give-up-ir1-transform
 159                       "can't determine sequence argument type"))))
 160         (when into
 161           (process-vector `(array-dimension ,into 0))))
 162       (when found-vector-p
 163         (bindings `(length (min ,@(vector-lengths))))
 164         (tests `(>= index length)))
 165       `(do (,@(bindings))
 166            ((or ,@(tests)) ,result)
 167          (declare ,@(declarations))
 168          (let ((funcall-result (funcall fun ,@(places))))
 169            (declare (ignorable funcall-result))
 170            ,body)))))
 171
 172 ;;; Try to compile %MAP efficiently when we can determine sequence
 173 ;;; argument types at compile time.
 174 ;;;
 175 ;;; Note: This transform was written to allow open coding of
 176 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 177 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 178 ;;; necessarily as efficient as possible. In particular, it will be
 179 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 180 ;;; numeric element types. It should be straightforward to make it
 181 ;;; handle that case more efficiently, but it's left as an exercise to
 182 ;;; the reader, because the code is complicated enough already and I
 183 ;;; don't happen to need that functionality right now. -- WHN 20000410
 184 (deftransform %map ((result-type fun seq &rest seqs) * *
 185                     :policy (>= speed space))
 186   "open code"
 187   (unless (constant-lvar-p result-type)
 188     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 189   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 190            (fn-1subtypep (fn x y)
 191              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 192                (if valid-p
 193                    subtype-p
 194                    (give-up-ir1-transform
 195                     "can't analyze sequence type relationship"))))
 196            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 197     (let* ((result-type-value (lvar-value result-type))
 198            (result-supertype (cond ((null result-type-value) 'null)
 199                                    ((1subtypep result-type-value 'vector)
 200                                     'vector)
 201                                    ((1subtypep result-type-value 'list)
 202                                     'list)
 203                                    (t
 204                                     (give-up-ir1-transform
 205                                      "result type unsuitable")))))
 206       (cond ((and result-type-value (null seqs))
 207              ;; The consing arity-1 cases can be implemented
 208              ;; reasonably efficiently as function calls, and the cost
 209              ;; of consing should be significantly larger than
 210              ;; function call overhead, so we always compile these
 211              ;; cases as full calls regardless of speed-versus-space
 212              ;; optimization policy.
 213              (cond ((subtypep result-type-value 'list)
 214                     '(%map-to-list-arity-1 fun seq))
 215                    ( ;; (This one can be inefficient due to COERCE, but
 216                     ;; the current open-coded implementation has the
 217                     ;; same problem.)
 218                     (subtypep result-type-value 'vector)
 219                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 220                              ',result-type-value))
 221                    (t (bug "impossible (?) sequence type"))))
 222             (t
 223              (let* ((seqs (cons seq seqs))
 224                     (seq-args (make-gensym-list (length seqs))))
 225                (multiple-value-bind (push-dacc result)
 226                    (ecase result-supertype
 227                      (null (values nil nil))
 228                      (list (values `(push funcall-result acc)
 229                                    `(nreverse acc)))
 230                      (vector (values `(push funcall-result acc)
 231                                      `(coerce (nreverse acc)
 232                                               ',result-type-value))))
 233                  ;; (We use the same idiom, of returning a LAMBDA from
 234                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 235                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 236                  ;; reason: we need to get the runtime values of each
 237                  ;; of the &REST vars.)
 238                  `(lambda (result-type fun ,@seq-args)
 239                     (declare (ignore result-type))
 240                     (let ((fun (%coerce-callable-to-fun fun))
 241                           (acc nil))
 242                       (declare (type list acc))
 243                       (declare (ignorable acc))
 244                       ,(build-sequence-iterator
 245                         seqs seq-args
 246                         :result result
 247                         :body push-dacc))))))))))
 248
 249 ;;; MAP-INTO
 250 (deftransform map-into ((result fun &rest seqs)
 251                         (vector * &rest *)
 252                         *)
 253   "open code"
 254   (let ((seqs-names (mapcar (lambda (x)
 255                               (declare (ignore x))
 256                               (gensym))
 257                             seqs)))
 258     `(lambda (result fun ,@seqs-names)
 259        ,(build-sequence-iterator
 260          seqs seqs-names
 261          :result '(when (array-has-fill-pointer-p result)
 262                    (setf (fill-pointer result) index))
 263          :into 'result
 264          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 265                  (setf (aref result index) funcall-result)))
 266        result)))
 267
 268 \f
 269 ;;; FIXME: once the confusion over doing transforms with known-complex
 270 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 271 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 272 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 273   '(aref s i))
 274
 275 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 276   '(nth i s))
 277
 278 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 279   '(%aset s i v))
 280
 281 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 282   '(setf (car (nthcdr i s)) v))
 283
 284 (deftransform %check-vector-sequence-bounds ((vector start end)
 285                                              (vector * *) *
 286                                              :node node)
 287   (if (policy node (= 0 insert-array-bounds-checks))
 288       '(or end (length vector))
 289       '(let ((length (length vector)))
 290          (if (<= 0 start (or end length) length)
 291              (or end length)
 292              (sequence-bounding-indices-bad-error vector start end)))))
 293
 294 (defun specialized-list-seek-function-name (function-name key-functions variant)
 295   (or (find-symbol (with-output-to-string (s)
 296                      ;; Write "%NAME-FUN1-FUN2-FUN3", etc. Not only is
 297                      ;; this ever so slightly faster then FORMAT, this
 298                      ;; way we are also proof against *PRINT-CASE*
 299                      ;; frobbing and such.
 300                      (write-char #\% s)
 301                      (write-string (symbol-name function-name) s)
 302                      (dolist (f key-functions)
 303                        (write-char #\- s)
 304                        (write-string (symbol-name f) s))
 305                      (when variant
 306                        (write-char #\- s)
 307                        (write-string (symbol-name variant) s)))
 308                    (load-time-value (find-package "SB!KERNEL")))
 309       (bug "Unknown list item seek transform: name=~S, key-functions=~S variant=~S"
 310            function-name key-functions variant)))
 311
 312 (defun transform-list-item-seek (name item list key test test-not node)
 313   ;; If TEST is EQL, drop it.
 314   (when (and test (lvar-for-named-function test 'eql))
 315     (setf test nil))
 316   ;; Ditto for KEY IDENTITY.
 317   (when (and key (lvar-for-named-function key 'identity))
 318     (setf key nil))
 319   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 320   ;; not there at all. If it might be NIL, make up a form to that
 321   ;; ensures it is a function.
 322   (multiple-value-bind (key key-form)
 323       (when key
 324         (let ((key-type (lvar-type key))
 325               (null-type (specifier-type 'null)))
 326           (cond ((csubtypep key-type null-type)
 327                  (values nil nil))
 328                 ((csubtypep null-type key-type)
 329                  (values key '(if key
 330                                (%coerce-callable-to-fun key)
 331                                #'identity)))
 332                 (t
 333                  (values key '(%coerce-callable-to-fun key))))))
 334     (let* ((c-test (cond ((and test (lvar-for-named-function test 'eq))
 335                           (setf test nil)
 336                           'eq)
 337                          ((and (not test) (not test-not))
 338                           (when (eq-comparable-type-p (lvar-type item))
 339                             'eq))))
 340            (funs (remove nil (list (and key 'key) (cond (test 'test)
 341                                                         (test-not 'test-not)))))
 342            (target-expr (if key '(%funcall key target) 'target))
 343            (test-expr (cond (test `(%funcall test item ,target-expr))
 344                             (test-not `(not (%funcall test-not item ,target-expr)))
 345                             (c-test `(,c-test item ,target-expr))
 346                             (t `(eql item ,target-expr)))))
 347       (labels ((open-code (tail)
 348                  (when tail
 349                    `(if (let ((this ',(car tail)))
 350                           ,(ecase name
 351                                   (assoc
 352                                    `(and this (let ((target (car this)))
 353                                                 ,test-expr)))
 354                                   (member
 355                                    `(let ((target this))
 356                                       ,test-expr))))
 357                         ',(ecase name
 358                                  (assoc (car tail))
 359                                  (member tail))
 360                         ,(open-code (cdr tail)))))
 361                (ensure-fun (fun)
 362                  (if (eq 'key fun)
 363                      key-form
 364                      `(%coerce-callable-to-fun ,fun))))
 365         (let* ((cp (constant-lvar-p list))
 366                (c-list (when cp (lvar-value list))))
 367           (cond ((and cp c-list (member name '(assoc member))
 368                       (policy node (>= speed space)))
 369                  `(let ,(mapcar (lambda (fun) `(,fun ,(ensure-fun fun))) funs)
 370                     ,(open-code c-list)))
 371                 ((and cp (not c-list))
 372                  ;; constant nil list -- nothing to find!
 373                  nil)
 374                 (t
 375                  ;; specialized out-of-line version
 376                  `(,(specialized-list-seek-function-name name funs c-test)
 377                     item list ,@(mapcar #'ensure-fun funs)))))))))
 378
 379 (deftransform member ((item list &key key test test-not) * * :node node)
 380   (transform-list-item-seek 'member item list key test test-not node))
 381
 382 (deftransform assoc ((item list &key key test test-not) * * :node node)
 383   (transform-list-item-seek 'assoc item list key test test-not node))
 384
 385 (deftransform adjoin ((item list &key key test test-not) * * :node node)
 386   (transform-list-item-seek 'adjoin item list key test test-not node))
 387
 388 (deftransform memq ((item list) (t (constant-arg list)))
 389   (labels ((rec (tail)
 390              (if tail
 391                  `(if (eq item ',(car tail))
 392                       ',tail
 393                       ,(rec (cdr tail)))
 394                  nil)))
 395     (rec (lvar-value list))))
 396
 397 ;;; A similar transform used to apply to MEMBER and ASSOC, but since
 398 ;;; TRANSFORM-LIST-ITEM-SEEK now takes care of them those transform
 399 ;;; would never fire, and (%MEMBER-TEST ITEM LIST #'EQ) should be
 400 ;;; almost as fast as MEMQ.
 401 (deftransform delete ((item list &key test) (t list &rest t) *)
 402   "convert to EQ test"
 403   ;; FIXME: The scope of this transformation could be
 404   ;; widened somewhat, letting it work whenever the test is
 405   ;; 'EQL and we know from the type of ITEM that it #'EQ
 406   ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 407   ;; and SYMBOL.)
 408   ;;   If TEST is EQ, apply transform, else
 409   ;;   if test is not EQL, then give up on transform, else
 410   ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 411   ;;   transform, else give up on transform.
 412   (cond (test
 413          (unless (lvar-fun-is test '(eq))
 414            (give-up-ir1-transform)))
 415         ((types-equal-or-intersect (lvar-type item)
 416                                    (specifier-type 'number))
 417          (give-up-ir1-transform "Item might be a number.")))
 418   `(delq item list))
 419
 420 (deftransform delete-if ((pred list) (t list))
 421   "open code"
 422   '(do ((x list (cdr x))
 423         (splice '()))
 424        ((endp x) list)
 425      (cond ((funcall pred (car x))
 426             (if (null splice)
 427                 (setq list (cdr x))
 428                 (rplacd splice (cdr x))))
 429            (t (setq splice x)))))
 430
 431 (deftransform fill ((seq item &key (start 0) (end nil))
 432                     (list t &key (:start t) (:end t)))
 433   '(list-fill* seq item start end))
 434
 435 (deftransform fill ((seq item &key (start 0) (end nil))
 436                     (vector t &key (:start t) (:end t))
 437                     *
 438                     :node node)
 439   (let ((type (lvar-type seq))
 440         (element-type (type-specifier (extract-upgraded-element-type seq))))
 441     (cond ((and (neq '* element-type) (policy node (> speed space)))
 442            (values
 443             `(with-array-data ((data seq)
 444                                (start start)
 445                                (end end)
 446                                :check-fill-pointer t)
 447                (declare (type (simple-array ,element-type 1) data))
 448                (declare (type index start end))
 449                ;; WITH-ARRAY-DATA did our range checks once and for all, so
 450                ;; it'd be wasteful to check again on every AREF...
 451                (declare (optimize (safety 0) (speed 3)))
 452                (do ((i start (1+ i)))
 453                    ((= i end) seq)
 454                  (declare (type index i))
 455                  (setf (aref data i) item)))
 456             ;; ... though we still need to check that the new element can fit
 457             ;; into the vector in safe code. -- CSR, 2002-07-05
 458             `((declare (type ,element-type item)))))
 459           ((csubtypep type (specifier-type 'string))
 460            '(string-fill* seq item start end))
 461           (t
 462            '(vector-fill* seq item start end)))))
 463
 464 (deftransform fill ((seq item &key (start 0) (end nil))
 465                     ((and sequence (not vector) (not list)) t &key (:start t) (:end t)))
 466   `(sb!sequence:fill seq item
 467                      :start start
 468                      :end (%check-generic-sequence-bounds seq start end)))
 469 \f
 470 ;;;; utilities
 471
 472 ;;; Return true if LVAR's only use is a non-NOTINLINE reference to a
 473 ;;; global function with one of the specified NAMES.
 474 (defun lvar-fun-is (lvar names)
 475   (declare (type lvar lvar) (list names))
 476   (let ((use (lvar-uses lvar)))
 477     (and (ref-p use)
 478          (let ((leaf (ref-leaf use)))
 479            (and (global-var-p leaf)
 480                 (eq (global-var-kind leaf) :global-function)
 481                 (not (null (member (leaf-source-name leaf) names
 482                                    :test #'equal))))))))
 483
 484 ;;; If LVAR is a constant lvar, the return the constant value. If it
 485 ;;; is null, then return default, otherwise quietly give up the IR1
 486 ;;; transform.
 487 ;;;
 488 ;;; ### Probably should take an ARG and flame using the NAME.
 489 (defun constant-value-or-lose (lvar &optional default)
 490   (declare (type (or lvar null) lvar))
 491   (cond ((not lvar) default)
 492         ((constant-lvar-p lvar)
 493          (lvar-value lvar))
 494         (t
 495          (give-up-ir1-transform))))
 496
 497
 498 ;;;; hairy sequence transforms
 499
 500 ;;; FIXME: no hairy sequence transforms in SBCL?
 501 ;;;
 502 ;;; There used to be a bunch of commented out code about here,
 503 ;;; containing the (apparent) beginning of hairy sequence transform
 504 ;;; infrastructure. People interested in implementing better sequence
 505 ;;; transforms might want to look at it for inspiration, even though
 506 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 507 ;;; was deleted in 1.0.7.23.
 508 \f
 509 ;;;; string operations
 510
 511 ;;; We transform the case-sensitive string predicates into a non-keyword
 512 ;;; version. This is an IR1 transform so that we don't have to worry about
 513 ;;; changing the order of evaluation.
 514 (macrolet ((def (fun pred*)
 515              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 516                                                          (start2 0) end2)
 517                                    * *)
 518                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 519   (def string< string<*)
 520   (def string> string>*)
 521   (def string<= string<=*)
 522   (def string>= string>=*)
 523   (def string= string=*)
 524   (def string/= string/=*))
 525
 526 ;;; Return a form that tests the free variables STRING1 and STRING2
 527 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 528 ;;; start and end are also gotten from the environment. Both strings
 529 ;;; must be SIMPLE-BASE-STRINGs.
 530 (macrolet ((def (name lessp equalp)
 531              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 532                                    (simple-base-string simple-base-string t t t t) *)
 533                 `(let* ((end1 (if (not end1) (length string1) end1))
 534                         (end2 (if (not end2) (length string2) end2))
 535                         (index (sb!impl::%sp-string-compare
 536                                 string1 start1 end1 string2 start2 end2)))
 537                   (if index
 538                       (cond ((= index end1)
 539                              ,(if ',lessp 'index nil))
 540                             ((= (+ index (- start2 start1)) end2)
 541                              ,(if ',lessp nil 'index))
 542                             ((,(if ',lessp 'char< 'char>)
 543                                (schar string1 index)
 544                                (schar string2
 545                                       (truly-the index
 546                                                  (+ index
 547                                                     (truly-the fixnum
 548                                                                (- start2
 549                                                                   start1))))))
 550                              index)
 551                             (t nil))
 552                       ,(if ',equalp 'end1 nil))))))
 553   (def string<* t nil)
 554   (def string<=* t t)
 555   (def string>* nil nil)
 556   (def string>=* nil t))
 557
 558 (macrolet ((def (name result-fun)
 559              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 560                                    (simple-base-string simple-base-string t t t t) *)
 561                 `(,',result-fun
 562                   (sb!impl::%sp-string-compare
 563                    string1 start1 (or end1 (length string1))
 564                    string2 start2 (or end2 (length string2)))))))
 565   (def string=* not)
 566   (def string/=* identity))
 567
 568 \f
 569 ;;;; transforms for sequence functions
 570
 571 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 572 ;;; to vectors based on simple arrays.
 573 (def!constant vector-data-bit-offset
 574   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 575
 576 (eval-when (:compile-toplevel)
 577 (defun valid-bit-bash-saetp-p (saetp)
 578   ;; BIT-BASHing isn't allowed on simple vectors that contain pointers
 579   (and (not (eq t (sb!vm:saetp-specifier saetp)))
 580        ;; Disallowing (VECTOR NIL) also means that we won't transform
 581        ;; sequence functions into bit-bashing code and we let the
 582        ;; generic sequence functions signal errors if necessary.
 583        (not (zerop (sb!vm:saetp-n-bits saetp)))
 584        ;; Due to limitations with the current BIT-BASHing code, we can't
 585        ;; BIT-BASH reliably on arrays whose element types are larger
 586        ;; than the word size.
 587        (<= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)))
 588 ) ; EVAL-WHEN
 589
 590 ;;; FIXME: In the copy loops below, we code the loops in a strange
 591 ;;; fashion:
 592 ;;;
 593 ;;; (do ((i (+ src-offset length) (1- i)))
 594 ;;;     ((<= i 0) ...)
 595 ;;;   (... (aref foo (1- i)) ...))
 596 ;;;
 597 ;;; rather than the more natural (and seemingly more efficient):
 598 ;;;
 599 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 600 ;;;     ((< i 0) ...)
 601 ;;;   (... (aref foo i) ...))
 602 ;;;
 603 ;;; (more efficient because we don't have to do the index adjusting on
 604 ;;; every iteration of the loop)
 605 ;;;
 606 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 607 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 608 ;;; when used as an array index, the backend thinks I is a
 609 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 610 ;;; these as distinct storage classes, it cannot coerce a move from a
 611 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 612 ;;; deficiency is that we have two extra moves and increased register
 613 ;;; pressure, which can lead to some spectacularly bad register
 614 ;;; allocation.  (sub-FIXME: the register allocation even with the
 615 ;;; strangely written loops is not always excellent, either...).  Doing
 616 ;;; it the first way, above, means that I is always thought of as a
 617 ;;; POSITIVE-FIXNUM and there are no issues.
 618 ;;;
 619 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 620 ;;; adjustments in the first version into the array addressing at no
 621 ;;; performance penalty!
 622
 623 ;;; This transform is critical to the performance of string streams.  If
 624 ;;; you tweak it, make sure that you compare the disassembly, if not the
 625 ;;; performance of, the functions implementing string streams
 626 ;;; (e.g. SB!IMPL::STRING-OUCH).
 627 (eval-when (:compile-toplevel :load-toplevel :execute)
 628   (defun make-replace-transform (saetp sequence-type1 sequence-type2)
 629     `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 630                             (,sequence-type1 ,sequence-type2 &rest t)
 631                             ,sequence-type1
 632                             :node node)
 633        ,(cond
 634          ((and saetp (valid-bit-bash-saetp-p saetp)) nil)
 635          ;; If the sequence types are different, SEQ1 and SEQ2 must
 636          ;; be distinct arrays, and we can open code the copy loop.
 637          ((not (eql sequence-type1 sequence-type2)) nil)
 638          ;; If we're not bit-bashing, only allow cases where we
 639          ;; can determine the order of copying up front.  (There
 640          ;; are actually more cases we can handle if we know the
 641          ;; amount that we're copying, but this handles the
 642          ;; common cases.)
 643          (t '(unless (= (constant-value-or-lose start1 0)
 644                       (constant-value-or-lose start2 0))
 645               (give-up-ir1-transform))))
 646        `(let* ((len1 (length seq1))
 647                (len2 (length seq2))
 648                (end1 (or end1 len1))
 649                (end2 (or end2 len2))
 650                (replace-len1 (- end1 start1))
 651                (replace-len2 (- end2 start2)))
 652           ,(unless (policy node (= safety 0))
 653              `(progn
 654                  (unless (<= 0 start1 end1 len1)
 655                    (sequence-bounding-indices-bad-error seq1 start1 end1))
 656                  (unless (<= 0 start2 end2 len2)
 657                    (sequence-bounding-indices-bad-error seq2 start2 end2))))
 658           ,',(cond
 659               ((and saetp (valid-bit-bash-saetp-p saetp))
 660                (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 661                       (bash-function (intern (format nil "UB~D-BASH-COPY"
 662                                                      n-element-bits)
 663                                              (find-package "SB!KERNEL"))))
 664                  `(funcall (function ,bash-function) seq2 start2
 665                            seq1 start1 (min replace-len1 replace-len2))))
 666               (t
 667                ;; We can expand the loop inline here because we
 668                ;; would have given up the transform (see above)
 669                ;; if we didn't have constant matching start
 670                ;; indices.
 671                '(do ((i start1 (1+ i))
 672                      (j start2 (1+ j))
 673                      (end (+ start1
 674                              (min replace-len1 replace-len2))))
 675                  ((>= i end))
 676                  (declare (optimize (insert-array-bounds-checks 0)))
 677                  (setf (aref seq1 i) (aref seq2 j)))))
 678           seq1))))
 679
 680 (macrolet
 681     ((define-replace-transforms ()
 682        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 683              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 684              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 685              collect (make-replace-transform saetp sequence-type sequence-type)
 686              into forms
 687              finally (return `(progn ,@forms))))
 688      (define-one-transform (sequence-type1 sequence-type2)
 689        (make-replace-transform nil sequence-type1 sequence-type2)))
 690   (define-replace-transforms)
 691   #!+sb-unicode
 692   (progn
 693    (define-one-transform (simple-array base-char (*)) (simple-array character (*)))
 694    (define-one-transform (simple-array character (*)) (simple-array base-char (*)))))
 695
 696 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 697 ;;; defined as those cases where we are doing word-aligned copies from
 698 ;;; both the source and the destination and we are copying from the same
 699 ;;; offset from both the source and the destination.  (The last
 700 ;;; condition is there so we can determine the direction to copy at
 701 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 702 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 703 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 704 ;;; N)-size buffer and blitting in the old N-size buffer in.
 705
 706 (defun frob-bash-transform (src src-offset
 707                             dst dst-offset
 708                             length n-elems-per-word)
 709   (declare (ignore src dst length))
 710   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 711     (multiple-value-bind (src-word src-elt)
 712         (truncate (lvar-value src-offset) n-elems-per-word)
 713       (multiple-value-bind (dst-word dst-elt)
 714           (truncate (lvar-value dst-offset) n-elems-per-word)
 715         ;; Avoid non-word aligned copies.
 716         (unless (and (zerop src-elt) (zerop dst-elt))
 717           (give-up-ir1-transform))
 718         ;; Avoid copies where we would have to insert code for
 719         ;; determining the direction of copying.
 720         (unless (= src-word dst-word)
 721           (give-up-ir1-transform))
 722         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 723         ;; so we have to do its work here.
 724         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 725                                       'length
 726                                       `(truncate (the index length) ,n-elems-per-word)))))
 727            (declare (type index end))
 728            ;; Handle any bits at the end.
 729            (when (logtest length (1- ,n-elems-per-word))
 730              (let* ((extra (mod length ,n-elems-per-word))
 731                     ;; FIXME: The shift amount on this ASH is
 732                     ;; *always* negative, but the backend doesn't
 733                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 734                     ;; wind up with a pile of code that tests the
 735                     ;; sign of the shift count prior to shifting when
 736                     ;; all we need is a simple negate and shift
 737                     ;; right.  Yuck.
 738                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 739                                (* (- extra ,n-elems-per-word)
 740                                   ,n-bits-per-elem))))
 741                (setf (sb!kernel:%vector-raw-bits dst end)
 742                      (logior
 743                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 744                                 (ash mask
 745                                      ,(ecase sb!c:*backend-byte-order*
 746                                              (:little-endian 0)
 747                                              (:big-endian `(* (- ,n-elems-per-word extra)
 748                                                               ,n-bits-per-elem)))))
 749                       (logand (sb!kernel:%vector-raw-bits src end)
 750                               (ash mask
 751                                    ,(ecase sb!c:*backend-byte-order*
 752                                            (:little-endian 0)
 753                                            (:big-endian `(* (- ,n-elems-per-word extra)
 754                                                             ,n-bits-per-elem)))))))))
 755            ;; Copy from the end to save a register.
 756            (do ((i end (1- i)))
 757                ((<= i ,src-word))
 758              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 759                    (sb!kernel:%vector-raw-bits src (1- i))))
 760            (values))))))
 761
 762 #.(loop for i = 1 then (* i 2)
 763         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 764                                         "SB!KERNEL")
 765                                                         ((src src-offset
 766                                                           dst dst-offset
 767                                                           length)
 768                                                         ((simple-unboxed-array (*))
 769                                                          (constant-arg index)
 770                                                          (simple-unboxed-array (*))
 771                                                          (constant-arg index)
 772                                                          index)
 773                                                         *)
 774                   (frob-bash-transform src src-offset
 775                                        dst dst-offset length
 776                                        ,(truncate sb!vm:n-word-bits i))) into forms
 777         until (= i sb!vm:n-word-bits)
 778         finally (return `(progn ,@forms)))
 779
 780 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 781 ;;; arrays with elements of size >= the word size.  We do this because
 782 ;;; we know the arrays cannot alias (one was just consed), therefore we
 783 ;;; can determine at compile time the direction to copy, and for
 784 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 785 ;;; needless checking to figure out what's going on.  The same
 786 ;;; considerations apply if we are copying elements larger than the word
 787 ;;; size, with the additional twist that doing it inline is likely to
 788 ;;; cons far less than calling REPLACE and letting generic code do the
 789 ;;; work.
 790 ;;;
 791 ;;; However, we do not do this for elements whose size is < than the
 792 ;;; word size because we don't want to deal with any alignment issues
 793 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 794 ;;; anyway.
 795
 796 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 797                                       element-type)
 798   (let ((saetp (find-saetp element-type)))
 799     (aver saetp)
 800     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 801         (expand-aref-copy-loop src src-offset dst dst-offset length)
 802         `(locally (declare (optimize (safety 0)))
 803            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 804
 805 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 806   (if (eql src-offset dst-offset)
 807       `(do ((i (+ ,src-offset ,length) (1- i)))
 808            ((<= i ,src-offset))
 809          (declare (optimize (insert-array-bounds-checks 0)))
 810          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 811       ;; KLUDGE: The compiler is not able to derive that (+ offset
 812       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 813       ;; We, however, know it must be so, as by this point the bounds
 814       ;; have already been checked.
 815       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 816             (j (+ ,dst-offset ,length) (1- j)))
 817            ((<= i ,src-offset))
 818          (declare (optimize (insert-array-bounds-checks 0))
 819                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 820          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 821
 822 ;;; SUBSEQ, COPY-SEQ
 823
 824 (deftransform subseq ((seq start &optional end)
 825                       (vector t &optional t)
 826                       *
 827                       :node node)
 828   (let ((type (lvar-type seq)))
 829     (cond
 830       ((and (array-type-p type)
 831             (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 832        (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 833          `(let* ((length (length seq))
 834                  (end (or end length)))
 835             ,(unless (policy node (zerop insert-array-bounds-checks))
 836                      '(progn
 837                        (unless (<= 0 start end length)
 838                          (sequence-bounding-indices-bad-error seq start end))))
 839             (let* ((size (- end start))
 840                    (result (make-array size :element-type ',element-type)))
 841               ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
 842                                                        (lvar-value start)
 843                                                        'start)
 844                                               'result 0 'size element-type)
 845               result))))
 846       ((csubtypep type (specifier-type 'string))
 847        '(string-subseq* seq start end))
 848       (t
 849        '(vector-subseq* seq start end)))))
 850
 851 (deftransform subseq ((seq start &optional end)
 852                       (list t &optional t))
 853   `(list-subseq* seq start end))
 854
 855 (deftransform subseq ((seq start &optional end)
 856                       ((and sequence (not vector) (not list)) t &optional t))
 857   '(sb!sequence:subseq seq start end))
 858
 859 (deftransform copy-seq ((seq) (vector))
 860   (let ((type (lvar-type seq)))
 861     (cond ((and (array-type-p type)
 862                 (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 863            (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 864              `(let* ((length (length seq))
 865                      (result (make-array length :element-type ',element-type)))
 866                 ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
 867                 result)))
 868           ((csubtypep type (specifier-type 'string))
 869            '(string-subseq* seq 0 nil))
 870           (t
 871            '(vector-subseq* seq 0 nil)))))
 872
 873 (deftransform copy-seq ((seq) (list))
 874   '(list-copy-seq* seq))
 875
 876 (deftransform copy-seq ((seq) ((and sequence (not vector) (not list))))
 877   '(sb!sequence:copy-seq seq))
 878
 879 ;;; FIXME: it really should be possible to take advantage of the
 880 ;;; macros used in code/seq.lisp here to avoid duplication of code,
 881 ;;; and enable even funkier transformations.
 882 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
 883                                (test #'eql)
 884                                (key #'identity)
 885                                from-end)
 886                       (vector vector &rest t)
 887                       *
 888                       :node node
 889                       :policy (> speed (max space safety)))
 890   "open code"
 891   (let ((from-end (when (lvar-p from-end)
 892                     (unless (constant-lvar-p from-end)
 893                       (give-up-ir1-transform ":FROM-END is not constant."))
 894                     (lvar-value from-end)))
 895         (keyp (lvar-p key))
 896         (testp (lvar-p test))
 897         (check-bounds-p (policy node (plusp insert-array-bounds-checks))))
 898     `(block search
 899        (flet ((oops (vector start end)
 900                 (sequence-bounding-indices-bad-error vector start end)))
 901          (let* ((len1 (length pattern))
 902                 (len2 (length text))
 903                 (end1 (or end1 len1))
 904                 (end2 (or end2 len2))
 905                ,@(when keyp
 906                        '((key (coerce key 'function))))
 907                ,@(when testp
 908                        '((test (coerce test 'function)))))
 909           (declare (type index start1 start2 end1 end2))
 910           ,@(when check-bounds-p
 911              `((unless (<= start1 end1 len1)
 912                  (oops pattern start1 end1))
 913                (unless (<= start2 end2 len2)
 914                  (oops pattern start2 end2))))
 915           (do (,(if from-end
 916                     '(index2 (- end2 (- end1 start1)) (1- index2))
 917                     '(index2 start2 (1+ index2))))
 918               (,(if from-end
 919                     '(< index2 start2)
 920                     '(>= index2 end2))
 921                nil)
 922             ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
 923             ;; terminates is hits -1 when :FROM-END is true and :START2
 924             ;; is 0.
 925             (declare (type fixnum index2))
 926             (when (do ((index1 start1 (1+ index1))
 927                        (index2 index2 (1+ index2)))
 928                       ((>= index1 end1) t)
 929                     (declare (type index index1 index2)
 930                              (optimize (insert-array-bounds-checks 0)))
 931                     ,@(unless from-end
 932                               '((when (= index2 end2)
 933                                   (return-from search nil))))
 934                     (unless (,@(if testp
 935                                    '(funcall test)
 936                                    '(eql))
 937                                ,(if keyp
 938                                     '(funcall key (aref pattern index1))
 939                                     '(aref pattern index1))
 940                                ,(if keyp
 941                                     '(funcall key (aref text index2))
 942                                     '(aref text index2)))
 943                       (return nil)))
 944               (return index2))))))))
 945
 946
 947 ;;; Open-code CONCATENATE for strings. It would be possible to extend
 948 ;;; this transform to non-strings, but I chose to just do the case that
 949 ;;; should cover 95% of CONCATENATE performance complaints for now.
 950 ;;;   -- JES, 2007-11-17
 951 (deftransform concatenate ((result-type &rest lvars)
 952                            (symbol &rest sequence)
 953                            *
 954                            :policy (> speed space))
 955   (unless (constant-lvar-p result-type)
 956     (give-up-ir1-transform))
 957   (let* ((element-type (let ((type (lvar-value result-type)))
 958                          ;; Only handle the simple result type cases. If
 959                          ;; somebody does (CONCATENATE '(STRING 6) ...)
 960                          ;; their code won't be optimized, but nobody does
 961                          ;; that in practice.
 962                          (case type
 963                            ((string simple-string) 'character)
 964                            ((base-string simple-base-string) 'base-char)
 965                            (t (give-up-ir1-transform)))))
 966          (vars (loop for x in lvars collect (gensym)))
 967          (lvar-values (loop for lvar in lvars
 968                             collect (when (constant-lvar-p lvar)
 969                                       (lvar-value lvar))))
 970          (lengths
 971           (loop for value in lvar-values
 972                 for var in vars
 973                 collect (if value
 974                             (length value)
 975                             `(sb!impl::string-dispatch ((simple-array * (*))
 976                                                         sequence)
 977                                  ,var
 978                                (declare (muffle-conditions compiler-note))
 979                                (length ,var))))))
 980     `(apply
 981       (lambda ,vars
 982         (declare (ignorable ,@vars))
 983         (let* ((.length. (+ ,@lengths))
 984                (.pos. 0)
 985                (.string. (make-string .length. :element-type ',element-type)))
 986           (declare (type index .length. .pos.)
 987                    (muffle-conditions compiler-note))
 988           ,@(loop for value in lvar-values
 989                   for var in vars
 990                   collect (if (stringp value)
 991                               ;; Fold the array reads for constant arguments
 992                               `(progn
 993                                  ,@(loop for c across value
 994                                          collect `(setf (aref .string.
 995                                                               .pos.) ,c)
 996                                          collect `(incf .pos.)))
 997                               `(sb!impl::string-dispatch
 998                                    (#!+sb-unicode
 999                                     (simple-array character (*))
1000                                     (simple-array base-char (*))
1001                                     t)
1002                                    ,var
1003                                  (replace .string. ,var :start1 .pos.)
1004                                  (incf .pos. (length ,var)))))
1005           .string.))
1006       lvars)))
1007 \f
1008 ;;;; CONS accessor DERIVE-TYPE optimizers
1009
1010 (defoptimizer (car derive-type) ((cons))
1011   (let ((type (lvar-type cons))
1012         (null-type (specifier-type 'null)))
1013     (cond ((eq type null-type)
1014            null-type)
1015           ((cons-type-p type)
1016            (cons-type-car-type type)))))
1017
1018 (defoptimizer (cdr derive-type) ((cons))
1019   (let ((type (lvar-type cons))
1020         (null-type (specifier-type 'null)))
1021     (cond ((eq type null-type)
1022            null-type)
1023           ((cons-type-p type)
1024            (cons-type-cdr-type type)))))
1025 \f
1026 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
1027
1028 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
1029 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
1030 ;;; expansion, so we factor out the condition into this function.
1031 (defun check-inlineability-of-find-position-if (sequence from-end)
1032   (let ((ctype (lvar-type sequence)))
1033     (cond ((csubtypep ctype (specifier-type 'vector))
1034            ;; It's not worth trying to inline vector code unless we
1035            ;; know a fair amount about it at compile time.
1036            (upgraded-element-type-specifier-or-give-up sequence)
1037            (unless (constant-lvar-p from-end)
1038              (give-up-ir1-transform
1039               "FROM-END argument value not known at compile time")))
1040           ((csubtypep ctype (specifier-type 'list))
1041            ;; Inlining on lists is generally worthwhile.
1042            )
1043           (t
1044            (give-up-ir1-transform
1045             "sequence type not known at compile time")))))
1046
1047 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
1048 (macrolet ((def (name condition)
1049              `(deftransform ,name ((predicate sequence from-end start end key)
1050                                    (function list t t t function)
1051                                    *
1052                                    :policy (> speed space))
1053                 "expand inline"
1054                 `(let ((index 0)
1055                        (find nil)
1056                        (position nil))
1057                    (declare (type index index))
1058                    (dolist (i sequence
1059                             (if (and end (> end index))
1060                                 (sequence-bounding-indices-bad-error
1061                                  sequence start end)
1062                                 (values find position)))
1063                      (let ((key-i (funcall key i)))
1064                        (when (and end (>= index end))
1065                          (return (values find position)))
1066                        (when (>= index start)
1067                          (,',condition (funcall predicate key-i)
1068                           ;; This hack of dealing with non-NIL
1069                           ;; FROM-END for list data by iterating
1070                           ;; forward through the list and keeping
1071                           ;; track of the last time we found a match
1072                           ;; might be more screwy than what the user
1073                           ;; expects, but it seems to be allowed by
1074                           ;; the ANSI standard. (And if the user is
1075                           ;; screwy enough to ask for FROM-END
1076                           ;; behavior on list data, turnabout is
1077                           ;; fair play.)
1078                           ;;
1079                           ;; It's also not enormously efficient,
1080                           ;; calling PREDICATE and KEY more often
1081                           ;; than necessary; but all the
1082                           ;; alternatives seem to have their own
1083                           ;; efficiency problems.
1084                           (if from-end
1085                               (setf find i
1086                                     position index)
1087                               (return (values i index))))))
1088                      (incf index))))))
1089   (def %find-position-if when)
1090   (def %find-position-if-not unless))
1091
1092 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
1093 ;;; without loss of efficiency. (I.e., the optimizer should be able
1094 ;;; to straighten everything out.)
1095 (deftransform %find-position ((item sequence from-end start end key test)
1096                               (t list t t t t t)
1097                               *
1098                               :policy (> speed space))
1099   "expand inline"
1100   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
1101                         ;; The order of arguments for asymmetric tests
1102                         ;; (e.g. #'<, as opposed to order-independent
1103                         ;; tests like #'=) is specified in the spec
1104                         ;; section 17.2.1 -- the O/Zi stuff there.
1105                         (lambda (i)
1106                           (funcall test-fun item i)))
1107                       sequence
1108                       from-end
1109                       start
1110                       end
1111                       (%coerce-callable-to-fun key)))
1112
1113 ;;; The inline expansions for the VECTOR case are saved as macros so
1114 ;;; that we can share them between the DEFTRANSFORMs and the default
1115 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
1116 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1117 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1118                                                             from-end
1119                                                             start
1120                                                             end-arg
1121                                                             element
1122                                                             done-p-expr)
1123   (with-unique-names (offset block index n-sequence sequence end)
1124     `(let* ((,n-sequence ,sequence-arg))
1125        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1126                          (,start ,start)
1127                          (,end ,end-arg)
1128                          :check-fill-pointer t)
1129          (block ,block
1130            (macrolet ((maybe-return ()
1131                         ;; WITH-ARRAY-DATA has already performed bounds
1132                         ;; checking, so we can safely elide the checks
1133                         ;; in the inner loop.
1134                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1135                                            (aref ,sequence ,index))))
1136                           (when ,done-p-expr
1137                             (return-from ,block
1138                               (values ,element
1139                                       (- ,index ,offset)))))))
1140              (if ,from-end
1141                  (loop for ,index
1142                        ;; (If we aren't fastidious about declaring that
1143                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1144                        ;; can send us off into never-never land, since
1145                        ;; INDEX is initialized to -1.)
1146                        of-type index-or-minus-1
1147                        from (1- ,end) downto ,start do
1148                        (maybe-return))
1149                  (loop for ,index of-type index from ,start below ,end do
1150                           (maybe-return))))
1151            (values nil nil))))))
1152
1153 (def!macro %find-position-vector-macro (item sequence
1154                                              from-end start end key test)
1155   (with-unique-names (element)
1156     (%find-position-or-find-position-if-vector-expansion
1157      sequence
1158      from-end
1159      start
1160      end
1161      element
1162      ;; (See the LIST transform for a discussion of the correct
1163      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1164      ;; or after the checked sequence element.)
1165      `(funcall ,test ,item (funcall ,key ,element)))))
1166
1167 (def!macro %find-position-if-vector-macro (predicate sequence
1168                                                      from-end start end key)
1169   (with-unique-names (element)
1170     (%find-position-or-find-position-if-vector-expansion
1171      sequence
1172      from-end
1173      start
1174      end
1175      element
1176      `(funcall ,predicate (funcall ,key ,element)))))
1177
1178 (def!macro %find-position-if-not-vector-macro (predicate sequence
1179                                                          from-end start end key)
1180   (with-unique-names (element)
1181     (%find-position-or-find-position-if-vector-expansion
1182      sequence
1183      from-end
1184      start
1185      end
1186      element
1187      `(not (funcall ,predicate (funcall ,key ,element))))))
1188
1189 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1190 ;;; VECTOR data
1191 (deftransform %find-position-if ((predicate sequence from-end start end key)
1192                                  (function vector t t t function)
1193                                  *
1194                                  :policy (> speed space))
1195   "expand inline"
1196   (check-inlineability-of-find-position-if sequence from-end)
1197   '(%find-position-if-vector-macro predicate sequence
1198                                    from-end start end key))
1199
1200 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1201                                      (function vector t t t function)
1202                                      *
1203                                      :policy (> speed space))
1204   "expand inline"
1205   (check-inlineability-of-find-position-if sequence from-end)
1206   '(%find-position-if-not-vector-macro predicate sequence
1207                                        from-end start end key))
1208
1209 (deftransform %find-position ((item sequence from-end start end key test)
1210                               (t vector t t t function function)
1211                               *
1212                               :policy (> speed space))
1213   "expand inline"
1214   (check-inlineability-of-find-position-if sequence from-end)
1215   '(%find-position-vector-macro item sequence
1216     from-end start end key test))
1217
1218 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1219 ;;; POSITION-IF, etc.
1220 (define-source-transform effective-find-position-test (test test-not)
1221   (once-only ((test test)
1222               (test-not test-not))
1223     `(cond
1224       ((and ,test ,test-not)
1225        (error "can't specify both :TEST and :TEST-NOT"))
1226       (,test (%coerce-callable-to-fun ,test))
1227       (,test-not
1228        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1229        ;; inefficient, but since the TEST-NOT option is deprecated
1230        ;; anyway, we don't care.)
1231        (complement (%coerce-callable-to-fun ,test-not)))
1232       (t #'eql))))
1233 (define-source-transform effective-find-position-key (key)
1234   (once-only ((key key))
1235     `(if ,key
1236          (%coerce-callable-to-fun ,key)
1237          #'identity)))
1238
1239 (macrolet ((define-find-position (fun-name values-index)
1240              `(deftransform ,fun-name ((item sequence &key
1241                                              from-end (start 0) end
1242                                              key test test-not)
1243                                        (t (or list vector) &rest t))
1244                 '(nth-value ,values-index
1245                             (%find-position item sequence
1246                                             from-end start
1247                                             end
1248                                             (effective-find-position-key key)
1249                                             (effective-find-position-test
1250                                              test test-not))))))
1251   (define-find-position find 0)
1252   (define-find-position position 1))
1253
1254 (macrolet ((define-find-position-if (fun-name values-index)
1255              `(deftransform ,fun-name ((predicate sequence &key
1256                                                   from-end (start 0)
1257                                                   end key)
1258                                        (t (or list vector) &rest t))
1259                 '(nth-value
1260                   ,values-index
1261                   (%find-position-if (%coerce-callable-to-fun predicate)
1262                                      sequence from-end
1263                                      start end
1264                                      (effective-find-position-key key))))))
1265   (define-find-position-if find-if 0)
1266   (define-find-position-if position-if 1))
1267
1268 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1269 ;;; didn't bother to worry about optimizing them, except note that on
1270 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1271 ;;; sbcl-devel
1272 ;;;
1273 ;;;     My understanding is that while the :test-not argument is
1274 ;;;     deprecated in favour of :test (complement #'foo) because of
1275 ;;;     semantic difficulties (what happens if both :test and :test-not
1276 ;;;     are supplied, etc) the -if-not variants, while officially
1277 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1278 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1279 ;;;     reasons for allowing the -if-not versions equal status,
1280 ;;;     particularly remove-if-not (== filter).
1281 ;;;
1282 ;;;     This is only an informal understanding, I grant you, but
1283 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1284 ;;;     way as the others?
1285 ;;;
1286 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1287 ;;; implementation of SBCL.
1288 (macrolet ((define-find-position-if-not (fun-name values-index)
1289                `(deftransform ,fun-name ((predicate sequence &key
1290                                           from-end (start 0)
1291                                           end key)
1292                                          (t (or list vector) &rest t))
1293                  '(nth-value
1294                    ,values-index
1295                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1296                     sequence from-end
1297                     start end
1298                     (effective-find-position-key key))))))
1299   (define-find-position-if-not find-if-not 0)
1300   (define-find-position-if-not position-if-not 1))
1301
1302 (macrolet ((define-trimmer-transform (fun-name leftp rightp)
1303              `(deftransform ,fun-name ((char-bag string)
1304                                        (t simple-string))
1305                 (let ((find-expr
1306                        (if (constant-lvar-p char-bag)
1307                            ;; If the bag is constant, use MEMBER
1308                            ;; instead of FIND, since we have a
1309                            ;; deftransform for MEMBER that can
1310                            ;; open-code all of the comparisons when
1311                            ;; the list is constant. -- JES, 2007-12-10
1312                            `(not (member (schar string index)
1313                                          ',(coerce (lvar-value char-bag) 'list)
1314                                          :test #'char=))
1315                            '(not (find (schar string index) char-bag :test #'char=)))))
1316                   `(flet ((char-not-in-bag (index)
1317                             ,find-expr))
1318                      (let* ((end (length string))
1319                             (left-end (if ,',leftp
1320                                           (do ((index 0 (1+ index)))
1321                                               ((or (= index (the fixnum end))
1322                                                    (char-not-in-bag index))
1323                                                index)
1324                                             (declare (fixnum index)))
1325                                           0))
1326                             (right-end (if ,',rightp
1327                                            (do ((index (1- end) (1- index)))
1328                                                ((or (< index left-end)
1329                                                     (char-not-in-bag index))
1330                                                 (1+ index))
1331                                              (declare (fixnum index)))
1332                                            end)))
1333                        (if (and (eql left-end 0)
1334                                 (eql right-end (length string)))
1335                            string
1336                            (subseq string left-end right-end))))))))
1337   (define-trimmer-transform string-left-trim t nil)
1338   (define-trimmer-transform string-right-trim nil t)
1339   (define-trimmer-transform string-trim t t))
1340