src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places))
 137     (let ((found-vector-p nil))
 138       (flet ((process-vector (length)
 139                (unless found-vector-p
 140                  (setq found-vector-p t)
 141                  (bindings `(index 0 (1+ index)))
 142                  (declarations `(type index index)))
 143                (vector-lengths length)))
 144         (loop for seq of-type lvar in seqs
 145            for seq-name in seq-names
 146            for type = (lvar-type seq)
 147            do (cond ((csubtypep type (specifier-type 'list))
 148                      (with-unique-names (index)
 149                        (bindings `(,index ,seq-name (cdr ,index)))
 150                        (declarations `(type list ,index))
 151                        (places `(car ,index))
 152                        (tests `(endp ,index))))
 153                     ((csubtypep type (specifier-type 'vector))
 154                      (process-vector `(length ,seq-name))
 155                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 156                                 (aref ,seq-name index))))
 157                     (t
 158                      (give-up-ir1-transform
 159                       "can't determine sequence argument type"))))
 160         (when into
 161           (process-vector `(array-dimension ,into 0))))
 162       (when found-vector-p
 163         (bindings `(length (min ,@(vector-lengths))))
 164         (tests `(>= index length)))
 165       `(do (,@(bindings))
 166            ((or ,@(tests)) ,result)
 167          (declare ,@(declarations))
 168          (let ((funcall-result (funcall fun ,@(places))))
 169            (declare (ignorable funcall-result))
 170            ,body)))))
 171
 172 ;;; Try to compile %MAP efficiently when we can determine sequence
 173 ;;; argument types at compile time.
 174 ;;;
 175 ;;; Note: This transform was written to allow open coding of
 176 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 177 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 178 ;;; necessarily as efficient as possible. In particular, it will be
 179 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 180 ;;; numeric element types. It should be straightforward to make it
 181 ;;; handle that case more efficiently, but it's left as an exercise to
 182 ;;; the reader, because the code is complicated enough already and I
 183 ;;; don't happen to need that functionality right now. -- WHN 20000410
 184 (deftransform %map ((result-type fun seq &rest seqs) * *
 185                     :policy (>= speed space))
 186   "open code"
 187   (unless (constant-lvar-p result-type)
 188     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 189   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 190            (fn-1subtypep (fn x y)
 191              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 192                (if valid-p
 193                    subtype-p
 194                    (give-up-ir1-transform
 195                     "can't analyze sequence type relationship"))))
 196            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 197     (let* ((result-type-value (lvar-value result-type))
 198            (result-supertype (cond ((null result-type-value) 'null)
 199                                    ((1subtypep result-type-value 'vector)
 200                                     'vector)
 201                                    ((1subtypep result-type-value 'list)
 202                                     'list)
 203                                    (t
 204                                     (give-up-ir1-transform
 205                                      "result type unsuitable")))))
 206       (cond ((and result-type-value (null seqs))
 207              ;; The consing arity-1 cases can be implemented
 208              ;; reasonably efficiently as function calls, and the cost
 209              ;; of consing should be significantly larger than
 210              ;; function call overhead, so we always compile these
 211              ;; cases as full calls regardless of speed-versus-space
 212              ;; optimization policy.
 213              (cond ((subtypep result-type-value 'list)
 214                     '(%map-to-list-arity-1 fun seq))
 215                    ( ;; (This one can be inefficient due to COERCE, but
 216                     ;; the current open-coded implementation has the
 217                     ;; same problem.)
 218                     (subtypep result-type-value 'vector)
 219                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 220                              ',result-type-value))
 221                    (t (bug "impossible (?) sequence type"))))
 222             (t
 223              (let* ((seqs (cons seq seqs))
 224                     (seq-args (make-gensym-list (length seqs))))
 225                (multiple-value-bind (push-dacc result)
 226                    (ecase result-supertype
 227                      (null (values nil nil))
 228                      (list (values `(push funcall-result acc)
 229                                    `(nreverse acc)))
 230                      (vector (values `(push funcall-result acc)
 231                                      `(coerce (nreverse acc)
 232                                               ',result-type-value))))
 233                  ;; (We use the same idiom, of returning a LAMBDA from
 234                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 235                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 236                  ;; reason: we need to get the runtime values of each
 237                  ;; of the &REST vars.)
 238                  `(lambda (result-type fun ,@seq-args)
 239                     (declare (ignore result-type))
 240                     (let ((fun (%coerce-callable-to-fun fun))
 241                           (acc nil))
 242                       (declare (type list acc))
 243                       (declare (ignorable acc))
 244                       ,(build-sequence-iterator
 245                         seqs seq-args
 246                         :result result
 247                         :body push-dacc))))))))))
 248
 249 ;;; MAP-INTO
 250 (deftransform map-into ((result fun &rest seqs)
 251                         (vector * &rest *)
 252                         *)
 253   "open code"
 254   (let ((seqs-names (mapcar (lambda (x)
 255                               (declare (ignore x))
 256                               (gensym))
 257                             seqs)))
 258     `(lambda (result fun ,@seqs-names)
 259        ,(build-sequence-iterator
 260          seqs seqs-names
 261          :result '(when (array-has-fill-pointer-p result)
 262                    (setf (fill-pointer result) index))
 263          :into 'result
 264          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 265                  (setf (aref result index) funcall-result)))
 266        result)))
 267
 268 \f
 269 ;;; FIXME: once the confusion over doing transforms with known-complex
 270 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 271 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 272 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 273   '(aref s i))
 274
 275 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 276   '(nth i s))
 277
 278 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 279   '(%aset s i v))
 280
 281 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 282   '(setf (car (nthcdr i s)) v))
 283
 284 (deftransform %check-vector-sequence-bounds ((vector start end)
 285                                              (vector * *) *
 286                                              :node node)
 287   (if (policy node (= 0 insert-array-bounds-checks))
 288       '(or end (length vector))
 289       '(let ((length (length vector)))
 290          (if (<= 0 start (or end length) length)
 291              (or end length)
 292              (sequence-bounding-indices-bad-error vector start end)))))
 293
 294 (defun specialized-list-seek-function-name (function-name key-functions variant)
 295   (or (find-symbol (with-output-to-string (s)
 296                      ;; Write "%NAME-FUN1-FUN2-FUN3", etc. Not only is
 297                      ;; this ever so slightly faster then FORMAT, this
 298                      ;; way we are also proof against *PRINT-CASE*
 299                      ;; frobbing and such.
 300                      (write-char #\% s)
 301                      (write-string (symbol-name function-name) s)
 302                      (dolist (f key-functions)
 303                        (write-char #\- s)
 304                        (write-string (symbol-name f) s))
 305                      (when variant
 306                        (write-char #\- s)
 307                        (write-string (symbol-name variant) s)))
 308                    (load-time-value (find-package "SB!KERNEL")))
 309       (bug "Unknown list item seek transform: name=~S, key-functions=~S variant=~S"
 310            function-name key-functions variant)))
 311
 312 (defun transform-list-item-seek (name item list key test test-not node)
 313   ;; If TEST is EQL, drop it.
 314   (when (and test (lvar-for-named-function test 'eql))
 315     (setf test nil))
 316   ;; Ditto for KEY IDENTITY.
 317   (when (and key (lvar-for-named-function key 'identity))
 318     (setf key nil))
 319   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 320   ;; not there at all. If it might be NIL, make up a form to that
 321   ;; ensures it is a function.
 322   (multiple-value-bind (key key-form)
 323       (when key
 324         (let ((key-type (lvar-type key))
 325               (null-type (specifier-type 'null)))
 326           (cond ((csubtypep key-type null-type)
 327                  (values nil nil))
 328                 ((csubtypep null-type key-type)
 329                  (values key '(if key
 330                                (%coerce-callable-to-fun key)
 331                                #'identity)))
 332                 (t
 333                  (values key '(%coerce-callable-to-fun key))))))
 334     (let* ((c-test (cond ((and test (lvar-for-named-function test 'eq))
 335                           (setf test nil)
 336                           'eq)
 337                          ((and (not test) (not test-not))
 338                           (when (eq-comparable-type-p (lvar-type item))
 339                             'eq))))
 340            (funs (remove nil (list (and key 'key) (cond (test 'test)
 341                                                         (test-not 'test-not)))))
 342            (target-expr (if key '(%funcall key target) 'target))
 343            (test-expr (cond (test `(%funcall test item ,target-expr))
 344                             (test-not `(not (%funcall test-not item ,target-expr)))
 345                             (c-test `(,c-test item ,target-expr))
 346                             (t `(eql item ,target-expr)))))
 347       (labels ((open-code (tail)
 348                  (when tail
 349                    `(if (let ((this ',(car tail)))
 350                           ,(ecase name
 351                                   (assoc
 352                                    `(and this (let ((target (car this)))
 353                                                 ,test-expr)))
 354                                   (member
 355                                    `(let ((target this))
 356                                       ,test-expr))))
 357                         ',(ecase name
 358                                  (assoc (car tail))
 359                                  (member tail))
 360                         ,(open-code (cdr tail)))))
 361                (ensure-fun (fun)
 362                  (if (eq 'key fun)
 363                      key-form
 364                      `(%coerce-callable-to-fun ,fun))))
 365         (let* ((cp (constant-lvar-p list))
 366                (c-list (when cp (lvar-value list))))
 367           (cond ((and cp c-list (policy node (>= speed space)))
 368                  `(let ,(mapcar (lambda (fun) `(,fun ,(ensure-fun fun))) funs)
 369                     ,(open-code c-list)))
 370                 ((and cp (not c-list))
 371                  ;; constant nil list -- nothing to find!
 372                  nil)
 373                 (t
 374                  ;; specialized out-of-line version
 375                  `(,(specialized-list-seek-function-name name funs c-test)
 376                     item list ,@(mapcar #'ensure-fun funs)))))))))
 377
 378 (deftransform member ((item list &key key test test-not) * * :node node)
 379   (transform-list-item-seek 'member item list key test test-not node))
 380
 381 (deftransform assoc ((item list &key key test test-not) * * :node node)
 382   (transform-list-item-seek 'assoc item list key test test-not node))
 383
 384 (deftransform adjoin ((item list &key key test test-not) * * :node node)
 385   (transform-list-item-seek 'adjoin item list key test test-not node))
 386
 387 (deftransform memq ((item list) (t (constant-arg list)))
 388   (labels ((rec (tail)
 389              (if tail
 390                  `(if (eq item ',(car tail))
 391                       ',tail
 392                       ,(rec (cdr tail)))
 393                  nil)))
 394     (rec (lvar-value list))))
 395
 396 ;;; A similar transform used to apply to MEMBER and ASSOC, but since
 397 ;;; TRANSFORM-LIST-ITEM-SEEK now takes care of them those transform
 398 ;;; would never fire, and (%MEMBER-TEST ITEM LIST #'EQ) should be
 399 ;;; almost as fast as MEMQ.
 400 (deftransform delete ((item list &key test) (t list &rest t) *)
 401   "convert to EQ test"
 402   ;; FIXME: The scope of this transformation could be
 403   ;; widened somewhat, letting it work whenever the test is
 404   ;; 'EQL and we know from the type of ITEM that it #'EQ
 405   ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 406   ;; and SYMBOL.)
 407   ;;   If TEST is EQ, apply transform, else
 408   ;;   if test is not EQL, then give up on transform, else
 409   ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 410   ;;   transform, else give up on transform.
 411   (cond (test
 412          (unless (lvar-fun-is test '(eq))
 413            (give-up-ir1-transform)))
 414         ((types-equal-or-intersect (lvar-type item)
 415                                    (specifier-type 'number))
 416          (give-up-ir1-transform "Item might be a number.")))
 417   `(delq item list))
 418
 419 (deftransform delete-if ((pred list) (t list))
 420   "open code"
 421   '(do ((x list (cdr x))
 422         (splice '()))
 423        ((endp x) list)
 424      (cond ((funcall pred (car x))
 425             (if (null splice)
 426                 (setq list (cdr x))
 427                 (rplacd splice (cdr x))))
 428            (t (setq splice x)))))
 429
 430 (deftransform fill ((seq item &key (start 0) (end nil))
 431                     (list t &key (:start t) (:end t)))
 432   '(list-fill* seq item start end))
 433
 434 (deftransform fill ((seq item &key (start 0) (end nil))
 435                     (vector t &key (:start t) (:end t))
 436                     *
 437                     :node node)
 438   (let ((type (lvar-type seq))
 439         (element-type (type-specifier (extract-upgraded-element-type seq))))
 440     (cond ((and (neq '* element-type) (policy node (> speed space)))
 441            (values
 442             `(with-array-data ((data seq)
 443                                (start start)
 444                                (end end)
 445                                :check-fill-pointer t)
 446                (declare (type (simple-array ,element-type 1) data))
 447                (declare (type index start end))
 448                ;; WITH-ARRAY-DATA did our range checks once and for all, so
 449                ;; it'd be wasteful to check again on every AREF...
 450                (declare (optimize (safety 0) (speed 3)))
 451                (do ((i start (1+ i)))
 452                    ((= i end) seq)
 453                  (declare (type index i))
 454                  (setf (aref data i) item)))
 455             ;; ... though we still need to check that the new element can fit
 456             ;; into the vector in safe code. -- CSR, 2002-07-05
 457             `((declare (type ,element-type item)))))
 458           ((csubtypep type (specifier-type 'string))
 459            '(string-fill* seq item start end))
 460           (t
 461            '(vector-fill* seq item start end)))))
 462
 463 (deftransform fill ((seq item &key (start 0) (end nil))
 464                     ((and sequence (not vector) (not list)) t &key (:start t) (:end t)))
 465   `(sb!sequence:fill seq item
 466                      :start start
 467                      :end (%check-generic-sequence-bounds seq start end)))
 468 \f
 469 ;;;; utilities
 470
 471 ;;; Return true if LVAR's only use is a non-NOTINLINE reference to a
 472 ;;; global function with one of the specified NAMES.
 473 (defun lvar-fun-is (lvar names)
 474   (declare (type lvar lvar) (list names))
 475   (let ((use (lvar-uses lvar)))
 476     (and (ref-p use)
 477          (let ((leaf (ref-leaf use)))
 478            (and (global-var-p leaf)
 479                 (eq (global-var-kind leaf) :global-function)
 480                 (not (null (member (leaf-source-name leaf) names
 481                                    :test #'equal))))))))
 482
 483 ;;; If LVAR is a constant lvar, the return the constant value. If it
 484 ;;; is null, then return default, otherwise quietly give up the IR1
 485 ;;; transform.
 486 ;;;
 487 ;;; ### Probably should take an ARG and flame using the NAME.
 488 (defun constant-value-or-lose (lvar &optional default)
 489   (declare (type (or lvar null) lvar))
 490   (cond ((not lvar) default)
 491         ((constant-lvar-p lvar)
 492          (lvar-value lvar))
 493         (t
 494          (give-up-ir1-transform))))
 495
 496
 497 ;;;; hairy sequence transforms
 498
 499 ;;; FIXME: no hairy sequence transforms in SBCL?
 500 ;;;
 501 ;;; There used to be a bunch of commented out code about here,
 502 ;;; containing the (apparent) beginning of hairy sequence transform
 503 ;;; infrastructure. People interested in implementing better sequence
 504 ;;; transforms might want to look at it for inspiration, even though
 505 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 506 ;;; was deleted in 1.0.7.23.
 507 \f
 508 ;;;; string operations
 509
 510 ;;; We transform the case-sensitive string predicates into a non-keyword
 511 ;;; version. This is an IR1 transform so that we don't have to worry about
 512 ;;; changing the order of evaluation.
 513 (macrolet ((def (fun pred*)
 514              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 515                                                          (start2 0) end2)
 516                                    * *)
 517                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 518   (def string< string<*)
 519   (def string> string>*)
 520   (def string<= string<=*)
 521   (def string>= string>=*)
 522   (def string= string=*)
 523   (def string/= string/=*))
 524
 525 ;;; Return a form that tests the free variables STRING1 and STRING2
 526 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 527 ;;; start and end are also gotten from the environment. Both strings
 528 ;;; must be SIMPLE-BASE-STRINGs.
 529 (macrolet ((def (name lessp equalp)
 530              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 531                                    (simple-base-string simple-base-string t t t t) *)
 532                 `(let* ((end1 (if (not end1) (length string1) end1))
 533                         (end2 (if (not end2) (length string2) end2))
 534                         (index (sb!impl::%sp-string-compare
 535                                 string1 start1 end1 string2 start2 end2)))
 536                   (if index
 537                       (cond ((= index end1)
 538                              ,(if ',lessp 'index nil))
 539                             ((= (+ index (- start2 start1)) end2)
 540                              ,(if ',lessp nil 'index))
 541                             ((,(if ',lessp 'char< 'char>)
 542                                (schar string1 index)
 543                                (schar string2
 544                                       (truly-the index
 545                                                  (+ index
 546                                                     (truly-the fixnum
 547                                                                (- start2
 548                                                                   start1))))))
 549                              index)
 550                             (t nil))
 551                       ,(if ',equalp 'end1 nil))))))
 552   (def string<* t nil)
 553   (def string<=* t t)
 554   (def string>* nil nil)
 555   (def string>=* nil t))
 556
 557 (macrolet ((def (name result-fun)
 558              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 559                                    (simple-base-string simple-base-string t t t t) *)
 560                 `(,',result-fun
 561                   (sb!impl::%sp-string-compare
 562                    string1 start1 (or end1 (length string1))
 563                    string2 start2 (or end2 (length string2)))))))
 564   (def string=* not)
 565   (def string/=* identity))
 566
 567 \f
 568 ;;;; transforms for sequence functions
 569
 570 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 571 ;;; to vectors based on simple arrays.
 572 (def!constant vector-data-bit-offset
 573   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 574
 575 (eval-when (:compile-toplevel)
 576 (defun valid-bit-bash-saetp-p (saetp)
 577   ;; BIT-BASHing isn't allowed on simple vectors that contain pointers
 578   (and (not (eq t (sb!vm:saetp-specifier saetp)))
 579        ;; Disallowing (VECTOR NIL) also means that we won't transform
 580        ;; sequence functions into bit-bashing code and we let the
 581        ;; generic sequence functions signal errors if necessary.
 582        (not (zerop (sb!vm:saetp-n-bits saetp)))
 583        ;; Due to limitations with the current BIT-BASHing code, we can't
 584        ;; BIT-BASH reliably on arrays whose element types are larger
 585        ;; than the word size.
 586        (<= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)))
 587 ) ; EVAL-WHEN
 588
 589 ;;; FIXME: In the copy loops below, we code the loops in a strange
 590 ;;; fashion:
 591 ;;;
 592 ;;; (do ((i (+ src-offset length) (1- i)))
 593 ;;;     ((<= i 0) ...)
 594 ;;;   (... (aref foo (1- i)) ...))
 595 ;;;
 596 ;;; rather than the more natural (and seemingly more efficient):
 597 ;;;
 598 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 599 ;;;     ((< i 0) ...)
 600 ;;;   (... (aref foo i) ...))
 601 ;;;
 602 ;;; (more efficient because we don't have to do the index adjusting on
 603 ;;; every iteration of the loop)
 604 ;;;
 605 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 606 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 607 ;;; when used as an array index, the backend thinks I is a
 608 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 609 ;;; these as distinct storage classes, it cannot coerce a move from a
 610 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 611 ;;; deficiency is that we have two extra moves and increased register
 612 ;;; pressure, which can lead to some spectacularly bad register
 613 ;;; allocation.  (sub-FIXME: the register allocation even with the
 614 ;;; strangely written loops is not always excellent, either...).  Doing
 615 ;;; it the first way, above, means that I is always thought of as a
 616 ;;; POSITIVE-FIXNUM and there are no issues.
 617 ;;;
 618 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 619 ;;; adjustments in the first version into the array addressing at no
 620 ;;; performance penalty!
 621
 622 ;;; This transform is critical to the performance of string streams.  If
 623 ;;; you tweak it, make sure that you compare the disassembly, if not the
 624 ;;; performance of, the functions implementing string streams
 625 ;;; (e.g. SB!IMPL::STRING-OUCH).
 626 (eval-when (:compile-toplevel :load-toplevel :execute)
 627   (defun make-replace-transform (saetp sequence-type1 sequence-type2)
 628     `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 629                             (,sequence-type1 ,sequence-type2 &rest t)
 630                             ,sequence-type1
 631                             :node node)
 632        ,(cond
 633          ((and saetp (valid-bit-bash-saetp-p saetp)) nil)
 634          ;; If the sequence types are different, SEQ1 and SEQ2 must
 635          ;; be distinct arrays, and we can open code the copy loop.
 636          ((not (eql sequence-type1 sequence-type2)) nil)
 637          ;; If we're not bit-bashing, only allow cases where we
 638          ;; can determine the order of copying up front.  (There
 639          ;; are actually more cases we can handle if we know the
 640          ;; amount that we're copying, but this handles the
 641          ;; common cases.)
 642          (t '(unless (= (constant-value-or-lose start1 0)
 643                       (constant-value-or-lose start2 0))
 644               (give-up-ir1-transform))))
 645        `(let* ((len1 (length seq1))
 646                (len2 (length seq2))
 647                (end1 (or end1 len1))
 648                (end2 (or end2 len2))
 649                (replace-len1 (- end1 start1))
 650                (replace-len2 (- end2 start2)))
 651           ,(unless (policy node (= safety 0))
 652              `(progn
 653                  (unless (<= 0 start1 end1 len1)
 654                    (sequence-bounding-indices-bad-error seq1 start1 end1))
 655                  (unless (<= 0 start2 end2 len2)
 656                    (sequence-bounding-indices-bad-error seq2 start2 end2))))
 657           ,',(cond
 658               ((and saetp (valid-bit-bash-saetp-p saetp))
 659                (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 660                       (bash-function (intern (format nil "UB~D-BASH-COPY"
 661                                                      n-element-bits)
 662                                              (find-package "SB!KERNEL"))))
 663                  `(funcall (function ,bash-function) seq2 start2
 664                            seq1 start1 (min replace-len1 replace-len2))))
 665               (t
 666                ;; We can expand the loop inline here because we
 667                ;; would have given up the transform (see above)
 668                ;; if we didn't have constant matching start
 669                ;; indices.
 670                '(do ((i start1 (1+ i))
 671                      (j start2 (1+ j))
 672                      (end (+ start1
 673                              (min replace-len1 replace-len2))))
 674                  ((>= i end))
 675                  (declare (optimize (insert-array-bounds-checks 0)))
 676                  (setf (aref seq1 i) (aref seq2 j)))))
 677           seq1))))
 678
 679 (macrolet
 680     ((define-replace-transforms ()
 681        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 682              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 683              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 684              collect (make-replace-transform saetp sequence-type sequence-type)
 685              into forms
 686              finally (return `(progn ,@forms))))
 687      (define-one-transform (sequence-type1 sequence-type2)
 688        (make-replace-transform nil sequence-type1 sequence-type2)))
 689   (define-replace-transforms)
 690   #!+sb-unicode
 691   (progn
 692    (define-one-transform (simple-array base-char (*)) (simple-array character (*)))
 693    (define-one-transform (simple-array character (*)) (simple-array base-char (*)))))
 694
 695 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 696 ;;; defined as those cases where we are doing word-aligned copies from
 697 ;;; both the source and the destination and we are copying from the same
 698 ;;; offset from both the source and the destination.  (The last
 699 ;;; condition is there so we can determine the direction to copy at
 700 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 701 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 702 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 703 ;;; N)-size buffer and blitting in the old N-size buffer in.
 704
 705 (defun frob-bash-transform (src src-offset
 706                             dst dst-offset
 707                             length n-elems-per-word)
 708   (declare (ignore src dst length))
 709   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 710     (multiple-value-bind (src-word src-elt)
 711         (truncate (lvar-value src-offset) n-elems-per-word)
 712       (multiple-value-bind (dst-word dst-elt)
 713           (truncate (lvar-value dst-offset) n-elems-per-word)
 714         ;; Avoid non-word aligned copies.
 715         (unless (and (zerop src-elt) (zerop dst-elt))
 716           (give-up-ir1-transform))
 717         ;; Avoid copies where we would have to insert code for
 718         ;; determining the direction of copying.
 719         (unless (= src-word dst-word)
 720           (give-up-ir1-transform))
 721         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 722         ;; so we have to do its work here.
 723         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 724                                       'length
 725                                       `(truncate (the index length) ,n-elems-per-word)))))
 726            (declare (type index end))
 727            ;; Handle any bits at the end.
 728            (when (logtest length (1- ,n-elems-per-word))
 729              (let* ((extra (mod length ,n-elems-per-word))
 730                     ;; FIXME: The shift amount on this ASH is
 731                     ;; *always* negative, but the backend doesn't
 732                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 733                     ;; wind up with a pile of code that tests the
 734                     ;; sign of the shift count prior to shifting when
 735                     ;; all we need is a simple negate and shift
 736                     ;; right.  Yuck.
 737                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 738                                (* (- extra ,n-elems-per-word)
 739                                   ,n-bits-per-elem))))
 740                (setf (sb!kernel:%vector-raw-bits dst end)
 741                      (logior
 742                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 743                                 (ash mask
 744                                      ,(ecase sb!c:*backend-byte-order*
 745                                              (:little-endian 0)
 746                                              (:big-endian `(* (- ,n-elems-per-word extra)
 747                                                               ,n-bits-per-elem)))))
 748                       (logand (sb!kernel:%vector-raw-bits src end)
 749                               (ash mask
 750                                    ,(ecase sb!c:*backend-byte-order*
 751                                            (:little-endian 0)
 752                                            (:big-endian `(* (- ,n-elems-per-word extra)
 753                                                             ,n-bits-per-elem)))))))))
 754            ;; Copy from the end to save a register.
 755            (do ((i end (1- i)))
 756                ((<= i ,src-word))
 757              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 758                    (sb!kernel:%vector-raw-bits src (1- i))))
 759            (values))))))
 760
 761 #.(loop for i = 1 then (* i 2)
 762         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 763                                         "SB!KERNEL")
 764                                                         ((src src-offset
 765                                                           dst dst-offset
 766                                                           length)
 767                                                         ((simple-unboxed-array (*))
 768                                                          (constant-arg index)
 769                                                          (simple-unboxed-array (*))
 770                                                          (constant-arg index)
 771                                                          index)
 772                                                         *)
 773                   (frob-bash-transform src src-offset
 774                                        dst dst-offset length
 775                                        ,(truncate sb!vm:n-word-bits i))) into forms
 776         until (= i sb!vm:n-word-bits)
 777         finally (return `(progn ,@forms)))
 778
 779 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 780 ;;; arrays with elements of size >= the word size.  We do this because
 781 ;;; we know the arrays cannot alias (one was just consed), therefore we
 782 ;;; can determine at compile time the direction to copy, and for
 783 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 784 ;;; needless checking to figure out what's going on.  The same
 785 ;;; considerations apply if we are copying elements larger than the word
 786 ;;; size, with the additional twist that doing it inline is likely to
 787 ;;; cons far less than calling REPLACE and letting generic code do the
 788 ;;; work.
 789 ;;;
 790 ;;; However, we do not do this for elements whose size is < than the
 791 ;;; word size because we don't want to deal with any alignment issues
 792 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 793 ;;; anyway.
 794
 795 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 796                                       element-type)
 797   (let ((saetp (find-saetp element-type)))
 798     (aver saetp)
 799     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 800         (expand-aref-copy-loop src src-offset dst dst-offset length)
 801         `(locally (declare (optimize (safety 0)))
 802            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 803
 804 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 805   (if (eql src-offset dst-offset)
 806       `(do ((i (+ ,src-offset ,length) (1- i)))
 807            ((<= i ,src-offset))
 808          (declare (optimize (insert-array-bounds-checks 0)))
 809          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 810       ;; KLUDGE: The compiler is not able to derive that (+ offset
 811       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 812       ;; We, however, know it must be so, as by this point the bounds
 813       ;; have already been checked.
 814       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 815             (j (+ ,dst-offset ,length) (1- j)))
 816            ((<= i ,src-offset))
 817          (declare (optimize (insert-array-bounds-checks 0))
 818                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 819          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 820
 821 ;;; SUBSEQ, COPY-SEQ
 822
 823 (deftransform subseq ((seq start &optional end)
 824                       (vector t &optional t)
 825                       *
 826                       :node node)
 827   (let ((type (lvar-type seq)))
 828     (cond
 829       ((and (array-type-p type)
 830             (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 831        (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 832          `(let* ((length (length seq))
 833                  (end (or end length)))
 834             ,(unless (policy node (zerop insert-array-bounds-checks))
 835                      '(progn
 836                        (unless (<= 0 start end length)
 837                          (sequence-bounding-indices-bad-error seq start end))))
 838             (let* ((size (- end start))
 839                    (result (make-array size :element-type ',element-type)))
 840               ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
 841                                                        (lvar-value start)
 842                                                        'start)
 843                                               'result 0 'size element-type)
 844               result))))
 845       ((csubtypep type (specifier-type 'string))
 846        '(string-subseq* seq start end))
 847       (t
 848        '(vector-subseq* seq start end)))))
 849
 850 (deftransform subseq ((seq start &optional end)
 851                       (list t &optional t))
 852   `(list-subseq* seq start end))
 853
 854 (deftransform subseq ((seq start &optional end)
 855                       ((and sequence (not vector) (not list)) t &optional t))
 856   '(sb!sequence:subseq seq start end))
 857
 858 (deftransform copy-seq ((seq) (vector))
 859   (let ((type (lvar-type seq)))
 860     (cond ((and (array-type-p type)
 861                 (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 862            (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 863              `(let* ((length (length seq))
 864                      (result (make-array length :element-type ',element-type)))
 865                 ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
 866                 result)))
 867           ((csubtypep type (specifier-type 'string))
 868            '(string-subseq* seq 0 nil))
 869           (t
 870            '(vector-subseq* seq 0 nil)))))
 871
 872 (deftransform copy-seq ((seq) (list))
 873   '(list-copy-seq* seq))
 874
 875 (deftransform copy-seq ((seq) ((and sequence (not vector) (not list))))
 876   '(sb!sequence:copy-seq seq))
 877
 878 ;;; FIXME: it really should be possible to take advantage of the
 879 ;;; macros used in code/seq.lisp here to avoid duplication of code,
 880 ;;; and enable even funkier transformations.
 881 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
 882                                (test #'eql)
 883                                (key #'identity)
 884                                from-end)
 885                       (vector vector &rest t)
 886                       *
 887                       :node node
 888                       :policy (> speed (max space safety)))
 889   "open code"
 890   (let ((from-end (when (lvar-p from-end)
 891                     (unless (constant-lvar-p from-end)
 892                       (give-up-ir1-transform ":FROM-END is not constant."))
 893                     (lvar-value from-end)))
 894         (keyp (lvar-p key))
 895         (testp (lvar-p test))
 896         (check-bounds-p (policy node (plusp insert-array-bounds-checks))))
 897     `(block search
 898        (flet ((oops (vector start end)
 899                 (sequence-bounding-indices-bad-error vector start end)))
 900          (let* ((len1 (length pattern))
 901                 (len2 (length text))
 902                 (end1 (or end1 len1))
 903                 (end2 (or end2 len2))
 904                ,@(when keyp
 905                        '((key (coerce key 'function))))
 906                ,@(when testp
 907                        '((test (coerce test 'function)))))
 908           (declare (type index start1 start2 end1 end2))
 909           ,@(when check-bounds-p
 910              `((unless (<= start1 end1 len1)
 911                  (oops pattern start1 end1))
 912                (unless (<= start2 end2 len2)
 913                  (oops pattern start2 end2))))
 914           (do (,(if from-end
 915                     '(index2 (- end2 (- end1 start1)) (1- index2))
 916                     '(index2 start2 (1+ index2))))
 917               (,(if from-end
 918                     '(< index2 start2)
 919                     '(>= index2 end2))
 920                nil)
 921             ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
 922             ;; terminates is hits -1 when :FROM-END is true and :START2
 923             ;; is 0.
 924             (declare (type fixnum index2))
 925             (when (do ((index1 start1 (1+ index1))
 926                        (index2 index2 (1+ index2)))
 927                       ((>= index1 end1) t)
 928                     (declare (type index index1 index2)
 929                              (optimize (insert-array-bounds-checks 0)))
 930                     ,@(unless from-end
 931                               '((when (= index2 end2)
 932                                   (return-from search nil))))
 933                     (unless (,@(if testp
 934                                    '(funcall test)
 935                                    '(eql))
 936                                ,(if keyp
 937                                     '(funcall key (aref pattern index1))
 938                                     '(aref pattern index1))
 939                                ,(if keyp
 940                                     '(funcall key (aref text index2))
 941                                     '(aref text index2)))
 942                       (return nil)))
 943               (return index2))))))))
 944
 945
 946 ;;; Open-code CONCATENATE for strings. It would be possible to extend
 947 ;;; this transform to non-strings, but I chose to just do the case that
 948 ;;; should cover 95% of CONCATENATE performance complaints for now.
 949 ;;;   -- JES, 2007-11-17
 950 (deftransform concatenate ((result-type &rest lvars)
 951                            (symbol &rest sequence)
 952                            *
 953                            :policy (> speed space))
 954   (unless (constant-lvar-p result-type)
 955     (give-up-ir1-transform))
 956   (let* ((element-type (let ((type (lvar-value result-type)))
 957                          ;; Only handle the simple result type cases. If
 958                          ;; somebody does (CONCATENATE '(STRING 6) ...)
 959                          ;; their code won't be optimized, but nobody does
 960                          ;; that in practice.
 961                          (case type
 962                            ((string simple-string) 'character)
 963                            ((base-string simple-base-string) 'base-char)
 964                            (t (give-up-ir1-transform)))))
 965          (vars (loop for x in lvars collect (gensym)))
 966          (lvar-values (loop for lvar in lvars
 967                             collect (when (constant-lvar-p lvar)
 968                                       (lvar-value lvar))))
 969          (lengths
 970           (loop for value in lvar-values
 971                 for var in vars
 972                 collect (if value
 973                             (length value)
 974                             `(sb!impl::string-dispatch ((simple-array * (*))
 975                                                         sequence)
 976                                  ,var
 977                                (declare (muffle-conditions compiler-note))
 978                                (length ,var))))))
 979     `(apply
 980       (lambda ,vars
 981         (declare (ignorable ,@vars))
 982         (let* ((.length. (+ ,@lengths))
 983                (.pos. 0)
 984                (.string. (make-string .length. :element-type ',element-type)))
 985           (declare (type index .length. .pos.)
 986                    (muffle-conditions compiler-note))
 987           ,@(loop for value in lvar-values
 988                   for var in vars
 989                   collect (if (stringp value)
 990                               ;; Fold the array reads for constant arguments
 991                               `(progn
 992                                  ,@(loop for c across value
 993                                          collect `(setf (aref .string.
 994                                                               .pos.) ,c)
 995                                          collect `(incf .pos.)))
 996                               `(sb!impl::string-dispatch
 997                                    (#!+sb-unicode
 998                                     (simple-array character (*))
 999                                     (simple-array base-char (*))
1000                                     t)
1001                                    ,var
1002                                  (replace .string. ,var :start1 .pos.)
1003                                  (incf .pos. (length ,var)))))
1004           .string.))
1005       lvars)))
1006 \f
1007 ;;;; CONS accessor DERIVE-TYPE optimizers
1008
1009 (defoptimizer (car derive-type) ((cons))
1010   (let ((type (lvar-type cons))
1011         (null-type (specifier-type 'null)))
1012     (cond ((eq type null-type)
1013            null-type)
1014           ((cons-type-p type)
1015            (cons-type-car-type type)))))
1016
1017 (defoptimizer (cdr derive-type) ((cons))
1018   (let ((type (lvar-type cons))
1019         (null-type (specifier-type 'null)))
1020     (cond ((eq type null-type)
1021            null-type)
1022           ((cons-type-p type)
1023            (cons-type-cdr-type type)))))
1024 \f
1025 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
1026
1027 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
1028 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
1029 ;;; expansion, so we factor out the condition into this function.
1030 (defun check-inlineability-of-find-position-if (sequence from-end)
1031   (let ((ctype (lvar-type sequence)))
1032     (cond ((csubtypep ctype (specifier-type 'vector))
1033            ;; It's not worth trying to inline vector code unless we
1034            ;; know a fair amount about it at compile time.
1035            (upgraded-element-type-specifier-or-give-up sequence)
1036            (unless (constant-lvar-p from-end)
1037              (give-up-ir1-transform
1038               "FROM-END argument value not known at compile time")))
1039           ((csubtypep ctype (specifier-type 'list))
1040            ;; Inlining on lists is generally worthwhile.
1041            )
1042           (t
1043            (give-up-ir1-transform
1044             "sequence type not known at compile time")))))
1045
1046 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
1047 (macrolet ((def (name condition)
1048              `(deftransform ,name ((predicate sequence from-end start end key)
1049                                    (function list t t t function)
1050                                    *
1051                                    :policy (> speed space))
1052                 "expand inline"
1053                 `(let ((index 0)
1054                        (find nil)
1055                        (position nil))
1056                    (declare (type index index))
1057                    (dolist (i sequence
1058                             (if (and end (> end index))
1059                                 (sequence-bounding-indices-bad-error
1060                                  sequence start end)
1061                                 (values find position)))
1062                      (let ((key-i (funcall key i)))
1063                        (when (and end (>= index end))
1064                          (return (values find position)))
1065                        (when (>= index start)
1066                          (,',condition (funcall predicate key-i)
1067                           ;; This hack of dealing with non-NIL
1068                           ;; FROM-END for list data by iterating
1069                           ;; forward through the list and keeping
1070                           ;; track of the last time we found a match
1071                           ;; might be more screwy than what the user
1072                           ;; expects, but it seems to be allowed by
1073                           ;; the ANSI standard. (And if the user is
1074                           ;; screwy enough to ask for FROM-END
1075                           ;; behavior on list data, turnabout is
1076                           ;; fair play.)
1077                           ;;
1078                           ;; It's also not enormously efficient,
1079                           ;; calling PREDICATE and KEY more often
1080                           ;; than necessary; but all the
1081                           ;; alternatives seem to have their own
1082                           ;; efficiency problems.
1083                           (if from-end
1084                               (setf find i
1085                                     position index)
1086                               (return (values i index))))))
1087                      (incf index))))))
1088   (def %find-position-if when)
1089   (def %find-position-if-not unless))
1090
1091 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
1092 ;;; without loss of efficiency. (I.e., the optimizer should be able
1093 ;;; to straighten everything out.)
1094 (deftransform %find-position ((item sequence from-end start end key test)
1095                               (t list t t t t t)
1096                               *
1097                               :policy (> speed space))
1098   "expand inline"
1099   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
1100                         ;; The order of arguments for asymmetric tests
1101                         ;; (e.g. #'<, as opposed to order-independent
1102                         ;; tests like #'=) is specified in the spec
1103                         ;; section 17.2.1 -- the O/Zi stuff there.
1104                         (lambda (i)
1105                           (funcall test-fun item i)))
1106                       sequence
1107                       from-end
1108                       start
1109                       end
1110                       (%coerce-callable-to-fun key)))
1111
1112 ;;; The inline expansions for the VECTOR case are saved as macros so
1113 ;;; that we can share them between the DEFTRANSFORMs and the default
1114 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
1115 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1116 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1117                                                             from-end
1118                                                             start
1119                                                             end-arg
1120                                                             element
1121                                                             done-p-expr)
1122   (with-unique-names (offset block index n-sequence sequence end)
1123     `(let* ((,n-sequence ,sequence-arg))
1124        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1125                          (,start ,start)
1126                          (,end ,end-arg)
1127                          :check-fill-pointer t)
1128          (block ,block
1129            (macrolet ((maybe-return ()
1130                         ;; WITH-ARRAY-DATA has already performed bounds
1131                         ;; checking, so we can safely elide the checks
1132                         ;; in the inner loop.
1133                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1134                                            (aref ,sequence ,index))))
1135                           (when ,done-p-expr
1136                             (return-from ,block
1137                               (values ,element
1138                                       (- ,index ,offset)))))))
1139              (if ,from-end
1140                  (loop for ,index
1141                        ;; (If we aren't fastidious about declaring that
1142                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1143                        ;; can send us off into never-never land, since
1144                        ;; INDEX is initialized to -1.)
1145                        of-type index-or-minus-1
1146                        from (1- ,end) downto ,start do
1147                        (maybe-return))
1148                  (loop for ,index of-type index from ,start below ,end do
1149                           (maybe-return))))
1150            (values nil nil))))))
1151
1152 (def!macro %find-position-vector-macro (item sequence
1153                                              from-end start end key test)
1154   (with-unique-names (element)
1155     (%find-position-or-find-position-if-vector-expansion
1156      sequence
1157      from-end
1158      start
1159      end
1160      element
1161      ;; (See the LIST transform for a discussion of the correct
1162      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1163      ;; or after the checked sequence element.)
1164      `(funcall ,test ,item (funcall ,key ,element)))))
1165
1166 (def!macro %find-position-if-vector-macro (predicate sequence
1167                                                      from-end start end key)
1168   (with-unique-names (element)
1169     (%find-position-or-find-position-if-vector-expansion
1170      sequence
1171      from-end
1172      start
1173      end
1174      element
1175      `(funcall ,predicate (funcall ,key ,element)))))
1176
1177 (def!macro %find-position-if-not-vector-macro (predicate sequence
1178                                                          from-end start end key)
1179   (with-unique-names (element)
1180     (%find-position-or-find-position-if-vector-expansion
1181      sequence
1182      from-end
1183      start
1184      end
1185      element
1186      `(not (funcall ,predicate (funcall ,key ,element))))))
1187
1188 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1189 ;;; VECTOR data
1190 (deftransform %find-position-if ((predicate sequence from-end start end key)
1191                                  (function vector t t t function)
1192                                  *
1193                                  :policy (> speed space))
1194   "expand inline"
1195   (check-inlineability-of-find-position-if sequence from-end)
1196   '(%find-position-if-vector-macro predicate sequence
1197                                    from-end start end key))
1198
1199 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1200                                      (function vector t t t function)
1201                                      *
1202                                      :policy (> speed space))
1203   "expand inline"
1204   (check-inlineability-of-find-position-if sequence from-end)
1205   '(%find-position-if-not-vector-macro predicate sequence
1206                                        from-end start end key))
1207
1208 (deftransform %find-position ((item sequence from-end start end key test)
1209                               (t vector t t t function function)
1210                               *
1211                               :policy (> speed space))
1212   "expand inline"
1213   (check-inlineability-of-find-position-if sequence from-end)
1214   '(%find-position-vector-macro item sequence
1215     from-end start end key test))
1216
1217 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1218 ;;; POSITION-IF, etc.
1219 (define-source-transform effective-find-position-test (test test-not)
1220   (once-only ((test test)
1221               (test-not test-not))
1222     `(cond
1223       ((and ,test ,test-not)
1224        (error "can't specify both :TEST and :TEST-NOT"))
1225       (,test (%coerce-callable-to-fun ,test))
1226       (,test-not
1227        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1228        ;; inefficient, but since the TEST-NOT option is deprecated
1229        ;; anyway, we don't care.)
1230        (complement (%coerce-callable-to-fun ,test-not)))
1231       (t #'eql))))
1232 (define-source-transform effective-find-position-key (key)
1233   (once-only ((key key))
1234     `(if ,key
1235          (%coerce-callable-to-fun ,key)
1236          #'identity)))
1237
1238 (macrolet ((define-find-position (fun-name values-index)
1239              `(deftransform ,fun-name ((item sequence &key
1240                                              from-end (start 0) end
1241                                              key test test-not)
1242                                        (t (or list vector) &rest t))
1243                 '(nth-value ,values-index
1244                             (%find-position item sequence
1245                                             from-end start
1246                                             end
1247                                             (effective-find-position-key key)
1248                                             (effective-find-position-test
1249                                              test test-not))))))
1250   (define-find-position find 0)
1251   (define-find-position position 1))
1252
1253 (macrolet ((define-find-position-if (fun-name values-index)
1254              `(deftransform ,fun-name ((predicate sequence &key
1255                                                   from-end (start 0)
1256                                                   end key)
1257                                        (t (or list vector) &rest t))
1258                 '(nth-value
1259                   ,values-index
1260                   (%find-position-if (%coerce-callable-to-fun predicate)
1261                                      sequence from-end
1262                                      start end
1263                                      (effective-find-position-key key))))))
1264   (define-find-position-if find-if 0)
1265   (define-find-position-if position-if 1))
1266
1267 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1268 ;;; didn't bother to worry about optimizing them, except note that on
1269 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1270 ;;; sbcl-devel
1271 ;;;
1272 ;;;     My understanding is that while the :test-not argument is
1273 ;;;     deprecated in favour of :test (complement #'foo) because of
1274 ;;;     semantic difficulties (what happens if both :test and :test-not
1275 ;;;     are supplied, etc) the -if-not variants, while officially
1276 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1277 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1278 ;;;     reasons for allowing the -if-not versions equal status,
1279 ;;;     particularly remove-if-not (== filter).
1280 ;;;
1281 ;;;     This is only an informal understanding, I grant you, but
1282 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1283 ;;;     way as the others?
1284 ;;;
1285 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1286 ;;; implementation of SBCL.
1287 (macrolet ((define-find-position-if-not (fun-name values-index)
1288                `(deftransform ,fun-name ((predicate sequence &key
1289                                           from-end (start 0)
1290                                           end key)
1291                                          (t (or list vector) &rest t))
1292                  '(nth-value
1293                    ,values-index
1294                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1295                     sequence from-end
1296                     start end
1297                     (effective-find-position-key key))))))
1298   (define-find-position-if-not find-if-not 0)
1299   (define-find-position-if-not position-if-not 1))
1300
1301 (macrolet ((define-trimmer-transform (fun-name leftp rightp)
1302              `(deftransform ,fun-name ((char-bag string)
1303                                        (t simple-string))
1304                 (let ((find-expr
1305                        (if (constant-lvar-p char-bag)
1306                            ;; If the bag is constant, use MEMBER
1307                            ;; instead of FIND, since we have a
1308                            ;; deftransform for MEMBER that can
1309                            ;; open-code all of the comparisons when
1310                            ;; the list is constant. -- JES, 2007-12-10
1311                            `(not (member (schar string index)
1312                                          ',(coerce (lvar-value char-bag) 'list)
1313                                          :test #'char=))
1314                            '(not (find (schar string index) char-bag :test #'char=)))))
1315                   `(flet ((char-not-in-bag (index)
1316                             ,find-expr))
1317                      (let* ((end (length string))
1318                             (left-end (if ,',leftp
1319                                           (do ((index 0 (1+ index)))
1320                                               ((or (= index (the fixnum end))
1321                                                    (char-not-in-bag index))
1322                                                index)
1323                                             (declare (fixnum index)))
1324                                           0))
1325                             (right-end (if ,',rightp
1326                                            (do ((index (1- end) (1- index)))
1327                                                ((or (< index left-end)
1328                                                     (char-not-in-bag index))
1329                                                 (1+ index))
1330                                              (declare (fixnum index)))
1331                                            end)))
1332                        (if (and (eql left-end 0)
1333                                 (eql right-end (length string)))
1334                            string
1335                            (subseq string left-end right-end))))))))
1336   (define-trimmer-transform string-left-trim t nil)
1337   (define-trimmer-transform string-right-trim nil t)
1338   (define-trimmer-transform string-trim t t))
1339