src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let ((call `(funcall ,fn . ,(args-to-fn)))
  30             (endtest `(or ,@(tests))))
  31         (ecase accumulate
  32           (:nconc
  33            (let ((temp (gensym))
  34                  (map-result (gensym)))
  35              `(let ((,map-result (list nil)))
  36                 (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  37                               (,endtest (cdr ,map-result))
  38                   (setq ,temp (last (nconc ,temp ,call)))))))
  39           (:list
  40            (let ((temp (gensym))
  41                  (map-result (gensym)))
  42              `(let ((,map-result (list nil)))
  43                 (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  44                               (,endtest (cdr ,map-result))
  45                   (rplacd ,temp (setq ,temp (list ,call)))))))
  46           ((nil)
  47            `(let ((,n-first ,(first arglists)))
  48               (do-anonymous ,(do-clauses)
  49                             (,endtest ,n-first) ,call))))))))
  50
  51 (define-source-transform mapc (function list &rest more-lists)
  52   (mapfoo-transform function (cons list more-lists) nil t))
  53
  54 (define-source-transform mapcar (function list &rest more-lists)
  55   (mapfoo-transform function (cons list more-lists) :list t))
  56
  57 (define-source-transform mapcan (function list &rest more-lists)
  58   (mapfoo-transform function (cons list more-lists) :nconc t))
  59
  60 (define-source-transform mapl (function list &rest more-lists)
  61   (mapfoo-transform function (cons list more-lists) nil nil))
  62
  63 (define-source-transform maplist (function list &rest more-lists)
  64   (mapfoo-transform function (cons list more-lists) :list nil))
  65
  66 (define-source-transform mapcon (function list &rest more-lists)
  67   (mapfoo-transform function (cons list more-lists) :nconc nil))
  68 \f
  69 ;;;; mapping onto sequences: the MAP function
  70
  71 ;;; MAP is %MAP plus a check to make sure that any length specified in
  72 ;;; the result type matches the actual result. We also wrap it in a
  73 ;;; TRULY-THE for the most specific type we can determine.
  74 (deftransform map ((result-type-arg fun &rest seqs) * * :node node)
  75   (let* ((seq-names (make-gensym-list (length seqs)))
  76          (bare `(%map result-type-arg fun ,@seq-names))
  77          (constant-result-type-arg-p (constant-continuation-p result-type-arg))
  78          ;; what we know about the type of the result. (Note that the
  79          ;; "result type" argument is not necessarily the type of the
  80          ;; result, since NIL means the result has NULL type.)
  81          (result-type (if (not constant-result-type-arg-p)
  82                           'consed-sequence
  83                           (let ((result-type-arg-value
  84                                  (continuation-value result-type-arg)))
  85                             (if (null result-type-arg-value)
  86                                 'null
  87                                 result-type-arg-value)))))
  88     `(lambda (result-type-arg fun ,@seq-names)
  89        (truly-the ,result-type
  90          ,(cond ((policy node (> speed safety))
  91                  bare)
  92                 ((not constant-result-type-arg-p)
  93                  `(sequence-of-checked-length-given-type ,bare
  94                                                          result-type-arg))
  95                 (t
  96                  (let ((result-ctype (specifier-type result-type)))
  97                    (if (array-type-p result-ctype)
  98                        (let* ((dims (array-type-dimensions result-ctype))
  99                               (dim (first dims)))
 100                          (if (eq dim '*)
 101                              bare
 102                              `(vector-of-checked-length-given-length ,bare
 103                                                                      ,dim)))
 104                        bare))))))))
 105
 106 ;;; Try to compile %MAP efficiently when we can determine sequence
 107 ;;; argument types at compile time.
 108 ;;;
 109 ;;; Note: This transform was written to allow open coding of
 110 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 111 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 112 ;;; necessarily as efficient as possible. In particular, it will be
 113 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 114 ;;; numeric element types. It should be straightforward to make it
 115 ;;; handle that case more efficiently, but it's left as an exercise to
 116 ;;; the reader, because the code is complicated enough already and I
 117 ;;; don't happen to need that functionality right now. -- WHN 20000410
 118 (deftransform %map ((result-type fun &rest seqs) * * :policy (>= speed space))
 119   "open code"
 120   (unless seqs (abort-ir1-transform "no sequence args"))
 121   (unless (constant-continuation-p result-type)
 122     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 123   (labels (;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 124            (fn-1subtypep (fn x y)
 125              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 126                (if valid-p
 127                    subtype-p
 128                    (give-up-ir1-transform
 129                     "can't analyze sequence type relationship"))))
 130            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y))
 131            (1csubtypep (x y) (fn-1subtypep #'csubtypep x y))
 132            (seq-supertype (seq)
 133              (let ((ctype (continuation-type seq)))
 134                (cond ((1csubtypep ctype (specifier-type 'vector)) 'vector)
 135                      ((1csubtypep ctype (specifier-type 'list)) 'list)
 136                      (t
 137                       (give-up-ir1-transform
 138                        "can't determine sequence argument type"))))))
 139     (let* ((result-type-value (continuation-value result-type))
 140            (result-supertype (cond ((null result-type-value) 'null)
 141                                    ((1subtypep result-type-value 'vector)
 142                                     'vector)
 143                                    ((1subtypep result-type-value 'list)
 144                                     'list)
 145                                    (t
 146                                     (give-up-ir1-transform
 147                                      "can't determine result type"))))
 148            (seq-supertypes (mapcar #'seq-supertype seqs)))
 149       (cond ((and result-type-value (= 1 (length seqs)))
 150              ;; The consing arity-1 cases can be implemented
 151              ;; reasonably efficiently as function calls, and the cost
 152              ;; of consing should be significantly larger than
 153              ;; function call overhead, so we always compile these
 154              ;; cases as full calls regardless of speed-versus-space
 155              ;; optimization policy.
 156              (cond ((subtypep 'list result-type-value)
 157                     '(apply #'%map-to-list-arity-1 fun seqs))
 158                    (;; (This one can be inefficient due to COERCE, but
 159                     ;; the current open-coded implementation has the
 160                     ;; same problem.)
 161                     (subtypep result-type-value 'vector)
 162                     `(coerce (apply #'%map-to-simple-vector-arity-1 fun seqs)
 163                              ',result-type-value))
 164                    (t (bug "impossible (?) sequence type"))))
 165             (t
 166              (let* ((seq-args (make-gensym-list (length seqs)))
 167                     (index-bindingoids
 168                      (mapcar (lambda (seq-arg seq-supertype)
 169                                (let ((i (gensym "I")))
 170                                  (ecase seq-supertype
 171                                    (vector `(,i 0 (1+ ,i)))
 172                                    (list `(,i ,seq-arg (rest ,i))))))
 173                              seq-args seq-supertypes))
 174                     (indices (mapcar #'first index-bindingoids))
 175                     (index-decls (mapcar (lambda (index seq-supertype)
 176                                            `(type ,(ecase seq-supertype
 177                                                      (vector 'index)
 178                                                      (list 'list))
 179                                                   ,index))
 180                                          indices seq-supertypes))
 181                     (tests (mapcar (lambda (seq-arg seq-supertype index)
 182                                      (ecase seq-supertype
 183                                        (vector `(>= ,index (length ,seq-arg)))
 184                                        (list `(endp ,index))))
 185                                    seq-args seq-supertypes indices))
 186                     (values (mapcar (lambda (seq-arg seq-supertype index)
 187                                       (ecase seq-supertype
 188                                         (vector `(aref ,seq-arg ,index))
 189                                         (list `(first ,index))))
 190                                     seq-args seq-supertypes indices)))
 191                (multiple-value-bind (push-dacc final-result)
 192                    (ecase result-supertype
 193                      (null (values nil nil))
 194                      (list (values `(push dacc acc) `(nreverse acc)))
 195                      (vector (values `(push dacc acc)
 196                                      `(coerce (nreverse acc)
 197                                               ',result-type-value))))
 198                  ;; (We use the same idiom, of returning a LAMBDA from
 199                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 200                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 201                  ;; reason: we need to get the runtime values of each
 202                  ;; of the &REST vars.)
 203                  `(lambda (result-type fun ,@seq-args)
 204                     (declare (ignore result-type))
 205                     (do ((really-fun (%coerce-callable-to-fun fun))
 206                          ,@index-bindingoids
 207                          (acc nil))
 208                     ((or ,@tests)
 209                      ,final-result)
 210                     (declare ,@index-decls)
 211                     (declare (type list acc))
 212                     (declare (ignorable acc))
 213                     (let ((dacc (funcall really-fun ,@values)))
 214                       (declare (ignorable dacc))
 215                       ,push-dacc))))))))))
 216 \f
 217 (deftransform elt ((s i) ((simple-array * (*)) *) * :when :both)
 218   '(aref s i))
 219
 220 (deftransform elt ((s i) (list *) * :when :both)
 221   '(nth i s))
 222
 223 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) * :when :both)
 224   '(%aset s i v))
 225
 226 (deftransform %setelt ((s i v) (list * *))
 227   '(setf (car (nthcdr i s)) v))
 228
 229 (macrolet ((def (name)
 230              `(deftransform ,name ((e l &key (test #'eql)) * *
 231                                    :node node :when :both)
 232                 (unless (constant-continuation-p l)
 233                   (give-up-ir1-transform))
 234
 235                 (let ((val (continuation-value l)))
 236                   (unless (policy node
 237                                   (or (= speed 3)
 238                                       (and (>= speed space)
 239                                            (<= (length val) 5))))
 240                     (give-up-ir1-transform))
 241
 242                   (labels ((frob (els)
 243                              (if els
 244                                  `(if (funcall test e ',(car els))
 245                                       ',els
 246                                       ,(frob (cdr els)))
 247                                  nil)))
 248                     (frob val))))))
 249   (def member)
 250   (def memq))
 251
 252 ;;; FIXME: We have rewritten the original code that used DOLIST to this
 253 ;;; more natural MACROLET.  However, the original code suggested that when
 254 ;;; this was done, a few bytes could be saved by a call to a shared
 255 ;;; function.  This remains to be done.
 256 (macrolet ((def (fun eq-fun)
 257              `(deftransform ,fun ((item list &key test) (t list &rest t) *)
 258                 "convert to EQ test"
 259                 ;; FIXME: The scope of this transformation could be
 260                 ;; widened somewhat, letting it work whenever the test is
 261                 ;; 'EQL and we know from the type of ITEM that it #'EQ
 262                 ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 263                 ;; and SYMBOL.)
 264                 ;;   If TEST is EQ, apply transform, else
 265                 ;;   if test is not EQL, then give up on transform, else
 266                 ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 267                 ;;   transform, else give up on transform.
 268                 (cond (test
 269                        (unless (continuation-fun-is test '(eq))
 270                          (give-up-ir1-transform)))
 271                       ((types-equal-or-intersect (continuation-type item)
 272                                                  (specifier-type 'number))
 273                        (give-up-ir1-transform "Item might be a number.")))
 274                 `(,',eq-fun item list))))
 275   (def delete delq)
 276   (def assoc assq)
 277   (def member memq))
 278
 279 (deftransform delete-if ((pred list) (t list))
 280   "open code"
 281   '(do ((x list (cdr x))
 282         (splice '()))
 283        ((endp x) list)
 284      (cond ((funcall pred (car x))
 285             (if (null splice)
 286                 (setq list (cdr x))
 287                 (rplacd splice (cdr x))))
 288            (T (setq splice x)))))
 289
 290 (deftransform fill ((seq item &key (start 0) (end (length seq)))
 291                     (vector t &key (:start t) (:end index))
 292                     *
 293                     :policy (> speed space))
 294   "open code"
 295   (let ((element-type (upgraded-element-type-specifier-or-give-up seq)))
 296     `(with-array-data ((data seq)
 297                        (start start)
 298                        (end end))
 299        (declare (type (simple-array ,element-type 1) data))
 300        (do ((i start (1+ i)))
 301            ((= i end) seq)
 302          (declare (type index i))
 303          ;; WITH-ARRAY-DATA did our range checks once and for all, so
 304          ;; it'd be wasteful to check again on every AREF.
 305          (declare (optimize (safety 0)))
 306          (setf (aref data i) item)))))
 307 \f
 308 ;;;; utilities
 309
 310 ;;; Return true if CONT's only use is a non-NOTINLINE reference to a
 311 ;;; global function with one of the specified NAMES.
 312 (defun continuation-fun-is (cont names)
 313   (declare (type continuation cont) (list names))
 314   (let ((use (continuation-use cont)))
 315     (and (ref-p use)
 316          (let ((leaf (ref-leaf use)))
 317            (and (global-var-p leaf)
 318                 (eq (global-var-kind leaf) :global-function)
 319                 (not (null (member (leaf-source-name leaf) names
 320                                    :test #'equal))))))))
 321
 322 ;;; If CONT is a constant continuation, the return the constant value.
 323 ;;; If it is null, then return default, otherwise quietly give up the
 324 ;;; IR1 transform.
 325 ;;;
 326 ;;; ### Probably should take an ARG and flame using the NAME.
 327 (defun constant-value-or-lose (cont &optional default)
 328   (declare (type (or continuation null) cont))
 329   (cond ((not cont) default)
 330         ((constant-continuation-p cont)
 331          (continuation-value cont))
 332         (t
 333          (give-up-ir1-transform))))
 334
 335 ;;; FIXME: Why is this code commented out? (Why *was* it commented
 336 ;;; out? We inherited this situation from cmucl-2.4.8, with no
 337 ;;; explanation.) Should we just delete this code?
 338 #|
 339 ;;; This is a frob whose job it is to make it easier to pass around
 340 ;;; the arguments to IR1 transforms. It bundles together the name of
 341 ;;; the argument (which should be referenced in any expansion), and
 342 ;;; the continuation for that argument (or NIL if unsupplied.)
 343 (defstruct (arg (:constructor %make-arg (name cont))
 344                 (:copier nil))
 345   (name nil :type symbol)
 346   (cont nil :type (or continuation null)))
 347 (defmacro make-arg (name)
 348   `(%make-arg ',name ,name))
 349
 350 ;;; If Arg is null or its CONT is null, then return Default, otherwise
 351 ;;; return Arg's NAME.
 352 (defun default-arg (arg default)
 353   (declare (type (or arg null) arg))
 354   (if (and arg (arg-cont arg))
 355       (arg-name arg)
 356       default))
 357
 358 ;;; If Arg is null or has no CONT, return the default. Otherwise, Arg's
 359 ;;; CONT must be a constant continuation whose value we return. If not, we
 360 ;;; give up.
 361 (defun arg-constant-value (arg default)
 362   (declare (type (or arg null) arg))
 363   (if (and arg (arg-cont arg))
 364       (let ((cont (arg-cont arg)))
 365         (unless (constant-continuation-p cont)
 366           (give-up-ir1-transform "Argument is not constant: ~S."
 367                                  (arg-name arg)))
 368         (continuation-value from-end))
 369       default))
 370
 371 ;;; If Arg is a constant and is EQL to X, then return T, otherwise NIL. If
 372 ;;; Arg is NIL or its CONT is NIL, then compare to the default.
 373 (defun arg-eql (arg default x)
 374   (declare (type (or arg null) x))
 375   (if (and arg (arg-cont arg))
 376       (let ((cont (arg-cont arg)))
 377         (and (constant-continuation-p cont)
 378              (eql (continuation-value cont) x)))
 379       (eql default x)))
 380
 381 (defstruct (iterator (:copier nil))
 382   ;; The kind of iterator.
 383   (kind nil (member :normal :result))
 384   ;; A list of LET* bindings to create the initial state.
 385   (binds nil :type list)
 386   ;; A list of declarations for Binds.
 387   (decls nil :type list)
 388   ;; A form that returns the current value. This may be set with SETF to set
 389   ;; the current value.
 390   (current (error "Must specify CURRENT."))
 391   ;; In a :Normal iterator, a form that tests whether there is a current value.
 392   (done nil)
 393   ;; In a :Result iterator, a form that truncates the result at the current
 394   ;; position and returns it.
 395   (result nil)
 396   ;; A form that returns the initial total number of values. The result is
 397   ;; undefined after NEXT has been evaluated.
 398   (length (error "Must specify LENGTH."))
 399   ;; A form that advances the state to the next value. It is an error to call
 400   ;; this when the iterator is Done.
 401   (next (error "Must specify NEXT.")))
 402
 403 ;;; Type of an index var that can go negative (in the from-end case.)
 404 (deftype neg-index ()
 405   `(integer -1 ,most-positive-fixnum))
 406
 407 ;;; Return an ITERATOR structure describing how to iterate over an arbitrary
 408 ;;; sequence. Sequence is a variable bound to the sequence, and Type is the
 409 ;;; type of the sequence. If true, INDEX is a variable that should be bound to
 410 ;;; the index of the current element in the sequence.
 411 ;;;
 412 ;;; If we can't tell whether the sequence is a list or a vector, or whether
 413 ;;; the iteration is forward or backward, then GIVE-UP.
 414 (defun make-sequence-iterator (sequence type &key start end from-end index)
 415   (declare (symbol sequence) (type ctype type)
 416            (type (or arg null) start end from-end)
 417            (type (or symbol null) index))
 418   (let ((from-end (arg-constant-value from-end nil)))
 419     (cond ((csubtypep type (specifier-type 'vector))
 420            (let* ((n-stop (gensym))
 421                   (n-idx (or index (gensym)))
 422                   (start (default-arg 0 start))
 423                   (end (default-arg `(length ,sequence) end)))
 424              (make-iterator
 425               :kind :normal
 426               :binds `((,n-idx ,(if from-end `(1- ,end) ,start))
 427                        (,n-stop ,(if from-end `(1- ,start) ,end)))
 428               :decls `((type neg-index ,n-idx ,n-stop))
 429               :current `(aref ,sequence ,n-idx)
 430               :done `(,(if from-end '<= '>=) ,n-idx ,n-stop)
 431               :next `(setq ,n-idx
 432                            ,(if from-end `(1- ,n-idx) `(1+ ,n-idx)))
 433               :length (if from-end
 434                           `(- ,n-idx ,n-stop)
 435                           `(- ,n-stop ,n-idx)))))
 436           ((csubtypep type (specifier-type 'list))
 437            (let* ((n-stop (if (and end (not from-end)) (gensym) nil))
 438                   (n-current (gensym))
 439                   (start-p (not (arg-eql start 0 0)))
 440                   (end-p (not (arg-eql end nil nil)))
 441                   (start (default-arg start 0))
 442                   (end (default-arg end nil)))
 443              (make-iterator
 444               :binds `((,n-current
 445                         ,(if from-end
 446                              (if (or start-p end-p)
 447                                  `(nreverse (subseq ,sequence ,start
 448                                                     ,@(when end `(,end))))
 449                                  `(reverse ,sequence))
 450                              (if start-p
 451                                  `(nthcdr ,start ,sequence)
 452                                  sequence)))
 453                        ,@(when n-stop
 454                            `((,n-stop (nthcdr (the index
 455                                                    (- ,end ,start))
 456                                               ,n-current))))
 457                        ,@(when index
 458                            `((,index ,(if from-end `(1- ,end) start)))))
 459               :kind :normal
 460               :decls `((list ,n-current ,n-end)
 461                        ,@(when index `((type neg-index ,index))))
 462               :current `(car ,n-current)
 463               :done `(eq ,n-current ,n-stop)
 464               :length `(- ,(or end `(length ,sequence)) ,start)
 465               :next `(progn
 466                        (setq ,n-current (cdr ,n-current))
 467                        ,@(when index
 468                            `((setq ,n-idx
 469                                    ,(if from-end
 470                                         `(1- ,index)
 471                                         `(1+ ,index)))))))))
 472           (t
 473            (give-up-ir1-transform
 474             "can't tell whether sequence is a list or a vector")))))
 475
 476 ;;; Make an iterator used for constructing result sequences. Name is a
 477 ;;; variable to be bound to the result sequence. Type is the type of result
 478 ;;; sequence to make. Length is an expression to be evaluated to get the
 479 ;;; maximum length of the result (not evaluated in list case.)
 480 (defun make-result-sequence-iterator (name type length)
 481   (declare (symbol name) (type ctype type))
 482
 483 ;;; Define each NAME as a local macro that will call the value of the
 484 ;;; function arg with the given arguments. If the argument isn't known to be a
 485 ;;; function, give them an efficiency note and reference a coerced version.
 486 (defmacro coerce-funs (specs &body body)
 487   #!+sb-doc
 488   "COERCE-FUNCTIONS ({(Name Fun-Arg Default)}*) Form*"
 489   (collect ((binds)
 490             (defs))
 491     (dolist (spec specs)
 492       `(let ((body (progn ,@body))
 493              (n-fun (arg-name ,(second spec)))
 494              (fun-cont (arg-cont ,(second spec))))
 495          (cond ((not fun-cont)
 496                 `(macrolet ((,',(first spec) (&rest args)
 497                              `(,',',(third spec) ,@args)))
 498                    ,body))
 499                ((not (csubtypep (continuation-type fun-cont)
 500                                 (specifier-type 'function)))
 501                 (when (policy *compiler-error-context*
 502                               (> speed inhibit-warnings))
 503                   (compiler-note
 504                    "~S may not be a function, so must coerce at run-time."
 505                    n-fun))
 506                 (once-only ((n-fun `(if (functionp ,n-fun)
 507                                         ,n-fun
 508                                         (symbol-function ,n-fun))))
 509                   `(macrolet ((,',(first spec) (&rest args)
 510                                `(funcall ,',n-fun ,@args)))
 511                      ,body)))
 512                (t
 513                 `(macrolet ((,',(first spec) (&rest args)
 514                               `(funcall ,',n-fun ,@args)))
 515                    ,body)))))))
 516
 517 ;;; Wrap code around the result of the body to define Name as a local macro
 518 ;;; that returns true when its arguments satisfy the test according to the Args
 519 ;;; Test and Test-Not. If both Test and Test-Not are supplied, abort the
 520 ;;; transform.
 521 (defmacro with-sequence-test ((name test test-not) &body body)
 522   `(let ((not-p (arg-cont ,test-not)))
 523      (when (and (arg-cont ,test) not-p)
 524        (abort-ir1-transform "Both ~S and ~S were supplied."
 525                             (arg-name ,test)
 526                             (arg-name ,test-not)))
 527      (coerce-funs ((,name (if not-p ,test-not ,test) eql))
 528        ,@body)))
 529 |#
 530 \f
 531 ;;;; hairy sequence transforms
 532
 533 ;;; FIXME: no hairy sequence transforms in SBCL?
 534 \f
 535 ;;;; string operations
 536
 537 ;;; We transform the case-sensitive string predicates into a non-keyword
 538 ;;; version. This is an IR1 transform so that we don't have to worry about
 539 ;;; changing the order of evaluation.
 540 (macrolet ((def (fun pred*)
 541              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 542                                                          (start2 0) end2)
 543                                    * *)
 544                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 545   (def string< string<*)
 546   (def string> string>*)
 547   (def string<= string<=*)
 548   (def string>= string>=*)
 549   (def string= string=*)
 550   (def string/= string/=*))
 551
 552 ;;; Return a form that tests the free variables STRING1 and STRING2
 553 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 554 ;;; start and end are also gotten from the environment. Both strings
 555 ;;; must be SIMPLE-STRINGs.
 556 (macrolet ((def (name lessp equalp)
 557              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 558                                     (simple-string simple-string t t t t) *)
 559                 `(let* ((end1 (if (not end1) (length string1) end1))
 560                         (end2 (if (not end2) (length string2) end2))
 561                         (index (sb!impl::%sp-string-compare
 562                                 string1 start1 end1 string2 start2 end2)))
 563                   (if index
 564                       (cond ((= index ,(if ',lessp 'end1 'end2)) index)
 565                             ((= index ,(if ',lessp 'end2 'end1)) nil)
 566                             ((,(if ',lessp 'char< 'char>)
 567                                (schar string1 index)
 568                                (schar string2
 569                                       (truly-the index
 570                                                  (+ index
 571                                                     (truly-the fixnum
 572                                                                (- start2
 573                                                                   start1))))))
 574                              index)
 575                             (t nil))
 576                       ,(if ',equalp 'end1 nil))))))
 577   (def string<* t nil)
 578   (def string<=* t t)
 579   (def string>* nil nil)
 580   (def string>=* nil t))
 581
 582 (macrolet ((def (name result-fun)
 583              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 584                                    (simple-string simple-string t t t t) *)
 585                 `(,',result-fun
 586                   (sb!impl::%sp-string-compare
 587                    string1 start1 (or end1 (length string1))
 588                    string2 start2 (or end2 (length string2)))))))
 589   (def string=* not)
 590   (def string/=* identity))
 591
 592 \f
 593 ;;;; string-only transforms for sequence functions
 594 ;;;;
 595 ;;;; Note: CMU CL had more of these, including transforms for
 596 ;;;; functions which cons. In SBCL, we've gotten rid of most of the
 597 ;;;; transforms for functions which cons, since our GC overhead is
 598 ;;;; sufficiently large that it doesn't seem worth it to try to
 599 ;;;; economize on function call overhead or on the overhead of runtime
 600 ;;;; type dispatch in AREF. The exception is CONCATENATE, since
 601 ;;;; a full call to CONCATENATE would have to look up the sequence
 602 ;;;; type, which can be really slow.
 603 ;;;;
 604 ;;;; FIXME: It would be nicer for these transforms to work for any
 605 ;;;; calls when all arguments are vectors with the same element type,
 606 ;;;; rather than restricting them to STRINGs only.
 607
 608 ;;; FIXME: Shouldn't we be testing for legality of
 609 ;;;   * START1, START2, END1, and END2 indices?
 610 ;;;   * size of copied string relative to destination string?
 611 ;;; (Either there should be tests conditional on SAFETY>=SPEED, or
 612 ;;; the transform should be conditional on SPEED>SAFETY.)
 613 ;;;
 614 ;;; FIXME: Also, the transform should probably be dependent on
 615 ;;; SPEED>SPACE.
 616 (deftransform replace ((string1 string2 &key (start1 0) (start2 0)
 617                                 end1 end2)
 618                        (simple-string simple-string &rest t))
 619   `(locally
 620      (declare (optimize (safety 0)))
 621      (bit-bash-copy string2
 622                     (the index
 623                          (+ (the index (* start2 sb!vm:n-byte-bits))
 624                             ,vector-data-bit-offset))
 625                     string1
 626                     (the index
 627                          (+ (the index (* start1 sb!vm:n-byte-bits))
 628                             ,vector-data-bit-offset))
 629                     (the index
 630                          (* (min (the index (- (or end1 (length string1))
 631                                                start1))
 632                                  (the index (- (or end2 (length string2))
 633                                                start2)))
 634                             sb!vm:n-byte-bits)))
 635      string1))
 636
 637 ;;; FIXME: It seems as though it should be possible to make a DEFUN
 638 ;;; %CONCATENATE (with a DEFTRANSFORM to translate constant RTYPE to
 639 ;;; CTYPE before calling %CONCATENATE) which is comparably efficient,
 640 ;;; at least once DYNAMIC-EXTENT works.
 641 (deftransform concatenate ((rtype &rest sequences)
 642                            (t &rest simple-string)
 643                            simple-string)
 644   (collect ((lets)
 645             (forms)
 646             (all-lengths)
 647             (args))
 648     (dolist (seq sequences)
 649       (declare (ignore seq))
 650       (let ((n-seq (gensym))
 651             (n-length (gensym)))
 652         (args n-seq)
 653         (lets `(,n-length (the index (* (length ,n-seq) sb!vm:n-byte-bits))))
 654         (all-lengths n-length)
 655         (forms `(bit-bash-copy ,n-seq ,vector-data-bit-offset
 656                                res start
 657                                ,n-length))
 658         (forms `(setq start (+ start ,n-length)))))
 659     `(lambda (rtype ,@(args))
 660        (declare (ignore rtype))
 661        (let* (,@(lets)
 662               (res (make-string (truncate (the index (+ ,@(all-lengths)))
 663                                           sb!vm:n-byte-bits)))
 664               (start ,vector-data-bit-offset))
 665          (declare (type index start ,@(all-lengths)))
 666          ,@(forms)
 667          res))))
 668 \f
 669 ;;;; CONS accessor DERIVE-TYPE optimizers
 670
 671 (defoptimizer (car derive-type) ((cons))
 672   (let ((type (continuation-type cons))
 673         (null-type (specifier-type 'null)))
 674     (cond ((eq type null-type)
 675            null-type)
 676           ((cons-type-p type)
 677            (cons-type-car-type type)))))
 678
 679 (defoptimizer (cdr derive-type) ((cons))
 680   (let ((type (continuation-type cons))
 681         (null-type (specifier-type 'null)))
 682     (cond ((eq type null-type)
 683            null-type)
 684           ((cons-type-p type)
 685            (cons-type-cdr-type type)))))
 686 \f
 687 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
 688
 689 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
 690 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
 691 ;;; expansion, so we factor out the condition into this function.
 692 (defun check-inlineability-of-find-position-if (sequence from-end)
 693   (let ((ctype (continuation-type sequence)))
 694     (cond ((csubtypep ctype (specifier-type 'vector))
 695            ;; It's not worth trying to inline vector code unless we
 696            ;; know a fair amount about it at compile time.
 697            (upgraded-element-type-specifier-or-give-up sequence)
 698            (unless (constant-continuation-p from-end)
 699              (give-up-ir1-transform
 700               "FROM-END argument value not known at compile time")))
 701           ((csubtypep ctype (specifier-type 'list))
 702            ;; Inlining on lists is generally worthwhile.
 703            )
 704           (t
 705            (give-up-ir1-transform
 706             "sequence type not known at compile time")))))
 707
 708 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
 709 (macrolet ((def (name condition)
 710              `(deftransform ,name ((predicate sequence from-end start end key)
 711                                    (function list t t t function)
 712                                    *
 713                                    :policy (> speed space)
 714                                    :important t)
 715                 "expand inline"
 716                 `(let ((index 0)
 717                        (find nil)
 718                        (position nil))
 719                    (declare (type index index))
 720                    (dolist (i sequence (values find position))
 721                      (let ((key-i (funcall key i)))
 722                        (when (and end (>= index end))
 723                          (return (values find position)))
 724                        (when (>= index start)
 725                          (,',condition (funcall predicate key-i)
 726                           ;; This hack of dealing with non-NIL
 727                           ;; FROM-END for list data by iterating
 728                           ;; forward through the list and keeping
 729                           ;; track of the last time we found a match
 730                           ;; might be more screwy than what the user
 731                           ;; expects, but it seems to be allowed by
 732                           ;; the ANSI standard. (And if the user is
 733                           ;; screwy enough to ask for FROM-END
 734                           ;; behavior on list data, turnabout is
 735                           ;; fair play.)
 736                           ;;
 737                           ;; It's also not enormously efficient,
 738                           ;; calling PREDICATE and KEY more often
 739                           ;; than necessary; but all the
 740                           ;; alternatives seem to have their own
 741                           ;; efficiency problems.
 742                           (if from-end
 743                               (setf find i
 744                                     position index)
 745                               (return (values i index))))))
 746                      (incf index))))))
 747   (def %find-position-if when)
 748   (def %find-position-if-not unless))
 749
 750 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
 751 ;;; without loss of efficiency. (I.e., the optimizer should be able
 752 ;;; to straighten everything out.)
 753 (deftransform %find-position ((item sequence from-end start end key test)
 754                               (t list t t t t t)
 755                               *
 756                               :policy (> speed space)
 757                               :important t)
 758   "expand inline"
 759   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
 760                         ;; I'm having difficulty believing I'm
 761                         ;; reading it right, but as far as I can see,
 762                         ;; the only guidance that ANSI gives for the
 763                         ;; order of arguments to asymmetric tests is
 764                         ;; the character-set dependent example from
 765                         ;; the definition of FIND,
 766                         ;;   (find #\d "here are some.." :test #'char>)
 767                         ;;     => #\Space
 768                         ;; (In ASCII, we have (CHAR> #\d #\SPACE)=>T.)
 769                         ;; (Neither the POSITION definition page nor
 770                         ;; section 17.2 ("Rules about Test Functions")
 771                         ;; seem to consider the possibility of
 772                         ;; asymmetry.)
 773                         ;;
 774                         ;; So, judging from the example, we want to
 775                         ;; do (FUNCALL TEST-FUN ITEM I), because
 776                         ;; (FUNCALL #'CHAR> #\d #\SPACE)=>T.
 777                         ;;
 778                         ;; -- WHN (whose attention was drawn to it by
 779                         ;;         Alexey Dejneka's bug report/fix)
 780                         (lambda (i)
 781                           (funcall test-fun item i)))
 782                       sequence
 783                       from-end
 784                       start
 785                       end
 786                       (%coerce-callable-to-fun key)))
 787
 788 ;;; The inline expansions for the VECTOR case are saved as macros so
 789 ;;; that we can share them between the DEFTRANSFORMs and the default
 790 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
 791 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
 792 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
 793                                                             from-end
 794                                                             start
 795                                                             end-arg
 796                                                             element
 797                                                             done-p-expr)
 798   (let ((offset (gensym "OFFSET"))
 799         (block (gensym "BLOCK"))
 800         (index (gensym "INDEX"))
 801         (n-sequence (gensym "N-SEQUENCE-"))
 802         (sequence (gensym "SEQUENCE"))
 803         (n-end (gensym "N-END-"))
 804         (end (gensym "END-")))
 805     `(let ((,n-sequence ,sequence-arg)
 806            (,n-end ,end-arg))
 807        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
 808                          (,start ,start)
 809                          (,end (or ,n-end (length ,n-sequence))))
 810          (block ,block
 811            (macrolet ((maybe-return ()
 812                         '(let ((,element (aref ,sequence ,index)))
 813                            (when ,done-p-expr
 814                              (return-from ,block
 815                                (values ,element
 816                                        (- ,index ,offset)))))))
 817              (if ,from-end
 818                  (loop for ,index
 819                        ;; (If we aren't fastidious about declaring that
 820                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
 821                        ;; can send us off into never-never land, since
 822                        ;; INDEX is initialized to -1.)
 823                        of-type index-or-minus-1
 824                        from (1- ,end) downto ,start do
 825                        (maybe-return))
 826                  (loop for ,index of-type index from ,start below ,end do
 827                        (maybe-return))))
 828            (values nil nil))))))
 829
 830 (def!macro %find-position-vector-macro (item sequence
 831                                              from-end start end key test)
 832   (let ((element (gensym "ELEMENT")))
 833     (%find-position-or-find-position-if-vector-expansion
 834      sequence
 835      from-end
 836      start
 837      end
 838      element
 839      ;; (See the LIST transform for a discussion of the correct
 840      ;; argument order, i.e. whether the searched-for ,ITEM goes before
 841      ;; or after the checked sequence element.)
 842      `(funcall ,test ,item (funcall ,key ,element)))))
 843
 844 (def!macro %find-position-if-vector-macro (predicate sequence
 845                                                      from-end start end key)
 846   (let ((element (gensym "ELEMENT")))
 847     (%find-position-or-find-position-if-vector-expansion
 848      sequence
 849      from-end
 850      start
 851      end
 852      element
 853      `(funcall ,predicate (funcall ,key ,element)))))
 854
 855 (def!macro %find-position-if-not-vector-macro (predicate sequence
 856                                                          from-end start end key)
 857   (let ((element (gensym "ELEMENT")))
 858     (%find-position-or-find-position-if-vector-expansion
 859      sequence
 860      from-end
 861      start
 862      end
 863      element
 864      `(not (funcall ,predicate (funcall ,key ,element))))))
 865
 866 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
 867 ;;; VECTOR data
 868 (deftransform %find-position-if ((predicate sequence from-end start end key)
 869                                  (function vector t t t function)
 870                                  *
 871                                  :policy (> speed space)
 872                                  :important t)
 873   "expand inline"
 874   (check-inlineability-of-find-position-if sequence from-end)
 875   '(%find-position-if-vector-macro predicate sequence
 876                                    from-end start end key))
 877
 878 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
 879                                      (function vector t t t function)
 880                                      *
 881                                      :policy (> speed space)
 882                                      :important t)
 883   "expand inline"
 884   (check-inlineability-of-find-position-if sequence from-end)
 885   '(%find-position-if-not-vector-macro predicate sequence
 886                                        from-end start end key))
 887
 888 (deftransform %find-position ((item sequence from-end start end key test)
 889                               (t vector t t t function function)
 890                               *
 891                               :policy (> speed space)
 892                               :important t)
 893   "expand inline"
 894   (check-inlineability-of-find-position-if sequence from-end)
 895   '(%find-position-vector-macro item sequence
 896                                 from-end start end key test))