src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body fast)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places)
 137             (around))
 138     (let ((found-vector-p nil))
 139       (flet ((process-vector (length)
 140                (unless found-vector-p
 141                  (setq found-vector-p t)
 142                  (bindings `(index 0 (1+ index)))
 143                  (declarations `(type index index)))
 144                (vector-lengths length)))
 145         (loop for seq of-type lvar in seqs
 146            for seq-name in seq-names
 147            for type = (lvar-type seq)
 148            do (cond ((csubtypep type (specifier-type 'list))
 149                      (with-unique-names (index)
 150                        (bindings `(,index ,seq-name (cdr ,index)))
 151                        (declarations `(type list ,index))
 152                        (places `(car ,index))
 153                        (tests `(endp ,index))))
 154                     ((or (csubtypep type (specifier-type '(simple-array * 1)))
 155                          (and (not fast)
 156                               (csubtypep type (specifier-type 'vector))))
 157                      (process-vector `(length ,seq-name))
 158                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 159                                 (aref ,seq-name index))))
 160                     ((csubtypep type (specifier-type 'vector))
 161                      (let ((data  (gensym "DATA"))
 162                            (start (gensym "START"))
 163                            (end   (gensym "END")))
 164                        (around `(with-array-data ((,data ,seq-name)
 165                                                   (,start)
 166                                                   (,end (length ,seq-name)))))
 167                        (process-vector `(- ,end ,start))
 168                        (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 169                                   (aref ,data (truly-the index (+ index ,start)))))))
 170                     (t
 171                      (give-up-ir1-transform
 172                       "can't determine sequence argument type"))))
 173         (when into
 174           (process-vector `(array-dimension ,into 0))))
 175       (when found-vector-p
 176         (bindings `(length (min ,@(vector-lengths))))
 177         (tests `(>= index length)))
 178       (let ((body `(do (,@(bindings))
 179                        ((or ,@(tests)) ,result)
 180                      (declare ,@(declarations))
 181                      (let ((funcall-result (funcall fun ,@(places))))
 182                        (declare (ignorable funcall-result))
 183                        ,body))))
 184         (if (around)
 185             (reduce (lambda (wrap body) (append wrap (list body)))
 186                     (around)
 187                     :from-end t
 188                     :initial-value body)
 189             body)))))
 190
 191 ;;; Try to compile %MAP efficiently when we can determine sequence
 192 ;;; argument types at compile time.
 193 ;;;
 194 ;;; Note: This transform was written to allow open coding of
 195 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 196 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 197 ;;; necessarily as efficient as possible. In particular, it will be
 198 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 199 ;;; numeric element types. It should be straightforward to make it
 200 ;;; handle that case more efficiently, but it's left as an exercise to
 201 ;;; the reader, because the code is complicated enough already and I
 202 ;;; don't happen to need that functionality right now. -- WHN 20000410
 203 (deftransform %map ((result-type fun seq &rest seqs) * *
 204                     :node node :policy (>= speed space))
 205   "open code"
 206   (unless (constant-lvar-p result-type)
 207     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 208   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 209            (fn-1subtypep (fn x y)
 210              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 211                (if valid-p
 212                    subtype-p
 213                    (give-up-ir1-transform
 214                     "can't analyze sequence type relationship"))))
 215            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 216     (let* ((result-type-value (lvar-value result-type))
 217            (result-supertype (cond ((null result-type-value) 'null)
 218                                    ((1subtypep result-type-value 'vector)
 219                                     'vector)
 220                                    ((1subtypep result-type-value 'list)
 221                                     'list)
 222                                    (t
 223                                     (give-up-ir1-transform
 224                                      "result type unsuitable")))))
 225       (cond ((and result-type-value (null seqs))
 226              ;; The consing arity-1 cases can be implemented
 227              ;; reasonably efficiently as function calls, and the cost
 228              ;; of consing should be significantly larger than
 229              ;; function call overhead, so we always compile these
 230              ;; cases as full calls regardless of speed-versus-space
 231              ;; optimization policy.
 232              (cond ((subtypep result-type-value 'list)
 233                     '(%map-to-list-arity-1 fun seq))
 234                    ( ;; (This one can be inefficient due to COERCE, but
 235                     ;; the current open-coded implementation has the
 236                     ;; same problem.)
 237                     (subtypep result-type-value 'vector)
 238                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 239                              ',result-type-value))
 240                    (t (bug "impossible (?) sequence type"))))
 241             (t
 242              (let* ((seqs (cons seq seqs))
 243                     (seq-args (make-gensym-list (length seqs))))
 244                (multiple-value-bind (push-dacc result)
 245                    (ecase result-supertype
 246                      (null (values nil nil))
 247                      (list (values `(push funcall-result acc)
 248                                    `(nreverse acc)))
 249                      (vector (values `(push funcall-result acc)
 250                                      `(coerce (nreverse acc)
 251                                               ',result-type-value))))
 252                  ;; (We use the same idiom, of returning a LAMBDA from
 253                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 254                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 255                  ;; reason: we need to get the runtime values of each
 256                  ;; of the &REST vars.)
 257                  `(lambda (result-type fun ,@seq-args)
 258                     (declare (ignore result-type))
 259                     (let ((fun (%coerce-callable-to-fun fun))
 260                           (acc nil))
 261                       (declare (type list acc))
 262                       (declare (ignorable acc))
 263                       ,(build-sequence-iterator
 264                         seqs seq-args
 265                         :result result
 266                         :body push-dacc
 267                         :fast (policy node (> speed space))))))))))))
 268
 269 ;;; MAP-INTO
 270 (deftransform map-into ((result fun &rest seqs)
 271                         (vector * &rest *)
 272                         * :node node)
 273   "open code"
 274   (let ((seqs-names (mapcar (lambda (x)
 275                               (declare (ignore x))
 276                               (gensym))
 277                             seqs)))
 278     `(lambda (result fun ,@seqs-names)
 279        ,(if (and (policy node (> speed space))
 280                  (not (csubtypep (lvar-type result)
 281                                  (specifier-type '(simple-array * 1)))))
 282             (let ((data  (gensym "DATA"))
 283                   (start (gensym "START"))
 284                   (end   (gensym "END")))
 285               `(with-array-data ((,data result)
 286                                  (,start)
 287                                  (,end))
 288                  (declare (ignore ,end))
 289                  ,(build-sequence-iterator
 290                    seqs seqs-names
 291                    :result '(when (array-has-fill-pointer-p result)
 292                              (setf (fill-pointer result) index))
 293                    :into 'result
 294                    :body `(locally (declare (optimize (insert-array-bounds-checks 0)))
 295                            (setf (aref ,data (truly-the index (+ index ,start)))
 296                                  funcall-result))
 297                    :fast t)))
 298             (build-sequence-iterator
 299              seqs seqs-names
 300              :result '(when (array-has-fill-pointer-p result)
 301                        (setf (fill-pointer result) index))
 302              :into 'result
 303              :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 304                      (setf (aref result index) funcall-result))))
 305        result)))
 306
 307 \f
 308 ;;; FIXME: once the confusion over doing transforms with known-complex
 309 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 310 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 311 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 312   '(aref s i))
 313
 314 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 315   '(nth i s))
 316
 317 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 318   '(%aset s i v))
 319
 320 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 321   '(setf (car (nthcdr i s)) v))
 322
 323 (deftransform %check-vector-sequence-bounds ((vector start end)
 324                                              (vector * *) *
 325                                              :node node)
 326   (if (policy node (= 0 insert-array-bounds-checks))
 327       '(or end (length vector))
 328       '(let ((length (length vector)))
 329          (if (<= 0 start (or end length) length)
 330              (or end length)
 331              (sequence-bounding-indices-bad-error vector start end)))))
 332
 333 (def!type eq-comparable-type ()
 334   '(or fixnum (not number)))
 335
 336 ;;; True if EQL comparisons involving type can be simplified to EQ.
 337 (defun eq-comparable-type-p (type)
 338   (csubtypep type (specifier-type 'eq-comparable-type)))
 339
 340 (defun specialized-list-seek-function-name (function-name key-functions &optional variant)
 341   (or (find-symbol (with-output-to-string (s)
 342                      ;; Write "%NAME-FUN1-FUN2-FUN3", etc. Not only is
 343                      ;; this ever so slightly faster then FORMAT, this
 344                      ;; way we are also proof against *PRINT-CASE*
 345                      ;; frobbing and such.
 346                      (write-char #\% s)
 347                      (write-string (symbol-name function-name) s)
 348                      (dolist (f key-functions)
 349                        (write-char #\- s)
 350                        (write-string (symbol-name f) s))
 351                      (when variant
 352                        (write-char #\- s)
 353                        (write-string (symbol-name variant) s)))
 354                    (load-time-value (find-package "SB!KERNEL")))
 355       (bug "Unknown list item seek transform: name=~S, key-functions=~S variant=~S"
 356            function-name key-functions variant)))
 357
 358 (defparameter *list-open-code-limit* 128)
 359
 360 (defun transform-list-item-seek (name item list key test test-not node)
 361   (when (and test test-not)
 362     (abort-ir1-transform "Both ~S and ~S supplied to ~S." :test :test-not name))
 363   ;; If TEST is EQL, drop it.
 364   (when (and test (lvar-fun-is test '(eql)))
 365     (setf test nil))
 366   ;; Ditto for KEY IDENTITY.
 367   (when (and key (lvar-fun-is key '(identity)))
 368     (setf key nil))
 369   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 370   ;; not there at all. If it might be NIL, make up a form to that
 371   ;; ensures it is a function.
 372   (multiple-value-bind (key key-form)
 373       (when key
 374         (let ((key-type (lvar-type key))
 375               (null-type (specifier-type 'null)))
 376           (cond ((csubtypep key-type null-type)
 377                  (values nil nil))
 378                 ((csubtypep null-type key-type)
 379                  (values key '(if key
 380                                (%coerce-callable-to-fun key)
 381                                #'identity)))
 382                 (t
 383                  (values key (ensure-lvar-fun-form key 'key))))))
 384     (let* ((c-test (cond ((and test (lvar-fun-is test '(eq)))
 385                           (setf test nil)
 386                           'eq)
 387                          ((and (not test) (not test-not))
 388                           (when (eq-comparable-type-p (lvar-type item))
 389                             'eq))))
 390            (funs (delete nil (list (when key (list key 'key))
 391                                    (when test (list test 'test))
 392                                    (when test-not (list test-not 'test-not)))))
 393            (target-expr (if key '(%funcall key target) 'target))
 394            (test-expr (cond (test `(%funcall test item ,target-expr))
 395                             (test-not `(not (%funcall test-not item ,target-expr)))
 396                             (c-test `(,c-test item ,target-expr))
 397                             (t `(eql item ,target-expr)))))
 398       (labels ((open-code (tail)
 399                  (when tail
 400                    `(if (let ((this ',(car tail)))
 401                           ,(ecase name
 402                                   ((assoc rassoc)
 403                                    (let ((cxx (if (eq name 'assoc) 'car 'cdr)))
 404                                      `(and this (let ((target (,cxx this)))
 405                                                   ,test-expr))))
 406                                   (member
 407                                    `(let ((target this))
 408                                       ,test-expr))))
 409                         ',(ecase name
 410                                  ((assoc rassoc) (car tail))
 411                                  (member tail))
 412                         ,(open-code (cdr tail)))))
 413                (ensure-fun (args)
 414                  (if (eq 'key (second args))
 415                      key-form
 416                      (apply #'ensure-lvar-fun-form args))))
 417         (let* ((cp (constant-lvar-p list))
 418                (c-list (when cp (lvar-value list))))
 419           (cond ((and cp c-list (member name '(assoc rassoc member))
 420                       (policy node (>= speed space))
 421                       (not (nthcdr *list-open-code-limit* c-list)))
 422                  `(let ,(mapcar (lambda (fun) `(,(second fun) ,(ensure-fun fun))) funs)
 423                     ,(open-code c-list)))
 424                 ((and cp (not c-list))
 425                  ;; constant nil list
 426                  (if (eq name 'adjoin)
 427                      '(list item)
 428                      nil))
 429                 (t
 430                  ;; specialized out-of-line version
 431                  `(,(specialized-list-seek-function-name name (mapcar #'second funs) c-test)
 432                     item list ,@(mapcar #'ensure-fun funs)))))))))
 433
 434 (defun transform-list-pred-seek (name pred list key node)
 435   ;; If KEY is IDENTITY, drop it.
 436   (when (and key (lvar-fun-is key '(identity)))
 437     (setf key nil))
 438   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 439   ;; not there at all. If it might be NIL, make up a form to that
 440   ;; ensures it is a function.
 441   (multiple-value-bind (key key-form)
 442       (when key
 443         (let ((key-type (lvar-type key))
 444               (null-type (specifier-type 'null)))
 445           (cond ((csubtypep key-type null-type)
 446                  (values nil nil))
 447                 ((csubtypep null-type key-type)
 448                  (values key '(if key
 449                                (%coerce-callable-to-fun key)
 450                                #'identity)))
 451                 (t
 452                  (values key (ensure-lvar-fun-form key 'key))))))
 453     (let ((test-expr `(%funcall pred ,(if key '(%funcall key target) 'target)))
 454           (pred-expr (ensure-lvar-fun-form pred 'pred)))
 455       (when (member name '(member-if-not assoc-if-not rassoc-if-not))
 456         (setf test-expr `(not ,test-expr)))
 457       (labels ((open-code (tail)
 458                  (when tail
 459                    `(if (let ((this ',(car tail)))
 460                           ,(ecase name
 461                                   ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 462                                    (let ((cxx (if (member name '(assoc-if assoc-if-not)) 'car 'cdr)))
 463                                      `(and this (let ((target (,cxx this)))
 464                                                   ,test-expr))))
 465                                   ((member-if member-if-not)
 466                                    `(let ((target this))
 467                                       ,test-expr))))
 468                         ',(ecase name
 469                                  ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 470                                   (car tail))
 471                                  ((member-if member-if-not)
 472                                   tail))
 473                         ,(open-code (cdr tail))))))
 474         (let* ((cp (constant-lvar-p list))
 475                (c-list (when cp (lvar-value list))))
 476           (cond ((and cp c-list (policy node (>= speed space))
 477                       (not (nthcdr *list-open-code-limit* c-list)))
 478                  `(let ((pred ,pred-expr)
 479                         ,@(when key `((key ,key-form))))
 480                     ,(open-code c-list)))
 481                 ((and cp (not c-list))
 482                  ;; constant nil list -- nothing to find!
 483                  nil)
 484                 (t
 485                  ;; specialized out-of-line version
 486                  `(,(specialized-list-seek-function-name name (when key '(key)))
 487                     ,pred-expr list ,@(when key (list key-form))))))))))
 488
 489 (macrolet ((def (name &optional if/if-not)
 490              (let ((basic (symbolicate "%" name))
 491                    (basic-eq (symbolicate "%" name "-EQ"))
 492                    (basic-key (symbolicate "%" name "-KEY"))
 493                    (basic-key-eq (symbolicate "%" name "-KEY-EQ")))
 494                `(progn
 495                   (deftransform ,name ((item list &key key test test-not) * * :node node)
 496                     (transform-list-item-seek ',name item list key test test-not node))
 497                   (deftransform ,basic ((item list) (eq-comparable-type t))
 498                     `(,',basic-eq item list))
 499                   (deftransform ,basic-key ((item list) (eq-comparable-type t))
 500                     `(,',basic-key-eq item list))
 501                   ,@(when if/if-not
 502                           (let ((if-name (symbolicate name "-IF"))
 503                                 (if-not-name (symbolicate name "-IF-NOT")))
 504                             `((deftransform ,if-name ((pred list &key key) * * :node node)
 505                                 (transform-list-pred-seek ',if-name pred list key node))
 506                               (deftransform ,if-not-name ((pred list &key key) * * :node node)
 507                                 (transform-list-pred-seek ',if-not-name pred list key node)))))))))
 508   (def adjoin)
 509   (def assoc  t)
 510   (def member t)
 511   (def rassoc t))
 512
 513 (deftransform memq ((item list) (t (constant-arg list)))
 514   (labels ((rec (tail)
 515              (if tail
 516                  `(if (eq item ',(car tail))
 517                       ',tail
 518                       ,(rec (cdr tail)))
 519                  nil)))
 520     (rec (lvar-value list))))
 521
 522 ;;; A similar transform used to apply to MEMBER and ASSOC, but since
 523 ;;; TRANSFORM-LIST-ITEM-SEEK now takes care of them those transform
 524 ;;; would never fire, and (%MEMBER-TEST ITEM LIST #'EQ) should be
 525 ;;; almost as fast as MEMQ.
 526 (deftransform delete ((item list &key test) (t list &rest t) *)
 527   "convert to EQ test"
 528   (let ((type (lvar-type item)))
 529     (unless (or (and test (lvar-fun-is test '(eq)))
 530                 (and (eq-comparable-type-p type)
 531                      (or (not test) (lvar-fun-is test '(eql)))))
 532       (give-up-ir1-transform)))
 533   `(delq item list))
 534
 535 (deftransform delete-if ((pred list) (t list))
 536   "open code"
 537   '(do ((x list (cdr x))
 538         (splice '()))
 539        ((endp x) list)
 540      (cond ((funcall pred (car x))
 541             (if (null splice)
 542                 (setq list (cdr x))
 543                 (rplacd splice (cdr x))))
 544            (t (setq splice x)))))
 545
 546 (deftransform fill ((seq item &key (start 0) (end nil))
 547                     (list t &key (:start t) (:end t)))
 548   '(list-fill* seq item start end))
 549
 550 (deftransform fill ((seq item &key (start 0) (end nil))
 551                     (vector t &key (:start t) (:end t))
 552                     *
 553                     :node node)
 554   (let* ((type (lvar-type seq))
 555          (element-ctype (array-type-upgraded-element-type type))
 556          (element-type (type-specifier element-ctype))
 557          (saetp (unless (eq *wild-type* element-ctype)
 558                   (find-saetp-by-ctype element-ctype))))
 559     (cond ((eq *wild-type* element-ctype)
 560            (delay-ir1-transform node :constraint)
 561            `(vector-fill* seq item start end))
 562           ((and saetp (sb!vm::valid-bit-bash-saetp-p saetp))
 563            (let* ((n-bits (sb!vm:saetp-n-bits saetp))
 564                   (basher-name (format nil "UB~D-BASH-FILL" n-bits))
 565                   (basher (or (find-symbol basher-name
 566                                            (load-time-value (find-package :sb!kernel)))
 567                               (abort-ir1-transform
 568                                "Unknown fill basher, please report to sbcl-devel: ~A"
 569                                basher-name)))
 570                   (kind (cond ((sb!vm:saetp-fixnum-p saetp) :tagged)
 571                               ((member element-type '(character base-char)) :char)
 572                               ((eq element-type 'single-float) :single-float)
 573                               #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 574                               ((eq element-type 'double-float) :double-float)
 575                               #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 576                               ((equal element-type '(complex single-float))
 577                                :complex-single-float)
 578                               (t
 579                                (aver (integer-type-p element-ctype))
 580                                :bits)))
 581                   ;; BASH-VALUE is a word that we can repeatedly smash
 582                   ;; on the array: for less-than-word sized elements it
 583                   ;; contains multiple copies of the fill item.
 584                   (bash-value
 585                    (if (constant-lvar-p item)
 586                        (let ((tmp (lvar-value item)))
 587                          (unless (ctypep tmp element-ctype)
 588                            (abort-ir1-transform "~S is not ~S" tmp element-type))
 589                          (let* ((bits
 590                                  (ldb (byte n-bits 0)
 591                                       (ecase kind
 592                                         (:tagged
 593                                          (ash tmp sb!vm:n-fixnum-tag-bits))
 594                                         (:char
 595                                          (char-code tmp))
 596                                         (:bits
 597                                          tmp)
 598                                         (:single-float
 599                                          (single-float-bits tmp))
 600                                         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 601                                         (:double-float
 602                                          (logior (ash (double-float-high-bits tmp) 32)
 603                                                  (double-float-low-bits tmp)))
 604                                         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 605                                         (:complex-single-float
 606                                          (logior (ash (single-float-bits (imagpart tmp)) 32)
 607                                                  (ldb (byte 32 0)
 608                                                       (single-float-bits (realpart tmp))))))))
 609                                 (res bits))
 610                            (loop for i of-type sb!vm:word from n-bits by n-bits
 611                                  until (= i sb!vm:n-word-bits)
 612                                  do (setf res (ldb (byte sb!vm:n-word-bits 0)
 613                                                    (logior res (ash bits i)))))
 614                            res))
 615                        (progn
 616                          (delay-ir1-transform node :constraint)
 617                         `(let* ((bits (ldb (byte ,n-bits 0)
 618                                            ,(ecase kind
 619                                                    (:tagged
 620                                                     `(ash item ,sb!vm:n-fixnum-tag-bits))
 621                                                    (:char
 622                                                     `(char-code item))
 623                                                    (:bits
 624                                                     `item)
 625                                                    (:single-float
 626                                                     `(single-float-bits item))
 627                                                    #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 628                                                    (:double-float
 629                                                     `(logior (ash (double-float-high-bits item) 32)
 630                                                              (double-float-low-bits item)))
 631                                                    #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 632                                                    (:complex-single-float
 633                                                     `(logior (ash (single-float-bits (imagpart item)) 32)
 634                                                              (ldb (byte 32 0)
 635                                                                   (single-float-bits (realpart item))))))))
 636                                 (res bits))
 637                            (declare (type sb!vm:word res))
 638                            ,@(unless (= sb!vm:n-word-bits n-bits)
 639                                      `((loop for i of-type sb!vm:word from ,n-bits by ,n-bits
 640                                              until (= i sb!vm:n-word-bits)
 641                                              do (setf res
 642                                                       (ldb (byte ,sb!vm:n-word-bits 0)
 643                                                            (logior res (ash bits (truly-the (integer 0 ,(- sb!vm:n-word-bits n-bits)) i))))))))
 644                            res)))))
 645              (values
 646               `(with-array-data ((data seq)
 647                                  (start start)
 648                                  (end end)
 649                                  :check-fill-pointer t)
 650                  (declare (type (simple-array ,element-type 1) data))
 651                  (declare (type index start end))
 652                  (declare (optimize (safety 0) (speed 3))
 653                           (muffle-conditions compiler-note))
 654                  (,basher ,bash-value data start (- end start))
 655                  seq)
 656               `((declare (type ,element-type item))))))
 657           ((policy node (> speed space))
 658            (values
 659             `(with-array-data ((data seq)
 660                                (start start)
 661                                (end end)
 662                                :check-fill-pointer t)
 663                (declare (type (simple-array ,element-type 1) data))
 664                (declare (type index start end))
 665                ;; WITH-ARRAY-DATA did our range checks once and for all, so
 666                ;; it'd be wasteful to check again on every AREF...
 667                (declare (optimize (safety 0) (speed 3)))
 668                (do ((i start (1+ i)))
 669                    ((= i end) seq)
 670                  (declare (type index i))
 671                  (setf (aref data i) item)))
 672             ;; ... though we still need to check that the new element can fit
 673             ;; into the vector in safe code. -- CSR, 2002-07-05
 674             `((declare (type ,element-type item)))))
 675           ((csubtypep type (specifier-type 'string))
 676            '(string-fill* seq item start end))
 677           (t
 678            '(vector-fill* seq item start end)))))
 679
 680 (deftransform fill ((seq item &key (start 0) (end nil))
 681                     ((and sequence (not vector) (not list)) t &key (:start t) (:end t)))
 682   `(sb!sequence:fill seq item
 683                      :start start
 684                      :end (%check-generic-sequence-bounds seq start end)))
 685 \f
 686 ;;;; hairy sequence transforms
 687
 688 ;;; FIXME: no hairy sequence transforms in SBCL?
 689 ;;;
 690 ;;; There used to be a bunch of commented out code about here,
 691 ;;; containing the (apparent) beginning of hairy sequence transform
 692 ;;; infrastructure. People interested in implementing better sequence
 693 ;;; transforms might want to look at it for inspiration, even though
 694 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 695 ;;; was deleted in 1.0.7.23.
 696 \f
 697 ;;;; string operations
 698
 699 ;;; We transform the case-sensitive string predicates into a non-keyword
 700 ;;; version. This is an IR1 transform so that we don't have to worry about
 701 ;;; changing the order of evaluation.
 702 (macrolet ((def (fun pred*)
 703              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 704                                                          (start2 0) end2)
 705                                    * *)
 706                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 707   (def string< string<*)
 708   (def string> string>*)
 709   (def string<= string<=*)
 710   (def string>= string>=*)
 711   (def string= string=*)
 712   (def string/= string/=*))
 713
 714 ;;; Return a form that tests the free variables STRING1 and STRING2
 715 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 716 ;;; start and end are also gotten from the environment. Both strings
 717 ;;; must be SIMPLE-BASE-STRINGs.
 718 (macrolet ((def (name lessp equalp)
 719              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 720                                    (simple-base-string simple-base-string t t t t) *)
 721                 `(let* ((end1 (if (not end1) (length string1) end1))
 722                         (end2 (if (not end2) (length string2) end2))
 723                         (index (sb!impl::%sp-string-compare
 724                                 string1 start1 end1 string2 start2 end2)))
 725                   (if index
 726                       (cond ((= index end1)
 727                              ,(if ',lessp 'index nil))
 728                             ((= (+ index (- start2 start1)) end2)
 729                              ,(if ',lessp nil 'index))
 730                             ((,(if ',lessp 'char< 'char>)
 731                                (schar string1 index)
 732                                (schar string2
 733                                       (truly-the index
 734                                                  (+ index
 735                                                     (truly-the fixnum
 736                                                                (- start2
 737                                                                   start1))))))
 738                              index)
 739                             (t nil))
 740                       ,(if ',equalp 'end1 nil))))))
 741   (def string<* t nil)
 742   (def string<=* t t)
 743   (def string>* nil nil)
 744   (def string>=* nil t))
 745
 746 (macrolet ((def (name result-fun)
 747              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 748                                    (simple-base-string simple-base-string t t t t) *)
 749                 `(,',result-fun
 750                   (sb!impl::%sp-string-compare
 751                    string1 start1 (or end1 (length string1))
 752                    string2 start2 (or end2 (length string2)))))))
 753   (def string=* not)
 754   (def string/=* identity))
 755
 756 \f
 757 ;;;; transforms for sequence functions
 758
 759 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 760 ;;; to vectors based on simple arrays.
 761 (def!constant vector-data-bit-offset
 762   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 763
 764 ;;; FIXME: In the copy loops below, we code the loops in a strange
 765 ;;; fashion:
 766 ;;;
 767 ;;; (do ((i (+ src-offset length) (1- i)))
 768 ;;;     ((<= i 0) ...)
 769 ;;;   (... (aref foo (1- i)) ...))
 770 ;;;
 771 ;;; rather than the more natural (and seemingly more efficient):
 772 ;;;
 773 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 774 ;;;     ((< i 0) ...)
 775 ;;;   (... (aref foo i) ...))
 776 ;;;
 777 ;;; (more efficient because we don't have to do the index adjusting on
 778 ;;; every iteration of the loop)
 779 ;;;
 780 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 781 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 782 ;;; when used as an array index, the backend thinks I is a
 783 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 784 ;;; these as distinct storage classes, it cannot coerce a move from a
 785 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 786 ;;; deficiency is that we have two extra moves and increased register
 787 ;;; pressure, which can lead to some spectacularly bad register
 788 ;;; allocation.  (sub-FIXME: the register allocation even with the
 789 ;;; strangely written loops is not always excellent, either...).  Doing
 790 ;;; it the first way, above, means that I is always thought of as a
 791 ;;; POSITIVE-FIXNUM and there are no issues.
 792 ;;;
 793 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 794 ;;; adjustments in the first version into the array addressing at no
 795 ;;; performance penalty!
 796
 797 ;;; This transform is critical to the performance of string streams.  If
 798 ;;; you tweak it, make sure that you compare the disassembly, if not the
 799 ;;; performance of, the functions implementing string streams
 800 ;;; (e.g. SB!IMPL::STRING-OUCH).
 801 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 802   (defun make-replace-transform (saetp sequence-type1 sequence-type2)
 803     `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 804                             (,sequence-type1 ,sequence-type2 &rest t)
 805                             ,sequence-type1
 806                             :node node)
 807        `(let* ((len1 (length seq1))
 808                (len2 (length seq2))
 809                (end1 (or end1 len1))
 810                (end2 (or end2 len2))
 811                (replace-len (min (- end1 start1) (- end2 start2))))
 812           ,(unless (policy node (= insert-array-bounds-checks 0))
 813              `(progn
 814                 (unless (<= 0 start1 end1 len1)
 815                   (sequence-bounding-indices-bad-error seq1 start1 end1))
 816                 (unless (<= 0 start2 end2 len2)
 817                   (sequence-bounding-indices-bad-error seq2 start2 end2))))
 818           ,',(cond
 819                ((and saetp (sb!vm:valid-bit-bash-saetp-p saetp))
 820                 (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 821                        (bash-function (intern (format nil "UB~D-BASH-COPY"
 822                                                       n-element-bits)
 823                                               (find-package "SB!KERNEL"))))
 824                   `(funcall (function ,bash-function) seq2 start2
 825                     seq1 start1 replace-len)))
 826                (t
 827                 `(if (and
 828                       ;; If the sequence types are different, SEQ1 and
 829                       ;; SEQ2 must be distinct arrays.
 830                       ,(eql sequence-type1 sequence-type2)
 831                       (eq seq1 seq2) (> start1 start2))
 832                      (do ((i (truly-the index (+ start1 replace-len -1))
 833                              (1- i))
 834                           (j (truly-the index (+ start2 replace-len -1))
 835                              (1- j)))
 836                          ((< i start1))
 837                        (declare (optimize (insert-array-bounds-checks 0)))
 838                        (setf (aref seq1 i) (aref seq2 j)))
 839                      (do ((i start1 (1+ i))
 840                           (j start2 (1+ j))
 841                           (end (+ start1 replace-len)))
 842                          ((>= i end))
 843                        (declare (optimize (insert-array-bounds-checks 0)))
 844                        (setf (aref seq1 i) (aref seq2 j))))))
 845           seq1))))
 846
 847 (macrolet
 848     ((define-replace-transforms ()
 849        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 850              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 851              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 852              collect (make-replace-transform saetp sequence-type sequence-type)
 853              into forms
 854              finally (return `(progn ,@forms))))
 855      (define-one-transform (sequence-type1 sequence-type2)
 856        (make-replace-transform nil sequence-type1 sequence-type2)))
 857   (define-replace-transforms)
 858   #!+sb-unicode
 859   (progn
 860    (define-one-transform (simple-array base-char (*)) (simple-array character (*)))
 861    (define-one-transform (simple-array character (*)) (simple-array base-char (*)))))
 862
 863 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 864 ;;; defined as those cases where we are doing word-aligned copies from
 865 ;;; both the source and the destination and we are copying from the same
 866 ;;; offset from both the source and the destination.  (The last
 867 ;;; condition is there so we can determine the direction to copy at
 868 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 869 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 870 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 871 ;;; N)-size buffer and blitting in the old N-size buffer in.
 872
 873 (defun frob-bash-transform (src src-offset
 874                             dst dst-offset
 875                             length n-elems-per-word)
 876   (declare (ignore src dst length))
 877   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 878     (multiple-value-bind (src-word src-elt)
 879         (truncate (lvar-value src-offset) n-elems-per-word)
 880       (multiple-value-bind (dst-word dst-elt)
 881           (truncate (lvar-value dst-offset) n-elems-per-word)
 882         ;; Avoid non-word aligned copies.
 883         (unless (and (zerop src-elt) (zerop dst-elt))
 884           (give-up-ir1-transform))
 885         ;; Avoid copies where we would have to insert code for
 886         ;; determining the direction of copying.
 887         (unless (= src-word dst-word)
 888           (give-up-ir1-transform))
 889         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 890         ;; so we have to do its work here.
 891         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 892                                       'length
 893                                       `(truncate (the index length) ,n-elems-per-word)))))
 894            (declare (type index end))
 895            ;; Handle any bits at the end.
 896            (when (logtest length (1- ,n-elems-per-word))
 897              (let* ((extra (mod length ,n-elems-per-word))
 898                     ;; FIXME: The shift amount on this ASH is
 899                     ;; *always* negative, but the backend doesn't
 900                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 901                     ;; wind up with a pile of code that tests the
 902                     ;; sign of the shift count prior to shifting when
 903                     ;; all we need is a simple negate and shift
 904                     ;; right.  Yuck.
 905                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 906                                (* (- extra ,n-elems-per-word)
 907                                   ,n-bits-per-elem))))
 908                (setf (sb!kernel:%vector-raw-bits dst end)
 909                      (logior
 910                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 911                                 (ash mask
 912                                      ,(ecase sb!c:*backend-byte-order*
 913                                              (:little-endian 0)
 914                                              (:big-endian `(* (- ,n-elems-per-word extra)
 915                                                               ,n-bits-per-elem)))))
 916                       (logand (sb!kernel:%vector-raw-bits src end)
 917                               (ash mask
 918                                    ,(ecase sb!c:*backend-byte-order*
 919                                            (:little-endian 0)
 920                                            (:big-endian `(* (- ,n-elems-per-word extra)
 921                                                             ,n-bits-per-elem)))))))))
 922            ;; Copy from the end to save a register.
 923            (do ((i end (1- i)))
 924                ((<= i ,src-word))
 925              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 926                    (sb!kernel:%vector-raw-bits src (1- i))))
 927            (values))))))
 928
 929 #.(loop for i = 1 then (* i 2)
 930         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 931                                         "SB!KERNEL")
 932                                                         ((src src-offset
 933                                                           dst dst-offset
 934                                                           length)
 935                                                         ((simple-unboxed-array (*))
 936                                                          (constant-arg index)
 937                                                          (simple-unboxed-array (*))
 938                                                          (constant-arg index)
 939                                                          index)
 940                                                         *)
 941                   (frob-bash-transform src src-offset
 942                                        dst dst-offset length
 943                                        ,(truncate sb!vm:n-word-bits i))) into forms
 944         until (= i sb!vm:n-word-bits)
 945         finally (return `(progn ,@forms)))
 946
 947 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 948 ;;; arrays with elements of size >= the word size.  We do this because
 949 ;;; we know the arrays cannot alias (one was just consed), therefore we
 950 ;;; can determine at compile time the direction to copy, and for
 951 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 952 ;;; needless checking to figure out what's going on.  The same
 953 ;;; considerations apply if we are copying elements larger than the word
 954 ;;; size, with the additional twist that doing it inline is likely to
 955 ;;; cons far less than calling REPLACE and letting generic code do the
 956 ;;; work.
 957 ;;;
 958 ;;; However, we do not do this for elements whose size is < than the
 959 ;;; word size because we don't want to deal with any alignment issues
 960 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 961 ;;; anyway.
 962
 963 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 964                                       element-type)
 965   (let ((saetp (find-saetp element-type)))
 966     (aver saetp)
 967     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 968         (expand-aref-copy-loop src src-offset dst dst-offset length)
 969         `(locally (declare (optimize (safety 0)))
 970            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 971
 972 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 973   (if (eql src-offset dst-offset)
 974       `(do ((i (+ ,src-offset ,length) (1- i)))
 975            ((<= i ,src-offset))
 976          (declare (optimize (insert-array-bounds-checks 0)))
 977          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 978       ;; KLUDGE: The compiler is not able to derive that (+ offset
 979       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 980       ;; We, however, know it must be so, as by this point the bounds
 981       ;; have already been checked.
 982       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 983             (j (+ ,dst-offset ,length) (1- j)))
 984            ((<= i ,src-offset))
 985          (declare (optimize (insert-array-bounds-checks 0))
 986                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 987          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 988
 989 ;;; SUBSEQ, COPY-SEQ
 990
 991 (deftransform subseq ((seq start &optional end)
 992                       (vector t &optional t)
 993                       *
 994                       :node node)
 995   (let ((type (lvar-type seq)))
 996     (cond
 997       ((and (array-type-p type)
 998             (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 999        (let ((element-type (type-specifier (array-type-specialized-element-type type))))
1000          `(let* ((length (length seq))
1001                  (end (or end length)))
1002             ,(unless (policy node (zerop insert-array-bounds-checks))
1003                      '(progn
1004                        (unless (<= 0 start end length)
1005                          (sequence-bounding-indices-bad-error seq start end))))
1006             (let* ((size (- end start))
1007                    (result (make-array size :element-type ',element-type)))
1008               ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
1009                                                        (lvar-value start)
1010                                                        'start)
1011                                               'result 0 'size element-type)
1012               result))))
1013       ((csubtypep type (specifier-type 'string))
1014        '(string-subseq* seq start end))
1015       (t
1016        '(vector-subseq* seq start end)))))
1017
1018 (deftransform subseq ((seq start &optional end)
1019                       (list t &optional t))
1020   `(list-subseq* seq start end))
1021
1022 (deftransform subseq ((seq start &optional end)
1023                       ((and sequence (not vector) (not list)) t &optional t))
1024   '(sb!sequence:subseq seq start end))
1025
1026 (deftransform copy-seq ((seq) (vector))
1027   (let ((type (lvar-type seq)))
1028     (cond ((and (array-type-p type)
1029                 (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
1030            (let ((element-type (type-specifier (array-type-specialized-element-type type))))
1031              `(let* ((length (length seq))
1032                      (result (make-array length :element-type ',element-type)))
1033                 ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
1034                 result)))
1035           ((csubtypep type (specifier-type 'string))
1036            '(string-subseq* seq 0 nil))
1037           (t
1038            '(vector-subseq* seq 0 nil)))))
1039
1040 (deftransform copy-seq ((seq) (list))
1041   '(list-copy-seq* seq))
1042
1043 (deftransform copy-seq ((seq) ((and sequence (not vector) (not list))))
1044   '(sb!sequence:copy-seq seq))
1045
1046 ;;; FIXME: it really should be possible to take advantage of the
1047 ;;; macros used in code/seq.lisp here to avoid duplication of code,
1048 ;;; and enable even funkier transformations.
1049 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
1050                                (test #'eql)
1051                                (key #'identity)
1052                                from-end)
1053                       (vector vector &rest t)
1054                       *
1055                       :node node
1056                       :policy (> speed (max space safety)))
1057   "open code"
1058   (let ((from-end (when (lvar-p from-end)
1059                     (unless (constant-lvar-p from-end)
1060                       (give-up-ir1-transform ":FROM-END is not constant."))
1061                     (lvar-value from-end)))
1062         (keyp (lvar-p key))
1063         (testp (lvar-p test))
1064         (check-bounds-p (policy node (plusp insert-array-bounds-checks))))
1065     `(block search
1066        (flet ((oops (vector start end)
1067                 (sequence-bounding-indices-bad-error vector start end)))
1068          (let* ((len1 (length pattern))
1069                 (len2 (length text))
1070                 (end1 (or end1 len1))
1071                 (end2 (or end2 len2))
1072                ,@(when keyp
1073                        '((key (coerce key 'function))))
1074                ,@(when testp
1075                        '((test (coerce test 'function)))))
1076           (declare (type index start1 start2 end1 end2))
1077           ,@(when check-bounds-p
1078              `((unless (<= start1 end1 len1)
1079                  (oops pattern start1 end1))
1080                (unless (<= start2 end2 len2)
1081                  (oops pattern start2 end2))))
1082           (do (,(if from-end
1083                     '(index2 (- end2 (- end1 start1)) (1- index2))
1084                     '(index2 start2 (1+ index2))))
1085               (,(if from-end
1086                     '(< index2 start2)
1087                     '(>= index2 end2))
1088                nil)
1089             ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
1090             ;; terminates is hits -1 when :FROM-END is true and :START2
1091             ;; is 0.
1092             (declare (type fixnum index2))
1093             (when (do ((index1 start1 (1+ index1))
1094                        (index2 index2 (1+ index2)))
1095                       ((>= index1 end1) t)
1096                     (declare (type index index1 index2)
1097                              (optimize (insert-array-bounds-checks 0)))
1098                     ,@(unless from-end
1099                               '((when (= index2 end2)
1100                                   (return-from search nil))))
1101                     (unless (,@(if testp
1102                                    '(funcall test)
1103                                    '(eql))
1104                                ,(if keyp
1105                                     '(funcall key (aref pattern index1))
1106                                     '(aref pattern index1))
1107                                ,(if keyp
1108                                     '(funcall key (aref text index2))
1109                                     '(aref text index2)))
1110                       (return nil)))
1111               (return index2))))))))
1112
1113
1114 ;;; Open-code CONCATENATE for strings. It would be possible to extend
1115 ;;; this transform to non-strings, but I chose to just do the case that
1116 ;;; should cover 95% of CONCATENATE performance complaints for now.
1117 ;;;   -- JES, 2007-11-17
1118 ;;;
1119 ;;; Only handle the simple result type cases. If somebody does (CONCATENATE
1120 ;;; '(STRING 6) ...) their code won't be optimized, but nobody does that in
1121 ;;; practice.
1122 ;;;
1123 ;;; Limit full open coding based on length of constant sequences. Default
1124 ;;; value is chosen so that other parts of to compiler (constraint propagation
1125 ;;; mainly) won't go nonlinear too badly. It's not an exact number -- but
1126 ;;; in the right ballpark.
1127 (defvar *concatenate-open-code-limit* 129)
1128
1129 (deftransform concatenate ((result-type &rest lvars)
1130                            ((constant-arg
1131                              (member string simple-string base-string simple-base-string))
1132                             &rest sequence)
1133                            * :node node)
1134   (let ((vars (loop for x in lvars collect (gensym)))
1135         (type (lvar-value result-type)))
1136     (if (policy node (<= speed space))
1137         ;; Out-of-line
1138         `(lambda (.dummy. ,@vars)
1139            (declare (ignore .dummy.))
1140            ,(ecase type
1141                    ((string simple-string)
1142                     `(%concatenate-to-string ,@vars))
1143                    ((base-string simple-base-string)
1144                     `(%concatenate-to-base-string ,@vars))))
1145         ;; Inline
1146         (let* ((element-type (ecase type
1147                                ((string simple-string) 'character)
1148                                ((base-string simple-base-string) 'base-char)))
1149                (lvar-values (loop for lvar in lvars
1150                                   collect (when (constant-lvar-p lvar)
1151                                             (lvar-value lvar))))
1152                (lengths
1153                 (loop for value in lvar-values
1154                       for var in vars
1155                       collect (if value
1156                                   (length value)
1157                                   `(sb!impl::string-dispatch ((simple-array * (*))
1158                                                               sequence)
1159                                        ,var
1160                                      (declare (muffle-conditions compiler-note))
1161                                      (length ,var))))))
1162           `(apply
1163             (lambda ,vars
1164               (declare (ignorable ,@vars))
1165               (declare (optimize (insert-array-bounds-checks 0)))
1166               (let* ((.length. (+ ,@lengths))
1167                      (.pos. 0)
1168                      (.string. (make-string .length. :element-type ',element-type)))
1169                 (declare (type index .length. .pos.)
1170                          (muffle-conditions compiler-note))
1171                 ,@(loop for value in lvar-values
1172                         for var in vars
1173                         collect (if (and (stringp value)
1174                                          (< (length value) *concatenate-open-code-limit*))
1175                                     ;; Fold the array reads for constant arguments
1176                                     `(progn
1177                                        ,@(loop for c across value
1178                                                for i from 0
1179                                                collect
1180                                                ;; Without truly-the we get massive numbers
1181                                                ;; of pointless error traps.
1182                                                   `(setf (aref .string.
1183                                                                (truly-the index (+ .pos. ,i)))
1184                                                          ,c))
1185                                        (incf .pos. ,(length value)))
1186                                     `(sb!impl::string-dispatch
1187                                          (#!+sb-unicode
1188                                           (simple-array character (*))
1189                                           (simple-array base-char (*))
1190                                           t)
1191                                          ,var
1192                                        (replace .string. ,var :start1 .pos.)
1193                                        (incf .pos. (length ,var)))))
1194                 .string.))
1195             lvars)))))
1196 \f
1197 ;;;; CONS accessor DERIVE-TYPE optimizers
1198
1199 (defoptimizer (car derive-type) ((cons))
1200   ;; This and CDR needs to use LVAR-CONSERVATIVE-TYPE because type inference
1201   ;; gets confused by things like (SETF CAR).
1202   (let ((type (lvar-conservative-type cons))
1203         (null-type (specifier-type 'null)))
1204     (cond ((eq type null-type)
1205            null-type)
1206           ((cons-type-p type)
1207            (cons-type-car-type type)))))
1208
1209 (defoptimizer (cdr derive-type) ((cons))
1210   (let ((type (lvar-conservative-type cons))
1211         (null-type (specifier-type 'null)))
1212     (cond ((eq type null-type)
1213            null-type)
1214           ((cons-type-p type)
1215            (cons-type-cdr-type type)))))
1216 \f
1217 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
1218
1219 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
1220 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
1221 ;;; expansion, so we factor out the condition into this function.
1222 (defun check-inlineability-of-find-position-if (sequence from-end)
1223   (let ((ctype (lvar-type sequence)))
1224     (cond ((csubtypep ctype (specifier-type 'vector))
1225            ;; It's not worth trying to inline vector code unless we
1226            ;; know a fair amount about it at compile time.
1227            (upgraded-element-type-specifier-or-give-up sequence)
1228            (unless (constant-lvar-p from-end)
1229              (give-up-ir1-transform
1230               "FROM-END argument value not known at compile time")))
1231           ((csubtypep ctype (specifier-type 'list))
1232            ;; Inlining on lists is generally worthwhile.
1233            )
1234           (t
1235            (give-up-ir1-transform
1236             "sequence type not known at compile time")))))
1237
1238 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
1239 (macrolet ((def (name condition)
1240              `(deftransform ,name ((predicate sequence from-end start end key)
1241                                    (function list t t t function)
1242                                    *
1243                                    :policy (> speed space))
1244                 "expand inline"
1245                 `(let ((find nil)
1246                        (position nil))
1247                    (flet ((bounds-error ()
1248                             (sequence-bounding-indices-bad-error sequence start end)))
1249                      (if (and end (> start end))
1250                          (bounds-error)
1251                          (do ((slow sequence (cdr slow))
1252                               (fast (cdr sequence) (cddr fast))
1253                               (index 0 (+ index 1)))
1254                              ((cond ((null slow)
1255                                      (if (and end (> end index))
1256                                          (bounds-error)
1257                                          (return (values find position))))
1258                                     ((and end (>= index end))
1259                                      (return (values find position)))
1260                                     ((eq slow fast)
1261                                      (circular-list-error sequence)))
1262                               (bug "never"))
1263                            (declare (list slow fast))
1264                            (when (>= index start)
1265                              (let* ((element (car slow))
1266                                     (key-i (funcall key element)))
1267                                (,',condition (funcall predicate key-i)
1268                                              ;; This hack of dealing with non-NIL
1269                                              ;; FROM-END for list data by iterating
1270                                              ;; forward through the list and keeping
1271                                              ;; track of the last time we found a
1272                                              ;; match might be more screwy than what
1273                                              ;; the user expects, but it seems to be
1274                                              ;; allowed by the ANSI standard. (And
1275                                              ;; if the user is screwy enough to ask
1276                                              ;; for FROM-END behavior on list data,
1277                                              ;; turnabout is fair play.)
1278                                              ;;
1279                                              ;; It's also not enormously efficient,
1280                                              ;; calling PREDICATE and KEY more often
1281                                              ;; than necessary; but all the
1282                                              ;; alternatives seem to have their own
1283                                              ;; efficiency problems.
1284                                              (if from-end
1285                                                  (setf find element
1286                                                        position index)
1287                                                  (return (values element index)))))))))))))
1288   (def %find-position-if when)
1289   (def %find-position-if-not unless))
1290
1291 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
1292 ;;; without loss of efficiency. (I.e., the optimizer should be able
1293 ;;; to straighten everything out.)
1294 (deftransform %find-position ((item sequence from-end start end key test)
1295                               (t list t t t t t)
1296                               *
1297                               :policy (> speed space))
1298   "expand inline"
1299   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
1300                         ;; The order of arguments for asymmetric tests
1301                         ;; (e.g. #'<, as opposed to order-independent
1302                         ;; tests like #'=) is specified in the spec
1303                         ;; section 17.2.1 -- the O/Zi stuff there.
1304                         (lambda (i)
1305                           (funcall test-fun item i)))
1306                       sequence
1307                       from-end
1308                       start
1309                       end
1310                       (%coerce-callable-to-fun key)))
1311
1312 ;;; The inline expansions for the VECTOR case are saved as macros so
1313 ;;; that we can share them between the DEFTRANSFORMs and the default
1314 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
1315 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1316 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1317                                                             from-end
1318                                                             start
1319                                                             end-arg
1320                                                             element
1321                                                             done-p-expr)
1322   (with-unique-names (offset block index n-sequence sequence end)
1323     `(let* ((,n-sequence ,sequence-arg))
1324        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1325                          (,start ,start)
1326                          (,end ,end-arg)
1327                          :check-fill-pointer t)
1328          (block ,block
1329            (macrolet ((maybe-return ()
1330                         ;; WITH-ARRAY-DATA has already performed bounds
1331                         ;; checking, so we can safely elide the checks
1332                         ;; in the inner loop.
1333                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1334                                            (aref ,sequence ,index))))
1335                           (when ,done-p-expr
1336                             (return-from ,block
1337                               (values ,element
1338                                       (- ,index ,offset)))))))
1339              (if ,from-end
1340                  (loop for ,index
1341                        ;; (If we aren't fastidious about declaring that
1342                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1343                        ;; can send us off into never-never land, since
1344                        ;; INDEX is initialized to -1.)
1345                        of-type index-or-minus-1
1346                        from (1- ,end) downto ,start do
1347                        (maybe-return))
1348                  (loop for ,index of-type index from ,start below ,end do
1349                           (maybe-return))))
1350            (values nil nil))))))
1351
1352 (def!macro %find-position-vector-macro (item sequence
1353                                              from-end start end key test)
1354   (with-unique-names (element)
1355     (%find-position-or-find-position-if-vector-expansion
1356      sequence
1357      from-end
1358      start
1359      end
1360      element
1361      ;; (See the LIST transform for a discussion of the correct
1362      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1363      ;; or after the checked sequence element.)
1364      `(funcall ,test ,item (funcall ,key ,element)))))
1365
1366 (def!macro %find-position-if-vector-macro (predicate sequence
1367                                                      from-end start end key)
1368   (with-unique-names (element)
1369     (%find-position-or-find-position-if-vector-expansion
1370      sequence
1371      from-end
1372      start
1373      end
1374      element
1375      `(funcall ,predicate (funcall ,key ,element)))))
1376
1377 (def!macro %find-position-if-not-vector-macro (predicate sequence
1378                                                          from-end start end key)
1379   (with-unique-names (element)
1380     (%find-position-or-find-position-if-vector-expansion
1381      sequence
1382      from-end
1383      start
1384      end
1385      element
1386      `(not (funcall ,predicate (funcall ,key ,element))))))
1387
1388 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1389 ;;; VECTOR data
1390 (deftransform %find-position-if ((predicate sequence from-end start end key)
1391                                  (function vector t t t function)
1392                                  *
1393                                  :policy (> speed space))
1394   "expand inline"
1395   (check-inlineability-of-find-position-if sequence from-end)
1396   '(%find-position-if-vector-macro predicate sequence
1397                                    from-end start end key))
1398
1399 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1400                                      (function vector t t t function)
1401                                      *
1402                                      :policy (> speed space))
1403   "expand inline"
1404   (check-inlineability-of-find-position-if sequence from-end)
1405   '(%find-position-if-not-vector-macro predicate sequence
1406                                        from-end start end key))
1407
1408 (deftransform %find-position ((item sequence from-end start end key test)
1409                               (t vector t t t function function)
1410                               *
1411                               :policy (> speed space))
1412   "expand inline"
1413   (check-inlineability-of-find-position-if sequence from-end)
1414   '(%find-position-vector-macro item sequence
1415     from-end start end key test))
1416
1417 (deftransform %find-position ((item sequence from-end start end key test)
1418                               (character string t t t function function)
1419                               *
1420                               :policy (> speed space))
1421   (if (eq '* (upgraded-element-type-specifier sequence))
1422       (let ((form
1423              `(sb!impl::string-dispatch ((simple-array character (*))
1424                                          (simple-array base-char (*))
1425                                          (simple-array nil (*)))
1426                   sequence
1427                 (%find-position item sequence from-end start end key test))))
1428         (if (csubtypep (lvar-type sequence) (specifier-type 'simple-string))
1429             form
1430             ;; Otherwise we'd get three instances of WITH-ARRAY-DATA from
1431             ;; %FIND-POSITION.
1432             `(with-array-data ((sequence sequence :offset-var offset)
1433                                (start start)
1434                                (end end)
1435                                :check-fill-pointer t)
1436                (multiple-value-bind (elt index) ,form
1437                  (values elt (when (fixnump index) (- index offset)))))))
1438       ;; The type is known exactly, other transforms will take care of it.
1439       (give-up-ir1-transform)))
1440
1441 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1442 ;;; POSITION-IF, etc.
1443 (define-source-transform effective-find-position-test (test test-not)
1444   (once-only ((test test)
1445               (test-not test-not))
1446     `(cond
1447       ((and ,test ,test-not)
1448        (error "can't specify both :TEST and :TEST-NOT"))
1449       (,test (%coerce-callable-to-fun ,test))
1450       (,test-not
1451        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1452        ;; inefficient, but since the TEST-NOT option is deprecated
1453        ;; anyway, we don't care.)
1454        (complement (%coerce-callable-to-fun ,test-not)))
1455       (t #'eql))))
1456 (define-source-transform effective-find-position-key (key)
1457   (once-only ((key key))
1458     `(if ,key
1459          (%coerce-callable-to-fun ,key)
1460          #'identity)))
1461
1462 (macrolet ((define-find-position (fun-name values-index)
1463              `(deftransform ,fun-name ((item sequence &key
1464                                              from-end (start 0) end
1465                                              key test test-not)
1466                                        (t (or list vector) &rest t))
1467                 '(nth-value ,values-index
1468                             (%find-position item sequence
1469                                             from-end start
1470                                             end
1471                                             (effective-find-position-key key)
1472                                             (effective-find-position-test
1473                                              test test-not))))))
1474   (define-find-position find 0)
1475   (define-find-position position 1))
1476
1477 (macrolet ((define-find-position-if (fun-name values-index)
1478              `(deftransform ,fun-name ((predicate sequence &key
1479                                                   from-end (start 0)
1480                                                   end key)
1481                                        (t (or list vector) &rest t))
1482                 '(nth-value
1483                   ,values-index
1484                   (%find-position-if (%coerce-callable-to-fun predicate)
1485                                      sequence from-end
1486                                      start end
1487                                      (effective-find-position-key key))))))
1488   (define-find-position-if find-if 0)
1489   (define-find-position-if position-if 1))
1490
1491 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1492 ;;; didn't bother to worry about optimizing them, except note that on
1493 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1494 ;;; sbcl-devel
1495 ;;;
1496 ;;;     My understanding is that while the :test-not argument is
1497 ;;;     deprecated in favour of :test (complement #'foo) because of
1498 ;;;     semantic difficulties (what happens if both :test and :test-not
1499 ;;;     are supplied, etc) the -if-not variants, while officially
1500 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1501 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1502 ;;;     reasons for allowing the -if-not versions equal status,
1503 ;;;     particularly remove-if-not (== filter).
1504 ;;;
1505 ;;;     This is only an informal understanding, I grant you, but
1506 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1507 ;;;     way as the others?
1508 ;;;
1509 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1510 ;;; implementation of SBCL.
1511 (macrolet ((define-find-position-if-not (fun-name values-index)
1512                `(deftransform ,fun-name ((predicate sequence &key
1513                                           from-end (start 0)
1514                                           end key)
1515                                          (t (or list vector) &rest t))
1516                  '(nth-value
1517                    ,values-index
1518                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1519                     sequence from-end
1520                     start end
1521                     (effective-find-position-key key))))))
1522   (define-find-position-if-not find-if-not 0)
1523   (define-find-position-if-not position-if-not 1))
1524
1525 (macrolet ((define-trimmer-transform (fun-name leftp rightp)
1526              `(deftransform ,fun-name ((char-bag string)
1527                                        (t simple-string))
1528                 (let ((find-expr
1529                        (if (constant-lvar-p char-bag)
1530                            ;; If the bag is constant, use MEMBER
1531                            ;; instead of FIND, since we have a
1532                            ;; deftransform for MEMBER that can
1533                            ;; open-code all of the comparisons when
1534                            ;; the list is constant. -- JES, 2007-12-10
1535                            `(not (member (schar string index)
1536                                          ',(coerce (lvar-value char-bag) 'list)
1537                                          :test #'char=))
1538                            '(not (find (schar string index) char-bag :test #'char=)))))
1539                   `(flet ((char-not-in-bag (index)
1540                             ,find-expr))
1541                      (let* ((end (length string))
1542                             (left-end (if ,',leftp
1543                                           (do ((index 0 (1+ index)))
1544                                               ((or (= index (the fixnum end))
1545                                                    (char-not-in-bag index))
1546                                                index)
1547                                             (declare (fixnum index)))
1548                                           0))
1549                             (right-end (if ,',rightp
1550                                            (do ((index (1- end) (1- index)))
1551                                                ((or (< index left-end)
1552                                                     (char-not-in-bag index))
1553                                                 (1+ index))
1554                                              (declare (fixnum index)))
1555                                            end)))
1556                        (if (and (eql left-end 0)
1557                                 (eql right-end (length string)))
1558                            string
1559                            (subseq string left-end right-end))))))))
1560   (define-trimmer-transform string-left-trim t nil)
1561   (define-trimmer-transform string-right-trim nil t)
1562   (define-trimmer-transform string-trim t t))
1563