src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body fast)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places)
 137             (around))
 138     (let ((found-vector-p nil))
 139       (flet ((process-vector (length)
 140                (unless found-vector-p
 141                  (setq found-vector-p t)
 142                  (bindings `(index 0 (1+ index)))
 143                  (declarations `(type index index)))
 144                (vector-lengths length)))
 145         (loop for seq of-type lvar in seqs
 146            for seq-name in seq-names
 147            for type = (lvar-type seq)
 148            do (cond ((csubtypep type (specifier-type 'list))
 149                      (with-unique-names (index)
 150                        (bindings `(,index ,seq-name (cdr ,index)))
 151                        (declarations `(type list ,index))
 152                        (places `(car ,index))
 153                        (tests `(endp ,index))))
 154                     ((or (csubtypep type (specifier-type '(simple-array * 1)))
 155                          (and (not fast)
 156                               (csubtypep type (specifier-type 'vector))))
 157                      (process-vector `(length ,seq-name))
 158                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 159                                 (aref ,seq-name index))))
 160                     ((csubtypep type (specifier-type 'vector))
 161                      (let ((data  (gensym "DATA"))
 162                            (start (gensym "START"))
 163                            (end   (gensym "END")))
 164                        (around `(with-array-data ((,data ,seq-name)
 165                                                   (,start)
 166                                                   (,end (length ,seq-name)))))
 167                        (process-vector `(- ,end ,start))
 168                        (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 169                                   (aref ,data (truly-the index (+ index ,start)))))))
 170                     (t
 171                      (give-up-ir1-transform
 172                       "can't determine sequence argument type"))))
 173         (when into
 174           (process-vector `(array-dimension ,into 0))))
 175       (when found-vector-p
 176         (bindings `(length (min ,@(vector-lengths))))
 177         (tests `(>= index length)))
 178       (let ((body `(do (,@(bindings))
 179                        ((or ,@(tests)) ,result)
 180                      (declare ,@(declarations))
 181                      (let ((funcall-result (funcall fun ,@(places))))
 182                        (declare (ignorable funcall-result))
 183                        ,body))))
 184         (if (around)
 185             (reduce (lambda (wrap body) (append wrap (list body)))
 186                     (around)
 187                     :from-end t
 188                     :initial-value body)
 189             body)))))
 190
 191 ;;; Try to compile %MAP efficiently when we can determine sequence
 192 ;;; argument types at compile time.
 193 ;;;
 194 ;;; Note: This transform was written to allow open coding of
 195 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 196 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 197 ;;; necessarily as efficient as possible. In particular, it will be
 198 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 199 ;;; numeric element types. It should be straightforward to make it
 200 ;;; handle that case more efficiently, but it's left as an exercise to
 201 ;;; the reader, because the code is complicated enough already and I
 202 ;;; don't happen to need that functionality right now. -- WHN 20000410
 203 (deftransform %map ((result-type fun seq &rest seqs) * *
 204                     :node node :policy (>= speed space))
 205   "open code"
 206   (unless (constant-lvar-p result-type)
 207     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 208   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 209            (fn-1subtypep (fn x y)
 210              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 211                (if valid-p
 212                    subtype-p
 213                    (give-up-ir1-transform
 214                     "can't analyze sequence type relationship"))))
 215            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 216     (let* ((result-type-value (lvar-value result-type))
 217            (result-supertype (cond ((null result-type-value) 'null)
 218                                    ((1subtypep result-type-value 'vector)
 219                                     'vector)
 220                                    ((1subtypep result-type-value 'list)
 221                                     'list)
 222                                    (t
 223                                     (give-up-ir1-transform
 224                                      "result type unsuitable")))))
 225       (cond ((and result-type-value (null seqs))
 226              ;; The consing arity-1 cases can be implemented
 227              ;; reasonably efficiently as function calls, and the cost
 228              ;; of consing should be significantly larger than
 229              ;; function call overhead, so we always compile these
 230              ;; cases as full calls regardless of speed-versus-space
 231              ;; optimization policy.
 232              (cond ((subtypep result-type-value 'list)
 233                     '(%map-to-list-arity-1 fun seq))
 234                    ( ;; (This one can be inefficient due to COERCE, but
 235                     ;; the current open-coded implementation has the
 236                     ;; same problem.)
 237                     (subtypep result-type-value 'vector)
 238                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 239                              ',result-type-value))
 240                    (t (bug "impossible (?) sequence type"))))
 241             (t
 242              (let* ((seqs (cons seq seqs))
 243                     (seq-args (make-gensym-list (length seqs))))
 244                (multiple-value-bind (push-dacc result)
 245                    (ecase result-supertype
 246                      (null (values nil nil))
 247                      (list (values `(push funcall-result acc)
 248                                    `(nreverse acc)))
 249                      (vector (values `(push funcall-result acc)
 250                                      `(coerce (nreverse acc)
 251                                               ',result-type-value))))
 252                  ;; (We use the same idiom, of returning a LAMBDA from
 253                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 254                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 255                  ;; reason: we need to get the runtime values of each
 256                  ;; of the &REST vars.)
 257                  `(lambda (result-type fun ,@seq-args)
 258                     (declare (ignore result-type))
 259                     (let ((fun (%coerce-callable-to-fun fun))
 260                           (acc nil))
 261                       (declare (type list acc))
 262                       (declare (ignorable acc))
 263                       ,(build-sequence-iterator
 264                         seqs seq-args
 265                         :result result
 266                         :body push-dacc
 267                         :fast (policy node (> speed space))))))))))))
 268
 269 ;;; MAP-INTO
 270 (deftransform map-into ((result fun &rest seqs)
 271                         (vector * &rest *)
 272                         * :node node)
 273   "open code"
 274   (let ((seqs-names (mapcar (lambda (x)
 275                               (declare (ignore x))
 276                               (gensym))
 277                             seqs)))
 278     `(lambda (result fun ,@seqs-names)
 279        ,(if (and (policy node (> speed space))
 280                  (not (csubtypep (lvar-type result)
 281                                  (specifier-type '(simple-array * 1)))))
 282             (let ((data  (gensym "DATA"))
 283                   (start (gensym "START"))
 284                   (end   (gensym "END")))
 285               `(with-array-data ((,data result)
 286                                  (,start)
 287                                  (,end))
 288                  (declare (ignore ,end))
 289                  ,(build-sequence-iterator
 290                    seqs seqs-names
 291                    :result '(when (array-has-fill-pointer-p result)
 292                              (setf (fill-pointer result) index))
 293                    :into 'result
 294                    :body `(locally (declare (optimize (insert-array-bounds-checks 0)))
 295                            (setf (aref ,data (truly-the index (+ index ,start)))
 296                                  funcall-result))
 297                    :fast t)))
 298             (build-sequence-iterator
 299              seqs seqs-names
 300              :result '(when (array-has-fill-pointer-p result)
 301                        (setf (fill-pointer result) index))
 302              :into 'result
 303              :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 304                      (setf (aref result index) funcall-result))))
 305        result)))
 306
 307 \f
 308 ;;; FIXME: once the confusion over doing transforms with known-complex
 309 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 310 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 311 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 312   '(aref s i))
 313
 314 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 315   '(nth i s))
 316
 317 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 318   '(%aset s i v))
 319
 320 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 321   '(setf (car (nthcdr i s)) v))
 322
 323 (deftransform %check-vector-sequence-bounds ((vector start end)
 324                                              (vector * *) *
 325                                              :node node)
 326   (if (policy node (= 0 insert-array-bounds-checks))
 327       '(or end (length vector))
 328       '(let ((length (length vector)))
 329          (if (<= 0 start (or end length) length)
 330              (or end length)
 331              (sequence-bounding-indices-bad-error vector start end)))))
 332
 333 (def!type eq-comparable-type ()
 334   '(or fixnum (not number)))
 335
 336 ;;; True if EQL comparisons involving type can be simplified to EQ.
 337 (defun eq-comparable-type-p (type)
 338   (csubtypep type (specifier-type 'eq-comparable-type)))
 339
 340 (defun specialized-list-seek-function-name (function-name key-functions &optional variant)
 341   (or (find-symbol (with-output-to-string (s)
 342                      ;; Write "%NAME-FUN1-FUN2-FUN3", etc. Not only is
 343                      ;; this ever so slightly faster then FORMAT, this
 344                      ;; way we are also proof against *PRINT-CASE*
 345                      ;; frobbing and such.
 346                      (write-char #\% s)
 347                      (write-string (symbol-name function-name) s)
 348                      (dolist (f key-functions)
 349                        (write-char #\- s)
 350                        (write-string (symbol-name f) s))
 351                      (when variant
 352                        (write-char #\- s)
 353                        (write-string (symbol-name variant) s)))
 354                    (load-time-value (find-package "SB!KERNEL")))
 355       (bug "Unknown list item seek transform: name=~S, key-functions=~S variant=~S"
 356            function-name key-functions variant)))
 357
 358 (defparameter *list-open-code-limit* 128)
 359
 360 (defun transform-list-item-seek (name item list key test test-not node)
 361   (when (and test test-not)
 362     (abort-ir1-transform "Both ~S and ~S supplied to ~S." :test :test-not name))
 363   ;; If TEST is EQL, drop it.
 364   (when (and test (lvar-fun-is test '(eql)))
 365     (setf test nil))
 366   ;; Ditto for KEY IDENTITY.
 367   (when (and key (lvar-fun-is key '(identity)))
 368     (setf key nil))
 369   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 370   ;; not there at all. If it might be NIL, make up a form to that
 371   ;; ensures it is a function.
 372   (multiple-value-bind (key key-form)
 373       (when key
 374         (let ((key-type (lvar-type key))
 375               (null-type (specifier-type 'null)))
 376           (cond ((csubtypep key-type null-type)
 377                  (values nil nil))
 378                 ((csubtypep null-type key-type)
 379                  (values key '(if key
 380                                (%coerce-callable-to-fun key)
 381                                #'identity)))
 382                 (t
 383                  (values key (ensure-lvar-fun-form key 'key))))))
 384     (let* ((c-test (cond ((and test (lvar-fun-is test '(eq)))
 385                           (setf test nil)
 386                           'eq)
 387                          ((and (not test) (not test-not))
 388                           (when (eq-comparable-type-p (lvar-type item))
 389                             'eq))))
 390            (funs (delete nil (list (when key (list key 'key))
 391                                    (when test (list test 'test))
 392                                    (when test-not (list test-not 'test-not)))))
 393            (target-expr (if key '(%funcall key target) 'target))
 394            (test-expr (cond (test `(%funcall test item ,target-expr))
 395                             (test-not `(not (%funcall test-not item ,target-expr)))
 396                             (c-test `(,c-test item ,target-expr))
 397                             (t `(eql item ,target-expr)))))
 398       (labels ((open-code (tail)
 399                  (when tail
 400                    `(if (let ((this ',(car tail)))
 401                           ,(ecase name
 402                                   ((assoc rassoc)
 403                                    (let ((cxx (if (eq name 'assoc) 'car 'cdr)))
 404                                      `(and this (let ((target (,cxx this)))
 405                                                   ,test-expr))))
 406                                   (member
 407                                    `(let ((target this))
 408                                       ,test-expr))))
 409                         ',(ecase name
 410                                  ((assoc rassoc) (car tail))
 411                                  (member tail))
 412                         ,(open-code (cdr tail)))))
 413                (ensure-fun (args)
 414                  (if (eq 'key (second args))
 415                      key-form
 416                      (apply #'ensure-lvar-fun-form args))))
 417         (let* ((cp (constant-lvar-p list))
 418                (c-list (when cp (lvar-value list))))
 419           (cond ((and cp c-list (member name '(assoc rassoc member))
 420                       (policy node (>= speed space))
 421                       (not (nthcdr *list-open-code-limit* c-list)))
 422                  `(let ,(mapcar (lambda (fun) `(,(second fun) ,(ensure-fun fun))) funs)
 423                     ,(open-code c-list)))
 424                 ((and cp (not c-list))
 425                  ;; constant nil list
 426                  (if (eq name 'adjoin)
 427                      '(list item)
 428                      nil))
 429                 (t
 430                  ;; specialized out-of-line version
 431                  `(,(specialized-list-seek-function-name name (mapcar #'second funs) c-test)
 432                     item list ,@(mapcar #'ensure-fun funs)))))))))
 433
 434 (defun transform-list-pred-seek (name pred list key node)
 435   ;; If KEY is IDENTITY, drop it.
 436   (when (and key (lvar-fun-is key '(identity)))
 437     (setf key nil))
 438   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 439   ;; not there at all. If it might be NIL, make up a form to that
 440   ;; ensures it is a function.
 441   (multiple-value-bind (key key-form)
 442       (when key
 443         (let ((key-type (lvar-type key))
 444               (null-type (specifier-type 'null)))
 445           (cond ((csubtypep key-type null-type)
 446                  (values nil nil))
 447                 ((csubtypep null-type key-type)
 448                  (values key '(if key
 449                                (%coerce-callable-to-fun key)
 450                                #'identity)))
 451                 (t
 452                  (values key (ensure-lvar-fun-form key 'key))))))
 453     (let ((test-expr `(%funcall pred ,(if key '(%funcall key target) 'target)))
 454           (pred-expr (ensure-lvar-fun-form pred 'pred)))
 455       (when (member name '(member-if-not assoc-if-not rassoc-if-not))
 456         (setf test-expr `(not ,test-expr)))
 457       (labels ((open-code (tail)
 458                  (when tail
 459                    `(if (let ((this ',(car tail)))
 460                           ,(ecase name
 461                                   ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 462                                    (let ((cxx (if (member name '(assoc-if assoc-if-not)) 'car 'cdr)))
 463                                      `(and this (let ((target (,cxx this)))
 464                                                   ,test-expr))))
 465                                   ((member-if member-if-not)
 466                                    `(let ((target this))
 467                                       ,test-expr))))
 468                         ',(ecase name
 469                                  ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 470                                   (car tail))
 471                                  ((member-if member-if-not)
 472                                   tail))
 473                         ,(open-code (cdr tail))))))
 474         (let* ((cp (constant-lvar-p list))
 475                (c-list (when cp (lvar-value list))))
 476           (cond ((and cp c-list (policy node (>= speed space))
 477                       (not (nthcdr *list-open-code-limit* c-list)))
 478                  `(let ((pred ,pred-expr)
 479                         ,@(when key `((key ,key-form))))
 480                     ,(open-code c-list)))
 481                 ((and cp (not c-list))
 482                  ;; constant nil list -- nothing to find!
 483                  nil)
 484                 (t
 485                  ;; specialized out-of-line version
 486                  `(,(specialized-list-seek-function-name name (when key '(key)))
 487                     ,pred-expr list ,@(when key (list key-form))))))))))
 488
 489 (macrolet ((def (name &optional if/if-not)
 490              (let ((basic (symbolicate "%" name))
 491                    (basic-eq (symbolicate "%" name "-EQ"))
 492                    (basic-key (symbolicate "%" name "-KEY"))
 493                    (basic-key-eq (symbolicate "%" name "-KEY-EQ")))
 494                `(progn
 495                   (deftransform ,name ((item list &key key test test-not) * * :node node)
 496                     (transform-list-item-seek ',name item list key test test-not node))
 497                   (deftransform ,basic ((item list) (eq-comparable-type t))
 498                     `(,',basic-eq item list))
 499                   (deftransform ,basic-key ((item list) (eq-comparable-type t))
 500                     `(,',basic-key-eq item list))
 501                   ,@(when if/if-not
 502                           (let ((if-name (symbolicate name "-IF"))
 503                                 (if-not-name (symbolicate name "-IF-NOT")))
 504                             `((deftransform ,if-name ((pred list &key key) * * :node node)
 505                                 (transform-list-pred-seek ',if-name pred list key node))
 506                               (deftransform ,if-not-name ((pred list &key key) * * :node node)
 507                                 (transform-list-pred-seek ',if-not-name pred list key node)))))))))
 508   (def adjoin)
 509   (def assoc  t)
 510   (def member t)
 511   (def rassoc t))
 512
 513 (deftransform memq ((item list) (t (constant-arg list)))
 514   (labels ((rec (tail)
 515              (if tail
 516                  `(if (eq item ',(car tail))
 517                       ',tail
 518                       ,(rec (cdr tail)))
 519                  nil)))
 520     (rec (lvar-value list))))
 521
 522 ;;; A similar transform used to apply to MEMBER and ASSOC, but since
 523 ;;; TRANSFORM-LIST-ITEM-SEEK now takes care of them those transform
 524 ;;; would never fire, and (%MEMBER-TEST ITEM LIST #'EQ) should be
 525 ;;; almost as fast as MEMQ.
 526 (deftransform delete ((item list &key test) (t list &rest t) *)
 527   "convert to EQ test"
 528   (let ((type (lvar-type item)))
 529     (unless (or (and test (lvar-fun-is test '(eq)))
 530                 (and (eq-comparable-type-p type)
 531                      (or (not test) (lvar-fun-is test '(eql)))))
 532       (give-up-ir1-transform)))
 533   `(delq item list))
 534
 535 (deftransform delete-if ((pred list) (t list))
 536   "open code"
 537   '(do ((x list (cdr x))
 538         (splice '()))
 539        ((endp x) list)
 540      (cond ((funcall pred (car x))
 541             (if (null splice)
 542                 (setq list (cdr x))
 543                 (rplacd splice (cdr x))))
 544            (t (setq splice x)))))
 545
 546 (deftransform fill ((seq item &key (start 0) (end nil))
 547                     (list t &key (:start t) (:end t)))
 548   '(list-fill* seq item start end))
 549
 550 (deftransform fill ((seq item &key (start 0) (end nil))
 551                     (vector t &key (:start t) (:end t))
 552                     *
 553                     :node node)
 554   (let* ((type (lvar-type seq))
 555          (element-ctype (array-type-upgraded-element-type type))
 556          (element-type (type-specifier element-ctype))
 557          (saetp (unless (eq *wild-type* element-ctype)
 558                   (find-saetp-by-ctype element-ctype))))
 559     (cond ((eq *wild-type* element-ctype)
 560            (delay-ir1-transform node :constraint)
 561            `(vector-fill* seq item start end))
 562           ((and saetp (sb!vm::valid-bit-bash-saetp-p saetp))
 563            (let* ((n-bits (sb!vm:saetp-n-bits saetp))
 564                   (basher-name (format nil "UB~D-BASH-FILL" n-bits))
 565                   (basher (or (find-symbol basher-name
 566                                            (load-time-value (find-package :sb!kernel)))
 567                               (abort-ir1-transform
 568                                "Unknown fill basher, please report to sbcl-devel: ~A"
 569                                basher-name)))
 570                   (kind (cond ((sb!vm:saetp-fixnum-p saetp) :tagged)
 571                               ((member element-type '(character base-char)) :char)
 572                               ((eq element-type 'single-float) :single-float)
 573                               #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 574                               ((eq element-type 'double-float) :double-float)
 575                               #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 576                               ((equal element-type '(complex single-float))
 577                                :complex-single-float)
 578                               (t
 579                                (aver (integer-type-p element-ctype))
 580                                :bits)))
 581                   ;; BASH-VALUE is a word that we can repeatedly smash
 582                   ;; on the array: for less-than-word sized elements it
 583                   ;; contains multiple copies of the fill item.
 584                   (bash-value
 585                    (if (constant-lvar-p item)
 586                        (let ((tmp (lvar-value item)))
 587                          (unless (ctypep tmp element-ctype)
 588                            (abort-ir1-transform "~S is not ~S" tmp element-type))
 589                          (let* ((bits
 590                                  (ldb (byte n-bits 0)
 591                                       (ecase kind
 592                                         (:tagged
 593                                          (ash tmp sb!vm:n-fixnum-tag-bits))
 594                                         (:char
 595                                          (char-code tmp))
 596                                         (:bits
 597                                          tmp)
 598                                         (:single-float
 599                                          (single-float-bits tmp))
 600                                         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 601                                         (:double-float
 602                                          (logior (ash (double-float-high-bits tmp) 32)
 603                                                  (double-float-low-bits tmp)))
 604                                         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 605                                         (:complex-single-float
 606                                          (logior (ash (single-float-bits (imagpart tmp)) 32)
 607                                                  (ldb (byte 32 0)
 608                                                       (single-float-bits (realpart tmp))))))))
 609                                 (res bits))
 610                            (loop for i of-type sb!vm:word from n-bits by n-bits
 611                                  until (= i sb!vm:n-word-bits)
 612                                  do (setf res (ldb (byte sb!vm:n-word-bits 0)
 613                                                    (logior res (ash bits i)))))
 614                            res))
 615                        (progn
 616                          (delay-ir1-transform node :constraint)
 617                         `(let* ((bits (ldb (byte ,n-bits 0)
 618                                            ,(ecase kind
 619                                                    (:tagged
 620                                                     `(ash item ,sb!vm:n-fixnum-tag-bits))
 621                                                    (:char
 622                                                     `(char-code item))
 623                                                    (:bits
 624                                                     `item)
 625                                                    (:single-float
 626                                                     `(single-float-bits item))
 627                                                    #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 628                                                    (:double-float
 629                                                     `(logior (ash (double-float-high-bits item) 32)
 630                                                              (double-float-low-bits item)))
 631                                                    #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 632                                                    (:complex-single-float
 633                                                     `(logior (ash (single-float-bits (imagpart item)) 32)
 634                                                              (ldb (byte 32 0)
 635                                                                   (single-float-bits (realpart item))))))))
 636                                 (res bits))
 637                            (declare (type sb!vm:word res))
 638                            ,@(unless (= sb!vm:n-word-bits n-bits)
 639                                      `((loop for i of-type sb!vm:word from ,n-bits by ,n-bits
 640                                              until (= i sb!vm:n-word-bits)
 641                                              do (setf res
 642                                                       (ldb (byte ,sb!vm:n-word-bits 0)
 643                                                            (logior res (ash bits (truly-the (integer 0 ,(- sb!vm:n-word-bits n-bits)) i))))))))
 644                            res)))))
 645              (values
 646               `(with-array-data ((data seq)
 647                                  (start start)
 648                                  (end end)
 649                                  :check-fill-pointer t)
 650                  (declare (type (simple-array ,element-type 1) data))
 651                  (declare (type index start end))
 652                  (declare (optimize (safety 0) (speed 3)))
 653                  (,basher ,bash-value data start (- end start))
 654                  seq)
 655               `((declare (type ,element-type item))))))
 656           ((policy node (> speed space))
 657            (values
 658             `(with-array-data ((data seq)
 659                                (start start)
 660                                (end end)
 661                                :check-fill-pointer t)
 662                (declare (type (simple-array ,element-type 1) data))
 663                (declare (type index start end))
 664                ;; WITH-ARRAY-DATA did our range checks once and for all, so
 665                ;; it'd be wasteful to check again on every AREF...
 666                (declare (optimize (safety 0) (speed 3)))
 667                (do ((i start (1+ i)))
 668                    ((= i end) seq)
 669                  (declare (type index i))
 670                  (setf (aref data i) item)))
 671             ;; ... though we still need to check that the new element can fit
 672             ;; into the vector in safe code. -- CSR, 2002-07-05
 673             `((declare (type ,element-type item)))))
 674           ((csubtypep type (specifier-type 'string))
 675            '(string-fill* seq item start end))
 676           (t
 677            '(vector-fill* seq item start end)))))
 678
 679 (deftransform fill ((seq item &key (start 0) (end nil))
 680                     ((and sequence (not vector) (not list)) t &key (:start t) (:end t)))
 681   `(sb!sequence:fill seq item
 682                      :start start
 683                      :end (%check-generic-sequence-bounds seq start end)))
 684 \f
 685 ;;;; hairy sequence transforms
 686
 687 ;;; FIXME: no hairy sequence transforms in SBCL?
 688 ;;;
 689 ;;; There used to be a bunch of commented out code about here,
 690 ;;; containing the (apparent) beginning of hairy sequence transform
 691 ;;; infrastructure. People interested in implementing better sequence
 692 ;;; transforms might want to look at it for inspiration, even though
 693 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 694 ;;; was deleted in 1.0.7.23.
 695 \f
 696 ;;;; string operations
 697
 698 ;;; We transform the case-sensitive string predicates into a non-keyword
 699 ;;; version. This is an IR1 transform so that we don't have to worry about
 700 ;;; changing the order of evaluation.
 701 (macrolet ((def (fun pred*)
 702              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 703                                                          (start2 0) end2)
 704                                    * *)
 705                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 706   (def string< string<*)
 707   (def string> string>*)
 708   (def string<= string<=*)
 709   (def string>= string>=*)
 710   (def string= string=*)
 711   (def string/= string/=*))
 712
 713 ;;; Return a form that tests the free variables STRING1 and STRING2
 714 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 715 ;;; start and end are also gotten from the environment. Both strings
 716 ;;; must be SIMPLE-BASE-STRINGs.
 717 (macrolet ((def (name lessp equalp)
 718              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 719                                    (simple-base-string simple-base-string t t t t) *)
 720                 `(let* ((end1 (if (not end1) (length string1) end1))
 721                         (end2 (if (not end2) (length string2) end2))
 722                         (index (sb!impl::%sp-string-compare
 723                                 string1 start1 end1 string2 start2 end2)))
 724                   (if index
 725                       (cond ((= index end1)
 726                              ,(if ',lessp 'index nil))
 727                             ((= (+ index (- start2 start1)) end2)
 728                              ,(if ',lessp nil 'index))
 729                             ((,(if ',lessp 'char< 'char>)
 730                                (schar string1 index)
 731                                (schar string2
 732                                       (truly-the index
 733                                                  (+ index
 734                                                     (truly-the fixnum
 735                                                                (- start2
 736                                                                   start1))))))
 737                              index)
 738                             (t nil))
 739                       ,(if ',equalp 'end1 nil))))))
 740   (def string<* t nil)
 741   (def string<=* t t)
 742   (def string>* nil nil)
 743   (def string>=* nil t))
 744
 745 (macrolet ((def (name result-fun)
 746              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 747                                    (simple-base-string simple-base-string t t t t) *)
 748                 `(,',result-fun
 749                   (sb!impl::%sp-string-compare
 750                    string1 start1 (or end1 (length string1))
 751                    string2 start2 (or end2 (length string2)))))))
 752   (def string=* not)
 753   (def string/=* identity))
 754
 755 \f
 756 ;;;; transforms for sequence functions
 757
 758 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 759 ;;; to vectors based on simple arrays.
 760 (def!constant vector-data-bit-offset
 761   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 762
 763 ;;; FIXME: In the copy loops below, we code the loops in a strange
 764 ;;; fashion:
 765 ;;;
 766 ;;; (do ((i (+ src-offset length) (1- i)))
 767 ;;;     ((<= i 0) ...)
 768 ;;;   (... (aref foo (1- i)) ...))
 769 ;;;
 770 ;;; rather than the more natural (and seemingly more efficient):
 771 ;;;
 772 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 773 ;;;     ((< i 0) ...)
 774 ;;;   (... (aref foo i) ...))
 775 ;;;
 776 ;;; (more efficient because we don't have to do the index adjusting on
 777 ;;; every iteration of the loop)
 778 ;;;
 779 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 780 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 781 ;;; when used as an array index, the backend thinks I is a
 782 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 783 ;;; these as distinct storage classes, it cannot coerce a move from a
 784 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 785 ;;; deficiency is that we have two extra moves and increased register
 786 ;;; pressure, which can lead to some spectacularly bad register
 787 ;;; allocation.  (sub-FIXME: the register allocation even with the
 788 ;;; strangely written loops is not always excellent, either...).  Doing
 789 ;;; it the first way, above, means that I is always thought of as a
 790 ;;; POSITIVE-FIXNUM and there are no issues.
 791 ;;;
 792 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 793 ;;; adjustments in the first version into the array addressing at no
 794 ;;; performance penalty!
 795
 796 ;;; This transform is critical to the performance of string streams.  If
 797 ;;; you tweak it, make sure that you compare the disassembly, if not the
 798 ;;; performance of, the functions implementing string streams
 799 ;;; (e.g. SB!IMPL::STRING-OUCH).
 800 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 801   (defun make-replace-transform (saetp sequence-type1 sequence-type2)
 802     `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 803                             (,sequence-type1 ,sequence-type2 &rest t)
 804                             ,sequence-type1
 805                             :node node)
 806        `(let* ((len1 (length seq1))
 807                (len2 (length seq2))
 808                (end1 (or end1 len1))
 809                (end2 (or end2 len2))
 810                (replace-len (min (- end1 start1) (- end2 start2))))
 811           ,(unless (policy node (= insert-array-bounds-checks 0))
 812              `(progn
 813                 (unless (<= 0 start1 end1 len1)
 814                   (sequence-bounding-indices-bad-error seq1 start1 end1))
 815                 (unless (<= 0 start2 end2 len2)
 816                   (sequence-bounding-indices-bad-error seq2 start2 end2))))
 817           ,',(cond
 818                ((and saetp (sb!vm:valid-bit-bash-saetp-p saetp))
 819                 (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 820                        (bash-function (intern (format nil "UB~D-BASH-COPY"
 821                                                       n-element-bits)
 822                                               (find-package "SB!KERNEL"))))
 823                   `(funcall (function ,bash-function) seq2 start2
 824                     seq1 start1 replace-len)))
 825                (t
 826                 `(if (and
 827                       ;; If the sequence types are different, SEQ1 and
 828                       ;; SEQ2 must be distinct arrays.
 829                       ,(eql sequence-type1 sequence-type2)
 830                       (eq seq1 seq2) (> start1 start2))
 831                      (do ((i (truly-the index (+ start1 replace-len -1))
 832                              (1- i))
 833                           (j (truly-the index (+ start2 replace-len -1))
 834                              (1- j)))
 835                          ((< i start1))
 836                        (declare (optimize (insert-array-bounds-checks 0)))
 837                        (setf (aref seq1 i) (aref seq2 j)))
 838                      (do ((i start1 (1+ i))
 839                           (j start2 (1+ j))
 840                           (end (+ start1 replace-len)))
 841                          ((>= i end))
 842                        (declare (optimize (insert-array-bounds-checks 0)))
 843                        (setf (aref seq1 i) (aref seq2 j))))))
 844           seq1))))
 845
 846 (macrolet
 847     ((define-replace-transforms ()
 848        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 849              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 850              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 851              collect (make-replace-transform saetp sequence-type sequence-type)
 852              into forms
 853              finally (return `(progn ,@forms))))
 854      (define-one-transform (sequence-type1 sequence-type2)
 855        (make-replace-transform nil sequence-type1 sequence-type2)))
 856   (define-replace-transforms)
 857   #!+sb-unicode
 858   (progn
 859    (define-one-transform (simple-array base-char (*)) (simple-array character (*)))
 860    (define-one-transform (simple-array character (*)) (simple-array base-char (*)))))
 861
 862 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 863 ;;; defined as those cases where we are doing word-aligned copies from
 864 ;;; both the source and the destination and we are copying from the same
 865 ;;; offset from both the source and the destination.  (The last
 866 ;;; condition is there so we can determine the direction to copy at
 867 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 868 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 869 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 870 ;;; N)-size buffer and blitting in the old N-size buffer in.
 871
 872 (defun frob-bash-transform (src src-offset
 873                             dst dst-offset
 874                             length n-elems-per-word)
 875   (declare (ignore src dst length))
 876   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 877     (multiple-value-bind (src-word src-elt)
 878         (truncate (lvar-value src-offset) n-elems-per-word)
 879       (multiple-value-bind (dst-word dst-elt)
 880           (truncate (lvar-value dst-offset) n-elems-per-word)
 881         ;; Avoid non-word aligned copies.
 882         (unless (and (zerop src-elt) (zerop dst-elt))
 883           (give-up-ir1-transform))
 884         ;; Avoid copies where we would have to insert code for
 885         ;; determining the direction of copying.
 886         (unless (= src-word dst-word)
 887           (give-up-ir1-transform))
 888         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 889         ;; so we have to do its work here.
 890         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 891                                       'length
 892                                       `(truncate (the index length) ,n-elems-per-word)))))
 893            (declare (type index end))
 894            ;; Handle any bits at the end.
 895            (when (logtest length (1- ,n-elems-per-word))
 896              (let* ((extra (mod length ,n-elems-per-word))
 897                     ;; FIXME: The shift amount on this ASH is
 898                     ;; *always* negative, but the backend doesn't
 899                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 900                     ;; wind up with a pile of code that tests the
 901                     ;; sign of the shift count prior to shifting when
 902                     ;; all we need is a simple negate and shift
 903                     ;; right.  Yuck.
 904                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 905                                (* (- extra ,n-elems-per-word)
 906                                   ,n-bits-per-elem))))
 907                (setf (sb!kernel:%vector-raw-bits dst end)
 908                      (logior
 909                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 910                                 (ash mask
 911                                      ,(ecase sb!c:*backend-byte-order*
 912                                              (:little-endian 0)
 913                                              (:big-endian `(* (- ,n-elems-per-word extra)
 914                                                               ,n-bits-per-elem)))))
 915                       (logand (sb!kernel:%vector-raw-bits src end)
 916                               (ash mask
 917                                    ,(ecase sb!c:*backend-byte-order*
 918                                            (:little-endian 0)
 919                                            (:big-endian `(* (- ,n-elems-per-word extra)
 920                                                             ,n-bits-per-elem)))))))))
 921            ;; Copy from the end to save a register.
 922            (do ((i end (1- i)))
 923                ((<= i ,src-word))
 924              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 925                    (sb!kernel:%vector-raw-bits src (1- i))))
 926            (values))))))
 927
 928 #.(loop for i = 1 then (* i 2)
 929         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 930                                         "SB!KERNEL")
 931                                                         ((src src-offset
 932                                                           dst dst-offset
 933                                                           length)
 934                                                         ((simple-unboxed-array (*))
 935                                                          (constant-arg index)
 936                                                          (simple-unboxed-array (*))
 937                                                          (constant-arg index)
 938                                                          index)
 939                                                         *)
 940                   (frob-bash-transform src src-offset
 941                                        dst dst-offset length
 942                                        ,(truncate sb!vm:n-word-bits i))) into forms
 943         until (= i sb!vm:n-word-bits)
 944         finally (return `(progn ,@forms)))
 945
 946 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 947 ;;; arrays with elements of size >= the word size.  We do this because
 948 ;;; we know the arrays cannot alias (one was just consed), therefore we
 949 ;;; can determine at compile time the direction to copy, and for
 950 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 951 ;;; needless checking to figure out what's going on.  The same
 952 ;;; considerations apply if we are copying elements larger than the word
 953 ;;; size, with the additional twist that doing it inline is likely to
 954 ;;; cons far less than calling REPLACE and letting generic code do the
 955 ;;; work.
 956 ;;;
 957 ;;; However, we do not do this for elements whose size is < than the
 958 ;;; word size because we don't want to deal with any alignment issues
 959 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 960 ;;; anyway.
 961
 962 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 963                                       element-type)
 964   (let ((saetp (find-saetp element-type)))
 965     (aver saetp)
 966     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 967         (expand-aref-copy-loop src src-offset dst dst-offset length)
 968         `(locally (declare (optimize (safety 0)))
 969            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 970
 971 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 972   (if (eql src-offset dst-offset)
 973       `(do ((i (+ ,src-offset ,length) (1- i)))
 974            ((<= i ,src-offset))
 975          (declare (optimize (insert-array-bounds-checks 0)))
 976          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 977       ;; KLUDGE: The compiler is not able to derive that (+ offset
 978       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 979       ;; We, however, know it must be so, as by this point the bounds
 980       ;; have already been checked.
 981       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 982             (j (+ ,dst-offset ,length) (1- j)))
 983            ((<= i ,src-offset))
 984          (declare (optimize (insert-array-bounds-checks 0))
 985                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 986          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 987
 988 ;;; SUBSEQ, COPY-SEQ
 989
 990 (deftransform subseq ((seq start &optional end)
 991                       (vector t &optional t)
 992                       *
 993                       :node node)
 994   (let ((type (lvar-type seq)))
 995     (cond
 996       ((and (array-type-p type)
 997             (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 998        (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 999          `(let* ((length (length seq))
1000                  (end (or end length)))
1001             ,(unless (policy node (zerop insert-array-bounds-checks))
1002                      '(progn
1003                        (unless (<= 0 start end length)
1004                          (sequence-bounding-indices-bad-error seq start end))))
1005             (let* ((size (- end start))
1006                    (result (make-array size :element-type ',element-type)))
1007               ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
1008                                                        (lvar-value start)
1009                                                        'start)
1010                                               'result 0 'size element-type)
1011               result))))
1012       ((csubtypep type (specifier-type 'string))
1013        '(string-subseq* seq start end))
1014       (t
1015        '(vector-subseq* seq start end)))))
1016
1017 (deftransform subseq ((seq start &optional end)
1018                       (list t &optional t))
1019   `(list-subseq* seq start end))
1020
1021 (deftransform subseq ((seq start &optional end)
1022                       ((and sequence (not vector) (not list)) t &optional t))
1023   '(sb!sequence:subseq seq start end))
1024
1025 (deftransform copy-seq ((seq) (vector))
1026   (let ((type (lvar-type seq)))
1027     (cond ((and (array-type-p type)
1028                 (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
1029            (let ((element-type (type-specifier (array-type-specialized-element-type type))))
1030              `(let* ((length (length seq))
1031                      (result (make-array length :element-type ',element-type)))
1032                 ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
1033                 result)))
1034           ((csubtypep type (specifier-type 'string))
1035            '(string-subseq* seq 0 nil))
1036           (t
1037            '(vector-subseq* seq 0 nil)))))
1038
1039 (deftransform copy-seq ((seq) (list))
1040   '(list-copy-seq* seq))
1041
1042 (deftransform copy-seq ((seq) ((and sequence (not vector) (not list))))
1043   '(sb!sequence:copy-seq seq))
1044
1045 ;;; FIXME: it really should be possible to take advantage of the
1046 ;;; macros used in code/seq.lisp here to avoid duplication of code,
1047 ;;; and enable even funkier transformations.
1048 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
1049                                (test #'eql)
1050                                (key #'identity)
1051                                from-end)
1052                       (vector vector &rest t)
1053                       *
1054                       :node node
1055                       :policy (> speed (max space safety)))
1056   "open code"
1057   (flet ((maybe (x)
1058            (when (lvar-p x)
1059              (if (constant-lvar-p x)
1060                  (when (lvar-value x)
1061                    :yes)
1062                  :maybe))))
1063     (let ((from-end (when (lvar-p from-end)
1064                      (unless (constant-lvar-p from-end)
1065                        (give-up-ir1-transform ":FROM-END is not constant."))
1066                      (lvar-value from-end)))
1067          (key? (maybe key))
1068          (test? (maybe test))
1069          (check-bounds-p (policy node (plusp insert-array-bounds-checks))))
1070      `(block search
1071         (flet ((oops (vector start end)
1072                  (sequence-bounding-indices-bad-error vector start end)))
1073           (let* ((len1 (length pattern))
1074                  (len2 (length text))
1075                  (end1 (or end1 len1))
1076                  (end2 (or end2 len2))
1077                  ,@(case key?
1078                      (:yes `((key (%coerce-callable-to-fun key))))
1079                      (:maybe `((key (when key
1080                                       (%coerce-callable-to-fun key))))))
1081                  ,@(when test?
1082                      `((test (%coerce-callable-to-fun test)))))
1083             (declare (type index start1 start2 end1 end2))
1084             ,@(when check-bounds-p
1085                 `((unless (<= start1 end1 len1)
1086                     (oops pattern start1 end1))
1087                   (unless (<= start2 end2 len2)
1088                     (oops pattern start2 end2))))
1089             (when (= end1 start1)
1090               (return-from search (if from-end
1091                                       end2
1092                                       start2)))
1093             (do (,(if from-end
1094                       '(index2 (- end2 (- end1 start1)) (1- index2))
1095                       '(index2 start2 (1+ index2))))
1096                 (,(if from-end
1097                       '(< index2 start2)
1098                       '(>= index2 end2))
1099                  nil)
1100               ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
1101               ;; terminates is hits -1 when :FROM-END is true and :START2
1102               ;; is 0.
1103               (declare (type fixnum index2))
1104               (when (do ((index1 start1 (1+ index1))
1105                          (index2 index2 (1+ index2)))
1106                         ((>= index1 end1) t)
1107                       (declare (type index index1 index2)
1108                                (optimize (insert-array-bounds-checks 0)))
1109                       ,@(unless from-end
1110                           '((when (= index2 end2)
1111                               (return-from search nil))))
1112                       (unless (,@(if test?
1113                                      `(funcall test)
1114                                      `(eql))
1115                                ,(case key?
1116                                   (:yes `(funcall key (aref pattern index1)))
1117                                   (:maybe `(let ((elt (aref pattern index1)))
1118                                              (if key
1119                                                  (funcall key elt)
1120                                                  elt)))
1121                                   (otherwise `(aref pattern index1)))
1122                                ,(case key?
1123                                   (:yes `(funcall key (aref text index2)))
1124                                   (:maybe `(let ((elt (aref text index2)))
1125                                              (if key
1126                                                  (funcall key elt)
1127                                                  elt)))
1128                                   (otherwise `(aref text index2))))
1129                         (return nil)))
1130                 (return index2)))))))))
1131
1132
1133 ;;; Open-code CONCATENATE for strings. It would be possible to extend
1134 ;;; this transform to non-strings, but I chose to just do the case that
1135 ;;; should cover 95% of CONCATENATE performance complaints for now.
1136 ;;;   -- JES, 2007-11-17
1137 ;;;
1138 ;;; Only handle the simple result type cases. If somebody does (CONCATENATE
1139 ;;; '(STRING 6) ...) their code won't be optimized, but nobody does that in
1140 ;;; practice.
1141 ;;;
1142 ;;; Limit full open coding based on length of constant sequences. Default
1143 ;;; value is chosen so that other parts of to compiler (constraint propagation
1144 ;;; mainly) won't go nonlinear too badly. It's not an exact number -- but
1145 ;;; in the right ballpark.
1146 (defvar *concatenate-open-code-limit* 129)
1147
1148 (deftransform concatenate ((result-type &rest lvars)
1149                            ((constant-arg
1150                              (member string simple-string base-string simple-base-string))
1151                             &rest sequence)
1152                            * :node node)
1153   (let ((vars (loop for x in lvars collect (gensym)))
1154         (type (lvar-value result-type)))
1155     (if (policy node (<= speed space))
1156         ;; Out-of-line
1157         `(lambda (.dummy. ,@vars)
1158            (declare (ignore .dummy.))
1159            ,(ecase type
1160                    ((string simple-string)
1161                     `(%concatenate-to-string ,@vars))
1162                    ((base-string simple-base-string)
1163                     `(%concatenate-to-base-string ,@vars))))
1164         ;; Inline
1165         (let* ((element-type (ecase type
1166                                ((string simple-string) 'character)
1167                                ((base-string simple-base-string) 'base-char)))
1168                (lvar-values (loop for lvar in lvars
1169                                   collect (when (constant-lvar-p lvar)
1170                                             (lvar-value lvar))))
1171                (lengths
1172                 (loop for value in lvar-values
1173                       for var in vars
1174                       collect (if value
1175                                   (length value)
1176                                   `(sb!impl::string-dispatch ((simple-array * (*))
1177                                                               sequence)
1178                                        ,var
1179                                      (declare (muffle-conditions compiler-note))
1180                                      (length ,var))))))
1181           `(apply
1182             (lambda ,vars
1183               (declare (ignorable ,@vars))
1184               (declare (optimize (insert-array-bounds-checks 0)))
1185               (let* ((.length. (+ ,@lengths))
1186                      (.pos. 0)
1187                      (.string. (make-string .length. :element-type ',element-type)))
1188                 (declare (type index .length. .pos.)
1189                          (muffle-conditions compiler-note))
1190                 ,@(loop for value in lvar-values
1191                         for var in vars
1192                         collect (if (and (stringp value)
1193                                          (< (length value) *concatenate-open-code-limit*))
1194                                     ;; Fold the array reads for constant arguments
1195                                     `(progn
1196                                        ,@(loop for c across value
1197                                                for i from 0
1198                                                collect
1199                                                ;; Without truly-the we get massive numbers
1200                                                ;; of pointless error traps.
1201                                                   `(setf (aref .string.
1202                                                                (truly-the index (+ .pos. ,i)))
1203                                                          ,c))
1204                                        (incf .pos. ,(length value)))
1205                                     `(sb!impl::string-dispatch
1206                                          (#!+sb-unicode
1207                                           (simple-array character (*))
1208                                           (simple-array base-char (*))
1209                                           t)
1210                                          ,var
1211                                        (replace .string. ,var :start1 .pos.)
1212                                        (incf .pos. (length ,var)))))
1213                 .string.))
1214             lvars)))))
1215 \f
1216 ;;;; CONS accessor DERIVE-TYPE optimizers
1217
1218 (defoptimizer (car derive-type) ((cons))
1219   ;; This and CDR needs to use LVAR-CONSERVATIVE-TYPE because type inference
1220   ;; gets confused by things like (SETF CAR).
1221   (let ((type (lvar-conservative-type cons))
1222         (null-type (specifier-type 'null)))
1223     (cond ((eq type null-type)
1224            null-type)
1225           ((cons-type-p type)
1226            (cons-type-car-type type)))))
1227
1228 (defoptimizer (cdr derive-type) ((cons))
1229   (let ((type (lvar-conservative-type cons))
1230         (null-type (specifier-type 'null)))
1231     (cond ((eq type null-type)
1232            null-type)
1233           ((cons-type-p type)
1234            (cons-type-cdr-type type)))))
1235 \f
1236 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
1237
1238 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
1239 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
1240 ;;; expansion, so we factor out the condition into this function.
1241 (defun check-inlineability-of-find-position-if (sequence from-end)
1242   (let ((ctype (lvar-type sequence)))
1243     (cond ((csubtypep ctype (specifier-type 'vector))
1244            ;; It's not worth trying to inline vector code unless we
1245            ;; know a fair amount about it at compile time.
1246            (upgraded-element-type-specifier-or-give-up sequence)
1247            (unless (constant-lvar-p from-end)
1248              (give-up-ir1-transform
1249               "FROM-END argument value not known at compile time")))
1250           ((csubtypep ctype (specifier-type 'list))
1251            ;; Inlining on lists is generally worthwhile.
1252            )
1253           (t
1254            (give-up-ir1-transform
1255             "sequence type not known at compile time")))))
1256
1257 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
1258 (macrolet ((def (name condition)
1259              `(deftransform ,name ((predicate sequence from-end start end key)
1260                                    (function list t t t function)
1261                                    *
1262                                    :policy (> speed space))
1263                 "expand inline"
1264                 `(let ((find nil)
1265                        (position nil))
1266                    (flet ((bounds-error ()
1267                             (sequence-bounding-indices-bad-error sequence start end)))
1268                      (if (and end (> start end))
1269                          (bounds-error)
1270                          (do ((slow sequence (cdr slow))
1271                               (fast (cdr sequence) (cddr fast))
1272                               (index 0 (+ index 1)))
1273                              ((cond ((null slow)
1274                                      (if (and end (> end index))
1275                                          (bounds-error)
1276                                          (return (values find position))))
1277                                     ((and end (>= index end))
1278                                      (return (values find position)))
1279                                     ((eq slow fast)
1280                                      (circular-list-error sequence)))
1281                               (bug "never"))
1282                            (declare (list slow fast))
1283                            (when (>= index start)
1284                              (let* ((element (car slow))
1285                                     (key-i (funcall key element)))
1286                                (,',condition (funcall predicate key-i)
1287                                              ;; This hack of dealing with non-NIL
1288                                              ;; FROM-END for list data by iterating
1289                                              ;; forward through the list and keeping
1290                                              ;; track of the last time we found a
1291                                              ;; match might be more screwy than what
1292                                              ;; the user expects, but it seems to be
1293                                              ;; allowed by the ANSI standard. (And
1294                                              ;; if the user is screwy enough to ask
1295                                              ;; for FROM-END behavior on list data,
1296                                              ;; turnabout is fair play.)
1297                                              ;;
1298                                              ;; It's also not enormously efficient,
1299                                              ;; calling PREDICATE and KEY more often
1300                                              ;; than necessary; but all the
1301                                              ;; alternatives seem to have their own
1302                                              ;; efficiency problems.
1303                                              (if from-end
1304                                                  (setf find element
1305                                                        position index)
1306                                                  (return (values element index)))))))))))))
1307   (def %find-position-if when)
1308   (def %find-position-if-not unless))
1309
1310 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
1311 ;;; without loss of efficiency. (I.e., the optimizer should be able
1312 ;;; to straighten everything out.)
1313 (deftransform %find-position ((item sequence from-end start end key test)
1314                               (t list t t t t t)
1315                               *
1316                               :policy (> speed space))
1317   "expand inline"
1318   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
1319                         ;; The order of arguments for asymmetric tests
1320                         ;; (e.g. #'<, as opposed to order-independent
1321                         ;; tests like #'=) is specified in the spec
1322                         ;; section 17.2.1 -- the O/Zi stuff there.
1323                         (lambda (i)
1324                           (funcall test-fun item i)))
1325                       sequence
1326                       from-end
1327                       start
1328                       end
1329                       (%coerce-callable-to-fun key)))
1330
1331 ;;; The inline expansions for the VECTOR case are saved as macros so
1332 ;;; that we can share them between the DEFTRANSFORMs and the default
1333 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
1334 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1335 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1336                                                             from-end
1337                                                             start
1338                                                             end-arg
1339                                                             element
1340                                                             done-p-expr)
1341   (with-unique-names (offset block index n-sequence sequence end)
1342     `(let* ((,n-sequence ,sequence-arg))
1343        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1344                          (,start ,start)
1345                          (,end ,end-arg)
1346                          :check-fill-pointer t)
1347          (block ,block
1348            (macrolet ((maybe-return ()
1349                         ;; WITH-ARRAY-DATA has already performed bounds
1350                         ;; checking, so we can safely elide the checks
1351                         ;; in the inner loop.
1352                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1353                                            (aref ,sequence ,index))))
1354                           (when ,done-p-expr
1355                             (return-from ,block
1356                               (values ,element
1357                                       (- ,index ,offset)))))))
1358              (if ,from-end
1359                  (loop for ,index
1360                        ;; (If we aren't fastidious about declaring that
1361                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1362                        ;; can send us off into never-never land, since
1363                        ;; INDEX is initialized to -1.)
1364                        of-type index-or-minus-1
1365                        from (1- ,end) downto ,start do
1366                        (maybe-return))
1367                  (loop for ,index of-type index from ,start below ,end do
1368                           (maybe-return))))
1369            (values nil nil))))))
1370
1371 (def!macro %find-position-vector-macro (item sequence
1372                                              from-end start end key test)
1373   (with-unique-names (element)
1374     (%find-position-or-find-position-if-vector-expansion
1375      sequence
1376      from-end
1377      start
1378      end
1379      element
1380      ;; (See the LIST transform for a discussion of the correct
1381      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1382      ;; or after the checked sequence element.)
1383      `(funcall ,test ,item (funcall ,key ,element)))))
1384
1385 (def!macro %find-position-if-vector-macro (predicate sequence
1386                                                      from-end start end key)
1387   (with-unique-names (element)
1388     (%find-position-or-find-position-if-vector-expansion
1389      sequence
1390      from-end
1391      start
1392      end
1393      element
1394      `(funcall ,predicate (funcall ,key ,element)))))
1395
1396 (def!macro %find-position-if-not-vector-macro (predicate sequence
1397                                                          from-end start end key)
1398   (with-unique-names (element)
1399     (%find-position-or-find-position-if-vector-expansion
1400      sequence
1401      from-end
1402      start
1403      end
1404      element
1405      `(not (funcall ,predicate (funcall ,key ,element))))))
1406
1407 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1408 ;;; VECTOR data
1409 (deftransform %find-position-if ((predicate sequence from-end start end key)
1410                                  (function vector t t t function)
1411                                  *
1412                                  :policy (> speed space))
1413   "expand inline"
1414   (check-inlineability-of-find-position-if sequence from-end)
1415   '(%find-position-if-vector-macro predicate sequence
1416                                    from-end start end key))
1417
1418 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1419                                      (function vector t t t function)
1420                                      *
1421                                      :policy (> speed space))
1422   "expand inline"
1423   (check-inlineability-of-find-position-if sequence from-end)
1424   '(%find-position-if-not-vector-macro predicate sequence
1425                                        from-end start end key))
1426
1427 (deftransform %find-position ((item sequence from-end start end key test)
1428                               (t vector t t t function function)
1429                               *
1430                               :policy (> speed space))
1431   "expand inline"
1432   (check-inlineability-of-find-position-if sequence from-end)
1433   '(%find-position-vector-macro item sequence
1434     from-end start end key test))
1435
1436 (deftransform %find-position ((item sequence from-end start end key test)
1437                               (character string t t t function function)
1438                               *
1439                               :policy (> speed space))
1440   (if (eq '* (upgraded-element-type-specifier sequence))
1441       (let ((form
1442              `(sb!impl::string-dispatch ((simple-array character (*))
1443                                          (simple-array base-char (*))
1444                                          (simple-array nil (*)))
1445                   sequence
1446                 (%find-position item sequence from-end start end key test))))
1447         (if (csubtypep (lvar-type sequence) (specifier-type 'simple-string))
1448             form
1449             ;; Otherwise we'd get three instances of WITH-ARRAY-DATA from
1450             ;; %FIND-POSITION.
1451             `(with-array-data ((sequence sequence :offset-var offset)
1452                                (start start)
1453                                (end end)
1454                                :check-fill-pointer t)
1455                (multiple-value-bind (elt index) ,form
1456                  (values elt (when (fixnump index) (- index offset)))))))
1457       ;; The type is known exactly, other transforms will take care of it.
1458       (give-up-ir1-transform)))
1459
1460 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1461 ;;; POSITION-IF, etc.
1462 (define-source-transform effective-find-position-test (test test-not)
1463   (once-only ((test test)
1464               (test-not test-not))
1465     `(cond
1466       ((and ,test ,test-not)
1467        (error "can't specify both :TEST and :TEST-NOT"))
1468       (,test (%coerce-callable-to-fun ,test))
1469       (,test-not
1470        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1471        ;; inefficient, but since the TEST-NOT option is deprecated
1472        ;; anyway, we don't care.)
1473        (complement (%coerce-callable-to-fun ,test-not)))
1474       (t #'eql))))
1475 (define-source-transform effective-find-position-key (key)
1476   (once-only ((key key))
1477     `(if ,key
1478          (%coerce-callable-to-fun ,key)
1479          #'identity)))
1480
1481 (macrolet ((define-find-position (fun-name values-index)
1482              `(deftransform ,fun-name ((item sequence &key
1483                                              from-end (start 0) end
1484                                              key test test-not)
1485                                        (t (or list vector) &rest t))
1486                 '(nth-value ,values-index
1487                             (%find-position item sequence
1488                                             from-end start
1489                                             end
1490                                             (effective-find-position-key key)
1491                                             (effective-find-position-test
1492                                              test test-not))))))
1493   (define-find-position find 0)
1494   (define-find-position position 1))
1495
1496 (macrolet ((define-find-position-if (fun-name values-index)
1497              `(deftransform ,fun-name ((predicate sequence &key
1498                                                   from-end (start 0)
1499                                                   end key)
1500                                        (t (or list vector) &rest t))
1501                 '(nth-value
1502                   ,values-index
1503                   (%find-position-if (%coerce-callable-to-fun predicate)
1504                                      sequence from-end
1505                                      start end
1506                                      (effective-find-position-key key))))))
1507   (define-find-position-if find-if 0)
1508   (define-find-position-if position-if 1))
1509
1510 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1511 ;;; didn't bother to worry about optimizing them, except note that on
1512 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1513 ;;; sbcl-devel
1514 ;;;
1515 ;;;     My understanding is that while the :test-not argument is
1516 ;;;     deprecated in favour of :test (complement #'foo) because of
1517 ;;;     semantic difficulties (what happens if both :test and :test-not
1518 ;;;     are supplied, etc) the -if-not variants, while officially
1519 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1520 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1521 ;;;     reasons for allowing the -if-not versions equal status,
1522 ;;;     particularly remove-if-not (== filter).
1523 ;;;
1524 ;;;     This is only an informal understanding, I grant you, but
1525 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1526 ;;;     way as the others?
1527 ;;;
1528 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1529 ;;; implementation of SBCL.
1530 (macrolet ((define-find-position-if-not (fun-name values-index)
1531                `(deftransform ,fun-name ((predicate sequence &key
1532                                           from-end (start 0)
1533                                           end key)
1534                                          (t (or list vector) &rest t))
1535                  '(nth-value
1536                    ,values-index
1537                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1538                     sequence from-end
1539                     start end
1540                     (effective-find-position-key key))))))
1541   (define-find-position-if-not find-if-not 0)
1542   (define-find-position-if-not position-if-not 1))
1543
1544 (macrolet ((define-trimmer-transform (fun-name leftp rightp)
1545              `(deftransform ,fun-name ((char-bag string)
1546                                        (t simple-string))
1547                 (let ((find-expr
1548                        (if (constant-lvar-p char-bag)
1549                            ;; If the bag is constant, use MEMBER
1550                            ;; instead of FIND, since we have a
1551                            ;; deftransform for MEMBER that can
1552                            ;; open-code all of the comparisons when
1553                            ;; the list is constant. -- JES, 2007-12-10
1554                            `(not (member (schar string index)
1555                                          ',(coerce (lvar-value char-bag) 'list)
1556                                          :test #'char=))
1557                            '(not (find (schar string index) char-bag :test #'char=)))))
1558                   `(flet ((char-not-in-bag (index)
1559                             ,find-expr))
1560                      (let* ((end (length string))
1561                             (left-end (if ,',leftp
1562                                           (do ((index 0 (1+ index)))
1563                                               ((or (= index (the fixnum end))
1564                                                    (char-not-in-bag index))
1565                                                index)
1566                                             (declare (fixnum index)))
1567                                           0))
1568                             (right-end (if ,',rightp
1569                                            (do ((index (1- end) (1- index)))
1570                                                ((or (< index left-end)
1571                                                     (char-not-in-bag index))
1572                                                 (1+ index))
1573                                              (declare (fixnum index)))
1574                                            end)))
1575                        (if (and (eql left-end 0)
1576                                 (eql right-end (length string)))
1577                            string
1578                            (subseq string left-end right-end))))))))
1579   (define-trimmer-transform string-left-trim t nil)
1580   (define-trimmer-transform string-right-trim nil t)
1581   (define-trimmer-transform string-trim t t))
1582