src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places))
 137     (let ((found-vector-p nil))
 138       (flet ((process-vector (length)
 139                (unless found-vector-p
 140                  (setq found-vector-p t)
 141                  (bindings `(index 0 (1+ index)))
 142                  (declarations `(type index index)))
 143                (vector-lengths length)))
 144         (loop for seq of-type lvar in seqs
 145            for seq-name in seq-names
 146            for type = (lvar-type seq)
 147            do (cond ((csubtypep type (specifier-type 'list))
 148                      (with-unique-names (index)
 149                        (bindings `(,index ,seq-name (cdr ,index)))
 150                        (declarations `(type list ,index))
 151                        (places `(car ,index))
 152                        (tests `(endp ,index))))
 153                     ((csubtypep type (specifier-type 'vector))
 154                      (process-vector `(length ,seq-name))
 155                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 156                                 (aref ,seq-name index))))
 157                     (t
 158                      (give-up-ir1-transform
 159                       "can't determine sequence argument type"))))
 160         (when into
 161           (process-vector `(array-dimension ,into 0))))
 162       (when found-vector-p
 163         (bindings `(length (min ,@(vector-lengths))))
 164         (tests `(>= index length)))
 165       `(do (,@(bindings))
 166            ((or ,@(tests)) ,result)
 167          (declare ,@(declarations))
 168          (let ((funcall-result (funcall fun ,@(places))))
 169            (declare (ignorable funcall-result))
 170            ,body)))))
 171
 172 ;;; Try to compile %MAP efficiently when we can determine sequence
 173 ;;; argument types at compile time.
 174 ;;;
 175 ;;; Note: This transform was written to allow open coding of
 176 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 177 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 178 ;;; necessarily as efficient as possible. In particular, it will be
 179 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 180 ;;; numeric element types. It should be straightforward to make it
 181 ;;; handle that case more efficiently, but it's left as an exercise to
 182 ;;; the reader, because the code is complicated enough already and I
 183 ;;; don't happen to need that functionality right now. -- WHN 20000410
 184 (deftransform %map ((result-type fun seq &rest seqs) * *
 185                     :policy (>= speed space))
 186   "open code"
 187   (unless (constant-lvar-p result-type)
 188     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 189   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 190            (fn-1subtypep (fn x y)
 191              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 192                (if valid-p
 193                    subtype-p
 194                    (give-up-ir1-transform
 195                     "can't analyze sequence type relationship"))))
 196            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 197     (let* ((result-type-value (lvar-value result-type))
 198            (result-supertype (cond ((null result-type-value) 'null)
 199                                    ((1subtypep result-type-value 'vector)
 200                                     'vector)
 201                                    ((1subtypep result-type-value 'list)
 202                                     'list)
 203                                    (t
 204                                     (give-up-ir1-transform
 205                                      "result type unsuitable")))))
 206       (cond ((and result-type-value (null seqs))
 207              ;; The consing arity-1 cases can be implemented
 208              ;; reasonably efficiently as function calls, and the cost
 209              ;; of consing should be significantly larger than
 210              ;; function call overhead, so we always compile these
 211              ;; cases as full calls regardless of speed-versus-space
 212              ;; optimization policy.
 213              (cond ((subtypep result-type-value 'list)
 214                     '(%map-to-list-arity-1 fun seq))
 215                    ( ;; (This one can be inefficient due to COERCE, but
 216                     ;; the current open-coded implementation has the
 217                     ;; same problem.)
 218                     (subtypep result-type-value 'vector)
 219                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 220                              ',result-type-value))
 221                    (t (bug "impossible (?) sequence type"))))
 222             (t
 223              (let* ((seqs (cons seq seqs))
 224                     (seq-args (make-gensym-list (length seqs))))
 225                (multiple-value-bind (push-dacc result)
 226                    (ecase result-supertype
 227                      (null (values nil nil))
 228                      (list (values `(push funcall-result acc)
 229                                    `(nreverse acc)))
 230                      (vector (values `(push funcall-result acc)
 231                                      `(coerce (nreverse acc)
 232                                               ',result-type-value))))
 233                  ;; (We use the same idiom, of returning a LAMBDA from
 234                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 235                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 236                  ;; reason: we need to get the runtime values of each
 237                  ;; of the &REST vars.)
 238                  `(lambda (result-type fun ,@seq-args)
 239                     (declare (ignore result-type))
 240                     (let ((fun (%coerce-callable-to-fun fun))
 241                           (acc nil))
 242                       (declare (type list acc))
 243                       (declare (ignorable acc))
 244                       ,(build-sequence-iterator
 245                         seqs seq-args
 246                         :result result
 247                         :body push-dacc))))))))))
 248
 249 ;;; MAP-INTO
 250 (deftransform map-into ((result fun &rest seqs)
 251                         (vector * &rest *)
 252                         *)
 253   "open code"
 254   (let ((seqs-names (mapcar (lambda (x)
 255                               (declare (ignore x))
 256                               (gensym))
 257                             seqs)))
 258     `(lambda (result fun ,@seqs-names)
 259        ,(build-sequence-iterator
 260          seqs seqs-names
 261          :result '(when (array-has-fill-pointer-p result)
 262                    (setf (fill-pointer result) index))
 263          :into 'result
 264          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 265                  (setf (aref result index) funcall-result)))
 266        result)))
 267
 268 \f
 269 ;;; FIXME: once the confusion over doing transforms with known-complex
 270 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 271 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 272 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 273   '(aref s i))
 274
 275 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 276   '(nth i s))
 277
 278 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 279   '(%aset s i v))
 280
 281 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 282   '(setf (car (nthcdr i s)) v))
 283
 284 (deftransform %check-vector-sequence-bounds ((vector start end)
 285                                              (vector * *) *
 286                                              :node node)
 287   (if (policy node (< safety speed))
 288       '(or end (length vector))
 289       '(let ((length (length vector)))
 290         (if (<= 0 start (or end length) length)
 291             (or end length)
 292             (sb!impl::signal-bounding-indices-bad-error vector start end)))))
 293
 294 (defun transform-list-item-seek (name list key test test-not node)
 295   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 296   ;; not there at all. If it might be NIL, make up a form to that
 297   ;; ensure it is a function.
 298   (multiple-value-bind (key key-form)
 299       (if key
 300           (let ((key-type (lvar-type key))
 301                 (null-type (specifier-type 'null)))
 302             (cond ((csubtypep key-type null-type)
 303                    (values nil nil))
 304                   ((csubtypep null-type key-type)
 305                    (values key '(if key
 306                                  (%coerce-callable-to-fun key)
 307                                  #'identity)))
 308                   (t
 309                    (values key '(%coerce-callable-to-fun key))))))
 310     (let* ((funs (remove nil (list (and key 'key) (cond (test 'test)
 311                                                         (test-not 'test-not)))))
 312            (out-of-line (or (find-symbol (format nil "%~A~{-~A~}" name funs)
 313                                          (load-time-value (find-package "SB!KERNEL")))
 314                             (bug "Unknown list item seek transform: name=~S, funs=~S"
 315                                  name funs)))
 316            (target-expr (if key '(%funcall key target) 'target))
 317            (test-expr (cond (test `(%funcall test item ,target-expr))
 318                             (test-not `(not (%funcall test-not item ,target-expr)))
 319                             (t `(eql item ,target-expr)))))
 320       (labels ((open-code (tail)
 321                  (when tail
 322                    `(if (let ((this ',(car tail)))
 323                           ,(ecase name
 324                                   (assoc
 325                                    `(and this (let ((target (car this)))
 326                                                 ,test-expr)))
 327                                   (member
 328                                    `(let ((target this))
 329                                       ,test-expr))))
 330                         ',(ecase name
 331                                  (assoc (car tail))
 332                                  (member tail))
 333                         ,(open-code (cdr tail)))))
 334                (ensure-fun (fun)
 335                  (if (eq 'key fun)
 336                      key-form
 337                      `(%coerce-callable-to-fun ,fun))))
 338         (if (and (constant-lvar-p list) (policy node (>= speed space)))
 339             `(let ,(mapcar (lambda (fun) `(,fun ,(ensure-fun fun))) funs)
 340                ,(open-code (lvar-value list)))
 341             `(,out-of-line item list ,@(mapcar #'ensure-fun funs)))))))
 342
 343 (deftransform member ((item list &key key test test-not) * * :node node)
 344   (transform-list-item-seek 'member list key test test-not node))
 345
 346 (deftransform assoc ((item list &key key test test-not) * * :node node)
 347   (transform-list-item-seek 'assoc list key test test-not node))
 348
 349 (deftransform memq ((item list) (t (constant-arg list)))
 350   (labels ((rec (tail)
 351              (if tail
 352                  `(if (eq item ',(car tail))
 353                       ',tail
 354                       ,(rec (cdr tail)))
 355                  nil)))
 356     (rec (lvar-value list))))
 357
 358 ;;; A similar transform used to apply to MEMBER and ASSOC, but since
 359 ;;; TRANSFORM-LIST-ITEM-SEEK now takes care of them those transform
 360 ;;; would never fire, and (%MEMBER-TEST ITEM LIST #'EQ) should be
 361 ;;; almost as fast as MEMQ.
 362 (deftransform delete ((item list &key test) (t list &rest t) *)
 363   "convert to EQ test"
 364   ;; FIXME: The scope of this transformation could be
 365   ;; widened somewhat, letting it work whenever the test is
 366   ;; 'EQL and we know from the type of ITEM that it #'EQ
 367   ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 368   ;; and SYMBOL.)
 369   ;;   If TEST is EQ, apply transform, else
 370   ;;   if test is not EQL, then give up on transform, else
 371   ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 372   ;;   transform, else give up on transform.
 373   (cond (test
 374          (unless (lvar-fun-is test '(eq))
 375            (give-up-ir1-transform)))
 376         ((types-equal-or-intersect (lvar-type item)
 377                                    (specifier-type 'number))
 378          (give-up-ir1-transform "Item might be a number.")))
 379   `(delq item list))
 380
 381 (deftransform delete-if ((pred list) (t list))
 382   "open code"
 383   '(do ((x list (cdr x))
 384         (splice '()))
 385        ((endp x) list)
 386      (cond ((funcall pred (car x))
 387             (if (null splice)
 388                 (setq list (cdr x))
 389                 (rplacd splice (cdr x))))
 390            (t (setq splice x)))))
 391
 392 (deftransform fill ((seq item &key (start 0) (end (length seq)))
 393                     (vector t &key (:start t) (:end index))
 394                     *
 395                     :policy (> speed space))
 396   "open code"
 397   (let ((element-type (upgraded-element-type-specifier-or-give-up seq)))
 398     (values
 399      `(with-array-data ((data seq)
 400                         (start start)
 401                         (end end))
 402        (declare (type (simple-array ,element-type 1) data))
 403        (declare (type fixnum start end))
 404        (do ((i start (1+ i)))
 405            ((= i end) seq)
 406          (declare (type index i))
 407          ;; WITH-ARRAY-DATA did our range checks once and for all, so
 408          ;; it'd be wasteful to check again on every AREF...
 409          (declare (optimize (safety 0)))
 410          (setf (aref data i) item)))
 411      ;; ... though we still need to check that the new element can fit
 412      ;; into the vector in safe code. -- CSR, 2002-07-05
 413      `((declare (type ,element-type item))))))
 414 \f
 415 ;;;; utilities
 416
 417 ;;; Return true if LVAR's only use is a non-NOTINLINE reference to a
 418 ;;; global function with one of the specified NAMES.
 419 (defun lvar-fun-is (lvar names)
 420   (declare (type lvar lvar) (list names))
 421   (let ((use (lvar-uses lvar)))
 422     (and (ref-p use)
 423          (let ((leaf (ref-leaf use)))
 424            (and (global-var-p leaf)
 425                 (eq (global-var-kind leaf) :global-function)
 426                 (not (null (member (leaf-source-name leaf) names
 427                                    :test #'equal))))))))
 428
 429 ;;; If LVAR is a constant lvar, the return the constant value. If it
 430 ;;; is null, then return default, otherwise quietly give up the IR1
 431 ;;; transform.
 432 ;;;
 433 ;;; ### Probably should take an ARG and flame using the NAME.
 434 (defun constant-value-or-lose (lvar &optional default)
 435   (declare (type (or lvar null) lvar))
 436   (cond ((not lvar) default)
 437         ((constant-lvar-p lvar)
 438          (lvar-value lvar))
 439         (t
 440          (give-up-ir1-transform))))
 441
 442
 443 ;;;; hairy sequence transforms
 444
 445 ;;; FIXME: no hairy sequence transforms in SBCL?
 446 ;;;
 447 ;;; There used to be a bunch of commented out code about here,
 448 ;;; containing the (apparent) beginning of hairy sequence transform
 449 ;;; infrastructure. People interested in implementing better sequence
 450 ;;; transforms might want to look at it for inspiration, even though
 451 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 452 ;;; was deleted in 1.0.7.23.
 453 \f
 454 ;;;; string operations
 455
 456 ;;; We transform the case-sensitive string predicates into a non-keyword
 457 ;;; version. This is an IR1 transform so that we don't have to worry about
 458 ;;; changing the order of evaluation.
 459 (macrolet ((def (fun pred*)
 460              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 461                                                          (start2 0) end2)
 462                                    * *)
 463                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 464   (def string< string<*)
 465   (def string> string>*)
 466   (def string<= string<=*)
 467   (def string>= string>=*)
 468   (def string= string=*)
 469   (def string/= string/=*))
 470
 471 ;;; Return a form that tests the free variables STRING1 and STRING2
 472 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 473 ;;; start and end are also gotten from the environment. Both strings
 474 ;;; must be SIMPLE-BASE-STRINGs.
 475 (macrolet ((def (name lessp equalp)
 476              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 477                                    (simple-base-string simple-base-string t t t t) *)
 478                 `(let* ((end1 (if (not end1) (length string1) end1))
 479                         (end2 (if (not end2) (length string2) end2))
 480                         (index (sb!impl::%sp-string-compare
 481                                 string1 start1 end1 string2 start2 end2)))
 482                   (if index
 483                       (cond ((= index end1)
 484                              ,(if ',lessp 'index nil))
 485                             ((= (+ index (- start2 start1)) end2)
 486                              ,(if ',lessp nil 'index))
 487                             ((,(if ',lessp 'char< 'char>)
 488                                (schar string1 index)
 489                                (schar string2
 490                                       (truly-the index
 491                                                  (+ index
 492                                                     (truly-the fixnum
 493                                                                (- start2
 494                                                                   start1))))))
 495                              index)
 496                             (t nil))
 497                       ,(if ',equalp 'end1 nil))))))
 498   (def string<* t nil)
 499   (def string<=* t t)
 500   (def string>* nil nil)
 501   (def string>=* nil t))
 502
 503 (macrolet ((def (name result-fun)
 504              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 505                                    (simple-base-string simple-base-string t t t t) *)
 506                 `(,',result-fun
 507                   (sb!impl::%sp-string-compare
 508                    string1 start1 (or end1 (length string1))
 509                    string2 start2 (or end2 (length string2)))))))
 510   (def string=* not)
 511   (def string/=* identity))
 512
 513 \f
 514 ;;;; transforms for sequence functions
 515
 516 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 517 ;;; to vectors based on simple arrays.
 518 (def!constant vector-data-bit-offset
 519   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 520
 521 (eval-when (:compile-toplevel)
 522 (defun valid-bit-bash-saetp-p (saetp)
 523   ;; BIT-BASHing isn't allowed on simple vectors that contain pointers
 524   (and (not (eq t (sb!vm:saetp-specifier saetp)))
 525        ;; Disallowing (VECTOR NIL) also means that we won't transform
 526        ;; sequence functions into bit-bashing code and we let the
 527        ;; generic sequence functions signal errors if necessary.
 528        (not (zerop (sb!vm:saetp-n-bits saetp)))
 529        ;; Due to limitations with the current BIT-BASHing code, we can't
 530        ;; BIT-BASH reliably on arrays whose element types are larger
 531        ;; than the word size.
 532        (<= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)))
 533 ) ; EVAL-WHEN
 534
 535 ;;; FIXME: In the copy loops below, we code the loops in a strange
 536 ;;; fashion:
 537 ;;;
 538 ;;; (do ((i (+ src-offset length) (1- i)))
 539 ;;;     ((<= i 0) ...)
 540 ;;;   (... (aref foo (1- i)) ...))
 541 ;;;
 542 ;;; rather than the more natural (and seemingly more efficient):
 543 ;;;
 544 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 545 ;;;     ((< i 0) ...)
 546 ;;;   (... (aref foo i) ...))
 547 ;;;
 548 ;;; (more efficient because we don't have to do the index adjusting on
 549 ;;; every iteration of the loop)
 550 ;;;
 551 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 552 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 553 ;;; when used as an array index, the backend thinks I is a
 554 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 555 ;;; these as distinct storage classes, it cannot coerce a move from a
 556 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 557 ;;; deficiency is that we have two extra moves and increased register
 558 ;;; pressure, which can lead to some spectacularly bad register
 559 ;;; allocation.  (sub-FIXME: the register allocation even with the
 560 ;;; strangely written loops is not always excellent, either...).  Doing
 561 ;;; it the first way, above, means that I is always thought of as a
 562 ;;; POSITIVE-FIXNUM and there are no issues.
 563 ;;;
 564 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 565 ;;; adjustments in the first version into the array addressing at no
 566 ;;; performance penalty!
 567
 568 ;;; This transform is critical to the performance of string streams.  If
 569 ;;; you tweak it, make sure that you compare the disassembly, if not the
 570 ;;; performance of, the functions implementing string streams
 571 ;;; (e.g. SB!IMPL::STRING-OUCH).
 572 (macrolet
 573     ((define-replace-transforms ()
 574        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 575              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 576              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 577              collect
 578             `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 579                                     (,sequence-type ,sequence-type &rest t)
 580                                     ,sequence-type
 581                                     :node node)
 582                ,(cond
 583                  ((valid-bit-bash-saetp-p saetp) nil)
 584                  ;; If we're not bit-bashing, only allow cases where we
 585                  ;; can determine the order of copying up front.  (There
 586                  ;; are actually more cases we can handle if we know the
 587                  ;; amount that we're copying, but this handles the
 588                  ;; common cases.)
 589                  (t '(unless (= (constant-value-or-lose start1 0)
 590                               (constant-value-or-lose start2 0))
 591                       (give-up-ir1-transform))))
 592                `(let* ((len1 (length seq1))
 593                        (len2 (length seq2))
 594                        (end1 (or end1 len1))
 595                        (end2 (or end2 len2))
 596                        (replace-len1 (- end1 start1))
 597                        (replace-len2 (- end2 start2)))
 598                   ,(unless (policy node (= safety 0))
 599                            `(progn
 600                               (unless (<= 0 start1 end1 len1)
 601                                 (sb!impl::signal-bounding-indices-bad-error seq1 start1 end1))
 602                               (unless (<= 0 start2 end2 len2)
 603                                 (sb!impl::signal-bounding-indices-bad-error seq2 start2 end2))))
 604                   ,',(cond
 605                       ((valid-bit-bash-saetp-p saetp)
 606                        (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 607                               (bash-function (intern (format nil "UB~D-BASH-COPY" n-element-bits)
 608                                                      (find-package "SB!KERNEL"))))
 609                          `(funcall (function ,bash-function) seq2 start2
 610                                    seq1 start1 (min replace-len1 replace-len2))))
 611                       (t
 612                        ;; We can expand the loop inline here because we
 613                        ;; would have given up the transform (see above)
 614                        ;; if we didn't have constant matching start
 615                        ;; indices.
 616                        '(do ((i start1 (1+ i))
 617                              (end (+ start1
 618                                      (min replace-len1 replace-len2))))
 619                          ((>= i end))
 620                          (declare (optimize (insert-array-bounds-checks 0)))
 621                          (setf (aref seq1 i) (aref seq2 i)))))
 622                   seq1))
 623              into forms
 624              finally (return `(progn ,@forms)))))
 625   (define-replace-transforms))
 626
 627 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 628 ;;; defined as those cases where we are doing word-aligned copies from
 629 ;;; both the source and the destination and we are copying from the same
 630 ;;; offset from both the source and the destination.  (The last
 631 ;;; condition is there so we can determine the direction to copy at
 632 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 633 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 634 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 635 ;;; N)-size buffer and blitting in the old N-size buffer in.
 636
 637 (defun frob-bash-transform (src src-offset
 638                             dst dst-offset
 639                             length n-elems-per-word)
 640   (declare (ignore src dst length))
 641   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 642     (multiple-value-bind (src-word src-elt)
 643         (truncate (lvar-value src-offset) n-elems-per-word)
 644       (multiple-value-bind (dst-word dst-elt)
 645           (truncate (lvar-value dst-offset) n-elems-per-word)
 646         ;; Avoid non-word aligned copies.
 647         (unless (and (zerop src-elt) (zerop dst-elt))
 648           (give-up-ir1-transform))
 649         ;; Avoid copies where we would have to insert code for
 650         ;; determining the direction of copying.
 651         (unless (= src-word dst-word)
 652           (give-up-ir1-transform))
 653         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 654         ;; so we have to do its work here.
 655         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 656                                       'length
 657                                       `(truncate (the index length) ,n-elems-per-word)))))
 658            (declare (type index end))
 659            ;; Handle any bits at the end.
 660            (when (logtest length (1- ,n-elems-per-word))
 661              (let* ((extra (mod length ,n-elems-per-word))
 662                     ;; FIXME: The shift amount on this ASH is
 663                     ;; *always* negative, but the backend doesn't
 664                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 665                     ;; wind up with a pile of code that tests the
 666                     ;; sign of the shift count prior to shifting when
 667                     ;; all we need is a simple negate and shift
 668                     ;; right.  Yuck.
 669                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 670                                (* (- extra ,n-elems-per-word)
 671                                   ,n-bits-per-elem))))
 672                (setf (sb!kernel:%vector-raw-bits dst end)
 673                      (logior
 674                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 675                                 (ash mask
 676                                      ,(ecase sb!c:*backend-byte-order*
 677                                              (:little-endian 0)
 678                                              (:big-endian `(* (- ,n-elems-per-word extra)
 679                                                               ,n-bits-per-elem)))))
 680                       (logand (sb!kernel:%vector-raw-bits src end)
 681                               (ash mask
 682                                    ,(ecase sb!c:*backend-byte-order*
 683                                            (:little-endian 0)
 684                                            (:big-endian `(* (- ,n-elems-per-word extra)
 685                                                             ,n-bits-per-elem)))))))))
 686            ;; Copy from the end to save a register.
 687            (do ((i end (1- i)))
 688                ((<= i ,src-word))
 689              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 690                    (sb!kernel:%vector-raw-bits src (1- i)))))))))
 691
 692 #.(loop for i = 1 then (* i 2)
 693         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 694                                         "SB!KERNEL")
 695                                                         ((src src-offset
 696                                                           dst dst-offset
 697                                                           length)
 698                                                         ((simple-unboxed-array (*))
 699                                                          (constant-arg index)
 700                                                          (simple-unboxed-array (*))
 701                                                          (constant-arg index)
 702                                                          index)
 703                                                         *)
 704                   (frob-bash-transform src src-offset
 705                                        dst dst-offset length
 706                                        ,(truncate sb!vm:n-word-bits i))) into forms
 707         until (= i sb!vm:n-word-bits)
 708         finally (return `(progn ,@forms)))
 709
 710 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 711 ;;; arrays with elements of size >= the word size.  We do this because
 712 ;;; we know the arrays cannot alias (one was just consed), therefore we
 713 ;;; can determine at compile time the direction to copy, and for
 714 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 715 ;;; needless checking to figure out what's going on.  The same
 716 ;;; considerations apply if we are copying elements larger than the word
 717 ;;; size, with the additional twist that doing it inline is likely to
 718 ;;; cons far less than calling REPLACE and letting generic code do the
 719 ;;; work.
 720 ;;;
 721 ;;; However, we do not do this for elements whose size is < than the
 722 ;;; word size because we don't want to deal with any alignment issues
 723 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 724 ;;; anyway.
 725
 726 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 727                                       element-type)
 728   (let ((saetp (find-saetp element-type)))
 729     (aver saetp)
 730     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 731         (expand-aref-copy-loop src src-offset dst dst-offset length)
 732         `(locally (declare (optimize (safety 0)))
 733            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 734
 735 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 736   (if (eql src-offset dst-offset)
 737       `(do ((i (+ ,src-offset ,length) (1- i)))
 738            ((<= i ,src-offset))
 739          (declare (optimize (insert-array-bounds-checks 0)))
 740          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 741       ;; KLUDGE: The compiler is not able to derive that (+ offset
 742       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 743       ;; We, however, know it must be so, as by this point the bounds
 744       ;; have already been checked.
 745       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 746             (j (+ ,dst-offset ,length) (1- j)))
 747            ((<= i ,src-offset))
 748          (declare (optimize (insert-array-bounds-checks 0))
 749                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 750          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 751
 752 (deftransform subseq ((seq start &optional end)
 753                       ((or (simple-unboxed-array (*)) simple-vector) t &optional t)
 754                       * :node node)
 755   (let ((array-type (lvar-type seq)))
 756     (unless (array-type-p array-type)
 757       (give-up-ir1-transform))
 758     (let ((element-type (type-specifier (array-type-specialized-element-type array-type))))
 759       `(let* ((length (length seq))
 760               (end (or end length)))
 761          ,(unless (policy node (= safety 0))
 762                   '(progn
 763                     (unless (<= 0 start end length)
 764                       (sb!impl::signal-bounding-indices-bad-error seq start end))))
 765          (let* ((size (- end start))
 766                 (result (make-array size :element-type ',element-type)))
 767            ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
 768                                                     (lvar-value start)
 769                                                     'start)
 770                                            'result 0 'size element-type)
 771            result)))))
 772
 773 (deftransform copy-seq ((seq) ((or (simple-unboxed-array (*)) simple-vector)) *)
 774   (let ((array-type (lvar-type seq)))
 775     (unless (array-type-p array-type)
 776       (give-up-ir1-transform))
 777     (let ((element-type (type-specifier (array-type-specialized-element-type array-type))))
 778       `(let* ((length (length seq))
 779               (result (make-array length :element-type ',element-type)))
 780          ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
 781          result))))
 782
 783 ;;; FIXME: it really should be possible to take advantage of the
 784 ;;; macros used in code/seq.lisp here to avoid duplication of code,
 785 ;;; and enable even funkier transformations.
 786 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
 787                                (test #'eql)
 788                                (key #'identity)
 789                                from-end)
 790                       (vector vector &rest t)
 791                       *
 792                       :policy (> speed (max space safety)))
 793   "open code"
 794   (let ((from-end (when (lvar-p from-end)
 795                     (unless (constant-lvar-p from-end)
 796                       (give-up-ir1-transform ":FROM-END is not constant."))
 797                     (lvar-value from-end)))
 798         (keyp (lvar-p key))
 799         (testp (lvar-p test)))
 800     `(block search
 801        (let ((end1 (or end1 (length pattern)))
 802              (end2 (or end2 (length text)))
 803              ,@(when keyp
 804                      '((key (coerce key 'function))))
 805              ,@(when testp
 806                      '((test (coerce test 'function)))))
 807          (declare (type index start1 start2 end1 end2))
 808          (do (,(if from-end
 809                    '(index2 (- end2 (- end1 start1)) (1- index2))
 810                    '(index2 start2 (1+ index2))))
 811              (,(if from-end
 812                    '(< index2 start2)
 813                    '(>= index2 end2))
 814               nil)
 815            ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
 816            ;; terminates is hits -1 when :FROM-END is true and :START2
 817            ;; is 0.
 818            (declare (type fixnum index2))
 819            (when (do ((index1 start1 (1+ index1))
 820                       (index2 index2 (1+ index2)))
 821                      ((>= index1 end1) t)
 822                    (declare (type index index1 index2))
 823                    ,@(unless from-end
 824                              '((when (= index2 end2)
 825                                  (return-from search nil))))
 826                    (unless (,@(if testp
 827                                   '(funcall test)
 828                                   '(eql))
 829                               ,(if keyp
 830                                    '(funcall key (aref pattern index1))
 831                                    '(aref pattern index1))
 832                               ,(if keyp
 833                                    '(funcall key (aref text index2))
 834                                    '(aref text index2)))
 835                      (return nil)))
 836              (return index2)))))))
 837
 838 ;;; FIXME: It seems as though it should be possible to make a DEFUN
 839 ;;; %CONCATENATE (with a DEFTRANSFORM to translate constant RTYPE to
 840 ;;; CTYPE before calling %CONCATENATE) which is comparably efficient,
 841 ;;; at least once DYNAMIC-EXTENT works.
 842 ;;;
 843 ;;; FIXME: currently KLUDGEed because of bug 188
 844 ;;;
 845 ;;; FIXME: disabled for sb-unicode: probably want it back
 846 #!-sb-unicode
 847 (deftransform concatenate ((rtype &rest sequences)
 848                            (t &rest (or simple-base-string
 849                                         (simple-array nil (*))))
 850                            simple-base-string
 851                            :policy (< safety 3))
 852   (loop for rest-seqs on sequences
 853         for n-seq = (gensym "N-SEQ")
 854         for n-length = (gensym "N-LENGTH")
 855         for start = 0 then next-start
 856         for next-start = (gensym "NEXT-START")
 857         collect n-seq into args
 858         collect `(,n-length (length ,n-seq)) into lets
 859         collect n-length into all-lengths
 860         collect next-start into starts
 861         collect `(if (and (typep ,n-seq '(simple-array nil (*)))
 862                           (> ,n-length 0))
 863                      (error 'nil-array-accessed-error)
 864                      (#.(let* ((i (position 'character sb!kernel::*specialized-array-element-types*))
 865                                (saetp (aref sb!vm:*specialized-array-element-type-properties* i))
 866                                (n-bits (sb!vm:saetp-n-bits saetp)))
 867                           (intern (format nil "UB~D-BASH-COPY" n-bits)
 868                                   "SB!KERNEL"))
 869                         ,n-seq 0 res ,start ,n-length))
 870                 into forms
 871         collect `(setq ,next-start (+ ,start ,n-length)) into forms
 872         finally
 873         (return
 874           `(lambda (rtype ,@args)
 875              (declare (ignore rtype))
 876              (let* (,@lets
 877                     (res (make-string (the index (+ ,@all-lengths))
 878                                       :element-type 'base-char)))
 879                (declare (type index ,@all-lengths))
 880                (let (,@(mapcar (lambda (name) `(,name 0)) starts))
 881                  (declare (type index ,@starts))
 882                  ,@forms)
 883                res)))))
 884 \f
 885 ;;;; CONS accessor DERIVE-TYPE optimizers
 886
 887 (defoptimizer (car derive-type) ((cons))
 888   (let ((type (lvar-type cons))
 889         (null-type (specifier-type 'null)))
 890     (cond ((eq type null-type)
 891            null-type)
 892           ((cons-type-p type)
 893            (cons-type-car-type type)))))
 894
 895 (defoptimizer (cdr derive-type) ((cons))
 896   (let ((type (lvar-type cons))
 897         (null-type (specifier-type 'null)))
 898     (cond ((eq type null-type)
 899            null-type)
 900           ((cons-type-p type)
 901            (cons-type-cdr-type type)))))
 902 \f
 903 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
 904
 905 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
 906 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
 907 ;;; expansion, so we factor out the condition into this function.
 908 (defun check-inlineability-of-find-position-if (sequence from-end)
 909   (let ((ctype (lvar-type sequence)))
 910     (cond ((csubtypep ctype (specifier-type 'vector))
 911            ;; It's not worth trying to inline vector code unless we
 912            ;; know a fair amount about it at compile time.
 913            (upgraded-element-type-specifier-or-give-up sequence)
 914            (unless (constant-lvar-p from-end)
 915              (give-up-ir1-transform
 916               "FROM-END argument value not known at compile time")))
 917           ((csubtypep ctype (specifier-type 'list))
 918            ;; Inlining on lists is generally worthwhile.
 919            )
 920           (t
 921            (give-up-ir1-transform
 922             "sequence type not known at compile time")))))
 923
 924 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
 925 (macrolet ((def (name condition)
 926              `(deftransform ,name ((predicate sequence from-end start end key)
 927                                    (function list t t t function)
 928                                    *
 929                                    :policy (> speed space))
 930                 "expand inline"
 931                 `(let ((index 0)
 932                        (find nil)
 933                        (position nil))
 934                    (declare (type index index))
 935                    (dolist (i sequence
 936                             (if (and end (> end index))
 937                                 (sb!impl::signal-bounding-indices-bad-error
 938                                  sequence start end)
 939                                 (values find position)))
 940                      (let ((key-i (funcall key i)))
 941                        (when (and end (>= index end))
 942                          (return (values find position)))
 943                        (when (>= index start)
 944                          (,',condition (funcall predicate key-i)
 945                           ;; This hack of dealing with non-NIL
 946                           ;; FROM-END for list data by iterating
 947                           ;; forward through the list and keeping
 948                           ;; track of the last time we found a match
 949                           ;; might be more screwy than what the user
 950                           ;; expects, but it seems to be allowed by
 951                           ;; the ANSI standard. (And if the user is
 952                           ;; screwy enough to ask for FROM-END
 953                           ;; behavior on list data, turnabout is
 954                           ;; fair play.)
 955                           ;;
 956                           ;; It's also not enormously efficient,
 957                           ;; calling PREDICATE and KEY more often
 958                           ;; than necessary; but all the
 959                           ;; alternatives seem to have their own
 960                           ;; efficiency problems.
 961                           (if from-end
 962                               (setf find i
 963                                     position index)
 964                               (return (values i index))))))
 965                      (incf index))))))
 966   (def %find-position-if when)
 967   (def %find-position-if-not unless))
 968
 969 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
 970 ;;; without loss of efficiency. (I.e., the optimizer should be able
 971 ;;; to straighten everything out.)
 972 (deftransform %find-position ((item sequence from-end start end key test)
 973                               (t list t t t t t)
 974                               *
 975                               :policy (> speed space))
 976   "expand inline"
 977   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
 978                         ;; The order of arguments for asymmetric tests
 979                         ;; (e.g. #'<, as opposed to order-independent
 980                         ;; tests like #'=) is specified in the spec
 981                         ;; section 17.2.1 -- the O/Zi stuff there.
 982                         (lambda (i)
 983                           (funcall test-fun item i)))
 984                       sequence
 985                       from-end
 986                       start
 987                       end
 988                       (%coerce-callable-to-fun key)))
 989
 990 ;;; The inline expansions for the VECTOR case are saved as macros so
 991 ;;; that we can share them between the DEFTRANSFORMs and the default
 992 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
 993 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
 994 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
 995                                                             from-end
 996                                                             start
 997                                                             end-arg
 998                                                             element
 999                                                             done-p-expr)
1000   (with-unique-names (offset block index n-sequence sequence n-end end)
1001     `(let ((,n-sequence ,sequence-arg)
1002            (,n-end ,end-arg))
1003        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1004                          (,start ,start)
1005                          (,end (%check-vector-sequence-bounds
1006                                 ,n-sequence ,start ,n-end)))
1007          (block ,block
1008            (macrolet ((maybe-return ()
1009                         ;; WITH-ARRAY-DATA has already performed bounds
1010                         ;; checking, so we can safely elide the checks
1011                         ;; in the inner loop.
1012                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1013                                            (aref ,sequence ,index))))
1014                            (when ,done-p-expr
1015                              (return-from ,block
1016                                (values ,element
1017                                        (- ,index ,offset)))))))
1018              (if ,from-end
1019                  (loop for ,index
1020                        ;; (If we aren't fastidious about declaring that
1021                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1022                        ;; can send us off into never-never land, since
1023                        ;; INDEX is initialized to -1.)
1024                        of-type index-or-minus-1
1025                        from (1- ,end) downto ,start do
1026                        (maybe-return))
1027                  (loop for ,index of-type index from ,start below ,end do
1028                        (maybe-return))))
1029            (values nil nil))))))
1030
1031 (def!macro %find-position-vector-macro (item sequence
1032                                              from-end start end key test)
1033   (with-unique-names (element)
1034     (%find-position-or-find-position-if-vector-expansion
1035      sequence
1036      from-end
1037      start
1038      end
1039      element
1040      ;; (See the LIST transform for a discussion of the correct
1041      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1042      ;; or after the checked sequence element.)
1043      `(funcall ,test ,item (funcall ,key ,element)))))
1044
1045 (def!macro %find-position-if-vector-macro (predicate sequence
1046                                                      from-end start end key)
1047   (with-unique-names (element)
1048     (%find-position-or-find-position-if-vector-expansion
1049      sequence
1050      from-end
1051      start
1052      end
1053      element
1054      `(funcall ,predicate (funcall ,key ,element)))))
1055
1056 (def!macro %find-position-if-not-vector-macro (predicate sequence
1057                                                          from-end start end key)
1058   (with-unique-names (element)
1059     (%find-position-or-find-position-if-vector-expansion
1060      sequence
1061      from-end
1062      start
1063      end
1064      element
1065      `(not (funcall ,predicate (funcall ,key ,element))))))
1066
1067 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1068 ;;; VECTOR data
1069 (deftransform %find-position-if ((predicate sequence from-end start end key)
1070                                  (function vector t t t function)
1071                                  *
1072                                  :policy (> speed space))
1073   "expand inline"
1074   (check-inlineability-of-find-position-if sequence from-end)
1075   '(%find-position-if-vector-macro predicate sequence
1076                                    from-end start end key))
1077
1078 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1079                                      (function vector t t t function)
1080                                      *
1081                                      :policy (> speed space))
1082   "expand inline"
1083   (check-inlineability-of-find-position-if sequence from-end)
1084   '(%find-position-if-not-vector-macro predicate sequence
1085                                        from-end start end key))
1086
1087 (deftransform %find-position ((item sequence from-end start end key test)
1088                               (t vector t t t function function)
1089                               *
1090                               :policy (> speed space))
1091   "expand inline"
1092   (check-inlineability-of-find-position-if sequence from-end)
1093   '(%find-position-vector-macro item sequence
1094                                 from-end start end key test))
1095
1096 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1097 ;;; POSITION-IF, etc.
1098 (define-source-transform effective-find-position-test (test test-not)
1099   (once-only ((test test)
1100               (test-not test-not))
1101     `(cond
1102       ((and ,test ,test-not)
1103        (error "can't specify both :TEST and :TEST-NOT"))
1104       (,test (%coerce-callable-to-fun ,test))
1105       (,test-not
1106        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1107        ;; inefficient, but since the TEST-NOT option is deprecated
1108        ;; anyway, we don't care.)
1109        (complement (%coerce-callable-to-fun ,test-not)))
1110       (t #'eql))))
1111 (define-source-transform effective-find-position-key (key)
1112   (once-only ((key key))
1113     `(if ,key
1114          (%coerce-callable-to-fun ,key)
1115          #'identity)))
1116
1117 (macrolet ((define-find-position (fun-name values-index)
1118              `(deftransform ,fun-name ((item sequence &key
1119                                              from-end (start 0) end
1120                                              key test test-not)
1121                                        (t (or list vector) &rest t))
1122                 '(nth-value ,values-index
1123                             (%find-position item sequence
1124                                             from-end start
1125                                             end
1126                                             (effective-find-position-key key)
1127                                             (effective-find-position-test
1128                                              test test-not))))))
1129   (define-find-position find 0)
1130   (define-find-position position 1))
1131
1132 (macrolet ((define-find-position-if (fun-name values-index)
1133              `(deftransform ,fun-name ((predicate sequence &key
1134                                                   from-end (start 0)
1135                                                   end key)
1136                                        (t (or list vector) &rest t))
1137                 '(nth-value
1138                   ,values-index
1139                   (%find-position-if (%coerce-callable-to-fun predicate)
1140                                      sequence from-end
1141                                      start end
1142                                      (effective-find-position-key key))))))
1143   (define-find-position-if find-if 0)
1144   (define-find-position-if position-if 1))
1145
1146 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1147 ;;; didn't bother to worry about optimizing them, except note that on
1148 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1149 ;;; sbcl-devel
1150 ;;;
1151 ;;;     My understanding is that while the :test-not argument is
1152 ;;;     deprecated in favour of :test (complement #'foo) because of
1153 ;;;     semantic difficulties (what happens if both :test and :test-not
1154 ;;;     are supplied, etc) the -if-not variants, while officially
1155 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1156 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1157 ;;;     reasons for allowing the -if-not versions equal status,
1158 ;;;     particularly remove-if-not (== filter).
1159 ;;;
1160 ;;;     This is only an informal understanding, I grant you, but
1161 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1162 ;;;     way as the others?
1163 ;;;
1164 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1165 ;;; implementation of SBCL.
1166 (macrolet ((define-find-position-if-not (fun-name values-index)
1167                `(deftransform ,fun-name ((predicate sequence &key
1168                                           from-end (start 0)
1169                                           end key)
1170                                          (t (or list vector) &rest t))
1171                  '(nth-value
1172                    ,values-index
1173                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1174                     sequence from-end
1175                     start end
1176                     (effective-find-position-key key))))))
1177   (define-find-position-if-not find-if-not 0)
1178   (define-find-position-if-not position-if-not 1))