src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places))
 137     (let ((found-vector-p nil))
 138       (flet ((process-vector (length)
 139                (unless found-vector-p
 140                  (setq found-vector-p t)
 141                  (bindings `(index 0 (1+ index)))
 142                  (declarations `(type index index)))
 143                (vector-lengths length)))
 144         (loop for seq of-type lvar in seqs
 145            for seq-name in seq-names
 146            for type = (lvar-type seq)
 147            do (cond ((csubtypep type (specifier-type 'list))
 148                      (with-unique-names (index)
 149                        (bindings `(,index ,seq-name (cdr ,index)))
 150                        (declarations `(type list ,index))
 151                        (places `(car ,index))
 152                        (tests `(endp ,index))))
 153                     ((csubtypep type (specifier-type 'vector))
 154                      (process-vector `(length ,seq-name))
 155                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 156                                 (aref ,seq-name index))))
 157                     (t
 158                      (give-up-ir1-transform
 159                       "can't determine sequence argument type"))))
 160         (when into
 161           (process-vector `(array-dimension ,into 0))))
 162       (when found-vector-p
 163         (bindings `(length (min ,@(vector-lengths))))
 164         (tests `(>= index length)))
 165       `(do (,@(bindings))
 166            ((or ,@(tests)) ,result)
 167          (declare ,@(declarations))
 168          (let ((funcall-result (funcall fun ,@(places))))
 169            (declare (ignorable funcall-result))
 170            ,body)))))
 171
 172 ;;; Try to compile %MAP efficiently when we can determine sequence
 173 ;;; argument types at compile time.
 174 ;;;
 175 ;;; Note: This transform was written to allow open coding of
 176 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 177 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 178 ;;; necessarily as efficient as possible. In particular, it will be
 179 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 180 ;;; numeric element types. It should be straightforward to make it
 181 ;;; handle that case more efficiently, but it's left as an exercise to
 182 ;;; the reader, because the code is complicated enough already and I
 183 ;;; don't happen to need that functionality right now. -- WHN 20000410
 184 (deftransform %map ((result-type fun seq &rest seqs) * *
 185                     :policy (>= speed space))
 186   "open code"
 187   (unless (constant-lvar-p result-type)
 188     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 189   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 190            (fn-1subtypep (fn x y)
 191              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 192                (if valid-p
 193                    subtype-p
 194                    (give-up-ir1-transform
 195                     "can't analyze sequence type relationship"))))
 196            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 197     (let* ((result-type-value (lvar-value result-type))
 198            (result-supertype (cond ((null result-type-value) 'null)
 199                                    ((1subtypep result-type-value 'vector)
 200                                     'vector)
 201                                    ((1subtypep result-type-value 'list)
 202                                     'list)
 203                                    (t
 204                                     (give-up-ir1-transform
 205                                      "result type unsuitable")))))
 206       (cond ((and result-type-value (null seqs))
 207              ;; The consing arity-1 cases can be implemented
 208              ;; reasonably efficiently as function calls, and the cost
 209              ;; of consing should be significantly larger than
 210              ;; function call overhead, so we always compile these
 211              ;; cases as full calls regardless of speed-versus-space
 212              ;; optimization policy.
 213              (cond ((subtypep result-type-value 'list)
 214                     '(%map-to-list-arity-1 fun seq))
 215                    ( ;; (This one can be inefficient due to COERCE, but
 216                     ;; the current open-coded implementation has the
 217                     ;; same problem.)
 218                     (subtypep result-type-value 'vector)
 219                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 220                              ',result-type-value))
 221                    (t (bug "impossible (?) sequence type"))))
 222             (t
 223              (let* ((seqs (cons seq seqs))
 224                     (seq-args (make-gensym-list (length seqs))))
 225                (multiple-value-bind (push-dacc result)
 226                    (ecase result-supertype
 227                      (null (values nil nil))
 228                      (list (values `(push funcall-result acc)
 229                                    `(nreverse acc)))
 230                      (vector (values `(push funcall-result acc)
 231                                      `(coerce (nreverse acc)
 232                                               ',result-type-value))))
 233                  ;; (We use the same idiom, of returning a LAMBDA from
 234                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 235                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 236                  ;; reason: we need to get the runtime values of each
 237                  ;; of the &REST vars.)
 238                  `(lambda (result-type fun ,@seq-args)
 239                     (declare (ignore result-type))
 240                     (let ((fun (%coerce-callable-to-fun fun))
 241                           (acc nil))
 242                       (declare (type list acc))
 243                       (declare (ignorable acc))
 244                       ,(build-sequence-iterator
 245                         seqs seq-args
 246                         :result result
 247                         :body push-dacc))))))))))
 248
 249 ;;; MAP-INTO
 250 (deftransform map-into ((result fun &rest seqs)
 251                         (vector * &rest *)
 252                         *)
 253   "open code"
 254   (let ((seqs-names (mapcar (lambda (x)
 255                               (declare (ignore x))
 256                               (gensym))
 257                             seqs)))
 258     `(lambda (result fun ,@seqs-names)
 259        ,(build-sequence-iterator
 260          seqs seqs-names
 261          :result '(when (array-has-fill-pointer-p result)
 262                    (setf (fill-pointer result) index))
 263          :into 'result
 264          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 265                  (setf (aref result index) funcall-result)))
 266        result)))
 267
 268 \f
 269 ;;; FIXME: once the confusion over doing transforms with known-complex
 270 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 271 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 272 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 273   '(aref s i))
 274
 275 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 276   '(nth i s))
 277
 278 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 279   '(%aset s i v))
 280
 281 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 282   '(setf (car (nthcdr i s)) v))
 283
 284 (deftransform %check-vector-sequence-bounds ((vector start end)
 285                                              (vector * *) *
 286                                              :node node)
 287   (if (policy node (= 0 insert-array-bounds-checks))
 288       '(or end (length vector))
 289       '(let ((length (length vector)))
 290          (if (<= 0 start (or end length) length)
 291              (or end length)
 292              (sequence-bounding-indices-bad-error vector start end)))))
 293
 294 (defun specialized-list-seek-function-name (function-name key-functions)
 295   (or (find-symbol (with-output-to-string (s)
 296                      ;; Write "%NAME-FUN1-FUN2-FUN3", etc. Not only is
 297                      ;; this ever so slightly faster then FORMAT, this
 298                      ;; way we are also proof against *PRINT-CASE*
 299                      ;; frobbing and such.
 300                      (write-char #\% s)
 301                      (write-string (symbol-name function-name) s)
 302                      (dolist (f key-functions)
 303                        (write-char #\- s)
 304                        (write-string (symbol-name f) s)))
 305                    (load-time-value (find-package "SB!KERNEL")))
 306       (bug "Unknown list item seek transform: name=~S, key-functions=~S"
 307            function-name key-functions)))
 308
 309 (defun transform-list-item-seek (name list key test test-not node)
 310   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 311   ;; not there at all. If it might be NIL, make up a form to that
 312   ;; ensure it is a function.
 313   (multiple-value-bind (key key-form)
 314       (if key
 315           (let ((key-type (lvar-type key))
 316                 (null-type (specifier-type 'null)))
 317             (cond ((csubtypep key-type null-type)
 318                    (values nil nil))
 319                   ((csubtypep null-type key-type)
 320                    (values key '(if key
 321                                  (%coerce-callable-to-fun key)
 322                                  #'identity)))
 323                   (t
 324                    (values key '(%coerce-callable-to-fun key))))))
 325     (let* ((funs (remove nil (list (and key 'key) (cond (test 'test)
 326                                                         (test-not 'test-not)))))
 327            (target-expr (if key '(%funcall key target) 'target))
 328            (test-expr (cond (test `(%funcall test item ,target-expr))
 329                             (test-not `(not (%funcall test-not item ,target-expr)))
 330                             (t `(eql item ,target-expr)))))
 331       (labels ((open-code (tail)
 332                  (when tail
 333                    `(if (let ((this ',(car tail)))
 334                           ,(ecase name
 335                                   (assoc
 336                                    `(and this (let ((target (car this)))
 337                                                 ,test-expr)))
 338                                   (member
 339                                    `(let ((target this))
 340                                       ,test-expr))))
 341                         ',(ecase name
 342                                  (assoc (car tail))
 343                                  (member tail))
 344                         ,(open-code (cdr tail)))))
 345                (ensure-fun (fun)
 346                  (if (eq 'key fun)
 347                      key-form
 348                      `(%coerce-callable-to-fun ,fun))))
 349         (let* ((cp (constant-lvar-p list))
 350                (c-list (when cp (lvar-value list))))
 351           (cond ((and cp c-list (policy node (>= speed space)))
 352                  `(let ,(mapcar (lambda (fun) `(,fun ,(ensure-fun fun))) funs)
 353                     ,(open-code c-list)))
 354                 ((and cp (not c-list))
 355                  ;; constant nil list -- nothing to find!
 356                  nil)
 357                 (t
 358                  ;; specialized out-of-line version
 359                  `(,(specialized-list-seek-function-name name funs)
 360                     item list ,@(mapcar #'ensure-fun funs)))))))))
 361
 362 (deftransform member ((item list &key key test test-not) * * :node node)
 363   (transform-list-item-seek 'member list key test test-not node))
 364
 365 (deftransform assoc ((item list &key key test test-not) * * :node node)
 366   (transform-list-item-seek 'assoc list key test test-not node))
 367
 368 (deftransform memq ((item list) (t (constant-arg list)))
 369   (labels ((rec (tail)
 370              (if tail
 371                  `(if (eq item ',(car tail))
 372                       ',tail
 373                       ,(rec (cdr tail)))
 374                  nil)))
 375     (rec (lvar-value list))))
 376
 377 ;;; A similar transform used to apply to MEMBER and ASSOC, but since
 378 ;;; TRANSFORM-LIST-ITEM-SEEK now takes care of them those transform
 379 ;;; would never fire, and (%MEMBER-TEST ITEM LIST #'EQ) should be
 380 ;;; almost as fast as MEMQ.
 381 (deftransform delete ((item list &key test) (t list &rest t) *)
 382   "convert to EQ test"
 383   ;; FIXME: The scope of this transformation could be
 384   ;; widened somewhat, letting it work whenever the test is
 385   ;; 'EQL and we know from the type of ITEM that it #'EQ
 386   ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 387   ;; and SYMBOL.)
 388   ;;   If TEST is EQ, apply transform, else
 389   ;;   if test is not EQL, then give up on transform, else
 390   ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 391   ;;   transform, else give up on transform.
 392   (cond (test
 393          (unless (lvar-fun-is test '(eq))
 394            (give-up-ir1-transform)))
 395         ((types-equal-or-intersect (lvar-type item)
 396                                    (specifier-type 'number))
 397          (give-up-ir1-transform "Item might be a number.")))
 398   `(delq item list))
 399
 400 (deftransform delete-if ((pred list) (t list))
 401   "open code"
 402   '(do ((x list (cdr x))
 403         (splice '()))
 404        ((endp x) list)
 405      (cond ((funcall pred (car x))
 406             (if (null splice)
 407                 (setq list (cdr x))
 408                 (rplacd splice (cdr x))))
 409            (t (setq splice x)))))
 410
 411 (deftransform fill ((seq item &key (start 0) (end (length seq)))
 412                     (vector t &key (:start t) (:end index))
 413                     *
 414                     :policy (> speed space))
 415   "open code"
 416   (let ((element-type (upgraded-element-type-specifier-or-give-up seq)))
 417     (values
 418      `(with-array-data ((data seq)
 419                         (start start)
 420                         (end end)
 421                         :check-fill-pointer t)
 422        (declare (type (simple-array ,element-type 1) data))
 423        (declare (type fixnum start end))
 424        (do ((i start (1+ i)))
 425            ((= i end) seq)
 426          (declare (type index i))
 427          ;; WITH-ARRAY-DATA did our range checks once and for all, so
 428          ;; it'd be wasteful to check again on every AREF...
 429          (declare (optimize (safety 0)))
 430          (setf (aref data i) item)))
 431      ;; ... though we still need to check that the new element can fit
 432      ;; into the vector in safe code. -- CSR, 2002-07-05
 433      `((declare (type ,element-type item))))))
 434 \f
 435 ;;;; utilities
 436
 437 ;;; Return true if LVAR's only use is a non-NOTINLINE reference to a
 438 ;;; global function with one of the specified NAMES.
 439 (defun lvar-fun-is (lvar names)
 440   (declare (type lvar lvar) (list names))
 441   (let ((use (lvar-uses lvar)))
 442     (and (ref-p use)
 443          (let ((leaf (ref-leaf use)))
 444            (and (global-var-p leaf)
 445                 (eq (global-var-kind leaf) :global-function)
 446                 (not (null (member (leaf-source-name leaf) names
 447                                    :test #'equal))))))))
 448
 449 ;;; If LVAR is a constant lvar, the return the constant value. If it
 450 ;;; is null, then return default, otherwise quietly give up the IR1
 451 ;;; transform.
 452 ;;;
 453 ;;; ### Probably should take an ARG and flame using the NAME.
 454 (defun constant-value-or-lose (lvar &optional default)
 455   (declare (type (or lvar null) lvar))
 456   (cond ((not lvar) default)
 457         ((constant-lvar-p lvar)
 458          (lvar-value lvar))
 459         (t
 460          (give-up-ir1-transform))))
 461
 462
 463 ;;;; hairy sequence transforms
 464
 465 ;;; FIXME: no hairy sequence transforms in SBCL?
 466 ;;;
 467 ;;; There used to be a bunch of commented out code about here,
 468 ;;; containing the (apparent) beginning of hairy sequence transform
 469 ;;; infrastructure. People interested in implementing better sequence
 470 ;;; transforms might want to look at it for inspiration, even though
 471 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 472 ;;; was deleted in 1.0.7.23.
 473 \f
 474 ;;;; string operations
 475
 476 ;;; We transform the case-sensitive string predicates into a non-keyword
 477 ;;; version. This is an IR1 transform so that we don't have to worry about
 478 ;;; changing the order of evaluation.
 479 (macrolet ((def (fun pred*)
 480              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 481                                                          (start2 0) end2)
 482                                    * *)
 483                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 484   (def string< string<*)
 485   (def string> string>*)
 486   (def string<= string<=*)
 487   (def string>= string>=*)
 488   (def string= string=*)
 489   (def string/= string/=*))
 490
 491 ;;; Return a form that tests the free variables STRING1 and STRING2
 492 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 493 ;;; start and end are also gotten from the environment. Both strings
 494 ;;; must be SIMPLE-BASE-STRINGs.
 495 (macrolet ((def (name lessp equalp)
 496              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 497                                    (simple-base-string simple-base-string t t t t) *)
 498                 `(let* ((end1 (if (not end1) (length string1) end1))
 499                         (end2 (if (not end2) (length string2) end2))
 500                         (index (sb!impl::%sp-string-compare
 501                                 string1 start1 end1 string2 start2 end2)))
 502                   (if index
 503                       (cond ((= index end1)
 504                              ,(if ',lessp 'index nil))
 505                             ((= (+ index (- start2 start1)) end2)
 506                              ,(if ',lessp nil 'index))
 507                             ((,(if ',lessp 'char< 'char>)
 508                                (schar string1 index)
 509                                (schar string2
 510                                       (truly-the index
 511                                                  (+ index
 512                                                     (truly-the fixnum
 513                                                                (- start2
 514                                                                   start1))))))
 515                              index)
 516                             (t nil))
 517                       ,(if ',equalp 'end1 nil))))))
 518   (def string<* t nil)
 519   (def string<=* t t)
 520   (def string>* nil nil)
 521   (def string>=* nil t))
 522
 523 (macrolet ((def (name result-fun)
 524              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 525                                    (simple-base-string simple-base-string t t t t) *)
 526                 `(,',result-fun
 527                   (sb!impl::%sp-string-compare
 528                    string1 start1 (or end1 (length string1))
 529                    string2 start2 (or end2 (length string2)))))))
 530   (def string=* not)
 531   (def string/=* identity))
 532
 533 \f
 534 ;;;; transforms for sequence functions
 535
 536 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 537 ;;; to vectors based on simple arrays.
 538 (def!constant vector-data-bit-offset
 539   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 540
 541 (eval-when (:compile-toplevel)
 542 (defun valid-bit-bash-saetp-p (saetp)
 543   ;; BIT-BASHing isn't allowed on simple vectors that contain pointers
 544   (and (not (eq t (sb!vm:saetp-specifier saetp)))
 545        ;; Disallowing (VECTOR NIL) also means that we won't transform
 546        ;; sequence functions into bit-bashing code and we let the
 547        ;; generic sequence functions signal errors if necessary.
 548        (not (zerop (sb!vm:saetp-n-bits saetp)))
 549        ;; Due to limitations with the current BIT-BASHing code, we can't
 550        ;; BIT-BASH reliably on arrays whose element types are larger
 551        ;; than the word size.
 552        (<= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)))
 553 ) ; EVAL-WHEN
 554
 555 ;;; FIXME: In the copy loops below, we code the loops in a strange
 556 ;;; fashion:
 557 ;;;
 558 ;;; (do ((i (+ src-offset length) (1- i)))
 559 ;;;     ((<= i 0) ...)
 560 ;;;   (... (aref foo (1- i)) ...))
 561 ;;;
 562 ;;; rather than the more natural (and seemingly more efficient):
 563 ;;;
 564 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 565 ;;;     ((< i 0) ...)
 566 ;;;   (... (aref foo i) ...))
 567 ;;;
 568 ;;; (more efficient because we don't have to do the index adjusting on
 569 ;;; every iteration of the loop)
 570 ;;;
 571 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 572 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 573 ;;; when used as an array index, the backend thinks I is a
 574 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 575 ;;; these as distinct storage classes, it cannot coerce a move from a
 576 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 577 ;;; deficiency is that we have two extra moves and increased register
 578 ;;; pressure, which can lead to some spectacularly bad register
 579 ;;; allocation.  (sub-FIXME: the register allocation even with the
 580 ;;; strangely written loops is not always excellent, either...).  Doing
 581 ;;; it the first way, above, means that I is always thought of as a
 582 ;;; POSITIVE-FIXNUM and there are no issues.
 583 ;;;
 584 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 585 ;;; adjustments in the first version into the array addressing at no
 586 ;;; performance penalty!
 587
 588 ;;; This transform is critical to the performance of string streams.  If
 589 ;;; you tweak it, make sure that you compare the disassembly, if not the
 590 ;;; performance of, the functions implementing string streams
 591 ;;; (e.g. SB!IMPL::STRING-OUCH).
 592 (eval-when (:compile-toplevel :load-toplevel :execute)
 593   (defun make-replace-transform (saetp sequence-type1 sequence-type2)
 594     `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 595                             (,sequence-type1 ,sequence-type2 &rest t)
 596                             ,sequence-type1
 597                             :node node)
 598        ,(cond
 599          ((and saetp (valid-bit-bash-saetp-p saetp)) nil)
 600          ;; If the sequence types are different, SEQ1 and SEQ2 must
 601          ;; be distinct arrays, and we can open code the copy loop.
 602          ((not (eql sequence-type1 sequence-type2)) nil)
 603          ;; If we're not bit-bashing, only allow cases where we
 604          ;; can determine the order of copying up front.  (There
 605          ;; are actually more cases we can handle if we know the
 606          ;; amount that we're copying, but this handles the
 607          ;; common cases.)
 608          (t '(unless (= (constant-value-or-lose start1 0)
 609                       (constant-value-or-lose start2 0))
 610               (give-up-ir1-transform))))
 611        `(let* ((len1 (length seq1))
 612                (len2 (length seq2))
 613                (end1 (or end1 len1))
 614                (end2 (or end2 len2))
 615                (replace-len1 (- end1 start1))
 616                (replace-len2 (- end2 start2)))
 617           ,(unless (policy node (= safety 0))
 618              `(progn
 619                  (unless (<= 0 start1 end1 len1)
 620                    (sequence-bounding-indices-bad-error seq1 start1 end1))
 621                  (unless (<= 0 start2 end2 len2)
 622                    (sequence-bounding-indices-bad-error seq2 start2 end2))))
 623           ,',(cond
 624               ((and saetp (valid-bit-bash-saetp-p saetp))
 625                (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 626                       (bash-function (intern (format nil "UB~D-BASH-COPY"
 627                                                      n-element-bits)
 628                                              (find-package "SB!KERNEL"))))
 629                  `(funcall (function ,bash-function) seq2 start2
 630                            seq1 start1 (min replace-len1 replace-len2))))
 631               (t
 632                ;; We can expand the loop inline here because we
 633                ;; would have given up the transform (see above)
 634                ;; if we didn't have constant matching start
 635                ;; indices.
 636                '(do ((i start1 (1+ i))
 637                      (j start2 (1+ j))
 638                      (end (+ start1
 639                              (min replace-len1 replace-len2))))
 640                  ((>= i end))
 641                  (declare (optimize (insert-array-bounds-checks 0)))
 642                  (setf (aref seq1 i) (aref seq2 j)))))
 643           seq1))))
 644
 645 (macrolet
 646     ((define-replace-transforms ()
 647        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 648              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 649              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 650              collect (make-replace-transform saetp sequence-type sequence-type)
 651              into forms
 652              finally (return `(progn ,@forms))))
 653      (define-one-transform (sequence-type1 sequence-type2)
 654        (make-replace-transform nil sequence-type1 sequence-type2)))
 655   (define-replace-transforms)
 656   (define-one-transform simple-base-string (simple-array character (*)))
 657   (define-one-transform (simple-array character (*)) simple-base-string))
 658
 659 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 660 ;;; defined as those cases where we are doing word-aligned copies from
 661 ;;; both the source and the destination and we are copying from the same
 662 ;;; offset from both the source and the destination.  (The last
 663 ;;; condition is there so we can determine the direction to copy at
 664 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 665 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 666 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 667 ;;; N)-size buffer and blitting in the old N-size buffer in.
 668
 669 (defun frob-bash-transform (src src-offset
 670                             dst dst-offset
 671                             length n-elems-per-word)
 672   (declare (ignore src dst length))
 673   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 674     (multiple-value-bind (src-word src-elt)
 675         (truncate (lvar-value src-offset) n-elems-per-word)
 676       (multiple-value-bind (dst-word dst-elt)
 677           (truncate (lvar-value dst-offset) n-elems-per-word)
 678         ;; Avoid non-word aligned copies.
 679         (unless (and (zerop src-elt) (zerop dst-elt))
 680           (give-up-ir1-transform))
 681         ;; Avoid copies where we would have to insert code for
 682         ;; determining the direction of copying.
 683         (unless (= src-word dst-word)
 684           (give-up-ir1-transform))
 685         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 686         ;; so we have to do its work here.
 687         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 688                                       'length
 689                                       `(truncate (the index length) ,n-elems-per-word)))))
 690            (declare (type index end))
 691            ;; Handle any bits at the end.
 692            (when (logtest length (1- ,n-elems-per-word))
 693              (let* ((extra (mod length ,n-elems-per-word))
 694                     ;; FIXME: The shift amount on this ASH is
 695                     ;; *always* negative, but the backend doesn't
 696                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 697                     ;; wind up with a pile of code that tests the
 698                     ;; sign of the shift count prior to shifting when
 699                     ;; all we need is a simple negate and shift
 700                     ;; right.  Yuck.
 701                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 702                                (* (- extra ,n-elems-per-word)
 703                                   ,n-bits-per-elem))))
 704                (setf (sb!kernel:%vector-raw-bits dst end)
 705                      (logior
 706                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 707                                 (ash mask
 708                                      ,(ecase sb!c:*backend-byte-order*
 709                                              (:little-endian 0)
 710                                              (:big-endian `(* (- ,n-elems-per-word extra)
 711                                                               ,n-bits-per-elem)))))
 712                       (logand (sb!kernel:%vector-raw-bits src end)
 713                               (ash mask
 714                                    ,(ecase sb!c:*backend-byte-order*
 715                                            (:little-endian 0)
 716                                            (:big-endian `(* (- ,n-elems-per-word extra)
 717                                                             ,n-bits-per-elem)))))))))
 718            ;; Copy from the end to save a register.
 719            (do ((i end (1- i)))
 720                ((<= i ,src-word))
 721              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 722                    (sb!kernel:%vector-raw-bits src (1- i)))))))))
 723
 724 #.(loop for i = 1 then (* i 2)
 725         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 726                                         "SB!KERNEL")
 727                                                         ((src src-offset
 728                                                           dst dst-offset
 729                                                           length)
 730                                                         ((simple-unboxed-array (*))
 731                                                          (constant-arg index)
 732                                                          (simple-unboxed-array (*))
 733                                                          (constant-arg index)
 734                                                          index)
 735                                                         *)
 736                   (frob-bash-transform src src-offset
 737                                        dst dst-offset length
 738                                        ,(truncate sb!vm:n-word-bits i))) into forms
 739         until (= i sb!vm:n-word-bits)
 740         finally (return `(progn ,@forms)))
 741
 742 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 743 ;;; arrays with elements of size >= the word size.  We do this because
 744 ;;; we know the arrays cannot alias (one was just consed), therefore we
 745 ;;; can determine at compile time the direction to copy, and for
 746 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 747 ;;; needless checking to figure out what's going on.  The same
 748 ;;; considerations apply if we are copying elements larger than the word
 749 ;;; size, with the additional twist that doing it inline is likely to
 750 ;;; cons far less than calling REPLACE and letting generic code do the
 751 ;;; work.
 752 ;;;
 753 ;;; However, we do not do this for elements whose size is < than the
 754 ;;; word size because we don't want to deal with any alignment issues
 755 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 756 ;;; anyway.
 757
 758 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 759                                       element-type)
 760   (let ((saetp (find-saetp element-type)))
 761     (aver saetp)
 762     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 763         (expand-aref-copy-loop src src-offset dst dst-offset length)
 764         `(locally (declare (optimize (safety 0)))
 765            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 766
 767 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 768   (if (eql src-offset dst-offset)
 769       `(do ((i (+ ,src-offset ,length) (1- i)))
 770            ((<= i ,src-offset))
 771          (declare (optimize (insert-array-bounds-checks 0)))
 772          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 773       ;; KLUDGE: The compiler is not able to derive that (+ offset
 774       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 775       ;; We, however, know it must be so, as by this point the bounds
 776       ;; have already been checked.
 777       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 778             (j (+ ,dst-offset ,length) (1- j)))
 779            ((<= i ,src-offset))
 780          (declare (optimize (insert-array-bounds-checks 0))
 781                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 782          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 783
 784 ;;; SUBSEQ, COPY-SEQ
 785
 786 (deftransform subseq ((seq start &optional end)
 787                       (vector t &optional t)
 788                       *
 789                       :node node)
 790   (let ((type (lvar-type seq)))
 791     (cond
 792       ((and (array-type-p type)
 793             (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 794        (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 795          `(let* ((length (length seq))
 796                  (end (or end length)))
 797             ,(unless (policy node (zerop insert-array-bounds-checks))
 798                      '(progn
 799                        (unless (<= 0 start end length)
 800                          (sequence-bounding-indices-bad-error seq start end))))
 801             (let* ((size (- end start))
 802                    (result (make-array size :element-type ',element-type)))
 803               ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
 804                                                        (lvar-value start)
 805                                                        'start)
 806                                               'result 0 'size element-type)
 807               result))))
 808       ((csubtypep type (specifier-type 'string))
 809        '(string-subseq* seq start end))
 810       (t
 811        '(vector-subseq* seq start end)))))
 812
 813 (deftransform subseq ((seq start &optional end)
 814                       (list t &optional t))
 815   `(list-subseq* seq start end))
 816
 817 (deftransform subseq ((seq start &optional end)
 818                       ((and sequence (not vector) (not list)) t &optional t))
 819   '(sb!sequence:subseq seq start end))
 820
 821 (deftransform copy-seq ((seq) (vector))
 822   (let ((type (lvar-type seq)))
 823     (cond ((and (array-type-p type)
 824                 (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 825            (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 826              `(let* ((length (length seq))
 827                      (result (make-array length :element-type ',element-type)))
 828                 ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
 829                 result)))
 830           ((csubtypep type (specifier-type 'string))
 831            '(string-subseq* seq 0 nil))
 832           (t
 833            '(vector-subseq* seq 0 nil)))))
 834
 835 (deftransform copy-seq ((seq) (list))
 836   '(list-copy-seq* seq))
 837
 838 (deftransform copy-seq ((seq) ((and sequence (not vector) (not list))))
 839   '(sb!sequence:copy-seq seq))
 840
 841 ;;; FIXME: it really should be possible to take advantage of the
 842 ;;; macros used in code/seq.lisp here to avoid duplication of code,
 843 ;;; and enable even funkier transformations.
 844 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
 845                                (test #'eql)
 846                                (key #'identity)
 847                                from-end)
 848                       (vector vector &rest t)
 849                       *
 850                       :node node
 851                       :policy (> speed (max space safety)))
 852   "open code"
 853   (let ((from-end (when (lvar-p from-end)
 854                     (unless (constant-lvar-p from-end)
 855                       (give-up-ir1-transform ":FROM-END is not constant."))
 856                     (lvar-value from-end)))
 857         (keyp (lvar-p key))
 858         (testp (lvar-p test))
 859         (check-bounds-p (policy node (plusp insert-array-bounds-checks))))
 860     `(block search
 861        (flet ((oops (vector start end)
 862                 (sequence-bounding-indices-bad-error vector start end)))
 863          (let* ((len1 (length pattern))
 864                 (len2 (length text))
 865                 (end1 (or end1 len1))
 866                 (end2 (or end2 len2))
 867                ,@(when keyp
 868                        '((key (coerce key 'function))))
 869                ,@(when testp
 870                        '((test (coerce test 'function)))))
 871           (declare (type index start1 start2 end1 end2))
 872           ,@(when check-bounds-p
 873              `((unless (<= start1 end1 len1)
 874                  (oops pattern start1 end1))
 875                (unless (<= start2 end2 len2)
 876                  (oops pattern start2 end2))))
 877           (do (,(if from-end
 878                     '(index2 (- end2 (- end1 start1)) (1- index2))
 879                     '(index2 start2 (1+ index2))))
 880               (,(if from-end
 881                     '(< index2 start2)
 882                     '(>= index2 end2))
 883                nil)
 884             ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
 885             ;; terminates is hits -1 when :FROM-END is true and :START2
 886             ;; is 0.
 887             (declare (type fixnum index2))
 888             (when (do ((index1 start1 (1+ index1))
 889                        (index2 index2 (1+ index2)))
 890                       ((>= index1 end1) t)
 891                     (declare (type index index1 index2)
 892                              (optimize (insert-array-bounds-checks 0)))
 893                     ,@(unless from-end
 894                               '((when (= index2 end2)
 895                                   (return-from search nil))))
 896                     (unless (,@(if testp
 897                                    '(funcall test)
 898                                    '(eql))
 899                                ,(if keyp
 900                                     '(funcall key (aref pattern index1))
 901                                     '(aref pattern index1))
 902                                ,(if keyp
 903                                     '(funcall key (aref text index2))
 904                                     '(aref text index2)))
 905                       (return nil)))
 906               (return index2))))))))
 907
 908
 909 ;;; Open-code CONCATENATE for strings. It would be possible to extend
 910 ;;; this transform to non-strings, but I chose to just do the case that
 911 ;;; should cover 95% of CONCATENATE performance complaints for now.
 912 ;;;   -- JES, 2007-11-17
 913 (deftransform concatenate ((result-type &rest lvars)
 914                            (symbol &rest sequence)
 915                            *
 916                            :policy (> speed space))
 917   (unless (constant-lvar-p result-type)
 918     (give-up-ir1-transform))
 919   (let* ((element-type (let ((type (lvar-value result-type)))
 920                          ;; Only handle the simple result type cases. If
 921                          ;; somebody does (CONCATENATE '(STRING 6) ...)
 922                          ;; their code won't be optimized, but nobody does
 923                          ;; that in practice.
 924                          (case type
 925                            ((string simple-string) 'character)
 926                            ((base-string simple-base-string) 'base-char)
 927                            (t (give-up-ir1-transform)))))
 928          (vars (loop for x in lvars collect (gensym)))
 929          (lvar-values (loop for lvar in lvars
 930                             collect (when (constant-lvar-p lvar)
 931                                       (lvar-value lvar))))
 932          (lengths
 933           (loop for value in lvar-values
 934                 for var in vars
 935                 collect (if value
 936                             (length value)
 937                             `(sb!impl::string-dispatch ((simple-array * (*))
 938                                                         sequence)
 939                                  ,var
 940                                (declare (muffle-conditions compiler-note))
 941                                (length ,var))))))
 942     `(apply
 943       (lambda ,vars
 944         (declare (ignorable ,@vars))
 945         (let* ((.length. (+ ,@lengths))
 946                (.pos. 0)
 947                (.string. (make-string .length. :element-type ',element-type)))
 948           (declare (type index .length. .pos.)
 949                    (muffle-conditions compiler-note))
 950           ,@(loop for value in lvar-values
 951                   for var in vars
 952                   collect (if (stringp value)
 953                               ;; Fold the array reads for constant arguments
 954                               `(progn
 955                                  ,@(loop for c across value
 956                                          collect `(setf (aref .string.
 957                                                               .pos.) ,c)
 958                                          collect `(incf .pos.)))
 959                               `(sb!impl::string-dispatch
 960                                    (#!+sb-unicode
 961                                     (simple-array character (*))
 962                                     (simple-array base-char (*))
 963                                     t)
 964                                    ,var
 965                                  (replace .string. ,var :start1 .pos.)
 966                                  (incf .pos. (length ,var)))))
 967           .string.))
 968       lvars)))
 969 \f
 970 ;;;; CONS accessor DERIVE-TYPE optimizers
 971
 972 (defoptimizer (car derive-type) ((cons))
 973   (let ((type (lvar-type cons))
 974         (null-type (specifier-type 'null)))
 975     (cond ((eq type null-type)
 976            null-type)
 977           ((cons-type-p type)
 978            (cons-type-car-type type)))))
 979
 980 (defoptimizer (cdr derive-type) ((cons))
 981   (let ((type (lvar-type cons))
 982         (null-type (specifier-type 'null)))
 983     (cond ((eq type null-type)
 984            null-type)
 985           ((cons-type-p type)
 986            (cons-type-cdr-type type)))))
 987 \f
 988 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
 989
 990 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
 991 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
 992 ;;; expansion, so we factor out the condition into this function.
 993 (defun check-inlineability-of-find-position-if (sequence from-end)
 994   (let ((ctype (lvar-type sequence)))
 995     (cond ((csubtypep ctype (specifier-type 'vector))
 996            ;; It's not worth trying to inline vector code unless we
 997            ;; know a fair amount about it at compile time.
 998            (upgraded-element-type-specifier-or-give-up sequence)
 999            (unless (constant-lvar-p from-end)
1000              (give-up-ir1-transform
1001               "FROM-END argument value not known at compile time")))
1002           ((csubtypep ctype (specifier-type 'list))
1003            ;; Inlining on lists is generally worthwhile.
1004            )
1005           (t
1006            (give-up-ir1-transform
1007             "sequence type not known at compile time")))))
1008
1009 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
1010 (macrolet ((def (name condition)
1011              `(deftransform ,name ((predicate sequence from-end start end key)
1012                                    (function list t t t function)
1013                                    *
1014                                    :policy (> speed space))
1015                 "expand inline"
1016                 `(let ((index 0)
1017                        (find nil)
1018                        (position nil))
1019                    (declare (type index index))
1020                    (dolist (i sequence
1021                             (if (and end (> end index))
1022                                 (sequence-bounding-indices-bad-error
1023                                  sequence start end)
1024                                 (values find position)))
1025                      (let ((key-i (funcall key i)))
1026                        (when (and end (>= index end))
1027                          (return (values find position)))
1028                        (when (>= index start)
1029                          (,',condition (funcall predicate key-i)
1030                           ;; This hack of dealing with non-NIL
1031                           ;; FROM-END for list data by iterating
1032                           ;; forward through the list and keeping
1033                           ;; track of the last time we found a match
1034                           ;; might be more screwy than what the user
1035                           ;; expects, but it seems to be allowed by
1036                           ;; the ANSI standard. (And if the user is
1037                           ;; screwy enough to ask for FROM-END
1038                           ;; behavior on list data, turnabout is
1039                           ;; fair play.)
1040                           ;;
1041                           ;; It's also not enormously efficient,
1042                           ;; calling PREDICATE and KEY more often
1043                           ;; than necessary; but all the
1044                           ;; alternatives seem to have their own
1045                           ;; efficiency problems.
1046                           (if from-end
1047                               (setf find i
1048                                     position index)
1049                               (return (values i index))))))
1050                      (incf index))))))
1051   (def %find-position-if when)
1052   (def %find-position-if-not unless))
1053
1054 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
1055 ;;; without loss of efficiency. (I.e., the optimizer should be able
1056 ;;; to straighten everything out.)
1057 (deftransform %find-position ((item sequence from-end start end key test)
1058                               (t list t t t t t)
1059                               *
1060                               :policy (> speed space))
1061   "expand inline"
1062   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
1063                         ;; The order of arguments for asymmetric tests
1064                         ;; (e.g. #'<, as opposed to order-independent
1065                         ;; tests like #'=) is specified in the spec
1066                         ;; section 17.2.1 -- the O/Zi stuff there.
1067                         (lambda (i)
1068                           (funcall test-fun item i)))
1069                       sequence
1070                       from-end
1071                       start
1072                       end
1073                       (%coerce-callable-to-fun key)))
1074
1075 ;;; The inline expansions for the VECTOR case are saved as macros so
1076 ;;; that we can share them between the DEFTRANSFORMs and the default
1077 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
1078 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1079 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1080                                                             from-end
1081                                                             start
1082                                                             end-arg
1083                                                             element
1084                                                             done-p-expr)
1085   (with-unique-names (offset block index n-sequence sequence end)
1086     `(let* ((,n-sequence ,sequence-arg))
1087        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1088                          (,start ,start)
1089                          (,end ,end-arg)
1090                          :check-fill-pointer t)
1091          (block ,block
1092            (macrolet ((maybe-return ()
1093                         ;; WITH-ARRAY-DATA has already performed bounds
1094                         ;; checking, so we can safely elide the checks
1095                         ;; in the inner loop.
1096                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1097                                            (aref ,sequence ,index))))
1098                           (when ,done-p-expr
1099                             (return-from ,block
1100                               (values ,element
1101                                       (- ,index ,offset)))))))
1102              (if ,from-end
1103                  (loop for ,index
1104                        ;; (If we aren't fastidious about declaring that
1105                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1106                        ;; can send us off into never-never land, since
1107                        ;; INDEX is initialized to -1.)
1108                        of-type index-or-minus-1
1109                        from (1- ,end) downto ,start do
1110                        (maybe-return))
1111                  (loop for ,index of-type index from ,start below ,end do
1112                           (maybe-return))))
1113            (values nil nil))))))
1114
1115 (def!macro %find-position-vector-macro (item sequence
1116                                              from-end start end key test)
1117   (with-unique-names (element)
1118     (%find-position-or-find-position-if-vector-expansion
1119      sequence
1120      from-end
1121      start
1122      end
1123      element
1124      ;; (See the LIST transform for a discussion of the correct
1125      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1126      ;; or after the checked sequence element.)
1127      `(funcall ,test ,item (funcall ,key ,element)))))
1128
1129 (def!macro %find-position-if-vector-macro (predicate sequence
1130                                                      from-end start end key)
1131   (with-unique-names (element)
1132     (%find-position-or-find-position-if-vector-expansion
1133      sequence
1134      from-end
1135      start
1136      end
1137      element
1138      `(funcall ,predicate (funcall ,key ,element)))))
1139
1140 (def!macro %find-position-if-not-vector-macro (predicate sequence
1141                                                          from-end start end key)
1142   (with-unique-names (element)
1143     (%find-position-or-find-position-if-vector-expansion
1144      sequence
1145      from-end
1146      start
1147      end
1148      element
1149      `(not (funcall ,predicate (funcall ,key ,element))))))
1150
1151 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1152 ;;; VECTOR data
1153 (deftransform %find-position-if ((predicate sequence from-end start end key)
1154                                  (function vector t t t function)
1155                                  *
1156                                  :policy (> speed space))
1157   "expand inline"
1158   (check-inlineability-of-find-position-if sequence from-end)
1159   '(%find-position-if-vector-macro predicate sequence
1160                                    from-end start end key))
1161
1162 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1163                                      (function vector t t t function)
1164                                      *
1165                                      :policy (> speed space))
1166   "expand inline"
1167   (check-inlineability-of-find-position-if sequence from-end)
1168   '(%find-position-if-not-vector-macro predicate sequence
1169                                        from-end start end key))
1170
1171 (deftransform %find-position ((item sequence from-end start end key test)
1172                               (t vector t t t function function)
1173                               *
1174                               :policy (> speed space))
1175   "expand inline"
1176   (check-inlineability-of-find-position-if sequence from-end)
1177   '(%find-position-vector-macro item sequence
1178     from-end start end key test))
1179
1180 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1181 ;;; POSITION-IF, etc.
1182 (define-source-transform effective-find-position-test (test test-not)
1183   (once-only ((test test)
1184               (test-not test-not))
1185     `(cond
1186       ((and ,test ,test-not)
1187        (error "can't specify both :TEST and :TEST-NOT"))
1188       (,test (%coerce-callable-to-fun ,test))
1189       (,test-not
1190        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1191        ;; inefficient, but since the TEST-NOT option is deprecated
1192        ;; anyway, we don't care.)
1193        (complement (%coerce-callable-to-fun ,test-not)))
1194       (t #'eql))))
1195 (define-source-transform effective-find-position-key (key)
1196   (once-only ((key key))
1197     `(if ,key
1198          (%coerce-callable-to-fun ,key)
1199          #'identity)))
1200
1201 (macrolet ((define-find-position (fun-name values-index)
1202              `(deftransform ,fun-name ((item sequence &key
1203                                              from-end (start 0) end
1204                                              key test test-not)
1205                                        (t (or list vector) &rest t))
1206                 '(nth-value ,values-index
1207                             (%find-position item sequence
1208                                             from-end start
1209                                             end
1210                                             (effective-find-position-key key)
1211                                             (effective-find-position-test
1212                                              test test-not))))))
1213   (define-find-position find 0)
1214   (define-find-position position 1))
1215
1216 (macrolet ((define-find-position-if (fun-name values-index)
1217              `(deftransform ,fun-name ((predicate sequence &key
1218                                                   from-end (start 0)
1219                                                   end key)
1220                                        (t (or list vector) &rest t))
1221                 '(nth-value
1222                   ,values-index
1223                   (%find-position-if (%coerce-callable-to-fun predicate)
1224                                      sequence from-end
1225                                      start end
1226                                      (effective-find-position-key key))))))
1227   (define-find-position-if find-if 0)
1228   (define-find-position-if position-if 1))
1229
1230 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1231 ;;; didn't bother to worry about optimizing them, except note that on
1232 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1233 ;;; sbcl-devel
1234 ;;;
1235 ;;;     My understanding is that while the :test-not argument is
1236 ;;;     deprecated in favour of :test (complement #'foo) because of
1237 ;;;     semantic difficulties (what happens if both :test and :test-not
1238 ;;;     are supplied, etc) the -if-not variants, while officially
1239 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1240 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1241 ;;;     reasons for allowing the -if-not versions equal status,
1242 ;;;     particularly remove-if-not (== filter).
1243 ;;;
1244 ;;;     This is only an informal understanding, I grant you, but
1245 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1246 ;;;     way as the others?
1247 ;;;
1248 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1249 ;;; implementation of SBCL.
1250 (macrolet ((define-find-position-if-not (fun-name values-index)
1251                `(deftransform ,fun-name ((predicate sequence &key
1252                                           from-end (start 0)
1253                                           end key)
1254                                          (t (or list vector) &rest t))
1255                  '(nth-value
1256                    ,values-index
1257                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1258                     sequence from-end
1259                     start end
1260                     (effective-find-position-key key))))))
1261   (define-find-position-if-not find-if-not 0)
1262   (define-find-position-if-not position-if-not 1))