src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places))
 137     (let ((found-vector-p nil))
 138       (flet ((process-vector (length)
 139                (unless found-vector-p
 140                  (setq found-vector-p t)
 141                  (bindings `(index 0 (1+ index)))
 142                  (declarations `(type index index)))
 143                (vector-lengths length)))
 144         (loop for seq of-type lvar in seqs
 145            for seq-name in seq-names
 146            for type = (lvar-type seq)
 147            do (cond ((csubtypep type (specifier-type 'list))
 148                      (with-unique-names (index)
 149                        (bindings `(,index ,seq-name (cdr ,index)))
 150                        (declarations `(type list ,index))
 151                        (places `(car ,index))
 152                        (tests `(endp ,index))))
 153                     ((csubtypep type (specifier-type 'vector))
 154                      (process-vector `(length ,seq-name))
 155                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 156                                 (aref ,seq-name index))))
 157                     (t
 158                      (give-up-ir1-transform
 159                       "can't determine sequence argument type"))))
 160         (when into
 161           (process-vector `(array-dimension ,into 0))))
 162       (when found-vector-p
 163         (bindings `(length (min ,@(vector-lengths))))
 164         (tests `(>= index length)))
 165       `(do (,@(bindings))
 166            ((or ,@(tests)) ,result)
 167          (declare ,@(declarations))
 168          (let ((funcall-result (funcall fun ,@(places))))
 169            (declare (ignorable funcall-result))
 170            ,body)))))
 171
 172 ;;; Try to compile %MAP efficiently when we can determine sequence
 173 ;;; argument types at compile time.
 174 ;;;
 175 ;;; Note: This transform was written to allow open coding of
 176 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 177 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 178 ;;; necessarily as efficient as possible. In particular, it will be
 179 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 180 ;;; numeric element types. It should be straightforward to make it
 181 ;;; handle that case more efficiently, but it's left as an exercise to
 182 ;;; the reader, because the code is complicated enough already and I
 183 ;;; don't happen to need that functionality right now. -- WHN 20000410
 184 (deftransform %map ((result-type fun seq &rest seqs) * *
 185                     :policy (>= speed space))
 186   "open code"
 187   (unless (constant-lvar-p result-type)
 188     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 189   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 190            (fn-1subtypep (fn x y)
 191              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 192                (if valid-p
 193                    subtype-p
 194                    (give-up-ir1-transform
 195                     "can't analyze sequence type relationship"))))
 196            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 197     (let* ((result-type-value (lvar-value result-type))
 198            (result-supertype (cond ((null result-type-value) 'null)
 199                                    ((1subtypep result-type-value 'vector)
 200                                     'vector)
 201                                    ((1subtypep result-type-value 'list)
 202                                     'list)
 203                                    (t
 204                                     (give-up-ir1-transform
 205                                      "result type unsuitable")))))
 206       (cond ((and result-type-value (null seqs))
 207              ;; The consing arity-1 cases can be implemented
 208              ;; reasonably efficiently as function calls, and the cost
 209              ;; of consing should be significantly larger than
 210              ;; function call overhead, so we always compile these
 211              ;; cases as full calls regardless of speed-versus-space
 212              ;; optimization policy.
 213              (cond ((subtypep result-type-value 'list)
 214                     '(%map-to-list-arity-1 fun seq))
 215                    ( ;; (This one can be inefficient due to COERCE, but
 216                     ;; the current open-coded implementation has the
 217                     ;; same problem.)
 218                     (subtypep result-type-value 'vector)
 219                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 220                              ',result-type-value))
 221                    (t (bug "impossible (?) sequence type"))))
 222             (t
 223              (let* ((seqs (cons seq seqs))
 224                     (seq-args (make-gensym-list (length seqs))))
 225                (multiple-value-bind (push-dacc result)
 226                    (ecase result-supertype
 227                      (null (values nil nil))
 228                      (list (values `(push funcall-result acc)
 229                                    `(nreverse acc)))
 230                      (vector (values `(push funcall-result acc)
 231                                      `(coerce (nreverse acc)
 232                                               ',result-type-value))))
 233                  ;; (We use the same idiom, of returning a LAMBDA from
 234                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 235                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 236                  ;; reason: we need to get the runtime values of each
 237                  ;; of the &REST vars.)
 238                  `(lambda (result-type fun ,@seq-args)
 239                     (declare (ignore result-type))
 240                     (let ((fun (%coerce-callable-to-fun fun))
 241                           (acc nil))
 242                       (declare (type list acc))
 243                       (declare (ignorable acc))
 244                       ,(build-sequence-iterator
 245                         seqs seq-args
 246                         :result result
 247                         :body push-dacc))))))))))
 248
 249 ;;; MAP-INTO
 250 (deftransform map-into ((result fun &rest seqs)
 251                         (vector * &rest *)
 252                         *)
 253   "open code"
 254   (let ((seqs-names (mapcar (lambda (x)
 255                               (declare (ignore x))
 256                               (gensym))
 257                             seqs)))
 258     `(lambda (result fun ,@seqs-names)
 259        ,(build-sequence-iterator
 260          seqs seqs-names
 261          :result '(when (array-has-fill-pointer-p result)
 262                    (setf (fill-pointer result) index))
 263          :into 'result
 264          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 265                  (setf (aref result index) funcall-result)))
 266        result)))
 267
 268 \f
 269 ;;; FIXME: once the confusion over doing transforms with known-complex
 270 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 271 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 272 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 273   '(aref s i))
 274
 275 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 276   '(nth i s))
 277
 278 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 279   '(%aset s i v))
 280
 281 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 282   '(setf (car (nthcdr i s)) v))
 283
 284 (deftransform %check-vector-sequence-bounds ((vector start end)
 285                                              (vector * *) *
 286                                              :node node)
 287   (if (policy node (= 0 insert-array-bounds-checks))
 288       '(or end (length vector))
 289       '(let ((length (length vector)))
 290          (if (<= 0 start (or end length) length)
 291              (or end length)
 292              (sequence-bounding-indices-bad-error vector start end)))))
 293
 294 (def!type eq-comparable-type ()
 295   '(or fixnum (not number)))
 296
 297 ;;; True if EQL comparisons involving type can be simplified to EQ.
 298 (defun eq-comparable-type-p (type)
 299   (csubtypep type (specifier-type 'eq-comparable-type)))
 300
 301 (defun specialized-list-seek-function-name (function-name key-functions &optional variant)
 302   (or (find-symbol (with-output-to-string (s)
 303                      ;; Write "%NAME-FUN1-FUN2-FUN3", etc. Not only is
 304                      ;; this ever so slightly faster then FORMAT, this
 305                      ;; way we are also proof against *PRINT-CASE*
 306                      ;; frobbing and such.
 307                      (write-char #\% s)
 308                      (write-string (symbol-name function-name) s)
 309                      (dolist (f key-functions)
 310                        (write-char #\- s)
 311                        (write-string (symbol-name f) s))
 312                      (when variant
 313                        (write-char #\- s)
 314                        (write-string (symbol-name variant) s)))
 315                    (load-time-value (find-package "SB!KERNEL")))
 316       (bug "Unknown list item seek transform: name=~S, key-functions=~S variant=~S"
 317            function-name key-functions variant)))
 318
 319 (defun transform-list-item-seek (name item list key test test-not node)
 320   (when (and test test-not)
 321     (abort-ir1-transform "Both ~S and ~S supplied to ~S." :test :test-not name))
 322   ;; If TEST is EQL, drop it.
 323   (when (and test (lvar-fun-is test '(eql)))
 324     (setf test nil))
 325   ;; Ditto for KEY IDENTITY.
 326   (when (and key (lvar-fun-is key '(identity)))
 327     (setf key nil))
 328   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 329   ;; not there at all. If it might be NIL, make up a form to that
 330   ;; ensures it is a function.
 331   (multiple-value-bind (key key-form)
 332       (when key
 333         (let ((key-type (lvar-type key))
 334               (null-type (specifier-type 'null)))
 335           (cond ((csubtypep key-type null-type)
 336                  (values nil nil))
 337                 ((csubtypep null-type key-type)
 338                  (values key '(if key
 339                                (%coerce-callable-to-fun key)
 340                                #'identity)))
 341                 (t
 342                  (values key (ensure-lvar-fun-form key 'key))))))
 343     (let* ((c-test (cond ((and test (lvar-fun-is test '(eq)))
 344                           (setf test nil)
 345                           'eq)
 346                          ((and (not test) (not test-not))
 347                           (when (eq-comparable-type-p (lvar-type item))
 348                             'eq))))
 349            (funs (delete nil (list (when key (list key 'key))
 350                                    (when test (list test 'test))
 351                                    (when test-not (list test-not 'test-not)))))
 352            (target-expr (if key '(%funcall key target) 'target))
 353            (test-expr (cond (test `(%funcall test item ,target-expr))
 354                             (test-not `(not (%funcall test-not item ,target-expr)))
 355                             (c-test `(,c-test item ,target-expr))
 356                             (t `(eql item ,target-expr)))))
 357       (labels ((open-code (tail)
 358                  (when tail
 359                    `(if (let ((this ',(car tail)))
 360                           ,(ecase name
 361                                   ((assoc rassoc)
 362                                    (let ((cxx (if (eq name 'assoc) 'car 'cdr)))
 363                                      `(and this (let ((target (,cxx this)))
 364                                                   ,test-expr))))
 365                                   (member
 366                                    `(let ((target this))
 367                                       ,test-expr))))
 368                         ',(ecase name
 369                                  ((assoc rassoc) (car tail))
 370                                  (member tail))
 371                         ,(open-code (cdr tail)))))
 372                (ensure-fun (args)
 373                  (if (eq 'key (second args))
 374                      key-form
 375                      (apply #'ensure-lvar-fun-form args))))
 376         (let* ((cp (constant-lvar-p list))
 377                (c-list (when cp (lvar-value list))))
 378           (cond ((and cp c-list (member name '(assoc rassoc member))
 379                       (policy node (>= speed space)))
 380                  `(let ,(mapcar (lambda (fun) `(,(second fun) ,(ensure-fun fun))) funs)
 381                     ,(open-code c-list)))
 382                 ((and cp (not c-list))
 383                  ;; constant nil list
 384                  (if (eq name 'adjoin)
 385                      '(list item)
 386                      nil))
 387                 (t
 388                  ;; specialized out-of-line version
 389                  `(,(specialized-list-seek-function-name name (mapcar #'second funs) c-test)
 390                     item list ,@(mapcar #'ensure-fun funs)))))))))
 391
 392 (defun transform-list-pred-seek (name pred list key node)
 393   ;; If KEY is IDENTITY, drop it.
 394   (when (and key (lvar-fun-is key '(identity)))
 395     (setf key nil))
 396   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 397   ;; not there at all. If it might be NIL, make up a form to that
 398   ;; ensures it is a function.
 399   (multiple-value-bind (key key-form)
 400       (when key
 401         (let ((key-type (lvar-type key))
 402               (null-type (specifier-type 'null)))
 403           (cond ((csubtypep key-type null-type)
 404                  (values nil nil))
 405                 ((csubtypep null-type key-type)
 406                  (values key '(if key
 407                                (%coerce-callable-to-fun key)
 408                                #'identity)))
 409                 (t
 410                  (values key (ensure-lvar-fun-form key 'key))))))
 411     (let ((test-expr `(%funcall pred ,(if key '(%funcall key target) 'target)))
 412           (pred-expr (ensure-lvar-fun-form pred 'pred)))
 413       (when (member name '(member-if-not assoc-if-not rassoc-if-not))
 414         (setf test-expr `(not ,test-expr)))
 415       (labels ((open-code (tail)
 416                  (when tail
 417                    `(if (let ((this ',(car tail)))
 418                           ,(ecase name
 419                                   ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 420                                    (let ((cxx (if (member name '(assoc-if assoc-if-not)) 'car 'cdr)))
 421                                      `(and this (let ((target (,cxx this)))
 422                                                   ,test-expr))))
 423                                   ((member-if member-if-not)
 424                                    `(let ((target this))
 425                                       ,test-expr))))
 426                         ',(ecase name
 427                                  ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 428                                   (car tail))
 429                                  ((member-if member-if-not)
 430                                   tail))
 431                         ,(open-code (cdr tail))))))
 432         (let* ((cp (constant-lvar-p list))
 433                (c-list (when cp (lvar-value list))))
 434           (cond ((and cp c-list (policy node (>= speed space)))
 435                  `(let ((pred ,pred-expr)
 436                         ,@(when key `((key ,key-form))))
 437                     ,(open-code c-list)))
 438                 ((and cp (not c-list))
 439                  ;; constant nil list -- nothing to find!
 440                  nil)
 441                 (t
 442                  ;; specialized out-of-line version
 443                  `(,(specialized-list-seek-function-name name (when key '(key)))
 444                     ,pred-expr list ,@(when key (list key-form))))))))))
 445
 446 (macrolet ((def (name &optional if/if-not)
 447              (let ((basic (symbolicate "%" name))
 448                    (basic-eq (symbolicate "%" name "-EQ"))
 449                    (basic-key (symbolicate "%" name "-KEY"))
 450                    (basic-key-eq (symbolicate "%" name "-KEY-EQ")))
 451                `(progn
 452                   (deftransform ,name ((item list &key key test test-not) * * :node node)
 453                     (transform-list-item-seek ',name item list key test test-not node))
 454                   (deftransform ,basic ((item list) (eq-comparable-type t))
 455                     `(,',basic-eq item list))
 456                   (deftransform ,basic-key ((item list) (eq-comparable-type t))
 457                     `(,',basic-key-eq item list))
 458                   ,@(when if/if-not
 459                           (let ((if-name (symbolicate name "-IF"))
 460                                 (if-not-name (symbolicate name "-IF-NOT")))
 461                             `((deftransform ,if-name ((pred list &key key) * * :node node)
 462                                 (transform-list-pred-seek ',if-name pred list key node))
 463                               (deftransform ,if-not-name ((pred list &key key) * * :node node)
 464                                 (transform-list-pred-seek ',if-not-name pred list key node)))))))))
 465   (def adjoin)
 466   (def assoc  t)
 467   (def member t)
 468   (def rassoc t))
 469
 470 (deftransform memq ((item list) (t (constant-arg list)))
 471   (labels ((rec (tail)
 472              (if tail
 473                  `(if (eq item ',(car tail))
 474                       ',tail
 475                       ,(rec (cdr tail)))
 476                  nil)))
 477     (rec (lvar-value list))))
 478
 479 ;;; A similar transform used to apply to MEMBER and ASSOC, but since
 480 ;;; TRANSFORM-LIST-ITEM-SEEK now takes care of them those transform
 481 ;;; would never fire, and (%MEMBER-TEST ITEM LIST #'EQ) should be
 482 ;;; almost as fast as MEMQ.
 483 (deftransform delete ((item list &key test) (t list &rest t) *)
 484   "convert to EQ test"
 485   (let ((type (lvar-type item)))
 486     (unless (or (and test (lvar-fun-is test '(eq)))
 487                 (and (eq-comparable-type-p type)
 488                      (or (not test) (lvar-fun-is test '(eql)))))
 489       (give-up-ir1-transform)))
 490   `(delq item list))
 491
 492 (deftransform delete-if ((pred list) (t list))
 493   "open code"
 494   '(do ((x list (cdr x))
 495         (splice '()))
 496        ((endp x) list)
 497      (cond ((funcall pred (car x))
 498             (if (null splice)
 499                 (setq list (cdr x))
 500                 (rplacd splice (cdr x))))
 501            (t (setq splice x)))))
 502
 503 (deftransform fill ((seq item &key (start 0) (end nil))
 504                     (list t &key (:start t) (:end t)))
 505   '(list-fill* seq item start end))
 506
 507 (deftransform fill ((seq item &key (start 0) (end nil))
 508                     (vector t &key (:start t) (:end t))
 509                     *
 510                     :node node)
 511   (let* ((type (lvar-type seq))
 512          (element-ctype (array-type-upgraded-element-type type))
 513          (element-type (type-specifier element-ctype))
 514          (saetp (unless (eq *wild-type* element-ctype)
 515                   (find-saetp-by-ctype element-ctype))))
 516     (cond ((eq *wild-type* element-ctype)
 517            (delay-ir1-transform node :constraint)
 518            `(vector-fill* seq item start end))
 519           ((and saetp (sb!vm::valid-bit-bash-saetp-p saetp))
 520            (let* ((n-bits (sb!vm:saetp-n-bits saetp))
 521                   (basher-name (format nil "UB~D-BASH-FILL" n-bits))
 522                   (basher (or (find-symbol basher-name
 523                                            (load-time-value (find-package :sb!kernel)))
 524                               (abort-ir1-transform
 525                                "Unknown fill basher, please report to sbcl-devel: ~A"
 526                                basher-name)))
 527                   (kind (cond ((sb!vm:saetp-fixnum-p saetp) :tagged)
 528                               ((member element-type '(character base-char)) :char)
 529                               ((eq element-type 'single-float) :single-float)
 530                               #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 531                               ((eq element-type 'double-float) :double-float)
 532                               #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 533                               ((equal element-type '(complex single-float))
 534                                :complex-single-float)
 535                               (t
 536                                (aver (integer-type-p element-ctype))
 537                                :bits)))
 538                   ;; BASH-VALUE is a word that we can repeatedly smash
 539                   ;; on the array: for less-than-word sized elements it
 540                   ;; contains multiple copies of the fill item.
 541                   (bash-value
 542                    (if (constant-lvar-p item)
 543                        (let ((tmp (lvar-value item)))
 544                          (unless (ctypep tmp element-ctype)
 545                            (abort-ir1-transform "~S is not ~S" tmp element-type))
 546                          (let* ((bits
 547                                  (ldb (byte n-bits 0)
 548                                       (ecase kind
 549                                         (:tagged
 550                                          (ash tmp sb!vm:n-fixnum-tag-bits))
 551                                         (:char
 552                                          (char-code tmp))
 553                                         (:bits
 554                                          tmp)
 555                                         (:single-float
 556                                          (single-float-bits tmp))
 557                                         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 558                                         (:double-float
 559                                          (logior (ash (double-float-high-bits tmp) 32)
 560                                                  (double-float-low-bits tmp)))
 561                                         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 562                                         (:complex-single-float
 563                                          (logior (ash (single-float-bits (imagpart tmp)) 32)
 564                                                  (ldb (byte 32 0)
 565                                                       (single-float-bits (realpart tmp))))))))
 566                                 (res bits))
 567                            (loop for i of-type sb!vm:word from n-bits by n-bits
 568                                  until (= i sb!vm:n-word-bits)
 569                                  do (setf res (ldb (byte sb!vm:n-word-bits 0)
 570                                                    (logior res (ash bits i)))))
 571                            res))
 572                        (progn
 573                          (delay-ir1-transform node :constraint)
 574                         `(let* ((bits (ldb (byte ,n-bits 0)
 575                                            ,(ecase kind
 576                                                    (:tagged
 577                                                     `(ash item ,sb!vm:n-fixnum-tag-bits))
 578                                                    (:char
 579                                                     `(char-code item))
 580                                                    (:bits
 581                                                     `item)
 582                                                    (:single-float
 583                                                     `(single-float-bits item))
 584                                                    #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 585                                                    (:double-float
 586                                                     `(logior (ash (double-float-high-bits item) 32)
 587                                                              (double-float-low-bits item)))
 588                                                    #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 589                                                    (:complex-single-float
 590                                                     `(logior (ash (single-float-bits (imagpart item)) 32)
 591                                                              (ldb (byte 32 0)
 592                                                                   (single-float-bits (realpart item))))))))
 593                                 (res bits))
 594                            (declare (type sb!vm:word res))
 595                            ,@(unless (= sb!vm:n-word-bits n-bits)
 596                                      `((loop for i of-type sb!vm:word from ,n-bits by ,n-bits
 597                                              until (= i sb!vm:n-word-bits)
 598                                              do (setf res
 599                                                       (ldb (byte ,sb!vm:n-word-bits 0)
 600                                                            (logior res (ash bits (truly-the (integer 0 ,(- sb!vm:n-word-bits n-bits)) i))))))))
 601                            res)))))
 602              (values
 603               `(with-array-data ((data seq)
 604                                  (start start)
 605                                  (end end)
 606                                  :check-fill-pointer t)
 607                  (declare (type (simple-array ,element-type 1) data))
 608                  (declare (type index start end))
 609                  (declare (optimize (safety 0) (speed 3))
 610                           (muffle-conditions compiler-note))
 611                  (,basher ,bash-value data start (- end start))
 612                  seq)
 613               `((declare (type ,element-type item))))))
 614           ((policy node (> speed space))
 615            (values
 616             `(with-array-data ((data seq)
 617                                (start start)
 618                                (end end)
 619                                :check-fill-pointer t)
 620                (declare (type (simple-array ,element-type 1) data))
 621                (declare (type index start end))
 622                ;; WITH-ARRAY-DATA did our range checks once and for all, so
 623                ;; it'd be wasteful to check again on every AREF...
 624                (declare (optimize (safety 0) (speed 3)))
 625                (do ((i start (1+ i)))
 626                    ((= i end) seq)
 627                  (declare (type index i))
 628                  (setf (aref data i) item)))
 629             ;; ... though we still need to check that the new element can fit
 630             ;; into the vector in safe code. -- CSR, 2002-07-05
 631             `((declare (type ,element-type item)))))
 632           ((csubtypep type (specifier-type 'string))
 633            '(string-fill* seq item start end))
 634           (t
 635            '(vector-fill* seq item start end)))))
 636
 637 (deftransform fill ((seq item &key (start 0) (end nil))
 638                     ((and sequence (not vector) (not list)) t &key (:start t) (:end t)))
 639   `(sb!sequence:fill seq item
 640                      :start start
 641                      :end (%check-generic-sequence-bounds seq start end)))
 642 \f
 643 ;;;; hairy sequence transforms
 644
 645 ;;; FIXME: no hairy sequence transforms in SBCL?
 646 ;;;
 647 ;;; There used to be a bunch of commented out code about here,
 648 ;;; containing the (apparent) beginning of hairy sequence transform
 649 ;;; infrastructure. People interested in implementing better sequence
 650 ;;; transforms might want to look at it for inspiration, even though
 651 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 652 ;;; was deleted in 1.0.7.23.
 653 \f
 654 ;;;; string operations
 655
 656 ;;; We transform the case-sensitive string predicates into a non-keyword
 657 ;;; version. This is an IR1 transform so that we don't have to worry about
 658 ;;; changing the order of evaluation.
 659 (macrolet ((def (fun pred*)
 660              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 661                                                          (start2 0) end2)
 662                                    * *)
 663                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 664   (def string< string<*)
 665   (def string> string>*)
 666   (def string<= string<=*)
 667   (def string>= string>=*)
 668   (def string= string=*)
 669   (def string/= string/=*))
 670
 671 ;;; Return a form that tests the free variables STRING1 and STRING2
 672 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 673 ;;; start and end are also gotten from the environment. Both strings
 674 ;;; must be SIMPLE-BASE-STRINGs.
 675 (macrolet ((def (name lessp equalp)
 676              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 677                                    (simple-base-string simple-base-string t t t t) *)
 678                 `(let* ((end1 (if (not end1) (length string1) end1))
 679                         (end2 (if (not end2) (length string2) end2))
 680                         (index (sb!impl::%sp-string-compare
 681                                 string1 start1 end1 string2 start2 end2)))
 682                   (if index
 683                       (cond ((= index end1)
 684                              ,(if ',lessp 'index nil))
 685                             ((= (+ index (- start2 start1)) end2)
 686                              ,(if ',lessp nil 'index))
 687                             ((,(if ',lessp 'char< 'char>)
 688                                (schar string1 index)
 689                                (schar string2
 690                                       (truly-the index
 691                                                  (+ index
 692                                                     (truly-the fixnum
 693                                                                (- start2
 694                                                                   start1))))))
 695                              index)
 696                             (t nil))
 697                       ,(if ',equalp 'end1 nil))))))
 698   (def string<* t nil)
 699   (def string<=* t t)
 700   (def string>* nil nil)
 701   (def string>=* nil t))
 702
 703 (macrolet ((def (name result-fun)
 704              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 705                                    (simple-base-string simple-base-string t t t t) *)
 706                 `(,',result-fun
 707                   (sb!impl::%sp-string-compare
 708                    string1 start1 (or end1 (length string1))
 709                    string2 start2 (or end2 (length string2)))))))
 710   (def string=* not)
 711   (def string/=* identity))
 712
 713 \f
 714 ;;;; transforms for sequence functions
 715
 716 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 717 ;;; to vectors based on simple arrays.
 718 (def!constant vector-data-bit-offset
 719   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 720
 721 ;;; FIXME: In the copy loops below, we code the loops in a strange
 722 ;;; fashion:
 723 ;;;
 724 ;;; (do ((i (+ src-offset length) (1- i)))
 725 ;;;     ((<= i 0) ...)
 726 ;;;   (... (aref foo (1- i)) ...))
 727 ;;;
 728 ;;; rather than the more natural (and seemingly more efficient):
 729 ;;;
 730 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 731 ;;;     ((< i 0) ...)
 732 ;;;   (... (aref foo i) ...))
 733 ;;;
 734 ;;; (more efficient because we don't have to do the index adjusting on
 735 ;;; every iteration of the loop)
 736 ;;;
 737 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 738 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 739 ;;; when used as an array index, the backend thinks I is a
 740 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 741 ;;; these as distinct storage classes, it cannot coerce a move from a
 742 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 743 ;;; deficiency is that we have two extra moves and increased register
 744 ;;; pressure, which can lead to some spectacularly bad register
 745 ;;; allocation.  (sub-FIXME: the register allocation even with the
 746 ;;; strangely written loops is not always excellent, either...).  Doing
 747 ;;; it the first way, above, means that I is always thought of as a
 748 ;;; POSITIVE-FIXNUM and there are no issues.
 749 ;;;
 750 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 751 ;;; adjustments in the first version into the array addressing at no
 752 ;;; performance penalty!
 753
 754 ;;; This transform is critical to the performance of string streams.  If
 755 ;;; you tweak it, make sure that you compare the disassembly, if not the
 756 ;;; performance of, the functions implementing string streams
 757 ;;; (e.g. SB!IMPL::STRING-OUCH).
 758 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 759   (defun make-replace-transform (saetp sequence-type1 sequence-type2)
 760     `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 761                             (,sequence-type1 ,sequence-type2 &rest t)
 762                             ,sequence-type1
 763                             :node node)
 764        `(let* ((len1 (length seq1))
 765                (len2 (length seq2))
 766                (end1 (or end1 len1))
 767                (end2 (or end2 len2))
 768                (replace-len (min (- end1 start1) (- end2 start2))))
 769           ,(unless (policy node (= insert-array-bounds-checks 0))
 770              `(progn
 771                 (unless (<= 0 start1 end1 len1)
 772                   (sequence-bounding-indices-bad-error seq1 start1 end1))
 773                 (unless (<= 0 start2 end2 len2)
 774                   (sequence-bounding-indices-bad-error seq2 start2 end2))))
 775           ,',(cond
 776                ((and saetp (sb!vm:valid-bit-bash-saetp-p saetp))
 777                 (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 778                        (bash-function (intern (format nil "UB~D-BASH-COPY"
 779                                                       n-element-bits)
 780                                               (find-package "SB!KERNEL"))))
 781                   `(funcall (function ,bash-function) seq2 start2
 782                     seq1 start1 replace-len)))
 783                (t
 784                 `(if (and
 785                       ;; If the sequence types are different, SEQ1 and
 786                       ;; SEQ2 must be distinct arrays.
 787                       ,(eql sequence-type1 sequence-type2)
 788                       (eq seq1 seq2) (> start1 start2))
 789                      (do ((i (truly-the index (+ start1 replace-len -1))
 790                              (1- i))
 791                           (j (truly-the index (+ start2 replace-len -1))
 792                              (1- j)))
 793                          ((< i start1))
 794                        (declare (optimize (insert-array-bounds-checks 0)))
 795                        (setf (aref seq1 i) (aref seq2 j)))
 796                      (do ((i start1 (1+ i))
 797                           (j start2 (1+ j))
 798                           (end (+ start1 replace-len)))
 799                          ((>= i end))
 800                        (declare (optimize (insert-array-bounds-checks 0)))
 801                        (setf (aref seq1 i) (aref seq2 j))))))
 802           seq1))))
 803
 804 (macrolet
 805     ((define-replace-transforms ()
 806        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 807              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 808              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 809              collect (make-replace-transform saetp sequence-type sequence-type)
 810              into forms
 811              finally (return `(progn ,@forms))))
 812      (define-one-transform (sequence-type1 sequence-type2)
 813        (make-replace-transform nil sequence-type1 sequence-type2)))
 814   (define-replace-transforms)
 815   #!+sb-unicode
 816   (progn
 817    (define-one-transform (simple-array base-char (*)) (simple-array character (*)))
 818    (define-one-transform (simple-array character (*)) (simple-array base-char (*)))))
 819
 820 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 821 ;;; defined as those cases where we are doing word-aligned copies from
 822 ;;; both the source and the destination and we are copying from the same
 823 ;;; offset from both the source and the destination.  (The last
 824 ;;; condition is there so we can determine the direction to copy at
 825 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 826 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 827 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 828 ;;; N)-size buffer and blitting in the old N-size buffer in.
 829
 830 (defun frob-bash-transform (src src-offset
 831                             dst dst-offset
 832                             length n-elems-per-word)
 833   (declare (ignore src dst length))
 834   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 835     (multiple-value-bind (src-word src-elt)
 836         (truncate (lvar-value src-offset) n-elems-per-word)
 837       (multiple-value-bind (dst-word dst-elt)
 838           (truncate (lvar-value dst-offset) n-elems-per-word)
 839         ;; Avoid non-word aligned copies.
 840         (unless (and (zerop src-elt) (zerop dst-elt))
 841           (give-up-ir1-transform))
 842         ;; Avoid copies where we would have to insert code for
 843         ;; determining the direction of copying.
 844         (unless (= src-word dst-word)
 845           (give-up-ir1-transform))
 846         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 847         ;; so we have to do its work here.
 848         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 849                                       'length
 850                                       `(truncate (the index length) ,n-elems-per-word)))))
 851            (declare (type index end))
 852            ;; Handle any bits at the end.
 853            (when (logtest length (1- ,n-elems-per-word))
 854              (let* ((extra (mod length ,n-elems-per-word))
 855                     ;; FIXME: The shift amount on this ASH is
 856                     ;; *always* negative, but the backend doesn't
 857                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 858                     ;; wind up with a pile of code that tests the
 859                     ;; sign of the shift count prior to shifting when
 860                     ;; all we need is a simple negate and shift
 861                     ;; right.  Yuck.
 862                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 863                                (* (- extra ,n-elems-per-word)
 864                                   ,n-bits-per-elem))))
 865                (setf (sb!kernel:%vector-raw-bits dst end)
 866                      (logior
 867                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 868                                 (ash mask
 869                                      ,(ecase sb!c:*backend-byte-order*
 870                                              (:little-endian 0)
 871                                              (:big-endian `(* (- ,n-elems-per-word extra)
 872                                                               ,n-bits-per-elem)))))
 873                       (logand (sb!kernel:%vector-raw-bits src end)
 874                               (ash mask
 875                                    ,(ecase sb!c:*backend-byte-order*
 876                                            (:little-endian 0)
 877                                            (:big-endian `(* (- ,n-elems-per-word extra)
 878                                                             ,n-bits-per-elem)))))))))
 879            ;; Copy from the end to save a register.
 880            (do ((i end (1- i)))
 881                ((<= i ,src-word))
 882              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 883                    (sb!kernel:%vector-raw-bits src (1- i))))
 884            (values))))))
 885
 886 #.(loop for i = 1 then (* i 2)
 887         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 888                                         "SB!KERNEL")
 889                                                         ((src src-offset
 890                                                           dst dst-offset
 891                                                           length)
 892                                                         ((simple-unboxed-array (*))
 893                                                          (constant-arg index)
 894                                                          (simple-unboxed-array (*))
 895                                                          (constant-arg index)
 896                                                          index)
 897                                                         *)
 898                   (frob-bash-transform src src-offset
 899                                        dst dst-offset length
 900                                        ,(truncate sb!vm:n-word-bits i))) into forms
 901         until (= i sb!vm:n-word-bits)
 902         finally (return `(progn ,@forms)))
 903
 904 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 905 ;;; arrays with elements of size >= the word size.  We do this because
 906 ;;; we know the arrays cannot alias (one was just consed), therefore we
 907 ;;; can determine at compile time the direction to copy, and for
 908 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 909 ;;; needless checking to figure out what's going on.  The same
 910 ;;; considerations apply if we are copying elements larger than the word
 911 ;;; size, with the additional twist that doing it inline is likely to
 912 ;;; cons far less than calling REPLACE and letting generic code do the
 913 ;;; work.
 914 ;;;
 915 ;;; However, we do not do this for elements whose size is < than the
 916 ;;; word size because we don't want to deal with any alignment issues
 917 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 918 ;;; anyway.
 919
 920 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 921                                       element-type)
 922   (let ((saetp (find-saetp element-type)))
 923     (aver saetp)
 924     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 925         (expand-aref-copy-loop src src-offset dst dst-offset length)
 926         `(locally (declare (optimize (safety 0)))
 927            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 928
 929 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 930   (if (eql src-offset dst-offset)
 931       `(do ((i (+ ,src-offset ,length) (1- i)))
 932            ((<= i ,src-offset))
 933          (declare (optimize (insert-array-bounds-checks 0)))
 934          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 935       ;; KLUDGE: The compiler is not able to derive that (+ offset
 936       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 937       ;; We, however, know it must be so, as by this point the bounds
 938       ;; have already been checked.
 939       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 940             (j (+ ,dst-offset ,length) (1- j)))
 941            ((<= i ,src-offset))
 942          (declare (optimize (insert-array-bounds-checks 0))
 943                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 944          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 945
 946 ;;; SUBSEQ, COPY-SEQ
 947
 948 (deftransform subseq ((seq start &optional end)
 949                       (vector t &optional t)
 950                       *
 951                       :node node)
 952   (let ((type (lvar-type seq)))
 953     (cond
 954       ((and (array-type-p type)
 955             (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 956        (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 957          `(let* ((length (length seq))
 958                  (end (or end length)))
 959             ,(unless (policy node (zerop insert-array-bounds-checks))
 960                      '(progn
 961                        (unless (<= 0 start end length)
 962                          (sequence-bounding-indices-bad-error seq start end))))
 963             (let* ((size (- end start))
 964                    (result (make-array size :element-type ',element-type)))
 965               ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
 966                                                        (lvar-value start)
 967                                                        'start)
 968                                               'result 0 'size element-type)
 969               result))))
 970       ((csubtypep type (specifier-type 'string))
 971        '(string-subseq* seq start end))
 972       (t
 973        '(vector-subseq* seq start end)))))
 974
 975 (deftransform subseq ((seq start &optional end)
 976                       (list t &optional t))
 977   `(list-subseq* seq start end))
 978
 979 (deftransform subseq ((seq start &optional end)
 980                       ((and sequence (not vector) (not list)) t &optional t))
 981   '(sb!sequence:subseq seq start end))
 982
 983 (deftransform copy-seq ((seq) (vector))
 984   (let ((type (lvar-type seq)))
 985     (cond ((and (array-type-p type)
 986                 (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 987            (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 988              `(let* ((length (length seq))
 989                      (result (make-array length :element-type ',element-type)))
 990                 ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
 991                 result)))
 992           ((csubtypep type (specifier-type 'string))
 993            '(string-subseq* seq 0 nil))
 994           (t
 995            '(vector-subseq* seq 0 nil)))))
 996
 997 (deftransform copy-seq ((seq) (list))
 998   '(list-copy-seq* seq))
 999
1000 (deftransform copy-seq ((seq) ((and sequence (not vector) (not list))))
1001   '(sb!sequence:copy-seq seq))
1002
1003 ;;; FIXME: it really should be possible to take advantage of the
1004 ;;; macros used in code/seq.lisp here to avoid duplication of code,
1005 ;;; and enable even funkier transformations.
1006 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
1007                                (test #'eql)
1008                                (key #'identity)
1009                                from-end)
1010                       (vector vector &rest t)
1011                       *
1012                       :node node
1013                       :policy (> speed (max space safety)))
1014   "open code"
1015   (let ((from-end (when (lvar-p from-end)
1016                     (unless (constant-lvar-p from-end)
1017                       (give-up-ir1-transform ":FROM-END is not constant."))
1018                     (lvar-value from-end)))
1019         (keyp (lvar-p key))
1020         (testp (lvar-p test))
1021         (check-bounds-p (policy node (plusp insert-array-bounds-checks))))
1022     `(block search
1023        (flet ((oops (vector start end)
1024                 (sequence-bounding-indices-bad-error vector start end)))
1025          (let* ((len1 (length pattern))
1026                 (len2 (length text))
1027                 (end1 (or end1 len1))
1028                 (end2 (or end2 len2))
1029                ,@(when keyp
1030                        '((key (coerce key 'function))))
1031                ,@(when testp
1032                        '((test (coerce test 'function)))))
1033           (declare (type index start1 start2 end1 end2))
1034           ,@(when check-bounds-p
1035              `((unless (<= start1 end1 len1)
1036                  (oops pattern start1 end1))
1037                (unless (<= start2 end2 len2)
1038                  (oops pattern start2 end2))))
1039           (do (,(if from-end
1040                     '(index2 (- end2 (- end1 start1)) (1- index2))
1041                     '(index2 start2 (1+ index2))))
1042               (,(if from-end
1043                     '(< index2 start2)
1044                     '(>= index2 end2))
1045                nil)
1046             ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
1047             ;; terminates is hits -1 when :FROM-END is true and :START2
1048             ;; is 0.
1049             (declare (type fixnum index2))
1050             (when (do ((index1 start1 (1+ index1))
1051                        (index2 index2 (1+ index2)))
1052                       ((>= index1 end1) t)
1053                     (declare (type index index1 index2)
1054                              (optimize (insert-array-bounds-checks 0)))
1055                     ,@(unless from-end
1056                               '((when (= index2 end2)
1057                                   (return-from search nil))))
1058                     (unless (,@(if testp
1059                                    '(funcall test)
1060                                    '(eql))
1061                                ,(if keyp
1062                                     '(funcall key (aref pattern index1))
1063                                     '(aref pattern index1))
1064                                ,(if keyp
1065                                     '(funcall key (aref text index2))
1066                                     '(aref text index2)))
1067                       (return nil)))
1068               (return index2))))))))
1069
1070
1071 ;;; Open-code CONCATENATE for strings. It would be possible to extend
1072 ;;; this transform to non-strings, but I chose to just do the case that
1073 ;;; should cover 95% of CONCATENATE performance complaints for now.
1074 ;;;   -- JES, 2007-11-17
1075 ;;;
1076 ;;; Only handle the simple result type cases. If somebody does (CONCATENATE
1077 ;;; '(STRING 6) ...) their code won't be optimized, but nobody does that in
1078 ;;; practice.
1079 ;;;
1080 ;;; Limit full open coding based on length of constant sequences. Default
1081 ;;; value is chosen so that other parts of to compiler (constraint propagation
1082 ;;; mainly) won't go nonlinear too badly. It's not an exact number -- but
1083 ;;; in the right ballpark.
1084 (defvar *concatenate-open-code-limit* 129)
1085
1086 (deftransform concatenate ((result-type &rest lvars)
1087                            ((constant-arg
1088                              (member string simple-string base-string simple-base-string))
1089                             &rest sequence)
1090                            * :node node)
1091   (let ((vars (loop for x in lvars collect (gensym)))
1092         (type (lvar-value result-type)))
1093     (if (policy node (<= speed space))
1094         ;; Out-of-line
1095         `(lambda (.dummy. ,@vars)
1096            (declare (ignore .dummy.))
1097            ,(ecase type
1098                    ((string simple-string)
1099                     `(%concatenate-to-string ,@vars))
1100                    ((base-string simple-base-string)
1101                     `(%concatenate-to-base-string ,@vars))))
1102         ;; Inline
1103         (let* ((element-type (ecase type
1104                                ((string simple-string) 'character)
1105                                ((base-string simple-base-string) 'base-char)))
1106                (lvar-values (loop for lvar in lvars
1107                                   collect (when (constant-lvar-p lvar)
1108                                             (lvar-value lvar))))
1109                (lengths
1110                 (loop for value in lvar-values
1111                       for var in vars
1112                       collect (if value
1113                                   (length value)
1114                                   `(sb!impl::string-dispatch ((simple-array * (*))
1115                                                               sequence)
1116                                        ,var
1117                                      (declare (muffle-conditions compiler-note))
1118                                      (length ,var))))))
1119           `(apply
1120             (lambda ,vars
1121               (declare (ignorable ,@vars))
1122               (declare (optimize (insert-array-bounds-checks 0)))
1123               (let* ((.length. (+ ,@lengths))
1124                      (.pos. 0)
1125                      (.string. (make-string .length. :element-type ',element-type)))
1126                 (declare (type index .length. .pos.)
1127                          (muffle-conditions compiler-note))
1128                 ,@(loop for value in lvar-values
1129                         for var in vars
1130                         collect (if (and (stringp value)
1131                                          (< (length value) *concatenate-open-code-limit*))
1132                                     ;; Fold the array reads for constant arguments
1133                                     `(progn
1134                                        ,@(loop for c across value
1135                                                for i from 0
1136                                                collect
1137                                                ;; Without truly-the we get massive numbers
1138                                                ;; of pointless error traps.
1139                                                   `(setf (aref .string.
1140                                                                (truly-the index (+ .pos. ,i)))
1141                                                          ,c))
1142                                        (incf .pos. ,(length value)))
1143                                     `(sb!impl::string-dispatch
1144                                          (#!+sb-unicode
1145                                           (simple-array character (*))
1146                                           (simple-array base-char (*))
1147                                           t)
1148                                          ,var
1149                                        (replace .string. ,var :start1 .pos.)
1150                                        (incf .pos. (length ,var)))))
1151                 .string.))
1152             lvars)))))
1153 \f
1154 ;;;; CONS accessor DERIVE-TYPE optimizers
1155
1156 (defoptimizer (car derive-type) ((cons))
1157   ;; This and CDR needs to use LVAR-CONSERVATIVE-TYPE because type inference
1158   ;; gets confused by things like (SETF CAR).
1159   (let ((type (lvar-conservative-type cons))
1160         (null-type (specifier-type 'null)))
1161     (cond ((eq type null-type)
1162            null-type)
1163           ((cons-type-p type)
1164            (cons-type-car-type type)))))
1165
1166 (defoptimizer (cdr derive-type) ((cons))
1167   (let ((type (lvar-conservative-type cons))
1168         (null-type (specifier-type 'null)))
1169     (cond ((eq type null-type)
1170            null-type)
1171           ((cons-type-p type)
1172            (cons-type-cdr-type type)))))
1173 \f
1174 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
1175
1176 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
1177 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
1178 ;;; expansion, so we factor out the condition into this function.
1179 (defun check-inlineability-of-find-position-if (sequence from-end)
1180   (let ((ctype (lvar-type sequence)))
1181     (cond ((csubtypep ctype (specifier-type 'vector))
1182            ;; It's not worth trying to inline vector code unless we
1183            ;; know a fair amount about it at compile time.
1184            (upgraded-element-type-specifier-or-give-up sequence)
1185            (unless (constant-lvar-p from-end)
1186              (give-up-ir1-transform
1187               "FROM-END argument value not known at compile time")))
1188           ((csubtypep ctype (specifier-type 'list))
1189            ;; Inlining on lists is generally worthwhile.
1190            )
1191           (t
1192            (give-up-ir1-transform
1193             "sequence type not known at compile time")))))
1194
1195 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
1196 (macrolet ((def (name condition)
1197              `(deftransform ,name ((predicate sequence from-end start end key)
1198                                    (function list t t t function)
1199                                    *
1200                                    :policy (> speed space))
1201                 "expand inline"
1202                 `(let ((find nil)
1203                        (position nil))
1204                    (flet ((bounds-error ()
1205                             (sequence-bounding-indices-bad-error sequence start end)))
1206                      (if (and end (> start end))
1207                          (bounds-error)
1208                          (do ((slow sequence (cdr slow))
1209                               (fast (cdr sequence) (cddr fast))
1210                               (index 0 (+ index 1)))
1211                              ((cond ((null slow)
1212                                      (if (and end (> end index))
1213                                          (bounds-error)
1214                                          (return (values find position))))
1215                                     ((and end (>= index end))
1216                                      (return (values find position)))
1217                                     ((eq slow fast)
1218                                      (circular-list-error sequence)))
1219                               (bug "never"))
1220                            (declare (list slow fast))
1221                            (when (>= index start)
1222                              (let* ((element (car slow))
1223                                     (key-i (funcall key element)))
1224                                (,',condition (funcall predicate key-i)
1225                                              ;; This hack of dealing with non-NIL
1226                                              ;; FROM-END for list data by iterating
1227                                              ;; forward through the list and keeping
1228                                              ;; track of the last time we found a
1229                                              ;; match might be more screwy than what
1230                                              ;; the user expects, but it seems to be
1231                                              ;; allowed by the ANSI standard. (And
1232                                              ;; if the user is screwy enough to ask
1233                                              ;; for FROM-END behavior on list data,
1234                                              ;; turnabout is fair play.)
1235                                              ;;
1236                                              ;; It's also not enormously efficient,
1237                                              ;; calling PREDICATE and KEY more often
1238                                              ;; than necessary; but all the
1239                                              ;; alternatives seem to have their own
1240                                              ;; efficiency problems.
1241                                              (if from-end
1242                                                  (setf find element
1243                                                        position index)
1244                                                  (return (values element index)))))))))))))
1245   (def %find-position-if when)
1246   (def %find-position-if-not unless))
1247
1248 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
1249 ;;; without loss of efficiency. (I.e., the optimizer should be able
1250 ;;; to straighten everything out.)
1251 (deftransform %find-position ((item sequence from-end start end key test)
1252                               (t list t t t t t)
1253                               *
1254                               :policy (> speed space))
1255   "expand inline"
1256   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
1257                         ;; The order of arguments for asymmetric tests
1258                         ;; (e.g. #'<, as opposed to order-independent
1259                         ;; tests like #'=) is specified in the spec
1260                         ;; section 17.2.1 -- the O/Zi stuff there.
1261                         (lambda (i)
1262                           (funcall test-fun item i)))
1263                       sequence
1264                       from-end
1265                       start
1266                       end
1267                       (%coerce-callable-to-fun key)))
1268
1269 ;;; The inline expansions for the VECTOR case are saved as macros so
1270 ;;; that we can share them between the DEFTRANSFORMs and the default
1271 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
1272 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1273 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1274                                                             from-end
1275                                                             start
1276                                                             end-arg
1277                                                             element
1278                                                             done-p-expr)
1279   (with-unique-names (offset block index n-sequence sequence end)
1280     `(let* ((,n-sequence ,sequence-arg))
1281        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1282                          (,start ,start)
1283                          (,end ,end-arg)
1284                          :check-fill-pointer t)
1285          (block ,block
1286            (macrolet ((maybe-return ()
1287                         ;; WITH-ARRAY-DATA has already performed bounds
1288                         ;; checking, so we can safely elide the checks
1289                         ;; in the inner loop.
1290                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1291                                            (aref ,sequence ,index))))
1292                           (when ,done-p-expr
1293                             (return-from ,block
1294                               (values ,element
1295                                       (- ,index ,offset)))))))
1296              (if ,from-end
1297                  (loop for ,index
1298                        ;; (If we aren't fastidious about declaring that
1299                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1300                        ;; can send us off into never-never land, since
1301                        ;; INDEX is initialized to -1.)
1302                        of-type index-or-minus-1
1303                        from (1- ,end) downto ,start do
1304                        (maybe-return))
1305                  (loop for ,index of-type index from ,start below ,end do
1306                           (maybe-return))))
1307            (values nil nil))))))
1308
1309 (def!macro %find-position-vector-macro (item sequence
1310                                              from-end start end key test)
1311   (with-unique-names (element)
1312     (%find-position-or-find-position-if-vector-expansion
1313      sequence
1314      from-end
1315      start
1316      end
1317      element
1318      ;; (See the LIST transform for a discussion of the correct
1319      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1320      ;; or after the checked sequence element.)
1321      `(funcall ,test ,item (funcall ,key ,element)))))
1322
1323 (def!macro %find-position-if-vector-macro (predicate sequence
1324                                                      from-end start end key)
1325   (with-unique-names (element)
1326     (%find-position-or-find-position-if-vector-expansion
1327      sequence
1328      from-end
1329      start
1330      end
1331      element
1332      `(funcall ,predicate (funcall ,key ,element)))))
1333
1334 (def!macro %find-position-if-not-vector-macro (predicate sequence
1335                                                          from-end start end key)
1336   (with-unique-names (element)
1337     (%find-position-or-find-position-if-vector-expansion
1338      sequence
1339      from-end
1340      start
1341      end
1342      element
1343      `(not (funcall ,predicate (funcall ,key ,element))))))
1344
1345 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1346 ;;; VECTOR data
1347 (deftransform %find-position-if ((predicate sequence from-end start end key)
1348                                  (function vector t t t function)
1349                                  *
1350                                  :policy (> speed space))
1351   "expand inline"
1352   (check-inlineability-of-find-position-if sequence from-end)
1353   '(%find-position-if-vector-macro predicate sequence
1354                                    from-end start end key))
1355
1356 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1357                                      (function vector t t t function)
1358                                      *
1359                                      :policy (> speed space))
1360   "expand inline"
1361   (check-inlineability-of-find-position-if sequence from-end)
1362   '(%find-position-if-not-vector-macro predicate sequence
1363                                        from-end start end key))
1364
1365 (deftransform %find-position ((item sequence from-end start end key test)
1366                               (t vector t t t function function)
1367                               *
1368                               :policy (> speed space))
1369   "expand inline"
1370   (check-inlineability-of-find-position-if sequence from-end)
1371   '(%find-position-vector-macro item sequence
1372     from-end start end key test))
1373
1374 (deftransform %find-position ((item sequence from-end start end key test)
1375                               (character string t t t function function)
1376                               *
1377                               :policy (> speed space))
1378   (if (eq '* (upgraded-element-type-specifier sequence))
1379       (let ((form
1380              `(sb!impl::string-dispatch ((simple-array character (*))
1381                                          (simple-array base-char (*))
1382                                          (simple-array nil (*)))
1383                   sequence
1384                 (%find-position item sequence from-end start end key test))))
1385         (if (csubtypep (lvar-type sequence) (specifier-type 'simple-string))
1386             form
1387             ;; Otherwise we'd get three instances of WITH-ARRAY-DATA from
1388             ;; %FIND-POSITION.
1389             `(with-array-data ((sequence sequence :offset-var offset)
1390                                (start start)
1391                                (end end)
1392                                :check-fill-pointer t)
1393                (multiple-value-bind (elt index) ,form
1394                  (values elt (when (fixnump index) (- index offset)))))))
1395       ;; The type is known exactly, other transforms will take care of it.
1396       (give-up-ir1-transform)))
1397
1398 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1399 ;;; POSITION-IF, etc.
1400 (define-source-transform effective-find-position-test (test test-not)
1401   (once-only ((test test)
1402               (test-not test-not))
1403     `(cond
1404       ((and ,test ,test-not)
1405        (error "can't specify both :TEST and :TEST-NOT"))
1406       (,test (%coerce-callable-to-fun ,test))
1407       (,test-not
1408        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1409        ;; inefficient, but since the TEST-NOT option is deprecated
1410        ;; anyway, we don't care.)
1411        (complement (%coerce-callable-to-fun ,test-not)))
1412       (t #'eql))))
1413 (define-source-transform effective-find-position-key (key)
1414   (once-only ((key key))
1415     `(if ,key
1416          (%coerce-callable-to-fun ,key)
1417          #'identity)))
1418
1419 (macrolet ((define-find-position (fun-name values-index)
1420              `(deftransform ,fun-name ((item sequence &key
1421                                              from-end (start 0) end
1422                                              key test test-not)
1423                                        (t (or list vector) &rest t))
1424                 '(nth-value ,values-index
1425                             (%find-position item sequence
1426                                             from-end start
1427                                             end
1428                                             (effective-find-position-key key)
1429                                             (effective-find-position-test
1430                                              test test-not))))))
1431   (define-find-position find 0)
1432   (define-find-position position 1))
1433
1434 (macrolet ((define-find-position-if (fun-name values-index)
1435              `(deftransform ,fun-name ((predicate sequence &key
1436                                                   from-end (start 0)
1437                                                   end key)
1438                                        (t (or list vector) &rest t))
1439                 '(nth-value
1440                   ,values-index
1441                   (%find-position-if (%coerce-callable-to-fun predicate)
1442                                      sequence from-end
1443                                      start end
1444                                      (effective-find-position-key key))))))
1445   (define-find-position-if find-if 0)
1446   (define-find-position-if position-if 1))
1447
1448 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1449 ;;; didn't bother to worry about optimizing them, except note that on
1450 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1451 ;;; sbcl-devel
1452 ;;;
1453 ;;;     My understanding is that while the :test-not argument is
1454 ;;;     deprecated in favour of :test (complement #'foo) because of
1455 ;;;     semantic difficulties (what happens if both :test and :test-not
1456 ;;;     are supplied, etc) the -if-not variants, while officially
1457 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1458 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1459 ;;;     reasons for allowing the -if-not versions equal status,
1460 ;;;     particularly remove-if-not (== filter).
1461 ;;;
1462 ;;;     This is only an informal understanding, I grant you, but
1463 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1464 ;;;     way as the others?
1465 ;;;
1466 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1467 ;;; implementation of SBCL.
1468 (macrolet ((define-find-position-if-not (fun-name values-index)
1469                `(deftransform ,fun-name ((predicate sequence &key
1470                                           from-end (start 0)
1471                                           end key)
1472                                          (t (or list vector) &rest t))
1473                  '(nth-value
1474                    ,values-index
1475                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1476                     sequence from-end
1477                     start end
1478                     (effective-find-position-key key))))))
1479   (define-find-position-if-not find-if-not 0)
1480   (define-find-position-if-not position-if-not 1))
1481
1482 (macrolet ((define-trimmer-transform (fun-name leftp rightp)
1483              `(deftransform ,fun-name ((char-bag string)
1484                                        (t simple-string))
1485                 (let ((find-expr
1486                        (if (constant-lvar-p char-bag)
1487                            ;; If the bag is constant, use MEMBER
1488                            ;; instead of FIND, since we have a
1489                            ;; deftransform for MEMBER that can
1490                            ;; open-code all of the comparisons when
1491                            ;; the list is constant. -- JES, 2007-12-10
1492                            `(not (member (schar string index)
1493                                          ',(coerce (lvar-value char-bag) 'list)
1494                                          :test #'char=))
1495                            '(not (find (schar string index) char-bag :test #'char=)))))
1496                   `(flet ((char-not-in-bag (index)
1497                             ,find-expr))
1498                      (let* ((end (length string))
1499                             (left-end (if ,',leftp
1500                                           (do ((index 0 (1+ index)))
1501                                               ((or (= index (the fixnum end))
1502                                                    (char-not-in-bag index))
1503                                                index)
1504                                             (declare (fixnum index)))
1505                                           0))
1506                             (right-end (if ,',rightp
1507                                            (do ((index (1- end) (1- index)))
1508                                                ((or (< index left-end)
1509                                                     (char-not-in-bag index))
1510                                                 (1+ index))
1511                                              (declare (fixnum index)))
1512                                            end)))
1513                        (if (and (eql left-end 0)
1514                                 (eql right-end (length string)))
1515                            string
1516                            (subseq string left-end right-end))))))))
1517   (define-trimmer-transform string-left-trim t nil)
1518   (define-trimmer-transform string-right-trim nil t)
1519   (define-trimmer-transform string-trim t t))
1520