src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places))
 137     (let ((found-vector-p nil))
 138       (flet ((process-vector (length)
 139                (unless found-vector-p
 140                  (setq found-vector-p t)
 141                  (bindings `(index 0 (1+ index)))
 142                  (declarations `(type index index)))
 143                (vector-lengths length)))
 144         (loop for seq of-type lvar in seqs
 145            for seq-name in seq-names
 146            for type = (lvar-type seq)
 147            do (cond ((csubtypep type (specifier-type 'list))
 148                      (with-unique-names (index)
 149                        (bindings `(,index ,seq-name (cdr ,index)))
 150                        (declarations `(type list ,index))
 151                        (places `(car ,index))
 152                        (tests `(endp ,index))))
 153                     ((csubtypep type (specifier-type 'vector))
 154                      (process-vector `(length ,seq-name))
 155                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 156                                 (aref ,seq-name index))))
 157                     (t
 158                      (give-up-ir1-transform
 159                       "can't determine sequence argument type"))))
 160         (when into
 161           (process-vector `(array-dimension ,into 0))))
 162       (when found-vector-p
 163         (bindings `(length (min ,@(vector-lengths))))
 164         (tests `(>= index length)))
 165       `(do (,@(bindings))
 166            ((or ,@(tests)) ,result)
 167          (declare ,@(declarations))
 168          (let ((funcall-result (funcall fun ,@(places))))
 169            (declare (ignorable funcall-result))
 170            ,body)))))
 171
 172 ;;; Try to compile %MAP efficiently when we can determine sequence
 173 ;;; argument types at compile time.
 174 ;;;
 175 ;;; Note: This transform was written to allow open coding of
 176 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 177 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 178 ;;; necessarily as efficient as possible. In particular, it will be
 179 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 180 ;;; numeric element types. It should be straightforward to make it
 181 ;;; handle that case more efficiently, but it's left as an exercise to
 182 ;;; the reader, because the code is complicated enough already and I
 183 ;;; don't happen to need that functionality right now. -- WHN 20000410
 184 (deftransform %map ((result-type fun seq &rest seqs) * *
 185                     :policy (>= speed space))
 186   "open code"
 187   (unless (constant-lvar-p result-type)
 188     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 189   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 190            (fn-1subtypep (fn x y)
 191              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 192                (if valid-p
 193                    subtype-p
 194                    (give-up-ir1-transform
 195                     "can't analyze sequence type relationship"))))
 196            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 197     (let* ((result-type-value (lvar-value result-type))
 198            (result-supertype (cond ((null result-type-value) 'null)
 199                                    ((1subtypep result-type-value 'vector)
 200                                     'vector)
 201                                    ((1subtypep result-type-value 'list)
 202                                     'list)
 203                                    (t
 204                                     (give-up-ir1-transform
 205                                      "result type unsuitable")))))
 206       (cond ((and result-type-value (null seqs))
 207              ;; The consing arity-1 cases can be implemented
 208              ;; reasonably efficiently as function calls, and the cost
 209              ;; of consing should be significantly larger than
 210              ;; function call overhead, so we always compile these
 211              ;; cases as full calls regardless of speed-versus-space
 212              ;; optimization policy.
 213              (cond ((subtypep result-type-value 'list)
 214                     '(%map-to-list-arity-1 fun seq))
 215                    ( ;; (This one can be inefficient due to COERCE, but
 216                     ;; the current open-coded implementation has the
 217                     ;; same problem.)
 218                     (subtypep result-type-value 'vector)
 219                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 220                              ',result-type-value))
 221                    (t (bug "impossible (?) sequence type"))))
 222             (t
 223              (let* ((seqs (cons seq seqs))
 224                     (seq-args (make-gensym-list (length seqs))))
 225                (multiple-value-bind (push-dacc result)
 226                    (ecase result-supertype
 227                      (null (values nil nil))
 228                      (list (values `(push funcall-result acc)
 229                                    `(nreverse acc)))
 230                      (vector (values `(push funcall-result acc)
 231                                      `(coerce (nreverse acc)
 232                                               ',result-type-value))))
 233                  ;; (We use the same idiom, of returning a LAMBDA from
 234                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 235                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 236                  ;; reason: we need to get the runtime values of each
 237                  ;; of the &REST vars.)
 238                  `(lambda (result-type fun ,@seq-args)
 239                     (declare (ignore result-type))
 240                     (let ((fun (%coerce-callable-to-fun fun))
 241                           (acc nil))
 242                       (declare (type list acc))
 243                       (declare (ignorable acc))
 244                       ,(build-sequence-iterator
 245                         seqs seq-args
 246                         :result result
 247                         :body push-dacc))))))))))
 248
 249 ;;; MAP-INTO
 250 (deftransform map-into ((result fun &rest seqs)
 251                         (vector * &rest *)
 252                         *)
 253   "open code"
 254   (let ((seqs-names (mapcar (lambda (x)
 255                               (declare (ignore x))
 256                               (gensym))
 257                             seqs)))
 258     `(lambda (result fun ,@seqs-names)
 259        ,(build-sequence-iterator
 260          seqs seqs-names
 261          :result '(when (array-has-fill-pointer-p result)
 262                    (setf (fill-pointer result) index))
 263          :into 'result
 264          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 265                  (setf (aref result index) funcall-result)))
 266        result)))
 267
 268 \f
 269 ;;; FIXME: once the confusion over doing transforms with known-complex
 270 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 271 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 272 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 273   '(aref s i))
 274
 275 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 276   '(nth i s))
 277
 278 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 279   '(%aset s i v))
 280
 281 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 282   '(setf (car (nthcdr i s)) v))
 283
 284 (deftransform %check-vector-sequence-bounds ((vector start end)
 285                                              (vector * *) *
 286                                              :node node)
 287   (if (policy node (= 0 insert-array-bounds-checks))
 288       '(or end (length vector))
 289       '(let ((length (length vector)))
 290          (if (<= 0 start (or end length) length)
 291              (or end length)
 292              (sequence-bounding-indices-bad-error vector start end)))))
 293
 294 (deftype eq-comparable-type ()
 295   '(or fixnum (not number)))
 296
 297 ;;; True if EQL comparisons involving type can be simplified to EQ.
 298 (defun eq-comparable-type-p (type)
 299   (csubtypep type (specifier-type 'eq-comparable-type)))
 300
 301 (defun specialized-list-seek-function-name (function-name key-functions &optional variant)
 302   (or (find-symbol (with-output-to-string (s)
 303                      ;; Write "%NAME-FUN1-FUN2-FUN3", etc. Not only is
 304                      ;; this ever so slightly faster then FORMAT, this
 305                      ;; way we are also proof against *PRINT-CASE*
 306                      ;; frobbing and such.
 307                      (write-char #\% s)
 308                      (write-string (symbol-name function-name) s)
 309                      (dolist (f key-functions)
 310                        (write-char #\- s)
 311                        (write-string (symbol-name f) s))
 312                      (when variant
 313                        (write-char #\- s)
 314                        (write-string (symbol-name variant) s)))
 315                    (load-time-value (find-package "SB!KERNEL")))
 316       (bug "Unknown list item seek transform: name=~S, key-functions=~S variant=~S"
 317            function-name key-functions variant)))
 318
 319 (defun transform-list-item-seek (name item list key test test-not node)
 320   ;; If TEST is EQL, drop it.
 321   (when (and test (lvar-fun-is test '(eql)))
 322     (setf test nil))
 323   ;; Ditto for KEY IDENTITY.
 324   (when (and key (lvar-fun-is key '(identity)))
 325     (setf key nil))
 326   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 327   ;; not there at all. If it might be NIL, make up a form to that
 328   ;; ensures it is a function.
 329   (multiple-value-bind (key key-form)
 330       (when key
 331         (let ((key-type (lvar-type key))
 332               (null-type (specifier-type 'null)))
 333           (cond ((csubtypep key-type null-type)
 334                  (values nil nil))
 335                 ((csubtypep null-type key-type)
 336                  (values key '(if key
 337                                (%coerce-callable-to-fun key)
 338                                #'identity)))
 339                 (t
 340                  (values key (ensure-lvar-fun-form key 'key))))))
 341     (let* ((c-test (cond ((and test (lvar-fun-is test '(eq)))
 342                           (setf test nil)
 343                           'eq)
 344                          ((and (not test) (not test-not))
 345                           (when (eq-comparable-type-p (lvar-type item))
 346                             'eq))))
 347            (funs (delete nil (list (when key (list key 'key))
 348                                    (when test (list test 'test))
 349                                    (when test-not (list test-not 'test-not)))))
 350            (target-expr (if key '(%funcall key target) 'target))
 351            (test-expr (cond (test `(%funcall test item ,target-expr))
 352                             (test-not `(not (%funcall test-not item ,target-expr)))
 353                             (c-test `(,c-test item ,target-expr))
 354                             (t `(eql item ,target-expr)))))
 355       (labels ((open-code (tail)
 356                  (when tail
 357                    `(if (let ((this ',(car tail)))
 358                           ,(ecase name
 359                                   ((assoc rassoc)
 360                                    (let ((cxx (if (eq name 'assoc) 'car 'cdr)))
 361                                      `(and this (let ((target (,cxx this)))
 362                                                   ,test-expr))))
 363                                   (member
 364                                    `(let ((target this))
 365                                       ,test-expr))))
 366                         ',(ecase name
 367                                  ((assoc rassoc) (car tail))
 368                                  (member tail))
 369                         ,(open-code (cdr tail)))))
 370                (ensure-fun (args)
 371                  (if (eq 'key (second args))
 372                      key-form
 373                      (apply #'ensure-lvar-fun-form args))))
 374         (let* ((cp (constant-lvar-p list))
 375                (c-list (when cp (lvar-value list))))
 376           (cond ((and cp c-list (member name '(assoc rassoc member))
 377                       (policy node (>= speed space)))
 378                  `(let ,(mapcar (lambda (fun) `(,(second fun) ,(ensure-fun fun))) funs)
 379                     ,(open-code c-list)))
 380                 ((and cp (not c-list))
 381                  ;; constant nil list
 382                  (if (eq name 'adjoin)
 383                      '(list item)
 384                      nil))
 385                 (t
 386                  ;; specialized out-of-line version
 387                  `(,(specialized-list-seek-function-name name (mapcar #'second funs) c-test)
 388                     item list ,@(mapcar #'ensure-fun funs)))))))))
 389
 390 (defun transform-list-pred-seek (name pred list key node)
 391   ;; If KEY is IDENTITY, drop it.
 392   (when (and key (lvar-fun-is key '(identity)))
 393     (setf key nil))
 394   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 395   ;; not there at all. If it might be NIL, make up a form to that
 396   ;; ensures it is a function.
 397   (multiple-value-bind (key key-form)
 398       (when key
 399         (let ((key-type (lvar-type key))
 400               (null-type (specifier-type 'null)))
 401           (cond ((csubtypep key-type null-type)
 402                  (values nil nil))
 403                 ((csubtypep null-type key-type)
 404                  (values key '(if key
 405                                (%coerce-callable-to-fun key)
 406                                #'identity)))
 407                 (t
 408                  (values key (ensure-lvar-fun-form key 'key))))))
 409     (let ((test-expr `(%funcall pred ,(if key '(%funcall key target) 'target)))
 410           (pred-expr (ensure-lvar-fun-form pred 'pred)))
 411       (when (member name '(member-if-not assoc-if-not rassoc-if-not))
 412         (setf test-expr `(not ,test-expr)))
 413       (labels ((open-code (tail)
 414                  (when tail
 415                    `(if (let ((this ',(car tail)))
 416                           ,(ecase name
 417                                   ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 418                                    (let ((cxx (if (member name '(assoc-if assoc-if-not)) 'car 'cdr)))
 419                                      `(and this (let ((target (,cxx this)))
 420                                                   ,test-expr))))
 421                                   ((member-if member-if-not)
 422                                    `(let ((target this))
 423                                       ,test-expr))))
 424                         ',(ecase name
 425                                  ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 426                                   (car tail))
 427                                  ((member-if member-if-not)
 428                                   tail))
 429                         ,(open-code (cdr tail))))))
 430         (let* ((cp (constant-lvar-p list))
 431                (c-list (when cp (lvar-value list))))
 432           (cond ((and cp c-list (policy node (>= speed space)))
 433                  `(let ((pred ,pred-expr)
 434                         ,@(when key `((key ,key-form))))
 435                     ,(open-code c-list)))
 436                 ((and cp (not c-list))
 437                  ;; constant nil list -- nothing to find!
 438                  nil)
 439                 (t
 440                  ;; specialized out-of-line version
 441                  `(,(specialized-list-seek-function-name name (when key '(key)))
 442                     ,pred-expr list ,@(when key (list key-form))))))))))
 443
 444 (macrolet ((def (name &optional if/if-not)
 445              (let ((basic (symbolicate "%" name))
 446                    (basic-eq (symbolicate "%" name "-EQ"))
 447                    (basic-key (symbolicate "%" name "-KEY"))
 448                    (basic-key-eq (symbolicate "%" name "-KEY-EQ")))
 449                `(progn
 450                   (deftransform ,name ((item list &key key test test-not) * * :node node)
 451                     (transform-list-item-seek ',name item list key test test-not node))
 452                   (deftransform ,basic ((item list) (eq-comparable-type t))
 453                     `(,',basic-eq item list))
 454                   (deftransform ,basic-key ((item list) (eq-comparable-type t))
 455                     `(,',basic-key-eq item list))
 456                   ,@(when if/if-not
 457                           (let ((if-name (symbolicate name "-IF"))
 458                                 (if-not-name (symbolicate name "-IF-NOT")))
 459                             `((deftransform ,if-name ((pred list &key key) * * :node node)
 460                                 (transform-list-pred-seek ',if-name pred list key node))
 461                               (deftransform ,if-not-name ((pred list &key key) * * :node node)
 462                                 (transform-list-pred-seek ',if-not-name pred list key node)))))))))
 463   (def adjoin)
 464   (def assoc  t)
 465   (def member t)
 466   (def rassoc t))
 467
 468 (deftransform memq ((item list) (t (constant-arg list)))
 469   (labels ((rec (tail)
 470              (if tail
 471                  `(if (eq item ',(car tail))
 472                       ',tail
 473                       ,(rec (cdr tail)))
 474                  nil)))
 475     (rec (lvar-value list))))
 476
 477 ;;; A similar transform used to apply to MEMBER and ASSOC, but since
 478 ;;; TRANSFORM-LIST-ITEM-SEEK now takes care of them those transform
 479 ;;; would never fire, and (%MEMBER-TEST ITEM LIST #'EQ) should be
 480 ;;; almost as fast as MEMQ.
 481 (deftransform delete ((item list &key test) (t list &rest t) *)
 482   "convert to EQ test"
 483   ;; FIXME: The scope of this transformation could be
 484   ;; widened somewhat, letting it work whenever the test is
 485   ;; 'EQL and we know from the type of ITEM that it #'EQ
 486   ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 487   ;; and SYMBOL.)
 488   ;;   If TEST is EQ, apply transform, else
 489   ;;   if test is not EQL, then give up on transform, else
 490   ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 491   ;;   transform, else give up on transform.
 492   (cond (test
 493          (unless (lvar-fun-is test '(eq))
 494            (give-up-ir1-transform)))
 495         ((types-equal-or-intersect (lvar-type item)
 496                                    (specifier-type 'number))
 497          (give-up-ir1-transform "Item might be a number.")))
 498   `(delq item list))
 499
 500 (deftransform delete-if ((pred list) (t list))
 501   "open code"
 502   '(do ((x list (cdr x))
 503         (splice '()))
 504        ((endp x) list)
 505      (cond ((funcall pred (car x))
 506             (if (null splice)
 507                 (setq list (cdr x))
 508                 (rplacd splice (cdr x))))
 509            (t (setq splice x)))))
 510
 511 (deftransform fill ((seq item &key (start 0) (end nil))
 512                     (list t &key (:start t) (:end t)))
 513   '(list-fill* seq item start end))
 514
 515 (deftransform fill ((seq item &key (start 0) (end nil))
 516                     (vector t &key (:start t) (:end t))
 517                     *
 518                     :node node)
 519   (let ((type (lvar-type seq))
 520         (element-type (type-specifier (extract-upgraded-element-type seq))))
 521     (cond ((and (neq '* element-type) (policy node (> speed space)))
 522            (values
 523             `(with-array-data ((data seq)
 524                                (start start)
 525                                (end end)
 526                                :check-fill-pointer t)
 527                (declare (type (simple-array ,element-type 1) data))
 528                (declare (type index start end))
 529                ;; WITH-ARRAY-DATA did our range checks once and for all, so
 530                ;; it'd be wasteful to check again on every AREF...
 531                (declare (optimize (safety 0) (speed 3)))
 532                (do ((i start (1+ i)))
 533                    ((= i end) seq)
 534                  (declare (type index i))
 535                  (setf (aref data i) item)))
 536             ;; ... though we still need to check that the new element can fit
 537             ;; into the vector in safe code. -- CSR, 2002-07-05
 538             `((declare (type ,element-type item)))))
 539           ((csubtypep type (specifier-type 'string))
 540            '(string-fill* seq item start end))
 541           (t
 542            '(vector-fill* seq item start end)))))
 543
 544 (deftransform fill ((seq item &key (start 0) (end nil))
 545                     ((and sequence (not vector) (not list)) t &key (:start t) (:end t)))
 546   `(sb!sequence:fill seq item
 547                      :start start
 548                      :end (%check-generic-sequence-bounds seq start end)))
 549 \f
 550 ;;;; utilities
 551
 552 ;;; If LVAR is a constant lvar, the return the constant value. If it
 553 ;;; is null, then return default, otherwise quietly give up the IR1
 554 ;;; transform.
 555 ;;;
 556 ;;; ### Probably should take an ARG and flame using the NAME.
 557 (defun constant-value-or-lose (lvar &optional default)
 558   (declare (type (or lvar null) lvar))
 559   (cond ((not lvar) default)
 560         ((constant-lvar-p lvar)
 561          (lvar-value lvar))
 562         (t
 563          (give-up-ir1-transform))))
 564
 565
 566 ;;;; hairy sequence transforms
 567
 568 ;;; FIXME: no hairy sequence transforms in SBCL?
 569 ;;;
 570 ;;; There used to be a bunch of commented out code about here,
 571 ;;; containing the (apparent) beginning of hairy sequence transform
 572 ;;; infrastructure. People interested in implementing better sequence
 573 ;;; transforms might want to look at it for inspiration, even though
 574 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 575 ;;; was deleted in 1.0.7.23.
 576 \f
 577 ;;;; string operations
 578
 579 ;;; We transform the case-sensitive string predicates into a non-keyword
 580 ;;; version. This is an IR1 transform so that we don't have to worry about
 581 ;;; changing the order of evaluation.
 582 (macrolet ((def (fun pred*)
 583              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 584                                                          (start2 0) end2)
 585                                    * *)
 586                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 587   (def string< string<*)
 588   (def string> string>*)
 589   (def string<= string<=*)
 590   (def string>= string>=*)
 591   (def string= string=*)
 592   (def string/= string/=*))
 593
 594 ;;; Return a form that tests the free variables STRING1 and STRING2
 595 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 596 ;;; start and end are also gotten from the environment. Both strings
 597 ;;; must be SIMPLE-BASE-STRINGs.
 598 (macrolet ((def (name lessp equalp)
 599              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 600                                    (simple-base-string simple-base-string t t t t) *)
 601                 `(let* ((end1 (if (not end1) (length string1) end1))
 602                         (end2 (if (not end2) (length string2) end2))
 603                         (index (sb!impl::%sp-string-compare
 604                                 string1 start1 end1 string2 start2 end2)))
 605                   (if index
 606                       (cond ((= index end1)
 607                              ,(if ',lessp 'index nil))
 608                             ((= (+ index (- start2 start1)) end2)
 609                              ,(if ',lessp nil 'index))
 610                             ((,(if ',lessp 'char< 'char>)
 611                                (schar string1 index)
 612                                (schar string2
 613                                       (truly-the index
 614                                                  (+ index
 615                                                     (truly-the fixnum
 616                                                                (- start2
 617                                                                   start1))))))
 618                              index)
 619                             (t nil))
 620                       ,(if ',equalp 'end1 nil))))))
 621   (def string<* t nil)
 622   (def string<=* t t)
 623   (def string>* nil nil)
 624   (def string>=* nil t))
 625
 626 (macrolet ((def (name result-fun)
 627              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 628                                    (simple-base-string simple-base-string t t t t) *)
 629                 `(,',result-fun
 630                   (sb!impl::%sp-string-compare
 631                    string1 start1 (or end1 (length string1))
 632                    string2 start2 (or end2 (length string2)))))))
 633   (def string=* not)
 634   (def string/=* identity))
 635
 636 \f
 637 ;;;; transforms for sequence functions
 638
 639 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 640 ;;; to vectors based on simple arrays.
 641 (def!constant vector-data-bit-offset
 642   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 643
 644 (eval-when (:compile-toplevel)
 645 (defun valid-bit-bash-saetp-p (saetp)
 646   ;; BIT-BASHing isn't allowed on simple vectors that contain pointers
 647   (and (not (eq t (sb!vm:saetp-specifier saetp)))
 648        ;; Disallowing (VECTOR NIL) also means that we won't transform
 649        ;; sequence functions into bit-bashing code and we let the
 650        ;; generic sequence functions signal errors if necessary.
 651        (not (zerop (sb!vm:saetp-n-bits saetp)))
 652        ;; Due to limitations with the current BIT-BASHing code, we can't
 653        ;; BIT-BASH reliably on arrays whose element types are larger
 654        ;; than the word size.
 655        (<= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)))
 656 ) ; EVAL-WHEN
 657
 658 ;;; FIXME: In the copy loops below, we code the loops in a strange
 659 ;;; fashion:
 660 ;;;
 661 ;;; (do ((i (+ src-offset length) (1- i)))
 662 ;;;     ((<= i 0) ...)
 663 ;;;   (... (aref foo (1- i)) ...))
 664 ;;;
 665 ;;; rather than the more natural (and seemingly more efficient):
 666 ;;;
 667 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 668 ;;;     ((< i 0) ...)
 669 ;;;   (... (aref foo i) ...))
 670 ;;;
 671 ;;; (more efficient because we don't have to do the index adjusting on
 672 ;;; every iteration of the loop)
 673 ;;;
 674 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 675 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 676 ;;; when used as an array index, the backend thinks I is a
 677 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 678 ;;; these as distinct storage classes, it cannot coerce a move from a
 679 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 680 ;;; deficiency is that we have two extra moves and increased register
 681 ;;; pressure, which can lead to some spectacularly bad register
 682 ;;; allocation.  (sub-FIXME: the register allocation even with the
 683 ;;; strangely written loops is not always excellent, either...).  Doing
 684 ;;; it the first way, above, means that I is always thought of as a
 685 ;;; POSITIVE-FIXNUM and there are no issues.
 686 ;;;
 687 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 688 ;;; adjustments in the first version into the array addressing at no
 689 ;;; performance penalty!
 690
 691 ;;; This transform is critical to the performance of string streams.  If
 692 ;;; you tweak it, make sure that you compare the disassembly, if not the
 693 ;;; performance of, the functions implementing string streams
 694 ;;; (e.g. SB!IMPL::STRING-OUCH).
 695 (eval-when (:compile-toplevel :load-toplevel :execute)
 696   (defun make-replace-transform (saetp sequence-type1 sequence-type2)
 697     `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 698                             (,sequence-type1 ,sequence-type2 &rest t)
 699                             ,sequence-type1
 700                             :node node)
 701        ,(cond
 702          ((and saetp (valid-bit-bash-saetp-p saetp)) nil)
 703          ;; If the sequence types are different, SEQ1 and SEQ2 must
 704          ;; be distinct arrays, and we can open code the copy loop.
 705          ((not (eql sequence-type1 sequence-type2)) nil)
 706          ;; If we're not bit-bashing, only allow cases where we
 707          ;; can determine the order of copying up front.  (There
 708          ;; are actually more cases we can handle if we know the
 709          ;; amount that we're copying, but this handles the
 710          ;; common cases.)
 711          (t '(unless (= (constant-value-or-lose start1 0)
 712                       (constant-value-or-lose start2 0))
 713               (give-up-ir1-transform))))
 714        `(let* ((len1 (length seq1))
 715                (len2 (length seq2))
 716                (end1 (or end1 len1))
 717                (end2 (or end2 len2))
 718                (replace-len1 (- end1 start1))
 719                (replace-len2 (- end2 start2)))
 720           ,(unless (policy node (= safety 0))
 721              `(progn
 722                  (unless (<= 0 start1 end1 len1)
 723                    (sequence-bounding-indices-bad-error seq1 start1 end1))
 724                  (unless (<= 0 start2 end2 len2)
 725                    (sequence-bounding-indices-bad-error seq2 start2 end2))))
 726           ,',(cond
 727               ((and saetp (valid-bit-bash-saetp-p saetp))
 728                (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 729                       (bash-function (intern (format nil "UB~D-BASH-COPY"
 730                                                      n-element-bits)
 731                                              (find-package "SB!KERNEL"))))
 732                  `(funcall (function ,bash-function) seq2 start2
 733                            seq1 start1 (min replace-len1 replace-len2))))
 734               (t
 735                ;; We can expand the loop inline here because we
 736                ;; would have given up the transform (see above)
 737                ;; if we didn't have constant matching start
 738                ;; indices.
 739                '(do ((i start1 (1+ i))
 740                      (j start2 (1+ j))
 741                      (end (+ start1
 742                              (min replace-len1 replace-len2))))
 743                  ((>= i end))
 744                  (declare (optimize (insert-array-bounds-checks 0)))
 745                  (setf (aref seq1 i) (aref seq2 j)))))
 746           seq1))))
 747
 748 (macrolet
 749     ((define-replace-transforms ()
 750        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 751              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 752              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 753              collect (make-replace-transform saetp sequence-type sequence-type)
 754              into forms
 755              finally (return `(progn ,@forms))))
 756      (define-one-transform (sequence-type1 sequence-type2)
 757        (make-replace-transform nil sequence-type1 sequence-type2)))
 758   (define-replace-transforms)
 759   #!+sb-unicode
 760   (progn
 761    (define-one-transform (simple-array base-char (*)) (simple-array character (*)))
 762    (define-one-transform (simple-array character (*)) (simple-array base-char (*)))))
 763
 764 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 765 ;;; defined as those cases where we are doing word-aligned copies from
 766 ;;; both the source and the destination and we are copying from the same
 767 ;;; offset from both the source and the destination.  (The last
 768 ;;; condition is there so we can determine the direction to copy at
 769 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 770 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 771 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 772 ;;; N)-size buffer and blitting in the old N-size buffer in.
 773
 774 (defun frob-bash-transform (src src-offset
 775                             dst dst-offset
 776                             length n-elems-per-word)
 777   (declare (ignore src dst length))
 778   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 779     (multiple-value-bind (src-word src-elt)
 780         (truncate (lvar-value src-offset) n-elems-per-word)
 781       (multiple-value-bind (dst-word dst-elt)
 782           (truncate (lvar-value dst-offset) n-elems-per-word)
 783         ;; Avoid non-word aligned copies.
 784         (unless (and (zerop src-elt) (zerop dst-elt))
 785           (give-up-ir1-transform))
 786         ;; Avoid copies where we would have to insert code for
 787         ;; determining the direction of copying.
 788         (unless (= src-word dst-word)
 789           (give-up-ir1-transform))
 790         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 791         ;; so we have to do its work here.
 792         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 793                                       'length
 794                                       `(truncate (the index length) ,n-elems-per-word)))))
 795            (declare (type index end))
 796            ;; Handle any bits at the end.
 797            (when (logtest length (1- ,n-elems-per-word))
 798              (let* ((extra (mod length ,n-elems-per-word))
 799                     ;; FIXME: The shift amount on this ASH is
 800                     ;; *always* negative, but the backend doesn't
 801                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 802                     ;; wind up with a pile of code that tests the
 803                     ;; sign of the shift count prior to shifting when
 804                     ;; all we need is a simple negate and shift
 805                     ;; right.  Yuck.
 806                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 807                                (* (- extra ,n-elems-per-word)
 808                                   ,n-bits-per-elem))))
 809                (setf (sb!kernel:%vector-raw-bits dst end)
 810                      (logior
 811                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 812                                 (ash mask
 813                                      ,(ecase sb!c:*backend-byte-order*
 814                                              (:little-endian 0)
 815                                              (:big-endian `(* (- ,n-elems-per-word extra)
 816                                                               ,n-bits-per-elem)))))
 817                       (logand (sb!kernel:%vector-raw-bits src end)
 818                               (ash mask
 819                                    ,(ecase sb!c:*backend-byte-order*
 820                                            (:little-endian 0)
 821                                            (:big-endian `(* (- ,n-elems-per-word extra)
 822                                                             ,n-bits-per-elem)))))))))
 823            ;; Copy from the end to save a register.
 824            (do ((i end (1- i)))
 825                ((<= i ,src-word))
 826              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 827                    (sb!kernel:%vector-raw-bits src (1- i))))
 828            (values))))))
 829
 830 #.(loop for i = 1 then (* i 2)
 831         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 832                                         "SB!KERNEL")
 833                                                         ((src src-offset
 834                                                           dst dst-offset
 835                                                           length)
 836                                                         ((simple-unboxed-array (*))
 837                                                          (constant-arg index)
 838                                                          (simple-unboxed-array (*))
 839                                                          (constant-arg index)
 840                                                          index)
 841                                                         *)
 842                   (frob-bash-transform src src-offset
 843                                        dst dst-offset length
 844                                        ,(truncate sb!vm:n-word-bits i))) into forms
 845         until (= i sb!vm:n-word-bits)
 846         finally (return `(progn ,@forms)))
 847
 848 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 849 ;;; arrays with elements of size >= the word size.  We do this because
 850 ;;; we know the arrays cannot alias (one was just consed), therefore we
 851 ;;; can determine at compile time the direction to copy, and for
 852 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 853 ;;; needless checking to figure out what's going on.  The same
 854 ;;; considerations apply if we are copying elements larger than the word
 855 ;;; size, with the additional twist that doing it inline is likely to
 856 ;;; cons far less than calling REPLACE and letting generic code do the
 857 ;;; work.
 858 ;;;
 859 ;;; However, we do not do this for elements whose size is < than the
 860 ;;; word size because we don't want to deal with any alignment issues
 861 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 862 ;;; anyway.
 863
 864 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 865                                       element-type)
 866   (let ((saetp (find-saetp element-type)))
 867     (aver saetp)
 868     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 869         (expand-aref-copy-loop src src-offset dst dst-offset length)
 870         `(locally (declare (optimize (safety 0)))
 871            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 872
 873 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 874   (if (eql src-offset dst-offset)
 875       `(do ((i (+ ,src-offset ,length) (1- i)))
 876            ((<= i ,src-offset))
 877          (declare (optimize (insert-array-bounds-checks 0)))
 878          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 879       ;; KLUDGE: The compiler is not able to derive that (+ offset
 880       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 881       ;; We, however, know it must be so, as by this point the bounds
 882       ;; have already been checked.
 883       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 884             (j (+ ,dst-offset ,length) (1- j)))
 885            ((<= i ,src-offset))
 886          (declare (optimize (insert-array-bounds-checks 0))
 887                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 888          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 889
 890 ;;; SUBSEQ, COPY-SEQ
 891
 892 (deftransform subseq ((seq start &optional end)
 893                       (vector t &optional t)
 894                       *
 895                       :node node)
 896   (let ((type (lvar-type seq)))
 897     (cond
 898       ((and (array-type-p type)
 899             (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 900        (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 901          `(let* ((length (length seq))
 902                  (end (or end length)))
 903             ,(unless (policy node (zerop insert-array-bounds-checks))
 904                      '(progn
 905                        (unless (<= 0 start end length)
 906                          (sequence-bounding-indices-bad-error seq start end))))
 907             (let* ((size (- end start))
 908                    (result (make-array size :element-type ',element-type)))
 909               ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
 910                                                        (lvar-value start)
 911                                                        'start)
 912                                               'result 0 'size element-type)
 913               result))))
 914       ((csubtypep type (specifier-type 'string))
 915        '(string-subseq* seq start end))
 916       (t
 917        '(vector-subseq* seq start end)))))
 918
 919 (deftransform subseq ((seq start &optional end)
 920                       (list t &optional t))
 921   `(list-subseq* seq start end))
 922
 923 (deftransform subseq ((seq start &optional end)
 924                       ((and sequence (not vector) (not list)) t &optional t))
 925   '(sb!sequence:subseq seq start end))
 926
 927 (deftransform copy-seq ((seq) (vector))
 928   (let ((type (lvar-type seq)))
 929     (cond ((and (array-type-p type)
 930                 (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 931            (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 932              `(let* ((length (length seq))
 933                      (result (make-array length :element-type ',element-type)))
 934                 ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
 935                 result)))
 936           ((csubtypep type (specifier-type 'string))
 937            '(string-subseq* seq 0 nil))
 938           (t
 939            '(vector-subseq* seq 0 nil)))))
 940
 941 (deftransform copy-seq ((seq) (list))
 942   '(list-copy-seq* seq))
 943
 944 (deftransform copy-seq ((seq) ((and sequence (not vector) (not list))))
 945   '(sb!sequence:copy-seq seq))
 946
 947 ;;; FIXME: it really should be possible to take advantage of the
 948 ;;; macros used in code/seq.lisp here to avoid duplication of code,
 949 ;;; and enable even funkier transformations.
 950 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
 951                                (test #'eql)
 952                                (key #'identity)
 953                                from-end)
 954                       (vector vector &rest t)
 955                       *
 956                       :node node
 957                       :policy (> speed (max space safety)))
 958   "open code"
 959   (let ((from-end (when (lvar-p from-end)
 960                     (unless (constant-lvar-p from-end)
 961                       (give-up-ir1-transform ":FROM-END is not constant."))
 962                     (lvar-value from-end)))
 963         (keyp (lvar-p key))
 964         (testp (lvar-p test))
 965         (check-bounds-p (policy node (plusp insert-array-bounds-checks))))
 966     `(block search
 967        (flet ((oops (vector start end)
 968                 (sequence-bounding-indices-bad-error vector start end)))
 969          (let* ((len1 (length pattern))
 970                 (len2 (length text))
 971                 (end1 (or end1 len1))
 972                 (end2 (or end2 len2))
 973                ,@(when keyp
 974                        '((key (coerce key 'function))))
 975                ,@(when testp
 976                        '((test (coerce test 'function)))))
 977           (declare (type index start1 start2 end1 end2))
 978           ,@(when check-bounds-p
 979              `((unless (<= start1 end1 len1)
 980                  (oops pattern start1 end1))
 981                (unless (<= start2 end2 len2)
 982                  (oops pattern start2 end2))))
 983           (do (,(if from-end
 984                     '(index2 (- end2 (- end1 start1)) (1- index2))
 985                     '(index2 start2 (1+ index2))))
 986               (,(if from-end
 987                     '(< index2 start2)
 988                     '(>= index2 end2))
 989                nil)
 990             ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
 991             ;; terminates is hits -1 when :FROM-END is true and :START2
 992             ;; is 0.
 993             (declare (type fixnum index2))
 994             (when (do ((index1 start1 (1+ index1))
 995                        (index2 index2 (1+ index2)))
 996                       ((>= index1 end1) t)
 997                     (declare (type index index1 index2)
 998                              (optimize (insert-array-bounds-checks 0)))
 999                     ,@(unless from-end
1000                               '((when (= index2 end2)
1001                                   (return-from search nil))))
1002                     (unless (,@(if testp
1003                                    '(funcall test)
1004                                    '(eql))
1005                                ,(if keyp
1006                                     '(funcall key (aref pattern index1))
1007                                     '(aref pattern index1))
1008                                ,(if keyp
1009                                     '(funcall key (aref text index2))
1010                                     '(aref text index2)))
1011                       (return nil)))
1012               (return index2))))))))
1013
1014
1015 ;;; Open-code CONCATENATE for strings. It would be possible to extend
1016 ;;; this transform to non-strings, but I chose to just do the case that
1017 ;;; should cover 95% of CONCATENATE performance complaints for now.
1018 ;;;   -- JES, 2007-11-17
1019 (deftransform concatenate ((result-type &rest lvars)
1020                            (symbol &rest sequence)
1021                            *
1022                            :policy (> speed space))
1023   (unless (constant-lvar-p result-type)
1024     (give-up-ir1-transform))
1025   (let* ((element-type (let ((type (lvar-value result-type)))
1026                          ;; Only handle the simple result type cases. If
1027                          ;; somebody does (CONCATENATE '(STRING 6) ...)
1028                          ;; their code won't be optimized, but nobody does
1029                          ;; that in practice.
1030                          (case type
1031                            ((string simple-string) 'character)
1032                            ((base-string simple-base-string) 'base-char)
1033                            (t (give-up-ir1-transform)))))
1034          (vars (loop for x in lvars collect (gensym)))
1035          (lvar-values (loop for lvar in lvars
1036                             collect (when (constant-lvar-p lvar)
1037                                       (lvar-value lvar))))
1038          (lengths
1039           (loop for value in lvar-values
1040                 for var in vars
1041                 collect (if value
1042                             (length value)
1043                             `(sb!impl::string-dispatch ((simple-array * (*))
1044                                                         sequence)
1045                                  ,var
1046                                (declare (muffle-conditions compiler-note))
1047                                (length ,var))))))
1048     `(apply
1049       (lambda ,vars
1050         (declare (ignorable ,@vars))
1051         (let* ((.length. (+ ,@lengths))
1052                (.pos. 0)
1053                (.string. (make-string .length. :element-type ',element-type)))
1054           (declare (type index .length. .pos.)
1055                    (muffle-conditions compiler-note))
1056           ,@(loop for value in lvar-values
1057                   for var in vars
1058                   collect (if (stringp value)
1059                               ;; Fold the array reads for constant arguments
1060                               `(progn
1061                                  ,@(loop for c across value
1062                                          collect `(setf (aref .string.
1063                                                               .pos.) ,c)
1064                                          collect `(incf .pos.)))
1065                               `(sb!impl::string-dispatch
1066                                    (#!+sb-unicode
1067                                     (simple-array character (*))
1068                                     (simple-array base-char (*))
1069                                     t)
1070                                    ,var
1071                                  (replace .string. ,var :start1 .pos.)
1072                                  (incf .pos. (length ,var)))))
1073           .string.))
1074       lvars)))
1075 \f
1076 ;;;; CONS accessor DERIVE-TYPE optimizers
1077
1078 (defoptimizer (car derive-type) ((cons))
1079   (let ((type (lvar-type cons))
1080         (null-type (specifier-type 'null)))
1081     (cond ((eq type null-type)
1082            null-type)
1083           ((cons-type-p type)
1084            (cons-type-car-type type)))))
1085
1086 (defoptimizer (cdr derive-type) ((cons))
1087   (let ((type (lvar-type cons))
1088         (null-type (specifier-type 'null)))
1089     (cond ((eq type null-type)
1090            null-type)
1091           ((cons-type-p type)
1092            (cons-type-cdr-type type)))))
1093 \f
1094 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
1095
1096 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
1097 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
1098 ;;; expansion, so we factor out the condition into this function.
1099 (defun check-inlineability-of-find-position-if (sequence from-end)
1100   (let ((ctype (lvar-type sequence)))
1101     (cond ((csubtypep ctype (specifier-type 'vector))
1102            ;; It's not worth trying to inline vector code unless we
1103            ;; know a fair amount about it at compile time.
1104            (upgraded-element-type-specifier-or-give-up sequence)
1105            (unless (constant-lvar-p from-end)
1106              (give-up-ir1-transform
1107               "FROM-END argument value not known at compile time")))
1108           ((csubtypep ctype (specifier-type 'list))
1109            ;; Inlining on lists is generally worthwhile.
1110            )
1111           (t
1112            (give-up-ir1-transform
1113             "sequence type not known at compile time")))))
1114
1115 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
1116 (macrolet ((def (name condition)
1117              `(deftransform ,name ((predicate sequence from-end start end key)
1118                                    (function list t t t function)
1119                                    *
1120                                    :policy (> speed space))
1121                 "expand inline"
1122                 `(let ((index 0)
1123                        (find nil)
1124                        (position nil))
1125                    (declare (type index index))
1126                    (dolist (i sequence
1127                             (if (and end (> end index))
1128                                 (sequence-bounding-indices-bad-error
1129                                  sequence start end)
1130                                 (values find position)))
1131                      (let ((key-i (funcall key i)))
1132                        (when (and end (>= index end))
1133                          (return (values find position)))
1134                        (when (>= index start)
1135                          (,',condition (funcall predicate key-i)
1136                           ;; This hack of dealing with non-NIL
1137                           ;; FROM-END for list data by iterating
1138                           ;; forward through the list and keeping
1139                           ;; track of the last time we found a match
1140                           ;; might be more screwy than what the user
1141                           ;; expects, but it seems to be allowed by
1142                           ;; the ANSI standard. (And if the user is
1143                           ;; screwy enough to ask for FROM-END
1144                           ;; behavior on list data, turnabout is
1145                           ;; fair play.)
1146                           ;;
1147                           ;; It's also not enormously efficient,
1148                           ;; calling PREDICATE and KEY more often
1149                           ;; than necessary; but all the
1150                           ;; alternatives seem to have their own
1151                           ;; efficiency problems.
1152                           (if from-end
1153                               (setf find i
1154                                     position index)
1155                               (return (values i index))))))
1156                      (incf index))))))
1157   (def %find-position-if when)
1158   (def %find-position-if-not unless))
1159
1160 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
1161 ;;; without loss of efficiency. (I.e., the optimizer should be able
1162 ;;; to straighten everything out.)
1163 (deftransform %find-position ((item sequence from-end start end key test)
1164                               (t list t t t t t)
1165                               *
1166                               :policy (> speed space))
1167   "expand inline"
1168   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
1169                         ;; The order of arguments for asymmetric tests
1170                         ;; (e.g. #'<, as opposed to order-independent
1171                         ;; tests like #'=) is specified in the spec
1172                         ;; section 17.2.1 -- the O/Zi stuff there.
1173                         (lambda (i)
1174                           (funcall test-fun item i)))
1175                       sequence
1176                       from-end
1177                       start
1178                       end
1179                       (%coerce-callable-to-fun key)))
1180
1181 ;;; The inline expansions for the VECTOR case are saved as macros so
1182 ;;; that we can share them between the DEFTRANSFORMs and the default
1183 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
1184 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1185 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1186                                                             from-end
1187                                                             start
1188                                                             end-arg
1189                                                             element
1190                                                             done-p-expr)
1191   (with-unique-names (offset block index n-sequence sequence end)
1192     `(let* ((,n-sequence ,sequence-arg))
1193        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1194                          (,start ,start)
1195                          (,end ,end-arg)
1196                          :check-fill-pointer t)
1197          (block ,block
1198            (macrolet ((maybe-return ()
1199                         ;; WITH-ARRAY-DATA has already performed bounds
1200                         ;; checking, so we can safely elide the checks
1201                         ;; in the inner loop.
1202                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1203                                            (aref ,sequence ,index))))
1204                           (when ,done-p-expr
1205                             (return-from ,block
1206                               (values ,element
1207                                       (- ,index ,offset)))))))
1208              (if ,from-end
1209                  (loop for ,index
1210                        ;; (If we aren't fastidious about declaring that
1211                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1212                        ;; can send us off into never-never land, since
1213                        ;; INDEX is initialized to -1.)
1214                        of-type index-or-minus-1
1215                        from (1- ,end) downto ,start do
1216                        (maybe-return))
1217                  (loop for ,index of-type index from ,start below ,end do
1218                           (maybe-return))))
1219            (values nil nil))))))
1220
1221 (def!macro %find-position-vector-macro (item sequence
1222                                              from-end start end key test)
1223   (with-unique-names (element)
1224     (%find-position-or-find-position-if-vector-expansion
1225      sequence
1226      from-end
1227      start
1228      end
1229      element
1230      ;; (See the LIST transform for a discussion of the correct
1231      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1232      ;; or after the checked sequence element.)
1233      `(funcall ,test ,item (funcall ,key ,element)))))
1234
1235 (def!macro %find-position-if-vector-macro (predicate sequence
1236                                                      from-end start end key)
1237   (with-unique-names (element)
1238     (%find-position-or-find-position-if-vector-expansion
1239      sequence
1240      from-end
1241      start
1242      end
1243      element
1244      `(funcall ,predicate (funcall ,key ,element)))))
1245
1246 (def!macro %find-position-if-not-vector-macro (predicate sequence
1247                                                          from-end start end key)
1248   (with-unique-names (element)
1249     (%find-position-or-find-position-if-vector-expansion
1250      sequence
1251      from-end
1252      start
1253      end
1254      element
1255      `(not (funcall ,predicate (funcall ,key ,element))))))
1256
1257 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1258 ;;; VECTOR data
1259 (deftransform %find-position-if ((predicate sequence from-end start end key)
1260                                  (function vector t t t function)
1261                                  *
1262                                  :policy (> speed space))
1263   "expand inline"
1264   (check-inlineability-of-find-position-if sequence from-end)
1265   '(%find-position-if-vector-macro predicate sequence
1266                                    from-end start end key))
1267
1268 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1269                                      (function vector t t t function)
1270                                      *
1271                                      :policy (> speed space))
1272   "expand inline"
1273   (check-inlineability-of-find-position-if sequence from-end)
1274   '(%find-position-if-not-vector-macro predicate sequence
1275                                        from-end start end key))
1276
1277 (deftransform %find-position ((item sequence from-end start end key test)
1278                               (t vector t t t function function)
1279                               *
1280                               :policy (> speed space))
1281   "expand inline"
1282   (check-inlineability-of-find-position-if sequence from-end)
1283   '(%find-position-vector-macro item sequence
1284     from-end start end key test))
1285
1286 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1287 ;;; POSITION-IF, etc.
1288 (define-source-transform effective-find-position-test (test test-not)
1289   (once-only ((test test)
1290               (test-not test-not))
1291     `(cond
1292       ((and ,test ,test-not)
1293        (error "can't specify both :TEST and :TEST-NOT"))
1294       (,test (%coerce-callable-to-fun ,test))
1295       (,test-not
1296        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1297        ;; inefficient, but since the TEST-NOT option is deprecated
1298        ;; anyway, we don't care.)
1299        (complement (%coerce-callable-to-fun ,test-not)))
1300       (t #'eql))))
1301 (define-source-transform effective-find-position-key (key)
1302   (once-only ((key key))
1303     `(if ,key
1304          (%coerce-callable-to-fun ,key)
1305          #'identity)))
1306
1307 (macrolet ((define-find-position (fun-name values-index)
1308              `(deftransform ,fun-name ((item sequence &key
1309                                              from-end (start 0) end
1310                                              key test test-not)
1311                                        (t (or list vector) &rest t))
1312                 '(nth-value ,values-index
1313                             (%find-position item sequence
1314                                             from-end start
1315                                             end
1316                                             (effective-find-position-key key)
1317                                             (effective-find-position-test
1318                                              test test-not))))))
1319   (define-find-position find 0)
1320   (define-find-position position 1))
1321
1322 (macrolet ((define-find-position-if (fun-name values-index)
1323              `(deftransform ,fun-name ((predicate sequence &key
1324                                                   from-end (start 0)
1325                                                   end key)
1326                                        (t (or list vector) &rest t))
1327                 '(nth-value
1328                   ,values-index
1329                   (%find-position-if (%coerce-callable-to-fun predicate)
1330                                      sequence from-end
1331                                      start end
1332                                      (effective-find-position-key key))))))
1333   (define-find-position-if find-if 0)
1334   (define-find-position-if position-if 1))
1335
1336 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1337 ;;; didn't bother to worry about optimizing them, except note that on
1338 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1339 ;;; sbcl-devel
1340 ;;;
1341 ;;;     My understanding is that while the :test-not argument is
1342 ;;;     deprecated in favour of :test (complement #'foo) because of
1343 ;;;     semantic difficulties (what happens if both :test and :test-not
1344 ;;;     are supplied, etc) the -if-not variants, while officially
1345 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1346 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1347 ;;;     reasons for allowing the -if-not versions equal status,
1348 ;;;     particularly remove-if-not (== filter).
1349 ;;;
1350 ;;;     This is only an informal understanding, I grant you, but
1351 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1352 ;;;     way as the others?
1353 ;;;
1354 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1355 ;;; implementation of SBCL.
1356 (macrolet ((define-find-position-if-not (fun-name values-index)
1357                `(deftransform ,fun-name ((predicate sequence &key
1358                                           from-end (start 0)
1359                                           end key)
1360                                          (t (or list vector) &rest t))
1361                  '(nth-value
1362                    ,values-index
1363                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1364                     sequence from-end
1365                     start end
1366                     (effective-find-position-key key))))))
1367   (define-find-position-if-not find-if-not 0)
1368   (define-find-position-if-not position-if-not 1))
1369
1370 (macrolet ((define-trimmer-transform (fun-name leftp rightp)
1371              `(deftransform ,fun-name ((char-bag string)
1372                                        (t simple-string))
1373                 (let ((find-expr
1374                        (if (constant-lvar-p char-bag)
1375                            ;; If the bag is constant, use MEMBER
1376                            ;; instead of FIND, since we have a
1377                            ;; deftransform for MEMBER that can
1378                            ;; open-code all of the comparisons when
1379                            ;; the list is constant. -- JES, 2007-12-10
1380                            `(not (member (schar string index)
1381                                          ',(coerce (lvar-value char-bag) 'list)
1382                                          :test #'char=))
1383                            '(not (find (schar string index) char-bag :test #'char=)))))
1384                   `(flet ((char-not-in-bag (index)
1385                             ,find-expr))
1386                      (let* ((end (length string))
1387                             (left-end (if ,',leftp
1388                                           (do ((index 0 (1+ index)))
1389                                               ((or (= index (the fixnum end))
1390                                                    (char-not-in-bag index))
1391                                                index)
1392                                             (declare (fixnum index)))
1393                                           0))
1394                             (right-end (if ,',rightp
1395                                            (do ((index (1- end) (1- index)))
1396                                                ((or (< index left-end)
1397                                                     (char-not-in-bag index))
1398                                                 (1+ index))
1399                                              (declare (fixnum index)))
1400                                            end)))
1401                        (if (and (eql left-end 0)
1402                                 (eql right-end (length string)))
1403                            string
1404                            (subseq string left-end right-end))))))))
1405   (define-trimmer-transform string-left-trim t nil)
1406   (define-trimmer-transform string-right-trim nil t)
1407   (define-trimmer-transform string-trim t t))
1408