src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places))
 137     (let ((found-vector-p nil))
 138       (flet ((process-vector (length)
 139                (unless found-vector-p
 140                  (setq found-vector-p t)
 141                  (bindings `(index 0 (1+ index)))
 142                  (declarations `(type index index)))
 143                (vector-lengths length)))
 144         (loop for seq of-type lvar in seqs
 145            for seq-name in seq-names
 146            for type = (lvar-type seq)
 147            do (cond ((csubtypep type (specifier-type 'list))
 148                      (with-unique-names (index)
 149                        (bindings `(,index ,seq-name (cdr ,index)))
 150                        (declarations `(type list ,index))
 151                        (places `(car ,index))
 152                        (tests `(endp ,index))))
 153                     ((csubtypep type (specifier-type 'vector))
 154                      (process-vector `(length ,seq-name))
 155                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 156                                 (aref ,seq-name index))))
 157                     (t
 158                      (give-up-ir1-transform
 159                       "can't determine sequence argument type"))))
 160         (when into
 161           (process-vector `(array-dimension ,into 0))))
 162       (when found-vector-p
 163         (bindings `(length (min ,@(vector-lengths))))
 164         (tests `(>= index length)))
 165       `(do (,@(bindings))
 166            ((or ,@(tests)) ,result)
 167          (declare ,@(declarations))
 168          (let ((funcall-result (funcall fun ,@(places))))
 169            (declare (ignorable funcall-result))
 170            ,body)))))
 171
 172 ;;; Try to compile %MAP efficiently when we can determine sequence
 173 ;;; argument types at compile time.
 174 ;;;
 175 ;;; Note: This transform was written to allow open coding of
 176 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 177 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 178 ;;; necessarily as efficient as possible. In particular, it will be
 179 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 180 ;;; numeric element types. It should be straightforward to make it
 181 ;;; handle that case more efficiently, but it's left as an exercise to
 182 ;;; the reader, because the code is complicated enough already and I
 183 ;;; don't happen to need that functionality right now. -- WHN 20000410
 184 (deftransform %map ((result-type fun seq &rest seqs) * *
 185                     :policy (>= speed space))
 186   "open code"
 187   (unless (constant-lvar-p result-type)
 188     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 189   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 190            (fn-1subtypep (fn x y)
 191              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 192                (if valid-p
 193                    subtype-p
 194                    (give-up-ir1-transform
 195                     "can't analyze sequence type relationship"))))
 196            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 197     (let* ((result-type-value (lvar-value result-type))
 198            (result-supertype (cond ((null result-type-value) 'null)
 199                                    ((1subtypep result-type-value 'vector)
 200                                     'vector)
 201                                    ((1subtypep result-type-value 'list)
 202                                     'list)
 203                                    (t
 204                                     (give-up-ir1-transform
 205                                      "result type unsuitable")))))
 206       (cond ((and result-type-value (null seqs))
 207              ;; The consing arity-1 cases can be implemented
 208              ;; reasonably efficiently as function calls, and the cost
 209              ;; of consing should be significantly larger than
 210              ;; function call overhead, so we always compile these
 211              ;; cases as full calls regardless of speed-versus-space
 212              ;; optimization policy.
 213              (cond ((subtypep result-type-value 'list)
 214                     '(%map-to-list-arity-1 fun seq))
 215                    ( ;; (This one can be inefficient due to COERCE, but
 216                     ;; the current open-coded implementation has the
 217                     ;; same problem.)
 218                     (subtypep result-type-value 'vector)
 219                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 220                              ',result-type-value))
 221                    (t (bug "impossible (?) sequence type"))))
 222             (t
 223              (let* ((seqs (cons seq seqs))
 224                     (seq-args (make-gensym-list (length seqs))))
 225                (multiple-value-bind (push-dacc result)
 226                    (ecase result-supertype
 227                      (null (values nil nil))
 228                      (list (values `(push funcall-result acc)
 229                                    `(nreverse acc)))
 230                      (vector (values `(push funcall-result acc)
 231                                      `(coerce (nreverse acc)
 232                                               ',result-type-value))))
 233                  ;; (We use the same idiom, of returning a LAMBDA from
 234                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 235                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 236                  ;; reason: we need to get the runtime values of each
 237                  ;; of the &REST vars.)
 238                  `(lambda (result-type fun ,@seq-args)
 239                     (declare (ignore result-type))
 240                     (let ((fun (%coerce-callable-to-fun fun))
 241                           (acc nil))
 242                       (declare (type list acc))
 243                       (declare (ignorable acc))
 244                       ,(build-sequence-iterator
 245                         seqs seq-args
 246                         :result result
 247                         :body push-dacc))))))))))
 248
 249 ;;; MAP-INTO
 250 (deftransform map-into ((result fun &rest seqs)
 251                         (vector * &rest *)
 252                         *)
 253   "open code"
 254   (let ((seqs-names (mapcar (lambda (x)
 255                               (declare (ignore x))
 256                               (gensym))
 257                             seqs)))
 258     `(lambda (result fun ,@seqs-names)
 259        ,(build-sequence-iterator
 260          seqs seqs-names
 261          :result '(when (array-has-fill-pointer-p result)
 262                    (setf (fill-pointer result) index))
 263          :into 'result
 264          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 265                  (setf (aref result index) funcall-result)))
 266        result)))
 267
 268 \f
 269 ;;; FIXME: once the confusion over doing transforms with known-complex
 270 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 271 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 272 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 273   '(aref s i))
 274
 275 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 276   '(nth i s))
 277
 278 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 279   '(%aset s i v))
 280
 281 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 282   '(setf (car (nthcdr i s)) v))
 283
 284 (deftransform %check-vector-sequence-bounds ((vector start end)
 285                                              (vector * *) *
 286                                              :node node)
 287   (if (policy node (= 0 insert-array-bounds-checks))
 288       '(or end (length vector))
 289       '(let ((length (length vector)))
 290          (if (<= 0 start (or end length) length)
 291              (or end length)
 292              (sequence-bounding-indices-bad-error vector start end)))))
 293
 294 (defun specialized-list-seek-function-name (function-name key-functions)
 295   (or (find-symbol (with-output-to-string (s)
 296                      ;; Write "%NAME-FUN1-FUN2-FUN3", etc. Not only is
 297                      ;; this ever so slightly faster then FORMAT, this
 298                      ;; way we are also proof against *PRINT-CASE*
 299                      ;; frobbing and such.
 300                      (write-char #\% s)
 301                      (write-string (symbol-name function-name) s)
 302                      (dolist (f key-functions)
 303                        (write-char #\- s)
 304                        (write-string (symbol-name f) s)))
 305                    (load-time-value (find-package "SB!KERNEL")))
 306       (bug "Unknown list item seek transform: name=~S, key-functions=~S"
 307            function-name key-functions)))
 308
 309 (defun transform-list-item-seek (name list key test test-not node)
 310   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 311   ;; not there at all. If it might be NIL, make up a form to that
 312   ;; ensure it is a function.
 313   (multiple-value-bind (key key-form)
 314       (if key
 315           (let ((key-type (lvar-type key))
 316                 (null-type (specifier-type 'null)))
 317             (cond ((csubtypep key-type null-type)
 318                    (values nil nil))
 319                   ((csubtypep null-type key-type)
 320                    (values key '(if key
 321                                  (%coerce-callable-to-fun key)
 322                                  #'identity)))
 323                   (t
 324                    (values key '(%coerce-callable-to-fun key))))))
 325     (let* ((funs (remove nil (list (and key 'key) (cond (test 'test)
 326                                                         (test-not 'test-not)))))
 327            (target-expr (if key '(%funcall key target) 'target))
 328            (test-expr (cond (test `(%funcall test item ,target-expr))
 329                             (test-not `(not (%funcall test-not item ,target-expr)))
 330                             (t `(eql item ,target-expr)))))
 331       (labels ((open-code (tail)
 332                  (when tail
 333                    `(if (let ((this ',(car tail)))
 334                           ,(ecase name
 335                                   (assoc
 336                                    `(and this (let ((target (car this)))
 337                                                 ,test-expr)))
 338                                   (member
 339                                    `(let ((target this))
 340                                       ,test-expr))))
 341                         ',(ecase name
 342                                  (assoc (car tail))
 343                                  (member tail))
 344                         ,(open-code (cdr tail)))))
 345                (ensure-fun (fun)
 346                  (if (eq 'key fun)
 347                      key-form
 348                      `(%coerce-callable-to-fun ,fun))))
 349         (let* ((cp (constant-lvar-p list))
 350                (c-list (when cp (lvar-value list))))
 351           (cond ((and cp c-list (policy node (>= speed space)))
 352                  `(let ,(mapcar (lambda (fun) `(,fun ,(ensure-fun fun))) funs)
 353                     ,(open-code c-list)))
 354                 ((and cp (not c-list))
 355                  ;; constant nil list -- nothing to find!
 356                  nil)
 357                 (t
 358                  ;; specialized out-of-line version
 359                  `(,(specialized-list-seek-function-name name funs)
 360                     item list ,@(mapcar #'ensure-fun funs)))))))))
 361
 362 (deftransform member ((item list &key key test test-not) * * :node node)
 363   (transform-list-item-seek 'member list key test test-not node))
 364
 365 (deftransform assoc ((item list &key key test test-not) * * :node node)
 366   (transform-list-item-seek 'assoc list key test test-not node))
 367
 368 (deftransform memq ((item list) (t (constant-arg list)))
 369   (labels ((rec (tail)
 370              (if tail
 371                  `(if (eq item ',(car tail))
 372                       ',tail
 373                       ,(rec (cdr tail)))
 374                  nil)))
 375     (rec (lvar-value list))))
 376
 377 ;;; A similar transform used to apply to MEMBER and ASSOC, but since
 378 ;;; TRANSFORM-LIST-ITEM-SEEK now takes care of them those transform
 379 ;;; would never fire, and (%MEMBER-TEST ITEM LIST #'EQ) should be
 380 ;;; almost as fast as MEMQ.
 381 (deftransform delete ((item list &key test) (t list &rest t) *)
 382   "convert to EQ test"
 383   ;; FIXME: The scope of this transformation could be
 384   ;; widened somewhat, letting it work whenever the test is
 385   ;; 'EQL and we know from the type of ITEM that it #'EQ
 386   ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 387   ;; and SYMBOL.)
 388   ;;   If TEST is EQ, apply transform, else
 389   ;;   if test is not EQL, then give up on transform, else
 390   ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 391   ;;   transform, else give up on transform.
 392   (cond (test
 393          (unless (lvar-fun-is test '(eq))
 394            (give-up-ir1-transform)))
 395         ((types-equal-or-intersect (lvar-type item)
 396                                    (specifier-type 'number))
 397          (give-up-ir1-transform "Item might be a number.")))
 398   `(delq item list))
 399
 400 (deftransform delete-if ((pred list) (t list))
 401   "open code"
 402   '(do ((x list (cdr x))
 403         (splice '()))
 404        ((endp x) list)
 405      (cond ((funcall pred (car x))
 406             (if (null splice)
 407                 (setq list (cdr x))
 408                 (rplacd splice (cdr x))))
 409            (t (setq splice x)))))
 410
 411 (deftransform fill ((seq item &key (start 0) (end nil))
 412                     (list t &key (:start t) (:end t)))
 413   '(list-fill* seq item start end))
 414
 415 (deftransform fill ((seq item &key (start 0) (end nil))
 416                     (vector t &key (:start t) (:end t))
 417                     *
 418                     :node node)
 419   (let ((type (lvar-type seq))
 420         (element-type (type-specifier (extract-upgraded-element-type seq))))
 421     (cond ((and (neq '* element-type) (policy node (> speed space)))
 422            (values
 423             `(with-array-data ((data seq)
 424                                (start start)
 425                                (end end)
 426                                :check-fill-pointer t)
 427                (declare (type (simple-array ,element-type 1) data))
 428                (declare (type index start end))
 429                ;; WITH-ARRAY-DATA did our range checks once and for all, so
 430                ;; it'd be wasteful to check again on every AREF...
 431                (declare (optimize (safety 0) (speed 3)))
 432                (do ((i start (1+ i)))
 433                    ((= i end) seq)
 434                  (declare (type index i))
 435                  (setf (aref data i) item)))
 436             ;; ... though we still need to check that the new element can fit
 437             ;; into the vector in safe code. -- CSR, 2002-07-05
 438             `((declare (type ,element-type item)))))
 439           ((csubtypep type (specifier-type 'string))
 440            '(string-fill* seq item start end))
 441           (t
 442            '(vector-fill* seq item start end)))))
 443
 444 (deftransform fill ((seq item &key (start 0) (end nil))
 445                     ((and sequence (not vector) (not list)) t &key (:start t) (:end t)))
 446   `(sb!sequence:fill seq item
 447                      :start start
 448                      :end (%check-generic-sequence-bounds seq start end)))
 449 \f
 450 ;;;; utilities
 451
 452 ;;; Return true if LVAR's only use is a non-NOTINLINE reference to a
 453 ;;; global function with one of the specified NAMES.
 454 (defun lvar-fun-is (lvar names)
 455   (declare (type lvar lvar) (list names))
 456   (let ((use (lvar-uses lvar)))
 457     (and (ref-p use)
 458          (let ((leaf (ref-leaf use)))
 459            (and (global-var-p leaf)
 460                 (eq (global-var-kind leaf) :global-function)
 461                 (not (null (member (leaf-source-name leaf) names
 462                                    :test #'equal))))))))
 463
 464 ;;; If LVAR is a constant lvar, the return the constant value. If it
 465 ;;; is null, then return default, otherwise quietly give up the IR1
 466 ;;; transform.
 467 ;;;
 468 ;;; ### Probably should take an ARG and flame using the NAME.
 469 (defun constant-value-or-lose (lvar &optional default)
 470   (declare (type (or lvar null) lvar))
 471   (cond ((not lvar) default)
 472         ((constant-lvar-p lvar)
 473          (lvar-value lvar))
 474         (t
 475          (give-up-ir1-transform))))
 476
 477
 478 ;;;; hairy sequence transforms
 479
 480 ;;; FIXME: no hairy sequence transforms in SBCL?
 481 ;;;
 482 ;;; There used to be a bunch of commented out code about here,
 483 ;;; containing the (apparent) beginning of hairy sequence transform
 484 ;;; infrastructure. People interested in implementing better sequence
 485 ;;; transforms might want to look at it for inspiration, even though
 486 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 487 ;;; was deleted in 1.0.7.23.
 488 \f
 489 ;;;; string operations
 490
 491 ;;; We transform the case-sensitive string predicates into a non-keyword
 492 ;;; version. This is an IR1 transform so that we don't have to worry about
 493 ;;; changing the order of evaluation.
 494 (macrolet ((def (fun pred*)
 495              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 496                                                          (start2 0) end2)
 497                                    * *)
 498                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 499   (def string< string<*)
 500   (def string> string>*)
 501   (def string<= string<=*)
 502   (def string>= string>=*)
 503   (def string= string=*)
 504   (def string/= string/=*))
 505
 506 ;;; Return a form that tests the free variables STRING1 and STRING2
 507 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 508 ;;; start and end are also gotten from the environment. Both strings
 509 ;;; must be SIMPLE-BASE-STRINGs.
 510 (macrolet ((def (name lessp equalp)
 511              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 512                                    (simple-base-string simple-base-string t t t t) *)
 513                 `(let* ((end1 (if (not end1) (length string1) end1))
 514                         (end2 (if (not end2) (length string2) end2))
 515                         (index (sb!impl::%sp-string-compare
 516                                 string1 start1 end1 string2 start2 end2)))
 517                   (if index
 518                       (cond ((= index end1)
 519                              ,(if ',lessp 'index nil))
 520                             ((= (+ index (- start2 start1)) end2)
 521                              ,(if ',lessp nil 'index))
 522                             ((,(if ',lessp 'char< 'char>)
 523                                (schar string1 index)
 524                                (schar string2
 525                                       (truly-the index
 526                                                  (+ index
 527                                                     (truly-the fixnum
 528                                                                (- start2
 529                                                                   start1))))))
 530                              index)
 531                             (t nil))
 532                       ,(if ',equalp 'end1 nil))))))
 533   (def string<* t nil)
 534   (def string<=* t t)
 535   (def string>* nil nil)
 536   (def string>=* nil t))
 537
 538 (macrolet ((def (name result-fun)
 539              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 540                                    (simple-base-string simple-base-string t t t t) *)
 541                 `(,',result-fun
 542                   (sb!impl::%sp-string-compare
 543                    string1 start1 (or end1 (length string1))
 544                    string2 start2 (or end2 (length string2)))))))
 545   (def string=* not)
 546   (def string/=* identity))
 547
 548 \f
 549 ;;;; transforms for sequence functions
 550
 551 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 552 ;;; to vectors based on simple arrays.
 553 (def!constant vector-data-bit-offset
 554   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 555
 556 (eval-when (:compile-toplevel)
 557 (defun valid-bit-bash-saetp-p (saetp)
 558   ;; BIT-BASHing isn't allowed on simple vectors that contain pointers
 559   (and (not (eq t (sb!vm:saetp-specifier saetp)))
 560        ;; Disallowing (VECTOR NIL) also means that we won't transform
 561        ;; sequence functions into bit-bashing code and we let the
 562        ;; generic sequence functions signal errors if necessary.
 563        (not (zerop (sb!vm:saetp-n-bits saetp)))
 564        ;; Due to limitations with the current BIT-BASHing code, we can't
 565        ;; BIT-BASH reliably on arrays whose element types are larger
 566        ;; than the word size.
 567        (<= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)))
 568 ) ; EVAL-WHEN
 569
 570 ;;; FIXME: In the copy loops below, we code the loops in a strange
 571 ;;; fashion:
 572 ;;;
 573 ;;; (do ((i (+ src-offset length) (1- i)))
 574 ;;;     ((<= i 0) ...)
 575 ;;;   (... (aref foo (1- i)) ...))
 576 ;;;
 577 ;;; rather than the more natural (and seemingly more efficient):
 578 ;;;
 579 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 580 ;;;     ((< i 0) ...)
 581 ;;;   (... (aref foo i) ...))
 582 ;;;
 583 ;;; (more efficient because we don't have to do the index adjusting on
 584 ;;; every iteration of the loop)
 585 ;;;
 586 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 587 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 588 ;;; when used as an array index, the backend thinks I is a
 589 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 590 ;;; these as distinct storage classes, it cannot coerce a move from a
 591 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 592 ;;; deficiency is that we have two extra moves and increased register
 593 ;;; pressure, which can lead to some spectacularly bad register
 594 ;;; allocation.  (sub-FIXME: the register allocation even with the
 595 ;;; strangely written loops is not always excellent, either...).  Doing
 596 ;;; it the first way, above, means that I is always thought of as a
 597 ;;; POSITIVE-FIXNUM and there are no issues.
 598 ;;;
 599 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 600 ;;; adjustments in the first version into the array addressing at no
 601 ;;; performance penalty!
 602
 603 ;;; This transform is critical to the performance of string streams.  If
 604 ;;; you tweak it, make sure that you compare the disassembly, if not the
 605 ;;; performance of, the functions implementing string streams
 606 ;;; (e.g. SB!IMPL::STRING-OUCH).
 607 (eval-when (:compile-toplevel :load-toplevel :execute)
 608   (defun make-replace-transform (saetp sequence-type1 sequence-type2)
 609     `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 610                             (,sequence-type1 ,sequence-type2 &rest t)
 611                             ,sequence-type1
 612                             :node node)
 613        ,(cond
 614          ((and saetp (valid-bit-bash-saetp-p saetp)) nil)
 615          ;; If the sequence types are different, SEQ1 and SEQ2 must
 616          ;; be distinct arrays, and we can open code the copy loop.
 617          ((not (eql sequence-type1 sequence-type2)) nil)
 618          ;; If we're not bit-bashing, only allow cases where we
 619          ;; can determine the order of copying up front.  (There
 620          ;; are actually more cases we can handle if we know the
 621          ;; amount that we're copying, but this handles the
 622          ;; common cases.)
 623          (t '(unless (= (constant-value-or-lose start1 0)
 624                       (constant-value-or-lose start2 0))
 625               (give-up-ir1-transform))))
 626        `(let* ((len1 (length seq1))
 627                (len2 (length seq2))
 628                (end1 (or end1 len1))
 629                (end2 (or end2 len2))
 630                (replace-len1 (- end1 start1))
 631                (replace-len2 (- end2 start2)))
 632           ,(unless (policy node (= safety 0))
 633              `(progn
 634                  (unless (<= 0 start1 end1 len1)
 635                    (sequence-bounding-indices-bad-error seq1 start1 end1))
 636                  (unless (<= 0 start2 end2 len2)
 637                    (sequence-bounding-indices-bad-error seq2 start2 end2))))
 638           ,',(cond
 639               ((and saetp (valid-bit-bash-saetp-p saetp))
 640                (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 641                       (bash-function (intern (format nil "UB~D-BASH-COPY"
 642                                                      n-element-bits)
 643                                              (find-package "SB!KERNEL"))))
 644                  `(funcall (function ,bash-function) seq2 start2
 645                            seq1 start1 (min replace-len1 replace-len2))))
 646               (t
 647                ;; We can expand the loop inline here because we
 648                ;; would have given up the transform (see above)
 649                ;; if we didn't have constant matching start
 650                ;; indices.
 651                '(do ((i start1 (1+ i))
 652                      (j start2 (1+ j))
 653                      (end (+ start1
 654                              (min replace-len1 replace-len2))))
 655                  ((>= i end))
 656                  (declare (optimize (insert-array-bounds-checks 0)))
 657                  (setf (aref seq1 i) (aref seq2 j)))))
 658           seq1))))
 659
 660 (macrolet
 661     ((define-replace-transforms ()
 662        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 663              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 664              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 665              collect (make-replace-transform saetp sequence-type sequence-type)
 666              into forms
 667              finally (return `(progn ,@forms))))
 668      (define-one-transform (sequence-type1 sequence-type2)
 669        (make-replace-transform nil sequence-type1 sequence-type2)))
 670   (define-replace-transforms)
 671   (define-one-transform simple-base-string (simple-array character (*)))
 672   (define-one-transform (simple-array character (*)) simple-base-string))
 673
 674 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 675 ;;; defined as those cases where we are doing word-aligned copies from
 676 ;;; both the source and the destination and we are copying from the same
 677 ;;; offset from both the source and the destination.  (The last
 678 ;;; condition is there so we can determine the direction to copy at
 679 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 680 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 681 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 682 ;;; N)-size buffer and blitting in the old N-size buffer in.
 683
 684 (defun frob-bash-transform (src src-offset
 685                             dst dst-offset
 686                             length n-elems-per-word)
 687   (declare (ignore src dst length))
 688   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 689     (multiple-value-bind (src-word src-elt)
 690         (truncate (lvar-value src-offset) n-elems-per-word)
 691       (multiple-value-bind (dst-word dst-elt)
 692           (truncate (lvar-value dst-offset) n-elems-per-word)
 693         ;; Avoid non-word aligned copies.
 694         (unless (and (zerop src-elt) (zerop dst-elt))
 695           (give-up-ir1-transform))
 696         ;; Avoid copies where we would have to insert code for
 697         ;; determining the direction of copying.
 698         (unless (= src-word dst-word)
 699           (give-up-ir1-transform))
 700         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 701         ;; so we have to do its work here.
 702         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 703                                       'length
 704                                       `(truncate (the index length) ,n-elems-per-word)))))
 705            (declare (type index end))
 706            ;; Handle any bits at the end.
 707            (when (logtest length (1- ,n-elems-per-word))
 708              (let* ((extra (mod length ,n-elems-per-word))
 709                     ;; FIXME: The shift amount on this ASH is
 710                     ;; *always* negative, but the backend doesn't
 711                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 712                     ;; wind up with a pile of code that tests the
 713                     ;; sign of the shift count prior to shifting when
 714                     ;; all we need is a simple negate and shift
 715                     ;; right.  Yuck.
 716                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 717                                (* (- extra ,n-elems-per-word)
 718                                   ,n-bits-per-elem))))
 719                (setf (sb!kernel:%vector-raw-bits dst end)
 720                      (logior
 721                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 722                                 (ash mask
 723                                      ,(ecase sb!c:*backend-byte-order*
 724                                              (:little-endian 0)
 725                                              (:big-endian `(* (- ,n-elems-per-word extra)
 726                                                               ,n-bits-per-elem)))))
 727                       (logand (sb!kernel:%vector-raw-bits src end)
 728                               (ash mask
 729                                    ,(ecase sb!c:*backend-byte-order*
 730                                            (:little-endian 0)
 731                                            (:big-endian `(* (- ,n-elems-per-word extra)
 732                                                             ,n-bits-per-elem)))))))))
 733            ;; Copy from the end to save a register.
 734            (do ((i end (1- i)))
 735                ((<= i ,src-word))
 736              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 737                    (sb!kernel:%vector-raw-bits src (1- i)))))))))
 738
 739 #.(loop for i = 1 then (* i 2)
 740         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 741                                         "SB!KERNEL")
 742                                                         ((src src-offset
 743                                                           dst dst-offset
 744                                                           length)
 745                                                         ((simple-unboxed-array (*))
 746                                                          (constant-arg index)
 747                                                          (simple-unboxed-array (*))
 748                                                          (constant-arg index)
 749                                                          index)
 750                                                         *)
 751                   (frob-bash-transform src src-offset
 752                                        dst dst-offset length
 753                                        ,(truncate sb!vm:n-word-bits i))) into forms
 754         until (= i sb!vm:n-word-bits)
 755         finally (return `(progn ,@forms)))
 756
 757 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 758 ;;; arrays with elements of size >= the word size.  We do this because
 759 ;;; we know the arrays cannot alias (one was just consed), therefore we
 760 ;;; can determine at compile time the direction to copy, and for
 761 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 762 ;;; needless checking to figure out what's going on.  The same
 763 ;;; considerations apply if we are copying elements larger than the word
 764 ;;; size, with the additional twist that doing it inline is likely to
 765 ;;; cons far less than calling REPLACE and letting generic code do the
 766 ;;; work.
 767 ;;;
 768 ;;; However, we do not do this for elements whose size is < than the
 769 ;;; word size because we don't want to deal with any alignment issues
 770 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 771 ;;; anyway.
 772
 773 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 774                                       element-type)
 775   (let ((saetp (find-saetp element-type)))
 776     (aver saetp)
 777     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 778         (expand-aref-copy-loop src src-offset dst dst-offset length)
 779         `(locally (declare (optimize (safety 0)))
 780            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 781
 782 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 783   (if (eql src-offset dst-offset)
 784       `(do ((i (+ ,src-offset ,length) (1- i)))
 785            ((<= i ,src-offset))
 786          (declare (optimize (insert-array-bounds-checks 0)))
 787          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 788       ;; KLUDGE: The compiler is not able to derive that (+ offset
 789       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 790       ;; We, however, know it must be so, as by this point the bounds
 791       ;; have already been checked.
 792       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 793             (j (+ ,dst-offset ,length) (1- j)))
 794            ((<= i ,src-offset))
 795          (declare (optimize (insert-array-bounds-checks 0))
 796                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 797          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 798
 799 ;;; SUBSEQ, COPY-SEQ
 800
 801 (deftransform subseq ((seq start &optional end)
 802                       (vector t &optional t)
 803                       *
 804                       :node node)
 805   (let ((type (lvar-type seq)))
 806     (cond
 807       ((and (array-type-p type)
 808             (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 809        (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 810          `(let* ((length (length seq))
 811                  (end (or end length)))
 812             ,(unless (policy node (zerop insert-array-bounds-checks))
 813                      '(progn
 814                        (unless (<= 0 start end length)
 815                          (sequence-bounding-indices-bad-error seq start end))))
 816             (let* ((size (- end start))
 817                    (result (make-array size :element-type ',element-type)))
 818               ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
 819                                                        (lvar-value start)
 820                                                        'start)
 821                                               'result 0 'size element-type)
 822               result))))
 823       ((csubtypep type (specifier-type 'string))
 824        '(string-subseq* seq start end))
 825       (t
 826        '(vector-subseq* seq start end)))))
 827
 828 (deftransform subseq ((seq start &optional end)
 829                       (list t &optional t))
 830   `(list-subseq* seq start end))
 831
 832 (deftransform subseq ((seq start &optional end)
 833                       ((and sequence (not vector) (not list)) t &optional t))
 834   '(sb!sequence:subseq seq start end))
 835
 836 (deftransform copy-seq ((seq) (vector))
 837   (let ((type (lvar-type seq)))
 838     (cond ((and (array-type-p type)
 839                 (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 840            (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 841              `(let* ((length (length seq))
 842                      (result (make-array length :element-type ',element-type)))
 843                 ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
 844                 result)))
 845           ((csubtypep type (specifier-type 'string))
 846            '(string-subseq* seq 0 nil))
 847           (t
 848            '(vector-subseq* seq 0 nil)))))
 849
 850 (deftransform copy-seq ((seq) (list))
 851   '(list-copy-seq* seq))
 852
 853 (deftransform copy-seq ((seq) ((and sequence (not vector) (not list))))
 854   '(sb!sequence:copy-seq seq))
 855
 856 ;;; FIXME: it really should be possible to take advantage of the
 857 ;;; macros used in code/seq.lisp here to avoid duplication of code,
 858 ;;; and enable even funkier transformations.
 859 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
 860                                (test #'eql)
 861                                (key #'identity)
 862                                from-end)
 863                       (vector vector &rest t)
 864                       *
 865                       :node node
 866                       :policy (> speed (max space safety)))
 867   "open code"
 868   (let ((from-end (when (lvar-p from-end)
 869                     (unless (constant-lvar-p from-end)
 870                       (give-up-ir1-transform ":FROM-END is not constant."))
 871                     (lvar-value from-end)))
 872         (keyp (lvar-p key))
 873         (testp (lvar-p test))
 874         (check-bounds-p (policy node (plusp insert-array-bounds-checks))))
 875     `(block search
 876        (flet ((oops (vector start end)
 877                 (sequence-bounding-indices-bad-error vector start end)))
 878          (let* ((len1 (length pattern))
 879                 (len2 (length text))
 880                 (end1 (or end1 len1))
 881                 (end2 (or end2 len2))
 882                ,@(when keyp
 883                        '((key (coerce key 'function))))
 884                ,@(when testp
 885                        '((test (coerce test 'function)))))
 886           (declare (type index start1 start2 end1 end2))
 887           ,@(when check-bounds-p
 888              `((unless (<= start1 end1 len1)
 889                  (oops pattern start1 end1))
 890                (unless (<= start2 end2 len2)
 891                  (oops pattern start2 end2))))
 892           (do (,(if from-end
 893                     '(index2 (- end2 (- end1 start1)) (1- index2))
 894                     '(index2 start2 (1+ index2))))
 895               (,(if from-end
 896                     '(< index2 start2)
 897                     '(>= index2 end2))
 898                nil)
 899             ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
 900             ;; terminates is hits -1 when :FROM-END is true and :START2
 901             ;; is 0.
 902             (declare (type fixnum index2))
 903             (when (do ((index1 start1 (1+ index1))
 904                        (index2 index2 (1+ index2)))
 905                       ((>= index1 end1) t)
 906                     (declare (type index index1 index2)
 907                              (optimize (insert-array-bounds-checks 0)))
 908                     ,@(unless from-end
 909                               '((when (= index2 end2)
 910                                   (return-from search nil))))
 911                     (unless (,@(if testp
 912                                    '(funcall test)
 913                                    '(eql))
 914                                ,(if keyp
 915                                     '(funcall key (aref pattern index1))
 916                                     '(aref pattern index1))
 917                                ,(if keyp
 918                                     '(funcall key (aref text index2))
 919                                     '(aref text index2)))
 920                       (return nil)))
 921               (return index2))))))))
 922
 923
 924 ;;; Open-code CONCATENATE for strings. It would be possible to extend
 925 ;;; this transform to non-strings, but I chose to just do the case that
 926 ;;; should cover 95% of CONCATENATE performance complaints for now.
 927 ;;;   -- JES, 2007-11-17
 928 (deftransform concatenate ((result-type &rest lvars)
 929                            (symbol &rest sequence)
 930                            *
 931                            :policy (> speed space))
 932   (unless (constant-lvar-p result-type)
 933     (give-up-ir1-transform))
 934   (let* ((element-type (let ((type (lvar-value result-type)))
 935                          ;; Only handle the simple result type cases. If
 936                          ;; somebody does (CONCATENATE '(STRING 6) ...)
 937                          ;; their code won't be optimized, but nobody does
 938                          ;; that in practice.
 939                          (case type
 940                            ((string simple-string) 'character)
 941                            ((base-string simple-base-string) 'base-char)
 942                            (t (give-up-ir1-transform)))))
 943          (vars (loop for x in lvars collect (gensym)))
 944          (lvar-values (loop for lvar in lvars
 945                             collect (when (constant-lvar-p lvar)
 946                                       (lvar-value lvar))))
 947          (lengths
 948           (loop for value in lvar-values
 949                 for var in vars
 950                 collect (if value
 951                             (length value)
 952                             `(sb!impl::string-dispatch ((simple-array * (*))
 953                                                         sequence)
 954                                  ,var
 955                                (declare (muffle-conditions compiler-note))
 956                                (length ,var))))))
 957     `(apply
 958       (lambda ,vars
 959         (declare (ignorable ,@vars))
 960         (let* ((.length. (+ ,@lengths))
 961                (.pos. 0)
 962                (.string. (make-string .length. :element-type ',element-type)))
 963           (declare (type index .length. .pos.)
 964                    (muffle-conditions compiler-note))
 965           ,@(loop for value in lvar-values
 966                   for var in vars
 967                   collect (if (stringp value)
 968                               ;; Fold the array reads for constant arguments
 969                               `(progn
 970                                  ,@(loop for c across value
 971                                          collect `(setf (aref .string.
 972                                                               .pos.) ,c)
 973                                          collect `(incf .pos.)))
 974                               `(sb!impl::string-dispatch
 975                                    (#!+sb-unicode
 976                                     (simple-array character (*))
 977                                     (simple-array base-char (*))
 978                                     t)
 979                                    ,var
 980                                  (replace .string. ,var :start1 .pos.)
 981                                  (incf .pos. (length ,var)))))
 982           .string.))
 983       lvars)))
 984 \f
 985 ;;;; CONS accessor DERIVE-TYPE optimizers
 986
 987 (defoptimizer (car derive-type) ((cons))
 988   (let ((type (lvar-type cons))
 989         (null-type (specifier-type 'null)))
 990     (cond ((eq type null-type)
 991            null-type)
 992           ((cons-type-p type)
 993            (cons-type-car-type type)))))
 994
 995 (defoptimizer (cdr derive-type) ((cons))
 996   (let ((type (lvar-type cons))
 997         (null-type (specifier-type 'null)))
 998     (cond ((eq type null-type)
 999            null-type)
1000           ((cons-type-p type)
1001            (cons-type-cdr-type type)))))
1002 \f
1003 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
1004
1005 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
1006 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
1007 ;;; expansion, so we factor out the condition into this function.
1008 (defun check-inlineability-of-find-position-if (sequence from-end)
1009   (let ((ctype (lvar-type sequence)))
1010     (cond ((csubtypep ctype (specifier-type 'vector))
1011            ;; It's not worth trying to inline vector code unless we
1012            ;; know a fair amount about it at compile time.
1013            (upgraded-element-type-specifier-or-give-up sequence)
1014            (unless (constant-lvar-p from-end)
1015              (give-up-ir1-transform
1016               "FROM-END argument value not known at compile time")))
1017           ((csubtypep ctype (specifier-type 'list))
1018            ;; Inlining on lists is generally worthwhile.
1019            )
1020           (t
1021            (give-up-ir1-transform
1022             "sequence type not known at compile time")))))
1023
1024 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
1025 (macrolet ((def (name condition)
1026              `(deftransform ,name ((predicate sequence from-end start end key)
1027                                    (function list t t t function)
1028                                    *
1029                                    :policy (> speed space))
1030                 "expand inline"
1031                 `(let ((index 0)
1032                        (find nil)
1033                        (position nil))
1034                    (declare (type index index))
1035                    (dolist (i sequence
1036                             (if (and end (> end index))
1037                                 (sequence-bounding-indices-bad-error
1038                                  sequence start end)
1039                                 (values find position)))
1040                      (let ((key-i (funcall key i)))
1041                        (when (and end (>= index end))
1042                          (return (values find position)))
1043                        (when (>= index start)
1044                          (,',condition (funcall predicate key-i)
1045                           ;; This hack of dealing with non-NIL
1046                           ;; FROM-END for list data by iterating
1047                           ;; forward through the list and keeping
1048                           ;; track of the last time we found a match
1049                           ;; might be more screwy than what the user
1050                           ;; expects, but it seems to be allowed by
1051                           ;; the ANSI standard. (And if the user is
1052                           ;; screwy enough to ask for FROM-END
1053                           ;; behavior on list data, turnabout is
1054                           ;; fair play.)
1055                           ;;
1056                           ;; It's also not enormously efficient,
1057                           ;; calling PREDICATE and KEY more often
1058                           ;; than necessary; but all the
1059                           ;; alternatives seem to have their own
1060                           ;; efficiency problems.
1061                           (if from-end
1062                               (setf find i
1063                                     position index)
1064                               (return (values i index))))))
1065                      (incf index))))))
1066   (def %find-position-if when)
1067   (def %find-position-if-not unless))
1068
1069 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
1070 ;;; without loss of efficiency. (I.e., the optimizer should be able
1071 ;;; to straighten everything out.)
1072 (deftransform %find-position ((item sequence from-end start end key test)
1073                               (t list t t t t t)
1074                               *
1075                               :policy (> speed space))
1076   "expand inline"
1077   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
1078                         ;; The order of arguments for asymmetric tests
1079                         ;; (e.g. #'<, as opposed to order-independent
1080                         ;; tests like #'=) is specified in the spec
1081                         ;; section 17.2.1 -- the O/Zi stuff there.
1082                         (lambda (i)
1083                           (funcall test-fun item i)))
1084                       sequence
1085                       from-end
1086                       start
1087                       end
1088                       (%coerce-callable-to-fun key)))
1089
1090 ;;; The inline expansions for the VECTOR case are saved as macros so
1091 ;;; that we can share them between the DEFTRANSFORMs and the default
1092 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
1093 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1094 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1095                                                             from-end
1096                                                             start
1097                                                             end-arg
1098                                                             element
1099                                                             done-p-expr)
1100   (with-unique-names (offset block index n-sequence sequence end)
1101     `(let* ((,n-sequence ,sequence-arg))
1102        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1103                          (,start ,start)
1104                          (,end ,end-arg)
1105                          :check-fill-pointer t)
1106          (block ,block
1107            (macrolet ((maybe-return ()
1108                         ;; WITH-ARRAY-DATA has already performed bounds
1109                         ;; checking, so we can safely elide the checks
1110                         ;; in the inner loop.
1111                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1112                                            (aref ,sequence ,index))))
1113                           (when ,done-p-expr
1114                             (return-from ,block
1115                               (values ,element
1116                                       (- ,index ,offset)))))))
1117              (if ,from-end
1118                  (loop for ,index
1119                        ;; (If we aren't fastidious about declaring that
1120                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1121                        ;; can send us off into never-never land, since
1122                        ;; INDEX is initialized to -1.)
1123                        of-type index-or-minus-1
1124                        from (1- ,end) downto ,start do
1125                        (maybe-return))
1126                  (loop for ,index of-type index from ,start below ,end do
1127                           (maybe-return))))
1128            (values nil nil))))))
1129
1130 (def!macro %find-position-vector-macro (item sequence
1131                                              from-end start end key test)
1132   (with-unique-names (element)
1133     (%find-position-or-find-position-if-vector-expansion
1134      sequence
1135      from-end
1136      start
1137      end
1138      element
1139      ;; (See the LIST transform for a discussion of the correct
1140      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1141      ;; or after the checked sequence element.)
1142      `(funcall ,test ,item (funcall ,key ,element)))))
1143
1144 (def!macro %find-position-if-vector-macro (predicate sequence
1145                                                      from-end start end key)
1146   (with-unique-names (element)
1147     (%find-position-or-find-position-if-vector-expansion
1148      sequence
1149      from-end
1150      start
1151      end
1152      element
1153      `(funcall ,predicate (funcall ,key ,element)))))
1154
1155 (def!macro %find-position-if-not-vector-macro (predicate sequence
1156                                                          from-end start end key)
1157   (with-unique-names (element)
1158     (%find-position-or-find-position-if-vector-expansion
1159      sequence
1160      from-end
1161      start
1162      end
1163      element
1164      `(not (funcall ,predicate (funcall ,key ,element))))))
1165
1166 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1167 ;;; VECTOR data
1168 (deftransform %find-position-if ((predicate sequence from-end start end key)
1169                                  (function vector t t t function)
1170                                  *
1171                                  :policy (> speed space))
1172   "expand inline"
1173   (check-inlineability-of-find-position-if sequence from-end)
1174   '(%find-position-if-vector-macro predicate sequence
1175                                    from-end start end key))
1176
1177 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1178                                      (function vector t t t function)
1179                                      *
1180                                      :policy (> speed space))
1181   "expand inline"
1182   (check-inlineability-of-find-position-if sequence from-end)
1183   '(%find-position-if-not-vector-macro predicate sequence
1184                                        from-end start end key))
1185
1186 (deftransform %find-position ((item sequence from-end start end key test)
1187                               (t vector t t t function function)
1188                               *
1189                               :policy (> speed space))
1190   "expand inline"
1191   (check-inlineability-of-find-position-if sequence from-end)
1192   '(%find-position-vector-macro item sequence
1193     from-end start end key test))
1194
1195 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1196 ;;; POSITION-IF, etc.
1197 (define-source-transform effective-find-position-test (test test-not)
1198   (once-only ((test test)
1199               (test-not test-not))
1200     `(cond
1201       ((and ,test ,test-not)
1202        (error "can't specify both :TEST and :TEST-NOT"))
1203       (,test (%coerce-callable-to-fun ,test))
1204       (,test-not
1205        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1206        ;; inefficient, but since the TEST-NOT option is deprecated
1207        ;; anyway, we don't care.)
1208        (complement (%coerce-callable-to-fun ,test-not)))
1209       (t #'eql))))
1210 (define-source-transform effective-find-position-key (key)
1211   (once-only ((key key))
1212     `(if ,key
1213          (%coerce-callable-to-fun ,key)
1214          #'identity)))
1215
1216 (macrolet ((define-find-position (fun-name values-index)
1217              `(deftransform ,fun-name ((item sequence &key
1218                                              from-end (start 0) end
1219                                              key test test-not)
1220                                        (t (or list vector) &rest t))
1221                 '(nth-value ,values-index
1222                             (%find-position item sequence
1223                                             from-end start
1224                                             end
1225                                             (effective-find-position-key key)
1226                                             (effective-find-position-test
1227                                              test test-not))))))
1228   (define-find-position find 0)
1229   (define-find-position position 1))
1230
1231 (macrolet ((define-find-position-if (fun-name values-index)
1232              `(deftransform ,fun-name ((predicate sequence &key
1233                                                   from-end (start 0)
1234                                                   end key)
1235                                        (t (or list vector) &rest t))
1236                 '(nth-value
1237                   ,values-index
1238                   (%find-position-if (%coerce-callable-to-fun predicate)
1239                                      sequence from-end
1240                                      start end
1241                                      (effective-find-position-key key))))))
1242   (define-find-position-if find-if 0)
1243   (define-find-position-if position-if 1))
1244
1245 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1246 ;;; didn't bother to worry about optimizing them, except note that on
1247 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1248 ;;; sbcl-devel
1249 ;;;
1250 ;;;     My understanding is that while the :test-not argument is
1251 ;;;     deprecated in favour of :test (complement #'foo) because of
1252 ;;;     semantic difficulties (what happens if both :test and :test-not
1253 ;;;     are supplied, etc) the -if-not variants, while officially
1254 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1255 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1256 ;;;     reasons for allowing the -if-not versions equal status,
1257 ;;;     particularly remove-if-not (== filter).
1258 ;;;
1259 ;;;     This is only an informal understanding, I grant you, but
1260 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1261 ;;;     way as the others?
1262 ;;;
1263 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1264 ;;; implementation of SBCL.
1265 (macrolet ((define-find-position-if-not (fun-name values-index)
1266                `(deftransform ,fun-name ((predicate sequence &key
1267                                           from-end (start 0)
1268                                           end key)
1269                                          (t (or list vector) &rest t))
1270                  '(nth-value
1271                    ,values-index
1272                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1273                     sequence from-end
1274                     start end
1275                     (effective-find-position-key key))))))
1276   (define-find-position-if-not find-if-not 0)
1277   (define-find-position-if-not position-if-not 1))