src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places))
 137     (let ((found-vector-p nil))
 138       (flet ((process-vector (length)
 139                (unless found-vector-p
 140                  (setq found-vector-p t)
 141                  (bindings `(index 0 (1+ index)))
 142                  (declarations `(type index index)))
 143                (vector-lengths length)))
 144         (loop for seq of-type lvar in seqs
 145            for seq-name in seq-names
 146            for type = (lvar-type seq)
 147            do (cond ((csubtypep type (specifier-type 'list))
 148                      (with-unique-names (index)
 149                        (bindings `(,index ,seq-name (cdr ,index)))
 150                        (declarations `(type list ,index))
 151                        (places `(car ,index))
 152                        (tests `(endp ,index))))
 153                     ((csubtypep type (specifier-type 'vector))
 154                      (process-vector `(length ,seq-name))
 155                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 156                                 (aref ,seq-name index))))
 157                     (t
 158                      (give-up-ir1-transform
 159                       "can't determine sequence argument type"))))
 160         (when into
 161           (process-vector `(array-dimension ,into 0))))
 162       (when found-vector-p
 163         (bindings `(length (min ,@(vector-lengths))))
 164         (tests `(>= index length)))
 165       `(do (,@(bindings))
 166            ((or ,@(tests)) ,result)
 167          (declare ,@(declarations))
 168          (let ((funcall-result (funcall fun ,@(places))))
 169            (declare (ignorable funcall-result))
 170            ,body)))))
 171
 172 ;;; Try to compile %MAP efficiently when we can determine sequence
 173 ;;; argument types at compile time.
 174 ;;;
 175 ;;; Note: This transform was written to allow open coding of
 176 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 177 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 178 ;;; necessarily as efficient as possible. In particular, it will be
 179 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 180 ;;; numeric element types. It should be straightforward to make it
 181 ;;; handle that case more efficiently, but it's left as an exercise to
 182 ;;; the reader, because the code is complicated enough already and I
 183 ;;; don't happen to need that functionality right now. -- WHN 20000410
 184 (deftransform %map ((result-type fun seq &rest seqs) * *
 185                     :policy (>= speed space))
 186   "open code"
 187   (unless (constant-lvar-p result-type)
 188     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 189   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 190            (fn-1subtypep (fn x y)
 191              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 192                (if valid-p
 193                    subtype-p
 194                    (give-up-ir1-transform
 195                     "can't analyze sequence type relationship"))))
 196            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 197     (let* ((result-type-value (lvar-value result-type))
 198            (result-supertype (cond ((null result-type-value) 'null)
 199                                    ((1subtypep result-type-value 'vector)
 200                                     'vector)
 201                                    ((1subtypep result-type-value 'list)
 202                                     'list)
 203                                    (t
 204                                     (give-up-ir1-transform
 205                                      "result type unsuitable")))))
 206       (cond ((and result-type-value (null seqs))
 207              ;; The consing arity-1 cases can be implemented
 208              ;; reasonably efficiently as function calls, and the cost
 209              ;; of consing should be significantly larger than
 210              ;; function call overhead, so we always compile these
 211              ;; cases as full calls regardless of speed-versus-space
 212              ;; optimization policy.
 213              (cond ((subtypep result-type-value 'list)
 214                     '(%map-to-list-arity-1 fun seq))
 215                    ( ;; (This one can be inefficient due to COERCE, but
 216                     ;; the current open-coded implementation has the
 217                     ;; same problem.)
 218                     (subtypep result-type-value 'vector)
 219                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 220                              ',result-type-value))
 221                    (t (bug "impossible (?) sequence type"))))
 222             (t
 223              (let* ((seqs (cons seq seqs))
 224                     (seq-args (make-gensym-list (length seqs))))
 225                (multiple-value-bind (push-dacc result)
 226                    (ecase result-supertype
 227                      (null (values nil nil))
 228                      (list (values `(push funcall-result acc)
 229                                    `(nreverse acc)))
 230                      (vector (values `(push funcall-result acc)
 231                                      `(coerce (nreverse acc)
 232                                               ',result-type-value))))
 233                  ;; (We use the same idiom, of returning a LAMBDA from
 234                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 235                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 236                  ;; reason: we need to get the runtime values of each
 237                  ;; of the &REST vars.)
 238                  `(lambda (result-type fun ,@seq-args)
 239                     (declare (ignore result-type))
 240                     (let ((fun (%coerce-callable-to-fun fun))
 241                           (acc nil))
 242                       (declare (type list acc))
 243                       (declare (ignorable acc))
 244                       ,(build-sequence-iterator
 245                         seqs seq-args
 246                         :result result
 247                         :body push-dacc))))))))))
 248
 249 ;;; MAP-INTO
 250 (deftransform map-into ((result fun &rest seqs)
 251                         (vector * &rest *)
 252                         *)
 253   "open code"
 254   (let ((seqs-names (mapcar (lambda (x)
 255                               (declare (ignore x))
 256                               (gensym))
 257                             seqs)))
 258     `(lambda (result fun ,@seqs-names)
 259        ,(build-sequence-iterator
 260          seqs seqs-names
 261          :result '(when (array-has-fill-pointer-p result)
 262                    (setf (fill-pointer result) index))
 263          :into 'result
 264          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 265                  (setf (aref result index) funcall-result)))
 266        result)))
 267
 268 \f
 269 ;;; FIXME: once the confusion over doing transforms with known-complex
 270 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 271 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 272 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 273   '(aref s i))
 274
 275 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 276   '(nth i s))
 277
 278 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 279   '(%aset s i v))
 280
 281 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 282   '(setf (car (nthcdr i s)) v))
 283
 284 (deftransform %check-vector-sequence-bounds ((vector start end)
 285                                              (vector * *) *
 286                                              :node node)
 287   (if (policy node (= 0 insert-array-bounds-checks))
 288       '(or end (length vector))
 289       '(let ((length (length vector)))
 290          (if (<= 0 start (or end length) length)
 291              (or end length)
 292              (sequence-bounding-indices-bad-error vector start end)))))
 293
 294 (deftype eq-comparable-type ()
 295   '(or fixnum (not number)))
 296
 297 ;;; True if EQL comparisons involving type can be simplified to EQ.
 298 (defun eq-comparable-type-p (type)
 299   (csubtypep type (specifier-type 'eq-comparable-type)))
 300
 301 (defun specialized-list-seek-function-name (function-name key-functions &optional variant)
 302   (or (find-symbol (with-output-to-string (s)
 303                      ;; Write "%NAME-FUN1-FUN2-FUN3", etc. Not only is
 304                      ;; this ever so slightly faster then FORMAT, this
 305                      ;; way we are also proof against *PRINT-CASE*
 306                      ;; frobbing and such.
 307                      (write-char #\% s)
 308                      (write-string (symbol-name function-name) s)
 309                      (dolist (f key-functions)
 310                        (write-char #\- s)
 311                        (write-string (symbol-name f) s))
 312                      (when variant
 313                        (write-char #\- s)
 314                        (write-string (symbol-name variant) s)))
 315                    (load-time-value (find-package "SB!KERNEL")))
 316       (bug "Unknown list item seek transform: name=~S, key-functions=~S variant=~S"
 317            function-name key-functions variant)))
 318
 319 (defun transform-list-item-seek (name item list key test test-not node)
 320   (when (and test test-not)
 321     (abort-ir1-transform "Both ~S and ~S supplied to ~S." :test :test-not name))
 322   ;; If TEST is EQL, drop it.
 323   (when (and test (lvar-fun-is test '(eql)))
 324     (setf test nil))
 325   ;; Ditto for KEY IDENTITY.
 326   (when (and key (lvar-fun-is key '(identity)))
 327     (setf key nil))
 328   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 329   ;; not there at all. If it might be NIL, make up a form to that
 330   ;; ensures it is a function.
 331   (multiple-value-bind (key key-form)
 332       (when key
 333         (let ((key-type (lvar-type key))
 334               (null-type (specifier-type 'null)))
 335           (cond ((csubtypep key-type null-type)
 336                  (values nil nil))
 337                 ((csubtypep null-type key-type)
 338                  (values key '(if key
 339                                (%coerce-callable-to-fun key)
 340                                #'identity)))
 341                 (t
 342                  (values key (ensure-lvar-fun-form key 'key))))))
 343     (let* ((c-test (cond ((and test (lvar-fun-is test '(eq)))
 344                           (setf test nil)
 345                           'eq)
 346                          ((and (not test) (not test-not))
 347                           (when (eq-comparable-type-p (lvar-type item))
 348                             'eq))))
 349            (funs (delete nil (list (when key (list key 'key))
 350                                    (when test (list test 'test))
 351                                    (when test-not (list test-not 'test-not)))))
 352            (target-expr (if key '(%funcall key target) 'target))
 353            (test-expr (cond (test `(%funcall test item ,target-expr))
 354                             (test-not `(not (%funcall test-not item ,target-expr)))
 355                             (c-test `(,c-test item ,target-expr))
 356                             (t `(eql item ,target-expr)))))
 357       (labels ((open-code (tail)
 358                  (when tail
 359                    `(if (let ((this ',(car tail)))
 360                           ,(ecase name
 361                                   ((assoc rassoc)
 362                                    (let ((cxx (if (eq name 'assoc) 'car 'cdr)))
 363                                      `(and this (let ((target (,cxx this)))
 364                                                   ,test-expr))))
 365                                   (member
 366                                    `(let ((target this))
 367                                       ,test-expr))))
 368                         ',(ecase name
 369                                  ((assoc rassoc) (car tail))
 370                                  (member tail))
 371                         ,(open-code (cdr tail)))))
 372                (ensure-fun (args)
 373                  (if (eq 'key (second args))
 374                      key-form
 375                      (apply #'ensure-lvar-fun-form args))))
 376         (let* ((cp (constant-lvar-p list))
 377                (c-list (when cp (lvar-value list))))
 378           (cond ((and cp c-list (member name '(assoc rassoc member))
 379                       (policy node (>= speed space)))
 380                  `(let ,(mapcar (lambda (fun) `(,(second fun) ,(ensure-fun fun))) funs)
 381                     ,(open-code c-list)))
 382                 ((and cp (not c-list))
 383                  ;; constant nil list
 384                  (if (eq name 'adjoin)
 385                      '(list item)
 386                      nil))
 387                 (t
 388                  ;; specialized out-of-line version
 389                  `(,(specialized-list-seek-function-name name (mapcar #'second funs) c-test)
 390                     item list ,@(mapcar #'ensure-fun funs)))))))))
 391
 392 (defun transform-list-pred-seek (name pred list key node)
 393   ;; If KEY is IDENTITY, drop it.
 394   (when (and key (lvar-fun-is key '(identity)))
 395     (setf key nil))
 396   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 397   ;; not there at all. If it might be NIL, make up a form to that
 398   ;; ensures it is a function.
 399   (multiple-value-bind (key key-form)
 400       (when key
 401         (let ((key-type (lvar-type key))
 402               (null-type (specifier-type 'null)))
 403           (cond ((csubtypep key-type null-type)
 404                  (values nil nil))
 405                 ((csubtypep null-type key-type)
 406                  (values key '(if key
 407                                (%coerce-callable-to-fun key)
 408                                #'identity)))
 409                 (t
 410                  (values key (ensure-lvar-fun-form key 'key))))))
 411     (let ((test-expr `(%funcall pred ,(if key '(%funcall key target) 'target)))
 412           (pred-expr (ensure-lvar-fun-form pred 'pred)))
 413       (when (member name '(member-if-not assoc-if-not rassoc-if-not))
 414         (setf test-expr `(not ,test-expr)))
 415       (labels ((open-code (tail)
 416                  (when tail
 417                    `(if (let ((this ',(car tail)))
 418                           ,(ecase name
 419                                   ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 420                                    (let ((cxx (if (member name '(assoc-if assoc-if-not)) 'car 'cdr)))
 421                                      `(and this (let ((target (,cxx this)))
 422                                                   ,test-expr))))
 423                                   ((member-if member-if-not)
 424                                    `(let ((target this))
 425                                       ,test-expr))))
 426                         ',(ecase name
 427                                  ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 428                                   (car tail))
 429                                  ((member-if member-if-not)
 430                                   tail))
 431                         ,(open-code (cdr tail))))))
 432         (let* ((cp (constant-lvar-p list))
 433                (c-list (when cp (lvar-value list))))
 434           (cond ((and cp c-list (policy node (>= speed space)))
 435                  `(let ((pred ,pred-expr)
 436                         ,@(when key `((key ,key-form))))
 437                     ,(open-code c-list)))
 438                 ((and cp (not c-list))
 439                  ;; constant nil list -- nothing to find!
 440                  nil)
 441                 (t
 442                  ;; specialized out-of-line version
 443                  `(,(specialized-list-seek-function-name name (when key '(key)))
 444                     ,pred-expr list ,@(when key (list key-form))))))))))
 445
 446 (macrolet ((def (name &optional if/if-not)
 447              (let ((basic (symbolicate "%" name))
 448                    (basic-eq (symbolicate "%" name "-EQ"))
 449                    (basic-key (symbolicate "%" name "-KEY"))
 450                    (basic-key-eq (symbolicate "%" name "-KEY-EQ")))
 451                `(progn
 452                   (deftransform ,name ((item list &key key test test-not) * * :node node)
 453                     (transform-list-item-seek ',name item list key test test-not node))
 454                   (deftransform ,basic ((item list) (eq-comparable-type t))
 455                     `(,',basic-eq item list))
 456                   (deftransform ,basic-key ((item list) (eq-comparable-type t))
 457                     `(,',basic-key-eq item list))
 458                   ,@(when if/if-not
 459                           (let ((if-name (symbolicate name "-IF"))
 460                                 (if-not-name (symbolicate name "-IF-NOT")))
 461                             `((deftransform ,if-name ((pred list &key key) * * :node node)
 462                                 (transform-list-pred-seek ',if-name pred list key node))
 463                               (deftransform ,if-not-name ((pred list &key key) * * :node node)
 464                                 (transform-list-pred-seek ',if-not-name pred list key node)))))))))
 465   (def adjoin)
 466   (def assoc  t)
 467   (def member t)
 468   (def rassoc t))
 469
 470 (deftransform memq ((item list) (t (constant-arg list)))
 471   (labels ((rec (tail)
 472              (if tail
 473                  `(if (eq item ',(car tail))
 474                       ',tail
 475                       ,(rec (cdr tail)))
 476                  nil)))
 477     (rec (lvar-value list))))
 478
 479 ;;; A similar transform used to apply to MEMBER and ASSOC, but since
 480 ;;; TRANSFORM-LIST-ITEM-SEEK now takes care of them those transform
 481 ;;; would never fire, and (%MEMBER-TEST ITEM LIST #'EQ) should be
 482 ;;; almost as fast as MEMQ.
 483 (deftransform delete ((item list &key test) (t list &rest t) *)
 484   "convert to EQ test"
 485   ;; FIXME: The scope of this transformation could be
 486   ;; widened somewhat, letting it work whenever the test is
 487   ;; 'EQL and we know from the type of ITEM that it #'EQ
 488   ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 489   ;; and SYMBOL.)
 490   ;;   If TEST is EQ, apply transform, else
 491   ;;   if test is not EQL, then give up on transform, else
 492   ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 493   ;;   transform, else give up on transform.
 494   (cond (test
 495          (unless (lvar-fun-is test '(eq))
 496            (give-up-ir1-transform)))
 497         ((types-equal-or-intersect (lvar-type item)
 498                                    (specifier-type 'number))
 499          (give-up-ir1-transform "Item might be a number.")))
 500   `(delq item list))
 501
 502 (deftransform delete-if ((pred list) (t list))
 503   "open code"
 504   '(do ((x list (cdr x))
 505         (splice '()))
 506        ((endp x) list)
 507      (cond ((funcall pred (car x))
 508             (if (null splice)
 509                 (setq list (cdr x))
 510                 (rplacd splice (cdr x))))
 511            (t (setq splice x)))))
 512
 513 (deftransform fill ((seq item &key (start 0) (end nil))
 514                     (list t &key (:start t) (:end t)))
 515   '(list-fill* seq item start end))
 516
 517 (deftransform fill ((seq item &key (start 0) (end nil))
 518                     (vector t &key (:start t) (:end t))
 519                     *
 520                     :node node)
 521   (let* ((element-ctype (extract-upgraded-element-type seq))
 522          (element-type (type-specifier element-ctype))
 523          (type (lvar-type seq))
 524          (saetp (unless (eq *wild-type* element-ctype)
 525                   (find-saetp-by-ctype element-ctype))))
 526     (cond ((eq *wild-type* element-ctype)
 527            (delay-ir1-transform node :constraint)
 528            `(vector-fill* seq item start end))
 529           ((and saetp (sb!vm::valid-bit-bash-saetp-p saetp))
 530            (let* ((n-bits (sb!vm:saetp-n-bits saetp))
 531                   (basher-name (format nil "UB~D-BASH-FILL" n-bits))
 532                   (basher (or (find-symbol basher-name
 533                                            (load-time-value (find-package :sb!kernel)))
 534                               (abort-ir1-transform
 535                                "Unknown fill basher, please report to sbcl-devel: ~A"
 536                                basher-name)))
 537                   (kind (cond ((sb!vm:saetp-fixnum-p saetp) :tagged)
 538                               ((member element-type '(character base-char)) :char)
 539                               ((eq element-type 'single-float) :single-float)
 540                               #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 541                               ((eq element-type 'double-float) :double-float)
 542                               #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 543                               ((equal element-type '(complex single-float))
 544                                :complex-single-float)
 545                               (t
 546                                (aver (integer-type-p element-ctype))
 547                                :bits)))
 548                   ;; BASH-VALUE is a word that we can repeatedly smash
 549                   ;; on the array: for less-than-word sized elements it
 550                   ;; contains multiple copies of the fill item.
 551                   (bash-value
 552                    (if (constant-lvar-p item)
 553                        (let ((tmp (lvar-value item)))
 554                          (unless (ctypep tmp element-ctype)
 555                            (abort-ir1-transform "~S is not ~S" tmp element-type))
 556                          (let* ((bits
 557                                  (ldb (byte n-bits 0)
 558                                       (ecase kind
 559                                         (:tagged
 560                                          (ash tmp sb!vm:n-fixnum-tag-bits))
 561                                         (:char
 562                                          (char-code tmp))
 563                                         (:bits
 564                                          tmp)
 565                                         (:single-float
 566                                          (single-float-bits tmp))
 567                                         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 568                                         (:double-float
 569                                          (logior (ash (double-float-high-bits tmp) 32)
 570                                                  (double-float-low-bits tmp)))
 571                                         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 572                                         (:complex-single-float
 573                                          (logior (ash (single-float-bits (imagpart tmp)) 32)
 574                                                  (ldb (byte 32 0)
 575                                                       (single-float-bits (realpart tmp))))))))
 576                                 (res bits))
 577                            (loop for i of-type sb!vm:word from n-bits by n-bits
 578                                  until (= i sb!vm:n-word-bits)
 579                                  do (setf res (ldb (byte sb!vm:n-word-bits 0)
 580                                                    (logior res (ash bits i)))))
 581                            res))
 582                        (progn
 583                          (delay-ir1-transform node :constraint)
 584                         `(let* ((bits (ldb (byte ,n-bits 0)
 585                                            ,(ecase kind
 586                                                    (:tagged
 587                                                     `(ash item ,sb!vm:n-fixnum-tag-bits))
 588                                                    (:char
 589                                                     `(char-code item))
 590                                                    (:bits
 591                                                     `item)
 592                                                    (:single-float
 593                                                     `(single-float-bits item))
 594                                                    #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 595                                                    (:double-float
 596                                                     `(logior (ash (double-float-high-bits item) 32)
 597                                                              (double-float-low-bits item)))
 598                                                    #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 599                                                    (:complex-single-float
 600                                                     `(logior (ash (single-float-bits (imagpart item)) 32)
 601                                                              (ldb (byte 32 0)
 602                                                                   (single-float-bits (realpart item))))))))
 603                                 (res bits))
 604                            (declare (type sb!vm:word res))
 605                            ,@(unless (= sb!vm:n-word-bits n-bits)
 606                                      `((loop for i of-type sb!vm:word from ,n-bits by ,n-bits
 607                                              until (= i sb!vm:n-word-bits)
 608                                              do (setf res
 609                                                       (ldb (byte ,sb!vm:n-word-bits 0)
 610                                                            (logior res (ash bits (truly-the (integer 0 ,(- sb!vm:n-word-bits n-bits)) i))))))))
 611                            res)))))
 612              (values
 613               `(with-array-data ((data seq)
 614                                  (start start)
 615                                  (end end)
 616                                  :check-fill-pointer t)
 617                  (declare (type (simple-array ,element-type 1) data))
 618                  (declare (type index start end))
 619                  (declare (optimize (safety 0) (speed 3))
 620                           (muffle-conditions compiler-note))
 621                  (,basher ,bash-value data start (- end start))
 622                  seq)
 623               `((declare (type ,element-type item))))))
 624           ((policy node (> speed space))
 625            (values
 626             `(with-array-data ((data seq)
 627                                (start start)
 628                                (end end)
 629                                :check-fill-pointer t)
 630                (declare (type (simple-array ,element-type 1) data))
 631                (declare (type index start end))
 632                ;; WITH-ARRAY-DATA did our range checks once and for all, so
 633                ;; it'd be wasteful to check again on every AREF...
 634                (declare (optimize (safety 0) (speed 3)))
 635                (do ((i start (1+ i)))
 636                    ((= i end) seq)
 637                  (declare (type index i))
 638                  (setf (aref data i) item)))
 639             ;; ... though we still need to check that the new element can fit
 640             ;; into the vector in safe code. -- CSR, 2002-07-05
 641             `((declare (type ,element-type item)))))
 642           ((csubtypep type (specifier-type 'string))
 643            '(string-fill* seq item start end))
 644           (t
 645            '(vector-fill* seq item start end)))))
 646
 647 (deftransform fill ((seq item &key (start 0) (end nil))
 648                     ((and sequence (not vector) (not list)) t &key (:start t) (:end t)))
 649   `(sb!sequence:fill seq item
 650                      :start start
 651                      :end (%check-generic-sequence-bounds seq start end)))
 652 \f
 653 ;;;; hairy sequence transforms
 654
 655 ;;; FIXME: no hairy sequence transforms in SBCL?
 656 ;;;
 657 ;;; There used to be a bunch of commented out code about here,
 658 ;;; containing the (apparent) beginning of hairy sequence transform
 659 ;;; infrastructure. People interested in implementing better sequence
 660 ;;; transforms might want to look at it for inspiration, even though
 661 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 662 ;;; was deleted in 1.0.7.23.
 663 \f
 664 ;;;; string operations
 665
 666 ;;; We transform the case-sensitive string predicates into a non-keyword
 667 ;;; version. This is an IR1 transform so that we don't have to worry about
 668 ;;; changing the order of evaluation.
 669 (macrolet ((def (fun pred*)
 670              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 671                                                          (start2 0) end2)
 672                                    * *)
 673                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 674   (def string< string<*)
 675   (def string> string>*)
 676   (def string<= string<=*)
 677   (def string>= string>=*)
 678   (def string= string=*)
 679   (def string/= string/=*))
 680
 681 ;;; Return a form that tests the free variables STRING1 and STRING2
 682 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 683 ;;; start and end are also gotten from the environment. Both strings
 684 ;;; must be SIMPLE-BASE-STRINGs.
 685 (macrolet ((def (name lessp equalp)
 686              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 687                                    (simple-base-string simple-base-string t t t t) *)
 688                 `(let* ((end1 (if (not end1) (length string1) end1))
 689                         (end2 (if (not end2) (length string2) end2))
 690                         (index (sb!impl::%sp-string-compare
 691                                 string1 start1 end1 string2 start2 end2)))
 692                   (if index
 693                       (cond ((= index end1)
 694                              ,(if ',lessp 'index nil))
 695                             ((= (+ index (- start2 start1)) end2)
 696                              ,(if ',lessp nil 'index))
 697                             ((,(if ',lessp 'char< 'char>)
 698                                (schar string1 index)
 699                                (schar string2
 700                                       (truly-the index
 701                                                  (+ index
 702                                                     (truly-the fixnum
 703                                                                (- start2
 704                                                                   start1))))))
 705                              index)
 706                             (t nil))
 707                       ,(if ',equalp 'end1 nil))))))
 708   (def string<* t nil)
 709   (def string<=* t t)
 710   (def string>* nil nil)
 711   (def string>=* nil t))
 712
 713 (macrolet ((def (name result-fun)
 714              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 715                                    (simple-base-string simple-base-string t t t t) *)
 716                 `(,',result-fun
 717                   (sb!impl::%sp-string-compare
 718                    string1 start1 (or end1 (length string1))
 719                    string2 start2 (or end2 (length string2)))))))
 720   (def string=* not)
 721   (def string/=* identity))
 722
 723 \f
 724 ;;;; transforms for sequence functions
 725
 726 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 727 ;;; to vectors based on simple arrays.
 728 (def!constant vector-data-bit-offset
 729   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 730
 731 ;;; FIXME: In the copy loops below, we code the loops in a strange
 732 ;;; fashion:
 733 ;;;
 734 ;;; (do ((i (+ src-offset length) (1- i)))
 735 ;;;     ((<= i 0) ...)
 736 ;;;   (... (aref foo (1- i)) ...))
 737 ;;;
 738 ;;; rather than the more natural (and seemingly more efficient):
 739 ;;;
 740 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 741 ;;;     ((< i 0) ...)
 742 ;;;   (... (aref foo i) ...))
 743 ;;;
 744 ;;; (more efficient because we don't have to do the index adjusting on
 745 ;;; every iteration of the loop)
 746 ;;;
 747 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 748 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 749 ;;; when used as an array index, the backend thinks I is a
 750 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 751 ;;; these as distinct storage classes, it cannot coerce a move from a
 752 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 753 ;;; deficiency is that we have two extra moves and increased register
 754 ;;; pressure, which can lead to some spectacularly bad register
 755 ;;; allocation.  (sub-FIXME: the register allocation even with the
 756 ;;; strangely written loops is not always excellent, either...).  Doing
 757 ;;; it the first way, above, means that I is always thought of as a
 758 ;;; POSITIVE-FIXNUM and there are no issues.
 759 ;;;
 760 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 761 ;;; adjustments in the first version into the array addressing at no
 762 ;;; performance penalty!
 763
 764 ;;; This transform is critical to the performance of string streams.  If
 765 ;;; you tweak it, make sure that you compare the disassembly, if not the
 766 ;;; performance of, the functions implementing string streams
 767 ;;; (e.g. SB!IMPL::STRING-OUCH).
 768 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 769   (defun make-replace-transform (saetp sequence-type1 sequence-type2)
 770     `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 771                             (,sequence-type1 ,sequence-type2 &rest t)
 772                             ,sequence-type1
 773                             :node node)
 774        `(let* ((len1 (length seq1))
 775                (len2 (length seq2))
 776                (end1 (or end1 len1))
 777                (end2 (or end2 len2))
 778                (replace-len (min (- end1 start1) (- end2 start2))))
 779           ,(unless (policy node (= safety 0))
 780              `(progn
 781                 (unless (<= 0 start1 end1 len1)
 782                   (sequence-bounding-indices-bad-error seq1 start1 end1))
 783                 (unless (<= 0 start2 end2 len2)
 784                   (sequence-bounding-indices-bad-error seq2 start2 end2))))
 785           ,',(cond
 786                ((and saetp (sb!vm:valid-bit-bash-saetp-p saetp))
 787                 (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 788                        (bash-function (intern (format nil "UB~D-BASH-COPY"
 789                                                       n-element-bits)
 790                                               (find-package "SB!KERNEL"))))
 791                   `(funcall (function ,bash-function) seq2 start2
 792                     seq1 start1 replace-len)))
 793                (t
 794                 `(if (and
 795                       ;; If the sequence types are different, SEQ1 and
 796                       ;; SEQ2 must be distinct arrays.
 797                       ,(eql sequence-type1 sequence-type2)
 798                       (eq seq1 seq2) (> start1 start2))
 799                      (do ((i (truly-the index (+ start1 replace-len -1))
 800                              (1- i))
 801                           (j (truly-the index (+ start2 replace-len -1))
 802                              (1- j)))
 803                          ((< i start1))
 804                        (declare (optimize (insert-array-bounds-checks 0)))
 805                        (setf (aref seq1 i) (aref seq2 j)))
 806                      (do ((i start1 (1+ i))
 807                           (j start2 (1+ j))
 808                           (end (+ start1 replace-len)))
 809                          ((>= i end))
 810                        (declare (optimize (insert-array-bounds-checks 0)))
 811                        (setf (aref seq1 i) (aref seq2 j))))))
 812           seq1))))
 813
 814 (macrolet
 815     ((define-replace-transforms ()
 816        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 817              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 818              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 819              collect (make-replace-transform saetp sequence-type sequence-type)
 820              into forms
 821              finally (return `(progn ,@forms))))
 822      (define-one-transform (sequence-type1 sequence-type2)
 823        (make-replace-transform nil sequence-type1 sequence-type2)))
 824   (define-replace-transforms)
 825   #!+sb-unicode
 826   (progn
 827    (define-one-transform (simple-array base-char (*)) (simple-array character (*)))
 828    (define-one-transform (simple-array character (*)) (simple-array base-char (*)))))
 829
 830 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 831 ;;; defined as those cases where we are doing word-aligned copies from
 832 ;;; both the source and the destination and we are copying from the same
 833 ;;; offset from both the source and the destination.  (The last
 834 ;;; condition is there so we can determine the direction to copy at
 835 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 836 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 837 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 838 ;;; N)-size buffer and blitting in the old N-size buffer in.
 839
 840 (defun frob-bash-transform (src src-offset
 841                             dst dst-offset
 842                             length n-elems-per-word)
 843   (declare (ignore src dst length))
 844   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 845     (multiple-value-bind (src-word src-elt)
 846         (truncate (lvar-value src-offset) n-elems-per-word)
 847       (multiple-value-bind (dst-word dst-elt)
 848           (truncate (lvar-value dst-offset) n-elems-per-word)
 849         ;; Avoid non-word aligned copies.
 850         (unless (and (zerop src-elt) (zerop dst-elt))
 851           (give-up-ir1-transform))
 852         ;; Avoid copies where we would have to insert code for
 853         ;; determining the direction of copying.
 854         (unless (= src-word dst-word)
 855           (give-up-ir1-transform))
 856         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 857         ;; so we have to do its work here.
 858         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 859                                       'length
 860                                       `(truncate (the index length) ,n-elems-per-word)))))
 861            (declare (type index end))
 862            ;; Handle any bits at the end.
 863            (when (logtest length (1- ,n-elems-per-word))
 864              (let* ((extra (mod length ,n-elems-per-word))
 865                     ;; FIXME: The shift amount on this ASH is
 866                     ;; *always* negative, but the backend doesn't
 867                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 868                     ;; wind up with a pile of code that tests the
 869                     ;; sign of the shift count prior to shifting when
 870                     ;; all we need is a simple negate and shift
 871                     ;; right.  Yuck.
 872                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 873                                (* (- extra ,n-elems-per-word)
 874                                   ,n-bits-per-elem))))
 875                (setf (sb!kernel:%vector-raw-bits dst end)
 876                      (logior
 877                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 878                                 (ash mask
 879                                      ,(ecase sb!c:*backend-byte-order*
 880                                              (:little-endian 0)
 881                                              (:big-endian `(* (- ,n-elems-per-word extra)
 882                                                               ,n-bits-per-elem)))))
 883                       (logand (sb!kernel:%vector-raw-bits src end)
 884                               (ash mask
 885                                    ,(ecase sb!c:*backend-byte-order*
 886                                            (:little-endian 0)
 887                                            (:big-endian `(* (- ,n-elems-per-word extra)
 888                                                             ,n-bits-per-elem)))))))))
 889            ;; Copy from the end to save a register.
 890            (do ((i end (1- i)))
 891                ((<= i ,src-word))
 892              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 893                    (sb!kernel:%vector-raw-bits src (1- i))))
 894            (values))))))
 895
 896 #.(loop for i = 1 then (* i 2)
 897         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 898                                         "SB!KERNEL")
 899                                                         ((src src-offset
 900                                                           dst dst-offset
 901                                                           length)
 902                                                         ((simple-unboxed-array (*))
 903                                                          (constant-arg index)
 904                                                          (simple-unboxed-array (*))
 905                                                          (constant-arg index)
 906                                                          index)
 907                                                         *)
 908                   (frob-bash-transform src src-offset
 909                                        dst dst-offset length
 910                                        ,(truncate sb!vm:n-word-bits i))) into forms
 911         until (= i sb!vm:n-word-bits)
 912         finally (return `(progn ,@forms)))
 913
 914 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 915 ;;; arrays with elements of size >= the word size.  We do this because
 916 ;;; we know the arrays cannot alias (one was just consed), therefore we
 917 ;;; can determine at compile time the direction to copy, and for
 918 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 919 ;;; needless checking to figure out what's going on.  The same
 920 ;;; considerations apply if we are copying elements larger than the word
 921 ;;; size, with the additional twist that doing it inline is likely to
 922 ;;; cons far less than calling REPLACE and letting generic code do the
 923 ;;; work.
 924 ;;;
 925 ;;; However, we do not do this for elements whose size is < than the
 926 ;;; word size because we don't want to deal with any alignment issues
 927 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 928 ;;; anyway.
 929
 930 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 931                                       element-type)
 932   (let ((saetp (find-saetp element-type)))
 933     (aver saetp)
 934     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 935         (expand-aref-copy-loop src src-offset dst dst-offset length)
 936         `(locally (declare (optimize (safety 0)))
 937            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 938
 939 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 940   (if (eql src-offset dst-offset)
 941       `(do ((i (+ ,src-offset ,length) (1- i)))
 942            ((<= i ,src-offset))
 943          (declare (optimize (insert-array-bounds-checks 0)))
 944          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 945       ;; KLUDGE: The compiler is not able to derive that (+ offset
 946       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 947       ;; We, however, know it must be so, as by this point the bounds
 948       ;; have already been checked.
 949       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 950             (j (+ ,dst-offset ,length) (1- j)))
 951            ((<= i ,src-offset))
 952          (declare (optimize (insert-array-bounds-checks 0))
 953                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 954          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 955
 956 ;;; SUBSEQ, COPY-SEQ
 957
 958 (deftransform subseq ((seq start &optional end)
 959                       (vector t &optional t)
 960                       *
 961                       :node node)
 962   (let ((type (lvar-type seq)))
 963     (cond
 964       ((and (array-type-p type)
 965             (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 966        (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 967          `(let* ((length (length seq))
 968                  (end (or end length)))
 969             ,(unless (policy node (zerop insert-array-bounds-checks))
 970                      '(progn
 971                        (unless (<= 0 start end length)
 972                          (sequence-bounding-indices-bad-error seq start end))))
 973             (let* ((size (- end start))
 974                    (result (make-array size :element-type ',element-type)))
 975               ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
 976                                                        (lvar-value start)
 977                                                        'start)
 978                                               'result 0 'size element-type)
 979               result))))
 980       ((csubtypep type (specifier-type 'string))
 981        '(string-subseq* seq start end))
 982       (t
 983        '(vector-subseq* seq start end)))))
 984
 985 (deftransform subseq ((seq start &optional end)
 986                       (list t &optional t))
 987   `(list-subseq* seq start end))
 988
 989 (deftransform subseq ((seq start &optional end)
 990                       ((and sequence (not vector) (not list)) t &optional t))
 991   '(sb!sequence:subseq seq start end))
 992
 993 (deftransform copy-seq ((seq) (vector))
 994   (let ((type (lvar-type seq)))
 995     (cond ((and (array-type-p type)
 996                 (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 997            (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 998              `(let* ((length (length seq))
 999                      (result (make-array length :element-type ',element-type)))
1000                 ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
1001                 result)))
1002           ((csubtypep type (specifier-type 'string))
1003            '(string-subseq* seq 0 nil))
1004           (t
1005            '(vector-subseq* seq 0 nil)))))
1006
1007 (deftransform copy-seq ((seq) (list))
1008   '(list-copy-seq* seq))
1009
1010 (deftransform copy-seq ((seq) ((and sequence (not vector) (not list))))
1011   '(sb!sequence:copy-seq seq))
1012
1013 ;;; FIXME: it really should be possible to take advantage of the
1014 ;;; macros used in code/seq.lisp here to avoid duplication of code,
1015 ;;; and enable even funkier transformations.
1016 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
1017                                (test #'eql)
1018                                (key #'identity)
1019                                from-end)
1020                       (vector vector &rest t)
1021                       *
1022                       :node node
1023                       :policy (> speed (max space safety)))
1024   "open code"
1025   (let ((from-end (when (lvar-p from-end)
1026                     (unless (constant-lvar-p from-end)
1027                       (give-up-ir1-transform ":FROM-END is not constant."))
1028                     (lvar-value from-end)))
1029         (keyp (lvar-p key))
1030         (testp (lvar-p test))
1031         (check-bounds-p (policy node (plusp insert-array-bounds-checks))))
1032     `(block search
1033        (flet ((oops (vector start end)
1034                 (sequence-bounding-indices-bad-error vector start end)))
1035          (let* ((len1 (length pattern))
1036                 (len2 (length text))
1037                 (end1 (or end1 len1))
1038                 (end2 (or end2 len2))
1039                ,@(when keyp
1040                        '((key (coerce key 'function))))
1041                ,@(when testp
1042                        '((test (coerce test 'function)))))
1043           (declare (type index start1 start2 end1 end2))
1044           ,@(when check-bounds-p
1045              `((unless (<= start1 end1 len1)
1046                  (oops pattern start1 end1))
1047                (unless (<= start2 end2 len2)
1048                  (oops pattern start2 end2))))
1049           (do (,(if from-end
1050                     '(index2 (- end2 (- end1 start1)) (1- index2))
1051                     '(index2 start2 (1+ index2))))
1052               (,(if from-end
1053                     '(< index2 start2)
1054                     '(>= index2 end2))
1055                nil)
1056             ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
1057             ;; terminates is hits -1 when :FROM-END is true and :START2
1058             ;; is 0.
1059             (declare (type fixnum index2))
1060             (when (do ((index1 start1 (1+ index1))
1061                        (index2 index2 (1+ index2)))
1062                       ((>= index1 end1) t)
1063                     (declare (type index index1 index2)
1064                              (optimize (insert-array-bounds-checks 0)))
1065                     ,@(unless from-end
1066                               '((when (= index2 end2)
1067                                   (return-from search nil))))
1068                     (unless (,@(if testp
1069                                    '(funcall test)
1070                                    '(eql))
1071                                ,(if keyp
1072                                     '(funcall key (aref pattern index1))
1073                                     '(aref pattern index1))
1074                                ,(if keyp
1075                                     '(funcall key (aref text index2))
1076                                     '(aref text index2)))
1077                       (return nil)))
1078               (return index2))))))))
1079
1080
1081 ;;; Open-code CONCATENATE for strings. It would be possible to extend
1082 ;;; this transform to non-strings, but I chose to just do the case that
1083 ;;; should cover 95% of CONCATENATE performance complaints for now.
1084 ;;;   -- JES, 2007-11-17
1085 (deftransform concatenate ((result-type &rest lvars)
1086                            (symbol &rest sequence)
1087                            *
1088                            :policy (> speed space))
1089   (unless (constant-lvar-p result-type)
1090     (give-up-ir1-transform))
1091   (let* ((element-type (let ((type (lvar-value result-type)))
1092                          ;; Only handle the simple result type cases. If
1093                          ;; somebody does (CONCATENATE '(STRING 6) ...)
1094                          ;; their code won't be optimized, but nobody does
1095                          ;; that in practice.
1096                          (case type
1097                            ((string simple-string) 'character)
1098                            ((base-string simple-base-string) 'base-char)
1099                            (t (give-up-ir1-transform)))))
1100          (vars (loop for x in lvars collect (gensym)))
1101          (lvar-values (loop for lvar in lvars
1102                             collect (when (constant-lvar-p lvar)
1103                                       (lvar-value lvar))))
1104          (lengths
1105           (loop for value in lvar-values
1106                 for var in vars
1107                 collect (if value
1108                             (length value)
1109                             `(sb!impl::string-dispatch ((simple-array * (*))
1110                                                         sequence)
1111                                  ,var
1112                                (declare (muffle-conditions compiler-note))
1113                                (length ,var))))))
1114     `(apply
1115       (lambda ,vars
1116         (declare (ignorable ,@vars))
1117         (let* ((.length. (+ ,@lengths))
1118                (.pos. 0)
1119                (.string. (make-string .length. :element-type ',element-type)))
1120           (declare (type index .length. .pos.)
1121                    (muffle-conditions compiler-note))
1122           ,@(loop for value in lvar-values
1123                   for var in vars
1124                   collect (if (stringp value)
1125                               ;; Fold the array reads for constant arguments
1126                               `(progn
1127                                  ,@(loop for c across value
1128                                          collect `(setf (aref .string.
1129                                                               .pos.) ,c)
1130                                          collect `(incf .pos.)))
1131                               `(sb!impl::string-dispatch
1132                                    (#!+sb-unicode
1133                                     (simple-array character (*))
1134                                     (simple-array base-char (*))
1135                                     t)
1136                                    ,var
1137                                  (replace .string. ,var :start1 .pos.)
1138                                  (incf .pos. (length ,var)))))
1139           .string.))
1140       lvars)))
1141 \f
1142 ;;;; CONS accessor DERIVE-TYPE optimizers
1143
1144 (defoptimizer (car derive-type) ((cons))
1145   ;; This and CDR needs to use LVAR-CONSERVATIVE-TYPE because type inference
1146   ;; gets confused by things like (SETF CAR).
1147   (let ((type (lvar-conservative-type cons))
1148         (null-type (specifier-type 'null)))
1149     (cond ((eq type null-type)
1150            null-type)
1151           ((cons-type-p type)
1152            (cons-type-car-type type)))))
1153
1154 (defoptimizer (cdr derive-type) ((cons))
1155   (let ((type (lvar-conservative-type cons))
1156         (null-type (specifier-type 'null)))
1157     (cond ((eq type null-type)
1158            null-type)
1159           ((cons-type-p type)
1160            (cons-type-cdr-type type)))))
1161 \f
1162 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
1163
1164 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
1165 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
1166 ;;; expansion, so we factor out the condition into this function.
1167 (defun check-inlineability-of-find-position-if (sequence from-end)
1168   (let ((ctype (lvar-type sequence)))
1169     (cond ((csubtypep ctype (specifier-type 'vector))
1170            ;; It's not worth trying to inline vector code unless we
1171            ;; know a fair amount about it at compile time.
1172            (upgraded-element-type-specifier-or-give-up sequence)
1173            (unless (constant-lvar-p from-end)
1174              (give-up-ir1-transform
1175               "FROM-END argument value not known at compile time")))
1176           ((csubtypep ctype (specifier-type 'list))
1177            ;; Inlining on lists is generally worthwhile.
1178            )
1179           (t
1180            (give-up-ir1-transform
1181             "sequence type not known at compile time")))))
1182
1183 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
1184 (macrolet ((def (name condition)
1185              `(deftransform ,name ((predicate sequence from-end start end key)
1186                                    (function list t t t function)
1187                                    *
1188                                    :policy (> speed space))
1189                 "expand inline"
1190                 `(let ((index 0)
1191                        (find nil)
1192                        (position nil))
1193                    (declare (type index index))
1194                    (dolist (i sequence
1195                             (if (and end (> end index))
1196                                 (sequence-bounding-indices-bad-error
1197                                  sequence start end)
1198                                 (values find position)))
1199                      (when (and end (>= index end))
1200                        (return (values find position)))
1201                      (when (>= index start)
1202                        (let ((key-i (funcall key i)))
1203                          (,',condition (funcall predicate key-i)
1204                                        ;; This hack of dealing with non-NIL
1205                                        ;; FROM-END for list data by iterating
1206                                        ;; forward through the list and keeping
1207                                        ;; track of the last time we found a
1208                                        ;; match might be more screwy than what
1209                                        ;; the user expects, but it seems to be
1210                                        ;; allowed by the ANSI standard. (And
1211                                        ;; if the user is screwy enough to ask
1212                                        ;; for FROM-END behavior on list data,
1213                                        ;; turnabout is fair play.)
1214                                        ;;
1215                                        ;; It's also not enormously efficient,
1216                                        ;; calling PREDICATE and KEY more often
1217                                        ;; than necessary; but all the
1218                                        ;; alternatives seem to have their own
1219                                        ;; efficiency problems.
1220                                        (if from-end
1221                                            (setf find i
1222                                                  position index)
1223                                            (return (values i index))))))
1224                      (incf index))))))
1225   (def %find-position-if when)
1226   (def %find-position-if-not unless))
1227
1228 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
1229 ;;; without loss of efficiency. (I.e., the optimizer should be able
1230 ;;; to straighten everything out.)
1231 (deftransform %find-position ((item sequence from-end start end key test)
1232                               (t list t t t t t)
1233                               *
1234                               :policy (> speed space))
1235   "expand inline"
1236   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
1237                         ;; The order of arguments for asymmetric tests
1238                         ;; (e.g. #'<, as opposed to order-independent
1239                         ;; tests like #'=) is specified in the spec
1240                         ;; section 17.2.1 -- the O/Zi stuff there.
1241                         (lambda (i)
1242                           (funcall test-fun item i)))
1243                       sequence
1244                       from-end
1245                       start
1246                       end
1247                       (%coerce-callable-to-fun key)))
1248
1249 ;;; The inline expansions for the VECTOR case are saved as macros so
1250 ;;; that we can share them between the DEFTRANSFORMs and the default
1251 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
1252 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1253 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1254                                                             from-end
1255                                                             start
1256                                                             end-arg
1257                                                             element
1258                                                             done-p-expr)
1259   (with-unique-names (offset block index n-sequence sequence end)
1260     `(let* ((,n-sequence ,sequence-arg))
1261        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1262                          (,start ,start)
1263                          (,end ,end-arg)
1264                          :check-fill-pointer t)
1265          (block ,block
1266            (macrolet ((maybe-return ()
1267                         ;; WITH-ARRAY-DATA has already performed bounds
1268                         ;; checking, so we can safely elide the checks
1269                         ;; in the inner loop.
1270                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1271                                            (aref ,sequence ,index))))
1272                           (when ,done-p-expr
1273                             (return-from ,block
1274                               (values ,element
1275                                       (- ,index ,offset)))))))
1276              (if ,from-end
1277                  (loop for ,index
1278                        ;; (If we aren't fastidious about declaring that
1279                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1280                        ;; can send us off into never-never land, since
1281                        ;; INDEX is initialized to -1.)
1282                        of-type index-or-minus-1
1283                        from (1- ,end) downto ,start do
1284                        (maybe-return))
1285                  (loop for ,index of-type index from ,start below ,end do
1286                           (maybe-return))))
1287            (values nil nil))))))
1288
1289 (def!macro %find-position-vector-macro (item sequence
1290                                              from-end start end key test)
1291   (with-unique-names (element)
1292     (%find-position-or-find-position-if-vector-expansion
1293      sequence
1294      from-end
1295      start
1296      end
1297      element
1298      ;; (See the LIST transform for a discussion of the correct
1299      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1300      ;; or after the checked sequence element.)
1301      `(funcall ,test ,item (funcall ,key ,element)))))
1302
1303 (def!macro %find-position-if-vector-macro (predicate sequence
1304                                                      from-end start end key)
1305   (with-unique-names (element)
1306     (%find-position-or-find-position-if-vector-expansion
1307      sequence
1308      from-end
1309      start
1310      end
1311      element
1312      `(funcall ,predicate (funcall ,key ,element)))))
1313
1314 (def!macro %find-position-if-not-vector-macro (predicate sequence
1315                                                          from-end start end key)
1316   (with-unique-names (element)
1317     (%find-position-or-find-position-if-vector-expansion
1318      sequence
1319      from-end
1320      start
1321      end
1322      element
1323      `(not (funcall ,predicate (funcall ,key ,element))))))
1324
1325 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1326 ;;; VECTOR data
1327 (deftransform %find-position-if ((predicate sequence from-end start end key)
1328                                  (function vector t t t function)
1329                                  *
1330                                  :policy (> speed space))
1331   "expand inline"
1332   (check-inlineability-of-find-position-if sequence from-end)
1333   '(%find-position-if-vector-macro predicate sequence
1334                                    from-end start end key))
1335
1336 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1337                                      (function vector t t t function)
1338                                      *
1339                                      :policy (> speed space))
1340   "expand inline"
1341   (check-inlineability-of-find-position-if sequence from-end)
1342   '(%find-position-if-not-vector-macro predicate sequence
1343                                        from-end start end key))
1344
1345 (deftransform %find-position ((item sequence from-end start end key test)
1346                               (t vector t t t function function)
1347                               *
1348                               :policy (> speed space))
1349   "expand inline"
1350   (check-inlineability-of-find-position-if sequence from-end)
1351   '(%find-position-vector-macro item sequence
1352     from-end start end key test))
1353
1354 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1355 ;;; POSITION-IF, etc.
1356 (define-source-transform effective-find-position-test (test test-not)
1357   (once-only ((test test)
1358               (test-not test-not))
1359     `(cond
1360       ((and ,test ,test-not)
1361        (error "can't specify both :TEST and :TEST-NOT"))
1362       (,test (%coerce-callable-to-fun ,test))
1363       (,test-not
1364        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1365        ;; inefficient, but since the TEST-NOT option is deprecated
1366        ;; anyway, we don't care.)
1367        (complement (%coerce-callable-to-fun ,test-not)))
1368       (t #'eql))))
1369 (define-source-transform effective-find-position-key (key)
1370   (once-only ((key key))
1371     `(if ,key
1372          (%coerce-callable-to-fun ,key)
1373          #'identity)))
1374
1375 (macrolet ((define-find-position (fun-name values-index)
1376              `(deftransform ,fun-name ((item sequence &key
1377                                              from-end (start 0) end
1378                                              key test test-not)
1379                                        (t (or list vector) &rest t))
1380                 '(nth-value ,values-index
1381                             (%find-position item sequence
1382                                             from-end start
1383                                             end
1384                                             (effective-find-position-key key)
1385                                             (effective-find-position-test
1386                                              test test-not))))))
1387   (define-find-position find 0)
1388   (define-find-position position 1))
1389
1390 (macrolet ((define-find-position-if (fun-name values-index)
1391              `(deftransform ,fun-name ((predicate sequence &key
1392                                                   from-end (start 0)
1393                                                   end key)
1394                                        (t (or list vector) &rest t))
1395                 '(nth-value
1396                   ,values-index
1397                   (%find-position-if (%coerce-callable-to-fun predicate)
1398                                      sequence from-end
1399                                      start end
1400                                      (effective-find-position-key key))))))
1401   (define-find-position-if find-if 0)
1402   (define-find-position-if position-if 1))
1403
1404 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1405 ;;; didn't bother to worry about optimizing them, except note that on
1406 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1407 ;;; sbcl-devel
1408 ;;;
1409 ;;;     My understanding is that while the :test-not argument is
1410 ;;;     deprecated in favour of :test (complement #'foo) because of
1411 ;;;     semantic difficulties (what happens if both :test and :test-not
1412 ;;;     are supplied, etc) the -if-not variants, while officially
1413 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1414 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1415 ;;;     reasons for allowing the -if-not versions equal status,
1416 ;;;     particularly remove-if-not (== filter).
1417 ;;;
1418 ;;;     This is only an informal understanding, I grant you, but
1419 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1420 ;;;     way as the others?
1421 ;;;
1422 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1423 ;;; implementation of SBCL.
1424 (macrolet ((define-find-position-if-not (fun-name values-index)
1425                `(deftransform ,fun-name ((predicate sequence &key
1426                                           from-end (start 0)
1427                                           end key)
1428                                          (t (or list vector) &rest t))
1429                  '(nth-value
1430                    ,values-index
1431                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1432                     sequence from-end
1433                     start end
1434                     (effective-find-position-key key))))))
1435   (define-find-position-if-not find-if-not 0)
1436   (define-find-position-if-not position-if-not 1))
1437
1438 (macrolet ((define-trimmer-transform (fun-name leftp rightp)
1439              `(deftransform ,fun-name ((char-bag string)
1440                                        (t simple-string))
1441                 (let ((find-expr
1442                        (if (constant-lvar-p char-bag)
1443                            ;; If the bag is constant, use MEMBER
1444                            ;; instead of FIND, since we have a
1445                            ;; deftransform for MEMBER that can
1446                            ;; open-code all of the comparisons when
1447                            ;; the list is constant. -- JES, 2007-12-10
1448                            `(not (member (schar string index)
1449                                          ',(coerce (lvar-value char-bag) 'list)
1450                                          :test #'char=))
1451                            '(not (find (schar string index) char-bag :test #'char=)))))
1452                   `(flet ((char-not-in-bag (index)
1453                             ,find-expr))
1454                      (let* ((end (length string))
1455                             (left-end (if ,',leftp
1456                                           (do ((index 0 (1+ index)))
1457                                               ((or (= index (the fixnum end))
1458                                                    (char-not-in-bag index))
1459                                                index)
1460                                             (declare (fixnum index)))
1461                                           0))
1462                             (right-end (if ,',rightp
1463                                            (do ((index (1- end) (1- index)))
1464                                                ((or (< index left-end)
1465                                                     (char-not-in-bag index))
1466                                                 (1+ index))
1467                                              (declare (fixnum index)))
1468                                            end)))
1469                        (if (and (eql left-end 0)
1470                                 (eql right-end (length string)))
1471                            string
1472                            (subseq string left-end right-end))))))))
1473   (define-trimmer-transform string-left-trim t nil)
1474   (define-trimmer-transform string-right-trim nil t)
1475   (define-trimmer-transform string-trim t t))
1476