src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places))
 137     (let ((found-vector-p nil))
 138       (flet ((process-vector (length)
 139                (unless found-vector-p
 140                  (setq found-vector-p t)
 141                  (bindings `(index 0 (1+ index)))
 142                  (declarations `(type index index)))
 143                (vector-lengths length)))
 144         (loop for seq of-type lvar in seqs
 145            for seq-name in seq-names
 146            for type = (lvar-type seq)
 147            do (cond ((csubtypep type (specifier-type 'list))
 148                      (with-unique-names (index)
 149                        (bindings `(,index ,seq-name (cdr ,index)))
 150                        (declarations `(type list ,index))
 151                        (places `(car ,index))
 152                        (tests `(endp ,index))))
 153                     ((csubtypep type (specifier-type 'vector))
 154                      (process-vector `(length ,seq-name))
 155                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 156                                 (aref ,seq-name index))))
 157                     (t
 158                      (give-up-ir1-transform
 159                       "can't determine sequence argument type"))))
 160         (when into
 161           (process-vector `(array-dimension ,into 0))))
 162       (when found-vector-p
 163         (bindings `(length (min ,@(vector-lengths))))
 164         (tests `(>= index length)))
 165       `(do (,@(bindings))
 166            ((or ,@(tests)) ,result)
 167          (declare ,@(declarations))
 168          (let ((funcall-result (funcall fun ,@(places))))
 169            (declare (ignorable funcall-result))
 170            ,body)))))
 171
 172 ;;; Try to compile %MAP efficiently when we can determine sequence
 173 ;;; argument types at compile time.
 174 ;;;
 175 ;;; Note: This transform was written to allow open coding of
 176 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 177 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 178 ;;; necessarily as efficient as possible. In particular, it will be
 179 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 180 ;;; numeric element types. It should be straightforward to make it
 181 ;;; handle that case more efficiently, but it's left as an exercise to
 182 ;;; the reader, because the code is complicated enough already and I
 183 ;;; don't happen to need that functionality right now. -- WHN 20000410
 184 (deftransform %map ((result-type fun seq &rest seqs) * *
 185                     :policy (>= speed space))
 186   "open code"
 187   (unless (constant-lvar-p result-type)
 188     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 189   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 190            (fn-1subtypep (fn x y)
 191              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 192                (if valid-p
 193                    subtype-p
 194                    (give-up-ir1-transform
 195                     "can't analyze sequence type relationship"))))
 196            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 197     (let* ((result-type-value (lvar-value result-type))
 198            (result-supertype (cond ((null result-type-value) 'null)
 199                                    ((1subtypep result-type-value 'vector)
 200                                     'vector)
 201                                    ((1subtypep result-type-value 'list)
 202                                     'list)
 203                                    (t
 204                                     (give-up-ir1-transform
 205                                      "result type unsuitable")))))
 206       (cond ((and result-type-value (null seqs))
 207              ;; The consing arity-1 cases can be implemented
 208              ;; reasonably efficiently as function calls, and the cost
 209              ;; of consing should be significantly larger than
 210              ;; function call overhead, so we always compile these
 211              ;; cases as full calls regardless of speed-versus-space
 212              ;; optimization policy.
 213              (cond ((subtypep result-type-value 'list)
 214                     '(%map-to-list-arity-1 fun seq))
 215                    ( ;; (This one can be inefficient due to COERCE, but
 216                     ;; the current open-coded implementation has the
 217                     ;; same problem.)
 218                     (subtypep result-type-value 'vector)
 219                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 220                              ',result-type-value))
 221                    (t (bug "impossible (?) sequence type"))))
 222             (t
 223              (let* ((seqs (cons seq seqs))
 224                     (seq-args (make-gensym-list (length seqs))))
 225                (multiple-value-bind (push-dacc result)
 226                    (ecase result-supertype
 227                      (null (values nil nil))
 228                      (list (values `(push funcall-result acc)
 229                                    `(nreverse acc)))
 230                      (vector (values `(push funcall-result acc)
 231                                      `(coerce (nreverse acc)
 232                                               ',result-type-value))))
 233                  ;; (We use the same idiom, of returning a LAMBDA from
 234                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 235                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 236                  ;; reason: we need to get the runtime values of each
 237                  ;; of the &REST vars.)
 238                  `(lambda (result-type fun ,@seq-args)
 239                     (declare (ignore result-type))
 240                     (let ((fun (%coerce-callable-to-fun fun))
 241                           (acc nil))
 242                       (declare (type list acc))
 243                       (declare (ignorable acc))
 244                       ,(build-sequence-iterator
 245                         seqs seq-args
 246                         :result result
 247                         :body push-dacc))))))))))
 248
 249 ;;; MAP-INTO
 250 (deftransform map-into ((result fun &rest seqs)
 251                         (vector * &rest *)
 252                         *)
 253   "open code"
 254   (let ((seqs-names (mapcar (lambda (x)
 255                               (declare (ignore x))
 256                               (gensym))
 257                             seqs)))
 258     `(lambda (result fun ,@seqs-names)
 259        ,(build-sequence-iterator
 260          seqs seqs-names
 261          :result '(when (array-has-fill-pointer-p result)
 262                    (setf (fill-pointer result) index))
 263          :into 'result
 264          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 265                  (setf (aref result index) funcall-result)))
 266        result)))
 267
 268 \f
 269 ;;; FIXME: once the confusion over doing transforms with known-complex
 270 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 271 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 272 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 273   '(aref s i))
 274
 275 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 276   '(nth i s))
 277
 278 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 279   '(%aset s i v))
 280
 281 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 282   '(setf (car (nthcdr i s)) v))
 283
 284 (deftransform %check-vector-sequence-bounds ((vector start end)
 285                                              (vector * *) *
 286                                              :node node)
 287   (if (policy node (< safety speed))
 288       '(or end (length vector))
 289       '(let ((length (length vector)))
 290         (if (<= 0 start (or end length) length)
 291             (or end length)
 292             (sb!impl::signal-bounding-indices-bad-error vector start end)))))
 293
 294 (defun specialized-list-seek-function-name (function-name key-functions)
 295   (or (find-symbol (with-output-to-string (s)
 296                      ;; Write "%NAME-FUN1-FUN2-FUN3", etc. Not only is
 297                      ;; this ever so slightly faster then FORMAT, this
 298                      ;; way we are also proof against *PRINT-CASE*
 299                      ;; frobbing and such.
 300                      (write-char #\% s)
 301                      (write-string (symbol-name function-name) s)
 302                      (dolist (f key-functions)
 303                        (write-char #\- s)
 304                        (write-string (symbol-name f) s)))
 305                    (load-time-value (find-package "SB!KERNEL")))
 306       (bug "Unknown list item seek transform: name=~S, key-functions=~S"
 307            function-name key-functions)))
 308
 309 (defun transform-list-item-seek (name list key test test-not node)
 310   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 311   ;; not there at all. If it might be NIL, make up a form to that
 312   ;; ensure it is a function.
 313   (multiple-value-bind (key key-form)
 314       (if key
 315           (let ((key-type (lvar-type key))
 316                 (null-type (specifier-type 'null)))
 317             (cond ((csubtypep key-type null-type)
 318                    (values nil nil))
 319                   ((csubtypep null-type key-type)
 320                    (values key '(if key
 321                                  (%coerce-callable-to-fun key)
 322                                  #'identity)))
 323                   (t
 324                    (values key '(%coerce-callable-to-fun key))))))
 325     (let* ((funs (remove nil (list (and key 'key) (cond (test 'test)
 326                                                         (test-not 'test-not)))))
 327            (target-expr (if key '(%funcall key target) 'target))
 328            (test-expr (cond (test `(%funcall test item ,target-expr))
 329                             (test-not `(not (%funcall test-not item ,target-expr)))
 330                             (t `(eql item ,target-expr)))))
 331       (labels ((open-code (tail)
 332                  (when tail
 333                    `(if (let ((this ',(car tail)))
 334                           ,(ecase name
 335                                   (assoc
 336                                    `(and this (let ((target (car this)))
 337                                                 ,test-expr)))
 338                                   (member
 339                                    `(let ((target this))
 340                                       ,test-expr))))
 341                         ',(ecase name
 342                                  (assoc (car tail))
 343                                  (member tail))
 344                         ,(open-code (cdr tail)))))
 345                (ensure-fun (fun)
 346                  (if (eq 'key fun)
 347                      key-form
 348                      `(%coerce-callable-to-fun ,fun))))
 349         (let* ((cp (constant-lvar-p list))
 350                (c-list (when cp (lvar-value list))))
 351           (cond ((and cp c-list (policy node (>= speed space)))
 352                  `(let ,(mapcar (lambda (fun) `(,fun ,(ensure-fun fun))) funs)
 353                     ,(open-code c-list)))
 354                 ((and cp (not c-list))
 355                  ;; constant nil list -- nothing to find!
 356                  nil)
 357                 (t
 358                  ;; specialized out-of-line version
 359                  `(,(specialized-list-seek-function-name name funs)
 360                     item list ,@(mapcar #'ensure-fun funs)))))))))
 361
 362 (deftransform member ((item list &key key test test-not) * * :node node)
 363   (transform-list-item-seek 'member list key test test-not node))
 364
 365 (deftransform assoc ((item list &key key test test-not) * * :node node)
 366   (transform-list-item-seek 'assoc list key test test-not node))
 367
 368 (deftransform memq ((item list) (t (constant-arg list)))
 369   (labels ((rec (tail)
 370              (if tail
 371                  `(if (eq item ',(car tail))
 372                       ',tail
 373                       ,(rec (cdr tail)))
 374                  nil)))
 375     (rec (lvar-value list))))
 376
 377 ;;; A similar transform used to apply to MEMBER and ASSOC, but since
 378 ;;; TRANSFORM-LIST-ITEM-SEEK now takes care of them those transform
 379 ;;; would never fire, and (%MEMBER-TEST ITEM LIST #'EQ) should be
 380 ;;; almost as fast as MEMQ.
 381 (deftransform delete ((item list &key test) (t list &rest t) *)
 382   "convert to EQ test"
 383   ;; FIXME: The scope of this transformation could be
 384   ;; widened somewhat, letting it work whenever the test is
 385   ;; 'EQL and we know from the type of ITEM that it #'EQ
 386   ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 387   ;; and SYMBOL.)
 388   ;;   If TEST is EQ, apply transform, else
 389   ;;   if test is not EQL, then give up on transform, else
 390   ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 391   ;;   transform, else give up on transform.
 392   (cond (test
 393          (unless (lvar-fun-is test '(eq))
 394            (give-up-ir1-transform)))
 395         ((types-equal-or-intersect (lvar-type item)
 396                                    (specifier-type 'number))
 397          (give-up-ir1-transform "Item might be a number.")))
 398   `(delq item list))
 399
 400 (deftransform delete-if ((pred list) (t list))
 401   "open code"
 402   '(do ((x list (cdr x))
 403         (splice '()))
 404        ((endp x) list)
 405      (cond ((funcall pred (car x))
 406             (if (null splice)
 407                 (setq list (cdr x))
 408                 (rplacd splice (cdr x))))
 409            (t (setq splice x)))))
 410
 411 (deftransform fill ((seq item &key (start 0) (end (length seq)))
 412                     (vector t &key (:start t) (:end index))
 413                     *
 414                     :policy (> speed space))
 415   "open code"
 416   (let ((element-type (upgraded-element-type-specifier-or-give-up seq)))
 417     (values
 418      `(with-array-data ((data seq)
 419                         (start start)
 420                         (end end))
 421        (declare (type (simple-array ,element-type 1) data))
 422        (declare (type fixnum start end))
 423        (do ((i start (1+ i)))
 424            ((= i end) seq)
 425          (declare (type index i))
 426          ;; WITH-ARRAY-DATA did our range checks once and for all, so
 427          ;; it'd be wasteful to check again on every AREF...
 428          (declare (optimize (safety 0)))
 429          (setf (aref data i) item)))
 430      ;; ... though we still need to check that the new element can fit
 431      ;; into the vector in safe code. -- CSR, 2002-07-05
 432      `((declare (type ,element-type item))))))
 433 \f
 434 ;;;; utilities
 435
 436 ;;; Return true if LVAR's only use is a non-NOTINLINE reference to a
 437 ;;; global function with one of the specified NAMES.
 438 (defun lvar-fun-is (lvar names)
 439   (declare (type lvar lvar) (list names))
 440   (let ((use (lvar-uses lvar)))
 441     (and (ref-p use)
 442          (let ((leaf (ref-leaf use)))
 443            (and (global-var-p leaf)
 444                 (eq (global-var-kind leaf) :global-function)
 445                 (not (null (member (leaf-source-name leaf) names
 446                                    :test #'equal))))))))
 447
 448 ;;; If LVAR is a constant lvar, the return the constant value. If it
 449 ;;; is null, then return default, otherwise quietly give up the IR1
 450 ;;; transform.
 451 ;;;
 452 ;;; ### Probably should take an ARG and flame using the NAME.
 453 (defun constant-value-or-lose (lvar &optional default)
 454   (declare (type (or lvar null) lvar))
 455   (cond ((not lvar) default)
 456         ((constant-lvar-p lvar)
 457          (lvar-value lvar))
 458         (t
 459          (give-up-ir1-transform))))
 460
 461
 462 ;;;; hairy sequence transforms
 463
 464 ;;; FIXME: no hairy sequence transforms in SBCL?
 465 ;;;
 466 ;;; There used to be a bunch of commented out code about here,
 467 ;;; containing the (apparent) beginning of hairy sequence transform
 468 ;;; infrastructure. People interested in implementing better sequence
 469 ;;; transforms might want to look at it for inspiration, even though
 470 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 471 ;;; was deleted in 1.0.7.23.
 472 \f
 473 ;;;; string operations
 474
 475 ;;; We transform the case-sensitive string predicates into a non-keyword
 476 ;;; version. This is an IR1 transform so that we don't have to worry about
 477 ;;; changing the order of evaluation.
 478 (macrolet ((def (fun pred*)
 479              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 480                                                          (start2 0) end2)
 481                                    * *)
 482                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 483   (def string< string<*)
 484   (def string> string>*)
 485   (def string<= string<=*)
 486   (def string>= string>=*)
 487   (def string= string=*)
 488   (def string/= string/=*))
 489
 490 ;;; Return a form that tests the free variables STRING1 and STRING2
 491 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 492 ;;; start and end are also gotten from the environment. Both strings
 493 ;;; must be SIMPLE-BASE-STRINGs.
 494 (macrolet ((def (name lessp equalp)
 495              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 496                                    (simple-base-string simple-base-string t t t t) *)
 497                 `(let* ((end1 (if (not end1) (length string1) end1))
 498                         (end2 (if (not end2) (length string2) end2))
 499                         (index (sb!impl::%sp-string-compare
 500                                 string1 start1 end1 string2 start2 end2)))
 501                   (if index
 502                       (cond ((= index end1)
 503                              ,(if ',lessp 'index nil))
 504                             ((= (+ index (- start2 start1)) end2)
 505                              ,(if ',lessp nil 'index))
 506                             ((,(if ',lessp 'char< 'char>)
 507                                (schar string1 index)
 508                                (schar string2
 509                                       (truly-the index
 510                                                  (+ index
 511                                                     (truly-the fixnum
 512                                                                (- start2
 513                                                                   start1))))))
 514                              index)
 515                             (t nil))
 516                       ,(if ',equalp 'end1 nil))))))
 517   (def string<* t nil)
 518   (def string<=* t t)
 519   (def string>* nil nil)
 520   (def string>=* nil t))
 521
 522 (macrolet ((def (name result-fun)
 523              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 524                                    (simple-base-string simple-base-string t t t t) *)
 525                 `(,',result-fun
 526                   (sb!impl::%sp-string-compare
 527                    string1 start1 (or end1 (length string1))
 528                    string2 start2 (or end2 (length string2)))))))
 529   (def string=* not)
 530   (def string/=* identity))
 531
 532 \f
 533 ;;;; transforms for sequence functions
 534
 535 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 536 ;;; to vectors based on simple arrays.
 537 (def!constant vector-data-bit-offset
 538   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 539
 540 (eval-when (:compile-toplevel)
 541 (defun valid-bit-bash-saetp-p (saetp)
 542   ;; BIT-BASHing isn't allowed on simple vectors that contain pointers
 543   (and (not (eq t (sb!vm:saetp-specifier saetp)))
 544        ;; Disallowing (VECTOR NIL) also means that we won't transform
 545        ;; sequence functions into bit-bashing code and we let the
 546        ;; generic sequence functions signal errors if necessary.
 547        (not (zerop (sb!vm:saetp-n-bits saetp)))
 548        ;; Due to limitations with the current BIT-BASHing code, we can't
 549        ;; BIT-BASH reliably on arrays whose element types are larger
 550        ;; than the word size.
 551        (<= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)))
 552 ) ; EVAL-WHEN
 553
 554 ;;; FIXME: In the copy loops below, we code the loops in a strange
 555 ;;; fashion:
 556 ;;;
 557 ;;; (do ((i (+ src-offset length) (1- i)))
 558 ;;;     ((<= i 0) ...)
 559 ;;;   (... (aref foo (1- i)) ...))
 560 ;;;
 561 ;;; rather than the more natural (and seemingly more efficient):
 562 ;;;
 563 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 564 ;;;     ((< i 0) ...)
 565 ;;;   (... (aref foo i) ...))
 566 ;;;
 567 ;;; (more efficient because we don't have to do the index adjusting on
 568 ;;; every iteration of the loop)
 569 ;;;
 570 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 571 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 572 ;;; when used as an array index, the backend thinks I is a
 573 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 574 ;;; these as distinct storage classes, it cannot coerce a move from a
 575 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 576 ;;; deficiency is that we have two extra moves and increased register
 577 ;;; pressure, which can lead to some spectacularly bad register
 578 ;;; allocation.  (sub-FIXME: the register allocation even with the
 579 ;;; strangely written loops is not always excellent, either...).  Doing
 580 ;;; it the first way, above, means that I is always thought of as a
 581 ;;; POSITIVE-FIXNUM and there are no issues.
 582 ;;;
 583 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 584 ;;; adjustments in the first version into the array addressing at no
 585 ;;; performance penalty!
 586
 587 ;;; This transform is critical to the performance of string streams.  If
 588 ;;; you tweak it, make sure that you compare the disassembly, if not the
 589 ;;; performance of, the functions implementing string streams
 590 ;;; (e.g. SB!IMPL::STRING-OUCH).
 591 (eval-when (:compile-toplevel :load-toplevel :execute)
 592   (defun make-replace-transform (saetp sequence-type1 sequence-type2)
 593     `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 594                             (,sequence-type1 ,sequence-type2 &rest t)
 595                             ,sequence-type1
 596                             :node node)
 597        ,(cond
 598          ((and saetp (valid-bit-bash-saetp-p saetp)) nil)
 599          ;; If the sequence types are different, SEQ1 and SEQ2 must
 600          ;; be distinct arrays, and we can open code the copy loop.
 601          ((not (eql sequence-type1 sequence-type2)) nil)
 602          ;; If we're not bit-bashing, only allow cases where we
 603          ;; can determine the order of copying up front.  (There
 604          ;; are actually more cases we can handle if we know the
 605          ;; amount that we're copying, but this handles the
 606          ;; common cases.)
 607          (t '(unless (= (constant-value-or-lose start1 0)
 608                       (constant-value-or-lose start2 0))
 609               (give-up-ir1-transform))))
 610        `(let* ((len1 (length seq1))
 611                (len2 (length seq2))
 612                (end1 (or end1 len1))
 613                (end2 (or end2 len2))
 614                (replace-len1 (- end1 start1))
 615                (replace-len2 (- end2 start2)))
 616           ,(unless (policy node (= safety 0))
 617              `(progn
 618                  (unless (<= 0 start1 end1 len1)
 619                    (sb!impl::signal-bounding-indices-bad-error seq1 start1 end1))
 620                  (unless (<= 0 start2 end2 len2)
 621                    (sb!impl::signal-bounding-indices-bad-error seq2 start2 end2))))
 622           ,',(cond
 623               ((and saetp (valid-bit-bash-saetp-p saetp))
 624                (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 625                       (bash-function (intern (format nil "UB~D-BASH-COPY"
 626                                                      n-element-bits)
 627                                              (find-package "SB!KERNEL"))))
 628                  `(funcall (function ,bash-function) seq2 start2
 629                            seq1 start1 (min replace-len1 replace-len2))))
 630               (t
 631                ;; We can expand the loop inline here because we
 632                ;; would have given up the transform (see above)
 633                ;; if we didn't have constant matching start
 634                ;; indices.
 635                '(do ((i start1 (1+ i))
 636                      (j start2 (1+ j))
 637                      (end (+ start1
 638                              (min replace-len1 replace-len2))))
 639                  ((>= i end))
 640                  (declare (optimize (insert-array-bounds-checks 0)))
 641                  (setf (aref seq1 i) (aref seq2 j)))))
 642           seq1))))
 643
 644 (macrolet
 645     ((define-replace-transforms ()
 646        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 647              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 648              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 649              collect (make-replace-transform saetp sequence-type sequence-type)
 650              into forms
 651              finally (return `(progn ,@forms))))
 652      (define-one-transform (sequence-type1 sequence-type2)
 653        (make-replace-transform nil sequence-type1 sequence-type2)))
 654   (define-replace-transforms)
 655   (define-one-transform simple-base-string (simple-array character (*)))
 656   (define-one-transform (simple-array character (*)) simple-base-string))
 657
 658 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 659 ;;; defined as those cases where we are doing word-aligned copies from
 660 ;;; both the source and the destination and we are copying from the same
 661 ;;; offset from both the source and the destination.  (The last
 662 ;;; condition is there so we can determine the direction to copy at
 663 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 664 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 665 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 666 ;;; N)-size buffer and blitting in the old N-size buffer in.
 667
 668 (defun frob-bash-transform (src src-offset
 669                             dst dst-offset
 670                             length n-elems-per-word)
 671   (declare (ignore src dst length))
 672   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 673     (multiple-value-bind (src-word src-elt)
 674         (truncate (lvar-value src-offset) n-elems-per-word)
 675       (multiple-value-bind (dst-word dst-elt)
 676           (truncate (lvar-value dst-offset) n-elems-per-word)
 677         ;; Avoid non-word aligned copies.
 678         (unless (and (zerop src-elt) (zerop dst-elt))
 679           (give-up-ir1-transform))
 680         ;; Avoid copies where we would have to insert code for
 681         ;; determining the direction of copying.
 682         (unless (= src-word dst-word)
 683           (give-up-ir1-transform))
 684         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 685         ;; so we have to do its work here.
 686         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 687                                       'length
 688                                       `(truncate (the index length) ,n-elems-per-word)))))
 689            (declare (type index end))
 690            ;; Handle any bits at the end.
 691            (when (logtest length (1- ,n-elems-per-word))
 692              (let* ((extra (mod length ,n-elems-per-word))
 693                     ;; FIXME: The shift amount on this ASH is
 694                     ;; *always* negative, but the backend doesn't
 695                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 696                     ;; wind up with a pile of code that tests the
 697                     ;; sign of the shift count prior to shifting when
 698                     ;; all we need is a simple negate and shift
 699                     ;; right.  Yuck.
 700                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 701                                (* (- extra ,n-elems-per-word)
 702                                   ,n-bits-per-elem))))
 703                (setf (sb!kernel:%vector-raw-bits dst end)
 704                      (logior
 705                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 706                                 (ash mask
 707                                      ,(ecase sb!c:*backend-byte-order*
 708                                              (:little-endian 0)
 709                                              (:big-endian `(* (- ,n-elems-per-word extra)
 710                                                               ,n-bits-per-elem)))))
 711                       (logand (sb!kernel:%vector-raw-bits src end)
 712                               (ash mask
 713                                    ,(ecase sb!c:*backend-byte-order*
 714                                            (:little-endian 0)
 715                                            (:big-endian `(* (- ,n-elems-per-word extra)
 716                                                             ,n-bits-per-elem)))))))))
 717            ;; Copy from the end to save a register.
 718            (do ((i end (1- i)))
 719                ((<= i ,src-word))
 720              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 721                    (sb!kernel:%vector-raw-bits src (1- i)))))))))
 722
 723 #.(loop for i = 1 then (* i 2)
 724         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 725                                         "SB!KERNEL")
 726                                                         ((src src-offset
 727                                                           dst dst-offset
 728                                                           length)
 729                                                         ((simple-unboxed-array (*))
 730                                                          (constant-arg index)
 731                                                          (simple-unboxed-array (*))
 732                                                          (constant-arg index)
 733                                                          index)
 734                                                         *)
 735                   (frob-bash-transform src src-offset
 736                                        dst dst-offset length
 737                                        ,(truncate sb!vm:n-word-bits i))) into forms
 738         until (= i sb!vm:n-word-bits)
 739         finally (return `(progn ,@forms)))
 740
 741 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 742 ;;; arrays with elements of size >= the word size.  We do this because
 743 ;;; we know the arrays cannot alias (one was just consed), therefore we
 744 ;;; can determine at compile time the direction to copy, and for
 745 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 746 ;;; needless checking to figure out what's going on.  The same
 747 ;;; considerations apply if we are copying elements larger than the word
 748 ;;; size, with the additional twist that doing it inline is likely to
 749 ;;; cons far less than calling REPLACE and letting generic code do the
 750 ;;; work.
 751 ;;;
 752 ;;; However, we do not do this for elements whose size is < than the
 753 ;;; word size because we don't want to deal with any alignment issues
 754 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 755 ;;; anyway.
 756
 757 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 758                                       element-type)
 759   (let ((saetp (find-saetp element-type)))
 760     (aver saetp)
 761     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 762         (expand-aref-copy-loop src src-offset dst dst-offset length)
 763         `(locally (declare (optimize (safety 0)))
 764            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 765
 766 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 767   (if (eql src-offset dst-offset)
 768       `(do ((i (+ ,src-offset ,length) (1- i)))
 769            ((<= i ,src-offset))
 770          (declare (optimize (insert-array-bounds-checks 0)))
 771          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 772       ;; KLUDGE: The compiler is not able to derive that (+ offset
 773       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 774       ;; We, however, know it must be so, as by this point the bounds
 775       ;; have already been checked.
 776       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 777             (j (+ ,dst-offset ,length) (1- j)))
 778            ((<= i ,src-offset))
 779          (declare (optimize (insert-array-bounds-checks 0))
 780                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 781          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 782
 783 (deftransform subseq ((seq start &optional end)
 784                       ((or (simple-unboxed-array (*)) simple-vector) t &optional t)
 785                       * :node node)
 786   (let ((array-type (lvar-type seq)))
 787     (unless (array-type-p array-type)
 788       (give-up-ir1-transform))
 789     (let ((element-type (type-specifier (array-type-specialized-element-type array-type))))
 790       `(let* ((length (length seq))
 791               (end (or end length)))
 792          ,(unless (policy node (= safety 0))
 793                   '(progn
 794                     (unless (<= 0 start end length)
 795                       (sb!impl::signal-bounding-indices-bad-error seq start end))))
 796          (let* ((size (- end start))
 797                 (result (make-array size :element-type ',element-type)))
 798            ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
 799                                                     (lvar-value start)
 800                                                     'start)
 801                                            'result 0 'size element-type)
 802            result)))))
 803
 804 (deftransform copy-seq ((seq) ((or (simple-unboxed-array (*)) simple-vector)) *)
 805   (let ((array-type (lvar-type seq)))
 806     (unless (array-type-p array-type)
 807       (give-up-ir1-transform))
 808     (let ((element-type (type-specifier (array-type-specialized-element-type array-type))))
 809       `(let* ((length (length seq))
 810               (result (make-array length :element-type ',element-type)))
 811          ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
 812          result))))
 813
 814 ;;; FIXME: it really should be possible to take advantage of the
 815 ;;; macros used in code/seq.lisp here to avoid duplication of code,
 816 ;;; and enable even funkier transformations.
 817 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
 818                                (test #'eql)
 819                                (key #'identity)
 820                                from-end)
 821                       (vector vector &rest t)
 822                       *
 823                       :policy (> speed (max space safety)))
 824   "open code"
 825   (let ((from-end (when (lvar-p from-end)
 826                     (unless (constant-lvar-p from-end)
 827                       (give-up-ir1-transform ":FROM-END is not constant."))
 828                     (lvar-value from-end)))
 829         (keyp (lvar-p key))
 830         (testp (lvar-p test)))
 831     `(block search
 832        (let ((end1 (or end1 (length pattern)))
 833              (end2 (or end2 (length text)))
 834              ,@(when keyp
 835                      '((key (coerce key 'function))))
 836              ,@(when testp
 837                      '((test (coerce test 'function)))))
 838          (declare (type index start1 start2 end1 end2))
 839          (do (,(if from-end
 840                    '(index2 (- end2 (- end1 start1)) (1- index2))
 841                    '(index2 start2 (1+ index2))))
 842              (,(if from-end
 843                    '(< index2 start2)
 844                    '(>= index2 end2))
 845               nil)
 846            ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
 847            ;; terminates is hits -1 when :FROM-END is true and :START2
 848            ;; is 0.
 849            (declare (type fixnum index2))
 850            (when (do ((index1 start1 (1+ index1))
 851                       (index2 index2 (1+ index2)))
 852                      ((>= index1 end1) t)
 853                    (declare (type index index1 index2))
 854                    ,@(unless from-end
 855                              '((when (= index2 end2)
 856                                  (return-from search nil))))
 857                    (unless (,@(if testp
 858                                   '(funcall test)
 859                                   '(eql))
 860                               ,(if keyp
 861                                    '(funcall key (aref pattern index1))
 862                                    '(aref pattern index1))
 863                               ,(if keyp
 864                                    '(funcall key (aref text index2))
 865                                    '(aref text index2)))
 866                      (return nil)))
 867              (return index2)))))))
 868
 869
 870 ;;; Open-code CONCATENATE for strings. It would be possible to extend
 871 ;;; this transform to non-strings, but I chose to just do the case that
 872 ;;; should cover 95% of CONCATENATE performance complaints for now.
 873 ;;;   -- JES, 2007-11-17
 874 (deftransform concatenate ((result-type &rest lvars)
 875                            (symbol &rest sequence)
 876                            *
 877                            :policy (> speed space))
 878   (unless (constant-lvar-p result-type)
 879     (give-up-ir1-transform))
 880   (let* ((element-type (let ((type (lvar-value result-type)))
 881                          ;; Only handle the simple result type cases. If
 882                          ;; somebody does (CONCATENATE '(STRING 6) ...)
 883                          ;; their code won't be optimized, but nobody does
 884                          ;; that in practice.
 885                          (case type
 886                            ((string simple-string) 'character)
 887                            ((base-string simple-base-string) 'base-char)
 888                            (t (give-up-ir1-transform)))))
 889          (vars (loop for x in lvars collect (gensym)))
 890          (lvar-values (loop for lvar in lvars
 891                             collect (when (constant-lvar-p lvar)
 892                                       (lvar-value lvar))))
 893          (lengths
 894           (loop for value in lvar-values
 895                 for var in vars
 896                 collect (if value
 897                             (length value)
 898                             `(sb!impl::string-dispatch ((simple-array * (*))
 899                                                         sequence)
 900                                  ,var
 901                                (declare (muffle-conditions compiler-note))
 902                                (length ,var))))))
 903     `(apply
 904       (lambda ,vars
 905         (declare (ignorable ,@vars))
 906         (let* ((.length. (+ ,@lengths))
 907                (.pos. 0)
 908                (.string. (make-string .length. :element-type ',element-type)))
 909           (declare (type index .length. .pos.)
 910                    (muffle-conditions compiler-note))
 911           ,@(loop for value in lvar-values
 912                   for var in vars
 913                   collect (if (stringp value)
 914                               ;; Fold the array reads for constant arguments
 915                               `(progn
 916                                  ,@(loop for c across value
 917                                          collect `(setf (aref .string.
 918                                                               .pos.) ,c)
 919                                          collect `(incf .pos.)))
 920                               `(sb!impl::string-dispatch
 921                                    (#!+sb-unicode
 922                                     (simple-array character (*))
 923                                     (simple-array base-char (*))
 924                                     t)
 925                                    ,var
 926                                  (replace .string. ,var :start1 .pos.)
 927                                  (incf .pos. (length ,var)))))
 928           .string.))
 929       lvars)))
 930 \f
 931 ;;;; CONS accessor DERIVE-TYPE optimizers
 932
 933 (defoptimizer (car derive-type) ((cons))
 934   (let ((type (lvar-type cons))
 935         (null-type (specifier-type 'null)))
 936     (cond ((eq type null-type)
 937            null-type)
 938           ((cons-type-p type)
 939            (cons-type-car-type type)))))
 940
 941 (defoptimizer (cdr derive-type) ((cons))
 942   (let ((type (lvar-type cons))
 943         (null-type (specifier-type 'null)))
 944     (cond ((eq type null-type)
 945            null-type)
 946           ((cons-type-p type)
 947            (cons-type-cdr-type type)))))
 948 \f
 949 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
 950
 951 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
 952 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
 953 ;;; expansion, so we factor out the condition into this function.
 954 (defun check-inlineability-of-find-position-if (sequence from-end)
 955   (let ((ctype (lvar-type sequence)))
 956     (cond ((csubtypep ctype (specifier-type 'vector))
 957            ;; It's not worth trying to inline vector code unless we
 958            ;; know a fair amount about it at compile time.
 959            (upgraded-element-type-specifier-or-give-up sequence)
 960            (unless (constant-lvar-p from-end)
 961              (give-up-ir1-transform
 962               "FROM-END argument value not known at compile time")))
 963           ((csubtypep ctype (specifier-type 'list))
 964            ;; Inlining on lists is generally worthwhile.
 965            )
 966           (t
 967            (give-up-ir1-transform
 968             "sequence type not known at compile time")))))
 969
 970 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
 971 (macrolet ((def (name condition)
 972              `(deftransform ,name ((predicate sequence from-end start end key)
 973                                    (function list t t t function)
 974                                    *
 975                                    :policy (> speed space))
 976                 "expand inline"
 977                 `(let ((index 0)
 978                        (find nil)
 979                        (position nil))
 980                    (declare (type index index))
 981                    (dolist (i sequence
 982                             (if (and end (> end index))
 983                                 (sb!impl::signal-bounding-indices-bad-error
 984                                  sequence start end)
 985                                 (values find position)))
 986                      (let ((key-i (funcall key i)))
 987                        (when (and end (>= index end))
 988                          (return (values find position)))
 989                        (when (>= index start)
 990                          (,',condition (funcall predicate key-i)
 991                           ;; This hack of dealing with non-NIL
 992                           ;; FROM-END for list data by iterating
 993                           ;; forward through the list and keeping
 994                           ;; track of the last time we found a match
 995                           ;; might be more screwy than what the user
 996                           ;; expects, but it seems to be allowed by
 997                           ;; the ANSI standard. (And if the user is
 998                           ;; screwy enough to ask for FROM-END
 999                           ;; behavior on list data, turnabout is
1000                           ;; fair play.)
1001                           ;;
1002                           ;; It's also not enormously efficient,
1003                           ;; calling PREDICATE and KEY more often
1004                           ;; than necessary; but all the
1005                           ;; alternatives seem to have their own
1006                           ;; efficiency problems.
1007                           (if from-end
1008                               (setf find i
1009                                     position index)
1010                               (return (values i index))))))
1011                      (incf index))))))
1012   (def %find-position-if when)
1013   (def %find-position-if-not unless))
1014
1015 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
1016 ;;; without loss of efficiency. (I.e., the optimizer should be able
1017 ;;; to straighten everything out.)
1018 (deftransform %find-position ((item sequence from-end start end key test)
1019                               (t list t t t t t)
1020                               *
1021                               :policy (> speed space))
1022   "expand inline"
1023   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
1024                         ;; The order of arguments for asymmetric tests
1025                         ;; (e.g. #'<, as opposed to order-independent
1026                         ;; tests like #'=) is specified in the spec
1027                         ;; section 17.2.1 -- the O/Zi stuff there.
1028                         (lambda (i)
1029                           (funcall test-fun item i)))
1030                       sequence
1031                       from-end
1032                       start
1033                       end
1034                       (%coerce-callable-to-fun key)))
1035
1036 ;;; The inline expansions for the VECTOR case are saved as macros so
1037 ;;; that we can share them between the DEFTRANSFORMs and the default
1038 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
1039 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1040 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1041                                                             from-end
1042                                                             start
1043                                                             end-arg
1044                                                             element
1045                                                             done-p-expr)
1046   (with-unique-names (offset block index n-sequence sequence n-end end)
1047     `(let ((,n-sequence ,sequence-arg)
1048            (,n-end ,end-arg))
1049        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1050                          (,start ,start)
1051                          (,end (%check-vector-sequence-bounds
1052                                 ,n-sequence ,start ,n-end)))
1053          (block ,block
1054            (macrolet ((maybe-return ()
1055                         ;; WITH-ARRAY-DATA has already performed bounds
1056                         ;; checking, so we can safely elide the checks
1057                         ;; in the inner loop.
1058                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1059                                            (aref ,sequence ,index))))
1060                            (when ,done-p-expr
1061                              (return-from ,block
1062                                (values ,element
1063                                        (- ,index ,offset)))))))
1064              (if ,from-end
1065                  (loop for ,index
1066                        ;; (If we aren't fastidious about declaring that
1067                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1068                        ;; can send us off into never-never land, since
1069                        ;; INDEX is initialized to -1.)
1070                        of-type index-or-minus-1
1071                        from (1- ,end) downto ,start do
1072                        (maybe-return))
1073                  (loop for ,index of-type index from ,start below ,end do
1074                        (maybe-return))))
1075            (values nil nil))))))
1076
1077 (def!macro %find-position-vector-macro (item sequence
1078                                              from-end start end key test)
1079   (with-unique-names (element)
1080     (%find-position-or-find-position-if-vector-expansion
1081      sequence
1082      from-end
1083      start
1084      end
1085      element
1086      ;; (See the LIST transform for a discussion of the correct
1087      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1088      ;; or after the checked sequence element.)
1089      `(funcall ,test ,item (funcall ,key ,element)))))
1090
1091 (def!macro %find-position-if-vector-macro (predicate sequence
1092                                                      from-end start end key)
1093   (with-unique-names (element)
1094     (%find-position-or-find-position-if-vector-expansion
1095      sequence
1096      from-end
1097      start
1098      end
1099      element
1100      `(funcall ,predicate (funcall ,key ,element)))))
1101
1102 (def!macro %find-position-if-not-vector-macro (predicate sequence
1103                                                          from-end start end key)
1104   (with-unique-names (element)
1105     (%find-position-or-find-position-if-vector-expansion
1106      sequence
1107      from-end
1108      start
1109      end
1110      element
1111      `(not (funcall ,predicate (funcall ,key ,element))))))
1112
1113 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1114 ;;; VECTOR data
1115 (deftransform %find-position-if ((predicate sequence from-end start end key)
1116                                  (function vector t t t function)
1117                                  *
1118                                  :policy (> speed space))
1119   "expand inline"
1120   (check-inlineability-of-find-position-if sequence from-end)
1121   '(%find-position-if-vector-macro predicate sequence
1122                                    from-end start end key))
1123
1124 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1125                                      (function vector t t t function)
1126                                      *
1127                                      :policy (> speed space))
1128   "expand inline"
1129   (check-inlineability-of-find-position-if sequence from-end)
1130   '(%find-position-if-not-vector-macro predicate sequence
1131                                        from-end start end key))
1132
1133 (deftransform %find-position ((item sequence from-end start end key test)
1134                               (t vector t t t function function)
1135                               *
1136                               :policy (> speed space))
1137   "expand inline"
1138   (check-inlineability-of-find-position-if sequence from-end)
1139   '(%find-position-vector-macro item sequence
1140                                 from-end start end key test))
1141
1142 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1143 ;;; POSITION-IF, etc.
1144 (define-source-transform effective-find-position-test (test test-not)
1145   (once-only ((test test)
1146               (test-not test-not))
1147     `(cond
1148       ((and ,test ,test-not)
1149        (error "can't specify both :TEST and :TEST-NOT"))
1150       (,test (%coerce-callable-to-fun ,test))
1151       (,test-not
1152        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1153        ;; inefficient, but since the TEST-NOT option is deprecated
1154        ;; anyway, we don't care.)
1155        (complement (%coerce-callable-to-fun ,test-not)))
1156       (t #'eql))))
1157 (define-source-transform effective-find-position-key (key)
1158   (once-only ((key key))
1159     `(if ,key
1160          (%coerce-callable-to-fun ,key)
1161          #'identity)))
1162
1163 (macrolet ((define-find-position (fun-name values-index)
1164              `(deftransform ,fun-name ((item sequence &key
1165                                              from-end (start 0) end
1166                                              key test test-not)
1167                                        (t (or list vector) &rest t))
1168                 '(nth-value ,values-index
1169                             (%find-position item sequence
1170                                             from-end start
1171                                             end
1172                                             (effective-find-position-key key)
1173                                             (effective-find-position-test
1174                                              test test-not))))))
1175   (define-find-position find 0)
1176   (define-find-position position 1))
1177
1178 (macrolet ((define-find-position-if (fun-name values-index)
1179              `(deftransform ,fun-name ((predicate sequence &key
1180                                                   from-end (start 0)
1181                                                   end key)
1182                                        (t (or list vector) &rest t))
1183                 '(nth-value
1184                   ,values-index
1185                   (%find-position-if (%coerce-callable-to-fun predicate)
1186                                      sequence from-end
1187                                      start end
1188                                      (effective-find-position-key key))))))
1189   (define-find-position-if find-if 0)
1190   (define-find-position-if position-if 1))
1191
1192 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1193 ;;; didn't bother to worry about optimizing them, except note that on
1194 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1195 ;;; sbcl-devel
1196 ;;;
1197 ;;;     My understanding is that while the :test-not argument is
1198 ;;;     deprecated in favour of :test (complement #'foo) because of
1199 ;;;     semantic difficulties (what happens if both :test and :test-not
1200 ;;;     are supplied, etc) the -if-not variants, while officially
1201 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1202 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1203 ;;;     reasons for allowing the -if-not versions equal status,
1204 ;;;     particularly remove-if-not (== filter).
1205 ;;;
1206 ;;;     This is only an informal understanding, I grant you, but
1207 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1208 ;;;     way as the others?
1209 ;;;
1210 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1211 ;;; implementation of SBCL.
1212 (macrolet ((define-find-position-if-not (fun-name values-index)
1213                `(deftransform ,fun-name ((predicate sequence &key
1214                                           from-end (start 0)
1215                                           end key)
1216                                          (t (or list vector) &rest t))
1217                  '(nth-value
1218                    ,values-index
1219                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1220                     sequence from-end
1221                     start end
1222                     (effective-find-position-key key))))))
1223   (define-find-position-if-not find-if-not 0)
1224   (define-find-position-if-not position-if-not 1))