src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places))
 137     (let ((found-vector-p nil))
 138       (flet ((process-vector (length)
 139                (unless found-vector-p
 140                  (setq found-vector-p t)
 141                  (bindings `(index 0 (1+ index)))
 142                  (declarations `(type index index)))
 143                (vector-lengths length)))
 144         (loop for seq of-type lvar in seqs
 145            for seq-name in seq-names
 146            for type = (lvar-type seq)
 147            do (cond ((csubtypep type (specifier-type 'list))
 148                      (with-unique-names (index)
 149                        (bindings `(,index ,seq-name (cdr ,index)))
 150                        (declarations `(type list ,index))
 151                        (places `(car ,index))
 152                        (tests `(endp ,index))))
 153                     ((csubtypep type (specifier-type 'vector))
 154                      (process-vector `(length ,seq-name))
 155                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 156                                 (aref ,seq-name index))))
 157                     (t
 158                      (give-up-ir1-transform
 159                       "can't determine sequence argument type"))))
 160         (when into
 161           (process-vector `(array-dimension ,into 0))))
 162       (when found-vector-p
 163         (bindings `(length (min ,@(vector-lengths))))
 164         (tests `(>= index length)))
 165       `(do (,@(bindings))
 166            ((or ,@(tests)) ,result)
 167          (declare ,@(declarations))
 168          (let ((funcall-result (funcall fun ,@(places))))
 169            (declare (ignorable funcall-result))
 170            ,body)))))
 171
 172 ;;; Try to compile %MAP efficiently when we can determine sequence
 173 ;;; argument types at compile time.
 174 ;;;
 175 ;;; Note: This transform was written to allow open coding of
 176 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 177 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 178 ;;; necessarily as efficient as possible. In particular, it will be
 179 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 180 ;;; numeric element types. It should be straightforward to make it
 181 ;;; handle that case more efficiently, but it's left as an exercise to
 182 ;;; the reader, because the code is complicated enough already and I
 183 ;;; don't happen to need that functionality right now. -- WHN 20000410
 184 (deftransform %map ((result-type fun seq &rest seqs) * *
 185                     :policy (>= speed space))
 186   "open code"
 187   (unless (constant-lvar-p result-type)
 188     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 189   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 190            (fn-1subtypep (fn x y)
 191              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 192                (if valid-p
 193                    subtype-p
 194                    (give-up-ir1-transform
 195                     "can't analyze sequence type relationship"))))
 196            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 197     (let* ((result-type-value (lvar-value result-type))
 198            (result-supertype (cond ((null result-type-value) 'null)
 199                                    ((1subtypep result-type-value 'vector)
 200                                     'vector)
 201                                    ((1subtypep result-type-value 'list)
 202                                     'list)
 203                                    (t
 204                                     (give-up-ir1-transform
 205                                      "result type unsuitable")))))
 206       (cond ((and result-type-value (null seqs))
 207              ;; The consing arity-1 cases can be implemented
 208              ;; reasonably efficiently as function calls, and the cost
 209              ;; of consing should be significantly larger than
 210              ;; function call overhead, so we always compile these
 211              ;; cases as full calls regardless of speed-versus-space
 212              ;; optimization policy.
 213              (cond ((subtypep result-type-value 'list)
 214                     '(%map-to-list-arity-1 fun seq))
 215                    ( ;; (This one can be inefficient due to COERCE, but
 216                     ;; the current open-coded implementation has the
 217                     ;; same problem.)
 218                     (subtypep result-type-value 'vector)
 219                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 220                              ',result-type-value))
 221                    (t (bug "impossible (?) sequence type"))))
 222             (t
 223              (let* ((seqs (cons seq seqs))
 224                     (seq-args (make-gensym-list (length seqs))))
 225                (multiple-value-bind (push-dacc result)
 226                    (ecase result-supertype
 227                      (null (values nil nil))
 228                      (list (values `(push funcall-result acc)
 229                                    `(nreverse acc)))
 230                      (vector (values `(push funcall-result acc)
 231                                      `(coerce (nreverse acc)
 232                                               ',result-type-value))))
 233                  ;; (We use the same idiom, of returning a LAMBDA from
 234                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 235                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 236                  ;; reason: we need to get the runtime values of each
 237                  ;; of the &REST vars.)
 238                  `(lambda (result-type fun ,@seq-args)
 239                     (declare (ignore result-type))
 240                     (let ((fun (%coerce-callable-to-fun fun))
 241                           (acc nil))
 242                       (declare (type list acc))
 243                       (declare (ignorable acc))
 244                       ,(build-sequence-iterator
 245                         seqs seq-args
 246                         :result result
 247                         :body push-dacc))))))))))
 248
 249 ;;; MAP-INTO
 250 (deftransform map-into ((result fun &rest seqs)
 251                         (vector * &rest *)
 252                         *)
 253   "open code"
 254   (let ((seqs-names (mapcar (lambda (x)
 255                               (declare (ignore x))
 256                               (gensym))
 257                             seqs)))
 258     `(lambda (result fun ,@seqs-names)
 259        ,(build-sequence-iterator
 260          seqs seqs-names
 261          :result '(when (array-has-fill-pointer-p result)
 262                    (setf (fill-pointer result) index))
 263          :into 'result
 264          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 265                  (setf (aref result index) funcall-result)))
 266        result)))
 267
 268 \f
 269 ;;; FIXME: once the confusion over doing transforms with known-complex
 270 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 271 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 272 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 273   '(aref s i))
 274
 275 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 276   '(nth i s))
 277
 278 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 279   '(%aset s i v))
 280
 281 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 282   '(setf (car (nthcdr i s)) v))
 283
 284 (deftransform %check-vector-sequence-bounds ((vector start end)
 285                                              (vector * *) *
 286                                              :node node)
 287   (if (policy node (= 0 insert-array-bounds-checks))
 288       '(or end (length vector))
 289       '(let ((length (length vector)))
 290          (if (<= 0 start (or end length) length)
 291              (or end length)
 292              (sequence-bounding-indices-bad-error vector start end)))))
 293
 294 (deftype eq-comparable-type ()
 295   '(or fixnum (not number)))
 296
 297 ;;; True if EQL comparisons involving type can be simplified to EQ.
 298 (defun eq-comparable-type-p (type)
 299   (csubtypep type (specifier-type 'eq-comparable-type)))
 300
 301 (defun specialized-list-seek-function-name (function-name key-functions &optional variant)
 302   (or (find-symbol (with-output-to-string (s)
 303                      ;; Write "%NAME-FUN1-FUN2-FUN3", etc. Not only is
 304                      ;; this ever so slightly faster then FORMAT, this
 305                      ;; way we are also proof against *PRINT-CASE*
 306                      ;; frobbing and such.
 307                      (write-char #\% s)
 308                      (write-string (symbol-name function-name) s)
 309                      (dolist (f key-functions)
 310                        (write-char #\- s)
 311                        (write-string (symbol-name f) s))
 312                      (when variant
 313                        (write-char #\- s)
 314                        (write-string (symbol-name variant) s)))
 315                    (load-time-value (find-package "SB!KERNEL")))
 316       (bug "Unknown list item seek transform: name=~S, key-functions=~S variant=~S"
 317            function-name key-functions variant)))
 318
 319 (defun transform-list-item-seek (name item list key test test-not node)
 320   ;; If TEST is EQL, drop it.
 321   (when (and test (lvar-fun-is test '(eql)))
 322     (setf test nil))
 323   ;; Ditto for KEY IDENTITY.
 324   (when (and key (lvar-fun-is key '(identity)))
 325     (setf key nil))
 326   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 327   ;; not there at all. If it might be NIL, make up a form to that
 328   ;; ensures it is a function.
 329   (multiple-value-bind (key key-form)
 330       (when key
 331         (let ((key-type (lvar-type key))
 332               (null-type (specifier-type 'null)))
 333           (cond ((csubtypep key-type null-type)
 334                  (values nil nil))
 335                 ((csubtypep null-type key-type)
 336                  (values key '(if key
 337                                (%coerce-callable-to-fun key)
 338                                #'identity)))
 339                 (t
 340                  (values key (ensure-lvar-fun-form key 'key))))))
 341     (let* ((c-test (cond ((and test (lvar-fun-is test '(eq)))
 342                           (setf test nil)
 343                           'eq)
 344                          ((and (not test) (not test-not))
 345                           (when (eq-comparable-type-p (lvar-type item))
 346                             'eq))))
 347            (funs (delete nil (list (when key (list key 'key))
 348                                    (when test (list test 'test))
 349                                    (when test-not (list test-not 'test-not)))))
 350            (target-expr (if key '(%funcall key target) 'target))
 351            (test-expr (cond (test `(%funcall test item ,target-expr))
 352                             (test-not `(not (%funcall test-not item ,target-expr)))
 353                             (c-test `(,c-test item ,target-expr))
 354                             (t `(eql item ,target-expr)))))
 355       (labels ((open-code (tail)
 356                  (when tail
 357                    `(if (let ((this ',(car tail)))
 358                           ,(ecase name
 359                                   ((assoc rassoc)
 360                                    (let ((cxx (if (eq name 'assoc) 'car 'cdr)))
 361                                      `(and this (let ((target (,cxx this)))
 362                                                   ,test-expr))))
 363                                   (member
 364                                    `(let ((target this))
 365                                       ,test-expr))))
 366                         ',(ecase name
 367                                  ((assoc rassoc) (car tail))
 368                                  (member tail))
 369                         ,(open-code (cdr tail)))))
 370                (ensure-fun (args)
 371                  (if (eq 'key (second args))
 372                      key-form
 373                      (apply #'ensure-lvar-fun-form args))))
 374         (let* ((cp (constant-lvar-p list))
 375                (c-list (when cp (lvar-value list))))
 376           (cond ((and cp c-list (member name '(assoc rassoc member))
 377                       (policy node (>= speed space)))
 378                  `(let ,(mapcar (lambda (fun) `(,(second fun) ,(ensure-fun fun))) funs)
 379                     ,(open-code c-list)))
 380                 ((and cp (not c-list))
 381                  ;; constant nil list
 382                  (if (eq name 'adjoin)
 383                      '(list item)
 384                      nil))
 385                 (t
 386                  ;; specialized out-of-line version
 387                  `(,(specialized-list-seek-function-name name (mapcar #'second funs) c-test)
 388                     item list ,@(mapcar #'ensure-fun funs)))))))))
 389
 390 (defun transform-list-pred-seek (name pred list key node)
 391   ;; If KEY is IDENTITY, drop it.
 392   (when (and key (lvar-fun-is key '(identity)))
 393     (setf key nil))
 394   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 395   ;; not there at all. If it might be NIL, make up a form to that
 396   ;; ensures it is a function.
 397   (multiple-value-bind (key key-form)
 398       (when key
 399         (let ((key-type (lvar-type key))
 400               (null-type (specifier-type 'null)))
 401           (cond ((csubtypep key-type null-type)
 402                  (values nil nil))
 403                 ((csubtypep null-type key-type)
 404                  (values key '(if key
 405                                (%coerce-callable-to-fun key)
 406                                #'identity)))
 407                 (t
 408                  (values key (ensure-lvar-fun-form key 'key))))))
 409     (let ((test-expr `(%funcall pred ,(if key '(%funcall key target) 'target)))
 410           (pred-expr (ensure-lvar-fun-form pred 'pred)))
 411       (when (member name '(member-if-not assoc-if-not rassoc-if-not))
 412         (setf test-expr `(not ,test-expr)))
 413       (labels ((open-code (tail)
 414                  (when tail
 415                    `(if (let ((this ',(car tail)))
 416                           ,(ecase name
 417                                   ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 418                                    (let ((cxx (if (member name '(assoc-if assoc-if-not)) 'car 'cdr)))
 419                                      `(and this (let ((target (,cxx this)))
 420                                                   ,test-expr))))
 421                                   ((member-if member-if-not)
 422                                    `(let ((target this))
 423                                       ,test-expr))))
 424                         ',(ecase name
 425                                  ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 426                                   (car tail))
 427                                  ((member-if member-if-not)
 428                                   tail))
 429                         ,(open-code (cdr tail))))))
 430         (let* ((cp (constant-lvar-p list))
 431                (c-list (when cp (lvar-value list))))
 432           (cond ((and cp c-list (policy node (>= speed space)))
 433                  `(let ((pred ,pred-expr)
 434                         ,@(when key `((key ,key-form))))
 435                     ,(open-code c-list)))
 436                 ((and cp (not c-list))
 437                  ;; constant nil list -- nothing to find!
 438                  nil)
 439                 (t
 440                  ;; specialized out-of-line version
 441                  `(,(specialized-list-seek-function-name name (when key '(key)))
 442                     ,pred-expr list ,@(when key (list key-form))))))))))
 443
 444 (macrolet ((def (name &optional if/if-not)
 445              (let ((basic (symbolicate "%" name))
 446                    (basic-eq (symbolicate "%" name "-EQ"))
 447                    (basic-key (symbolicate "%" name "-KEY"))
 448                    (basic-key-eq (symbolicate "%" name "-KEY-EQ")))
 449                `(progn
 450                   (deftransform ,name ((item list &key key test test-not) * * :node node)
 451                     (transform-list-item-seek ',name item list key test test-not node))
 452                   (deftransform ,basic ((item list) (eq-comparable-type t))
 453                     `(,',basic-eq item list))
 454                   (deftransform ,basic-key ((item list) (eq-comparable-type t))
 455                     `(,',basic-key-eq item list))
 456                   ,@(when if/if-not
 457                           (let ((if-name (symbolicate name "-IF"))
 458                                 (if-not-name (symbolicate name "-IF-NOT")))
 459                             `((deftransform ,if-name ((pred list &key key) * * :node node)
 460                                 (transform-list-pred-seek ',if-name pred list key node))
 461                               (deftransform ,if-not-name ((pred list &key key) * * :node node)
 462                                 (transform-list-pred-seek ',if-not-name pred list key node)))))))))
 463   (def adjoin)
 464   (def assoc  t)
 465   (def member t)
 466   (def rassoc t))
 467
 468 (deftransform memq ((item list) (t (constant-arg list)))
 469   (labels ((rec (tail)
 470              (if tail
 471                  `(if (eq item ',(car tail))
 472                       ',tail
 473                       ,(rec (cdr tail)))
 474                  nil)))
 475     (rec (lvar-value list))))
 476
 477 ;;; A similar transform used to apply to MEMBER and ASSOC, but since
 478 ;;; TRANSFORM-LIST-ITEM-SEEK now takes care of them those transform
 479 ;;; would never fire, and (%MEMBER-TEST ITEM LIST #'EQ) should be
 480 ;;; almost as fast as MEMQ.
 481 (deftransform delete ((item list &key test) (t list &rest t) *)
 482   "convert to EQ test"
 483   ;; FIXME: The scope of this transformation could be
 484   ;; widened somewhat, letting it work whenever the test is
 485   ;; 'EQL and we know from the type of ITEM that it #'EQ
 486   ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 487   ;; and SYMBOL.)
 488   ;;   If TEST is EQ, apply transform, else
 489   ;;   if test is not EQL, then give up on transform, else
 490   ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 491   ;;   transform, else give up on transform.
 492   (cond (test
 493          (unless (lvar-fun-is test '(eq))
 494            (give-up-ir1-transform)))
 495         ((types-equal-or-intersect (lvar-type item)
 496                                    (specifier-type 'number))
 497          (give-up-ir1-transform "Item might be a number.")))
 498   `(delq item list))
 499
 500 (deftransform delete-if ((pred list) (t list))
 501   "open code"
 502   '(do ((x list (cdr x))
 503         (splice '()))
 504        ((endp x) list)
 505      (cond ((funcall pred (car x))
 506             (if (null splice)
 507                 (setq list (cdr x))
 508                 (rplacd splice (cdr x))))
 509            (t (setq splice x)))))
 510
 511 (deftransform fill ((seq item &key (start 0) (end nil))
 512                     (list t &key (:start t) (:end t)))
 513   '(list-fill* seq item start end))
 514
 515 (deftransform fill ((seq item &key (start 0) (end nil))
 516                     (vector t &key (:start t) (:end t))
 517                     *
 518                     :node node)
 519   (let ((type (lvar-type seq))
 520         (element-type (type-specifier (extract-upgraded-element-type seq))))
 521     (cond ((and (neq '* element-type) (policy node (> speed space)))
 522            (values
 523             `(with-array-data ((data seq)
 524                                (start start)
 525                                (end end)
 526                                :check-fill-pointer t)
 527                (declare (type (simple-array ,element-type 1) data))
 528                (declare (type index start end))
 529                ;; WITH-ARRAY-DATA did our range checks once and for all, so
 530                ;; it'd be wasteful to check again on every AREF...
 531                (declare (optimize (safety 0) (speed 3)))
 532                (do ((i start (1+ i)))
 533                    ((= i end) seq)
 534                  (declare (type index i))
 535                  (setf (aref data i) item)))
 536             ;; ... though we still need to check that the new element can fit
 537             ;; into the vector in safe code. -- CSR, 2002-07-05
 538             `((declare (type ,element-type item)))))
 539           ((csubtypep type (specifier-type 'string))
 540            '(string-fill* seq item start end))
 541           (t
 542            '(vector-fill* seq item start end)))))
 543
 544 (deftransform fill ((seq item &key (start 0) (end nil))
 545                     ((and sequence (not vector) (not list)) t &key (:start t) (:end t)))
 546   `(sb!sequence:fill seq item
 547                      :start start
 548                      :end (%check-generic-sequence-bounds seq start end)))
 549 \f
 550 ;;;; hairy sequence transforms
 551
 552 ;;; FIXME: no hairy sequence transforms in SBCL?
 553 ;;;
 554 ;;; There used to be a bunch of commented out code about here,
 555 ;;; containing the (apparent) beginning of hairy sequence transform
 556 ;;; infrastructure. People interested in implementing better sequence
 557 ;;; transforms might want to look at it for inspiration, even though
 558 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 559 ;;; was deleted in 1.0.7.23.
 560 \f
 561 ;;;; string operations
 562
 563 ;;; We transform the case-sensitive string predicates into a non-keyword
 564 ;;; version. This is an IR1 transform so that we don't have to worry about
 565 ;;; changing the order of evaluation.
 566 (macrolet ((def (fun pred*)
 567              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 568                                                          (start2 0) end2)
 569                                    * *)
 570                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 571   (def string< string<*)
 572   (def string> string>*)
 573   (def string<= string<=*)
 574   (def string>= string>=*)
 575   (def string= string=*)
 576   (def string/= string/=*))
 577
 578 ;;; Return a form that tests the free variables STRING1 and STRING2
 579 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 580 ;;; start and end are also gotten from the environment. Both strings
 581 ;;; must be SIMPLE-BASE-STRINGs.
 582 (macrolet ((def (name lessp equalp)
 583              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 584                                    (simple-base-string simple-base-string t t t t) *)
 585                 `(let* ((end1 (if (not end1) (length string1) end1))
 586                         (end2 (if (not end2) (length string2) end2))
 587                         (index (sb!impl::%sp-string-compare
 588                                 string1 start1 end1 string2 start2 end2)))
 589                   (if index
 590                       (cond ((= index end1)
 591                              ,(if ',lessp 'index nil))
 592                             ((= (+ index (- start2 start1)) end2)
 593                              ,(if ',lessp nil 'index))
 594                             ((,(if ',lessp 'char< 'char>)
 595                                (schar string1 index)
 596                                (schar string2
 597                                       (truly-the index
 598                                                  (+ index
 599                                                     (truly-the fixnum
 600                                                                (- start2
 601                                                                   start1))))))
 602                              index)
 603                             (t nil))
 604                       ,(if ',equalp 'end1 nil))))))
 605   (def string<* t nil)
 606   (def string<=* t t)
 607   (def string>* nil nil)
 608   (def string>=* nil t))
 609
 610 (macrolet ((def (name result-fun)
 611              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 612                                    (simple-base-string simple-base-string t t t t) *)
 613                 `(,',result-fun
 614                   (sb!impl::%sp-string-compare
 615                    string1 start1 (or end1 (length string1))
 616                    string2 start2 (or end2 (length string2)))))))
 617   (def string=* not)
 618   (def string/=* identity))
 619
 620 \f
 621 ;;;; transforms for sequence functions
 622
 623 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 624 ;;; to vectors based on simple arrays.
 625 (def!constant vector-data-bit-offset
 626   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 627
 628 (eval-when (:compile-toplevel)
 629 (defun valid-bit-bash-saetp-p (saetp)
 630   ;; BIT-BASHing isn't allowed on simple vectors that contain pointers
 631   (and (not (eq t (sb!vm:saetp-specifier saetp)))
 632        ;; Disallowing (VECTOR NIL) also means that we won't transform
 633        ;; sequence functions into bit-bashing code and we let the
 634        ;; generic sequence functions signal errors if necessary.
 635        (not (zerop (sb!vm:saetp-n-bits saetp)))
 636        ;; Due to limitations with the current BIT-BASHing code, we can't
 637        ;; BIT-BASH reliably on arrays whose element types are larger
 638        ;; than the word size.
 639        (<= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)))
 640 ) ; EVAL-WHEN
 641
 642 ;;; FIXME: In the copy loops below, we code the loops in a strange
 643 ;;; fashion:
 644 ;;;
 645 ;;; (do ((i (+ src-offset length) (1- i)))
 646 ;;;     ((<= i 0) ...)
 647 ;;;   (... (aref foo (1- i)) ...))
 648 ;;;
 649 ;;; rather than the more natural (and seemingly more efficient):
 650 ;;;
 651 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 652 ;;;     ((< i 0) ...)
 653 ;;;   (... (aref foo i) ...))
 654 ;;;
 655 ;;; (more efficient because we don't have to do the index adjusting on
 656 ;;; every iteration of the loop)
 657 ;;;
 658 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 659 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 660 ;;; when used as an array index, the backend thinks I is a
 661 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 662 ;;; these as distinct storage classes, it cannot coerce a move from a
 663 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 664 ;;; deficiency is that we have two extra moves and increased register
 665 ;;; pressure, which can lead to some spectacularly bad register
 666 ;;; allocation.  (sub-FIXME: the register allocation even with the
 667 ;;; strangely written loops is not always excellent, either...).  Doing
 668 ;;; it the first way, above, means that I is always thought of as a
 669 ;;; POSITIVE-FIXNUM and there are no issues.
 670 ;;;
 671 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 672 ;;; adjustments in the first version into the array addressing at no
 673 ;;; performance penalty!
 674
 675 ;;; This transform is critical to the performance of string streams.  If
 676 ;;; you tweak it, make sure that you compare the disassembly, if not the
 677 ;;; performance of, the functions implementing string streams
 678 ;;; (e.g. SB!IMPL::STRING-OUCH).
 679 (eval-when (:compile-toplevel :load-toplevel :execute)
 680   (defun make-replace-transform (saetp sequence-type1 sequence-type2)
 681     `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 682                             (,sequence-type1 ,sequence-type2 &rest t)
 683                             ,sequence-type1
 684                             :node node)
 685        `(let* ((len1 (length seq1))
 686                (len2 (length seq2))
 687                (end1 (or end1 len1))
 688                (end2 (or end2 len2))
 689                (replace-len (min (- end1 start1) (- end2 start2))))
 690           ,(unless (policy node (= safety 0))
 691              `(progn
 692                 (unless (<= 0 start1 end1 len1)
 693                   (sequence-bounding-indices-bad-error seq1 start1 end1))
 694                 (unless (<= 0 start2 end2 len2)
 695                   (sequence-bounding-indices-bad-error seq2 start2 end2))))
 696           ,',(cond
 697                ((and saetp (valid-bit-bash-saetp-p saetp))
 698                 (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 699                        (bash-function (intern (format nil "UB~D-BASH-COPY"
 700                                                       n-element-bits)
 701                                               (find-package "SB!KERNEL"))))
 702                   `(funcall (function ,bash-function) seq2 start2
 703                     seq1 start1 replace-len)))
 704                (t
 705                 `(if (and
 706                       ;; If the sequence types are different, SEQ1 and
 707                       ;; SEQ2 must be distinct arrays.
 708                       ,(eql sequence-type1 sequence-type2)
 709                       (eq seq1 seq2) (> start1 start2))
 710                      (do ((i (truly-the index (+ start1 replace-len -1))
 711                              (1- i))
 712                           (j (truly-the index (+ start2 replace-len -1))
 713                              (1- j)))
 714                          ((< i start1))
 715                        (declare (optimize (insert-array-bounds-checks 0)))
 716                        (setf (aref seq1 i) (aref seq2 j)))
 717                      (do ((i start1 (1+ i))
 718                           (j start2 (1+ j))
 719                           (end (+ start1 replace-len)))
 720                          ((>= i end))
 721                        (declare (optimize (insert-array-bounds-checks 0)))
 722                        (setf (aref seq1 i) (aref seq2 j))))))
 723           seq1))))
 724
 725 (macrolet
 726     ((define-replace-transforms ()
 727        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 728              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 729              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 730              collect (make-replace-transform saetp sequence-type sequence-type)
 731              into forms
 732              finally (return `(progn ,@forms))))
 733      (define-one-transform (sequence-type1 sequence-type2)
 734        (make-replace-transform nil sequence-type1 sequence-type2)))
 735   (define-replace-transforms)
 736   #!+sb-unicode
 737   (progn
 738    (define-one-transform (simple-array base-char (*)) (simple-array character (*)))
 739    (define-one-transform (simple-array character (*)) (simple-array base-char (*)))))
 740
 741 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 742 ;;; defined as those cases where we are doing word-aligned copies from
 743 ;;; both the source and the destination and we are copying from the same
 744 ;;; offset from both the source and the destination.  (The last
 745 ;;; condition is there so we can determine the direction to copy at
 746 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 747 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 748 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 749 ;;; N)-size buffer and blitting in the old N-size buffer in.
 750
 751 (defun frob-bash-transform (src src-offset
 752                             dst dst-offset
 753                             length n-elems-per-word)
 754   (declare (ignore src dst length))
 755   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 756     (multiple-value-bind (src-word src-elt)
 757         (truncate (lvar-value src-offset) n-elems-per-word)
 758       (multiple-value-bind (dst-word dst-elt)
 759           (truncate (lvar-value dst-offset) n-elems-per-word)
 760         ;; Avoid non-word aligned copies.
 761         (unless (and (zerop src-elt) (zerop dst-elt))
 762           (give-up-ir1-transform))
 763         ;; Avoid copies where we would have to insert code for
 764         ;; determining the direction of copying.
 765         (unless (= src-word dst-word)
 766           (give-up-ir1-transform))
 767         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 768         ;; so we have to do its work here.
 769         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 770                                       'length
 771                                       `(truncate (the index length) ,n-elems-per-word)))))
 772            (declare (type index end))
 773            ;; Handle any bits at the end.
 774            (when (logtest length (1- ,n-elems-per-word))
 775              (let* ((extra (mod length ,n-elems-per-word))
 776                     ;; FIXME: The shift amount on this ASH is
 777                     ;; *always* negative, but the backend doesn't
 778                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 779                     ;; wind up with a pile of code that tests the
 780                     ;; sign of the shift count prior to shifting when
 781                     ;; all we need is a simple negate and shift
 782                     ;; right.  Yuck.
 783                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 784                                (* (- extra ,n-elems-per-word)
 785                                   ,n-bits-per-elem))))
 786                (setf (sb!kernel:%vector-raw-bits dst end)
 787                      (logior
 788                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 789                                 (ash mask
 790                                      ,(ecase sb!c:*backend-byte-order*
 791                                              (:little-endian 0)
 792                                              (:big-endian `(* (- ,n-elems-per-word extra)
 793                                                               ,n-bits-per-elem)))))
 794                       (logand (sb!kernel:%vector-raw-bits src end)
 795                               (ash mask
 796                                    ,(ecase sb!c:*backend-byte-order*
 797                                            (:little-endian 0)
 798                                            (:big-endian `(* (- ,n-elems-per-word extra)
 799                                                             ,n-bits-per-elem)))))))))
 800            ;; Copy from the end to save a register.
 801            (do ((i end (1- i)))
 802                ((<= i ,src-word))
 803              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 804                    (sb!kernel:%vector-raw-bits src (1- i))))
 805            (values))))))
 806
 807 #.(loop for i = 1 then (* i 2)
 808         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 809                                         "SB!KERNEL")
 810                                                         ((src src-offset
 811                                                           dst dst-offset
 812                                                           length)
 813                                                         ((simple-unboxed-array (*))
 814                                                          (constant-arg index)
 815                                                          (simple-unboxed-array (*))
 816                                                          (constant-arg index)
 817                                                          index)
 818                                                         *)
 819                   (frob-bash-transform src src-offset
 820                                        dst dst-offset length
 821                                        ,(truncate sb!vm:n-word-bits i))) into forms
 822         until (= i sb!vm:n-word-bits)
 823         finally (return `(progn ,@forms)))
 824
 825 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 826 ;;; arrays with elements of size >= the word size.  We do this because
 827 ;;; we know the arrays cannot alias (one was just consed), therefore we
 828 ;;; can determine at compile time the direction to copy, and for
 829 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 830 ;;; needless checking to figure out what's going on.  The same
 831 ;;; considerations apply if we are copying elements larger than the word
 832 ;;; size, with the additional twist that doing it inline is likely to
 833 ;;; cons far less than calling REPLACE and letting generic code do the
 834 ;;; work.
 835 ;;;
 836 ;;; However, we do not do this for elements whose size is < than the
 837 ;;; word size because we don't want to deal with any alignment issues
 838 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 839 ;;; anyway.
 840
 841 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 842                                       element-type)
 843   (let ((saetp (find-saetp element-type)))
 844     (aver saetp)
 845     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 846         (expand-aref-copy-loop src src-offset dst dst-offset length)
 847         `(locally (declare (optimize (safety 0)))
 848            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 849
 850 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 851   (if (eql src-offset dst-offset)
 852       `(do ((i (+ ,src-offset ,length) (1- i)))
 853            ((<= i ,src-offset))
 854          (declare (optimize (insert-array-bounds-checks 0)))
 855          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 856       ;; KLUDGE: The compiler is not able to derive that (+ offset
 857       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 858       ;; We, however, know it must be so, as by this point the bounds
 859       ;; have already been checked.
 860       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 861             (j (+ ,dst-offset ,length) (1- j)))
 862            ((<= i ,src-offset))
 863          (declare (optimize (insert-array-bounds-checks 0))
 864                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 865          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 866
 867 ;;; SUBSEQ, COPY-SEQ
 868
 869 (deftransform subseq ((seq start &optional end)
 870                       (vector t &optional t)
 871                       *
 872                       :node node)
 873   (let ((type (lvar-type seq)))
 874     (cond
 875       ((and (array-type-p type)
 876             (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 877        (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 878          `(let* ((length (length seq))
 879                  (end (or end length)))
 880             ,(unless (policy node (zerop insert-array-bounds-checks))
 881                      '(progn
 882                        (unless (<= 0 start end length)
 883                          (sequence-bounding-indices-bad-error seq start end))))
 884             (let* ((size (- end start))
 885                    (result (make-array size :element-type ',element-type)))
 886               ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
 887                                                        (lvar-value start)
 888                                                        'start)
 889                                               'result 0 'size element-type)
 890               result))))
 891       ((csubtypep type (specifier-type 'string))
 892        '(string-subseq* seq start end))
 893       (t
 894        '(vector-subseq* seq start end)))))
 895
 896 (deftransform subseq ((seq start &optional end)
 897                       (list t &optional t))
 898   `(list-subseq* seq start end))
 899
 900 (deftransform subseq ((seq start &optional end)
 901                       ((and sequence (not vector) (not list)) t &optional t))
 902   '(sb!sequence:subseq seq start end))
 903
 904 (deftransform copy-seq ((seq) (vector))
 905   (let ((type (lvar-type seq)))
 906     (cond ((and (array-type-p type)
 907                 (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 908            (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 909              `(let* ((length (length seq))
 910                      (result (make-array length :element-type ',element-type)))
 911                 ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
 912                 result)))
 913           ((csubtypep type (specifier-type 'string))
 914            '(string-subseq* seq 0 nil))
 915           (t
 916            '(vector-subseq* seq 0 nil)))))
 917
 918 (deftransform copy-seq ((seq) (list))
 919   '(list-copy-seq* seq))
 920
 921 (deftransform copy-seq ((seq) ((and sequence (not vector) (not list))))
 922   '(sb!sequence:copy-seq seq))
 923
 924 ;;; FIXME: it really should be possible to take advantage of the
 925 ;;; macros used in code/seq.lisp here to avoid duplication of code,
 926 ;;; and enable even funkier transformations.
 927 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
 928                                (test #'eql)
 929                                (key #'identity)
 930                                from-end)
 931                       (vector vector &rest t)
 932                       *
 933                       :node node
 934                       :policy (> speed (max space safety)))
 935   "open code"
 936   (let ((from-end (when (lvar-p from-end)
 937                     (unless (constant-lvar-p from-end)
 938                       (give-up-ir1-transform ":FROM-END is not constant."))
 939                     (lvar-value from-end)))
 940         (keyp (lvar-p key))
 941         (testp (lvar-p test))
 942         (check-bounds-p (policy node (plusp insert-array-bounds-checks))))
 943     `(block search
 944        (flet ((oops (vector start end)
 945                 (sequence-bounding-indices-bad-error vector start end)))
 946          (let* ((len1 (length pattern))
 947                 (len2 (length text))
 948                 (end1 (or end1 len1))
 949                 (end2 (or end2 len2))
 950                ,@(when keyp
 951                        '((key (coerce key 'function))))
 952                ,@(when testp
 953                        '((test (coerce test 'function)))))
 954           (declare (type index start1 start2 end1 end2))
 955           ,@(when check-bounds-p
 956              `((unless (<= start1 end1 len1)
 957                  (oops pattern start1 end1))
 958                (unless (<= start2 end2 len2)
 959                  (oops pattern start2 end2))))
 960           (do (,(if from-end
 961                     '(index2 (- end2 (- end1 start1)) (1- index2))
 962                     '(index2 start2 (1+ index2))))
 963               (,(if from-end
 964                     '(< index2 start2)
 965                     '(>= index2 end2))
 966                nil)
 967             ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
 968             ;; terminates is hits -1 when :FROM-END is true and :START2
 969             ;; is 0.
 970             (declare (type fixnum index2))
 971             (when (do ((index1 start1 (1+ index1))
 972                        (index2 index2 (1+ index2)))
 973                       ((>= index1 end1) t)
 974                     (declare (type index index1 index2)
 975                              (optimize (insert-array-bounds-checks 0)))
 976                     ,@(unless from-end
 977                               '((when (= index2 end2)
 978                                   (return-from search nil))))
 979                     (unless (,@(if testp
 980                                    '(funcall test)
 981                                    '(eql))
 982                                ,(if keyp
 983                                     '(funcall key (aref pattern index1))
 984                                     '(aref pattern index1))
 985                                ,(if keyp
 986                                     '(funcall key (aref text index2))
 987                                     '(aref text index2)))
 988                       (return nil)))
 989               (return index2))))))))
 990
 991
 992 ;;; Open-code CONCATENATE for strings. It would be possible to extend
 993 ;;; this transform to non-strings, but I chose to just do the case that
 994 ;;; should cover 95% of CONCATENATE performance complaints for now.
 995 ;;;   -- JES, 2007-11-17
 996 (deftransform concatenate ((result-type &rest lvars)
 997                            (symbol &rest sequence)
 998                            *
 999                            :policy (> speed space))
1000   (unless (constant-lvar-p result-type)
1001     (give-up-ir1-transform))
1002   (let* ((element-type (let ((type (lvar-value result-type)))
1003                          ;; Only handle the simple result type cases. If
1004                          ;; somebody does (CONCATENATE '(STRING 6) ...)
1005                          ;; their code won't be optimized, but nobody does
1006                          ;; that in practice.
1007                          (case type
1008                            ((string simple-string) 'character)
1009                            ((base-string simple-base-string) 'base-char)
1010                            (t (give-up-ir1-transform)))))
1011          (vars (loop for x in lvars collect (gensym)))
1012          (lvar-values (loop for lvar in lvars
1013                             collect (when (constant-lvar-p lvar)
1014                                       (lvar-value lvar))))
1015          (lengths
1016           (loop for value in lvar-values
1017                 for var in vars
1018                 collect (if value
1019                             (length value)
1020                             `(sb!impl::string-dispatch ((simple-array * (*))
1021                                                         sequence)
1022                                  ,var
1023                                (declare (muffle-conditions compiler-note))
1024                                (length ,var))))))
1025     `(apply
1026       (lambda ,vars
1027         (declare (ignorable ,@vars))
1028         (let* ((.length. (+ ,@lengths))
1029                (.pos. 0)
1030                (.string. (make-string .length. :element-type ',element-type)))
1031           (declare (type index .length. .pos.)
1032                    (muffle-conditions compiler-note))
1033           ,@(loop for value in lvar-values
1034                   for var in vars
1035                   collect (if (stringp value)
1036                               ;; Fold the array reads for constant arguments
1037                               `(progn
1038                                  ,@(loop for c across value
1039                                          collect `(setf (aref .string.
1040                                                               .pos.) ,c)
1041                                          collect `(incf .pos.)))
1042                               `(sb!impl::string-dispatch
1043                                    (#!+sb-unicode
1044                                     (simple-array character (*))
1045                                     (simple-array base-char (*))
1046                                     t)
1047                                    ,var
1048                                  (replace .string. ,var :start1 .pos.)
1049                                  (incf .pos. (length ,var)))))
1050           .string.))
1051       lvars)))
1052 \f
1053 ;;;; CONS accessor DERIVE-TYPE optimizers
1054
1055 (defoptimizer (car derive-type) ((cons))
1056   (let ((type (lvar-type cons))
1057         (null-type (specifier-type 'null)))
1058     (cond ((eq type null-type)
1059            null-type)
1060           ((cons-type-p type)
1061            (cons-type-car-type type)))))
1062
1063 (defoptimizer (cdr derive-type) ((cons))
1064   (let ((type (lvar-type cons))
1065         (null-type (specifier-type 'null)))
1066     (cond ((eq type null-type)
1067            null-type)
1068           ((cons-type-p type)
1069            (cons-type-cdr-type type)))))
1070 \f
1071 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
1072
1073 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
1074 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
1075 ;;; expansion, so we factor out the condition into this function.
1076 (defun check-inlineability-of-find-position-if (sequence from-end)
1077   (let ((ctype (lvar-type sequence)))
1078     (cond ((csubtypep ctype (specifier-type 'vector))
1079            ;; It's not worth trying to inline vector code unless we
1080            ;; know a fair amount about it at compile time.
1081            (upgraded-element-type-specifier-or-give-up sequence)
1082            (unless (constant-lvar-p from-end)
1083              (give-up-ir1-transform
1084               "FROM-END argument value not known at compile time")))
1085           ((csubtypep ctype (specifier-type 'list))
1086            ;; Inlining on lists is generally worthwhile.
1087            )
1088           (t
1089            (give-up-ir1-transform
1090             "sequence type not known at compile time")))))
1091
1092 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
1093 (macrolet ((def (name condition)
1094              `(deftransform ,name ((predicate sequence from-end start end key)
1095                                    (function list t t t function)
1096                                    *
1097                                    :policy (> speed space))
1098                 "expand inline"
1099                 `(let ((index 0)
1100                        (find nil)
1101                        (position nil))
1102                    (declare (type index index))
1103                    (dolist (i sequence
1104                             (if (and end (> end index))
1105                                 (sequence-bounding-indices-bad-error
1106                                  sequence start end)
1107                                 (values find position)))
1108                      (when (and end (>= index end))
1109                        (return (values find position)))
1110                      (when (>= index start)
1111                        (let ((key-i (funcall key i)))
1112                          (,',condition (funcall predicate key-i)
1113                                        ;; This hack of dealing with non-NIL
1114                                        ;; FROM-END for list data by iterating
1115                                        ;; forward through the list and keeping
1116                                        ;; track of the last time we found a
1117                                        ;; match might be more screwy than what
1118                                        ;; the user expects, but it seems to be
1119                                        ;; allowed by the ANSI standard. (And
1120                                        ;; if the user is screwy enough to ask
1121                                        ;; for FROM-END behavior on list data,
1122                                        ;; turnabout is fair play.)
1123                                        ;;
1124                                        ;; It's also not enormously efficient,
1125                                        ;; calling PREDICATE and KEY more often
1126                                        ;; than necessary; but all the
1127                                        ;; alternatives seem to have their own
1128                                        ;; efficiency problems.
1129                                        (if from-end
1130                                            (setf find i
1131                                                  position index)
1132                                            (return (values i index))))))
1133                      (incf index))))))
1134   (def %find-position-if when)
1135   (def %find-position-if-not unless))
1136
1137 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
1138 ;;; without loss of efficiency. (I.e., the optimizer should be able
1139 ;;; to straighten everything out.)
1140 (deftransform %find-position ((item sequence from-end start end key test)
1141                               (t list t t t t t)
1142                               *
1143                               :policy (> speed space))
1144   "expand inline"
1145   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
1146                         ;; The order of arguments for asymmetric tests
1147                         ;; (e.g. #'<, as opposed to order-independent
1148                         ;; tests like #'=) is specified in the spec
1149                         ;; section 17.2.1 -- the O/Zi stuff there.
1150                         (lambda (i)
1151                           (funcall test-fun item i)))
1152                       sequence
1153                       from-end
1154                       start
1155                       end
1156                       (%coerce-callable-to-fun key)))
1157
1158 ;;; The inline expansions for the VECTOR case are saved as macros so
1159 ;;; that we can share them between the DEFTRANSFORMs and the default
1160 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
1161 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1162 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1163                                                             from-end
1164                                                             start
1165                                                             end-arg
1166                                                             element
1167                                                             done-p-expr)
1168   (with-unique-names (offset block index n-sequence sequence end)
1169     `(let* ((,n-sequence ,sequence-arg))
1170        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1171                          (,start ,start)
1172                          (,end ,end-arg)
1173                          :check-fill-pointer t)
1174          (block ,block
1175            (macrolet ((maybe-return ()
1176                         ;; WITH-ARRAY-DATA has already performed bounds
1177                         ;; checking, so we can safely elide the checks
1178                         ;; in the inner loop.
1179                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1180                                            (aref ,sequence ,index))))
1181                           (when ,done-p-expr
1182                             (return-from ,block
1183                               (values ,element
1184                                       (- ,index ,offset)))))))
1185              (if ,from-end
1186                  (loop for ,index
1187                        ;; (If we aren't fastidious about declaring that
1188                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1189                        ;; can send us off into never-never land, since
1190                        ;; INDEX is initialized to -1.)
1191                        of-type index-or-minus-1
1192                        from (1- ,end) downto ,start do
1193                        (maybe-return))
1194                  (loop for ,index of-type index from ,start below ,end do
1195                           (maybe-return))))
1196            (values nil nil))))))
1197
1198 (def!macro %find-position-vector-macro (item sequence
1199                                              from-end start end key test)
1200   (with-unique-names (element)
1201     (%find-position-or-find-position-if-vector-expansion
1202      sequence
1203      from-end
1204      start
1205      end
1206      element
1207      ;; (See the LIST transform for a discussion of the correct
1208      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1209      ;; or after the checked sequence element.)
1210      `(funcall ,test ,item (funcall ,key ,element)))))
1211
1212 (def!macro %find-position-if-vector-macro (predicate sequence
1213                                                      from-end start end key)
1214   (with-unique-names (element)
1215     (%find-position-or-find-position-if-vector-expansion
1216      sequence
1217      from-end
1218      start
1219      end
1220      element
1221      `(funcall ,predicate (funcall ,key ,element)))))
1222
1223 (def!macro %find-position-if-not-vector-macro (predicate sequence
1224                                                          from-end start end key)
1225   (with-unique-names (element)
1226     (%find-position-or-find-position-if-vector-expansion
1227      sequence
1228      from-end
1229      start
1230      end
1231      element
1232      `(not (funcall ,predicate (funcall ,key ,element))))))
1233
1234 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1235 ;;; VECTOR data
1236 (deftransform %find-position-if ((predicate sequence from-end start end key)
1237                                  (function vector t t t function)
1238                                  *
1239                                  :policy (> speed space))
1240   "expand inline"
1241   (check-inlineability-of-find-position-if sequence from-end)
1242   '(%find-position-if-vector-macro predicate sequence
1243                                    from-end start end key))
1244
1245 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1246                                      (function vector t t t function)
1247                                      *
1248                                      :policy (> speed space))
1249   "expand inline"
1250   (check-inlineability-of-find-position-if sequence from-end)
1251   '(%find-position-if-not-vector-macro predicate sequence
1252                                        from-end start end key))
1253
1254 (deftransform %find-position ((item sequence from-end start end key test)
1255                               (t vector t t t function function)
1256                               *
1257                               :policy (> speed space))
1258   "expand inline"
1259   (check-inlineability-of-find-position-if sequence from-end)
1260   '(%find-position-vector-macro item sequence
1261     from-end start end key test))
1262
1263 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1264 ;;; POSITION-IF, etc.
1265 (define-source-transform effective-find-position-test (test test-not)
1266   (once-only ((test test)
1267               (test-not test-not))
1268     `(cond
1269       ((and ,test ,test-not)
1270        (error "can't specify both :TEST and :TEST-NOT"))
1271       (,test (%coerce-callable-to-fun ,test))
1272       (,test-not
1273        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1274        ;; inefficient, but since the TEST-NOT option is deprecated
1275        ;; anyway, we don't care.)
1276        (complement (%coerce-callable-to-fun ,test-not)))
1277       (t #'eql))))
1278 (define-source-transform effective-find-position-key (key)
1279   (once-only ((key key))
1280     `(if ,key
1281          (%coerce-callable-to-fun ,key)
1282          #'identity)))
1283
1284 (macrolet ((define-find-position (fun-name values-index)
1285              `(deftransform ,fun-name ((item sequence &key
1286                                              from-end (start 0) end
1287                                              key test test-not)
1288                                        (t (or list vector) &rest t))
1289                 '(nth-value ,values-index
1290                             (%find-position item sequence
1291                                             from-end start
1292                                             end
1293                                             (effective-find-position-key key)
1294                                             (effective-find-position-test
1295                                              test test-not))))))
1296   (define-find-position find 0)
1297   (define-find-position position 1))
1298
1299 (macrolet ((define-find-position-if (fun-name values-index)
1300              `(deftransform ,fun-name ((predicate sequence &key
1301                                                   from-end (start 0)
1302                                                   end key)
1303                                        (t (or list vector) &rest t))
1304                 '(nth-value
1305                   ,values-index
1306                   (%find-position-if (%coerce-callable-to-fun predicate)
1307                                      sequence from-end
1308                                      start end
1309                                      (effective-find-position-key key))))))
1310   (define-find-position-if find-if 0)
1311   (define-find-position-if position-if 1))
1312
1313 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1314 ;;; didn't bother to worry about optimizing them, except note that on
1315 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1316 ;;; sbcl-devel
1317 ;;;
1318 ;;;     My understanding is that while the :test-not argument is
1319 ;;;     deprecated in favour of :test (complement #'foo) because of
1320 ;;;     semantic difficulties (what happens if both :test and :test-not
1321 ;;;     are supplied, etc) the -if-not variants, while officially
1322 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1323 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1324 ;;;     reasons for allowing the -if-not versions equal status,
1325 ;;;     particularly remove-if-not (== filter).
1326 ;;;
1327 ;;;     This is only an informal understanding, I grant you, but
1328 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1329 ;;;     way as the others?
1330 ;;;
1331 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1332 ;;; implementation of SBCL.
1333 (macrolet ((define-find-position-if-not (fun-name values-index)
1334                `(deftransform ,fun-name ((predicate sequence &key
1335                                           from-end (start 0)
1336                                           end key)
1337                                          (t (or list vector) &rest t))
1338                  '(nth-value
1339                    ,values-index
1340                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1341                     sequence from-end
1342                     start end
1343                     (effective-find-position-key key))))))
1344   (define-find-position-if-not find-if-not 0)
1345   (define-find-position-if-not position-if-not 1))
1346
1347 (macrolet ((define-trimmer-transform (fun-name leftp rightp)
1348              `(deftransform ,fun-name ((char-bag string)
1349                                        (t simple-string))
1350                 (let ((find-expr
1351                        (if (constant-lvar-p char-bag)
1352                            ;; If the bag is constant, use MEMBER
1353                            ;; instead of FIND, since we have a
1354                            ;; deftransform for MEMBER that can
1355                            ;; open-code all of the comparisons when
1356                            ;; the list is constant. -- JES, 2007-12-10
1357                            `(not (member (schar string index)
1358                                          ',(coerce (lvar-value char-bag) 'list)
1359                                          :test #'char=))
1360                            '(not (find (schar string index) char-bag :test #'char=)))))
1361                   `(flet ((char-not-in-bag (index)
1362                             ,find-expr))
1363                      (let* ((end (length string))
1364                             (left-end (if ,',leftp
1365                                           (do ((index 0 (1+ index)))
1366                                               ((or (= index (the fixnum end))
1367                                                    (char-not-in-bag index))
1368                                                index)
1369                                             (declare (fixnum index)))
1370                                           0))
1371                             (right-end (if ,',rightp
1372                                            (do ((index (1- end) (1- index)))
1373                                                ((or (< index left-end)
1374                                                     (char-not-in-bag index))
1375                                                 (1+ index))
1376                                              (declare (fixnum index)))
1377                                            end)))
1378                        (if (and (eql left-end 0)
1379                                 (eql right-end (length string)))
1380                            string
1381                            (subseq string left-end right-end))))))))
1382   (define-trimmer-transform string-left-trim t nil)
1383   (define-trimmer-transform string-right-trim nil t)
1384   (define-trimmer-transform string-trim t t))
1385