src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places))
 137     (let ((found-vector-p nil))
 138       (flet ((process-vector (length)
 139                (unless found-vector-p
 140                  (setq found-vector-p t)
 141                  (bindings `(index 0 (1+ index)))
 142                  (declarations `(type index index)))
 143                (vector-lengths length)))
 144         (loop for seq of-type lvar in seqs
 145            for seq-name in seq-names
 146            for type = (lvar-type seq)
 147            do (cond ((csubtypep type (specifier-type 'list))
 148                      (with-unique-names (index)
 149                        (bindings `(,index ,seq-name (cdr ,index)))
 150                        (declarations `(type list ,index))
 151                        (places `(car ,index))
 152                        (tests `(endp ,index))))
 153                     ((csubtypep type (specifier-type 'vector))
 154                      (process-vector `(length ,seq-name))
 155                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 156                                 (aref ,seq-name index))))
 157                     (t
 158                      (give-up-ir1-transform
 159                       "can't determine sequence argument type"))))
 160         (when into
 161           (process-vector `(array-dimension ,into 0))))
 162       (when found-vector-p
 163         (bindings `(length (min ,@(vector-lengths))))
 164         (tests `(>= index length)))
 165       `(do (,@(bindings))
 166            ((or ,@(tests)) ,result)
 167          (declare ,@(declarations))
 168          (let ((funcall-result (funcall fun ,@(places))))
 169            (declare (ignorable funcall-result))
 170            ,body)))))
 171
 172 ;;; Try to compile %MAP efficiently when we can determine sequence
 173 ;;; argument types at compile time.
 174 ;;;
 175 ;;; Note: This transform was written to allow open coding of
 176 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 177 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 178 ;;; necessarily as efficient as possible. In particular, it will be
 179 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 180 ;;; numeric element types. It should be straightforward to make it
 181 ;;; handle that case more efficiently, but it's left as an exercise to
 182 ;;; the reader, because the code is complicated enough already and I
 183 ;;; don't happen to need that functionality right now. -- WHN 20000410
 184 (deftransform %map ((result-type fun seq &rest seqs) * *
 185                     :policy (>= speed space))
 186   "open code"
 187   (unless (constant-lvar-p result-type)
 188     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 189   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 190            (fn-1subtypep (fn x y)
 191              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 192                (if valid-p
 193                    subtype-p
 194                    (give-up-ir1-transform
 195                     "can't analyze sequence type relationship"))))
 196            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 197     (let* ((result-type-value (lvar-value result-type))
 198            (result-supertype (cond ((null result-type-value) 'null)
 199                                    ((1subtypep result-type-value 'vector)
 200                                     'vector)
 201                                    ((1subtypep result-type-value 'list)
 202                                     'list)
 203                                    (t
 204                                     (give-up-ir1-transform
 205                                      "result type unsuitable")))))
 206       (cond ((and result-type-value (null seqs))
 207              ;; The consing arity-1 cases can be implemented
 208              ;; reasonably efficiently as function calls, and the cost
 209              ;; of consing should be significantly larger than
 210              ;; function call overhead, so we always compile these
 211              ;; cases as full calls regardless of speed-versus-space
 212              ;; optimization policy.
 213              (cond ((subtypep result-type-value 'list)
 214                     '(%map-to-list-arity-1 fun seq))
 215                    ( ;; (This one can be inefficient due to COERCE, but
 216                     ;; the current open-coded implementation has the
 217                     ;; same problem.)
 218                     (subtypep result-type-value 'vector)
 219                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 220                              ',result-type-value))
 221                    (t (bug "impossible (?) sequence type"))))
 222             (t
 223              (let* ((seqs (cons seq seqs))
 224                     (seq-args (make-gensym-list (length seqs))))
 225                (multiple-value-bind (push-dacc result)
 226                    (ecase result-supertype
 227                      (null (values nil nil))
 228                      (list (values `(push funcall-result acc)
 229                                    `(nreverse acc)))
 230                      (vector (values `(push funcall-result acc)
 231                                      `(coerce (nreverse acc)
 232                                               ',result-type-value))))
 233                  ;; (We use the same idiom, of returning a LAMBDA from
 234                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 235                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 236                  ;; reason: we need to get the runtime values of each
 237                  ;; of the &REST vars.)
 238                  `(lambda (result-type fun ,@seq-args)
 239                     (declare (ignore result-type))
 240                     (let ((fun (%coerce-callable-to-fun fun))
 241                           (acc nil))
 242                       (declare (type list acc))
 243                       (declare (ignorable acc))
 244                       ,(build-sequence-iterator
 245                         seqs seq-args
 246                         :result result
 247                         :body push-dacc))))))))))
 248
 249 ;;; MAP-INTO
 250 (deftransform map-into ((result fun &rest seqs)
 251                         (vector * &rest *)
 252                         *)
 253   "open code"
 254   (let ((seqs-names (mapcar (lambda (x)
 255                               (declare (ignore x))
 256                               (gensym))
 257                             seqs)))
 258     `(lambda (result fun ,@seqs-names)
 259        ,(build-sequence-iterator
 260          seqs seqs-names
 261          :result '(when (array-has-fill-pointer-p result)
 262                    (setf (fill-pointer result) index))
 263          :into 'result
 264          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 265                  (setf (aref result index) funcall-result)))
 266        result)))
 267
 268 \f
 269 ;;; FIXME: once the confusion over doing transforms with known-complex
 270 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 271 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 272 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 273   '(aref s i))
 274
 275 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 276   '(nth i s))
 277
 278 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 279   '(%aset s i v))
 280
 281 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 282   '(setf (car (nthcdr i s)) v))
 283
 284 (deftransform %check-vector-sequence-bounds ((vector start end)
 285                                              (vector * *) *
 286                                              :node node)
 287   (if (policy node (< safety speed))
 288       '(or end (length vector))
 289       '(let ((length (length vector)))
 290         (if (<= 0 start (or end length) length)
 291             (or end length)
 292             (sb!impl::signal-bounding-indices-bad-error vector start end)))))
 293
 294
 295 (deftransform member ((item list &key key test test-not) * * :node node)
 296   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 297   ;; not there at all. If it might be NIL, make up a form to that
 298   ;; ensure it is a function.
 299   (multiple-value-bind (key key-form)
 300       (if key
 301           (let ((key-type (lvar-type key))
 302                 (null-type (specifier-type 'null)))
 303             (cond ((csubtypep key-type null-type)
 304                    (values nil nil))
 305                   ((csubtypep null-type key-type)
 306                    (values key '(if key
 307                                  (%coerce-callable-to-fun key)
 308                                  #'identity)))
 309                   (t
 310                    (values key '(%coerce-callable-to-fun key))))))
 311     (multiple-value-bind (out-of-line funs test-expr)
 312         (cond ((and (not key) (not test) (not test-not))
 313                (values '%member
 314                        '()
 315                        '(eql item car)))
 316               ((and key (not test) (not test-not))
 317                (values '%member-key
 318                        '(key)
 319                        '(eql item (%funcall key car))))
 320               ((and key test)
 321                (values '%member-key-test
 322                        '(key test)
 323                        '(%funcall test item (%funcall key car))))
 324               ((and key test-not)
 325                (values '%member-key-test-not
 326                        '(key test-not)
 327                        '(not (%funcall test-not item (%funcall key car)))))
 328               (test
 329                (values '%member-test
 330                        '(test)
 331                        '(%funcall test item car)))
 332               (test-not
 333                (values '%member-test-not
 334                        '(test-not)
 335                        '(not (%funcall test item car))))
 336               (t
 337                (bug "never")))
 338       (labels ((open-code (tail)
 339                  (when tail
 340                    `(if (let ((car ',(car tail)))
 341                           ,test-expr)
 342                         ',tail
 343                         ,(open-code (cdr tail)))))
 344                (ensure-fun (fun)
 345                  (if (eq 'key fun)
 346                      key-form
 347                      `(%coerce-callable-to-fun ,fun))))
 348         (if (and (constant-lvar-p list) (policy node (>= speed space)))
 349             `(let ,(mapcar (lambda (fun) `(,fun ,(ensure-fun fun))) funs)
 350                ,(open-code (lvar-value list)))
 351             `(,out-of-line item list ,@(mapcar #'ensure-fun funs)))))))
 352
 353 (deftransform memq ((item list) (t (constant-arg list)))
 354   (labels ((rec (tail)
 355              (if tail
 356                  `(if (eq item ',(car tail))
 357                       ',tail
 358                       ,(rec (cdr tail)))
 359                  nil)))
 360     (rec (lvar-value list))))
 361
 362 ;;; FIXME: We have rewritten the original code that used DOLIST to this
 363 ;;; more natural MACROLET.  However, the original code suggested that when
 364 ;;; this was done, a few bytes could be saved by a call to a shared
 365 ;;; function.  This remains to be done.
 366 (macrolet ((def (fun eq-fun)
 367              `(deftransform ,fun ((item list &key test) (t list &rest t) *)
 368                 "convert to EQ test"
 369                 ;; FIXME: The scope of this transformation could be
 370                 ;; widened somewhat, letting it work whenever the test is
 371                 ;; 'EQL and we know from the type of ITEM that it #'EQ
 372                 ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 373                 ;; and SYMBOL.)
 374                 ;;   If TEST is EQ, apply transform, else
 375                 ;;   if test is not EQL, then give up on transform, else
 376                 ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 377                 ;;   transform, else give up on transform.
 378                 (cond (test
 379                        (unless (lvar-fun-is test '(eq))
 380                          (give-up-ir1-transform)))
 381                       ((types-equal-or-intersect (lvar-type item)
 382                                                  (specifier-type 'number))
 383                        (give-up-ir1-transform "Item might be a number.")))
 384                 `(,',eq-fun item list))))
 385   (def delete delq)
 386   (def assoc assq)
 387   (def member memq))
 388
 389 (deftransform delete-if ((pred list) (t list))
 390   "open code"
 391   '(do ((x list (cdr x))
 392         (splice '()))
 393        ((endp x) list)
 394      (cond ((funcall pred (car x))
 395             (if (null splice)
 396                 (setq list (cdr x))
 397                 (rplacd splice (cdr x))))
 398            (t (setq splice x)))))
 399
 400 (deftransform fill ((seq item &key (start 0) (end (length seq)))
 401                     (vector t &key (:start t) (:end index))
 402                     *
 403                     :policy (> speed space))
 404   "open code"
 405   (let ((element-type (upgraded-element-type-specifier-or-give-up seq)))
 406     (values
 407      `(with-array-data ((data seq)
 408                         (start start)
 409                         (end end))
 410        (declare (type (simple-array ,element-type 1) data))
 411        (declare (type fixnum start end))
 412        (do ((i start (1+ i)))
 413            ((= i end) seq)
 414          (declare (type index i))
 415          ;; WITH-ARRAY-DATA did our range checks once and for all, so
 416          ;; it'd be wasteful to check again on every AREF...
 417          (declare (optimize (safety 0)))
 418          (setf (aref data i) item)))
 419      ;; ... though we still need to check that the new element can fit
 420      ;; into the vector in safe code. -- CSR, 2002-07-05
 421      `((declare (type ,element-type item))))))
 422 \f
 423 ;;;; utilities
 424
 425 ;;; Return true if LVAR's only use is a non-NOTINLINE reference to a
 426 ;;; global function with one of the specified NAMES.
 427 (defun lvar-fun-is (lvar names)
 428   (declare (type lvar lvar) (list names))
 429   (let ((use (lvar-uses lvar)))
 430     (and (ref-p use)
 431          (let ((leaf (ref-leaf use)))
 432            (and (global-var-p leaf)
 433                 (eq (global-var-kind leaf) :global-function)
 434                 (not (null (member (leaf-source-name leaf) names
 435                                    :test #'equal))))))))
 436
 437 ;;; If LVAR is a constant lvar, the return the constant value. If it
 438 ;;; is null, then return default, otherwise quietly give up the IR1
 439 ;;; transform.
 440 ;;;
 441 ;;; ### Probably should take an ARG and flame using the NAME.
 442 (defun constant-value-or-lose (lvar &optional default)
 443   (declare (type (or lvar null) lvar))
 444   (cond ((not lvar) default)
 445         ((constant-lvar-p lvar)
 446          (lvar-value lvar))
 447         (t
 448          (give-up-ir1-transform))))
 449
 450
 451 ;;;; hairy sequence transforms
 452
 453 ;;; FIXME: no hairy sequence transforms in SBCL?
 454 ;;;
 455 ;;; There used to be a bunch of commented out code about here,
 456 ;;; containing the (apparent) beginning of hairy sequence transform
 457 ;;; infrastructure. People interested in implementing better sequence
 458 ;;; transforms might want to look at it for inspiration, even though
 459 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 460 ;;; was deleted in 1.0.7.23.
 461 \f
 462 ;;;; string operations
 463
 464 ;;; We transform the case-sensitive string predicates into a non-keyword
 465 ;;; version. This is an IR1 transform so that we don't have to worry about
 466 ;;; changing the order of evaluation.
 467 (macrolet ((def (fun pred*)
 468              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 469                                                          (start2 0) end2)
 470                                    * *)
 471                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 472   (def string< string<*)
 473   (def string> string>*)
 474   (def string<= string<=*)
 475   (def string>= string>=*)
 476   (def string= string=*)
 477   (def string/= string/=*))
 478
 479 ;;; Return a form that tests the free variables STRING1 and STRING2
 480 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 481 ;;; start and end are also gotten from the environment. Both strings
 482 ;;; must be SIMPLE-BASE-STRINGs.
 483 (macrolet ((def (name lessp equalp)
 484              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 485                                    (simple-base-string simple-base-string t t t t) *)
 486                 `(let* ((end1 (if (not end1) (length string1) end1))
 487                         (end2 (if (not end2) (length string2) end2))
 488                         (index (sb!impl::%sp-string-compare
 489                                 string1 start1 end1 string2 start2 end2)))
 490                   (if index
 491                       (cond ((= index end1)
 492                              ,(if ',lessp 'index nil))
 493                             ((= (+ index (- start2 start1)) end2)
 494                              ,(if ',lessp nil 'index))
 495                             ((,(if ',lessp 'char< 'char>)
 496                                (schar string1 index)
 497                                (schar string2
 498                                       (truly-the index
 499                                                  (+ index
 500                                                     (truly-the fixnum
 501                                                                (- start2
 502                                                                   start1))))))
 503                              index)
 504                             (t nil))
 505                       ,(if ',equalp 'end1 nil))))))
 506   (def string<* t nil)
 507   (def string<=* t t)
 508   (def string>* nil nil)
 509   (def string>=* nil t))
 510
 511 (macrolet ((def (name result-fun)
 512              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 513                                    (simple-base-string simple-base-string t t t t) *)
 514                 `(,',result-fun
 515                   (sb!impl::%sp-string-compare
 516                    string1 start1 (or end1 (length string1))
 517                    string2 start2 (or end2 (length string2)))))))
 518   (def string=* not)
 519   (def string/=* identity))
 520
 521 \f
 522 ;;;; transforms for sequence functions
 523
 524 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 525 ;;; to vectors based on simple arrays.
 526 (def!constant vector-data-bit-offset
 527   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 528
 529 (eval-when (:compile-toplevel)
 530 (defun valid-bit-bash-saetp-p (saetp)
 531   ;; BIT-BASHing isn't allowed on simple vectors that contain pointers
 532   (and (not (eq t (sb!vm:saetp-specifier saetp)))
 533        ;; Disallowing (VECTOR NIL) also means that we won't transform
 534        ;; sequence functions into bit-bashing code and we let the
 535        ;; generic sequence functions signal errors if necessary.
 536        (not (zerop (sb!vm:saetp-n-bits saetp)))
 537        ;; Due to limitations with the current BIT-BASHing code, we can't
 538        ;; BIT-BASH reliably on arrays whose element types are larger
 539        ;; than the word size.
 540        (<= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)))
 541 ) ; EVAL-WHEN
 542
 543 ;;; FIXME: In the copy loops below, we code the loops in a strange
 544 ;;; fashion:
 545 ;;;
 546 ;;; (do ((i (+ src-offset length) (1- i)))
 547 ;;;     ((<= i 0) ...)
 548 ;;;   (... (aref foo (1- i)) ...))
 549 ;;;
 550 ;;; rather than the more natural (and seemingly more efficient):
 551 ;;;
 552 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 553 ;;;     ((< i 0) ...)
 554 ;;;   (... (aref foo i) ...))
 555 ;;;
 556 ;;; (more efficient because we don't have to do the index adjusting on
 557 ;;; every iteration of the loop)
 558 ;;;
 559 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 560 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 561 ;;; when used as an array index, the backend thinks I is a
 562 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 563 ;;; these as distinct storage classes, it cannot coerce a move from a
 564 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 565 ;;; deficiency is that we have two extra moves and increased register
 566 ;;; pressure, which can lead to some spectacularly bad register
 567 ;;; allocation.  (sub-FIXME: the register allocation even with the
 568 ;;; strangely written loops is not always excellent, either...).  Doing
 569 ;;; it the first way, above, means that I is always thought of as a
 570 ;;; POSITIVE-FIXNUM and there are no issues.
 571 ;;;
 572 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 573 ;;; adjustments in the first version into the array addressing at no
 574 ;;; performance penalty!
 575
 576 ;;; This transform is critical to the performance of string streams.  If
 577 ;;; you tweak it, make sure that you compare the disassembly, if not the
 578 ;;; performance of, the functions implementing string streams
 579 ;;; (e.g. SB!IMPL::STRING-OUCH).
 580 (macrolet
 581     ((define-replace-transforms ()
 582        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 583              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 584              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 585              collect
 586             `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 587                                     (,sequence-type ,sequence-type &rest t)
 588                                     ,sequence-type
 589                                     :node node)
 590                ,(cond
 591                  ((valid-bit-bash-saetp-p saetp) nil)
 592                  ;; If we're not bit-bashing, only allow cases where we
 593                  ;; can determine the order of copying up front.  (There
 594                  ;; are actually more cases we can handle if we know the
 595                  ;; amount that we're copying, but this handles the
 596                  ;; common cases.)
 597                  (t '(unless (= (constant-value-or-lose start1 0)
 598                               (constant-value-or-lose start2 0))
 599                       (give-up-ir1-transform))))
 600                `(let* ((len1 (length seq1))
 601                        (len2 (length seq2))
 602                        (end1 (or end1 len1))
 603                        (end2 (or end2 len2))
 604                        (replace-len1 (- end1 start1))
 605                        (replace-len2 (- end2 start2)))
 606                   ,(unless (policy node (= safety 0))
 607                            `(progn
 608                               (unless (<= 0 start1 end1 len1)
 609                                 (sb!impl::signal-bounding-indices-bad-error seq1 start1 end1))
 610                               (unless (<= 0 start2 end2 len2)
 611                                 (sb!impl::signal-bounding-indices-bad-error seq2 start2 end2))))
 612                   ,',(cond
 613                       ((valid-bit-bash-saetp-p saetp)
 614                        (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 615                               (bash-function (intern (format nil "UB~D-BASH-COPY" n-element-bits)
 616                                                      (find-package "SB!KERNEL"))))
 617                          `(funcall (function ,bash-function) seq2 start2
 618                                    seq1 start1 (min replace-len1 replace-len2))))
 619                       (t
 620                        ;; We can expand the loop inline here because we
 621                        ;; would have given up the transform (see above)
 622                        ;; if we didn't have constant matching start
 623                        ;; indices.
 624                        '(do ((i start1 (1+ i))
 625                              (end (+ start1
 626                                      (min replace-len1 replace-len2))))
 627                          ((>= i end))
 628                          (declare (optimize (insert-array-bounds-checks 0)))
 629                          (setf (aref seq1 i) (aref seq2 i)))))
 630                   seq1))
 631              into forms
 632              finally (return `(progn ,@forms)))))
 633   (define-replace-transforms))
 634
 635 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 636 ;;; defined as those cases where we are doing word-aligned copies from
 637 ;;; both the source and the destination and we are copying from the same
 638 ;;; offset from both the source and the destination.  (The last
 639 ;;; condition is there so we can determine the direction to copy at
 640 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 641 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 642 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 643 ;;; N)-size buffer and blitting in the old N-size buffer in.
 644
 645 (defun frob-bash-transform (src src-offset
 646                             dst dst-offset
 647                             length n-elems-per-word)
 648   (declare (ignore src dst length))
 649   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 650     (multiple-value-bind (src-word src-elt)
 651         (truncate (lvar-value src-offset) n-elems-per-word)
 652       (multiple-value-bind (dst-word dst-elt)
 653           (truncate (lvar-value dst-offset) n-elems-per-word)
 654         ;; Avoid non-word aligned copies.
 655         (unless (and (zerop src-elt) (zerop dst-elt))
 656           (give-up-ir1-transform))
 657         ;; Avoid copies where we would have to insert code for
 658         ;; determining the direction of copying.
 659         (unless (= src-word dst-word)
 660           (give-up-ir1-transform))
 661         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 662         ;; so we have to do its work here.
 663         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 664                                       'length
 665                                       `(truncate (the index length) ,n-elems-per-word)))))
 666            (declare (type index end))
 667            ;; Handle any bits at the end.
 668            (when (logtest length (1- ,n-elems-per-word))
 669              (let* ((extra (mod length ,n-elems-per-word))
 670                     ;; FIXME: The shift amount on this ASH is
 671                     ;; *always* negative, but the backend doesn't
 672                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 673                     ;; wind up with a pile of code that tests the
 674                     ;; sign of the shift count prior to shifting when
 675                     ;; all we need is a simple negate and shift
 676                     ;; right.  Yuck.
 677                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 678                                (* (- extra ,n-elems-per-word)
 679                                   ,n-bits-per-elem))))
 680                (setf (sb!kernel:%vector-raw-bits dst end)
 681                      (logior
 682                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 683                                 (ash mask
 684                                      ,(ecase sb!c:*backend-byte-order*
 685                                              (:little-endian 0)
 686                                              (:big-endian `(* (- ,n-elems-per-word extra)
 687                                                               ,n-bits-per-elem)))))
 688                       (logand (sb!kernel:%vector-raw-bits src end)
 689                               (ash mask
 690                                    ,(ecase sb!c:*backend-byte-order*
 691                                            (:little-endian 0)
 692                                            (:big-endian `(* (- ,n-elems-per-word extra)
 693                                                             ,n-bits-per-elem)))))))))
 694            ;; Copy from the end to save a register.
 695            (do ((i end (1- i)))
 696                ((<= i ,src-word))
 697              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 698                    (sb!kernel:%vector-raw-bits src (1- i)))))))))
 699
 700 #.(loop for i = 1 then (* i 2)
 701         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 702                                         "SB!KERNEL")
 703                                                         ((src src-offset
 704                                                           dst dst-offset
 705                                                           length)
 706                                                         ((simple-unboxed-array (*))
 707                                                          (constant-arg index)
 708                                                          (simple-unboxed-array (*))
 709                                                          (constant-arg index)
 710                                                          index)
 711                                                         *)
 712                   (frob-bash-transform src src-offset
 713                                        dst dst-offset length
 714                                        ,(truncate sb!vm:n-word-bits i))) into forms
 715         until (= i sb!vm:n-word-bits)
 716         finally (return `(progn ,@forms)))
 717
 718 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 719 ;;; arrays with elements of size >= the word size.  We do this because
 720 ;;; we know the arrays cannot alias (one was just consed), therefore we
 721 ;;; can determine at compile time the direction to copy, and for
 722 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 723 ;;; needless checking to figure out what's going on.  The same
 724 ;;; considerations apply if we are copying elements larger than the word
 725 ;;; size, with the additional twist that doing it inline is likely to
 726 ;;; cons far less than calling REPLACE and letting generic code do the
 727 ;;; work.
 728 ;;;
 729 ;;; However, we do not do this for elements whose size is < than the
 730 ;;; word size because we don't want to deal with any alignment issues
 731 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 732 ;;; anyway.
 733
 734 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 735                                       element-type)
 736   (let ((saetp (find-saetp element-type)))
 737     (aver saetp)
 738     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 739         (expand-aref-copy-loop src src-offset dst dst-offset length)
 740         `(locally (declare (optimize (safety 0)))
 741            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 742
 743 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 744   (if (eql src-offset dst-offset)
 745       `(do ((i (+ ,src-offset ,length) (1- i)))
 746            ((<= i ,src-offset))
 747          (declare (optimize (insert-array-bounds-checks 0)))
 748          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 749       ;; KLUDGE: The compiler is not able to derive that (+ offset
 750       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 751       ;; We, however, know it must be so, as by this point the bounds
 752       ;; have already been checked.
 753       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 754             (j (+ ,dst-offset ,length) (1- j)))
 755            ((<= i ,src-offset))
 756          (declare (optimize (insert-array-bounds-checks 0))
 757                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 758          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 759
 760 (deftransform subseq ((seq start &optional end)
 761                       ((or (simple-unboxed-array (*)) simple-vector) t &optional t)
 762                       * :node node)
 763   (let ((array-type (lvar-type seq)))
 764     (unless (array-type-p array-type)
 765       (give-up-ir1-transform))
 766     (let ((element-type (type-specifier (array-type-specialized-element-type array-type))))
 767       `(let* ((length (length seq))
 768               (end (or end length)))
 769          ,(unless (policy node (= safety 0))
 770                   '(progn
 771                     (unless (<= 0 start end length)
 772                       (sb!impl::signal-bounding-indices-bad-error seq start end))))
 773          (let* ((size (- end start))
 774                 (result (make-array size :element-type ',element-type)))
 775            ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
 776                                                     (lvar-value start)
 777                                                     'start)
 778                                            'result 0 'size element-type)
 779            result)))))
 780
 781 (deftransform copy-seq ((seq) ((or (simple-unboxed-array (*)) simple-vector)) *)
 782   (let ((array-type (lvar-type seq)))
 783     (unless (array-type-p array-type)
 784       (give-up-ir1-transform))
 785     (let ((element-type (type-specifier (array-type-specialized-element-type array-type))))
 786       `(let* ((length (length seq))
 787               (result (make-array length :element-type ',element-type)))
 788          ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
 789          result))))
 790
 791 ;;; FIXME: it really should be possible to take advantage of the
 792 ;;; macros used in code/seq.lisp here to avoid duplication of code,
 793 ;;; and enable even funkier transformations.
 794 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
 795                                (test #'eql)
 796                                (key #'identity)
 797                                from-end)
 798                       (vector vector &rest t)
 799                       *
 800                       :policy (> speed (max space safety)))
 801   "open code"
 802   (let ((from-end (when (lvar-p from-end)
 803                     (unless (constant-lvar-p from-end)
 804                       (give-up-ir1-transform ":FROM-END is not constant."))
 805                     (lvar-value from-end)))
 806         (keyp (lvar-p key))
 807         (testp (lvar-p test)))
 808     `(block search
 809        (let ((end1 (or end1 (length pattern)))
 810              (end2 (or end2 (length text)))
 811              ,@(when keyp
 812                      '((key (coerce key 'function))))
 813              ,@(when testp
 814                      '((test (coerce test 'function)))))
 815          (declare (type index start1 start2 end1 end2))
 816          (do (,(if from-end
 817                    '(index2 (- end2 (- end1 start1)) (1- index2))
 818                    '(index2 start2 (1+ index2))))
 819              (,(if from-end
 820                    '(< index2 start2)
 821                    '(>= index2 end2))
 822               nil)
 823            ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
 824            ;; terminates is hits -1 when :FROM-END is true and :START2
 825            ;; is 0.
 826            (declare (type fixnum index2))
 827            (when (do ((index1 start1 (1+ index1))
 828                       (index2 index2 (1+ index2)))
 829                      ((>= index1 end1) t)
 830                    (declare (type index index1 index2))
 831                    ,@(unless from-end
 832                              '((when (= index2 end2)
 833                                  (return-from search nil))))
 834                    (unless (,@(if testp
 835                                   '(funcall test)
 836                                   '(eql))
 837                               ,(if keyp
 838                                    '(funcall key (aref pattern index1))
 839                                    '(aref pattern index1))
 840                               ,(if keyp
 841                                    '(funcall key (aref text index2))
 842                                    '(aref text index2)))
 843                      (return nil)))
 844              (return index2)))))))
 845
 846 ;;; FIXME: It seems as though it should be possible to make a DEFUN
 847 ;;; %CONCATENATE (with a DEFTRANSFORM to translate constant RTYPE to
 848 ;;; CTYPE before calling %CONCATENATE) which is comparably efficient,
 849 ;;; at least once DYNAMIC-EXTENT works.
 850 ;;;
 851 ;;; FIXME: currently KLUDGEed because of bug 188
 852 ;;;
 853 ;;; FIXME: disabled for sb-unicode: probably want it back
 854 #!-sb-unicode
 855 (deftransform concatenate ((rtype &rest sequences)
 856                            (t &rest (or simple-base-string
 857                                         (simple-array nil (*))))
 858                            simple-base-string
 859                            :policy (< safety 3))
 860   (loop for rest-seqs on sequences
 861         for n-seq = (gensym "N-SEQ")
 862         for n-length = (gensym "N-LENGTH")
 863         for start = 0 then next-start
 864         for next-start = (gensym "NEXT-START")
 865         collect n-seq into args
 866         collect `(,n-length (length ,n-seq)) into lets
 867         collect n-length into all-lengths
 868         collect next-start into starts
 869         collect `(if (and (typep ,n-seq '(simple-array nil (*)))
 870                           (> ,n-length 0))
 871                      (error 'nil-array-accessed-error)
 872                      (#.(let* ((i (position 'character sb!kernel::*specialized-array-element-types*))
 873                                (saetp (aref sb!vm:*specialized-array-element-type-properties* i))
 874                                (n-bits (sb!vm:saetp-n-bits saetp)))
 875                           (intern (format nil "UB~D-BASH-COPY" n-bits)
 876                                   "SB!KERNEL"))
 877                         ,n-seq 0 res ,start ,n-length))
 878                 into forms
 879         collect `(setq ,next-start (+ ,start ,n-length)) into forms
 880         finally
 881         (return
 882           `(lambda (rtype ,@args)
 883              (declare (ignore rtype))
 884              (let* (,@lets
 885                     (res (make-string (the index (+ ,@all-lengths))
 886                                       :element-type 'base-char)))
 887                (declare (type index ,@all-lengths))
 888                (let (,@(mapcar (lambda (name) `(,name 0)) starts))
 889                  (declare (type index ,@starts))
 890                  ,@forms)
 891                res)))))
 892 \f
 893 ;;;; CONS accessor DERIVE-TYPE optimizers
 894
 895 (defoptimizer (car derive-type) ((cons))
 896   (let ((type (lvar-type cons))
 897         (null-type (specifier-type 'null)))
 898     (cond ((eq type null-type)
 899            null-type)
 900           ((cons-type-p type)
 901            (cons-type-car-type type)))))
 902
 903 (defoptimizer (cdr derive-type) ((cons))
 904   (let ((type (lvar-type cons))
 905         (null-type (specifier-type 'null)))
 906     (cond ((eq type null-type)
 907            null-type)
 908           ((cons-type-p type)
 909            (cons-type-cdr-type type)))))
 910 \f
 911 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
 912
 913 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
 914 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
 915 ;;; expansion, so we factor out the condition into this function.
 916 (defun check-inlineability-of-find-position-if (sequence from-end)
 917   (let ((ctype (lvar-type sequence)))
 918     (cond ((csubtypep ctype (specifier-type 'vector))
 919            ;; It's not worth trying to inline vector code unless we
 920            ;; know a fair amount about it at compile time.
 921            (upgraded-element-type-specifier-or-give-up sequence)
 922            (unless (constant-lvar-p from-end)
 923              (give-up-ir1-transform
 924               "FROM-END argument value not known at compile time")))
 925           ((csubtypep ctype (specifier-type 'list))
 926            ;; Inlining on lists is generally worthwhile.
 927            )
 928           (t
 929            (give-up-ir1-transform
 930             "sequence type not known at compile time")))))
 931
 932 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
 933 (macrolet ((def (name condition)
 934              `(deftransform ,name ((predicate sequence from-end start end key)
 935                                    (function list t t t function)
 936                                    *
 937                                    :policy (> speed space))
 938                 "expand inline"
 939                 `(let ((index 0)
 940                        (find nil)
 941                        (position nil))
 942                    (declare (type index index))
 943                    (dolist (i sequence
 944                             (if (and end (> end index))
 945                                 (sb!impl::signal-bounding-indices-bad-error
 946                                  sequence start end)
 947                                 (values find position)))
 948                      (let ((key-i (funcall key i)))
 949                        (when (and end (>= index end))
 950                          (return (values find position)))
 951                        (when (>= index start)
 952                          (,',condition (funcall predicate key-i)
 953                           ;; This hack of dealing with non-NIL
 954                           ;; FROM-END for list data by iterating
 955                           ;; forward through the list and keeping
 956                           ;; track of the last time we found a match
 957                           ;; might be more screwy than what the user
 958                           ;; expects, but it seems to be allowed by
 959                           ;; the ANSI standard. (And if the user is
 960                           ;; screwy enough to ask for FROM-END
 961                           ;; behavior on list data, turnabout is
 962                           ;; fair play.)
 963                           ;;
 964                           ;; It's also not enormously efficient,
 965                           ;; calling PREDICATE and KEY more often
 966                           ;; than necessary; but all the
 967                           ;; alternatives seem to have their own
 968                           ;; efficiency problems.
 969                           (if from-end
 970                               (setf find i
 971                                     position index)
 972                               (return (values i index))))))
 973                      (incf index))))))
 974   (def %find-position-if when)
 975   (def %find-position-if-not unless))
 976
 977 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
 978 ;;; without loss of efficiency. (I.e., the optimizer should be able
 979 ;;; to straighten everything out.)
 980 (deftransform %find-position ((item sequence from-end start end key test)
 981                               (t list t t t t t)
 982                               *
 983                               :policy (> speed space))
 984   "expand inline"
 985   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
 986                         ;; The order of arguments for asymmetric tests
 987                         ;; (e.g. #'<, as opposed to order-independent
 988                         ;; tests like #'=) is specified in the spec
 989                         ;; section 17.2.1 -- the O/Zi stuff there.
 990                         (lambda (i)
 991                           (funcall test-fun item i)))
 992                       sequence
 993                       from-end
 994                       start
 995                       end
 996                       (%coerce-callable-to-fun key)))
 997
 998 ;;; The inline expansions for the VECTOR case are saved as macros so
 999 ;;; that we can share them between the DEFTRANSFORMs and the default
1000 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
1001 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1002 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1003                                                             from-end
1004                                                             start
1005                                                             end-arg
1006                                                             element
1007                                                             done-p-expr)
1008   (with-unique-names (offset block index n-sequence sequence n-end end)
1009     `(let ((,n-sequence ,sequence-arg)
1010            (,n-end ,end-arg))
1011        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1012                          (,start ,start)
1013                          (,end (%check-vector-sequence-bounds
1014                                 ,n-sequence ,start ,n-end)))
1015          (block ,block
1016            (macrolet ((maybe-return ()
1017                         ;; WITH-ARRAY-DATA has already performed bounds
1018                         ;; checking, so we can safely elide the checks
1019                         ;; in the inner loop.
1020                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1021                                            (aref ,sequence ,index))))
1022                            (when ,done-p-expr
1023                              (return-from ,block
1024                                (values ,element
1025                                        (- ,index ,offset)))))))
1026              (if ,from-end
1027                  (loop for ,index
1028                        ;; (If we aren't fastidious about declaring that
1029                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1030                        ;; can send us off into never-never land, since
1031                        ;; INDEX is initialized to -1.)
1032                        of-type index-or-minus-1
1033                        from (1- ,end) downto ,start do
1034                        (maybe-return))
1035                  (loop for ,index of-type index from ,start below ,end do
1036                        (maybe-return))))
1037            (values nil nil))))))
1038
1039 (def!macro %find-position-vector-macro (item sequence
1040                                              from-end start end key test)
1041   (with-unique-names (element)
1042     (%find-position-or-find-position-if-vector-expansion
1043      sequence
1044      from-end
1045      start
1046      end
1047      element
1048      ;; (See the LIST transform for a discussion of the correct
1049      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1050      ;; or after the checked sequence element.)
1051      `(funcall ,test ,item (funcall ,key ,element)))))
1052
1053 (def!macro %find-position-if-vector-macro (predicate sequence
1054                                                      from-end start end key)
1055   (with-unique-names (element)
1056     (%find-position-or-find-position-if-vector-expansion
1057      sequence
1058      from-end
1059      start
1060      end
1061      element
1062      `(funcall ,predicate (funcall ,key ,element)))))
1063
1064 (def!macro %find-position-if-not-vector-macro (predicate sequence
1065                                                          from-end start end key)
1066   (with-unique-names (element)
1067     (%find-position-or-find-position-if-vector-expansion
1068      sequence
1069      from-end
1070      start
1071      end
1072      element
1073      `(not (funcall ,predicate (funcall ,key ,element))))))
1074
1075 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1076 ;;; VECTOR data
1077 (deftransform %find-position-if ((predicate sequence from-end start end key)
1078                                  (function vector t t t function)
1079                                  *
1080                                  :policy (> speed space))
1081   "expand inline"
1082   (check-inlineability-of-find-position-if sequence from-end)
1083   '(%find-position-if-vector-macro predicate sequence
1084                                    from-end start end key))
1085
1086 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1087                                      (function vector t t t function)
1088                                      *
1089                                      :policy (> speed space))
1090   "expand inline"
1091   (check-inlineability-of-find-position-if sequence from-end)
1092   '(%find-position-if-not-vector-macro predicate sequence
1093                                        from-end start end key))
1094
1095 (deftransform %find-position ((item sequence from-end start end key test)
1096                               (t vector t t t function function)
1097                               *
1098                               :policy (> speed space))
1099   "expand inline"
1100   (check-inlineability-of-find-position-if sequence from-end)
1101   '(%find-position-vector-macro item sequence
1102                                 from-end start end key test))
1103
1104 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1105 ;;; POSITION-IF, etc.
1106 (define-source-transform effective-find-position-test (test test-not)
1107   (once-only ((test test)
1108               (test-not test-not))
1109     `(cond
1110       ((and ,test ,test-not)
1111        (error "can't specify both :TEST and :TEST-NOT"))
1112       (,test (%coerce-callable-to-fun ,test))
1113       (,test-not
1114        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1115        ;; inefficient, but since the TEST-NOT option is deprecated
1116        ;; anyway, we don't care.)
1117        (complement (%coerce-callable-to-fun ,test-not)))
1118       (t #'eql))))
1119 (define-source-transform effective-find-position-key (key)
1120   (once-only ((key key))
1121     `(if ,key
1122          (%coerce-callable-to-fun ,key)
1123          #'identity)))
1124
1125 (macrolet ((define-find-position (fun-name values-index)
1126              `(deftransform ,fun-name ((item sequence &key
1127                                              from-end (start 0) end
1128                                              key test test-not)
1129                                        (t (or list vector) &rest t))
1130                 '(nth-value ,values-index
1131                             (%find-position item sequence
1132                                             from-end start
1133                                             end
1134                                             (effective-find-position-key key)
1135                                             (effective-find-position-test
1136                                              test test-not))))))
1137   (define-find-position find 0)
1138   (define-find-position position 1))
1139
1140 (macrolet ((define-find-position-if (fun-name values-index)
1141              `(deftransform ,fun-name ((predicate sequence &key
1142                                                   from-end (start 0)
1143                                                   end key)
1144                                        (t (or list vector) &rest t))
1145                 '(nth-value
1146                   ,values-index
1147                   (%find-position-if (%coerce-callable-to-fun predicate)
1148                                      sequence from-end
1149                                      start end
1150                                      (effective-find-position-key key))))))
1151   (define-find-position-if find-if 0)
1152   (define-find-position-if position-if 1))
1153
1154 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1155 ;;; didn't bother to worry about optimizing them, except note that on
1156 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1157 ;;; sbcl-devel
1158 ;;;
1159 ;;;     My understanding is that while the :test-not argument is
1160 ;;;     deprecated in favour of :test (complement #'foo) because of
1161 ;;;     semantic difficulties (what happens if both :test and :test-not
1162 ;;;     are supplied, etc) the -if-not variants, while officially
1163 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1164 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1165 ;;;     reasons for allowing the -if-not versions equal status,
1166 ;;;     particularly remove-if-not (== filter).
1167 ;;;
1168 ;;;     This is only an informal understanding, I grant you, but
1169 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1170 ;;;     way as the others?
1171 ;;;
1172 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1173 ;;; implementation of SBCL.
1174 (macrolet ((define-find-position-if-not (fun-name values-index)
1175                `(deftransform ,fun-name ((predicate sequence &key
1176                                           from-end (start 0)
1177                                           end key)
1178                                          (t (or list vector) &rest t))
1179                  '(nth-value
1180                    ,values-index
1181                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1182                     sequence from-end
1183                     start end
1184                     (effective-find-position-key key))))))
1185   (define-find-position-if-not find-if-not 0)
1186   (define-find-position-if-not position-if-not 1))