src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32         (ecase accumulate
  33           (:nconc
  34            (let ((temp (gensym))
  35                  (map-result (gensym)))
  36              `(let ((,fn-sym ,fn)
  37                     (,map-result (list nil)))
  38                 (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  39                               (,endtest (cdr ,map-result))
  40                   (setq ,temp (last (nconc ,temp ,call)))))))
  41           (:list
  42            (let ((temp (gensym))
  43                  (map-result (gensym)))
  44              `(let ((,fn-sym ,fn)
  45                     (,map-result (list nil)))
  46                 (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                               (,endtest (cdr ,map-result))
  48                   (rplacd ,temp (setq ,temp (list ,call)))))))
  49           ((nil)
  50            `(let ((,fn-sym ,fn)
  51                   (,n-first ,(first arglists)))
  52               (do-anonymous ,(do-clauses)
  53                             (,endtest ,n-first) ,call))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-continuation-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (continuation-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of continuations, SEQ-NAMES - list of
 125 ;;; variables, bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places))
 137     (let ((found-vector-p nil))
 138       (flet ((process-vector (length)
 139                (unless found-vector-p
 140                  (setq found-vector-p t)
 141                  (bindings `(index 0 (1+ index)))
 142                  (declarations `(type index index)))
 143                (vector-lengths length)))
 144         (loop for seq of-type continuation in seqs
 145            for seq-name in seq-names
 146            for type = (continuation-type seq)
 147            do (cond ((csubtypep type (specifier-type 'list))
 148                      (with-unique-names (index)
 149                        (bindings `(,index ,seq-name (cdr ,index)))
 150                        (declarations `(type list ,index))
 151                        (places `(car ,index))
 152                        (tests `(endp ,index))))
 153                     ((csubtypep type (specifier-type 'vector))
 154                      (process-vector `(length ,seq-name))
 155                      (places `(aref ,seq-name index)))
 156                     (t
 157                      (give-up-ir1-transform
 158                       "can't determine sequence argument type"))))
 159         (when into
 160           (process-vector `(array-dimension ,into 0))))
 161       (when found-vector-p
 162         (bindings `(length (min ,@(vector-lengths))))
 163         (tests `(= index length)))
 164       `(do (,@(bindings))
 165            ((or ,@(tests)) ,result)
 166          (declare ,@(declarations))
 167          (let ((funcall-result (funcall fun ,@(places))))
 168            (declare (ignorable funcall-result))
 169            ,body)))))
 170
 171 ;;; Try to compile %MAP efficiently when we can determine sequence
 172 ;;; argument types at compile time.
 173 ;;;
 174 ;;; Note: This transform was written to allow open coding of
 175 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 176 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 177 ;;; necessarily as efficient as possible. In particular, it will be
 178 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 179 ;;; numeric element types. It should be straightforward to make it
 180 ;;; handle that case more efficiently, but it's left as an exercise to
 181 ;;; the reader, because the code is complicated enough already and I
 182 ;;; don't happen to need that functionality right now. -- WHN 20000410
 183 (deftransform %map ((result-type fun seq &rest seqs) * *
 184                     :policy (>= speed space))
 185   "open code"
 186   (unless (constant-continuation-p result-type)
 187     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 188   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 189            (fn-1subtypep (fn x y)
 190              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 191                (if valid-p
 192                    subtype-p
 193                    (give-up-ir1-transform
 194                     "can't analyze sequence type relationship"))))
 195            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 196     (let* ((result-type-value (continuation-value result-type))
 197            (result-supertype (cond ((null result-type-value) 'null)
 198                                    ((1subtypep result-type-value 'vector)
 199                                     'vector)
 200                                    ((1subtypep result-type-value 'list)
 201                                     'list)
 202                                    (t
 203                                     (give-up-ir1-transform
 204                                      "can't determine result type")))))
 205       (cond ((and result-type-value (null seqs))
 206              ;; The consing arity-1 cases can be implemented
 207              ;; reasonably efficiently as function calls, and the cost
 208              ;; of consing should be significantly larger than
 209              ;; function call overhead, so we always compile these
 210              ;; cases as full calls regardless of speed-versus-space
 211              ;; optimization policy.
 212              (cond ((subtypep result-type-value 'list)
 213                     '(%map-to-list-arity-1 fun seq))
 214                    ( ;; (This one can be inefficient due to COERCE, but
 215                     ;; the current open-coded implementation has the
 216                     ;; same problem.)
 217                     (subtypep result-type-value 'vector)
 218                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 219                              ',result-type-value))
 220                    (t (bug "impossible (?) sequence type"))))
 221             (t
 222              (let* ((seqs (cons seq seqs))
 223                     (seq-args (make-gensym-list (length seqs))))
 224                (multiple-value-bind (push-dacc result)
 225                    (ecase result-supertype
 226                      (null (values nil nil))
 227                      (list (values `(push funcall-result acc)
 228                                    `(nreverse acc)))
 229                      (vector (values `(push funcall-result acc)
 230                                      `(coerce (nreverse acc)
 231                                               ',result-type-value))))
 232                  ;; (We use the same idiom, of returning a LAMBDA from
 233                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 234                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 235                  ;; reason: we need to get the runtime values of each
 236                  ;; of the &REST vars.)
 237                  `(lambda (result-type fun ,@seq-args)
 238                     (declare (ignore result-type))
 239                     (let ((fun (%coerce-callable-to-fun fun))
 240                           (acc nil))
 241                       (declare (type list acc))
 242                       (declare (ignorable acc))
 243                       ,(build-sequence-iterator
 244                         seqs seq-args
 245                         :result result
 246                         :body push-dacc))))))))))
 247
 248 ;;; MAP-INTO
 249 (deftransform map-into ((result fun &rest seqs)
 250                         (vector * &rest *)
 251                         *)
 252   "open code"
 253   (let ((seqs-names (mapcar (lambda (x)
 254                               (declare (ignore x))
 255                               (gensym))
 256                             seqs)))
 257     `(lambda (result fun ,@seqs-names)
 258        ,(build-sequence-iterator
 259          seqs seqs-names
 260          :result '(when (array-has-fill-pointer-p result)
 261                    (setf (fill-pointer result) index))
 262          :into 'result
 263          :body '(setf (aref result index) funcall-result))
 264        result)))
 265
 266 \f
 267 ;;; FIXME: once the confusion over doing transforms with known-complex
 268 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 269 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 270 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 271   '(aref s i))
 272
 273 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 274   '(nth i s))
 275
 276 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 277   '(%aset s i v))
 278
 279 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 280   '(setf (car (nthcdr i s)) v))
 281
 282 (deftransform %check-vector-sequence-bounds ((vector start end)
 283                                              (vector * *) *
 284                                              :node node)
 285   (if (policy node (< safety speed))
 286       '(or end (length vector))
 287       '(let ((length (length vector)))
 288         (if (<= 0 start (or end length) length)
 289             (or end length)
 290             (sb!impl::signal-bounding-indices-bad-error vector start end)))))
 291
 292 (macrolet ((def (name)
 293              `(deftransform ,name ((e l &key (test #'eql)) * *
 294                                    :node node)
 295                 (unless (constant-continuation-p l)
 296                   (give-up-ir1-transform))
 297
 298                 (let ((val (continuation-value l)))
 299                   (unless (policy node
 300                                   (or (= speed 3)
 301                                       (and (>= speed space)
 302                                            (<= (length val) 5))))
 303                     (give-up-ir1-transform))
 304
 305                   (labels ((frob (els)
 306                              (if els
 307                                  `(if (funcall test e ',(car els))
 308                                       ',els
 309                                       ,(frob (cdr els)))
 310                                  nil)))
 311                     (frob val))))))
 312   (def member)
 313   (def memq))
 314
 315 ;;; FIXME: We have rewritten the original code that used DOLIST to this
 316 ;;; more natural MACROLET.  However, the original code suggested that when
 317 ;;; this was done, a few bytes could be saved by a call to a shared
 318 ;;; function.  This remains to be done.
 319 (macrolet ((def (fun eq-fun)
 320              `(deftransform ,fun ((item list &key test) (t list &rest t) *)
 321                 "convert to EQ test"
 322                 ;; FIXME: The scope of this transformation could be
 323                 ;; widened somewhat, letting it work whenever the test is
 324                 ;; 'EQL and we know from the type of ITEM that it #'EQ
 325                 ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 326                 ;; and SYMBOL.)
 327                 ;;   If TEST is EQ, apply transform, else
 328                 ;;   if test is not EQL, then give up on transform, else
 329                 ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 330                 ;;   transform, else give up on transform.
 331                 (cond (test
 332                        (unless (continuation-fun-is test '(eq))
 333                          (give-up-ir1-transform)))
 334                       ((types-equal-or-intersect (continuation-type item)
 335                                                  (specifier-type 'number))
 336                        (give-up-ir1-transform "Item might be a number.")))
 337                 `(,',eq-fun item list))))
 338   (def delete delq)
 339   (def assoc assq)
 340   (def member memq))
 341
 342 (deftransform delete-if ((pred list) (t list))
 343   "open code"
 344   '(do ((x list (cdr x))
 345         (splice '()))
 346        ((endp x) list)
 347      (cond ((funcall pred (car x))
 348             (if (null splice)
 349                 (setq list (cdr x))
 350                 (rplacd splice (cdr x))))
 351            (T (setq splice x)))))
 352
 353 (deftransform fill ((seq item &key (start 0) (end (length seq)))
 354                     (vector t &key (:start t) (:end index))
 355                     *
 356                     :policy (> speed space))
 357   "open code"
 358   (let ((element-type (upgraded-element-type-specifier-or-give-up seq)))
 359     (values
 360      `(with-array-data ((data seq)
 361                         (start start)
 362                         (end end))
 363        (declare (type (simple-array ,element-type 1) data))
 364        (declare (type fixnum start end))
 365        (do ((i start (1+ i)))
 366            ((= i end) seq)
 367          (declare (type index i))
 368          ;; WITH-ARRAY-DATA did our range checks once and for all, so
 369          ;; it'd be wasteful to check again on every AREF...
 370          (declare (optimize (safety 0)))
 371          (setf (aref data i) item)))
 372      ;; ... though we still need to check that the new element can fit
 373      ;; into the vector in safe code. -- CSR, 2002-07-05
 374      `((declare (type ,element-type item))))))
 375 \f
 376 ;;;; utilities
 377
 378 ;;; Return true if CONT's only use is a non-NOTINLINE reference to a
 379 ;;; global function with one of the specified NAMES.
 380 (defun continuation-fun-is (cont names)
 381   (declare (type continuation cont) (list names))
 382   (let ((use (continuation-use cont)))
 383     (and (ref-p use)
 384          (let ((leaf (ref-leaf use)))
 385            (and (global-var-p leaf)
 386                 (eq (global-var-kind leaf) :global-function)
 387                 (not (null (member (leaf-source-name leaf) names
 388                                    :test #'equal))))))))
 389
 390 ;;; If CONT is a constant continuation, the return the constant value.
 391 ;;; If it is null, then return default, otherwise quietly give up the
 392 ;;; IR1 transform.
 393 ;;;
 394 ;;; ### Probably should take an ARG and flame using the NAME.
 395 (defun constant-value-or-lose (cont &optional default)
 396   (declare (type (or continuation null) cont))
 397   (cond ((not cont) default)
 398         ((constant-continuation-p cont)
 399          (continuation-value cont))
 400         (t
 401          (give-up-ir1-transform))))
 402
 403 ;;; FIXME: Why is this code commented out? (Why *was* it commented
 404 ;;; out? We inherited this situation from cmucl-2.4.8, with no
 405 ;;; explanation.) Should we just delete this code?
 406 #|
 407 ;;; This is a frob whose job it is to make it easier to pass around
 408 ;;; the arguments to IR1 transforms. It bundles together the name of
 409 ;;; the argument (which should be referenced in any expansion), and
 410 ;;; the continuation for that argument (or NIL if unsupplied.)
 411 (defstruct (arg (:constructor %make-arg (name cont))
 412                 (:copier nil))
 413   (name nil :type symbol)
 414   (cont nil :type (or continuation null)))
 415 (defmacro make-arg (name)
 416   `(%make-arg ',name ,name))
 417
 418 ;;; If Arg is null or its CONT is null, then return Default, otherwise
 419 ;;; return Arg's NAME.
 420 (defun default-arg (arg default)
 421   (declare (type (or arg null) arg))
 422   (if (and arg (arg-cont arg))
 423       (arg-name arg)
 424       default))
 425
 426 ;;; If Arg is null or has no CONT, return the default. Otherwise, Arg's
 427 ;;; CONT must be a constant continuation whose value we return. If not, we
 428 ;;; give up.
 429 (defun arg-constant-value (arg default)
 430   (declare (type (or arg null) arg))
 431   (if (and arg (arg-cont arg))
 432       (let ((cont (arg-cont arg)))
 433         (unless (constant-continuation-p cont)
 434           (give-up-ir1-transform "Argument is not constant: ~S."
 435                                  (arg-name arg)))
 436         (continuation-value from-end))
 437       default))
 438
 439 ;;; If Arg is a constant and is EQL to X, then return T, otherwise NIL. If
 440 ;;; Arg is NIL or its CONT is NIL, then compare to the default.
 441 (defun arg-eql (arg default x)
 442   (declare (type (or arg null) x))
 443   (if (and arg (arg-cont arg))
 444       (let ((cont (arg-cont arg)))
 445         (and (constant-continuation-p cont)
 446              (eql (continuation-value cont) x)))
 447       (eql default x)))
 448
 449 (defstruct (iterator (:copier nil))
 450   ;; The kind of iterator.
 451   (kind nil (member :normal :result))
 452   ;; A list of LET* bindings to create the initial state.
 453   (binds nil :type list)
 454   ;; A list of declarations for Binds.
 455   (decls nil :type list)
 456   ;; A form that returns the current value. This may be set with SETF to set
 457   ;; the current value.
 458   (current (error "Must specify CURRENT."))
 459   ;; In a :NORMAL iterator, a form that tests whether there is a current value.
 460   (done nil)
 461   ;; In a :RESULT iterator, a form that truncates the result at the current
 462   ;; position and returns it.
 463   (result nil)
 464   ;; A form that returns the initial total number of values. The result is
 465   ;; undefined after NEXT has been evaluated.
 466   (length (error "Must specify LENGTH."))
 467   ;; A form that advances the state to the next value. It is an error to call
 468   ;; this when the iterator is Done.
 469   (next (error "Must specify NEXT.")))
 470
 471 ;;; Type of an index var that can go negative (in the from-end case.)
 472 (deftype neg-index ()
 473   `(integer -1 ,most-positive-fixnum))
 474
 475 ;;; Return an ITERATOR structure describing how to iterate over an arbitrary
 476 ;;; sequence. Sequence is a variable bound to the sequence, and Type is the
 477 ;;; type of the sequence. If true, INDEX is a variable that should be bound to
 478 ;;; the index of the current element in the sequence.
 479 ;;;
 480 ;;; If we can't tell whether the sequence is a list or a vector, or whether
 481 ;;; the iteration is forward or backward, then GIVE-UP.
 482 (defun make-sequence-iterator (sequence type &key start end from-end index)
 483   (declare (symbol sequence) (type ctype type)
 484            (type (or arg null) start end from-end)
 485            (type (or symbol null) index))
 486   (let ((from-end (arg-constant-value from-end nil)))
 487     (cond ((csubtypep type (specifier-type 'vector))
 488            (let* ((n-stop (gensym))
 489                   (n-idx (or index (gensym)))
 490                   (start (default-arg 0 start))
 491                   (end (default-arg `(length ,sequence) end)))
 492              (make-iterator
 493               :kind :normal
 494               :binds `((,n-idx ,(if from-end `(1- ,end) ,start))
 495                        (,n-stop ,(if from-end `(1- ,start) ,end)))
 496               :decls `((type neg-index ,n-idx ,n-stop))
 497               :current `(aref ,sequence ,n-idx)
 498               :done `(,(if from-end '<= '>=) ,n-idx ,n-stop)
 499               :next `(setq ,n-idx
 500                            ,(if from-end `(1- ,n-idx) `(1+ ,n-idx)))
 501               :length (if from-end
 502                           `(- ,n-idx ,n-stop)
 503                           `(- ,n-stop ,n-idx)))))
 504           ((csubtypep type (specifier-type 'list))
 505            (let* ((n-stop (if (and end (not from-end)) (gensym) nil))
 506                   (n-current (gensym))
 507                   (start-p (not (arg-eql start 0 0)))
 508                   (end-p (not (arg-eql end nil nil)))
 509                   (start (default-arg start 0))
 510                   (end (default-arg end nil)))
 511              (make-iterator
 512               :binds `((,n-current
 513                         ,(if from-end
 514                              (if (or start-p end-p)
 515                                  `(nreverse (subseq ,sequence ,start
 516                                                     ,@(when end `(,end))))
 517                                  `(reverse ,sequence))
 518                              (if start-p
 519                                  `(nthcdr ,start ,sequence)
 520                                  sequence)))
 521                        ,@(when n-stop
 522                            `((,n-stop (nthcdr (the index
 523                                                    (- ,end ,start))
 524                                               ,n-current))))
 525                        ,@(when index
 526                            `((,index ,(if from-end `(1- ,end) start)))))
 527               :kind :normal
 528               :decls `((list ,n-current ,n-end)
 529                        ,@(when index `((type neg-index ,index))))
 530               :current `(car ,n-current)
 531               :done `(eq ,n-current ,n-stop)
 532               :length `(- ,(or end `(length ,sequence)) ,start)
 533               :next `(progn
 534                        (setq ,n-current (cdr ,n-current))
 535                        ,@(when index
 536                            `((setq ,n-idx
 537                                    ,(if from-end
 538                                         `(1- ,index)
 539                                         `(1+ ,index)))))))))
 540           (t
 541            (give-up-ir1-transform
 542             "can't tell whether sequence is a list or a vector")))))
 543
 544 ;;; Make an iterator used for constructing result sequences. Name is a
 545 ;;; variable to be bound to the result sequence. Type is the type of result
 546 ;;; sequence to make. Length is an expression to be evaluated to get the
 547 ;;; maximum length of the result (not evaluated in list case.)
 548 (defun make-result-sequence-iterator (name type length)
 549   (declare (symbol name) (type ctype type))
 550
 551 ;;; Define each NAME as a local macro that will call the value of the
 552 ;;; function arg with the given arguments. If the argument isn't known to be a
 553 ;;; function, give them an efficiency note and reference a coerced version.
 554 (defmacro coerce-funs (specs &body body)
 555   #!+sb-doc
 556   "COERCE-FUNCTIONS ({(Name Fun-Arg Default)}*) Form*"
 557   (collect ((binds)
 558             (defs))
 559     (dolist (spec specs)
 560       `(let ((body (progn ,@body))
 561              (n-fun (arg-name ,(second spec)))
 562              (fun-cont (arg-cont ,(second spec))))
 563          (cond ((not fun-cont)
 564                 `(macrolet ((,',(first spec) (&rest args)
 565                              `(,',',(third spec) ,@args)))
 566                    ,body))
 567                ((not (csubtypep (continuation-type fun-cont)
 568                                 (specifier-type 'function)))
 569                 (when (policy *compiler-error-context*
 570                               (> speed inhibit-warnings))
 571                   (compiler-note
 572                    "~S may not be a function, so must coerce at run-time."
 573                    n-fun))
 574                 (once-only ((n-fun `(if (functionp ,n-fun)
 575                                         ,n-fun
 576                                         (symbol-function ,n-fun))))
 577                   `(macrolet ((,',(first spec) (&rest args)
 578                                `(funcall ,',n-fun ,@args)))
 579                      ,body)))
 580                (t
 581                 `(macrolet ((,',(first spec) (&rest args)
 582                               `(funcall ,',n-fun ,@args)))
 583                    ,body)))))))
 584
 585 ;;; Wrap code around the result of the body to define Name as a local macro
 586 ;;; that returns true when its arguments satisfy the test according to the Args
 587 ;;; Test and Test-Not. If both Test and Test-Not are supplied, abort the
 588 ;;; transform.
 589 (defmacro with-sequence-test ((name test test-not) &body body)
 590   `(let ((not-p (arg-cont ,test-not)))
 591      (when (and (arg-cont ,test) not-p)
 592        (abort-ir1-transform "Both ~S and ~S were supplied."
 593                             (arg-name ,test)
 594                             (arg-name ,test-not)))
 595      (coerce-funs ((,name (if not-p ,test-not ,test) eql))
 596        ,@body)))
 597 |#
 598 \f
 599 ;;;; hairy sequence transforms
 600
 601 ;;; FIXME: no hairy sequence transforms in SBCL?
 602 \f
 603 ;;;; string operations
 604
 605 ;;; We transform the case-sensitive string predicates into a non-keyword
 606 ;;; version. This is an IR1 transform so that we don't have to worry about
 607 ;;; changing the order of evaluation.
 608 (macrolet ((def (fun pred*)
 609              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 610                                                          (start2 0) end2)
 611                                    * *)
 612                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 613   (def string< string<*)
 614   (def string> string>*)
 615   (def string<= string<=*)
 616   (def string>= string>=*)
 617   (def string= string=*)
 618   (def string/= string/=*))
 619
 620 ;;; Return a form that tests the free variables STRING1 and STRING2
 621 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 622 ;;; start and end are also gotten from the environment. Both strings
 623 ;;; must be SIMPLE-STRINGs.
 624 (macrolet ((def (name lessp equalp)
 625              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 626                                     (simple-string simple-string t t t t) *)
 627                 `(let* ((end1 (if (not end1) (length string1) end1))
 628                         (end2 (if (not end2) (length string2) end2))
 629                         (index (sb!impl::%sp-string-compare
 630                                 string1 start1 end1 string2 start2 end2)))
 631                   (if index
 632                       (cond ((= index ,(if ',lessp 'end1 'end2)) index)
 633                             ((= index ,(if ',lessp 'end2 'end1)) nil)
 634                             ((,(if ',lessp 'char< 'char>)
 635                                (schar string1 index)
 636                                (schar string2
 637                                       (truly-the index
 638                                                  (+ index
 639                                                     (truly-the fixnum
 640                                                                (- start2
 641                                                                   start1))))))
 642                              index)
 643                             (t nil))
 644                       ,(if ',equalp 'end1 nil))))))
 645   (def string<* t nil)
 646   (def string<=* t t)
 647   (def string>* nil nil)
 648   (def string>=* nil t))
 649
 650 (macrolet ((def (name result-fun)
 651              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 652                                    (simple-string simple-string t t t t) *)
 653                 `(,',result-fun
 654                   (sb!impl::%sp-string-compare
 655                    string1 start1 (or end1 (length string1))
 656                    string2 start2 (or end2 (length string2)))))))
 657   (def string=* not)
 658   (def string/=* identity))
 659
 660 \f
 661 ;;;; string-only transforms for sequence functions
 662 ;;;;
 663 ;;;; Note: CMU CL had more of these, including transforms for
 664 ;;;; functions which cons. In SBCL, we've gotten rid of most of the
 665 ;;;; transforms for functions which cons, since our GC overhead is
 666 ;;;; sufficiently large that it doesn't seem worth it to try to
 667 ;;;; economize on function call overhead or on the overhead of runtime
 668 ;;;; type dispatch in AREF. The exception is CONCATENATE, since
 669 ;;;; a full call to CONCATENATE would have to look up the sequence
 670 ;;;; type, which can be really slow.
 671 ;;;;
 672 ;;;; FIXME: It would be nicer for these transforms to work for any
 673 ;;;; calls when all arguments are vectors with the same element type,
 674 ;;;; rather than restricting them to STRINGs only.
 675
 676 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp
 677 ;;;
 678 ;;; FIXME: Add a comment telling whether this holds for all vectors
 679 ;;; or only for vectors based on simple arrays (non-adjustable, etc.).
 680 (def!constant vector-data-bit-offset
 681   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 682
 683 (deftransform replace ((string1 string2 &key (start1 0) (start2 0)
 684                                 end1 end2)
 685                        (simple-string simple-string &rest t)
 686                        *
 687                        ;; FIXME: consider replacing this policy test
 688                        ;; with some tests for the STARTx and ENDx
 689                        ;; indices being valid, conditional on high
 690                        ;; SAFETY code.
 691                        ;;
 692                        ;; FIXME: It turns out that this transform is
 693                        ;; critical for the performance of string
 694                        ;; streams.  Make this more explicit.
 695                        :policy (< (max safety space) 3))
 696   `(locally
 697      (declare (optimize (safety 0)))
 698      (bit-bash-copy string2
 699                     (the index
 700                          (+ (the index (* start2 sb!vm:n-byte-bits))
 701                             ,vector-data-bit-offset))
 702                     string1
 703                     (the index
 704                          (+ (the index (* start1 sb!vm:n-byte-bits))
 705                             ,vector-data-bit-offset))
 706                     (the index
 707                          (* (min (the index (- (or end1 (length string1))
 708                                                start1))
 709                                  (the index (- (or end2 (length string2))
 710                                                start2)))
 711                             sb!vm:n-byte-bits)))
 712      string1))
 713
 714 ;;; FIXME: It seems as though it should be possible to make a DEFUN
 715 ;;; %CONCATENATE (with a DEFTRANSFORM to translate constant RTYPE to
 716 ;;; CTYPE before calling %CONCATENATE) which is comparably efficient,
 717 ;;; at least once DYNAMIC-EXTENT works.
 718 ;;;
 719 ;;; FIXME: currently KLUDGEed because of bug 188
 720 (deftransform concatenate ((rtype &rest sequences)
 721                            (t &rest simple-string)
 722                            simple-string
 723                            :policy (< safety 3))
 724   (collect ((lets)
 725             (forms)
 726             (all-lengths)
 727             (args))
 728     (dolist (seq sequences)
 729       (declare (ignorable seq))
 730       (let ((n-seq (gensym))
 731             (n-length (gensym)))
 732         (args n-seq)
 733         (lets `(,n-length (the index (* (length ,n-seq) sb!vm:n-byte-bits))))
 734         (all-lengths n-length)
 735         (forms `(bit-bash-copy ,n-seq ,vector-data-bit-offset
 736                                res start
 737                                ,n-length))
 738         (forms `(setq start (opaque-identity (+ start ,n-length))))))
 739     `(lambda (rtype ,@(args))
 740        (declare (ignore rtype))
 741        ;; KLUDGE
 742        (flet ((opaque-identity (x) x))
 743          (declare (notinline opaque-identity))
 744          (let* (,@(lets)
 745                   (res (make-string (truncate (the index (+ ,@(all-lengths)))
 746                                               sb!vm:n-byte-bits)))
 747                   (start ,vector-data-bit-offset))
 748            (declare (type index start ,@(all-lengths)))
 749            ,@(forms)
 750            res)))))
 751 \f
 752 ;;;; CONS accessor DERIVE-TYPE optimizers
 753
 754 (defoptimizer (car derive-type) ((cons))
 755   (let ((type (continuation-type cons))
 756         (null-type (specifier-type 'null)))
 757     (cond ((eq type null-type)
 758            null-type)
 759           ((cons-type-p type)
 760            (cons-type-car-type type)))))
 761
 762 (defoptimizer (cdr derive-type) ((cons))
 763   (let ((type (continuation-type cons))
 764         (null-type (specifier-type 'null)))
 765     (cond ((eq type null-type)
 766            null-type)
 767           ((cons-type-p type)
 768            (cons-type-cdr-type type)))))
 769 \f
 770 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
 771
 772 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
 773 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
 774 ;;; expansion, so we factor out the condition into this function.
 775 (defun check-inlineability-of-find-position-if (sequence from-end)
 776   (let ((ctype (continuation-type sequence)))
 777     (cond ((csubtypep ctype (specifier-type 'vector))
 778            ;; It's not worth trying to inline vector code unless we
 779            ;; know a fair amount about it at compile time.
 780            (upgraded-element-type-specifier-or-give-up sequence)
 781            (unless (constant-continuation-p from-end)
 782              (give-up-ir1-transform
 783               "FROM-END argument value not known at compile time")))
 784           ((csubtypep ctype (specifier-type 'list))
 785            ;; Inlining on lists is generally worthwhile.
 786            )
 787           (t
 788            (give-up-ir1-transform
 789             "sequence type not known at compile time")))))
 790
 791 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
 792 (macrolet ((def (name condition)
 793              `(deftransform ,name ((predicate sequence from-end start end key)
 794                                    (function list t t t function)
 795                                    *
 796                                    :policy (> speed space)
 797                                    :important t)
 798                 "expand inline"
 799                 `(let ((index 0)
 800                        (find nil)
 801                        (position nil))
 802                    (declare (type index index))
 803                    (dolist (i sequence
 804                             (if (and end (> end index))
 805                                 (sb!impl::signal-bounding-indices-bad-error
 806                                  sequence start end)
 807                                 (values find position)))
 808                      (let ((key-i (funcall key i)))
 809                        (when (and end (>= index end))
 810                          (return (values find position)))
 811                        (when (>= index start)
 812                          (,',condition (funcall predicate key-i)
 813                           ;; This hack of dealing with non-NIL
 814                           ;; FROM-END for list data by iterating
 815                           ;; forward through the list and keeping
 816                           ;; track of the last time we found a match
 817                           ;; might be more screwy than what the user
 818                           ;; expects, but it seems to be allowed by
 819                           ;; the ANSI standard. (And if the user is
 820                           ;; screwy enough to ask for FROM-END
 821                           ;; behavior on list data, turnabout is
 822                           ;; fair play.)
 823                           ;;
 824                           ;; It's also not enormously efficient,
 825                           ;; calling PREDICATE and KEY more often
 826                           ;; than necessary; but all the
 827                           ;; alternatives seem to have their own
 828                           ;; efficiency problems.
 829                           (if from-end
 830                               (setf find i
 831                                     position index)
 832                               (return (values i index))))))
 833                      (incf index))))))
 834   (def %find-position-if when)
 835   (def %find-position-if-not unless))
 836
 837 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
 838 ;;; without loss of efficiency. (I.e., the optimizer should be able
 839 ;;; to straighten everything out.)
 840 (deftransform %find-position ((item sequence from-end start end key test)
 841                               (t list t t t t t)
 842                               *
 843                               :policy (> speed space)
 844                               :important t)
 845   "expand inline"
 846   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
 847                         ;; The order of arguments for asymmetric tests
 848                         ;; (e.g. #'<, as opposed to order-independent
 849                         ;; tests like #'=) is specified in the spec
 850                         ;; section 17.2.1 -- the O/Zi stuff there.
 851                         (lambda (i)
 852                           (funcall test-fun item i)))
 853                       sequence
 854                       from-end
 855                       start
 856                       end
 857                       (%coerce-callable-to-fun key)))
 858
 859 ;;; The inline expansions for the VECTOR case are saved as macros so
 860 ;;; that we can share them between the DEFTRANSFORMs and the default
 861 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
 862 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
 863 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
 864                                                             from-end
 865                                                             start
 866                                                             end-arg
 867                                                             element
 868                                                             done-p-expr)
 869   (with-unique-names (offset block index n-sequence sequence n-end end)
 870     `(let ((,n-sequence ,sequence-arg)
 871            (,n-end ,end-arg))
 872        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
 873                          (,start ,start)
 874                          (,end (%check-vector-sequence-bounds
 875                                 ,n-sequence ,start ,n-end)))
 876          (block ,block
 877            (macrolet ((maybe-return ()
 878                         '(let ((,element (aref ,sequence ,index)))
 879                            (when ,done-p-expr
 880                              (return-from ,block
 881                                (values ,element
 882                                        (- ,index ,offset)))))))
 883              (if ,from-end
 884                  (loop for ,index
 885                        ;; (If we aren't fastidious about declaring that
 886                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
 887                        ;; can send us off into never-never land, since
 888                        ;; INDEX is initialized to -1.)
 889                        of-type index-or-minus-1
 890                        from (1- ,end) downto ,start do
 891                        (maybe-return))
 892                  (loop for ,index of-type index from ,start below ,end do
 893                        (maybe-return))))
 894            (values nil nil))))))
 895
 896 (def!macro %find-position-vector-macro (item sequence
 897                                              from-end start end key test)
 898   (with-unique-names (element)
 899     (%find-position-or-find-position-if-vector-expansion
 900      sequence
 901      from-end
 902      start
 903      end
 904      element
 905      ;; (See the LIST transform for a discussion of the correct
 906      ;; argument order, i.e. whether the searched-for ,ITEM goes before
 907      ;; or after the checked sequence element.)
 908      `(funcall ,test ,item (funcall ,key ,element)))))
 909
 910 (def!macro %find-position-if-vector-macro (predicate sequence
 911                                                      from-end start end key)
 912   (with-unique-names (element)
 913     (%find-position-or-find-position-if-vector-expansion
 914      sequence
 915      from-end
 916      start
 917      end
 918      element
 919      `(funcall ,predicate (funcall ,key ,element)))))
 920
 921 (def!macro %find-position-if-not-vector-macro (predicate sequence
 922                                                          from-end start end key)
 923   (with-unique-names (element)
 924     (%find-position-or-find-position-if-vector-expansion
 925      sequence
 926      from-end
 927      start
 928      end
 929      element
 930      `(not (funcall ,predicate (funcall ,key ,element))))))
 931
 932 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
 933 ;;; VECTOR data
 934 (deftransform %find-position-if ((predicate sequence from-end start end key)
 935                                  (function vector t t t function)
 936                                  *
 937                                  :policy (> speed space)
 938                                  :important t)
 939   "expand inline"
 940   (check-inlineability-of-find-position-if sequence from-end)
 941   '(%find-position-if-vector-macro predicate sequence
 942                                    from-end start end key))
 943
 944 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
 945                                      (function vector t t t function)
 946                                      *
 947                                      :policy (> speed space)
 948                                      :important t)
 949   "expand inline"
 950   (check-inlineability-of-find-position-if sequence from-end)
 951   '(%find-position-if-not-vector-macro predicate sequence
 952                                        from-end start end key))
 953
 954 (deftransform %find-position ((item sequence from-end start end key test)
 955                               (t vector t t t function function)
 956                               *
 957                               :policy (> speed space)
 958                               :important t)
 959   "expand inline"
 960   (check-inlineability-of-find-position-if sequence from-end)
 961   '(%find-position-vector-macro item sequence
 962                                 from-end start end key test))
 963
 964 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
 965 ;;; POSITION-IF, etc.
 966 (define-source-transform effective-find-position-test (test test-not)
 967   (once-only ((test test)
 968               (test-not test-not))
 969     `(cond
 970       ((and ,test ,test-not)
 971        (error "can't specify both :TEST and :TEST-NOT"))
 972       (,test (%coerce-callable-to-fun ,test))
 973       (,test-not
 974        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
 975        ;; inefficient, but since the TEST-NOT option is deprecated
 976        ;; anyway, we don't care.)
 977        (complement (%coerce-callable-to-fun ,test-not)))
 978       (t #'eql))))
 979 (define-source-transform effective-find-position-key (key)
 980   (once-only ((key key))
 981     `(if ,key
 982          (%coerce-callable-to-fun ,key)
 983          #'identity)))
 984
 985 (macrolet ((define-find-position (fun-name values-index)
 986              `(deftransform ,fun-name ((item sequence &key
 987                                              from-end (start 0) end
 988                                              key test test-not))
 989                 '(nth-value ,values-index
 990                             (%find-position item sequence
 991                                             from-end start
 992                                             end
 993                                             (effective-find-position-key key)
 994                                             (effective-find-position-test
 995                                              test test-not))))))
 996   (define-find-position find 0)
 997   (define-find-position position 1))
 998
 999 (macrolet ((define-find-position-if (fun-name values-index)
1000              `(deftransform ,fun-name ((predicate sequence &key
1001                                                   from-end (start 0)
1002                                                   end key))
1003                 '(nth-value
1004                   ,values-index
1005                   (%find-position-if (%coerce-callable-to-fun predicate)
1006                                      sequence from-end
1007                                      start end
1008                                      (effective-find-position-key key))))))
1009   (define-find-position-if find-if 0)
1010   (define-find-position-if position-if 1))
1011
1012 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1013 ;;; didn't bother to worry about optimizing them, except note that on
1014 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1015 ;;; sbcl-devel
1016 ;;;
1017 ;;;     My understanding is that while the :test-not argument is
1018 ;;;     deprecated in favour of :test (complement #'foo) because of
1019 ;;;     semantic difficulties (what happens if both :test and :test-not
1020 ;;;     are supplied, etc) the -if-not variants, while officially
1021 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1022 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1023 ;;;     reasons for allowing the -if-not versions equal status,
1024 ;;;     particularly remove-if-not (== filter).
1025 ;;;
1026 ;;;     This is only an informal understanding, I grant you, but
1027 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1028 ;;;     way as the others?
1029 ;;;
1030 ;;; FIXME: Maybe remove uses of these deprecated functions (and
1031 ;;; definitely of :TEST-NOT) within the implementation of SBCL.
1032 (macrolet ((define-find-position-if-not (fun-name values-index)
1033                `(deftransform ,fun-name ((predicate sequence &key
1034                                           from-end (start 0)
1035                                           end key))
1036                  '(nth-value
1037                    ,values-index
1038                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1039                     sequence from-end
1040                     start end
1041                     (effective-find-position-key key))))))
1042   (define-find-position-if-not find-if-not 0)
1043   (define-find-position-if-not position-if-not 1))