src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places))
 137     (let ((found-vector-p nil))
 138       (flet ((process-vector (length)
 139                (unless found-vector-p
 140                  (setq found-vector-p t)
 141                  (bindings `(index 0 (1+ index)))
 142                  (declarations `(type index index)))
 143                (vector-lengths length)))
 144         (loop for seq of-type lvar in seqs
 145            for seq-name in seq-names
 146            for type = (lvar-type seq)
 147            do (cond ((csubtypep type (specifier-type 'list))
 148                      (with-unique-names (index)
 149                        (bindings `(,index ,seq-name (cdr ,index)))
 150                        (declarations `(type list ,index))
 151                        (places `(car ,index))
 152                        (tests `(endp ,index))))
 153                     ((csubtypep type (specifier-type 'vector))
 154                      (process-vector `(length ,seq-name))
 155                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 156                                 (aref ,seq-name index))))
 157                     (t
 158                      (give-up-ir1-transform
 159                       "can't determine sequence argument type"))))
 160         (when into
 161           (process-vector `(array-dimension ,into 0))))
 162       (when found-vector-p
 163         (bindings `(length (min ,@(vector-lengths))))
 164         (tests `(>= index length)))
 165       `(do (,@(bindings))
 166            ((or ,@(tests)) ,result)
 167          (declare ,@(declarations))
 168          (let ((funcall-result (funcall fun ,@(places))))
 169            (declare (ignorable funcall-result))
 170            ,body)))))
 171
 172 ;;; Try to compile %MAP efficiently when we can determine sequence
 173 ;;; argument types at compile time.
 174 ;;;
 175 ;;; Note: This transform was written to allow open coding of
 176 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 177 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 178 ;;; necessarily as efficient as possible. In particular, it will be
 179 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 180 ;;; numeric element types. It should be straightforward to make it
 181 ;;; handle that case more efficiently, but it's left as an exercise to
 182 ;;; the reader, because the code is complicated enough already and I
 183 ;;; don't happen to need that functionality right now. -- WHN 20000410
 184 (deftransform %map ((result-type fun seq &rest seqs) * *
 185                     :policy (>= speed space))
 186   "open code"
 187   (unless (constant-lvar-p result-type)
 188     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 189   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 190            (fn-1subtypep (fn x y)
 191              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 192                (if valid-p
 193                    subtype-p
 194                    (give-up-ir1-transform
 195                     "can't analyze sequence type relationship"))))
 196            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 197     (let* ((result-type-value (lvar-value result-type))
 198            (result-supertype (cond ((null result-type-value) 'null)
 199                                    ((1subtypep result-type-value 'vector)
 200                                     'vector)
 201                                    ((1subtypep result-type-value 'list)
 202                                     'list)
 203                                    (t
 204                                     (give-up-ir1-transform
 205                                      "result type unsuitable")))))
 206       (cond ((and result-type-value (null seqs))
 207              ;; The consing arity-1 cases can be implemented
 208              ;; reasonably efficiently as function calls, and the cost
 209              ;; of consing should be significantly larger than
 210              ;; function call overhead, so we always compile these
 211              ;; cases as full calls regardless of speed-versus-space
 212              ;; optimization policy.
 213              (cond ((subtypep result-type-value 'list)
 214                     '(%map-to-list-arity-1 fun seq))
 215                    ( ;; (This one can be inefficient due to COERCE, but
 216                     ;; the current open-coded implementation has the
 217                     ;; same problem.)
 218                     (subtypep result-type-value 'vector)
 219                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 220                              ',result-type-value))
 221                    (t (bug "impossible (?) sequence type"))))
 222             (t
 223              (let* ((seqs (cons seq seqs))
 224                     (seq-args (make-gensym-list (length seqs))))
 225                (multiple-value-bind (push-dacc result)
 226                    (ecase result-supertype
 227                      (null (values nil nil))
 228                      (list (values `(push funcall-result acc)
 229                                    `(nreverse acc)))
 230                      (vector (values `(push funcall-result acc)
 231                                      `(coerce (nreverse acc)
 232                                               ',result-type-value))))
 233                  ;; (We use the same idiom, of returning a LAMBDA from
 234                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 235                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 236                  ;; reason: we need to get the runtime values of each
 237                  ;; of the &REST vars.)
 238                  `(lambda (result-type fun ,@seq-args)
 239                     (declare (ignore result-type))
 240                     (let ((fun (%coerce-callable-to-fun fun))
 241                           (acc nil))
 242                       (declare (type list acc))
 243                       (declare (ignorable acc))
 244                       ,(build-sequence-iterator
 245                         seqs seq-args
 246                         :result result
 247                         :body push-dacc))))))))))
 248
 249 ;;; MAP-INTO
 250 (deftransform map-into ((result fun &rest seqs)
 251                         (vector * &rest *)
 252                         *)
 253   "open code"
 254   (let ((seqs-names (mapcar (lambda (x)
 255                               (declare (ignore x))
 256                               (gensym))
 257                             seqs)))
 258     `(lambda (result fun ,@seqs-names)
 259        ,(build-sequence-iterator
 260          seqs seqs-names
 261          :result '(when (array-has-fill-pointer-p result)
 262                    (setf (fill-pointer result) index))
 263          :into 'result
 264          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 265                  (setf (aref result index) funcall-result)))
 266        result)))
 267
 268 \f
 269 ;;; FIXME: once the confusion over doing transforms with known-complex
 270 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 271 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 272 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 273   '(aref s i))
 274
 275 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 276   '(nth i s))
 277
 278 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 279   '(%aset s i v))
 280
 281 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 282   '(setf (car (nthcdr i s)) v))
 283
 284 (deftransform %check-vector-sequence-bounds ((vector start end)
 285                                              (vector * *) *
 286                                              :node node)
 287   (if (policy node (< safety speed))
 288       '(or end (length vector))
 289       '(let ((length (length vector)))
 290         (if (<= 0 start (or end length) length)
 291             (or end length)
 292             (sb!impl::signal-bounding-indices-bad-error vector start end)))))
 293
 294 (defun transform-list-item-seek (name list key test test-not node)
 295   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 296   ;; not there at all. If it might be NIL, make up a form to that
 297   ;; ensure it is a function.
 298   (multiple-value-bind (key key-form)
 299       (if key
 300           (let ((key-type (lvar-type key))
 301                 (null-type (specifier-type 'null)))
 302             (cond ((csubtypep key-type null-type)
 303                    (values nil nil))
 304                   ((csubtypep null-type key-type)
 305                    (values key '(if key
 306                                  (%coerce-callable-to-fun key)
 307                                  #'identity)))
 308                   (t
 309                    (values key '(%coerce-callable-to-fun key))))))
 310     (let* ((funs (remove nil (list (and key 'key) (cond (test 'test)
 311                                                         (test-not 'test-not)))))
 312            (out-of-line (or (find-symbol (format nil "%~A~{-~A~}" name funs)
 313                                          (load-time-value (find-package "SB!KERNEL")))
 314                             (bug "Unknown list item seek transform: name=~S, funs=~S"
 315                                  name funs)))
 316            (target-expr (if key '(%funcall key target) 'target))
 317            (test-expr (cond (test `(%funcall test item ,target-expr))
 318                             (test-not `(not (%funcall test-not item ,target-expr)))
 319                             (t `(eql item ,target-expr)))))
 320       (labels ((open-code (tail)
 321                  (when tail
 322                    `(if (let ((this ',(car tail)))
 323                           ,(ecase name
 324                                   (assoc
 325                                    `(and this (let ((target (car this)))
 326                                                 ,test-expr)))
 327                                   (member
 328                                    `(let ((target this))
 329                                       ,test-expr))))
 330                         ',(ecase name
 331                                  (assoc (car tail))
 332                                  (member tail))
 333                         ,(open-code (cdr tail)))))
 334                (ensure-fun (fun)
 335                  (if (eq 'key fun)
 336                      key-form
 337                      `(%coerce-callable-to-fun ,fun))))
 338         (let* ((cp (constant-lvar-p list))
 339                (c-list (when cp (lvar-value list))))
 340           (cond ((and cp c-list (policy node (>= speed space)))
 341                  `(let ,(mapcar (lambda (fun) `(,fun ,(ensure-fun fun))) funs)
 342                     ,(open-code c-list)))
 343                 ((and cp (not c-list))
 344                  ;; constant nil list -- nothing to find!
 345                  nil)
 346                 (t
 347                  `(,out-of-line item list ,@(mapcar #'ensure-fun funs)))))))))
 348
 349 (deftransform member ((item list &key key test test-not) * * :node node)
 350   (transform-list-item-seek 'member list key test test-not node))
 351
 352 (deftransform assoc ((item list &key key test test-not) * * :node node)
 353   (transform-list-item-seek 'assoc list key test test-not node))
 354
 355 (deftransform memq ((item list) (t (constant-arg list)))
 356   (labels ((rec (tail)
 357              (if tail
 358                  `(if (eq item ',(car tail))
 359                       ',tail
 360                       ,(rec (cdr tail)))
 361                  nil)))
 362     (rec (lvar-value list))))
 363
 364 ;;; A similar transform used to apply to MEMBER and ASSOC, but since
 365 ;;; TRANSFORM-LIST-ITEM-SEEK now takes care of them those transform
 366 ;;; would never fire, and (%MEMBER-TEST ITEM LIST #'EQ) should be
 367 ;;; almost as fast as MEMQ.
 368 (deftransform delete ((item list &key test) (t list &rest t) *)
 369   "convert to EQ test"
 370   ;; FIXME: The scope of this transformation could be
 371   ;; widened somewhat, letting it work whenever the test is
 372   ;; 'EQL and we know from the type of ITEM that it #'EQ
 373   ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 374   ;; and SYMBOL.)
 375   ;;   If TEST is EQ, apply transform, else
 376   ;;   if test is not EQL, then give up on transform, else
 377   ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 378   ;;   transform, else give up on transform.
 379   (cond (test
 380          (unless (lvar-fun-is test '(eq))
 381            (give-up-ir1-transform)))
 382         ((types-equal-or-intersect (lvar-type item)
 383                                    (specifier-type 'number))
 384          (give-up-ir1-transform "Item might be a number.")))
 385   `(delq item list))
 386
 387 (deftransform delete-if ((pred list) (t list))
 388   "open code"
 389   '(do ((x list (cdr x))
 390         (splice '()))
 391        ((endp x) list)
 392      (cond ((funcall pred (car x))
 393             (if (null splice)
 394                 (setq list (cdr x))
 395                 (rplacd splice (cdr x))))
 396            (t (setq splice x)))))
 397
 398 (deftransform fill ((seq item &key (start 0) (end (length seq)))
 399                     (vector t &key (:start t) (:end index))
 400                     *
 401                     :policy (> speed space))
 402   "open code"
 403   (let ((element-type (upgraded-element-type-specifier-or-give-up seq)))
 404     (values
 405      `(with-array-data ((data seq)
 406                         (start start)
 407                         (end end))
 408        (declare (type (simple-array ,element-type 1) data))
 409        (declare (type fixnum start end))
 410        (do ((i start (1+ i)))
 411            ((= i end) seq)
 412          (declare (type index i))
 413          ;; WITH-ARRAY-DATA did our range checks once and for all, so
 414          ;; it'd be wasteful to check again on every AREF...
 415          (declare (optimize (safety 0)))
 416          (setf (aref data i) item)))
 417      ;; ... though we still need to check that the new element can fit
 418      ;; into the vector in safe code. -- CSR, 2002-07-05
 419      `((declare (type ,element-type item))))))
 420 \f
 421 ;;;; utilities
 422
 423 ;;; Return true if LVAR's only use is a non-NOTINLINE reference to a
 424 ;;; global function with one of the specified NAMES.
 425 (defun lvar-fun-is (lvar names)
 426   (declare (type lvar lvar) (list names))
 427   (let ((use (lvar-uses lvar)))
 428     (and (ref-p use)
 429          (let ((leaf (ref-leaf use)))
 430            (and (global-var-p leaf)
 431                 (eq (global-var-kind leaf) :global-function)
 432                 (not (null (member (leaf-source-name leaf) names
 433                                    :test #'equal))))))))
 434
 435 ;;; If LVAR is a constant lvar, the return the constant value. If it
 436 ;;; is null, then return default, otherwise quietly give up the IR1
 437 ;;; transform.
 438 ;;;
 439 ;;; ### Probably should take an ARG and flame using the NAME.
 440 (defun constant-value-or-lose (lvar &optional default)
 441   (declare (type (or lvar null) lvar))
 442   (cond ((not lvar) default)
 443         ((constant-lvar-p lvar)
 444          (lvar-value lvar))
 445         (t
 446          (give-up-ir1-transform))))
 447
 448
 449 ;;;; hairy sequence transforms
 450
 451 ;;; FIXME: no hairy sequence transforms in SBCL?
 452 ;;;
 453 ;;; There used to be a bunch of commented out code about here,
 454 ;;; containing the (apparent) beginning of hairy sequence transform
 455 ;;; infrastructure. People interested in implementing better sequence
 456 ;;; transforms might want to look at it for inspiration, even though
 457 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 458 ;;; was deleted in 1.0.7.23.
 459 \f
 460 ;;;; string operations
 461
 462 ;;; We transform the case-sensitive string predicates into a non-keyword
 463 ;;; version. This is an IR1 transform so that we don't have to worry about
 464 ;;; changing the order of evaluation.
 465 (macrolet ((def (fun pred*)
 466              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 467                                                          (start2 0) end2)
 468                                    * *)
 469                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 470   (def string< string<*)
 471   (def string> string>*)
 472   (def string<= string<=*)
 473   (def string>= string>=*)
 474   (def string= string=*)
 475   (def string/= string/=*))
 476
 477 ;;; Return a form that tests the free variables STRING1 and STRING2
 478 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 479 ;;; start and end are also gotten from the environment. Both strings
 480 ;;; must be SIMPLE-BASE-STRINGs.
 481 (macrolet ((def (name lessp equalp)
 482              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 483                                    (simple-base-string simple-base-string t t t t) *)
 484                 `(let* ((end1 (if (not end1) (length string1) end1))
 485                         (end2 (if (not end2) (length string2) end2))
 486                         (index (sb!impl::%sp-string-compare
 487                                 string1 start1 end1 string2 start2 end2)))
 488                   (if index
 489                       (cond ((= index end1)
 490                              ,(if ',lessp 'index nil))
 491                             ((= (+ index (- start2 start1)) end2)
 492                              ,(if ',lessp nil 'index))
 493                             ((,(if ',lessp 'char< 'char>)
 494                                (schar string1 index)
 495                                (schar string2
 496                                       (truly-the index
 497                                                  (+ index
 498                                                     (truly-the fixnum
 499                                                                (- start2
 500                                                                   start1))))))
 501                              index)
 502                             (t nil))
 503                       ,(if ',equalp 'end1 nil))))))
 504   (def string<* t nil)
 505   (def string<=* t t)
 506   (def string>* nil nil)
 507   (def string>=* nil t))
 508
 509 (macrolet ((def (name result-fun)
 510              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 511                                    (simple-base-string simple-base-string t t t t) *)
 512                 `(,',result-fun
 513                   (sb!impl::%sp-string-compare
 514                    string1 start1 (or end1 (length string1))
 515                    string2 start2 (or end2 (length string2)))))))
 516   (def string=* not)
 517   (def string/=* identity))
 518
 519 \f
 520 ;;;; transforms for sequence functions
 521
 522 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 523 ;;; to vectors based on simple arrays.
 524 (def!constant vector-data-bit-offset
 525   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 526
 527 (eval-when (:compile-toplevel)
 528 (defun valid-bit-bash-saetp-p (saetp)
 529   ;; BIT-BASHing isn't allowed on simple vectors that contain pointers
 530   (and (not (eq t (sb!vm:saetp-specifier saetp)))
 531        ;; Disallowing (VECTOR NIL) also means that we won't transform
 532        ;; sequence functions into bit-bashing code and we let the
 533        ;; generic sequence functions signal errors if necessary.
 534        (not (zerop (sb!vm:saetp-n-bits saetp)))
 535        ;; Due to limitations with the current BIT-BASHing code, we can't
 536        ;; BIT-BASH reliably on arrays whose element types are larger
 537        ;; than the word size.
 538        (<= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)))
 539 ) ; EVAL-WHEN
 540
 541 ;;; FIXME: In the copy loops below, we code the loops in a strange
 542 ;;; fashion:
 543 ;;;
 544 ;;; (do ((i (+ src-offset length) (1- i)))
 545 ;;;     ((<= i 0) ...)
 546 ;;;   (... (aref foo (1- i)) ...))
 547 ;;;
 548 ;;; rather than the more natural (and seemingly more efficient):
 549 ;;;
 550 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 551 ;;;     ((< i 0) ...)
 552 ;;;   (... (aref foo i) ...))
 553 ;;;
 554 ;;; (more efficient because we don't have to do the index adjusting on
 555 ;;; every iteration of the loop)
 556 ;;;
 557 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 558 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 559 ;;; when used as an array index, the backend thinks I is a
 560 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 561 ;;; these as distinct storage classes, it cannot coerce a move from a
 562 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 563 ;;; deficiency is that we have two extra moves and increased register
 564 ;;; pressure, which can lead to some spectacularly bad register
 565 ;;; allocation.  (sub-FIXME: the register allocation even with the
 566 ;;; strangely written loops is not always excellent, either...).  Doing
 567 ;;; it the first way, above, means that I is always thought of as a
 568 ;;; POSITIVE-FIXNUM and there are no issues.
 569 ;;;
 570 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 571 ;;; adjustments in the first version into the array addressing at no
 572 ;;; performance penalty!
 573
 574 ;;; This transform is critical to the performance of string streams.  If
 575 ;;; you tweak it, make sure that you compare the disassembly, if not the
 576 ;;; performance of, the functions implementing string streams
 577 ;;; (e.g. SB!IMPL::STRING-OUCH).
 578 (macrolet
 579     ((define-replace-transforms ()
 580        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 581              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 582              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 583              collect
 584             `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 585                                     (,sequence-type ,sequence-type &rest t)
 586                                     ,sequence-type
 587                                     :node node)
 588                ,(cond
 589                  ((valid-bit-bash-saetp-p saetp) nil)
 590                  ;; If we're not bit-bashing, only allow cases where we
 591                  ;; can determine the order of copying up front.  (There
 592                  ;; are actually more cases we can handle if we know the
 593                  ;; amount that we're copying, but this handles the
 594                  ;; common cases.)
 595                  (t '(unless (= (constant-value-or-lose start1 0)
 596                               (constant-value-or-lose start2 0))
 597                       (give-up-ir1-transform))))
 598                `(let* ((len1 (length seq1))
 599                        (len2 (length seq2))
 600                        (end1 (or end1 len1))
 601                        (end2 (or end2 len2))
 602                        (replace-len1 (- end1 start1))
 603                        (replace-len2 (- end2 start2)))
 604                   ,(unless (policy node (= safety 0))
 605                            `(progn
 606                               (unless (<= 0 start1 end1 len1)
 607                                 (sb!impl::signal-bounding-indices-bad-error seq1 start1 end1))
 608                               (unless (<= 0 start2 end2 len2)
 609                                 (sb!impl::signal-bounding-indices-bad-error seq2 start2 end2))))
 610                   ,',(cond
 611                       ((valid-bit-bash-saetp-p saetp)
 612                        (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 613                               (bash-function (intern (format nil "UB~D-BASH-COPY" n-element-bits)
 614                                                      (find-package "SB!KERNEL"))))
 615                          `(funcall (function ,bash-function) seq2 start2
 616                                    seq1 start1 (min replace-len1 replace-len2))))
 617                       (t
 618                        ;; We can expand the loop inline here because we
 619                        ;; would have given up the transform (see above)
 620                        ;; if we didn't have constant matching start
 621                        ;; indices.
 622                        '(do ((i start1 (1+ i))
 623                              (end (+ start1
 624                                      (min replace-len1 replace-len2))))
 625                          ((>= i end))
 626                          (declare (optimize (insert-array-bounds-checks 0)))
 627                          (setf (aref seq1 i) (aref seq2 i)))))
 628                   seq1))
 629              into forms
 630              finally (return `(progn ,@forms)))))
 631   (define-replace-transforms))
 632
 633 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 634 ;;; defined as those cases where we are doing word-aligned copies from
 635 ;;; both the source and the destination and we are copying from the same
 636 ;;; offset from both the source and the destination.  (The last
 637 ;;; condition is there so we can determine the direction to copy at
 638 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 639 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 640 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 641 ;;; N)-size buffer and blitting in the old N-size buffer in.
 642
 643 (defun frob-bash-transform (src src-offset
 644                             dst dst-offset
 645                             length n-elems-per-word)
 646   (declare (ignore src dst length))
 647   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 648     (multiple-value-bind (src-word src-elt)
 649         (truncate (lvar-value src-offset) n-elems-per-word)
 650       (multiple-value-bind (dst-word dst-elt)
 651           (truncate (lvar-value dst-offset) n-elems-per-word)
 652         ;; Avoid non-word aligned copies.
 653         (unless (and (zerop src-elt) (zerop dst-elt))
 654           (give-up-ir1-transform))
 655         ;; Avoid copies where we would have to insert code for
 656         ;; determining the direction of copying.
 657         (unless (= src-word dst-word)
 658           (give-up-ir1-transform))
 659         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 660         ;; so we have to do its work here.
 661         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 662                                       'length
 663                                       `(truncate (the index length) ,n-elems-per-word)))))
 664            (declare (type index end))
 665            ;; Handle any bits at the end.
 666            (when (logtest length (1- ,n-elems-per-word))
 667              (let* ((extra (mod length ,n-elems-per-word))
 668                     ;; FIXME: The shift amount on this ASH is
 669                     ;; *always* negative, but the backend doesn't
 670                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 671                     ;; wind up with a pile of code that tests the
 672                     ;; sign of the shift count prior to shifting when
 673                     ;; all we need is a simple negate and shift
 674                     ;; right.  Yuck.
 675                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 676                                (* (- extra ,n-elems-per-word)
 677                                   ,n-bits-per-elem))))
 678                (setf (sb!kernel:%vector-raw-bits dst end)
 679                      (logior
 680                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 681                                 (ash mask
 682                                      ,(ecase sb!c:*backend-byte-order*
 683                                              (:little-endian 0)
 684                                              (:big-endian `(* (- ,n-elems-per-word extra)
 685                                                               ,n-bits-per-elem)))))
 686                       (logand (sb!kernel:%vector-raw-bits src end)
 687                               (ash mask
 688                                    ,(ecase sb!c:*backend-byte-order*
 689                                            (:little-endian 0)
 690                                            (:big-endian `(* (- ,n-elems-per-word extra)
 691                                                             ,n-bits-per-elem)))))))))
 692            ;; Copy from the end to save a register.
 693            (do ((i end (1- i)))
 694                ((<= i ,src-word))
 695              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 696                    (sb!kernel:%vector-raw-bits src (1- i)))))))))
 697
 698 #.(loop for i = 1 then (* i 2)
 699         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 700                                         "SB!KERNEL")
 701                                                         ((src src-offset
 702                                                           dst dst-offset
 703                                                           length)
 704                                                         ((simple-unboxed-array (*))
 705                                                          (constant-arg index)
 706                                                          (simple-unboxed-array (*))
 707                                                          (constant-arg index)
 708                                                          index)
 709                                                         *)
 710                   (frob-bash-transform src src-offset
 711                                        dst dst-offset length
 712                                        ,(truncate sb!vm:n-word-bits i))) into forms
 713         until (= i sb!vm:n-word-bits)
 714         finally (return `(progn ,@forms)))
 715
 716 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 717 ;;; arrays with elements of size >= the word size.  We do this because
 718 ;;; we know the arrays cannot alias (one was just consed), therefore we
 719 ;;; can determine at compile time the direction to copy, and for
 720 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 721 ;;; needless checking to figure out what's going on.  The same
 722 ;;; considerations apply if we are copying elements larger than the word
 723 ;;; size, with the additional twist that doing it inline is likely to
 724 ;;; cons far less than calling REPLACE and letting generic code do the
 725 ;;; work.
 726 ;;;
 727 ;;; However, we do not do this for elements whose size is < than the
 728 ;;; word size because we don't want to deal with any alignment issues
 729 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 730 ;;; anyway.
 731
 732 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 733                                       element-type)
 734   (let ((saetp (find-saetp element-type)))
 735     (aver saetp)
 736     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 737         (expand-aref-copy-loop src src-offset dst dst-offset length)
 738         `(locally (declare (optimize (safety 0)))
 739            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 740
 741 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 742   (if (eql src-offset dst-offset)
 743       `(do ((i (+ ,src-offset ,length) (1- i)))
 744            ((<= i ,src-offset))
 745          (declare (optimize (insert-array-bounds-checks 0)))
 746          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 747       ;; KLUDGE: The compiler is not able to derive that (+ offset
 748       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 749       ;; We, however, know it must be so, as by this point the bounds
 750       ;; have already been checked.
 751       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 752             (j (+ ,dst-offset ,length) (1- j)))
 753            ((<= i ,src-offset))
 754          (declare (optimize (insert-array-bounds-checks 0))
 755                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 756          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 757
 758 (deftransform subseq ((seq start &optional end)
 759                       ((or (simple-unboxed-array (*)) simple-vector) t &optional t)
 760                       * :node node)
 761   (let ((array-type (lvar-type seq)))
 762     (unless (array-type-p array-type)
 763       (give-up-ir1-transform))
 764     (let ((element-type (type-specifier (array-type-specialized-element-type array-type))))
 765       `(let* ((length (length seq))
 766               (end (or end length)))
 767          ,(unless (policy node (= safety 0))
 768                   '(progn
 769                     (unless (<= 0 start end length)
 770                       (sb!impl::signal-bounding-indices-bad-error seq start end))))
 771          (let* ((size (- end start))
 772                 (result (make-array size :element-type ',element-type)))
 773            ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
 774                                                     (lvar-value start)
 775                                                     'start)
 776                                            'result 0 'size element-type)
 777            result)))))
 778
 779 (deftransform copy-seq ((seq) ((or (simple-unboxed-array (*)) simple-vector)) *)
 780   (let ((array-type (lvar-type seq)))
 781     (unless (array-type-p array-type)
 782       (give-up-ir1-transform))
 783     (let ((element-type (type-specifier (array-type-specialized-element-type array-type))))
 784       `(let* ((length (length seq))
 785               (result (make-array length :element-type ',element-type)))
 786          ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
 787          result))))
 788
 789 ;;; FIXME: it really should be possible to take advantage of the
 790 ;;; macros used in code/seq.lisp here to avoid duplication of code,
 791 ;;; and enable even funkier transformations.
 792 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
 793                                (test #'eql)
 794                                (key #'identity)
 795                                from-end)
 796                       (vector vector &rest t)
 797                       *
 798                       :policy (> speed (max space safety)))
 799   "open code"
 800   (let ((from-end (when (lvar-p from-end)
 801                     (unless (constant-lvar-p from-end)
 802                       (give-up-ir1-transform ":FROM-END is not constant."))
 803                     (lvar-value from-end)))
 804         (keyp (lvar-p key))
 805         (testp (lvar-p test)))
 806     `(block search
 807        (let ((end1 (or end1 (length pattern)))
 808              (end2 (or end2 (length text)))
 809              ,@(when keyp
 810                      '((key (coerce key 'function))))
 811              ,@(when testp
 812                      '((test (coerce test 'function)))))
 813          (declare (type index start1 start2 end1 end2))
 814          (do (,(if from-end
 815                    '(index2 (- end2 (- end1 start1)) (1- index2))
 816                    '(index2 start2 (1+ index2))))
 817              (,(if from-end
 818                    '(< index2 start2)
 819                    '(>= index2 end2))
 820               nil)
 821            ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
 822            ;; terminates is hits -1 when :FROM-END is true and :START2
 823            ;; is 0.
 824            (declare (type fixnum index2))
 825            (when (do ((index1 start1 (1+ index1))
 826                       (index2 index2 (1+ index2)))
 827                      ((>= index1 end1) t)
 828                    (declare (type index index1 index2))
 829                    ,@(unless from-end
 830                              '((when (= index2 end2)
 831                                  (return-from search nil))))
 832                    (unless (,@(if testp
 833                                   '(funcall test)
 834                                   '(eql))
 835                               ,(if keyp
 836                                    '(funcall key (aref pattern index1))
 837                                    '(aref pattern index1))
 838                               ,(if keyp
 839                                    '(funcall key (aref text index2))
 840                                    '(aref text index2)))
 841                      (return nil)))
 842              (return index2)))))))
 843
 844 ;;; FIXME: It seems as though it should be possible to make a DEFUN
 845 ;;; %CONCATENATE (with a DEFTRANSFORM to translate constant RTYPE to
 846 ;;; CTYPE before calling %CONCATENATE) which is comparably efficient,
 847 ;;; at least once DYNAMIC-EXTENT works.
 848 ;;;
 849 ;;; FIXME: currently KLUDGEed because of bug 188
 850 ;;;
 851 ;;; FIXME: disabled for sb-unicode: probably want it back
 852 #!-sb-unicode
 853 (deftransform concatenate ((rtype &rest sequences)
 854                            (t &rest (or simple-base-string
 855                                         (simple-array nil (*))))
 856                            simple-base-string
 857                            :policy (< safety 3))
 858   (loop for rest-seqs on sequences
 859         for n-seq = (gensym "N-SEQ")
 860         for n-length = (gensym "N-LENGTH")
 861         for start = 0 then next-start
 862         for next-start = (gensym "NEXT-START")
 863         collect n-seq into args
 864         collect `(,n-length (length ,n-seq)) into lets
 865         collect n-length into all-lengths
 866         collect next-start into starts
 867         collect `(if (and (typep ,n-seq '(simple-array nil (*)))
 868                           (> ,n-length 0))
 869                      (error 'nil-array-accessed-error)
 870                      (#.(let* ((i (position 'character sb!kernel::*specialized-array-element-types*))
 871                                (saetp (aref sb!vm:*specialized-array-element-type-properties* i))
 872                                (n-bits (sb!vm:saetp-n-bits saetp)))
 873                           (intern (format nil "UB~D-BASH-COPY" n-bits)
 874                                   "SB!KERNEL"))
 875                         ,n-seq 0 res ,start ,n-length))
 876                 into forms
 877         collect `(setq ,next-start (+ ,start ,n-length)) into forms
 878         finally
 879         (return
 880           `(lambda (rtype ,@args)
 881              (declare (ignore rtype))
 882              (let* (,@lets
 883                     (res (make-string (the index (+ ,@all-lengths))
 884                                       :element-type 'base-char)))
 885                (declare (type index ,@all-lengths))
 886                (let (,@(mapcar (lambda (name) `(,name 0)) starts))
 887                  (declare (type index ,@starts))
 888                  ,@forms)
 889                res)))))
 890 \f
 891 ;;;; CONS accessor DERIVE-TYPE optimizers
 892
 893 (defoptimizer (car derive-type) ((cons))
 894   (let ((type (lvar-type cons))
 895         (null-type (specifier-type 'null)))
 896     (cond ((eq type null-type)
 897            null-type)
 898           ((cons-type-p type)
 899            (cons-type-car-type type)))))
 900
 901 (defoptimizer (cdr derive-type) ((cons))
 902   (let ((type (lvar-type cons))
 903         (null-type (specifier-type 'null)))
 904     (cond ((eq type null-type)
 905            null-type)
 906           ((cons-type-p type)
 907            (cons-type-cdr-type type)))))
 908 \f
 909 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
 910
 911 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
 912 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
 913 ;;; expansion, so we factor out the condition into this function.
 914 (defun check-inlineability-of-find-position-if (sequence from-end)
 915   (let ((ctype (lvar-type sequence)))
 916     (cond ((csubtypep ctype (specifier-type 'vector))
 917            ;; It's not worth trying to inline vector code unless we
 918            ;; know a fair amount about it at compile time.
 919            (upgraded-element-type-specifier-or-give-up sequence)
 920            (unless (constant-lvar-p from-end)
 921              (give-up-ir1-transform
 922               "FROM-END argument value not known at compile time")))
 923           ((csubtypep ctype (specifier-type 'list))
 924            ;; Inlining on lists is generally worthwhile.
 925            )
 926           (t
 927            (give-up-ir1-transform
 928             "sequence type not known at compile time")))))
 929
 930 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
 931 (macrolet ((def (name condition)
 932              `(deftransform ,name ((predicate sequence from-end start end key)
 933                                    (function list t t t function)
 934                                    *
 935                                    :policy (> speed space))
 936                 "expand inline"
 937                 `(let ((index 0)
 938                        (find nil)
 939                        (position nil))
 940                    (declare (type index index))
 941                    (dolist (i sequence
 942                             (if (and end (> end index))
 943                                 (sb!impl::signal-bounding-indices-bad-error
 944                                  sequence start end)
 945                                 (values find position)))
 946                      (let ((key-i (funcall key i)))
 947                        (when (and end (>= index end))
 948                          (return (values find position)))
 949                        (when (>= index start)
 950                          (,',condition (funcall predicate key-i)
 951                           ;; This hack of dealing with non-NIL
 952                           ;; FROM-END for list data by iterating
 953                           ;; forward through the list and keeping
 954                           ;; track of the last time we found a match
 955                           ;; might be more screwy than what the user
 956                           ;; expects, but it seems to be allowed by
 957                           ;; the ANSI standard. (And if the user is
 958                           ;; screwy enough to ask for FROM-END
 959                           ;; behavior on list data, turnabout is
 960                           ;; fair play.)
 961                           ;;
 962                           ;; It's also not enormously efficient,
 963                           ;; calling PREDICATE and KEY more often
 964                           ;; than necessary; but all the
 965                           ;; alternatives seem to have their own
 966                           ;; efficiency problems.
 967                           (if from-end
 968                               (setf find i
 969                                     position index)
 970                               (return (values i index))))))
 971                      (incf index))))))
 972   (def %find-position-if when)
 973   (def %find-position-if-not unless))
 974
 975 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
 976 ;;; without loss of efficiency. (I.e., the optimizer should be able
 977 ;;; to straighten everything out.)
 978 (deftransform %find-position ((item sequence from-end start end key test)
 979                               (t list t t t t t)
 980                               *
 981                               :policy (> speed space))
 982   "expand inline"
 983   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
 984                         ;; The order of arguments for asymmetric tests
 985                         ;; (e.g. #'<, as opposed to order-independent
 986                         ;; tests like #'=) is specified in the spec
 987                         ;; section 17.2.1 -- the O/Zi stuff there.
 988                         (lambda (i)
 989                           (funcall test-fun item i)))
 990                       sequence
 991                       from-end
 992                       start
 993                       end
 994                       (%coerce-callable-to-fun key)))
 995
 996 ;;; The inline expansions for the VECTOR case are saved as macros so
 997 ;;; that we can share them between the DEFTRANSFORMs and the default
 998 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
 999 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1000 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1001                                                             from-end
1002                                                             start
1003                                                             end-arg
1004                                                             element
1005                                                             done-p-expr)
1006   (with-unique-names (offset block index n-sequence sequence n-end end)
1007     `(let ((,n-sequence ,sequence-arg)
1008            (,n-end ,end-arg))
1009        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1010                          (,start ,start)
1011                          (,end (%check-vector-sequence-bounds
1012                                 ,n-sequence ,start ,n-end)))
1013          (block ,block
1014            (macrolet ((maybe-return ()
1015                         ;; WITH-ARRAY-DATA has already performed bounds
1016                         ;; checking, so we can safely elide the checks
1017                         ;; in the inner loop.
1018                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1019                                            (aref ,sequence ,index))))
1020                            (when ,done-p-expr
1021                              (return-from ,block
1022                                (values ,element
1023                                        (- ,index ,offset)))))))
1024              (if ,from-end
1025                  (loop for ,index
1026                        ;; (If we aren't fastidious about declaring that
1027                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1028                        ;; can send us off into never-never land, since
1029                        ;; INDEX is initialized to -1.)
1030                        of-type index-or-minus-1
1031                        from (1- ,end) downto ,start do
1032                        (maybe-return))
1033                  (loop for ,index of-type index from ,start below ,end do
1034                        (maybe-return))))
1035            (values nil nil))))))
1036
1037 (def!macro %find-position-vector-macro (item sequence
1038                                              from-end start end key test)
1039   (with-unique-names (element)
1040     (%find-position-or-find-position-if-vector-expansion
1041      sequence
1042      from-end
1043      start
1044      end
1045      element
1046      ;; (See the LIST transform for a discussion of the correct
1047      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1048      ;; or after the checked sequence element.)
1049      `(funcall ,test ,item (funcall ,key ,element)))))
1050
1051 (def!macro %find-position-if-vector-macro (predicate sequence
1052                                                      from-end start end key)
1053   (with-unique-names (element)
1054     (%find-position-or-find-position-if-vector-expansion
1055      sequence
1056      from-end
1057      start
1058      end
1059      element
1060      `(funcall ,predicate (funcall ,key ,element)))))
1061
1062 (def!macro %find-position-if-not-vector-macro (predicate sequence
1063                                                          from-end start end key)
1064   (with-unique-names (element)
1065     (%find-position-or-find-position-if-vector-expansion
1066      sequence
1067      from-end
1068      start
1069      end
1070      element
1071      `(not (funcall ,predicate (funcall ,key ,element))))))
1072
1073 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1074 ;;; VECTOR data
1075 (deftransform %find-position-if ((predicate sequence from-end start end key)
1076                                  (function vector t t t function)
1077                                  *
1078                                  :policy (> speed space))
1079   "expand inline"
1080   (check-inlineability-of-find-position-if sequence from-end)
1081   '(%find-position-if-vector-macro predicate sequence
1082                                    from-end start end key))
1083
1084 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1085                                      (function vector t t t function)
1086                                      *
1087                                      :policy (> speed space))
1088   "expand inline"
1089   (check-inlineability-of-find-position-if sequence from-end)
1090   '(%find-position-if-not-vector-macro predicate sequence
1091                                        from-end start end key))
1092
1093 (deftransform %find-position ((item sequence from-end start end key test)
1094                               (t vector t t t function function)
1095                               *
1096                               :policy (> speed space))
1097   "expand inline"
1098   (check-inlineability-of-find-position-if sequence from-end)
1099   '(%find-position-vector-macro item sequence
1100                                 from-end start end key test))
1101
1102 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1103 ;;; POSITION-IF, etc.
1104 (define-source-transform effective-find-position-test (test test-not)
1105   (once-only ((test test)
1106               (test-not test-not))
1107     `(cond
1108       ((and ,test ,test-not)
1109        (error "can't specify both :TEST and :TEST-NOT"))
1110       (,test (%coerce-callable-to-fun ,test))
1111       (,test-not
1112        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1113        ;; inefficient, but since the TEST-NOT option is deprecated
1114        ;; anyway, we don't care.)
1115        (complement (%coerce-callable-to-fun ,test-not)))
1116       (t #'eql))))
1117 (define-source-transform effective-find-position-key (key)
1118   (once-only ((key key))
1119     `(if ,key
1120          (%coerce-callable-to-fun ,key)
1121          #'identity)))
1122
1123 (macrolet ((define-find-position (fun-name values-index)
1124              `(deftransform ,fun-name ((item sequence &key
1125                                              from-end (start 0) end
1126                                              key test test-not)
1127                                        (t (or list vector) &rest t))
1128                 '(nth-value ,values-index
1129                             (%find-position item sequence
1130                                             from-end start
1131                                             end
1132                                             (effective-find-position-key key)
1133                                             (effective-find-position-test
1134                                              test test-not))))))
1135   (define-find-position find 0)
1136   (define-find-position position 1))
1137
1138 (macrolet ((define-find-position-if (fun-name values-index)
1139              `(deftransform ,fun-name ((predicate sequence &key
1140                                                   from-end (start 0)
1141                                                   end key)
1142                                        (t (or list vector) &rest t))
1143                 '(nth-value
1144                   ,values-index
1145                   (%find-position-if (%coerce-callable-to-fun predicate)
1146                                      sequence from-end
1147                                      start end
1148                                      (effective-find-position-key key))))))
1149   (define-find-position-if find-if 0)
1150   (define-find-position-if position-if 1))
1151
1152 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1153 ;;; didn't bother to worry about optimizing them, except note that on
1154 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1155 ;;; sbcl-devel
1156 ;;;
1157 ;;;     My understanding is that while the :test-not argument is
1158 ;;;     deprecated in favour of :test (complement #'foo) because of
1159 ;;;     semantic difficulties (what happens if both :test and :test-not
1160 ;;;     are supplied, etc) the -if-not variants, while officially
1161 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1162 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1163 ;;;     reasons for allowing the -if-not versions equal status,
1164 ;;;     particularly remove-if-not (== filter).
1165 ;;;
1166 ;;;     This is only an informal understanding, I grant you, but
1167 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1168 ;;;     way as the others?
1169 ;;;
1170 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1171 ;;; implementation of SBCL.
1172 (macrolet ((define-find-position-if-not (fun-name values-index)
1173                `(deftransform ,fun-name ((predicate sequence &key
1174                                           from-end (start 0)
1175                                           end key)
1176                                          (t (or list vector) &rest t))
1177                  '(nth-value
1178                    ,values-index
1179                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1180                     sequence from-end
1181                     start end
1182                     (effective-find-position-key key))))))
1183   (define-find-position-if-not find-if-not 0)
1184   (define-find-position-if-not position-if-not 1))