src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32         (ecase accumulate
  33           (:nconc
  34            (let ((temp (gensym))
  35                  (map-result (gensym)))
  36              `(let ((,fn-sym ,fn)
  37                     (,map-result (list nil)))
  38                 (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  39                               (,endtest (cdr ,map-result))
  40                   (setq ,temp (last (nconc ,temp ,call)))))))
  41           (:list
  42            (let ((temp (gensym))
  43                  (map-result (gensym)))
  44              `(let ((,fn-sym ,fn)
  45                     (,map-result (list nil)))
  46                 (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                               (,endtest (truly-the list (cdr ,map-result)))
  48                   (rplacd ,temp (setq ,temp (list ,call)))))))
  49           ((nil)
  50            `(let ((,fn-sym ,fn)
  51                   (,n-first ,(first arglists)))
  52               (do-anonymous ,(do-clauses)
  53                             (,endtest (truly-the list ,n-first))
  54                             ,call))))))))
  55
  56 (define-source-transform mapc (function list &rest more-lists)
  57   (mapfoo-transform function (cons list more-lists) nil t))
  58
  59 (define-source-transform mapcar (function list &rest more-lists)
  60   (mapfoo-transform function (cons list more-lists) :list t))
  61
  62 (define-source-transform mapcan (function list &rest more-lists)
  63   (mapfoo-transform function (cons list more-lists) :nconc t))
  64
  65 (define-source-transform mapl (function list &rest more-lists)
  66   (mapfoo-transform function (cons list more-lists) nil nil))
  67
  68 (define-source-transform maplist (function list &rest more-lists)
  69   (mapfoo-transform function (cons list more-lists) :list nil))
  70
  71 (define-source-transform mapcon (function list &rest more-lists)
  72   (mapfoo-transform function (cons list more-lists) :nconc nil))
  73 \f
  74 ;;;; mapping onto sequences: the MAP function
  75
  76 ;;; MAP is %MAP plus a check to make sure that any length specified in
  77 ;;; the result type matches the actual result. We also wrap it in a
  78 ;;; TRULY-THE for the most specific type we can determine.
  79 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  80   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  81          (bare `(%map result-type-arg fun ,@seq-names))
  82          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  83          ;; what we know about the type of the result. (Note that the
  84          ;; "result type" argument is not necessarily the type of the
  85          ;; result, since NIL means the result has NULL type.)
  86          (result-type (if (not constant-result-type-arg-p)
  87                           'consed-sequence
  88                           (let ((result-type-arg-value
  89                                  (lvar-value result-type-arg)))
  90                             (if (null result-type-arg-value)
  91                                 'null
  92                                 result-type-arg-value)))))
  93     `(lambda (result-type-arg fun ,@seq-names)
  94        (truly-the ,result-type
  95          ,(cond ((policy node (< safety 3))
  96                  ;; ANSI requires the length-related type check only
  97                  ;; when the SAFETY quality is 3... in other cases, we
  98                  ;; skip it, because it could be expensive.
  99                  bare)
 100                 ((not constant-result-type-arg-p)
 101                  `(sequence-of-checked-length-given-type ,bare
 102                                                          result-type-arg))
 103                 (t
 104                  (let ((result-ctype (ir1-transform-specifier-type
 105                                       result-type)))
 106                    (if (array-type-p result-ctype)
 107                        (let ((dims (array-type-dimensions result-ctype)))
 108                          (unless (and (listp dims) (= (length dims) 1))
 109                            (give-up-ir1-transform "invalid sequence type"))
 110                          (let ((dim (first dims)))
 111                            (if (eq dim '*)
 112                                bare
 113                                `(vector-of-checked-length-given-length ,bare
 114                                                                        ,dim))))
 115                        ;; FIXME: this is wrong, as not all subtypes of
 116                        ;; VECTOR are ARRAY-TYPEs [consider, for
 117                        ;; example, (OR (VECTOR T 3) (VECTOR T
 118                        ;; 4))]. However, it's difficult to see what we
 119                        ;; should put here... maybe we should
 120                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 121                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 122                        bare))))))))
 123
 124 ;;; Return a DO loop, mapping a function FUN to elements of
 125 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 126 ;;; bound to sequences, INTO - a variable, which is used in
 127 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 128 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 129 ;;; INDEX, containing the current position in sequences.
 130 (defun build-sequence-iterator (seqs seq-names &key result into body)
 131   (declare (type list seqs seq-names)
 132            (type symbol into))
 133   (collect ((bindings)
 134             (declarations)
 135             (vector-lengths)
 136             (tests)
 137             (places))
 138     (let ((found-vector-p nil))
 139       (flet ((process-vector (length)
 140                (unless found-vector-p
 141                  (setq found-vector-p t)
 142                  (bindings `(index 0 (1+ index)))
 143                  (declarations `(type index index)))
 144                (vector-lengths length)))
 145         (loop for seq of-type lvar in seqs
 146            for seq-name in seq-names
 147            for type = (lvar-type seq)
 148            do (cond ((csubtypep type (specifier-type 'list))
 149                      (with-unique-names (index)
 150                        (bindings `(,index ,seq-name (cdr ,index)))
 151                        (declarations `(type list ,index))
 152                        (places `(car ,index))
 153                        (tests `(endp ,index))))
 154                     ((csubtypep type (specifier-type 'vector))
 155                      (process-vector `(length ,seq-name))
 156                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 157                                 (aref ,seq-name index))))
 158                     (t
 159                      (give-up-ir1-transform
 160                       "can't determine sequence argument type"))))
 161         (when into
 162           (process-vector `(array-dimension ,into 0))))
 163       (when found-vector-p
 164         (bindings `(length (min ,@(vector-lengths))))
 165         (tests `(>= index length)))
 166       `(do (,@(bindings))
 167            ((or ,@(tests)) ,result)
 168          (declare ,@(declarations))
 169          (let ((funcall-result (funcall fun ,@(places))))
 170            (declare (ignorable funcall-result))
 171            ,body)))))
 172
 173 ;;; Try to compile %MAP efficiently when we can determine sequence
 174 ;;; argument types at compile time.
 175 ;;;
 176 ;;; Note: This transform was written to allow open coding of
 177 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 178 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 179 ;;; necessarily as efficient as possible. In particular, it will be
 180 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 181 ;;; numeric element types. It should be straightforward to make it
 182 ;;; handle that case more efficiently, but it's left as an exercise to
 183 ;;; the reader, because the code is complicated enough already and I
 184 ;;; don't happen to need that functionality right now. -- WHN 20000410
 185 (deftransform %map ((result-type fun seq &rest seqs) * *
 186                     :policy (>= speed space))
 187   "open code"
 188   (unless (constant-lvar-p result-type)
 189     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 190   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 191            (fn-1subtypep (fn x y)
 192              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 193                (if valid-p
 194                    subtype-p
 195                    (give-up-ir1-transform
 196                     "can't analyze sequence type relationship"))))
 197            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 198     (let* ((result-type-value (lvar-value result-type))
 199            (result-supertype (cond ((null result-type-value) 'null)
 200                                    ((1subtypep result-type-value 'vector)
 201                                     'vector)
 202                                    ((1subtypep result-type-value 'list)
 203                                     'list)
 204                                    (t
 205                                     (give-up-ir1-transform
 206                                      "result type unsuitable")))))
 207       (cond ((and result-type-value (null seqs))
 208              ;; The consing arity-1 cases can be implemented
 209              ;; reasonably efficiently as function calls, and the cost
 210              ;; of consing should be significantly larger than
 211              ;; function call overhead, so we always compile these
 212              ;; cases as full calls regardless of speed-versus-space
 213              ;; optimization policy.
 214              (cond ((subtypep result-type-value 'list)
 215                     '(%map-to-list-arity-1 fun seq))
 216                    ( ;; (This one can be inefficient due to COERCE, but
 217                     ;; the current open-coded implementation has the
 218                     ;; same problem.)
 219                     (subtypep result-type-value 'vector)
 220                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 221                              ',result-type-value))
 222                    (t (bug "impossible (?) sequence type"))))
 223             (t
 224              (let* ((seqs (cons seq seqs))
 225                     (seq-args (make-gensym-list (length seqs))))
 226                (multiple-value-bind (push-dacc result)
 227                    (ecase result-supertype
 228                      (null (values nil nil))
 229                      (list (values `(push funcall-result acc)
 230                                    `(nreverse acc)))
 231                      (vector (values `(push funcall-result acc)
 232                                      `(coerce (nreverse acc)
 233                                               ',result-type-value))))
 234                  ;; (We use the same idiom, of returning a LAMBDA from
 235                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 236                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 237                  ;; reason: we need to get the runtime values of each
 238                  ;; of the &REST vars.)
 239                  `(lambda (result-type fun ,@seq-args)
 240                     (declare (ignore result-type))
 241                     (let ((fun (%coerce-callable-to-fun fun))
 242                           (acc nil))
 243                       (declare (type list acc))
 244                       (declare (ignorable acc))
 245                       ,(build-sequence-iterator
 246                         seqs seq-args
 247                         :result result
 248                         :body push-dacc))))))))))
 249
 250 ;;; MAP-INTO
 251 (deftransform map-into ((result fun &rest seqs)
 252                         (vector * &rest *)
 253                         *)
 254   "open code"
 255   (let ((seqs-names (mapcar (lambda (x)
 256                               (declare (ignore x))
 257                               (gensym))
 258                             seqs)))
 259     `(lambda (result fun ,@seqs-names)
 260        ,(build-sequence-iterator
 261          seqs seqs-names
 262          :result '(when (array-has-fill-pointer-p result)
 263                    (setf (fill-pointer result) index))
 264          :into 'result
 265          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 266                  (setf (aref result index) funcall-result)))
 267        result)))
 268
 269 \f
 270 ;;; FIXME: once the confusion over doing transforms with known-complex
 271 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 272 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 273 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 274   '(aref s i))
 275
 276 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 277   '(nth i s))
 278
 279 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 280   '(%aset s i v))
 281
 282 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 283   '(setf (car (nthcdr i s)) v))
 284
 285 (deftransform %check-vector-sequence-bounds ((vector start end)
 286                                              (vector * *) *
 287                                              :node node)
 288   (if (policy node (< safety speed))
 289       '(or end (length vector))
 290       '(let ((length (length vector)))
 291         (if (<= 0 start (or end length) length)
 292             (or end length)
 293             (sb!impl::signal-bounding-indices-bad-error vector start end)))))
 294
 295
 296 (deftransform member ((item list &key key test test-not) * * :node node)
 297   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 298   ;; not there at all. If it might be NIL, make up a form to that
 299   ;; ensure it is a function.
 300   (multiple-value-bind (key key-form)
 301       (if key
 302           (let ((key-type (lvar-type key))
 303                 (null-type (specifier-type 'null)))
 304             (cond ((csubtypep key-type null-type)
 305                    (values nil nil))
 306                   ((csubtypep null-type key-type)
 307                    (values key '(if key
 308                                  (%coerce-callable-to-fun key)
 309                                  #'identity)))
 310                   (t
 311                    (values key '(%coerce-callable-to-fun key))))))
 312     (multiple-value-bind (out-of-line funs test-expr)
 313         (cond ((and (not key) (not test) (not test-not))
 314                (values '%member
 315                        '()
 316                        '(eql item car)))
 317               ((and key (not test) (not test-not))
 318                (values '%member-key
 319                        '(key)
 320                        '(eql item (%funcall key car))))
 321               ((and key test)
 322                (values '%member-key-test
 323                        '(key test)
 324                        '(%funcall test item (%funcall key car))))
 325               ((and key test-not)
 326                (values '%member-key-test-not
 327                        '(key test-not)
 328                        '(not (%funcall test-not item (%funcall key car)))))
 329               (test
 330                (values '%member-test
 331                        '(test)
 332                        '(%funcall test item car)))
 333               (test-not
 334                (values '%member-test-not
 335                        '(test-not)
 336                        '(not (%funcall test item car))))
 337               (t
 338                (bug "never")))
 339       (labels ((open-code (tail)
 340                  (when tail
 341                    `(if (let ((car ',(car tail)))
 342                           ,test-expr)
 343                         ',tail
 344                         ,(open-code (cdr tail)))))
 345                (ensure-fun (fun)
 346                  (if (eq 'key fun)
 347                      key-form
 348                      `(%coerce-callable-to-fun ,fun))))
 349         (if (and (constant-lvar-p list) (policy node (>= speed space)))
 350             `(let ,(mapcar (lambda (fun) `(,fun ,(ensure-fun fun))) funs)
 351                ,(open-code (lvar-value list)))
 352             `(,out-of-line item list ,@(mapcar #'ensure-fun funs)))))))
 353
 354 (deftransform memq ((item list) (t (constant-arg list)))
 355   (labels ((rec (tail)
 356              (if tail
 357                  `(if (eq item ',(car tail))
 358                       ',tail
 359                       ,(rec (cdr tail)))
 360                  nil)))
 361     (rec (lvar-value list))))
 362
 363 ;;; FIXME: We have rewritten the original code that used DOLIST to this
 364 ;;; more natural MACROLET.  However, the original code suggested that when
 365 ;;; this was done, a few bytes could be saved by a call to a shared
 366 ;;; function.  This remains to be done.
 367 (macrolet ((def (fun eq-fun)
 368              `(deftransform ,fun ((item list &key test) (t list &rest t) *)
 369                 "convert to EQ test"
 370                 ;; FIXME: The scope of this transformation could be
 371                 ;; widened somewhat, letting it work whenever the test is
 372                 ;; 'EQL and we know from the type of ITEM that it #'EQ
 373                 ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 374                 ;; and SYMBOL.)
 375                 ;;   If TEST is EQ, apply transform, else
 376                 ;;   if test is not EQL, then give up on transform, else
 377                 ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 378                 ;;   transform, else give up on transform.
 379                 (cond (test
 380                        (unless (lvar-fun-is test '(eq))
 381                          (give-up-ir1-transform)))
 382                       ((types-equal-or-intersect (lvar-type item)
 383                                                  (specifier-type 'number))
 384                        (give-up-ir1-transform "Item might be a number.")))
 385                 `(,',eq-fun item list))))
 386   (def delete delq)
 387   (def assoc assq)
 388   (def member memq))
 389
 390 (deftransform delete-if ((pred list) (t list))
 391   "open code"
 392   '(do ((x list (cdr x))
 393         (splice '()))
 394        ((endp x) list)
 395      (cond ((funcall pred (car x))
 396             (if (null splice)
 397                 (setq list (cdr x))
 398                 (rplacd splice (cdr x))))
 399            (t (setq splice x)))))
 400
 401 (deftransform fill ((seq item &key (start 0) (end (length seq)))
 402                     (vector t &key (:start t) (:end index))
 403                     *
 404                     :policy (> speed space))
 405   "open code"
 406   (let ((element-type (upgraded-element-type-specifier-or-give-up seq)))
 407     (values
 408      `(with-array-data ((data seq)
 409                         (start start)
 410                         (end end))
 411        (declare (type (simple-array ,element-type 1) data))
 412        (declare (type fixnum start end))
 413        (do ((i start (1+ i)))
 414            ((= i end) seq)
 415          (declare (type index i))
 416          ;; WITH-ARRAY-DATA did our range checks once and for all, so
 417          ;; it'd be wasteful to check again on every AREF...
 418          (declare (optimize (safety 0)))
 419          (setf (aref data i) item)))
 420      ;; ... though we still need to check that the new element can fit
 421      ;; into the vector in safe code. -- CSR, 2002-07-05
 422      `((declare (type ,element-type item))))))
 423 \f
 424 ;;;; utilities
 425
 426 ;;; Return true if LVAR's only use is a non-NOTINLINE reference to a
 427 ;;; global function with one of the specified NAMES.
 428 (defun lvar-fun-is (lvar names)
 429   (declare (type lvar lvar) (list names))
 430   (let ((use (lvar-uses lvar)))
 431     (and (ref-p use)
 432          (let ((leaf (ref-leaf use)))
 433            (and (global-var-p leaf)
 434                 (eq (global-var-kind leaf) :global-function)
 435                 (not (null (member (leaf-source-name leaf) names
 436                                    :test #'equal))))))))
 437
 438 ;;; If LVAR is a constant lvar, the return the constant value. If it
 439 ;;; is null, then return default, otherwise quietly give up the IR1
 440 ;;; transform.
 441 ;;;
 442 ;;; ### Probably should take an ARG and flame using the NAME.
 443 (defun constant-value-or-lose (lvar &optional default)
 444   (declare (type (or lvar null) lvar))
 445   (cond ((not lvar) default)
 446         ((constant-lvar-p lvar)
 447          (lvar-value lvar))
 448         (t
 449          (give-up-ir1-transform))))
 450
 451
 452 ;;;; hairy sequence transforms
 453
 454 ;;; FIXME: no hairy sequence transforms in SBCL?
 455 ;;;
 456 ;;; There used to be a bunch of commented out code about here,
 457 ;;; containing the (apparent) beginning of hairy sequence transform
 458 ;;; infrastructure. People interested in implementing better sequence
 459 ;;; transforms might want to look at it for inspiration, even though
 460 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 461 ;;; was deleted in 1.0.7.23.
 462 \f
 463 ;;;; string operations
 464
 465 ;;; We transform the case-sensitive string predicates into a non-keyword
 466 ;;; version. This is an IR1 transform so that we don't have to worry about
 467 ;;; changing the order of evaluation.
 468 (macrolet ((def (fun pred*)
 469              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 470                                                          (start2 0) end2)
 471                                    * *)
 472                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 473   (def string< string<*)
 474   (def string> string>*)
 475   (def string<= string<=*)
 476   (def string>= string>=*)
 477   (def string= string=*)
 478   (def string/= string/=*))
 479
 480 ;;; Return a form that tests the free variables STRING1 and STRING2
 481 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 482 ;;; start and end are also gotten from the environment. Both strings
 483 ;;; must be SIMPLE-BASE-STRINGs.
 484 (macrolet ((def (name lessp equalp)
 485              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 486                                    (simple-base-string simple-base-string t t t t) *)
 487                 `(let* ((end1 (if (not end1) (length string1) end1))
 488                         (end2 (if (not end2) (length string2) end2))
 489                         (index (sb!impl::%sp-string-compare
 490                                 string1 start1 end1 string2 start2 end2)))
 491                   (if index
 492                       (cond ((= index end1)
 493                              ,(if ',lessp 'index nil))
 494                             ((= (+ index (- start2 start1)) end2)
 495                              ,(if ',lessp nil 'index))
 496                             ((,(if ',lessp 'char< 'char>)
 497                                (schar string1 index)
 498                                (schar string2
 499                                       (truly-the index
 500                                                  (+ index
 501                                                     (truly-the fixnum
 502                                                                (- start2
 503                                                                   start1))))))
 504                              index)
 505                             (t nil))
 506                       ,(if ',equalp 'end1 nil))))))
 507   (def string<* t nil)
 508   (def string<=* t t)
 509   (def string>* nil nil)
 510   (def string>=* nil t))
 511
 512 (macrolet ((def (name result-fun)
 513              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 514                                    (simple-base-string simple-base-string t t t t) *)
 515                 `(,',result-fun
 516                   (sb!impl::%sp-string-compare
 517                    string1 start1 (or end1 (length string1))
 518                    string2 start2 (or end2 (length string2)))))))
 519   (def string=* not)
 520   (def string/=* identity))
 521
 522 \f
 523 ;;;; transforms for sequence functions
 524
 525 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 526 ;;; to vectors based on simple arrays.
 527 (def!constant vector-data-bit-offset
 528   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 529
 530 (eval-when (:compile-toplevel)
 531 (defun valid-bit-bash-saetp-p (saetp)
 532   ;; BIT-BASHing isn't allowed on simple vectors that contain pointers
 533   (and (not (eq t (sb!vm:saetp-specifier saetp)))
 534        ;; Disallowing (VECTOR NIL) also means that we won't transform
 535        ;; sequence functions into bit-bashing code and we let the
 536        ;; generic sequence functions signal errors if necessary.
 537        (not (zerop (sb!vm:saetp-n-bits saetp)))
 538        ;; Due to limitations with the current BIT-BASHing code, we can't
 539        ;; BIT-BASH reliably on arrays whose element types are larger
 540        ;; than the word size.
 541        (<= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)))
 542 ) ; EVAL-WHEN
 543
 544 ;;; FIXME: In the copy loops below, we code the loops in a strange
 545 ;;; fashion:
 546 ;;;
 547 ;;; (do ((i (+ src-offset length) (1- i)))
 548 ;;;     ((<= i 0) ...)
 549 ;;;   (... (aref foo (1- i)) ...))
 550 ;;;
 551 ;;; rather than the more natural (and seemingly more efficient):
 552 ;;;
 553 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 554 ;;;     ((< i 0) ...)
 555 ;;;   (... (aref foo i) ...))
 556 ;;;
 557 ;;; (more efficient because we don't have to do the index adjusting on
 558 ;;; every iteration of the loop)
 559 ;;;
 560 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 561 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 562 ;;; when used as an array index, the backend thinks I is a
 563 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 564 ;;; these as distinct storage classes, it cannot coerce a move from a
 565 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 566 ;;; deficiency is that we have two extra moves and increased register
 567 ;;; pressure, which can lead to some spectacularly bad register
 568 ;;; allocation.  (sub-FIXME: the register allocation even with the
 569 ;;; strangely written loops is not always excellent, either...).  Doing
 570 ;;; it the first way, above, means that I is always thought of as a
 571 ;;; POSITIVE-FIXNUM and there are no issues.
 572 ;;;
 573 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 574 ;;; adjustments in the first version into the array addressing at no
 575 ;;; performance penalty!
 576
 577 ;;; This transform is critical to the performance of string streams.  If
 578 ;;; you tweak it, make sure that you compare the disassembly, if not the
 579 ;;; performance of, the functions implementing string streams
 580 ;;; (e.g. SB!IMPL::STRING-OUCH).
 581 (macrolet
 582     ((define-replace-transforms ()
 583        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 584              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 585              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 586              collect
 587             `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 588                                     (,sequence-type ,sequence-type &rest t)
 589                                     ,sequence-type
 590                                     :node node)
 591                ,(cond
 592                  ((valid-bit-bash-saetp-p saetp) nil)
 593                  ;; If we're not bit-bashing, only allow cases where we
 594                  ;; can determine the order of copying up front.  (There
 595                  ;; are actually more cases we can handle if we know the
 596                  ;; amount that we're copying, but this handles the
 597                  ;; common cases.)
 598                  (t '(unless (= (constant-value-or-lose start1 0)
 599                               (constant-value-or-lose start2 0))
 600                       (give-up-ir1-transform))))
 601                `(let* ((len1 (length seq1))
 602                        (len2 (length seq2))
 603                        (end1 (or end1 len1))
 604                        (end2 (or end2 len2))
 605                        (replace-len1 (- end1 start1))
 606                        (replace-len2 (- end2 start2)))
 607                   ,(unless (policy node (= safety 0))
 608                            `(progn
 609                               (unless (<= 0 start1 end1 len1)
 610                                 (sb!impl::signal-bounding-indices-bad-error seq1 start1 end1))
 611                               (unless (<= 0 start2 end2 len2)
 612                                 (sb!impl::signal-bounding-indices-bad-error seq2 start2 end2))))
 613                   ,',(cond
 614                       ((valid-bit-bash-saetp-p saetp)
 615                        (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 616                               (bash-function (intern (format nil "UB~D-BASH-COPY" n-element-bits)
 617                                                      (find-package "SB!KERNEL"))))
 618                          `(funcall (function ,bash-function) seq2 start2
 619                                    seq1 start1 (min replace-len1 replace-len2))))
 620                       (t
 621                        ;; We can expand the loop inline here because we
 622                        ;; would have given up the transform (see above)
 623                        ;; if we didn't have constant matching start
 624                        ;; indices.
 625                        '(do ((i start1 (1+ i))
 626                              (end (+ start1
 627                                      (min replace-len1 replace-len2))))
 628                          ((>= i end))
 629                          (declare (optimize (insert-array-bounds-checks 0)))
 630                          (setf (aref seq1 i) (aref seq2 i)))))
 631                   seq1))
 632              into forms
 633              finally (return `(progn ,@forms)))))
 634   (define-replace-transforms))
 635
 636 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 637 ;;; defined as those cases where we are doing word-aligned copies from
 638 ;;; both the source and the destination and we are copying from the same
 639 ;;; offset from both the source and the destination.  (The last
 640 ;;; condition is there so we can determine the direction to copy at
 641 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 642 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 643 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 644 ;;; N)-size buffer and blitting in the old N-size buffer in.
 645
 646 (defun frob-bash-transform (src src-offset
 647                             dst dst-offset
 648                             length n-elems-per-word)
 649   (declare (ignore src dst length))
 650   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 651     (multiple-value-bind (src-word src-elt)
 652         (truncate (lvar-value src-offset) n-elems-per-word)
 653       (multiple-value-bind (dst-word dst-elt)
 654           (truncate (lvar-value dst-offset) n-elems-per-word)
 655         ;; Avoid non-word aligned copies.
 656         (unless (and (zerop src-elt) (zerop dst-elt))
 657           (give-up-ir1-transform))
 658         ;; Avoid copies where we would have to insert code for
 659         ;; determining the direction of copying.
 660         (unless (= src-word dst-word)
 661           (give-up-ir1-transform))
 662         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 663         ;; so we have to do its work here.
 664         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 665                                       'length
 666                                       `(truncate (the index length) ,n-elems-per-word)))))
 667            (declare (type index end))
 668            ;; Handle any bits at the end.
 669            (when (logtest length (1- ,n-elems-per-word))
 670              (let* ((extra (mod length ,n-elems-per-word))
 671                     ;; FIXME: The shift amount on this ASH is
 672                     ;; *always* negative, but the backend doesn't
 673                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 674                     ;; wind up with a pile of code that tests the
 675                     ;; sign of the shift count prior to shifting when
 676                     ;; all we need is a simple negate and shift
 677                     ;; right.  Yuck.
 678                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 679                                (* (- extra ,n-elems-per-word)
 680                                   ,n-bits-per-elem))))
 681                (setf (sb!kernel:%vector-raw-bits dst end)
 682                      (logior
 683                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 684                                 (ash mask
 685                                      ,(ecase sb!c:*backend-byte-order*
 686                                              (:little-endian 0)
 687                                              (:big-endian `(* (- ,n-elems-per-word extra)
 688                                                               ,n-bits-per-elem)))))
 689                       (logand (sb!kernel:%vector-raw-bits src end)
 690                               (ash mask
 691                                    ,(ecase sb!c:*backend-byte-order*
 692                                            (:little-endian 0)
 693                                            (:big-endian `(* (- ,n-elems-per-word extra)
 694                                                             ,n-bits-per-elem)))))))))
 695            ;; Copy from the end to save a register.
 696            (do ((i end (1- i)))
 697                ((<= i ,src-word))
 698              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 699                    (sb!kernel:%vector-raw-bits src (1- i)))))))))
 700
 701 #.(loop for i = 1 then (* i 2)
 702         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 703                                         "SB!KERNEL")
 704                                                         ((src src-offset
 705                                                           dst dst-offset
 706                                                           length)
 707                                                         ((simple-unboxed-array (*))
 708                                                          (constant-arg index)
 709                                                          (simple-unboxed-array (*))
 710                                                          (constant-arg index)
 711                                                          index)
 712                                                         *)
 713                   (frob-bash-transform src src-offset
 714                                        dst dst-offset length
 715                                        ,(truncate sb!vm:n-word-bits i))) into forms
 716         until (= i sb!vm:n-word-bits)
 717         finally (return `(progn ,@forms)))
 718
 719 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 720 ;;; arrays with elements of size >= the word size.  We do this because
 721 ;;; we know the arrays cannot alias (one was just consed), therefore we
 722 ;;; can determine at compile time the direction to copy, and for
 723 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 724 ;;; needless checking to figure out what's going on.  The same
 725 ;;; considerations apply if we are copying elements larger than the word
 726 ;;; size, with the additional twist that doing it inline is likely to
 727 ;;; cons far less than calling REPLACE and letting generic code do the
 728 ;;; work.
 729 ;;;
 730 ;;; However, we do not do this for elements whose size is < than the
 731 ;;; word size because we don't want to deal with any alignment issues
 732 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 733 ;;; anyway.
 734
 735 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 736                                       element-type)
 737   (let ((saetp (find-saetp element-type)))
 738     (aver saetp)
 739     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 740         (expand-aref-copy-loop src src-offset dst dst-offset length)
 741         `(locally (declare (optimize (safety 0)))
 742            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 743
 744 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 745   (if (eql src-offset dst-offset)
 746       `(do ((i (+ ,src-offset ,length) (1- i)))
 747            ((<= i ,src-offset))
 748          (declare (optimize (insert-array-bounds-checks 0)))
 749          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 750       ;; KLUDGE: The compiler is not able to derive that (+ offset
 751       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 752       ;; We, however, know it must be so, as by this point the bounds
 753       ;; have already been checked.
 754       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 755             (j (+ ,dst-offset ,length) (1- j)))
 756            ((<= i ,src-offset))
 757          (declare (optimize (insert-array-bounds-checks 0))
 758                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 759          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 760
 761 (deftransform subseq ((seq start &optional end)
 762                       ((or (simple-unboxed-array (*)) simple-vector) t &optional t)
 763                       * :node node)
 764   (let ((array-type (lvar-type seq)))
 765     (unless (array-type-p array-type)
 766       (give-up-ir1-transform))
 767     (let ((element-type (type-specifier (array-type-specialized-element-type array-type))))
 768       `(let* ((length (length seq))
 769               (end (or end length)))
 770          ,(unless (policy node (= safety 0))
 771                   '(progn
 772                     (unless (<= 0 start end length)
 773                       (sb!impl::signal-bounding-indices-bad-error seq start end))))
 774          (let* ((size (- end start))
 775                 (result (make-array size :element-type ',element-type)))
 776            ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
 777                                                     (lvar-value start)
 778                                                     'start)
 779                                            'result 0 'size element-type)
 780            result)))))
 781
 782 (deftransform copy-seq ((seq) ((or (simple-unboxed-array (*)) simple-vector)) *)
 783   (let ((array-type (lvar-type seq)))
 784     (unless (array-type-p array-type)
 785       (give-up-ir1-transform))
 786     (let ((element-type (type-specifier (array-type-specialized-element-type array-type))))
 787       `(let* ((length (length seq))
 788               (result (make-array length :element-type ',element-type)))
 789          ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
 790          result))))
 791
 792 ;;; FIXME: it really should be possible to take advantage of the
 793 ;;; macros used in code/seq.lisp here to avoid duplication of code,
 794 ;;; and enable even funkier transformations.
 795 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
 796                                (test #'eql)
 797                                (key #'identity)
 798                                from-end)
 799                       (vector vector &rest t)
 800                       *
 801                       :policy (> speed (max space safety)))
 802   "open code"
 803   (let ((from-end (when (lvar-p from-end)
 804                     (unless (constant-lvar-p from-end)
 805                       (give-up-ir1-transform ":FROM-END is not constant."))
 806                     (lvar-value from-end)))
 807         (keyp (lvar-p key))
 808         (testp (lvar-p test)))
 809     `(block search
 810        (let ((end1 (or end1 (length pattern)))
 811              (end2 (or end2 (length text)))
 812              ,@(when keyp
 813                      '((key (coerce key 'function))))
 814              ,@(when testp
 815                      '((test (coerce test 'function)))))
 816          (declare (type index start1 start2 end1 end2))
 817          (do (,(if from-end
 818                    '(index2 (- end2 (- end1 start1)) (1- index2))
 819                    '(index2 start2 (1+ index2))))
 820              (,(if from-end
 821                    '(< index2 start2)
 822                    '(>= index2 end2))
 823               nil)
 824            ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
 825            ;; terminates is hits -1 when :FROM-END is true and :START2
 826            ;; is 0.
 827            (declare (type fixnum index2))
 828            (when (do ((index1 start1 (1+ index1))
 829                       (index2 index2 (1+ index2)))
 830                      ((>= index1 end1) t)
 831                    (declare (type index index1 index2))
 832                    ,@(unless from-end
 833                              '((when (= index2 end2)
 834                                  (return-from search nil))))
 835                    (unless (,@(if testp
 836                                   '(funcall test)
 837                                   '(eql))
 838                               ,(if keyp
 839                                    '(funcall key (aref pattern index1))
 840                                    '(aref pattern index1))
 841                               ,(if keyp
 842                                    '(funcall key (aref text index2))
 843                                    '(aref text index2)))
 844                      (return nil)))
 845              (return index2)))))))
 846
 847 ;;; FIXME: It seems as though it should be possible to make a DEFUN
 848 ;;; %CONCATENATE (with a DEFTRANSFORM to translate constant RTYPE to
 849 ;;; CTYPE before calling %CONCATENATE) which is comparably efficient,
 850 ;;; at least once DYNAMIC-EXTENT works.
 851 ;;;
 852 ;;; FIXME: currently KLUDGEed because of bug 188
 853 ;;;
 854 ;;; FIXME: disabled for sb-unicode: probably want it back
 855 #!-sb-unicode
 856 (deftransform concatenate ((rtype &rest sequences)
 857                            (t &rest (or simple-base-string
 858                                         (simple-array nil (*))))
 859                            simple-base-string
 860                            :policy (< safety 3))
 861   (loop for rest-seqs on sequences
 862         for n-seq = (gensym "N-SEQ")
 863         for n-length = (gensym "N-LENGTH")
 864         for start = 0 then next-start
 865         for next-start = (gensym "NEXT-START")
 866         collect n-seq into args
 867         collect `(,n-length (length ,n-seq)) into lets
 868         collect n-length into all-lengths
 869         collect next-start into starts
 870         collect `(if (and (typep ,n-seq '(simple-array nil (*)))
 871                           (> ,n-length 0))
 872                      (error 'nil-array-accessed-error)
 873                      (#.(let* ((i (position 'character sb!kernel::*specialized-array-element-types*))
 874                                (saetp (aref sb!vm:*specialized-array-element-type-properties* i))
 875                                (n-bits (sb!vm:saetp-n-bits saetp)))
 876                           (intern (format nil "UB~D-BASH-COPY" n-bits)
 877                                   "SB!KERNEL"))
 878                         ,n-seq 0 res ,start ,n-length))
 879                 into forms
 880         collect `(setq ,next-start (+ ,start ,n-length)) into forms
 881         finally
 882         (return
 883           `(lambda (rtype ,@args)
 884              (declare (ignore rtype))
 885              (let* (,@lets
 886                     (res (make-string (the index (+ ,@all-lengths))
 887                                       :element-type 'base-char)))
 888                (declare (type index ,@all-lengths))
 889                (let (,@(mapcar (lambda (name) `(,name 0)) starts))
 890                  (declare (type index ,@starts))
 891                  ,@forms)
 892                res)))))
 893 \f
 894 ;;;; CONS accessor DERIVE-TYPE optimizers
 895
 896 (defoptimizer (car derive-type) ((cons))
 897   (let ((type (lvar-type cons))
 898         (null-type (specifier-type 'null)))
 899     (cond ((eq type null-type)
 900            null-type)
 901           ((cons-type-p type)
 902            (cons-type-car-type type)))))
 903
 904 (defoptimizer (cdr derive-type) ((cons))
 905   (let ((type (lvar-type cons))
 906         (null-type (specifier-type 'null)))
 907     (cond ((eq type null-type)
 908            null-type)
 909           ((cons-type-p type)
 910            (cons-type-cdr-type type)))))
 911 \f
 912 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
 913
 914 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
 915 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
 916 ;;; expansion, so we factor out the condition into this function.
 917 (defun check-inlineability-of-find-position-if (sequence from-end)
 918   (let ((ctype (lvar-type sequence)))
 919     (cond ((csubtypep ctype (specifier-type 'vector))
 920            ;; It's not worth trying to inline vector code unless we
 921            ;; know a fair amount about it at compile time.
 922            (upgraded-element-type-specifier-or-give-up sequence)
 923            (unless (constant-lvar-p from-end)
 924              (give-up-ir1-transform
 925               "FROM-END argument value not known at compile time")))
 926           ((csubtypep ctype (specifier-type 'list))
 927            ;; Inlining on lists is generally worthwhile.
 928            )
 929           (t
 930            (give-up-ir1-transform
 931             "sequence type not known at compile time")))))
 932
 933 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
 934 (macrolet ((def (name condition)
 935              `(deftransform ,name ((predicate sequence from-end start end key)
 936                                    (function list t t t function)
 937                                    *
 938                                    :policy (> speed space))
 939                 "expand inline"
 940                 `(let ((index 0)
 941                        (find nil)
 942                        (position nil))
 943                    (declare (type index index))
 944                    (dolist (i sequence
 945                             (if (and end (> end index))
 946                                 (sb!impl::signal-bounding-indices-bad-error
 947                                  sequence start end)
 948                                 (values find position)))
 949                      (let ((key-i (funcall key i)))
 950                        (when (and end (>= index end))
 951                          (return (values find position)))
 952                        (when (>= index start)
 953                          (,',condition (funcall predicate key-i)
 954                           ;; This hack of dealing with non-NIL
 955                           ;; FROM-END for list data by iterating
 956                           ;; forward through the list and keeping
 957                           ;; track of the last time we found a match
 958                           ;; might be more screwy than what the user
 959                           ;; expects, but it seems to be allowed by
 960                           ;; the ANSI standard. (And if the user is
 961                           ;; screwy enough to ask for FROM-END
 962                           ;; behavior on list data, turnabout is
 963                           ;; fair play.)
 964                           ;;
 965                           ;; It's also not enormously efficient,
 966                           ;; calling PREDICATE and KEY more often
 967                           ;; than necessary; but all the
 968                           ;; alternatives seem to have their own
 969                           ;; efficiency problems.
 970                           (if from-end
 971                               (setf find i
 972                                     position index)
 973                               (return (values i index))))))
 974                      (incf index))))))
 975   (def %find-position-if when)
 976   (def %find-position-if-not unless))
 977
 978 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
 979 ;;; without loss of efficiency. (I.e., the optimizer should be able
 980 ;;; to straighten everything out.)
 981 (deftransform %find-position ((item sequence from-end start end key test)
 982                               (t list t t t t t)
 983                               *
 984                               :policy (> speed space))
 985   "expand inline"
 986   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
 987                         ;; The order of arguments for asymmetric tests
 988                         ;; (e.g. #'<, as opposed to order-independent
 989                         ;; tests like #'=) is specified in the spec
 990                         ;; section 17.2.1 -- the O/Zi stuff there.
 991                         (lambda (i)
 992                           (funcall test-fun item i)))
 993                       sequence
 994                       from-end
 995                       start
 996                       end
 997                       (%coerce-callable-to-fun key)))
 998
 999 ;;; The inline expansions for the VECTOR case are saved as macros so
1000 ;;; that we can share them between the DEFTRANSFORMs and the default
1001 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
1002 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1003 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1004                                                             from-end
1005                                                             start
1006                                                             end-arg
1007                                                             element
1008                                                             done-p-expr)
1009   (with-unique-names (offset block index n-sequence sequence n-end end)
1010     `(let ((,n-sequence ,sequence-arg)
1011            (,n-end ,end-arg))
1012        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1013                          (,start ,start)
1014                          (,end (%check-vector-sequence-bounds
1015                                 ,n-sequence ,start ,n-end)))
1016          (block ,block
1017            (macrolet ((maybe-return ()
1018                         ;; WITH-ARRAY-DATA has already performed bounds
1019                         ;; checking, so we can safely elide the checks
1020                         ;; in the inner loop.
1021                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1022                                            (aref ,sequence ,index))))
1023                            (when ,done-p-expr
1024                              (return-from ,block
1025                                (values ,element
1026                                        (- ,index ,offset)))))))
1027              (if ,from-end
1028                  (loop for ,index
1029                        ;; (If we aren't fastidious about declaring that
1030                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1031                        ;; can send us off into never-never land, since
1032                        ;; INDEX is initialized to -1.)
1033                        of-type index-or-minus-1
1034                        from (1- ,end) downto ,start do
1035                        (maybe-return))
1036                  (loop for ,index of-type index from ,start below ,end do
1037                        (maybe-return))))
1038            (values nil nil))))))
1039
1040 (def!macro %find-position-vector-macro (item sequence
1041                                              from-end start end key test)
1042   (with-unique-names (element)
1043     (%find-position-or-find-position-if-vector-expansion
1044      sequence
1045      from-end
1046      start
1047      end
1048      element
1049      ;; (See the LIST transform for a discussion of the correct
1050      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1051      ;; or after the checked sequence element.)
1052      `(funcall ,test ,item (funcall ,key ,element)))))
1053
1054 (def!macro %find-position-if-vector-macro (predicate sequence
1055                                                      from-end start end key)
1056   (with-unique-names (element)
1057     (%find-position-or-find-position-if-vector-expansion
1058      sequence
1059      from-end
1060      start
1061      end
1062      element
1063      `(funcall ,predicate (funcall ,key ,element)))))
1064
1065 (def!macro %find-position-if-not-vector-macro (predicate sequence
1066                                                          from-end start end key)
1067   (with-unique-names (element)
1068     (%find-position-or-find-position-if-vector-expansion
1069      sequence
1070      from-end
1071      start
1072      end
1073      element
1074      `(not (funcall ,predicate (funcall ,key ,element))))))
1075
1076 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1077 ;;; VECTOR data
1078 (deftransform %find-position-if ((predicate sequence from-end start end key)
1079                                  (function vector t t t function)
1080                                  *
1081                                  :policy (> speed space))
1082   "expand inline"
1083   (check-inlineability-of-find-position-if sequence from-end)
1084   '(%find-position-if-vector-macro predicate sequence
1085                                    from-end start end key))
1086
1087 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1088                                      (function vector t t t function)
1089                                      *
1090                                      :policy (> speed space))
1091   "expand inline"
1092   (check-inlineability-of-find-position-if sequence from-end)
1093   '(%find-position-if-not-vector-macro predicate sequence
1094                                        from-end start end key))
1095
1096 (deftransform %find-position ((item sequence from-end start end key test)
1097                               (t vector t t t function function)
1098                               *
1099                               :policy (> speed space))
1100   "expand inline"
1101   (check-inlineability-of-find-position-if sequence from-end)
1102   '(%find-position-vector-macro item sequence
1103                                 from-end start end key test))
1104
1105 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1106 ;;; POSITION-IF, etc.
1107 (define-source-transform effective-find-position-test (test test-not)
1108   (once-only ((test test)
1109               (test-not test-not))
1110     `(cond
1111       ((and ,test ,test-not)
1112        (error "can't specify both :TEST and :TEST-NOT"))
1113       (,test (%coerce-callable-to-fun ,test))
1114       (,test-not
1115        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1116        ;; inefficient, but since the TEST-NOT option is deprecated
1117        ;; anyway, we don't care.)
1118        (complement (%coerce-callable-to-fun ,test-not)))
1119       (t #'eql))))
1120 (define-source-transform effective-find-position-key (key)
1121   (once-only ((key key))
1122     `(if ,key
1123          (%coerce-callable-to-fun ,key)
1124          #'identity)))
1125
1126 (macrolet ((define-find-position (fun-name values-index)
1127              `(deftransform ,fun-name ((item sequence &key
1128                                              from-end (start 0) end
1129                                              key test test-not)
1130                                        (t (or list vector) &rest t))
1131                 '(nth-value ,values-index
1132                             (%find-position item sequence
1133                                             from-end start
1134                                             end
1135                                             (effective-find-position-key key)
1136                                             (effective-find-position-test
1137                                              test test-not))))))
1138   (define-find-position find 0)
1139   (define-find-position position 1))
1140
1141 (macrolet ((define-find-position-if (fun-name values-index)
1142              `(deftransform ,fun-name ((predicate sequence &key
1143                                                   from-end (start 0)
1144                                                   end key)
1145                                        (t (or list vector) &rest t))
1146                 '(nth-value
1147                   ,values-index
1148                   (%find-position-if (%coerce-callable-to-fun predicate)
1149                                      sequence from-end
1150                                      start end
1151                                      (effective-find-position-key key))))))
1152   (define-find-position-if find-if 0)
1153   (define-find-position-if position-if 1))
1154
1155 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1156 ;;; didn't bother to worry about optimizing them, except note that on
1157 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1158 ;;; sbcl-devel
1159 ;;;
1160 ;;;     My understanding is that while the :test-not argument is
1161 ;;;     deprecated in favour of :test (complement #'foo) because of
1162 ;;;     semantic difficulties (what happens if both :test and :test-not
1163 ;;;     are supplied, etc) the -if-not variants, while officially
1164 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1165 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1166 ;;;     reasons for allowing the -if-not versions equal status,
1167 ;;;     particularly remove-if-not (== filter).
1168 ;;;
1169 ;;;     This is only an informal understanding, I grant you, but
1170 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1171 ;;;     way as the others?
1172 ;;;
1173 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1174 ;;; implementation of SBCL.
1175 (macrolet ((define-find-position-if-not (fun-name values-index)
1176                `(deftransform ,fun-name ((predicate sequence &key
1177                                           from-end (start 0)
1178                                           end key)
1179                                          (t (or list vector) &rest t))
1180                  '(nth-value
1181                    ,values-index
1182                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1183                     sequence from-end
1184                     start end
1185                     (effective-find-position-key key))))))
1186   (define-find-position-if-not find-if-not 0)
1187   (define-find-position-if-not position-if-not 1))