src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32         (ecase accumulate
  33           (:nconc
  34            (let ((temp (gensym))
  35                  (map-result (gensym)))
  36              `(let ((,fn-sym ,fn)
  37                     (,map-result (list nil)))
  38                 (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  39                               (,endtest (cdr ,map-result))
  40                   (setq ,temp (last (nconc ,temp ,call)))))))
  41           (:list
  42            (let ((temp (gensym))
  43                  (map-result (gensym)))
  44              `(let ((,fn-sym ,fn)
  45                     (,map-result (list nil)))
  46                 (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                               (,endtest (truly-the list (cdr ,map-result)))
  48                   (rplacd ,temp (setq ,temp (list ,call)))))))
  49           ((nil)
  50            `(let ((,fn-sym ,fn)
  51                   (,n-first ,(first arglists)))
  52               (do-anonymous ,(do-clauses)
  53                             (,endtest (truly-the list ,n-first))
  54                             ,call))))))))
  55
  56 (define-source-transform mapc (function list &rest more-lists)
  57   (mapfoo-transform function (cons list more-lists) nil t))
  58
  59 (define-source-transform mapcar (function list &rest more-lists)
  60   (mapfoo-transform function (cons list more-lists) :list t))
  61
  62 (define-source-transform mapcan (function list &rest more-lists)
  63   (mapfoo-transform function (cons list more-lists) :nconc t))
  64
  65 (define-source-transform mapl (function list &rest more-lists)
  66   (mapfoo-transform function (cons list more-lists) nil nil))
  67
  68 (define-source-transform maplist (function list &rest more-lists)
  69   (mapfoo-transform function (cons list more-lists) :list nil))
  70
  71 (define-source-transform mapcon (function list &rest more-lists)
  72   (mapfoo-transform function (cons list more-lists) :nconc nil))
  73 \f
  74 ;;;; mapping onto sequences: the MAP function
  75
  76 ;;; MAP is %MAP plus a check to make sure that any length specified in
  77 ;;; the result type matches the actual result. We also wrap it in a
  78 ;;; TRULY-THE for the most specific type we can determine.
  79 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  80   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  81          (bare `(%map result-type-arg fun ,@seq-names))
  82          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  83          ;; what we know about the type of the result. (Note that the
  84          ;; "result type" argument is not necessarily the type of the
  85          ;; result, since NIL means the result has NULL type.)
  86          (result-type (if (not constant-result-type-arg-p)
  87                           'consed-sequence
  88                           (let ((result-type-arg-value
  89                                  (lvar-value result-type-arg)))
  90                             (if (null result-type-arg-value)
  91                                 'null
  92                                 result-type-arg-value)))))
  93     `(lambda (result-type-arg fun ,@seq-names)
  94        (truly-the ,result-type
  95          ,(cond ((policy node (< safety 3))
  96                  ;; ANSI requires the length-related type check only
  97                  ;; when the SAFETY quality is 3... in other cases, we
  98                  ;; skip it, because it could be expensive.
  99                  bare)
 100                 ((not constant-result-type-arg-p)
 101                  `(sequence-of-checked-length-given-type ,bare
 102                                                          result-type-arg))
 103                 (t
 104                  (let ((result-ctype (ir1-transform-specifier-type
 105                                       result-type)))
 106                    (if (array-type-p result-ctype)
 107                        (let ((dims (array-type-dimensions result-ctype)))
 108                          (unless (and (listp dims) (= (length dims) 1))
 109                            (give-up-ir1-transform "invalid sequence type"))
 110                          (let ((dim (first dims)))
 111                            (if (eq dim '*)
 112                                bare
 113                                `(vector-of-checked-length-given-length ,bare
 114                                                                        ,dim))))
 115                        ;; FIXME: this is wrong, as not all subtypes of
 116                        ;; VECTOR are ARRAY-TYPEs [consider, for
 117                        ;; example, (OR (VECTOR T 3) (VECTOR T
 118                        ;; 4))]. However, it's difficult to see what we
 119                        ;; should put here... maybe we should
 120                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 121                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 122                        bare))))))))
 123
 124 ;;; Return a DO loop, mapping a function FUN to elements of
 125 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 126 ;;; bound to sequences, INTO - a variable, which is used in
 127 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 128 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 129 ;;; INDEX, containing the current position in sequences.
 130 (defun build-sequence-iterator (seqs seq-names &key result into body)
 131   (declare (type list seqs seq-names)
 132            (type symbol into))
 133   (collect ((bindings)
 134             (declarations)
 135             (vector-lengths)
 136             (tests)
 137             (places))
 138     (let ((found-vector-p nil))
 139       (flet ((process-vector (length)
 140                (unless found-vector-p
 141                  (setq found-vector-p t)
 142                  (bindings `(index 0 (1+ index)))
 143                  (declarations `(type index index)))
 144                (vector-lengths length)))
 145         (loop for seq of-type lvar in seqs
 146            for seq-name in seq-names
 147            for type = (lvar-type seq)
 148            do (cond ((csubtypep type (specifier-type 'list))
 149                      (with-unique-names (index)
 150                        (bindings `(,index ,seq-name (cdr ,index)))
 151                        (declarations `(type list ,index))
 152                        (places `(car ,index))
 153                        (tests `(endp ,index))))
 154                     ((csubtypep type (specifier-type 'vector))
 155                      (process-vector `(length ,seq-name))
 156                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 157                                 (aref ,seq-name index))))
 158                     (t
 159                      (give-up-ir1-transform
 160                       "can't determine sequence argument type"))))
 161         (when into
 162           (process-vector `(array-dimension ,into 0))))
 163       (when found-vector-p
 164         (bindings `(length (min ,@(vector-lengths))))
 165         (tests `(>= index length)))
 166       `(do (,@(bindings))
 167            ((or ,@(tests)) ,result)
 168          (declare ,@(declarations))
 169          (let ((funcall-result (funcall fun ,@(places))))
 170            (declare (ignorable funcall-result))
 171            ,body)))))
 172
 173 ;;; Try to compile %MAP efficiently when we can determine sequence
 174 ;;; argument types at compile time.
 175 ;;;
 176 ;;; Note: This transform was written to allow open coding of
 177 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 178 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 179 ;;; necessarily as efficient as possible. In particular, it will be
 180 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 181 ;;; numeric element types. It should be straightforward to make it
 182 ;;; handle that case more efficiently, but it's left as an exercise to
 183 ;;; the reader, because the code is complicated enough already and I
 184 ;;; don't happen to need that functionality right now. -- WHN 20000410
 185 (deftransform %map ((result-type fun seq &rest seqs) * *
 186                     :policy (>= speed space))
 187   "open code"
 188   (unless (constant-lvar-p result-type)
 189     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 190   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 191            (fn-1subtypep (fn x y)
 192              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 193                (if valid-p
 194                    subtype-p
 195                    (give-up-ir1-transform
 196                     "can't analyze sequence type relationship"))))
 197            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 198     (let* ((result-type-value (lvar-value result-type))
 199            (result-supertype (cond ((null result-type-value) 'null)
 200                                    ((1subtypep result-type-value 'vector)
 201                                     'vector)
 202                                    ((1subtypep result-type-value 'list)
 203                                     'list)
 204                                    (t
 205                                     (give-up-ir1-transform
 206                                      "result type unsuitable")))))
 207       (cond ((and result-type-value (null seqs))
 208              ;; The consing arity-1 cases can be implemented
 209              ;; reasonably efficiently as function calls, and the cost
 210              ;; of consing should be significantly larger than
 211              ;; function call overhead, so we always compile these
 212              ;; cases as full calls regardless of speed-versus-space
 213              ;; optimization policy.
 214              (cond ((subtypep result-type-value 'list)
 215                     '(%map-to-list-arity-1 fun seq))
 216                    ( ;; (This one can be inefficient due to COERCE, but
 217                     ;; the current open-coded implementation has the
 218                     ;; same problem.)
 219                     (subtypep result-type-value 'vector)
 220                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 221                              ',result-type-value))
 222                    (t (bug "impossible (?) sequence type"))))
 223             (t
 224              (let* ((seqs (cons seq seqs))
 225                     (seq-args (make-gensym-list (length seqs))))
 226                (multiple-value-bind (push-dacc result)
 227                    (ecase result-supertype
 228                      (null (values nil nil))
 229                      (list (values `(push funcall-result acc)
 230                                    `(nreverse acc)))
 231                      (vector (values `(push funcall-result acc)
 232                                      `(coerce (nreverse acc)
 233                                               ',result-type-value))))
 234                  ;; (We use the same idiom, of returning a LAMBDA from
 235                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 236                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 237                  ;; reason: we need to get the runtime values of each
 238                  ;; of the &REST vars.)
 239                  `(lambda (result-type fun ,@seq-args)
 240                     (declare (ignore result-type))
 241                     (let ((fun (%coerce-callable-to-fun fun))
 242                           (acc nil))
 243                       (declare (type list acc))
 244                       (declare (ignorable acc))
 245                       ,(build-sequence-iterator
 246                         seqs seq-args
 247                         :result result
 248                         :body push-dacc))))))))))
 249
 250 ;;; MAP-INTO
 251 (deftransform map-into ((result fun &rest seqs)
 252                         (vector * &rest *)
 253                         *)
 254   "open code"
 255   (let ((seqs-names (mapcar (lambda (x)
 256                               (declare (ignore x))
 257                               (gensym))
 258                             seqs)))
 259     `(lambda (result fun ,@seqs-names)
 260        ,(build-sequence-iterator
 261          seqs seqs-names
 262          :result '(when (array-has-fill-pointer-p result)
 263                    (setf (fill-pointer result) index))
 264          :into 'result
 265          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 266                  (setf (aref result index) funcall-result)))
 267        result)))
 268
 269 \f
 270 ;;; FIXME: once the confusion over doing transforms with known-complex
 271 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 272 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 273 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 274   '(aref s i))
 275
 276 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 277   '(nth i s))
 278
 279 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 280   '(%aset s i v))
 281
 282 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 283   '(setf (car (nthcdr i s)) v))
 284
 285 (deftransform %check-vector-sequence-bounds ((vector start end)
 286                                              (vector * *) *
 287                                              :node node)
 288   (if (policy node (< safety speed))
 289       '(or end (length vector))
 290       '(let ((length (length vector)))
 291         (if (<= 0 start (or end length) length)
 292             (or end length)
 293             (sb!impl::signal-bounding-indices-bad-error vector start end)))))
 294
 295 (macrolet ((def (name)
 296              `(deftransform ,name ((e l &key (test #'eql)) * *
 297                                    :node node)
 298                 (unless (constant-lvar-p l)
 299                   (give-up-ir1-transform))
 300
 301                 (let ((val (lvar-value l)))
 302                   (unless (policy node
 303                                   (or (= speed 3)
 304                                       (and (>= speed space)
 305                                            (<= (length val) 5))))
 306                     (give-up-ir1-transform))
 307
 308                   (labels ((frob (els)
 309                              (if els
 310                                  `(if (funcall test e ',(car els))
 311                                       ',els
 312                                       ,(frob (cdr els)))
 313                                  nil)))
 314                     (frob val))))))
 315   (def member)
 316   (def memq))
 317
 318 ;;; FIXME: We have rewritten the original code that used DOLIST to this
 319 ;;; more natural MACROLET.  However, the original code suggested that when
 320 ;;; this was done, a few bytes could be saved by a call to a shared
 321 ;;; function.  This remains to be done.
 322 (macrolet ((def (fun eq-fun)
 323              `(deftransform ,fun ((item list &key test) (t list &rest t) *)
 324                 "convert to EQ test"
 325                 ;; FIXME: The scope of this transformation could be
 326                 ;; widened somewhat, letting it work whenever the test is
 327                 ;; 'EQL and we know from the type of ITEM that it #'EQ
 328                 ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 329                 ;; and SYMBOL.)
 330                 ;;   If TEST is EQ, apply transform, else
 331                 ;;   if test is not EQL, then give up on transform, else
 332                 ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 333                 ;;   transform, else give up on transform.
 334                 (cond (test
 335                        (unless (lvar-fun-is test '(eq))
 336                          (give-up-ir1-transform)))
 337                       ((types-equal-or-intersect (lvar-type item)
 338                                                  (specifier-type 'number))
 339                        (give-up-ir1-transform "Item might be a number.")))
 340                 `(,',eq-fun item list))))
 341   (def delete delq)
 342   (def assoc assq)
 343   (def member memq))
 344
 345 (deftransform delete-if ((pred list) (t list))
 346   "open code"
 347   '(do ((x list (cdr x))
 348         (splice '()))
 349        ((endp x) list)
 350      (cond ((funcall pred (car x))
 351             (if (null splice)
 352                 (setq list (cdr x))
 353                 (rplacd splice (cdr x))))
 354            (t (setq splice x)))))
 355
 356 (deftransform fill ((seq item &key (start 0) (end (length seq)))
 357                     (vector t &key (:start t) (:end index))
 358                     *
 359                     :policy (> speed space))
 360   "open code"
 361   (let ((element-type (upgraded-element-type-specifier-or-give-up seq)))
 362     (values
 363      `(with-array-data ((data seq)
 364                         (start start)
 365                         (end end))
 366        (declare (type (simple-array ,element-type 1) data))
 367        (declare (type fixnum start end))
 368        (do ((i start (1+ i)))
 369            ((= i end) seq)
 370          (declare (type index i))
 371          ;; WITH-ARRAY-DATA did our range checks once and for all, so
 372          ;; it'd be wasteful to check again on every AREF...
 373          (declare (optimize (safety 0)))
 374          (setf (aref data i) item)))
 375      ;; ... though we still need to check that the new element can fit
 376      ;; into the vector in safe code. -- CSR, 2002-07-05
 377      `((declare (type ,element-type item))))))
 378 \f
 379 ;;;; utilities
 380
 381 ;;; Return true if LVAR's only use is a non-NOTINLINE reference to a
 382 ;;; global function with one of the specified NAMES.
 383 (defun lvar-fun-is (lvar names)
 384   (declare (type lvar lvar) (list names))
 385   (let ((use (lvar-uses lvar)))
 386     (and (ref-p use)
 387          (let ((leaf (ref-leaf use)))
 388            (and (global-var-p leaf)
 389                 (eq (global-var-kind leaf) :global-function)
 390                 (not (null (member (leaf-source-name leaf) names
 391                                    :test #'equal))))))))
 392
 393 ;;; If LVAR is a constant lvar, the return the constant value. If it
 394 ;;; is null, then return default, otherwise quietly give up the IR1
 395 ;;; transform.
 396 ;;;
 397 ;;; ### Probably should take an ARG and flame using the NAME.
 398 (defun constant-value-or-lose (lvar &optional default)
 399   (declare (type (or lvar null) lvar))
 400   (cond ((not lvar) default)
 401         ((constant-lvar-p lvar)
 402          (lvar-value lvar))
 403         (t
 404          (give-up-ir1-transform))))
 405
 406 ;;; FIXME: Why is this code commented out? (Why *was* it commented
 407 ;;; out? We inherited this situation from cmucl-2.4.8, with no
 408 ;;; explanation.) Should we just delete this code?
 409 #|
 410 ;;; This is a frob whose job it is to make it easier to pass around
 411 ;;; the arguments to IR1 transforms. It bundles together the name of
 412 ;;; the argument (which should be referenced in any expansion), and
 413 ;;; the continuation for that argument (or NIL if unsupplied.)
 414 (defstruct (arg (:constructor %make-arg (name cont))
 415                 (:copier nil))
 416   (name nil :type symbol)
 417   (cont nil :type (or continuation null)))
 418 (defmacro make-arg (name)
 419   `(%make-arg ',name ,name))
 420
 421 ;;; If Arg is null or its CONT is null, then return Default, otherwise
 422 ;;; return Arg's NAME.
 423 (defun default-arg (arg default)
 424   (declare (type (or arg null) arg))
 425   (if (and arg (arg-cont arg))
 426       (arg-name arg)
 427       default))
 428
 429 ;;; If Arg is null or has no CONT, return the default. Otherwise, Arg's
 430 ;;; CONT must be a constant continuation whose value we return. If not, we
 431 ;;; give up.
 432 (defun arg-constant-value (arg default)
 433   (declare (type (or arg null) arg))
 434   (if (and arg (arg-cont arg))
 435       (let ((cont (arg-cont arg)))
 436         (unless (constant-continuation-p cont)
 437           (give-up-ir1-transform "Argument is not constant: ~S."
 438                                  (arg-name arg)))
 439         (continuation-value from-end))
 440       default))
 441
 442 ;;; If Arg is a constant and is EQL to X, then return T, otherwise NIL. If
 443 ;;; Arg is NIL or its CONT is NIL, then compare to the default.
 444 (defun arg-eql (arg default x)
 445   (declare (type (or arg null) x))
 446   (if (and arg (arg-cont arg))
 447       (let ((cont (arg-cont arg)))
 448         (and (constant-continuation-p cont)
 449              (eql (continuation-value cont) x)))
 450       (eql default x)))
 451
 452 (defstruct (iterator (:copier nil))
 453   ;; The kind of iterator.
 454   (kind nil (member :normal :result))
 455   ;; A list of LET* bindings to create the initial state.
 456   (binds nil :type list)
 457   ;; A list of declarations for Binds.
 458   (decls nil :type list)
 459   ;; A form that returns the current value. This may be set with SETF to set
 460   ;; the current value.
 461   (current (error "Must specify CURRENT."))
 462   ;; In a :NORMAL iterator, a form that tests whether there is a current value.
 463   (done nil)
 464   ;; In a :RESULT iterator, a form that truncates the result at the current
 465   ;; position and returns it.
 466   (result nil)
 467   ;; A form that returns the initial total number of values. The result is
 468   ;; undefined after NEXT has been evaluated.
 469   (length (error "Must specify LENGTH."))
 470   ;; A form that advances the state to the next value. It is an error to call
 471   ;; this when the iterator is Done.
 472   (next (error "Must specify NEXT.")))
 473
 474 ;;; Type of an index var that can go negative (in the from-end case.)
 475 (deftype neg-index ()
 476   `(integer -1 ,most-positive-fixnum))
 477
 478 ;;; Return an ITERATOR structure describing how to iterate over an arbitrary
 479 ;;; sequence. Sequence is a variable bound to the sequence, and Type is the
 480 ;;; type of the sequence. If true, INDEX is a variable that should be bound to
 481 ;;; the index of the current element in the sequence.
 482 ;;;
 483 ;;; If we can't tell whether the sequence is a list or a vector, or whether
 484 ;;; the iteration is forward or backward, then GIVE-UP.
 485 (defun make-sequence-iterator (sequence type &key start end from-end index)
 486   (declare (symbol sequence) (type ctype type)
 487            (type (or arg null) start end from-end)
 488            (type (or symbol null) index))
 489   (let ((from-end (arg-constant-value from-end nil)))
 490     (cond ((csubtypep type (specifier-type 'vector))
 491            (let* ((n-stop (gensym))
 492                   (n-idx (or index (gensym)))
 493                   (start (default-arg 0 start))
 494                   (end (default-arg `(length ,sequence) end)))
 495              (make-iterator
 496               :kind :normal
 497               :binds `((,n-idx ,(if from-end `(1- ,end) ,start))
 498                        (,n-stop ,(if from-end `(1- ,start) ,end)))
 499               :decls `((type neg-index ,n-idx ,n-stop))
 500               :current `(aref ,sequence ,n-idx)
 501               :done `(,(if from-end '<= '>=) ,n-idx ,n-stop)
 502               :next `(setq ,n-idx
 503                            ,(if from-end `(1- ,n-idx) `(1+ ,n-idx)))
 504               :length (if from-end
 505                           `(- ,n-idx ,n-stop)
 506                           `(- ,n-stop ,n-idx)))))
 507           ((csubtypep type (specifier-type 'list))
 508            (let* ((n-stop (if (and end (not from-end)) (gensym) nil))
 509                   (n-current (gensym))
 510                   (start-p (not (arg-eql start 0 0)))
 511                   (end-p (not (arg-eql end nil nil)))
 512                   (start (default-arg start 0))
 513                   (end (default-arg end nil)))
 514              (make-iterator
 515               :binds `((,n-current
 516                         ,(if from-end
 517                              (if (or start-p end-p)
 518                                  `(nreverse (subseq ,sequence ,start
 519                                                     ,@(when end `(,end))))
 520                                  `(reverse ,sequence))
 521                              (if start-p
 522                                  `(nthcdr ,start ,sequence)
 523                                  sequence)))
 524                        ,@(when n-stop
 525                            `((,n-stop (nthcdr (the index
 526                                                    (- ,end ,start))
 527                                               ,n-current))))
 528                        ,@(when index
 529                            `((,index ,(if from-end `(1- ,end) start)))))
 530               :kind :normal
 531               :decls `((list ,n-current ,n-end)
 532                        ,@(when index `((type neg-index ,index))))
 533               :current `(car ,n-current)
 534               :done `(eq ,n-current ,n-stop)
 535               :length `(- ,(or end `(length ,sequence)) ,start)
 536               :next `(progn
 537                        (setq ,n-current (cdr ,n-current))
 538                        ,@(when index
 539                            `((setq ,n-idx
 540                                    ,(if from-end
 541                                         `(1- ,index)
 542                                         `(1+ ,index)))))))))
 543           (t
 544            (give-up-ir1-transform
 545             "can't tell whether sequence is a list or a vector")))))
 546
 547 ;;; Make an iterator used for constructing result sequences. Name is a
 548 ;;; variable to be bound to the result sequence. Type is the type of result
 549 ;;; sequence to make. Length is an expression to be evaluated to get the
 550 ;;; maximum length of the result (not evaluated in list case.)
 551 (defun make-result-sequence-iterator (name type length)
 552   (declare (symbol name) (type ctype type))
 553
 554 ;;; Define each NAME as a local macro that will call the value of the
 555 ;;; function arg with the given arguments. If the argument isn't known to be a
 556 ;;; function, give them an efficiency note and reference a coerced version.
 557 (defmacro coerce-funs (specs &body body)
 558   #!+sb-doc
 559   "COERCE-FUNCTIONS ({(Name Fun-Arg Default)}*) Form*"
 560   (collect ((binds)
 561             (defs))
 562     (dolist (spec specs)
 563       `(let ((body (progn ,@body))
 564              (n-fun (arg-name ,(second spec)))
 565              (fun-cont (arg-cont ,(second spec))))
 566          (cond ((not fun-cont)
 567                 `(macrolet ((,',(first spec) (&rest args)
 568                              `(,',',(third spec) ,@args)))
 569                    ,body))
 570                ((not (csubtypep (continuation-type fun-cont)
 571                                 (specifier-type 'function)))
 572                 (when (policy *compiler-error-context*
 573                               (> speed inhibit-warnings))
 574                   (compiler-notify
 575                    "~S may not be a function, so must coerce at run-time."
 576                    n-fun))
 577                 (once-only ((n-fun `(if (functionp ,n-fun)
 578                                         ,n-fun
 579                                         (symbol-function ,n-fun))))
 580                   `(macrolet ((,',(first spec) (&rest args)
 581                                `(funcall ,',n-fun ,@args)))
 582                      ,body)))
 583                (t
 584                 `(macrolet ((,',(first spec) (&rest args)
 585                               `(funcall ,',n-fun ,@args)))
 586                    ,body)))))))
 587
 588 ;;; Wrap code around the result of the body to define Name as a local macro
 589 ;;; that returns true when its arguments satisfy the test according to the Args
 590 ;;; Test and Test-Not. If both Test and Test-Not are supplied, abort the
 591 ;;; transform.
 592 (defmacro with-sequence-test ((name test test-not) &body body)
 593   `(let ((not-p (arg-cont ,test-not)))
 594      (when (and (arg-cont ,test) not-p)
 595        (abort-ir1-transform "Both ~S and ~S were supplied."
 596                             (arg-name ,test)
 597                             (arg-name ,test-not)))
 598      (coerce-funs ((,name (if not-p ,test-not ,test) eql))
 599        ,@body)))
 600 |#
 601 \f
 602 ;;;; hairy sequence transforms
 603
 604 ;;; FIXME: no hairy sequence transforms in SBCL?
 605 \f
 606 ;;;; string operations
 607
 608 ;;; We transform the case-sensitive string predicates into a non-keyword
 609 ;;; version. This is an IR1 transform so that we don't have to worry about
 610 ;;; changing the order of evaluation.
 611 (macrolet ((def (fun pred*)
 612              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 613                                                          (start2 0) end2)
 614                                    * *)
 615                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 616   (def string< string<*)
 617   (def string> string>*)
 618   (def string<= string<=*)
 619   (def string>= string>=*)
 620   (def string= string=*)
 621   (def string/= string/=*))
 622
 623 ;;; Return a form that tests the free variables STRING1 and STRING2
 624 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 625 ;;; start and end are also gotten from the environment. Both strings
 626 ;;; must be SIMPLE-BASE-STRINGs.
 627 (macrolet ((def (name lessp equalp)
 628              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 629                                    (simple-base-string simple-base-string t t t t) *)
 630                 `(let* ((end1 (if (not end1) (length string1) end1))
 631                         (end2 (if (not end2) (length string2) end2))
 632                         (index (sb!impl::%sp-string-compare
 633                                 string1 start1 end1 string2 start2 end2)))
 634                   (if index
 635                       (cond ((= index end1)
 636                              ,(if ',lessp 'index nil))
 637                             ((= (+ index (- start2 start1)) end2)
 638                              ,(if ',lessp nil 'index))
 639                             ((,(if ',lessp 'char< 'char>)
 640                                (schar string1 index)
 641                                (schar string2
 642                                       (truly-the index
 643                                                  (+ index
 644                                                     (truly-the fixnum
 645                                                                (- start2
 646                                                                   start1))))))
 647                              index)
 648                             (t nil))
 649                       ,(if ',equalp 'end1 nil))))))
 650   (def string<* t nil)
 651   (def string<=* t t)
 652   (def string>* nil nil)
 653   (def string>=* nil t))
 654
 655 (macrolet ((def (name result-fun)
 656              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 657                                    (simple-base-string simple-base-string t t t t) *)
 658                 `(,',result-fun
 659                   (sb!impl::%sp-string-compare
 660                    string1 start1 (or end1 (length string1))
 661                    string2 start2 (or end2 (length string2)))))))
 662   (def string=* not)
 663   (def string/=* identity))
 664
 665 \f
 666 ;;;; string-only transforms for sequence functions
 667 ;;;;
 668 ;;;; Note: CMU CL had more of these, including transforms for
 669 ;;;; functions which cons. In SBCL, we've gotten rid of most of the
 670 ;;;; transforms for functions which cons, since our GC overhead is
 671 ;;;; sufficiently large that it doesn't seem worth it to try to
 672 ;;;; economize on function call overhead or on the overhead of runtime
 673 ;;;; type dispatch in AREF. The exception is CONCATENATE, since
 674 ;;;; a full call to CONCATENATE would have to look up the sequence
 675 ;;;; type, which can be really slow.
 676
 677 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp
 678 ;;;
 679 ;;; FIXME: Add a comment telling whether this holds for all vectors
 680 ;;; or only for vectors based on simple arrays (non-adjustable, etc.).
 681 (def!constant vector-data-bit-offset
 682   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 683
 684 (eval-when (:compile-toplevel)
 685 (defun valid-bit-bash-saetp-p (saetp)
 686   ;; BIT-BASHing isn't allowed on simple vectors that contain pointers
 687   (and (not (eq t (sb!vm:saetp-specifier saetp)))
 688        ;; Disallowing (VECTOR NIL) also means that we won't transform
 689        ;; sequence functions into bit-bashing code and we let the
 690        ;; generic sequence functions signal errors if necessary.
 691        (not (zerop (sb!vm:saetp-n-bits saetp)))
 692        ;; Due to limitations with the current BIT-BASHing code, we can't
 693        ;; BIT-BASH reliably on arrays whose element types are larger
 694        ;; than the word size.
 695        (<= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)))
 696 ) ; EVAL-WHEN
 697
 698 ;; FIXME: It turns out that this transform (for SIMPLE-BASE-STRINGS)
 699 ;; is critical for the performance of string streams.  Make this
 700 ;; more explicit.
 701 (macrolet
 702     ((define-replace-transforms ()
 703        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 704              when (valid-bit-bash-saetp-p saetp)
 705              collect
 706              (let* ((sequence-type `(simple-array ,(sb!vm:saetp-specifier saetp) (*)))
 707                     (n-element-bits (sb!vm:saetp-n-bits saetp))
 708                     (bash-function (intern (format nil "UB~D-BASH-COPY" n-element-bits)
 709                                             (find-package "SB!KERNEL"))))
 710                `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 711                                        (,sequence-type ,sequence-type &rest t)
 712                                        ,sequence-type
 713                                        :node node)
 714                  `(let* ((len1 (length seq1))
 715                          (len2 (length seq2))
 716                          (end1 (or end1 len1))
 717                          (end2 (or end2 len2))
 718                          (replace-len1 (- end1 start1))
 719                          (replace-len2 (- end2 start2)))
 720                    ,(unless (policy node (= safety 0))
 721                      `(progn
 722                        (unless (<= 0 start1 end1 len1)
 723                          (sb!impl::signal-bounding-indices-bad-error seq1 start1 end1))
 724                        (unless (<= 0 start2 end2 len2)
 725                          (sb!impl::signal-bounding-indices-bad-error seq2 start2 end2))))
 726                    (funcall (function ,',bash-function)
 727                     seq2 start2
 728                     seq1 start1
 729                     (min replace-len1 replace-len2))
 730                    seq1)))
 731              into forms
 732              finally (return `(progn ,@forms)))))
 733   (define-replace-transforms))
 734
 735 (macrolet
 736     ((define-subseq-transforms ()
 737        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 738              when (valid-bit-bash-saetp-p saetp)
 739              collect
 740              (let* ((sequence-type `(simple-array ,(sb!vm:saetp-specifier saetp) (*)))
 741                     (n-element-bits (sb!vm:saetp-n-bits saetp))
 742                     (bash-function (intern (format nil "UB~D-BASH-COPY" n-element-bits)
 743                                            (find-package "SB!KERNEL"))))
 744                `(deftransform subseq ((seq start &optional end)
 745                                       (,sequence-type t &optional t)
 746                                       ,sequence-type :node node)
 747                  `(let* ((length (length seq))
 748                          (end (if end (min end length) length)))
 749                    ,(unless (policy node (= safety 0))
 750                      `(progn
 751                        (unless (<= 0 start end length)
 752                          (sb!impl::signal-bounding-indices-bad-error seq start end))))
 753                    (let* ((size (- end start))
 754                           (result (make-array size :element-type ',',(sb!vm:saetp-specifier saetp))))
 755                      (funcall (function ,',bash-function)
 756                               seq start result 0 size)
 757                      result))))
 758              into forms
 759              finally (return `(progn ,@forms)))))
 760   (define-subseq-transforms))
 761
 762 (macrolet
 763     ((define-copy-seq-transforms ()
 764        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 765              when (valid-bit-bash-saetp-p saetp)
 766              collect
 767              (let* ((sequence-type `(simple-array ,(sb!vm:saetp-specifier saetp) (*)))
 768                     (n-element-bits (sb!vm:saetp-n-bits saetp))
 769                     (bash-function (intern (format nil "UB~D-BASH-COPY" n-element-bits)
 770                                            (find-package "SB!KERNEL"))))
 771                `(deftransform copy-seq ((seq) (,sequence-type)
 772                                         ,sequence-type)
 773                  `(let* ((length (length seq))
 774                          (result (make-array length :element-type ',',(sb!vm:saetp-specifier saetp))))
 775                    (funcall (function ,',bash-function)
 776                     seq 0 result 0 length)
 777                    result)))
 778              into forms
 779              finally (return `(progn ,@forms)))))
 780   (define-copy-seq-transforms))
 781
 782 ;;; FIXME: it really should be possible to take advantage of the
 783 ;;; macros used in code/seq.lisp here to avoid duplication of code,
 784 ;;; and enable even funkier transformations.
 785 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
 786                                (test #'eql)
 787                                (key #'identity)
 788                                from-end)
 789                       (vector vector &rest t)
 790                       *
 791                       :policy (> speed (max space safety)))
 792   "open code"
 793   (let ((from-end (when (lvar-p from-end)
 794                     (unless (constant-lvar-p from-end)
 795                       (give-up-ir1-transform ":FROM-END is not constant."))
 796                     (lvar-value from-end)))
 797         (keyp (lvar-p key))
 798         (testp (lvar-p test)))
 799     `(block search
 800        (let ((end1 (or end1 (length pattern)))
 801              (end2 (or end2 (length text)))
 802              ,@(when keyp
 803                      '((key (coerce key 'function))))
 804              ,@(when testp
 805                      '((test (coerce test 'function)))))
 806          (declare (type index start1 start2 end1 end2))
 807          (do (,(if from-end
 808                    '(index2 (- end2 (- end1 start1)) (1- index2))
 809                    '(index2 start2 (1+ index2))))
 810              (,(if from-end
 811                    '(< index2 start2)
 812                    '(>= index2 end2))
 813               nil)
 814            ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
 815            ;; terminates is hits -1 when :FROM-END is true and :START2
 816            ;; is 0.
 817            (declare (type fixnum index2))
 818            (when (do ((index1 start1 (1+ index1))
 819                       (index2 index2 (1+ index2)))
 820                      ((>= index1 end1) t)
 821                    (declare (type index index1 index2))
 822                    ,@(unless from-end
 823                              '((when (= index2 end2)
 824                                  (return-from search nil))))
 825                    (unless (,@(if testp
 826                                   '(funcall test)
 827                                   '(eql))
 828                               ,(if keyp
 829                                    '(funcall key (aref pattern index1))
 830                                    '(aref pattern index1))
 831                               ,(if keyp
 832                                    '(funcall key (aref text index2))
 833                                    '(aref text index2)))
 834                      (return nil)))
 835              (return index2)))))))
 836
 837 ;;; FIXME: It seems as though it should be possible to make a DEFUN
 838 ;;; %CONCATENATE (with a DEFTRANSFORM to translate constant RTYPE to
 839 ;;; CTYPE before calling %CONCATENATE) which is comparably efficient,
 840 ;;; at least once DYNAMIC-EXTENT works.
 841 ;;;
 842 ;;; FIXME: currently KLUDGEed because of bug 188
 843 ;;;
 844 ;;; FIXME: disabled for sb-unicode: probably want it back
 845 #!-sb-unicode
 846 (deftransform concatenate ((rtype &rest sequences)
 847                            (t &rest (or simple-base-string
 848                                         (simple-array nil (*))))
 849                            simple-base-string
 850                            :policy (< safety 3))
 851   (loop for rest-seqs on sequences
 852         for n-seq = (gensym "N-SEQ")
 853         for n-length = (gensym "N-LENGTH")
 854         for start = 0 then next-start
 855         for next-start = (gensym "NEXT-START")
 856         collect n-seq into args
 857         collect `(,n-length (length ,n-seq)) into lets
 858         collect n-length into all-lengths
 859         collect next-start into starts
 860         collect `(if (and (typep ,n-seq '(simple-array nil (*)))
 861                           (> ,n-length 0))
 862                      (error 'nil-array-accessed-error)
 863                      (#.(let* ((i (position 'character sb!kernel::*specialized-array-element-types*))
 864                                (saetp (aref sb!vm:*specialized-array-element-type-properties* i))
 865                                (n-bits (sb!vm:saetp-n-bits saetp)))
 866                           (intern (format nil "UB~D-BASH-COPY" n-bits)
 867                                   "SB!KERNEL"))
 868                         ,n-seq 0 res ,start ,n-length))
 869                 into forms
 870         collect `(setq ,next-start (+ ,start ,n-length)) into forms
 871         finally
 872         (return
 873           `(lambda (rtype ,@args)
 874              (declare (ignore rtype))
 875              (let* (,@lets
 876                     (res (make-string (the index (+ ,@all-lengths))
 877                                       :element-type 'base-char)))
 878                (declare (type index ,@all-lengths))
 879                (let (,@(mapcar (lambda (name) `(,name 0)) starts))
 880                  (declare (type index ,@starts))
 881                  ,@forms)
 882                res)))))
 883 \f
 884 ;;;; CONS accessor DERIVE-TYPE optimizers
 885
 886 (defoptimizer (car derive-type) ((cons))
 887   (let ((type (lvar-type cons))
 888         (null-type (specifier-type 'null)))
 889     (cond ((eq type null-type)
 890            null-type)
 891           ((cons-type-p type)
 892            (cons-type-car-type type)))))
 893
 894 (defoptimizer (cdr derive-type) ((cons))
 895   (let ((type (lvar-type cons))
 896         (null-type (specifier-type 'null)))
 897     (cond ((eq type null-type)
 898            null-type)
 899           ((cons-type-p type)
 900            (cons-type-cdr-type type)))))
 901 \f
 902 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
 903
 904 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
 905 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
 906 ;;; expansion, so we factor out the condition into this function.
 907 (defun check-inlineability-of-find-position-if (sequence from-end)
 908   (let ((ctype (lvar-type sequence)))
 909     (cond ((csubtypep ctype (specifier-type 'vector))
 910            ;; It's not worth trying to inline vector code unless we
 911            ;; know a fair amount about it at compile time.
 912            (upgraded-element-type-specifier-or-give-up sequence)
 913            (unless (constant-lvar-p from-end)
 914              (give-up-ir1-transform
 915               "FROM-END argument value not known at compile time")))
 916           ((csubtypep ctype (specifier-type 'list))
 917            ;; Inlining on lists is generally worthwhile.
 918            )
 919           (t
 920            (give-up-ir1-transform
 921             "sequence type not known at compile time")))))
 922
 923 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
 924 (macrolet ((def (name condition)
 925              `(deftransform ,name ((predicate sequence from-end start end key)
 926                                    (function list t t t function)
 927                                    *
 928                                    :policy (> speed space))
 929                 "expand inline"
 930                 `(let ((index 0)
 931                        (find nil)
 932                        (position nil))
 933                    (declare (type index index))
 934                    (dolist (i sequence
 935                             (if (and end (> end index))
 936                                 (sb!impl::signal-bounding-indices-bad-error
 937                                  sequence start end)
 938                                 (values find position)))
 939                      (let ((key-i (funcall key i)))
 940                        (when (and end (>= index end))
 941                          (return (values find position)))
 942                        (when (>= index start)
 943                          (,',condition (funcall predicate key-i)
 944                           ;; This hack of dealing with non-NIL
 945                           ;; FROM-END for list data by iterating
 946                           ;; forward through the list and keeping
 947                           ;; track of the last time we found a match
 948                           ;; might be more screwy than what the user
 949                           ;; expects, but it seems to be allowed by
 950                           ;; the ANSI standard. (And if the user is
 951                           ;; screwy enough to ask for FROM-END
 952                           ;; behavior on list data, turnabout is
 953                           ;; fair play.)
 954                           ;;
 955                           ;; It's also not enormously efficient,
 956                           ;; calling PREDICATE and KEY more often
 957                           ;; than necessary; but all the
 958                           ;; alternatives seem to have their own
 959                           ;; efficiency problems.
 960                           (if from-end
 961                               (setf find i
 962                                     position index)
 963                               (return (values i index))))))
 964                      (incf index))))))
 965   (def %find-position-if when)
 966   (def %find-position-if-not unless))
 967
 968 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
 969 ;;; without loss of efficiency. (I.e., the optimizer should be able
 970 ;;; to straighten everything out.)
 971 (deftransform %find-position ((item sequence from-end start end key test)
 972                               (t list t t t t t)
 973                               *
 974                               :policy (> speed space))
 975   "expand inline"
 976   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
 977                         ;; The order of arguments for asymmetric tests
 978                         ;; (e.g. #'<, as opposed to order-independent
 979                         ;; tests like #'=) is specified in the spec
 980                         ;; section 17.2.1 -- the O/Zi stuff there.
 981                         (lambda (i)
 982                           (funcall test-fun item i)))
 983                       sequence
 984                       from-end
 985                       start
 986                       end
 987                       (%coerce-callable-to-fun key)))
 988
 989 ;;; The inline expansions for the VECTOR case are saved as macros so
 990 ;;; that we can share them between the DEFTRANSFORMs and the default
 991 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
 992 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
 993 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
 994                                                             from-end
 995                                                             start
 996                                                             end-arg
 997                                                             element
 998                                                             done-p-expr)
 999   (with-unique-names (offset block index n-sequence sequence n-end end)
1000     `(let ((,n-sequence ,sequence-arg)
1001            (,n-end ,end-arg))
1002        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1003                          (,start ,start)
1004                          (,end (%check-vector-sequence-bounds
1005                                 ,n-sequence ,start ,n-end)))
1006          (block ,block
1007            (macrolet ((maybe-return ()
1008                         ;; WITH-ARRAY-DATA has already performed bounds
1009                         ;; checking, so we can safely elide the checks
1010                         ;; in the inner loop.
1011                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1012                                            (aref ,sequence ,index))))
1013                            (when ,done-p-expr
1014                              (return-from ,block
1015                                (values ,element
1016                                        (- ,index ,offset)))))))
1017              (if ,from-end
1018                  (loop for ,index
1019                        ;; (If we aren't fastidious about declaring that
1020                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1021                        ;; can send us off into never-never land, since
1022                        ;; INDEX is initialized to -1.)
1023                        of-type index-or-minus-1
1024                        from (1- ,end) downto ,start do
1025                        (maybe-return))
1026                  (loop for ,index of-type index from ,start below ,end do
1027                        (maybe-return))))
1028            (values nil nil))))))
1029
1030 (def!macro %find-position-vector-macro (item sequence
1031                                              from-end start end key test)
1032   (with-unique-names (element)
1033     (%find-position-or-find-position-if-vector-expansion
1034      sequence
1035      from-end
1036      start
1037      end
1038      element
1039      ;; (See the LIST transform for a discussion of the correct
1040      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1041      ;; or after the checked sequence element.)
1042      `(funcall ,test ,item (funcall ,key ,element)))))
1043
1044 (def!macro %find-position-if-vector-macro (predicate sequence
1045                                                      from-end start end key)
1046   (with-unique-names (element)
1047     (%find-position-or-find-position-if-vector-expansion
1048      sequence
1049      from-end
1050      start
1051      end
1052      element
1053      `(funcall ,predicate (funcall ,key ,element)))))
1054
1055 (def!macro %find-position-if-not-vector-macro (predicate sequence
1056                                                          from-end start end key)
1057   (with-unique-names (element)
1058     (%find-position-or-find-position-if-vector-expansion
1059      sequence
1060      from-end
1061      start
1062      end
1063      element
1064      `(not (funcall ,predicate (funcall ,key ,element))))))
1065
1066 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1067 ;;; VECTOR data
1068 (deftransform %find-position-if ((predicate sequence from-end start end key)
1069                                  (function vector t t t function)
1070                                  *
1071                                  :policy (> speed space))
1072   "expand inline"
1073   (check-inlineability-of-find-position-if sequence from-end)
1074   '(%find-position-if-vector-macro predicate sequence
1075                                    from-end start end key))
1076
1077 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1078                                      (function vector t t t function)
1079                                      *
1080                                      :policy (> speed space))
1081   "expand inline"
1082   (check-inlineability-of-find-position-if sequence from-end)
1083   '(%find-position-if-not-vector-macro predicate sequence
1084                                        from-end start end key))
1085
1086 (deftransform %find-position ((item sequence from-end start end key test)
1087                               (t vector t t t function function)
1088                               *
1089                               :policy (> speed space))
1090   "expand inline"
1091   (check-inlineability-of-find-position-if sequence from-end)
1092   '(%find-position-vector-macro item sequence
1093                                 from-end start end key test))
1094
1095 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1096 ;;; POSITION-IF, etc.
1097 (define-source-transform effective-find-position-test (test test-not)
1098   (once-only ((test test)
1099               (test-not test-not))
1100     `(cond
1101       ((and ,test ,test-not)
1102        (error "can't specify both :TEST and :TEST-NOT"))
1103       (,test (%coerce-callable-to-fun ,test))
1104       (,test-not
1105        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1106        ;; inefficient, but since the TEST-NOT option is deprecated
1107        ;; anyway, we don't care.)
1108        (complement (%coerce-callable-to-fun ,test-not)))
1109       (t #'eql))))
1110 (define-source-transform effective-find-position-key (key)
1111   (once-only ((key key))
1112     `(if ,key
1113          (%coerce-callable-to-fun ,key)
1114          #'identity)))
1115
1116 (macrolet ((define-find-position (fun-name values-index)
1117              `(deftransform ,fun-name ((item sequence &key
1118                                              from-end (start 0) end
1119                                              key test test-not)
1120                                        (t (or list vector) &rest t))
1121                 '(nth-value ,values-index
1122                             (%find-position item sequence
1123                                             from-end start
1124                                             end
1125                                             (effective-find-position-key key)
1126                                             (effective-find-position-test
1127                                              test test-not))))))
1128   (define-find-position find 0)
1129   (define-find-position position 1))
1130
1131 (macrolet ((define-find-position-if (fun-name values-index)
1132              `(deftransform ,fun-name ((predicate sequence &key
1133                                                   from-end (start 0)
1134                                                   end key)
1135                                        (t (or list vector) &rest t))
1136                 '(nth-value
1137                   ,values-index
1138                   (%find-position-if (%coerce-callable-to-fun predicate)
1139                                      sequence from-end
1140                                      start end
1141                                      (effective-find-position-key key))))))
1142   (define-find-position-if find-if 0)
1143   (define-find-position-if position-if 1))
1144
1145 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1146 ;;; didn't bother to worry about optimizing them, except note that on
1147 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1148 ;;; sbcl-devel
1149 ;;;
1150 ;;;     My understanding is that while the :test-not argument is
1151 ;;;     deprecated in favour of :test (complement #'foo) because of
1152 ;;;     semantic difficulties (what happens if both :test and :test-not
1153 ;;;     are supplied, etc) the -if-not variants, while officially
1154 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1155 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1156 ;;;     reasons for allowing the -if-not versions equal status,
1157 ;;;     particularly remove-if-not (== filter).
1158 ;;;
1159 ;;;     This is only an informal understanding, I grant you, but
1160 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1161 ;;;     way as the others?
1162 ;;;
1163 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1164 ;;; implementation of SBCL.
1165 (macrolet ((define-find-position-if-not (fun-name values-index)
1166                `(deftransform ,fun-name ((predicate sequence &key
1167                                           from-end (start 0)
1168                                           end key)
1169                                          (t (or list vector) &rest t))
1170                  '(nth-value
1171                    ,values-index
1172                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1173                     sequence from-end
1174                     start end
1175                     (effective-find-position-key key))))))
1176   (define-find-position-if-not find-if-not 0)
1177   (define-find-position-if-not position-if-not 1))