src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places))
 137     (let ((found-vector-p nil))
 138       (flet ((process-vector (length)
 139                (unless found-vector-p
 140                  (setq found-vector-p t)
 141                  (bindings `(index 0 (1+ index)))
 142                  (declarations `(type index index)))
 143                (vector-lengths length)))
 144         (loop for seq of-type lvar in seqs
 145            for seq-name in seq-names
 146            for type = (lvar-type seq)
 147            do (cond ((csubtypep type (specifier-type 'list))
 148                      (with-unique-names (index)
 149                        (bindings `(,index ,seq-name (cdr ,index)))
 150                        (declarations `(type list ,index))
 151                        (places `(car ,index))
 152                        (tests `(endp ,index))))
 153                     ((csubtypep type (specifier-type 'vector))
 154                      (process-vector `(length ,seq-name))
 155                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 156                                 (aref ,seq-name index))))
 157                     (t
 158                      (give-up-ir1-transform
 159                       "can't determine sequence argument type"))))
 160         (when into
 161           (process-vector `(array-dimension ,into 0))))
 162       (when found-vector-p
 163         (bindings `(length (min ,@(vector-lengths))))
 164         (tests `(>= index length)))
 165       `(do (,@(bindings))
 166            ((or ,@(tests)) ,result)
 167          (declare ,@(declarations))
 168          (let ((funcall-result (funcall fun ,@(places))))
 169            (declare (ignorable funcall-result))
 170            ,body)))))
 171
 172 ;;; Try to compile %MAP efficiently when we can determine sequence
 173 ;;; argument types at compile time.
 174 ;;;
 175 ;;; Note: This transform was written to allow open coding of
 176 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 177 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 178 ;;; necessarily as efficient as possible. In particular, it will be
 179 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 180 ;;; numeric element types. It should be straightforward to make it
 181 ;;; handle that case more efficiently, but it's left as an exercise to
 182 ;;; the reader, because the code is complicated enough already and I
 183 ;;; don't happen to need that functionality right now. -- WHN 20000410
 184 (deftransform %map ((result-type fun seq &rest seqs) * *
 185                     :policy (>= speed space))
 186   "open code"
 187   (unless (constant-lvar-p result-type)
 188     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 189   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 190            (fn-1subtypep (fn x y)
 191              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 192                (if valid-p
 193                    subtype-p
 194                    (give-up-ir1-transform
 195                     "can't analyze sequence type relationship"))))
 196            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 197     (let* ((result-type-value (lvar-value result-type))
 198            (result-supertype (cond ((null result-type-value) 'null)
 199                                    ((1subtypep result-type-value 'vector)
 200                                     'vector)
 201                                    ((1subtypep result-type-value 'list)
 202                                     'list)
 203                                    (t
 204                                     (give-up-ir1-transform
 205                                      "result type unsuitable")))))
 206       (cond ((and result-type-value (null seqs))
 207              ;; The consing arity-1 cases can be implemented
 208              ;; reasonably efficiently as function calls, and the cost
 209              ;; of consing should be significantly larger than
 210              ;; function call overhead, so we always compile these
 211              ;; cases as full calls regardless of speed-versus-space
 212              ;; optimization policy.
 213              (cond ((subtypep result-type-value 'list)
 214                     '(%map-to-list-arity-1 fun seq))
 215                    ( ;; (This one can be inefficient due to COERCE, but
 216                     ;; the current open-coded implementation has the
 217                     ;; same problem.)
 218                     (subtypep result-type-value 'vector)
 219                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 220                              ',result-type-value))
 221                    (t (bug "impossible (?) sequence type"))))
 222             (t
 223              (let* ((seqs (cons seq seqs))
 224                     (seq-args (make-gensym-list (length seqs))))
 225                (multiple-value-bind (push-dacc result)
 226                    (ecase result-supertype
 227                      (null (values nil nil))
 228                      (list (values `(push funcall-result acc)
 229                                    `(nreverse acc)))
 230                      (vector (values `(push funcall-result acc)
 231                                      `(coerce (nreverse acc)
 232                                               ',result-type-value))))
 233                  ;; (We use the same idiom, of returning a LAMBDA from
 234                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 235                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 236                  ;; reason: we need to get the runtime values of each
 237                  ;; of the &REST vars.)
 238                  `(lambda (result-type fun ,@seq-args)
 239                     (declare (ignore result-type))
 240                     (let ((fun (%coerce-callable-to-fun fun))
 241                           (acc nil))
 242                       (declare (type list acc))
 243                       (declare (ignorable acc))
 244                       ,(build-sequence-iterator
 245                         seqs seq-args
 246                         :result result
 247                         :body push-dacc))))))))))
 248
 249 ;;; MAP-INTO
 250 (deftransform map-into ((result fun &rest seqs)
 251                         (vector * &rest *)
 252                         *)
 253   "open code"
 254   (let ((seqs-names (mapcar (lambda (x)
 255                               (declare (ignore x))
 256                               (gensym))
 257                             seqs)))
 258     `(lambda (result fun ,@seqs-names)
 259        ,(build-sequence-iterator
 260          seqs seqs-names
 261          :result '(when (array-has-fill-pointer-p result)
 262                    (setf (fill-pointer result) index))
 263          :into 'result
 264          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 265                  (setf (aref result index) funcall-result)))
 266        result)))
 267
 268 \f
 269 ;;; FIXME: once the confusion over doing transforms with known-complex
 270 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 271 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 272 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 273   '(aref s i))
 274
 275 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 276   '(nth i s))
 277
 278 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 279   '(%aset s i v))
 280
 281 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 282   '(setf (car (nthcdr i s)) v))
 283
 284 (deftransform %check-vector-sequence-bounds ((vector start end)
 285                                              (vector * *) *
 286                                              :node node)
 287   (if (policy node (= 0 insert-array-bounds-checks))
 288       '(or end (length vector))
 289       '(let ((length (length vector)))
 290          (if (<= 0 start (or end length) length)
 291              (or end length)
 292              (sequence-bounding-indices-bad-error vector start end)))))
 293
 294 (defun specialized-list-seek-function-name (function-name key-functions &optional variant)
 295   (or (find-symbol (with-output-to-string (s)
 296                      ;; Write "%NAME-FUN1-FUN2-FUN3", etc. Not only is
 297                      ;; this ever so slightly faster then FORMAT, this
 298                      ;; way we are also proof against *PRINT-CASE*
 299                      ;; frobbing and such.
 300                      (write-char #\% s)
 301                      (write-string (symbol-name function-name) s)
 302                      (dolist (f key-functions)
 303                        (write-char #\- s)
 304                        (write-string (symbol-name f) s))
 305                      (when variant
 306                        (write-char #\- s)
 307                        (write-string (symbol-name variant) s)))
 308                    (load-time-value (find-package "SB!KERNEL")))
 309       (bug "Unknown list item seek transform: name=~S, key-functions=~S variant=~S"
 310            function-name key-functions variant)))
 311
 312 (defun transform-list-item-seek (name item list key test test-not node)
 313   ;; If TEST is EQL, drop it.
 314   (when (and test (lvar-fun-is test '(eql)))
 315     (setf test nil))
 316   ;; Ditto for KEY IDENTITY.
 317   (when (and key (lvar-fun-is key '(identity)))
 318     (setf key nil))
 319   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 320   ;; not there at all. If it might be NIL, make up a form to that
 321   ;; ensures it is a function.
 322   (multiple-value-bind (key key-form)
 323       (when key
 324         (let ((key-type (lvar-type key))
 325               (null-type (specifier-type 'null)))
 326           (cond ((csubtypep key-type null-type)
 327                  (values nil nil))
 328                 ((csubtypep null-type key-type)
 329                  (values key '(if key
 330                                (%coerce-callable-to-fun key)
 331                                #'identity)))
 332                 (t
 333                  (values key '(%coerce-callable-to-fun key))))))
 334     (let* ((c-test (cond ((and test (lvar-fun-is test '(eq)))
 335                           (setf test nil)
 336                           'eq)
 337                          ((and (not test) (not test-not))
 338                           (when (eq-comparable-type-p (lvar-type item))
 339                             'eq))))
 340            (funs (remove nil (list (and key 'key) (cond (test 'test)
 341                                                         (test-not 'test-not)))))
 342            (target-expr (if key '(%funcall key target) 'target))
 343            (test-expr (cond (test `(%funcall test item ,target-expr))
 344                             (test-not `(not (%funcall test-not item ,target-expr)))
 345                             (c-test `(,c-test item ,target-expr))
 346                             (t `(eql item ,target-expr)))))
 347       (labels ((open-code (tail)
 348                  (when tail
 349                    `(if (let ((this ',(car tail)))
 350                           ,(ecase name
 351                                   ((assoc rassoc)
 352                                    (let ((cxx (if (eq name 'assoc) 'car 'cdr)))
 353                                      `(and this (let ((target (,cxx this)))
 354                                                   ,test-expr))))
 355                                   (member
 356                                    `(let ((target this))
 357                                       ,test-expr))))
 358                         ',(ecase name
 359                                  ((assoc rassoc) (car tail))
 360                                  (member tail))
 361                         ,(open-code (cdr tail)))))
 362                (ensure-fun (fun)
 363                  (if (eq 'key fun)
 364                      key-form
 365                      `(%coerce-callable-to-fun ,fun))))
 366         (let* ((cp (constant-lvar-p list))
 367                (c-list (when cp (lvar-value list))))
 368           (cond ((and cp c-list (member name '(assoc rassoc member))
 369                       (policy node (>= speed space)))
 370                  `(let ,(mapcar (lambda (fun) `(,fun ,(ensure-fun fun))) funs)
 371                     ,(open-code c-list)))
 372                 ((and cp (not c-list))
 373                  ;; constant nil list
 374                  (if (eq name 'adjoin)
 375                      '(list item)
 376                      nil))
 377                 (t
 378                  ;; specialized out-of-line version
 379                  `(,(specialized-list-seek-function-name name funs c-test)
 380                     item list ,@(mapcar #'ensure-fun funs)))))))))
 381
 382 (defun transform-list-pred-seek (name pred list key node)
 383   ;; If KEY is IDENTITY, drop it.
 384   (when (and key (lvar-fun-is key '(identity)))
 385     (setf key nil))
 386   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 387   ;; not there at all. If it might be NIL, make up a form to that
 388   ;; ensures it is a function.
 389   (multiple-value-bind (key key-form)
 390       (when key
 391         (let ((key-type (lvar-type key))
 392               (null-type (specifier-type 'null)))
 393           (cond ((csubtypep key-type null-type)
 394                  (values nil nil))
 395                 ((csubtypep null-type key-type)
 396                  (values key '(if key
 397                                (%coerce-callable-to-fun key)
 398                                #'identity)))
 399                 (t
 400                  (values key '(%coerce-callable-to-fun key))))))
 401     (let ((test-expr `(%funcall pred ,(if key '(%funcall key target) 'target)))
 402           (pred-expr (if (csubtypep (lvar-type pred) (specifier-type 'function))
 403                          'pred
 404                          '(%coerce-callable-to-fun pred))))
 405       (when (member name '(member-if-not assoc-if-not rassoc-if-not))
 406         (setf test-expr `(not ,test-expr)))
 407       (labels ((open-code (tail)
 408                  (when tail
 409                    `(if (let ((this ',(car tail)))
 410                           ,(ecase name
 411                                   ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 412                                    (let ((cxx (if (member name '(assoc-if assoc-if-not)) 'car 'cdr)))
 413                                      `(and this (let ((target (,cxx this)))
 414                                                   ,test-expr))))
 415                                   ((member-if member-if-not)
 416                                    `(let ((target this))
 417                                       ,test-expr))))
 418                         ',(ecase name
 419                                  ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 420                                   (car tail))
 421                                  ((member-if member-if-not)
 422                                   tail))
 423                         ,(open-code (cdr tail))))))
 424         (let* ((cp (constant-lvar-p list))
 425                (c-list (when cp (lvar-value list))))
 426           (cond ((and cp c-list (policy node (>= speed space)))
 427                  `(let ((pred ,pred-expr)
 428                         ,@(when key `((key ,key-form))))
 429                     ,(open-code c-list)))
 430                 ((and cp (not c-list))
 431                  ;; constant nil list -- nothing to find!
 432                  nil)
 433                 (t
 434                  ;; specialized out-of-line version
 435                  `(,(specialized-list-seek-function-name name (when key '(key)))
 436                     ,pred-expr list ,@(when key (list key-form))))))))))
 437
 438 (macrolet ((def (name &optional if/if-not)
 439              `(progn
 440                 (deftransform ,name ((item list &key key test test-not) * * :node node)
 441                   (transform-list-item-seek ',name item list key test test-not node))
 442                 ,@(when if/if-not
 443                    (let ((if-name (symbolicate name "-IF"))
 444                          (if-not-name (symbolicate name "-IF-NOT")))
 445                      `((deftransform ,if-name ((pred list &key key) * * :node node)
 446                          (transform-list-pred-seek ',if-name pred list key node))
 447                        (deftransform ,if-not-name ((pred list &key key) * * :node node)
 448                          (transform-list-pred-seek ',if-not-name pred list key node))))))))
 449   (def adjoin)
 450   (def assoc  t)
 451   (def member t)
 452   (def rassoc t))
 453
 454 (deftransform memq ((item list) (t (constant-arg list)))
 455   (labels ((rec (tail)
 456              (if tail
 457                  `(if (eq item ',(car tail))
 458                       ',tail
 459                       ,(rec (cdr tail)))
 460                  nil)))
 461     (rec (lvar-value list))))
 462
 463 ;;; A similar transform used to apply to MEMBER and ASSOC, but since
 464 ;;; TRANSFORM-LIST-ITEM-SEEK now takes care of them those transform
 465 ;;; would never fire, and (%MEMBER-TEST ITEM LIST #'EQ) should be
 466 ;;; almost as fast as MEMQ.
 467 (deftransform delete ((item list &key test) (t list &rest t) *)
 468   "convert to EQ test"
 469   ;; FIXME: The scope of this transformation could be
 470   ;; widened somewhat, letting it work whenever the test is
 471   ;; 'EQL and we know from the type of ITEM that it #'EQ
 472   ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 473   ;; and SYMBOL.)
 474   ;;   If TEST is EQ, apply transform, else
 475   ;;   if test is not EQL, then give up on transform, else
 476   ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 477   ;;   transform, else give up on transform.
 478   (cond (test
 479          (unless (lvar-fun-is test '(eq))
 480            (give-up-ir1-transform)))
 481         ((types-equal-or-intersect (lvar-type item)
 482                                    (specifier-type 'number))
 483          (give-up-ir1-transform "Item might be a number.")))
 484   `(delq item list))
 485
 486 (deftransform delete-if ((pred list) (t list))
 487   "open code"
 488   '(do ((x list (cdr x))
 489         (splice '()))
 490        ((endp x) list)
 491      (cond ((funcall pred (car x))
 492             (if (null splice)
 493                 (setq list (cdr x))
 494                 (rplacd splice (cdr x))))
 495            (t (setq splice x)))))
 496
 497 (deftransform fill ((seq item &key (start 0) (end nil))
 498                     (list t &key (:start t) (:end t)))
 499   '(list-fill* seq item start end))
 500
 501 (deftransform fill ((seq item &key (start 0) (end nil))
 502                     (vector t &key (:start t) (:end t))
 503                     *
 504                     :node node)
 505   (let ((type (lvar-type seq))
 506         (element-type (type-specifier (extract-upgraded-element-type seq))))
 507     (cond ((and (neq '* element-type) (policy node (> speed space)))
 508            (values
 509             `(with-array-data ((data seq)
 510                                (start start)
 511                                (end end)
 512                                :check-fill-pointer t)
 513                (declare (type (simple-array ,element-type 1) data))
 514                (declare (type index start end))
 515                ;; WITH-ARRAY-DATA did our range checks once and for all, so
 516                ;; it'd be wasteful to check again on every AREF...
 517                (declare (optimize (safety 0) (speed 3)))
 518                (do ((i start (1+ i)))
 519                    ((= i end) seq)
 520                  (declare (type index i))
 521                  (setf (aref data i) item)))
 522             ;; ... though we still need to check that the new element can fit
 523             ;; into the vector in safe code. -- CSR, 2002-07-05
 524             `((declare (type ,element-type item)))))
 525           ((csubtypep type (specifier-type 'string))
 526            '(string-fill* seq item start end))
 527           (t
 528            '(vector-fill* seq item start end)))))
 529
 530 (deftransform fill ((seq item &key (start 0) (end nil))
 531                     ((and sequence (not vector) (not list)) t &key (:start t) (:end t)))
 532   `(sb!sequence:fill seq item
 533                      :start start
 534                      :end (%check-generic-sequence-bounds seq start end)))
 535 \f
 536 ;;;; utilities
 537
 538 ;;; If LVAR is a constant lvar, the return the constant value. If it
 539 ;;; is null, then return default, otherwise quietly give up the IR1
 540 ;;; transform.
 541 ;;;
 542 ;;; ### Probably should take an ARG and flame using the NAME.
 543 (defun constant-value-or-lose (lvar &optional default)
 544   (declare (type (or lvar null) lvar))
 545   (cond ((not lvar) default)
 546         ((constant-lvar-p lvar)
 547          (lvar-value lvar))
 548         (t
 549          (give-up-ir1-transform))))
 550
 551
 552 ;;;; hairy sequence transforms
 553
 554 ;;; FIXME: no hairy sequence transforms in SBCL?
 555 ;;;
 556 ;;; There used to be a bunch of commented out code about here,
 557 ;;; containing the (apparent) beginning of hairy sequence transform
 558 ;;; infrastructure. People interested in implementing better sequence
 559 ;;; transforms might want to look at it for inspiration, even though
 560 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 561 ;;; was deleted in 1.0.7.23.
 562 \f
 563 ;;;; string operations
 564
 565 ;;; We transform the case-sensitive string predicates into a non-keyword
 566 ;;; version. This is an IR1 transform so that we don't have to worry about
 567 ;;; changing the order of evaluation.
 568 (macrolet ((def (fun pred*)
 569              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 570                                                          (start2 0) end2)
 571                                    * *)
 572                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 573   (def string< string<*)
 574   (def string> string>*)
 575   (def string<= string<=*)
 576   (def string>= string>=*)
 577   (def string= string=*)
 578   (def string/= string/=*))
 579
 580 ;;; Return a form that tests the free variables STRING1 and STRING2
 581 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 582 ;;; start and end are also gotten from the environment. Both strings
 583 ;;; must be SIMPLE-BASE-STRINGs.
 584 (macrolet ((def (name lessp equalp)
 585              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 586                                    (simple-base-string simple-base-string t t t t) *)
 587                 `(let* ((end1 (if (not end1) (length string1) end1))
 588                         (end2 (if (not end2) (length string2) end2))
 589                         (index (sb!impl::%sp-string-compare
 590                                 string1 start1 end1 string2 start2 end2)))
 591                   (if index
 592                       (cond ((= index end1)
 593                              ,(if ',lessp 'index nil))
 594                             ((= (+ index (- start2 start1)) end2)
 595                              ,(if ',lessp nil 'index))
 596                             ((,(if ',lessp 'char< 'char>)
 597                                (schar string1 index)
 598                                (schar string2
 599                                       (truly-the index
 600                                                  (+ index
 601                                                     (truly-the fixnum
 602                                                                (- start2
 603                                                                   start1))))))
 604                              index)
 605                             (t nil))
 606                       ,(if ',equalp 'end1 nil))))))
 607   (def string<* t nil)
 608   (def string<=* t t)
 609   (def string>* nil nil)
 610   (def string>=* nil t))
 611
 612 (macrolet ((def (name result-fun)
 613              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 614                                    (simple-base-string simple-base-string t t t t) *)
 615                 `(,',result-fun
 616                   (sb!impl::%sp-string-compare
 617                    string1 start1 (or end1 (length string1))
 618                    string2 start2 (or end2 (length string2)))))))
 619   (def string=* not)
 620   (def string/=* identity))
 621
 622 \f
 623 ;;;; transforms for sequence functions
 624
 625 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 626 ;;; to vectors based on simple arrays.
 627 (def!constant vector-data-bit-offset
 628   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 629
 630 (eval-when (:compile-toplevel)
 631 (defun valid-bit-bash-saetp-p (saetp)
 632   ;; BIT-BASHing isn't allowed on simple vectors that contain pointers
 633   (and (not (eq t (sb!vm:saetp-specifier saetp)))
 634        ;; Disallowing (VECTOR NIL) also means that we won't transform
 635        ;; sequence functions into bit-bashing code and we let the
 636        ;; generic sequence functions signal errors if necessary.
 637        (not (zerop (sb!vm:saetp-n-bits saetp)))
 638        ;; Due to limitations with the current BIT-BASHing code, we can't
 639        ;; BIT-BASH reliably on arrays whose element types are larger
 640        ;; than the word size.
 641        (<= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)))
 642 ) ; EVAL-WHEN
 643
 644 ;;; FIXME: In the copy loops below, we code the loops in a strange
 645 ;;; fashion:
 646 ;;;
 647 ;;; (do ((i (+ src-offset length) (1- i)))
 648 ;;;     ((<= i 0) ...)
 649 ;;;   (... (aref foo (1- i)) ...))
 650 ;;;
 651 ;;; rather than the more natural (and seemingly more efficient):
 652 ;;;
 653 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 654 ;;;     ((< i 0) ...)
 655 ;;;   (... (aref foo i) ...))
 656 ;;;
 657 ;;; (more efficient because we don't have to do the index adjusting on
 658 ;;; every iteration of the loop)
 659 ;;;
 660 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 661 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 662 ;;; when used as an array index, the backend thinks I is a
 663 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 664 ;;; these as distinct storage classes, it cannot coerce a move from a
 665 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 666 ;;; deficiency is that we have two extra moves and increased register
 667 ;;; pressure, which can lead to some spectacularly bad register
 668 ;;; allocation.  (sub-FIXME: the register allocation even with the
 669 ;;; strangely written loops is not always excellent, either...).  Doing
 670 ;;; it the first way, above, means that I is always thought of as a
 671 ;;; POSITIVE-FIXNUM and there are no issues.
 672 ;;;
 673 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 674 ;;; adjustments in the first version into the array addressing at no
 675 ;;; performance penalty!
 676
 677 ;;; This transform is critical to the performance of string streams.  If
 678 ;;; you tweak it, make sure that you compare the disassembly, if not the
 679 ;;; performance of, the functions implementing string streams
 680 ;;; (e.g. SB!IMPL::STRING-OUCH).
 681 (eval-when (:compile-toplevel :load-toplevel :execute)
 682   (defun make-replace-transform (saetp sequence-type1 sequence-type2)
 683     `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 684                             (,sequence-type1 ,sequence-type2 &rest t)
 685                             ,sequence-type1
 686                             :node node)
 687        ,(cond
 688          ((and saetp (valid-bit-bash-saetp-p saetp)) nil)
 689          ;; If the sequence types are different, SEQ1 and SEQ2 must
 690          ;; be distinct arrays, and we can open code the copy loop.
 691          ((not (eql sequence-type1 sequence-type2)) nil)
 692          ;; If we're not bit-bashing, only allow cases where we
 693          ;; can determine the order of copying up front.  (There
 694          ;; are actually more cases we can handle if we know the
 695          ;; amount that we're copying, but this handles the
 696          ;; common cases.)
 697          (t '(unless (= (constant-value-or-lose start1 0)
 698                       (constant-value-or-lose start2 0))
 699               (give-up-ir1-transform))))
 700        `(let* ((len1 (length seq1))
 701                (len2 (length seq2))
 702                (end1 (or end1 len1))
 703                (end2 (or end2 len2))
 704                (replace-len1 (- end1 start1))
 705                (replace-len2 (- end2 start2)))
 706           ,(unless (policy node (= safety 0))
 707              `(progn
 708                  (unless (<= 0 start1 end1 len1)
 709                    (sequence-bounding-indices-bad-error seq1 start1 end1))
 710                  (unless (<= 0 start2 end2 len2)
 711                    (sequence-bounding-indices-bad-error seq2 start2 end2))))
 712           ,',(cond
 713               ((and saetp (valid-bit-bash-saetp-p saetp))
 714                (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 715                       (bash-function (intern (format nil "UB~D-BASH-COPY"
 716                                                      n-element-bits)
 717                                              (find-package "SB!KERNEL"))))
 718                  `(funcall (function ,bash-function) seq2 start2
 719                            seq1 start1 (min replace-len1 replace-len2))))
 720               (t
 721                ;; We can expand the loop inline here because we
 722                ;; would have given up the transform (see above)
 723                ;; if we didn't have constant matching start
 724                ;; indices.
 725                '(do ((i start1 (1+ i))
 726                      (j start2 (1+ j))
 727                      (end (+ start1
 728                              (min replace-len1 replace-len2))))
 729                  ((>= i end))
 730                  (declare (optimize (insert-array-bounds-checks 0)))
 731                  (setf (aref seq1 i) (aref seq2 j)))))
 732           seq1))))
 733
 734 (macrolet
 735     ((define-replace-transforms ()
 736        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 737              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 738              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 739              collect (make-replace-transform saetp sequence-type sequence-type)
 740              into forms
 741              finally (return `(progn ,@forms))))
 742      (define-one-transform (sequence-type1 sequence-type2)
 743        (make-replace-transform nil sequence-type1 sequence-type2)))
 744   (define-replace-transforms)
 745   #!+sb-unicode
 746   (progn
 747    (define-one-transform (simple-array base-char (*)) (simple-array character (*)))
 748    (define-one-transform (simple-array character (*)) (simple-array base-char (*)))))
 749
 750 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 751 ;;; defined as those cases where we are doing word-aligned copies from
 752 ;;; both the source and the destination and we are copying from the same
 753 ;;; offset from both the source and the destination.  (The last
 754 ;;; condition is there so we can determine the direction to copy at
 755 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 756 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 757 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 758 ;;; N)-size buffer and blitting in the old N-size buffer in.
 759
 760 (defun frob-bash-transform (src src-offset
 761                             dst dst-offset
 762                             length n-elems-per-word)
 763   (declare (ignore src dst length))
 764   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 765     (multiple-value-bind (src-word src-elt)
 766         (truncate (lvar-value src-offset) n-elems-per-word)
 767       (multiple-value-bind (dst-word dst-elt)
 768           (truncate (lvar-value dst-offset) n-elems-per-word)
 769         ;; Avoid non-word aligned copies.
 770         (unless (and (zerop src-elt) (zerop dst-elt))
 771           (give-up-ir1-transform))
 772         ;; Avoid copies where we would have to insert code for
 773         ;; determining the direction of copying.
 774         (unless (= src-word dst-word)
 775           (give-up-ir1-transform))
 776         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 777         ;; so we have to do its work here.
 778         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 779                                       'length
 780                                       `(truncate (the index length) ,n-elems-per-word)))))
 781            (declare (type index end))
 782            ;; Handle any bits at the end.
 783            (when (logtest length (1- ,n-elems-per-word))
 784              (let* ((extra (mod length ,n-elems-per-word))
 785                     ;; FIXME: The shift amount on this ASH is
 786                     ;; *always* negative, but the backend doesn't
 787                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 788                     ;; wind up with a pile of code that tests the
 789                     ;; sign of the shift count prior to shifting when
 790                     ;; all we need is a simple negate and shift
 791                     ;; right.  Yuck.
 792                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 793                                (* (- extra ,n-elems-per-word)
 794                                   ,n-bits-per-elem))))
 795                (setf (sb!kernel:%vector-raw-bits dst end)
 796                      (logior
 797                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 798                                 (ash mask
 799                                      ,(ecase sb!c:*backend-byte-order*
 800                                              (:little-endian 0)
 801                                              (:big-endian `(* (- ,n-elems-per-word extra)
 802                                                               ,n-bits-per-elem)))))
 803                       (logand (sb!kernel:%vector-raw-bits src end)
 804                               (ash mask
 805                                    ,(ecase sb!c:*backend-byte-order*
 806                                            (:little-endian 0)
 807                                            (:big-endian `(* (- ,n-elems-per-word extra)
 808                                                             ,n-bits-per-elem)))))))))
 809            ;; Copy from the end to save a register.
 810            (do ((i end (1- i)))
 811                ((<= i ,src-word))
 812              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 813                    (sb!kernel:%vector-raw-bits src (1- i))))
 814            (values))))))
 815
 816 #.(loop for i = 1 then (* i 2)
 817         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 818                                         "SB!KERNEL")
 819                                                         ((src src-offset
 820                                                           dst dst-offset
 821                                                           length)
 822                                                         ((simple-unboxed-array (*))
 823                                                          (constant-arg index)
 824                                                          (simple-unboxed-array (*))
 825                                                          (constant-arg index)
 826                                                          index)
 827                                                         *)
 828                   (frob-bash-transform src src-offset
 829                                        dst dst-offset length
 830                                        ,(truncate sb!vm:n-word-bits i))) into forms
 831         until (= i sb!vm:n-word-bits)
 832         finally (return `(progn ,@forms)))
 833
 834 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 835 ;;; arrays with elements of size >= the word size.  We do this because
 836 ;;; we know the arrays cannot alias (one was just consed), therefore we
 837 ;;; can determine at compile time the direction to copy, and for
 838 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 839 ;;; needless checking to figure out what's going on.  The same
 840 ;;; considerations apply if we are copying elements larger than the word
 841 ;;; size, with the additional twist that doing it inline is likely to
 842 ;;; cons far less than calling REPLACE and letting generic code do the
 843 ;;; work.
 844 ;;;
 845 ;;; However, we do not do this for elements whose size is < than the
 846 ;;; word size because we don't want to deal with any alignment issues
 847 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 848 ;;; anyway.
 849
 850 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 851                                       element-type)
 852   (let ((saetp (find-saetp element-type)))
 853     (aver saetp)
 854     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 855         (expand-aref-copy-loop src src-offset dst dst-offset length)
 856         `(locally (declare (optimize (safety 0)))
 857            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 858
 859 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 860   (if (eql src-offset dst-offset)
 861       `(do ((i (+ ,src-offset ,length) (1- i)))
 862            ((<= i ,src-offset))
 863          (declare (optimize (insert-array-bounds-checks 0)))
 864          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 865       ;; KLUDGE: The compiler is not able to derive that (+ offset
 866       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 867       ;; We, however, know it must be so, as by this point the bounds
 868       ;; have already been checked.
 869       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 870             (j (+ ,dst-offset ,length) (1- j)))
 871            ((<= i ,src-offset))
 872          (declare (optimize (insert-array-bounds-checks 0))
 873                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 874          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 875
 876 ;;; SUBSEQ, COPY-SEQ
 877
 878 (deftransform subseq ((seq start &optional end)
 879                       (vector t &optional t)
 880                       *
 881                       :node node)
 882   (let ((type (lvar-type seq)))
 883     (cond
 884       ((and (array-type-p type)
 885             (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 886        (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 887          `(let* ((length (length seq))
 888                  (end (or end length)))
 889             ,(unless (policy node (zerop insert-array-bounds-checks))
 890                      '(progn
 891                        (unless (<= 0 start end length)
 892                          (sequence-bounding-indices-bad-error seq start end))))
 893             (let* ((size (- end start))
 894                    (result (make-array size :element-type ',element-type)))
 895               ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
 896                                                        (lvar-value start)
 897                                                        'start)
 898                                               'result 0 'size element-type)
 899               result))))
 900       ((csubtypep type (specifier-type 'string))
 901        '(string-subseq* seq start end))
 902       (t
 903        '(vector-subseq* seq start end)))))
 904
 905 (deftransform subseq ((seq start &optional end)
 906                       (list t &optional t))
 907   `(list-subseq* seq start end))
 908
 909 (deftransform subseq ((seq start &optional end)
 910                       ((and sequence (not vector) (not list)) t &optional t))
 911   '(sb!sequence:subseq seq start end))
 912
 913 (deftransform copy-seq ((seq) (vector))
 914   (let ((type (lvar-type seq)))
 915     (cond ((and (array-type-p type)
 916                 (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 917            (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 918              `(let* ((length (length seq))
 919                      (result (make-array length :element-type ',element-type)))
 920                 ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
 921                 result)))
 922           ((csubtypep type (specifier-type 'string))
 923            '(string-subseq* seq 0 nil))
 924           (t
 925            '(vector-subseq* seq 0 nil)))))
 926
 927 (deftransform copy-seq ((seq) (list))
 928   '(list-copy-seq* seq))
 929
 930 (deftransform copy-seq ((seq) ((and sequence (not vector) (not list))))
 931   '(sb!sequence:copy-seq seq))
 932
 933 ;;; FIXME: it really should be possible to take advantage of the
 934 ;;; macros used in code/seq.lisp here to avoid duplication of code,
 935 ;;; and enable even funkier transformations.
 936 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
 937                                (test #'eql)
 938                                (key #'identity)
 939                                from-end)
 940                       (vector vector &rest t)
 941                       *
 942                       :node node
 943                       :policy (> speed (max space safety)))
 944   "open code"
 945   (let ((from-end (when (lvar-p from-end)
 946                     (unless (constant-lvar-p from-end)
 947                       (give-up-ir1-transform ":FROM-END is not constant."))
 948                     (lvar-value from-end)))
 949         (keyp (lvar-p key))
 950         (testp (lvar-p test))
 951         (check-bounds-p (policy node (plusp insert-array-bounds-checks))))
 952     `(block search
 953        (flet ((oops (vector start end)
 954                 (sequence-bounding-indices-bad-error vector start end)))
 955          (let* ((len1 (length pattern))
 956                 (len2 (length text))
 957                 (end1 (or end1 len1))
 958                 (end2 (or end2 len2))
 959                ,@(when keyp
 960                        '((key (coerce key 'function))))
 961                ,@(when testp
 962                        '((test (coerce test 'function)))))
 963           (declare (type index start1 start2 end1 end2))
 964           ,@(when check-bounds-p
 965              `((unless (<= start1 end1 len1)
 966                  (oops pattern start1 end1))
 967                (unless (<= start2 end2 len2)
 968                  (oops pattern start2 end2))))
 969           (do (,(if from-end
 970                     '(index2 (- end2 (- end1 start1)) (1- index2))
 971                     '(index2 start2 (1+ index2))))
 972               (,(if from-end
 973                     '(< index2 start2)
 974                     '(>= index2 end2))
 975                nil)
 976             ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
 977             ;; terminates is hits -1 when :FROM-END is true and :START2
 978             ;; is 0.
 979             (declare (type fixnum index2))
 980             (when (do ((index1 start1 (1+ index1))
 981                        (index2 index2 (1+ index2)))
 982                       ((>= index1 end1) t)
 983                     (declare (type index index1 index2)
 984                              (optimize (insert-array-bounds-checks 0)))
 985                     ,@(unless from-end
 986                               '((when (= index2 end2)
 987                                   (return-from search nil))))
 988                     (unless (,@(if testp
 989                                    '(funcall test)
 990                                    '(eql))
 991                                ,(if keyp
 992                                     '(funcall key (aref pattern index1))
 993                                     '(aref pattern index1))
 994                                ,(if keyp
 995                                     '(funcall key (aref text index2))
 996                                     '(aref text index2)))
 997                       (return nil)))
 998               (return index2))))))))
 999
1000
1001 ;;; Open-code CONCATENATE for strings. It would be possible to extend
1002 ;;; this transform to non-strings, but I chose to just do the case that
1003 ;;; should cover 95% of CONCATENATE performance complaints for now.
1004 ;;;   -- JES, 2007-11-17
1005 (deftransform concatenate ((result-type &rest lvars)
1006                            (symbol &rest sequence)
1007                            *
1008                            :policy (> speed space))
1009   (unless (constant-lvar-p result-type)
1010     (give-up-ir1-transform))
1011   (let* ((element-type (let ((type (lvar-value result-type)))
1012                          ;; Only handle the simple result type cases. If
1013                          ;; somebody does (CONCATENATE '(STRING 6) ...)
1014                          ;; their code won't be optimized, but nobody does
1015                          ;; that in practice.
1016                          (case type
1017                            ((string simple-string) 'character)
1018                            ((base-string simple-base-string) 'base-char)
1019                            (t (give-up-ir1-transform)))))
1020          (vars (loop for x in lvars collect (gensym)))
1021          (lvar-values (loop for lvar in lvars
1022                             collect (when (constant-lvar-p lvar)
1023                                       (lvar-value lvar))))
1024          (lengths
1025           (loop for value in lvar-values
1026                 for var in vars
1027                 collect (if value
1028                             (length value)
1029                             `(sb!impl::string-dispatch ((simple-array * (*))
1030                                                         sequence)
1031                                  ,var
1032                                (declare (muffle-conditions compiler-note))
1033                                (length ,var))))))
1034     `(apply
1035       (lambda ,vars
1036         (declare (ignorable ,@vars))
1037         (let* ((.length. (+ ,@lengths))
1038                (.pos. 0)
1039                (.string. (make-string .length. :element-type ',element-type)))
1040           (declare (type index .length. .pos.)
1041                    (muffle-conditions compiler-note))
1042           ,@(loop for value in lvar-values
1043                   for var in vars
1044                   collect (if (stringp value)
1045                               ;; Fold the array reads for constant arguments
1046                               `(progn
1047                                  ,@(loop for c across value
1048                                          collect `(setf (aref .string.
1049                                                               .pos.) ,c)
1050                                          collect `(incf .pos.)))
1051                               `(sb!impl::string-dispatch
1052                                    (#!+sb-unicode
1053                                     (simple-array character (*))
1054                                     (simple-array base-char (*))
1055                                     t)
1056                                    ,var
1057                                  (replace .string. ,var :start1 .pos.)
1058                                  (incf .pos. (length ,var)))))
1059           .string.))
1060       lvars)))
1061 \f
1062 ;;;; CONS accessor DERIVE-TYPE optimizers
1063
1064 (defoptimizer (car derive-type) ((cons))
1065   (let ((type (lvar-type cons))
1066         (null-type (specifier-type 'null)))
1067     (cond ((eq type null-type)
1068            null-type)
1069           ((cons-type-p type)
1070            (cons-type-car-type type)))))
1071
1072 (defoptimizer (cdr derive-type) ((cons))
1073   (let ((type (lvar-type cons))
1074         (null-type (specifier-type 'null)))
1075     (cond ((eq type null-type)
1076            null-type)
1077           ((cons-type-p type)
1078            (cons-type-cdr-type type)))))
1079 \f
1080 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
1081
1082 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
1083 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
1084 ;;; expansion, so we factor out the condition into this function.
1085 (defun check-inlineability-of-find-position-if (sequence from-end)
1086   (let ((ctype (lvar-type sequence)))
1087     (cond ((csubtypep ctype (specifier-type 'vector))
1088            ;; It's not worth trying to inline vector code unless we
1089            ;; know a fair amount about it at compile time.
1090            (upgraded-element-type-specifier-or-give-up sequence)
1091            (unless (constant-lvar-p from-end)
1092              (give-up-ir1-transform
1093               "FROM-END argument value not known at compile time")))
1094           ((csubtypep ctype (specifier-type 'list))
1095            ;; Inlining on lists is generally worthwhile.
1096            )
1097           (t
1098            (give-up-ir1-transform
1099             "sequence type not known at compile time")))))
1100
1101 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
1102 (macrolet ((def (name condition)
1103              `(deftransform ,name ((predicate sequence from-end start end key)
1104                                    (function list t t t function)
1105                                    *
1106                                    :policy (> speed space))
1107                 "expand inline"
1108                 `(let ((index 0)
1109                        (find nil)
1110                        (position nil))
1111                    (declare (type index index))
1112                    (dolist (i sequence
1113                             (if (and end (> end index))
1114                                 (sequence-bounding-indices-bad-error
1115                                  sequence start end)
1116                                 (values find position)))
1117                      (let ((key-i (funcall key i)))
1118                        (when (and end (>= index end))
1119                          (return (values find position)))
1120                        (when (>= index start)
1121                          (,',condition (funcall predicate key-i)
1122                           ;; This hack of dealing with non-NIL
1123                           ;; FROM-END for list data by iterating
1124                           ;; forward through the list and keeping
1125                           ;; track of the last time we found a match
1126                           ;; might be more screwy than what the user
1127                           ;; expects, but it seems to be allowed by
1128                           ;; the ANSI standard. (And if the user is
1129                           ;; screwy enough to ask for FROM-END
1130                           ;; behavior on list data, turnabout is
1131                           ;; fair play.)
1132                           ;;
1133                           ;; It's also not enormously efficient,
1134                           ;; calling PREDICATE and KEY more often
1135                           ;; than necessary; but all the
1136                           ;; alternatives seem to have their own
1137                           ;; efficiency problems.
1138                           (if from-end
1139                               (setf find i
1140                                     position index)
1141                               (return (values i index))))))
1142                      (incf index))))))
1143   (def %find-position-if when)
1144   (def %find-position-if-not unless))
1145
1146 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
1147 ;;; without loss of efficiency. (I.e., the optimizer should be able
1148 ;;; to straighten everything out.)
1149 (deftransform %find-position ((item sequence from-end start end key test)
1150                               (t list t t t t t)
1151                               *
1152                               :policy (> speed space))
1153   "expand inline"
1154   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
1155                         ;; The order of arguments for asymmetric tests
1156                         ;; (e.g. #'<, as opposed to order-independent
1157                         ;; tests like #'=) is specified in the spec
1158                         ;; section 17.2.1 -- the O/Zi stuff there.
1159                         (lambda (i)
1160                           (funcall test-fun item i)))
1161                       sequence
1162                       from-end
1163                       start
1164                       end
1165                       (%coerce-callable-to-fun key)))
1166
1167 ;;; The inline expansions for the VECTOR case are saved as macros so
1168 ;;; that we can share them between the DEFTRANSFORMs and the default
1169 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
1170 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1171 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1172                                                             from-end
1173                                                             start
1174                                                             end-arg
1175                                                             element
1176                                                             done-p-expr)
1177   (with-unique-names (offset block index n-sequence sequence end)
1178     `(let* ((,n-sequence ,sequence-arg))
1179        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1180                          (,start ,start)
1181                          (,end ,end-arg)
1182                          :check-fill-pointer t)
1183          (block ,block
1184            (macrolet ((maybe-return ()
1185                         ;; WITH-ARRAY-DATA has already performed bounds
1186                         ;; checking, so we can safely elide the checks
1187                         ;; in the inner loop.
1188                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1189                                            (aref ,sequence ,index))))
1190                           (when ,done-p-expr
1191                             (return-from ,block
1192                               (values ,element
1193                                       (- ,index ,offset)))))))
1194              (if ,from-end
1195                  (loop for ,index
1196                        ;; (If we aren't fastidious about declaring that
1197                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1198                        ;; can send us off into never-never land, since
1199                        ;; INDEX is initialized to -1.)
1200                        of-type index-or-minus-1
1201                        from (1- ,end) downto ,start do
1202                        (maybe-return))
1203                  (loop for ,index of-type index from ,start below ,end do
1204                           (maybe-return))))
1205            (values nil nil))))))
1206
1207 (def!macro %find-position-vector-macro (item sequence
1208                                              from-end start end key test)
1209   (with-unique-names (element)
1210     (%find-position-or-find-position-if-vector-expansion
1211      sequence
1212      from-end
1213      start
1214      end
1215      element
1216      ;; (See the LIST transform for a discussion of the correct
1217      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1218      ;; or after the checked sequence element.)
1219      `(funcall ,test ,item (funcall ,key ,element)))))
1220
1221 (def!macro %find-position-if-vector-macro (predicate sequence
1222                                                      from-end start end key)
1223   (with-unique-names (element)
1224     (%find-position-or-find-position-if-vector-expansion
1225      sequence
1226      from-end
1227      start
1228      end
1229      element
1230      `(funcall ,predicate (funcall ,key ,element)))))
1231
1232 (def!macro %find-position-if-not-vector-macro (predicate sequence
1233                                                          from-end start end key)
1234   (with-unique-names (element)
1235     (%find-position-or-find-position-if-vector-expansion
1236      sequence
1237      from-end
1238      start
1239      end
1240      element
1241      `(not (funcall ,predicate (funcall ,key ,element))))))
1242
1243 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1244 ;;; VECTOR data
1245 (deftransform %find-position-if ((predicate sequence from-end start end key)
1246                                  (function vector t t t function)
1247                                  *
1248                                  :policy (> speed space))
1249   "expand inline"
1250   (check-inlineability-of-find-position-if sequence from-end)
1251   '(%find-position-if-vector-macro predicate sequence
1252                                    from-end start end key))
1253
1254 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1255                                      (function vector t t t function)
1256                                      *
1257                                      :policy (> speed space))
1258   "expand inline"
1259   (check-inlineability-of-find-position-if sequence from-end)
1260   '(%find-position-if-not-vector-macro predicate sequence
1261                                        from-end start end key))
1262
1263 (deftransform %find-position ((item sequence from-end start end key test)
1264                               (t vector t t t function function)
1265                               *
1266                               :policy (> speed space))
1267   "expand inline"
1268   (check-inlineability-of-find-position-if sequence from-end)
1269   '(%find-position-vector-macro item sequence
1270     from-end start end key test))
1271
1272 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1273 ;;; POSITION-IF, etc.
1274 (define-source-transform effective-find-position-test (test test-not)
1275   (once-only ((test test)
1276               (test-not test-not))
1277     `(cond
1278       ((and ,test ,test-not)
1279        (error "can't specify both :TEST and :TEST-NOT"))
1280       (,test (%coerce-callable-to-fun ,test))
1281       (,test-not
1282        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1283        ;; inefficient, but since the TEST-NOT option is deprecated
1284        ;; anyway, we don't care.)
1285        (complement (%coerce-callable-to-fun ,test-not)))
1286       (t #'eql))))
1287 (define-source-transform effective-find-position-key (key)
1288   (once-only ((key key))
1289     `(if ,key
1290          (%coerce-callable-to-fun ,key)
1291          #'identity)))
1292
1293 (macrolet ((define-find-position (fun-name values-index)
1294              `(deftransform ,fun-name ((item sequence &key
1295                                              from-end (start 0) end
1296                                              key test test-not)
1297                                        (t (or list vector) &rest t))
1298                 '(nth-value ,values-index
1299                             (%find-position item sequence
1300                                             from-end start
1301                                             end
1302                                             (effective-find-position-key key)
1303                                             (effective-find-position-test
1304                                              test test-not))))))
1305   (define-find-position find 0)
1306   (define-find-position position 1))
1307
1308 (macrolet ((define-find-position-if (fun-name values-index)
1309              `(deftransform ,fun-name ((predicate sequence &key
1310                                                   from-end (start 0)
1311                                                   end key)
1312                                        (t (or list vector) &rest t))
1313                 '(nth-value
1314                   ,values-index
1315                   (%find-position-if (%coerce-callable-to-fun predicate)
1316                                      sequence from-end
1317                                      start end
1318                                      (effective-find-position-key key))))))
1319   (define-find-position-if find-if 0)
1320   (define-find-position-if position-if 1))
1321
1322 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1323 ;;; didn't bother to worry about optimizing them, except note that on
1324 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1325 ;;; sbcl-devel
1326 ;;;
1327 ;;;     My understanding is that while the :test-not argument is
1328 ;;;     deprecated in favour of :test (complement #'foo) because of
1329 ;;;     semantic difficulties (what happens if both :test and :test-not
1330 ;;;     are supplied, etc) the -if-not variants, while officially
1331 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1332 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1333 ;;;     reasons for allowing the -if-not versions equal status,
1334 ;;;     particularly remove-if-not (== filter).
1335 ;;;
1336 ;;;     This is only an informal understanding, I grant you, but
1337 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1338 ;;;     way as the others?
1339 ;;;
1340 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1341 ;;; implementation of SBCL.
1342 (macrolet ((define-find-position-if-not (fun-name values-index)
1343                `(deftransform ,fun-name ((predicate sequence &key
1344                                           from-end (start 0)
1345                                           end key)
1346                                          (t (or list vector) &rest t))
1347                  '(nth-value
1348                    ,values-index
1349                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1350                     sequence from-end
1351                     start end
1352                     (effective-find-position-key key))))))
1353   (define-find-position-if-not find-if-not 0)
1354   (define-find-position-if-not position-if-not 1))
1355
1356 (macrolet ((define-trimmer-transform (fun-name leftp rightp)
1357              `(deftransform ,fun-name ((char-bag string)
1358                                        (t simple-string))
1359                 (let ((find-expr
1360                        (if (constant-lvar-p char-bag)
1361                            ;; If the bag is constant, use MEMBER
1362                            ;; instead of FIND, since we have a
1363                            ;; deftransform for MEMBER that can
1364                            ;; open-code all of the comparisons when
1365                            ;; the list is constant. -- JES, 2007-12-10
1366                            `(not (member (schar string index)
1367                                          ',(coerce (lvar-value char-bag) 'list)
1368                                          :test #'char=))
1369                            '(not (find (schar string index) char-bag :test #'char=)))))
1370                   `(flet ((char-not-in-bag (index)
1371                             ,find-expr))
1372                      (let* ((end (length string))
1373                             (left-end (if ,',leftp
1374                                           (do ((index 0 (1+ index)))
1375                                               ((or (= index (the fixnum end))
1376                                                    (char-not-in-bag index))
1377                                                index)
1378                                             (declare (fixnum index)))
1379                                           0))
1380                             (right-end (if ,',rightp
1381                                            (do ((index (1- end) (1- index)))
1382                                                ((or (< index left-end)
1383                                                     (char-not-in-bag index))
1384                                                 (1+ index))
1385                                              (declare (fixnum index)))
1386                                            end)))
1387                        (if (and (eql left-end 0)
1388                                 (eql right-end (length string)))
1389                            string
1390                            (subseq string left-end right-end))))))))
1391   (define-trimmer-transform string-left-trim t nil)
1392   (define-trimmer-transform string-right-trim nil t)
1393   (define-trimmer-transform string-trim t t))
1394