src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places))
 137     (let ((found-vector-p nil))
 138       (flet ((process-vector (length)
 139                (unless found-vector-p
 140                  (setq found-vector-p t)
 141                  (bindings `(index 0 (1+ index)))
 142                  (declarations `(type index index)))
 143                (vector-lengths length)))
 144         (loop for seq of-type lvar in seqs
 145            for seq-name in seq-names
 146            for type = (lvar-type seq)
 147            do (cond ((csubtypep type (specifier-type 'list))
 148                      (with-unique-names (index)
 149                        (bindings `(,index ,seq-name (cdr ,index)))
 150                        (declarations `(type list ,index))
 151                        (places `(car ,index))
 152                        (tests `(endp ,index))))
 153                     ((csubtypep type (specifier-type 'vector))
 154                      (process-vector `(length ,seq-name))
 155                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 156                                 (aref ,seq-name index))))
 157                     (t
 158                      (give-up-ir1-transform
 159                       "can't determine sequence argument type"))))
 160         (when into
 161           (process-vector `(array-dimension ,into 0))))
 162       (when found-vector-p
 163         (bindings `(length (min ,@(vector-lengths))))
 164         (tests `(>= index length)))
 165       `(do (,@(bindings))
 166            ((or ,@(tests)) ,result)
 167          (declare ,@(declarations))
 168          (let ((funcall-result (funcall fun ,@(places))))
 169            (declare (ignorable funcall-result))
 170            ,body)))))
 171
 172 ;;; Try to compile %MAP efficiently when we can determine sequence
 173 ;;; argument types at compile time.
 174 ;;;
 175 ;;; Note: This transform was written to allow open coding of
 176 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 177 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 178 ;;; necessarily as efficient as possible. In particular, it will be
 179 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 180 ;;; numeric element types. It should be straightforward to make it
 181 ;;; handle that case more efficiently, but it's left as an exercise to
 182 ;;; the reader, because the code is complicated enough already and I
 183 ;;; don't happen to need that functionality right now. -- WHN 20000410
 184 (deftransform %map ((result-type fun seq &rest seqs) * *
 185                     :policy (>= speed space))
 186   "open code"
 187   (unless (constant-lvar-p result-type)
 188     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 189   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 190            (fn-1subtypep (fn x y)
 191              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 192                (if valid-p
 193                    subtype-p
 194                    (give-up-ir1-transform
 195                     "can't analyze sequence type relationship"))))
 196            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 197     (let* ((result-type-value (lvar-value result-type))
 198            (result-supertype (cond ((null result-type-value) 'null)
 199                                    ((1subtypep result-type-value 'vector)
 200                                     'vector)
 201                                    ((1subtypep result-type-value 'list)
 202                                     'list)
 203                                    (t
 204                                     (give-up-ir1-transform
 205                                      "result type unsuitable")))))
 206       (cond ((and result-type-value (null seqs))
 207              ;; The consing arity-1 cases can be implemented
 208              ;; reasonably efficiently as function calls, and the cost
 209              ;; of consing should be significantly larger than
 210              ;; function call overhead, so we always compile these
 211              ;; cases as full calls regardless of speed-versus-space
 212              ;; optimization policy.
 213              (cond ((subtypep result-type-value 'list)
 214                     '(%map-to-list-arity-1 fun seq))
 215                    ( ;; (This one can be inefficient due to COERCE, but
 216                     ;; the current open-coded implementation has the
 217                     ;; same problem.)
 218                     (subtypep result-type-value 'vector)
 219                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 220                              ',result-type-value))
 221                    (t (bug "impossible (?) sequence type"))))
 222             (t
 223              (let* ((seqs (cons seq seqs))
 224                     (seq-args (make-gensym-list (length seqs))))
 225                (multiple-value-bind (push-dacc result)
 226                    (ecase result-supertype
 227                      (null (values nil nil))
 228                      (list (values `(push funcall-result acc)
 229                                    `(nreverse acc)))
 230                      (vector (values `(push funcall-result acc)
 231                                      `(coerce (nreverse acc)
 232                                               ',result-type-value))))
 233                  ;; (We use the same idiom, of returning a LAMBDA from
 234                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 235                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 236                  ;; reason: we need to get the runtime values of each
 237                  ;; of the &REST vars.)
 238                  `(lambda (result-type fun ,@seq-args)
 239                     (declare (ignore result-type))
 240                     (let ((fun (%coerce-callable-to-fun fun))
 241                           (acc nil))
 242                       (declare (type list acc))
 243                       (declare (ignorable acc))
 244                       ,(build-sequence-iterator
 245                         seqs seq-args
 246                         :result result
 247                         :body push-dacc))))))))))
 248
 249 ;;; MAP-INTO
 250 (deftransform map-into ((result fun &rest seqs)
 251                         (vector * &rest *)
 252                         *)
 253   "open code"
 254   (let ((seqs-names (mapcar (lambda (x)
 255                               (declare (ignore x))
 256                               (gensym))
 257                             seqs)))
 258     `(lambda (result fun ,@seqs-names)
 259        ,(build-sequence-iterator
 260          seqs seqs-names
 261          :result '(when (array-has-fill-pointer-p result)
 262                    (setf (fill-pointer result) index))
 263          :into 'result
 264          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 265                  (setf (aref result index) funcall-result)))
 266        result)))
 267
 268 \f
 269 ;;; FIXME: once the confusion over doing transforms with known-complex
 270 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 271 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 272 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 273   '(aref s i))
 274
 275 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 276   '(nth i s))
 277
 278 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 279   '(%aset s i v))
 280
 281 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 282   '(setf (car (nthcdr i s)) v))
 283
 284 (deftransform %check-vector-sequence-bounds ((vector start end)
 285                                              (vector * *) *
 286                                              :node node)
 287   (if (policy node (= 0 insert-array-bounds-checks))
 288       '(or end (length vector))
 289       '(let ((length (length vector)))
 290          (if (<= 0 start (or end length) length)
 291              (or end length)
 292              (sequence-bounding-indices-bad-error vector start end)))))
 293
 294 (deftype eq-comparable-type ()
 295   '(or fixnum (not number)))
 296
 297 ;;; True if EQL comparisons involving type can be simplified to EQ.
 298 (defun eq-comparable-type-p (type)
 299   (csubtypep type (specifier-type 'eq-comparable-type)))
 300
 301 (defun specialized-list-seek-function-name (function-name key-functions &optional variant)
 302   (or (find-symbol (with-output-to-string (s)
 303                      ;; Write "%NAME-FUN1-FUN2-FUN3", etc. Not only is
 304                      ;; this ever so slightly faster then FORMAT, this
 305                      ;; way we are also proof against *PRINT-CASE*
 306                      ;; frobbing and such.
 307                      (write-char #\% s)
 308                      (write-string (symbol-name function-name) s)
 309                      (dolist (f key-functions)
 310                        (write-char #\- s)
 311                        (write-string (symbol-name f) s))
 312                      (when variant
 313                        (write-char #\- s)
 314                        (write-string (symbol-name variant) s)))
 315                    (load-time-value (find-package "SB!KERNEL")))
 316       (bug "Unknown list item seek transform: name=~S, key-functions=~S variant=~S"
 317            function-name key-functions variant)))
 318
 319 (defun transform-list-item-seek (name item list key test test-not node)
 320   ;; If TEST is EQL, drop it.
 321   (when (and test (lvar-fun-is test '(eql)))
 322     (setf test nil))
 323   ;; Ditto for KEY IDENTITY.
 324   (when (and key (lvar-fun-is key '(identity)))
 325     (setf key nil))
 326   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 327   ;; not there at all. If it might be NIL, make up a form to that
 328   ;; ensures it is a function.
 329   (multiple-value-bind (key key-form)
 330       (when key
 331         (let ((key-type (lvar-type key))
 332               (null-type (specifier-type 'null)))
 333           (cond ((csubtypep key-type null-type)
 334                  (values nil nil))
 335                 ((csubtypep null-type key-type)
 336                  (values key '(if key
 337                                (%coerce-callable-to-fun key)
 338                                #'identity)))
 339                 (t
 340                  (values key (ensure-lvar-fun-form key 'key))))))
 341     (let* ((c-test (cond ((and test (lvar-fun-is test '(eq)))
 342                           (setf test nil)
 343                           'eq)
 344                          ((and (not test) (not test-not))
 345                           (when (eq-comparable-type-p (lvar-type item))
 346                             'eq))))
 347            (funs (delete nil (list (when key (list key 'key))
 348                                    (when test (list test 'test))
 349                                    (when test-not (list test-not 'test-not)))))
 350            (target-expr (if key '(%funcall key target) 'target))
 351            (test-expr (cond (test `(%funcall test item ,target-expr))
 352                             (test-not `(not (%funcall test-not item ,target-expr)))
 353                             (c-test `(,c-test item ,target-expr))
 354                             (t `(eql item ,target-expr)))))
 355       (labels ((open-code (tail)
 356                  (when tail
 357                    `(if (let ((this ',(car tail)))
 358                           ,(ecase name
 359                                   ((assoc rassoc)
 360                                    (let ((cxx (if (eq name 'assoc) 'car 'cdr)))
 361                                      `(and this (let ((target (,cxx this)))
 362                                                   ,test-expr))))
 363                                   (member
 364                                    `(let ((target this))
 365                                       ,test-expr))))
 366                         ',(ecase name
 367                                  ((assoc rassoc) (car tail))
 368                                  (member tail))
 369                         ,(open-code (cdr tail)))))
 370                (ensure-fun (args)
 371                  (if (eq 'key (second args))
 372                      key-form
 373                      (apply #'ensure-lvar-fun-form args))))
 374         (let* ((cp (constant-lvar-p list))
 375                (c-list (when cp (lvar-value list))))
 376           (cond ((and cp c-list (member name '(assoc rassoc member))
 377                       (policy node (>= speed space)))
 378                  `(let ,(mapcar (lambda (fun) `(,(second fun) ,(ensure-fun fun))) funs)
 379                     ,(open-code c-list)))
 380                 ((and cp (not c-list))
 381                  ;; constant nil list
 382                  (if (eq name 'adjoin)
 383                      '(list item)
 384                      nil))
 385                 (t
 386                  ;; specialized out-of-line version
 387                  `(,(specialized-list-seek-function-name name (mapcar #'second funs) c-test)
 388                     item list ,@(mapcar #'ensure-fun funs)))))))))
 389
 390 (defun transform-list-pred-seek (name pred list key node)
 391   ;; If KEY is IDENTITY, drop it.
 392   (when (and key (lvar-fun-is key '(identity)))
 393     (setf key nil))
 394   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 395   ;; not there at all. If it might be NIL, make up a form to that
 396   ;; ensures it is a function.
 397   (multiple-value-bind (key key-form)
 398       (when key
 399         (let ((key-type (lvar-type key))
 400               (null-type (specifier-type 'null)))
 401           (cond ((csubtypep key-type null-type)
 402                  (values nil nil))
 403                 ((csubtypep null-type key-type)
 404                  (values key '(if key
 405                                (%coerce-callable-to-fun key)
 406                                #'identity)))
 407                 (t
 408                  (values key (ensure-lvar-fun-form key 'key))))))
 409     (let ((test-expr `(%funcall pred ,(if key '(%funcall key target) 'target)))
 410           (pred-expr (ensure-lvar-fun-form pred 'pred)))
 411       (when (member name '(member-if-not assoc-if-not rassoc-if-not))
 412         (setf test-expr `(not ,test-expr)))
 413       (labels ((open-code (tail)
 414                  (when tail
 415                    `(if (let ((this ',(car tail)))
 416                           ,(ecase name
 417                                   ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 418                                    (let ((cxx (if (member name '(assoc-if assoc-if-not)) 'car 'cdr)))
 419                                      `(and this (let ((target (,cxx this)))
 420                                                   ,test-expr))))
 421                                   ((member-if member-if-not)
 422                                    `(let ((target this))
 423                                       ,test-expr))))
 424                         ',(ecase name
 425                                  ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 426                                   (car tail))
 427                                  ((member-if member-if-not)
 428                                   tail))
 429                         ,(open-code (cdr tail))))))
 430         (let* ((cp (constant-lvar-p list))
 431                (c-list (when cp (lvar-value list))))
 432           (cond ((and cp c-list (policy node (>= speed space)))
 433                  `(let ((pred ,pred-expr)
 434                         ,@(when key `((key ,key-form))))
 435                     ,(open-code c-list)))
 436                 ((and cp (not c-list))
 437                  ;; constant nil list -- nothing to find!
 438                  nil)
 439                 (t
 440                  ;; specialized out-of-line version
 441                  `(,(specialized-list-seek-function-name name (when key '(key)))
 442                     ,pred-expr list ,@(when key (list key-form))))))))))
 443
 444 (macrolet ((def (name &optional if/if-not)
 445              (let ((basic (symbolicate "%" name))
 446                    (basic-eq (symbolicate "%" name "-EQ"))
 447                    (basic-key (symbolicate "%" name "-KEY"))
 448                    (basic-key-eq (symbolicate "%" name "-KEY-EQ")))
 449                `(progn
 450                   (deftransform ,name ((item list &key key test test-not) * * :node node)
 451                     (transform-list-item-seek ',name item list key test test-not node))
 452                   (deftransform ,basic ((item list) (eq-comparable-type t))
 453                     `(,',basic-eq item list))
 454                   (deftransform ,basic-key ((item list) (eq-comparable-type t))
 455                     `(,',basic-key-eq item list))
 456                   ,@(when if/if-not
 457                           (let ((if-name (symbolicate name "-IF"))
 458                                 (if-not-name (symbolicate name "-IF-NOT")))
 459                             `((deftransform ,if-name ((pred list &key key) * * :node node)
 460                                 (transform-list-pred-seek ',if-name pred list key node))
 461                               (deftransform ,if-not-name ((pred list &key key) * * :node node)
 462                                 (transform-list-pred-seek ',if-not-name pred list key node)))))))))
 463   (def adjoin)
 464   (def assoc  t)
 465   (def member t)
 466   (def rassoc t))
 467
 468 (deftransform memq ((item list) (t (constant-arg list)))
 469   (labels ((rec (tail)
 470              (if tail
 471                  `(if (eq item ',(car tail))
 472                       ',tail
 473                       ,(rec (cdr tail)))
 474                  nil)))
 475     (rec (lvar-value list))))
 476
 477 ;;; A similar transform used to apply to MEMBER and ASSOC, but since
 478 ;;; TRANSFORM-LIST-ITEM-SEEK now takes care of them those transform
 479 ;;; would never fire, and (%MEMBER-TEST ITEM LIST #'EQ) should be
 480 ;;; almost as fast as MEMQ.
 481 (deftransform delete ((item list &key test) (t list &rest t) *)
 482   "convert to EQ test"
 483   ;; FIXME: The scope of this transformation could be
 484   ;; widened somewhat, letting it work whenever the test is
 485   ;; 'EQL and we know from the type of ITEM that it #'EQ
 486   ;; works like #'EQL on it. (E.g. types FIXNUM, CHARACTER,
 487   ;; and SYMBOL.)
 488   ;;   If TEST is EQ, apply transform, else
 489   ;;   if test is not EQL, then give up on transform, else
 490   ;;   if ITEM is not a NUMBER or is a FIXNUM, apply
 491   ;;   transform, else give up on transform.
 492   (cond (test
 493          (unless (lvar-fun-is test '(eq))
 494            (give-up-ir1-transform)))
 495         ((types-equal-or-intersect (lvar-type item)
 496                                    (specifier-type 'number))
 497          (give-up-ir1-transform "Item might be a number.")))
 498   `(delq item list))
 499
 500 (deftransform delete-if ((pred list) (t list))
 501   "open code"
 502   '(do ((x list (cdr x))
 503         (splice '()))
 504        ((endp x) list)
 505      (cond ((funcall pred (car x))
 506             (if (null splice)
 507                 (setq list (cdr x))
 508                 (rplacd splice (cdr x))))
 509            (t (setq splice x)))))
 510
 511 (deftransform fill ((seq item &key (start 0) (end nil))
 512                     (list t &key (:start t) (:end t)))
 513   '(list-fill* seq item start end))
 514
 515 (deftransform fill ((seq item &key (start 0) (end nil))
 516                     (vector t &key (:start t) (:end t))
 517                     *
 518                     :node node)
 519   (let* ((element-ctype (extract-upgraded-element-type seq))
 520          (element-type (type-specifier element-ctype))
 521          (type (lvar-type seq))
 522          (saetp (unless (eq *wild-type* element-ctype)
 523                   (find-saetp-by-ctype element-ctype))))
 524     (cond ((eq *wild-type* element-ctype)
 525            (delay-ir1-transform node :constraint)
 526            `(vector-fill* seq item start end))
 527           ((and saetp (sb!vm::valid-bit-bash-saetp-p saetp))
 528            (let* ((n-bits (sb!vm:saetp-n-bits saetp))
 529                   (basher-name (format nil "UB~D-BASH-FILL" n-bits))
 530                   (basher (or (find-symbol basher-name
 531                                            (load-time-value (find-package :sb!kernel)))
 532                               (abort-ir1-transform
 533                                "Unknown fill basher, please report to sbcl-devel: ~A"
 534                                basher-name)))
 535                   (kind (cond ((sb!vm:saetp-fixnum-p saetp) :tagged)
 536                               ((member element-type '(character base-char)) :char)
 537                               ((eq element-type 'single-float) :single-float)
 538                               ((eq element-type 'double-float) :double-float)
 539                               (t :bits)))
 540                   ;; BASH-VALUE is a word that we can repeatedly smash
 541                   ;; on the array: for less-than-word sized elements it
 542                   ;; contains multiple copies of the fill item.
 543                   (bash-value
 544                    (if (constant-lvar-p item)
 545                        (let ((tmp (lvar-value item)))
 546                          (unless (ctypep tmp element-ctype)
 547                            (abort-ir1-transform "~S is not ~S" tmp element-type))
 548                          (let* ((bits
 549                                  (ldb (byte n-bits 0)
 550                                       (ecase kind
 551                                         (:tagged
 552                                          (ash tmp sb!vm:n-fixnum-tag-bits))
 553                                         (:char
 554                                          (char-code tmp))
 555                                         (:bits
 556                                          tmp)
 557                                         (:single-float
 558                                          (single-float-bits tmp))
 559                                         (:double-float
 560                                          (logior (ash (double-float-high-bits tmp) 32)
 561                                                  (double-float-low-bits tmp))))))
 562                                 (res bits))
 563                            (loop for i of-type sb!vm:word from n-bits by n-bits
 564                                  until (= i sb!vm:n-word-bits)
 565                                  do (setf res (ldb (byte sb!vm:n-word-bits 0)
 566                                                    (logior res (ash bits i)))))
 567                            res))
 568                        `(let* ((bits (ldb (byte ,n-bits 0)
 569                                           ,(ecase kind
 570                                                   (:tagged
 571                                                    `(ash item ,sb!vm:n-fixnum-tag-bits))
 572                                                   (:char
 573                                                    `(char-code item))
 574                                                   (:bits
 575                                                    `item)
 576                                                   (:single-float
 577                                                    `(single-float-bits item))
 578                                                   (:double-float
 579                                                    `(logior (ash (double-float-high-bits item) 32)
 580                                                             (double-float-low-bits item))))))
 581                                (res bits))
 582                           (declare (type sb!vm:word res))
 583                           ,@(unless (= sb!vm:n-word-bits n-bits)
 584                                     `((loop for i of-type sb!vm:word from ,n-bits by ,n-bits
 585                                             until (= i sb!vm:n-word-bits)
 586                                             do (setf res
 587                                                      (ldb (byte ,sb!vm:n-word-bits 0)
 588                                                           (logior res (ash bits (truly-the (integer 0 ,(- sb!vm:n-word-bits n-bits)) i))))))))
 589                           res))))
 590              (values
 591               `(with-array-data ((data seq)
 592                                  (start start)
 593                                  (end end)
 594                                  :check-fill-pointer t)
 595                  (declare (type (simple-array ,element-type 1) data))
 596                  (declare (type index start end))
 597                  (declare (optimize (safety 0) (speed 3))
 598                           (muffle-conditions compiler-note))
 599                  (,basher ,bash-value data start (- end start))
 600                  seq)
 601               `((declare (type ,element-type item))))))
 602           ((policy node (> speed space))
 603            (values
 604             `(with-array-data ((data seq)
 605                                (start start)
 606                                (end end)
 607                                :check-fill-pointer t)
 608                (declare (type (simple-array ,element-type 1) data))
 609                (declare (type index start end))
 610                ;; WITH-ARRAY-DATA did our range checks once and for all, so
 611                ;; it'd be wasteful to check again on every AREF...
 612                (declare (optimize (safety 0) (speed 3)))
 613                (do ((i start (1+ i)))
 614                    ((= i end) seq)
 615                  (declare (type index i))
 616                  (setf (aref data i) item)))
 617             ;; ... though we still need to check that the new element can fit
 618             ;; into the vector in safe code. -- CSR, 2002-07-05
 619             `((declare (type ,element-type item)))))
 620           ((csubtypep type (specifier-type 'string))
 621            '(string-fill* seq item start end))
 622           (t
 623            '(vector-fill* seq item start end)))))
 624
 625 (deftransform fill ((seq item &key (start 0) (end nil))
 626                     ((and sequence (not vector) (not list)) t &key (:start t) (:end t)))
 627   `(sb!sequence:fill seq item
 628                      :start start
 629                      :end (%check-generic-sequence-bounds seq start end)))
 630 \f
 631 ;;;; hairy sequence transforms
 632
 633 ;;; FIXME: no hairy sequence transforms in SBCL?
 634 ;;;
 635 ;;; There used to be a bunch of commented out code about here,
 636 ;;; containing the (apparent) beginning of hairy sequence transform
 637 ;;; infrastructure. People interested in implementing better sequence
 638 ;;; transforms might want to look at it for inspiration, even though
 639 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 640 ;;; was deleted in 1.0.7.23.
 641 \f
 642 ;;;; string operations
 643
 644 ;;; We transform the case-sensitive string predicates into a non-keyword
 645 ;;; version. This is an IR1 transform so that we don't have to worry about
 646 ;;; changing the order of evaluation.
 647 (macrolet ((def (fun pred*)
 648              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 649                                                          (start2 0) end2)
 650                                    * *)
 651                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 652   (def string< string<*)
 653   (def string> string>*)
 654   (def string<= string<=*)
 655   (def string>= string>=*)
 656   (def string= string=*)
 657   (def string/= string/=*))
 658
 659 ;;; Return a form that tests the free variables STRING1 and STRING2
 660 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 661 ;;; start and end are also gotten from the environment. Both strings
 662 ;;; must be SIMPLE-BASE-STRINGs.
 663 (macrolet ((def (name lessp equalp)
 664              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 665                                    (simple-base-string simple-base-string t t t t) *)
 666                 `(let* ((end1 (if (not end1) (length string1) end1))
 667                         (end2 (if (not end2) (length string2) end2))
 668                         (index (sb!impl::%sp-string-compare
 669                                 string1 start1 end1 string2 start2 end2)))
 670                   (if index
 671                       (cond ((= index end1)
 672                              ,(if ',lessp 'index nil))
 673                             ((= (+ index (- start2 start1)) end2)
 674                              ,(if ',lessp nil 'index))
 675                             ((,(if ',lessp 'char< 'char>)
 676                                (schar string1 index)
 677                                (schar string2
 678                                       (truly-the index
 679                                                  (+ index
 680                                                     (truly-the fixnum
 681                                                                (- start2
 682                                                                   start1))))))
 683                              index)
 684                             (t nil))
 685                       ,(if ',equalp 'end1 nil))))))
 686   (def string<* t nil)
 687   (def string<=* t t)
 688   (def string>* nil nil)
 689   (def string>=* nil t))
 690
 691 (macrolet ((def (name result-fun)
 692              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 693                                    (simple-base-string simple-base-string t t t t) *)
 694                 `(,',result-fun
 695                   (sb!impl::%sp-string-compare
 696                    string1 start1 (or end1 (length string1))
 697                    string2 start2 (or end2 (length string2)))))))
 698   (def string=* not)
 699   (def string/=* identity))
 700
 701 \f
 702 ;;;; transforms for sequence functions
 703
 704 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 705 ;;; to vectors based on simple arrays.
 706 (def!constant vector-data-bit-offset
 707   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 708
 709 ;;; FIXME: In the copy loops below, we code the loops in a strange
 710 ;;; fashion:
 711 ;;;
 712 ;;; (do ((i (+ src-offset length) (1- i)))
 713 ;;;     ((<= i 0) ...)
 714 ;;;   (... (aref foo (1- i)) ...))
 715 ;;;
 716 ;;; rather than the more natural (and seemingly more efficient):
 717 ;;;
 718 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 719 ;;;     ((< i 0) ...)
 720 ;;;   (... (aref foo i) ...))
 721 ;;;
 722 ;;; (more efficient because we don't have to do the index adjusting on
 723 ;;; every iteration of the loop)
 724 ;;;
 725 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 726 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 727 ;;; when used as an array index, the backend thinks I is a
 728 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 729 ;;; these as distinct storage classes, it cannot coerce a move from a
 730 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 731 ;;; deficiency is that we have two extra moves and increased register
 732 ;;; pressure, which can lead to some spectacularly bad register
 733 ;;; allocation.  (sub-FIXME: the register allocation even with the
 734 ;;; strangely written loops is not always excellent, either...).  Doing
 735 ;;; it the first way, above, means that I is always thought of as a
 736 ;;; POSITIVE-FIXNUM and there are no issues.
 737 ;;;
 738 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 739 ;;; adjustments in the first version into the array addressing at no
 740 ;;; performance penalty!
 741
 742 ;;; This transform is critical to the performance of string streams.  If
 743 ;;; you tweak it, make sure that you compare the disassembly, if not the
 744 ;;; performance of, the functions implementing string streams
 745 ;;; (e.g. SB!IMPL::STRING-OUCH).
 746 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 747   (defun make-replace-transform (saetp sequence-type1 sequence-type2)
 748     `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 749                             (,sequence-type1 ,sequence-type2 &rest t)
 750                             ,sequence-type1
 751                             :node node)
 752        `(let* ((len1 (length seq1))
 753                (len2 (length seq2))
 754                (end1 (or end1 len1))
 755                (end2 (or end2 len2))
 756                (replace-len (min (- end1 start1) (- end2 start2))))
 757           ,(unless (policy node (= safety 0))
 758              `(progn
 759                 (unless (<= 0 start1 end1 len1)
 760                   (sequence-bounding-indices-bad-error seq1 start1 end1))
 761                 (unless (<= 0 start2 end2 len2)
 762                   (sequence-bounding-indices-bad-error seq2 start2 end2))))
 763           ,',(cond
 764                ((and saetp (sb!vm:valid-bit-bash-saetp-p saetp))
 765                 (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 766                        (bash-function (intern (format nil "UB~D-BASH-COPY"
 767                                                       n-element-bits)
 768                                               (find-package "SB!KERNEL"))))
 769                   `(funcall (function ,bash-function) seq2 start2
 770                     seq1 start1 replace-len)))
 771                (t
 772                 `(if (and
 773                       ;; If the sequence types are different, SEQ1 and
 774                       ;; SEQ2 must be distinct arrays.
 775                       ,(eql sequence-type1 sequence-type2)
 776                       (eq seq1 seq2) (> start1 start2))
 777                      (do ((i (truly-the index (+ start1 replace-len -1))
 778                              (1- i))
 779                           (j (truly-the index (+ start2 replace-len -1))
 780                              (1- j)))
 781                          ((< i start1))
 782                        (declare (optimize (insert-array-bounds-checks 0)))
 783                        (setf (aref seq1 i) (aref seq2 j)))
 784                      (do ((i start1 (1+ i))
 785                           (j start2 (1+ j))
 786                           (end (+ start1 replace-len)))
 787                          ((>= i end))
 788                        (declare (optimize (insert-array-bounds-checks 0)))
 789                        (setf (aref seq1 i) (aref seq2 j))))))
 790           seq1))))
 791
 792 (macrolet
 793     ((define-replace-transforms ()
 794        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 795              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 796              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 797              collect (make-replace-transform saetp sequence-type sequence-type)
 798              into forms
 799              finally (return `(progn ,@forms))))
 800      (define-one-transform (sequence-type1 sequence-type2)
 801        (make-replace-transform nil sequence-type1 sequence-type2)))
 802   (define-replace-transforms)
 803   #!+sb-unicode
 804   (progn
 805    (define-one-transform (simple-array base-char (*)) (simple-array character (*)))
 806    (define-one-transform (simple-array character (*)) (simple-array base-char (*)))))
 807
 808 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 809 ;;; defined as those cases where we are doing word-aligned copies from
 810 ;;; both the source and the destination and we are copying from the same
 811 ;;; offset from both the source and the destination.  (The last
 812 ;;; condition is there so we can determine the direction to copy at
 813 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 814 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 815 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 816 ;;; N)-size buffer and blitting in the old N-size buffer in.
 817
 818 (defun frob-bash-transform (src src-offset
 819                             dst dst-offset
 820                             length n-elems-per-word)
 821   (declare (ignore src dst length))
 822   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 823     (multiple-value-bind (src-word src-elt)
 824         (truncate (lvar-value src-offset) n-elems-per-word)
 825       (multiple-value-bind (dst-word dst-elt)
 826           (truncate (lvar-value dst-offset) n-elems-per-word)
 827         ;; Avoid non-word aligned copies.
 828         (unless (and (zerop src-elt) (zerop dst-elt))
 829           (give-up-ir1-transform))
 830         ;; Avoid copies where we would have to insert code for
 831         ;; determining the direction of copying.
 832         (unless (= src-word dst-word)
 833           (give-up-ir1-transform))
 834         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 835         ;; so we have to do its work here.
 836         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 837                                       'length
 838                                       `(truncate (the index length) ,n-elems-per-word)))))
 839            (declare (type index end))
 840            ;; Handle any bits at the end.
 841            (when (logtest length (1- ,n-elems-per-word))
 842              (let* ((extra (mod length ,n-elems-per-word))
 843                     ;; FIXME: The shift amount on this ASH is
 844                     ;; *always* negative, but the backend doesn't
 845                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 846                     ;; wind up with a pile of code that tests the
 847                     ;; sign of the shift count prior to shifting when
 848                     ;; all we need is a simple negate and shift
 849                     ;; right.  Yuck.
 850                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 851                                (* (- extra ,n-elems-per-word)
 852                                   ,n-bits-per-elem))))
 853                (setf (sb!kernel:%vector-raw-bits dst end)
 854                      (logior
 855                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 856                                 (ash mask
 857                                      ,(ecase sb!c:*backend-byte-order*
 858                                              (:little-endian 0)
 859                                              (:big-endian `(* (- ,n-elems-per-word extra)
 860                                                               ,n-bits-per-elem)))))
 861                       (logand (sb!kernel:%vector-raw-bits src end)
 862                               (ash mask
 863                                    ,(ecase sb!c:*backend-byte-order*
 864                                            (:little-endian 0)
 865                                            (:big-endian `(* (- ,n-elems-per-word extra)
 866                                                             ,n-bits-per-elem)))))))))
 867            ;; Copy from the end to save a register.
 868            (do ((i end (1- i)))
 869                ((<= i ,src-word))
 870              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 871                    (sb!kernel:%vector-raw-bits src (1- i))))
 872            (values))))))
 873
 874 #.(loop for i = 1 then (* i 2)
 875         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 876                                         "SB!KERNEL")
 877                                                         ((src src-offset
 878                                                           dst dst-offset
 879                                                           length)
 880                                                         ((simple-unboxed-array (*))
 881                                                          (constant-arg index)
 882                                                          (simple-unboxed-array (*))
 883                                                          (constant-arg index)
 884                                                          index)
 885                                                         *)
 886                   (frob-bash-transform src src-offset
 887                                        dst dst-offset length
 888                                        ,(truncate sb!vm:n-word-bits i))) into forms
 889         until (= i sb!vm:n-word-bits)
 890         finally (return `(progn ,@forms)))
 891
 892 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 893 ;;; arrays with elements of size >= the word size.  We do this because
 894 ;;; we know the arrays cannot alias (one was just consed), therefore we
 895 ;;; can determine at compile time the direction to copy, and for
 896 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 897 ;;; needless checking to figure out what's going on.  The same
 898 ;;; considerations apply if we are copying elements larger than the word
 899 ;;; size, with the additional twist that doing it inline is likely to
 900 ;;; cons far less than calling REPLACE and letting generic code do the
 901 ;;; work.
 902 ;;;
 903 ;;; However, we do not do this for elements whose size is < than the
 904 ;;; word size because we don't want to deal with any alignment issues
 905 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 906 ;;; anyway.
 907
 908 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 909                                       element-type)
 910   (let ((saetp (find-saetp element-type)))
 911     (aver saetp)
 912     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 913         (expand-aref-copy-loop src src-offset dst dst-offset length)
 914         `(locally (declare (optimize (safety 0)))
 915            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 916
 917 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 918   (if (eql src-offset dst-offset)
 919       `(do ((i (+ ,src-offset ,length) (1- i)))
 920            ((<= i ,src-offset))
 921          (declare (optimize (insert-array-bounds-checks 0)))
 922          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 923       ;; KLUDGE: The compiler is not able to derive that (+ offset
 924       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 925       ;; We, however, know it must be so, as by this point the bounds
 926       ;; have already been checked.
 927       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 928             (j (+ ,dst-offset ,length) (1- j)))
 929            ((<= i ,src-offset))
 930          (declare (optimize (insert-array-bounds-checks 0))
 931                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 932          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 933
 934 ;;; SUBSEQ, COPY-SEQ
 935
 936 (deftransform subseq ((seq start &optional end)
 937                       (vector t &optional t)
 938                       *
 939                       :node node)
 940   (let ((type (lvar-type seq)))
 941     (cond
 942       ((and (array-type-p type)
 943             (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 944        (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 945          `(let* ((length (length seq))
 946                  (end (or end length)))
 947             ,(unless (policy node (zerop insert-array-bounds-checks))
 948                      '(progn
 949                        (unless (<= 0 start end length)
 950                          (sequence-bounding-indices-bad-error seq start end))))
 951             (let* ((size (- end start))
 952                    (result (make-array size :element-type ',element-type)))
 953               ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
 954                                                        (lvar-value start)
 955                                                        'start)
 956                                               'result 0 'size element-type)
 957               result))))
 958       ((csubtypep type (specifier-type 'string))
 959        '(string-subseq* seq start end))
 960       (t
 961        '(vector-subseq* seq start end)))))
 962
 963 (deftransform subseq ((seq start &optional end)
 964                       (list t &optional t))
 965   `(list-subseq* seq start end))
 966
 967 (deftransform subseq ((seq start &optional end)
 968                       ((and sequence (not vector) (not list)) t &optional t))
 969   '(sb!sequence:subseq seq start end))
 970
 971 (deftransform copy-seq ((seq) (vector))
 972   (let ((type (lvar-type seq)))
 973     (cond ((and (array-type-p type)
 974                 (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 975            (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 976              `(let* ((length (length seq))
 977                      (result (make-array length :element-type ',element-type)))
 978                 ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
 979                 result)))
 980           ((csubtypep type (specifier-type 'string))
 981            '(string-subseq* seq 0 nil))
 982           (t
 983            '(vector-subseq* seq 0 nil)))))
 984
 985 (deftransform copy-seq ((seq) (list))
 986   '(list-copy-seq* seq))
 987
 988 (deftransform copy-seq ((seq) ((and sequence (not vector) (not list))))
 989   '(sb!sequence:copy-seq seq))
 990
 991 ;;; FIXME: it really should be possible to take advantage of the
 992 ;;; macros used in code/seq.lisp here to avoid duplication of code,
 993 ;;; and enable even funkier transformations.
 994 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
 995                                (test #'eql)
 996                                (key #'identity)
 997                                from-end)
 998                       (vector vector &rest t)
 999                       *
1000                       :node node
1001                       :policy (> speed (max space safety)))
1002   "open code"
1003   (let ((from-end (when (lvar-p from-end)
1004                     (unless (constant-lvar-p from-end)
1005                       (give-up-ir1-transform ":FROM-END is not constant."))
1006                     (lvar-value from-end)))
1007         (keyp (lvar-p key))
1008         (testp (lvar-p test))
1009         (check-bounds-p (policy node (plusp insert-array-bounds-checks))))
1010     `(block search
1011        (flet ((oops (vector start end)
1012                 (sequence-bounding-indices-bad-error vector start end)))
1013          (let* ((len1 (length pattern))
1014                 (len2 (length text))
1015                 (end1 (or end1 len1))
1016                 (end2 (or end2 len2))
1017                ,@(when keyp
1018                        '((key (coerce key 'function))))
1019                ,@(when testp
1020                        '((test (coerce test 'function)))))
1021           (declare (type index start1 start2 end1 end2))
1022           ,@(when check-bounds-p
1023              `((unless (<= start1 end1 len1)
1024                  (oops pattern start1 end1))
1025                (unless (<= start2 end2 len2)
1026                  (oops pattern start2 end2))))
1027           (do (,(if from-end
1028                     '(index2 (- end2 (- end1 start1)) (1- index2))
1029                     '(index2 start2 (1+ index2))))
1030               (,(if from-end
1031                     '(< index2 start2)
1032                     '(>= index2 end2))
1033                nil)
1034             ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
1035             ;; terminates is hits -1 when :FROM-END is true and :START2
1036             ;; is 0.
1037             (declare (type fixnum index2))
1038             (when (do ((index1 start1 (1+ index1))
1039                        (index2 index2 (1+ index2)))
1040                       ((>= index1 end1) t)
1041                     (declare (type index index1 index2)
1042                              (optimize (insert-array-bounds-checks 0)))
1043                     ,@(unless from-end
1044                               '((when (= index2 end2)
1045                                   (return-from search nil))))
1046                     (unless (,@(if testp
1047                                    '(funcall test)
1048                                    '(eql))
1049                                ,(if keyp
1050                                     '(funcall key (aref pattern index1))
1051                                     '(aref pattern index1))
1052                                ,(if keyp
1053                                     '(funcall key (aref text index2))
1054                                     '(aref text index2)))
1055                       (return nil)))
1056               (return index2))))))))
1057
1058
1059 ;;; Open-code CONCATENATE for strings. It would be possible to extend
1060 ;;; this transform to non-strings, but I chose to just do the case that
1061 ;;; should cover 95% of CONCATENATE performance complaints for now.
1062 ;;;   -- JES, 2007-11-17
1063 (deftransform concatenate ((result-type &rest lvars)
1064                            (symbol &rest sequence)
1065                            *
1066                            :policy (> speed space))
1067   (unless (constant-lvar-p result-type)
1068     (give-up-ir1-transform))
1069   (let* ((element-type (let ((type (lvar-value result-type)))
1070                          ;; Only handle the simple result type cases. If
1071                          ;; somebody does (CONCATENATE '(STRING 6) ...)
1072                          ;; their code won't be optimized, but nobody does
1073                          ;; that in practice.
1074                          (case type
1075                            ((string simple-string) 'character)
1076                            ((base-string simple-base-string) 'base-char)
1077                            (t (give-up-ir1-transform)))))
1078          (vars (loop for x in lvars collect (gensym)))
1079          (lvar-values (loop for lvar in lvars
1080                             collect (when (constant-lvar-p lvar)
1081                                       (lvar-value lvar))))
1082          (lengths
1083           (loop for value in lvar-values
1084                 for var in vars
1085                 collect (if value
1086                             (length value)
1087                             `(sb!impl::string-dispatch ((simple-array * (*))
1088                                                         sequence)
1089                                  ,var
1090                                (declare (muffle-conditions compiler-note))
1091                                (length ,var))))))
1092     `(apply
1093       (lambda ,vars
1094         (declare (ignorable ,@vars))
1095         (let* ((.length. (+ ,@lengths))
1096                (.pos. 0)
1097                (.string. (make-string .length. :element-type ',element-type)))
1098           (declare (type index .length. .pos.)
1099                    (muffle-conditions compiler-note))
1100           ,@(loop for value in lvar-values
1101                   for var in vars
1102                   collect (if (stringp value)
1103                               ;; Fold the array reads for constant arguments
1104                               `(progn
1105                                  ,@(loop for c across value
1106                                          collect `(setf (aref .string.
1107                                                               .pos.) ,c)
1108                                          collect `(incf .pos.)))
1109                               `(sb!impl::string-dispatch
1110                                    (#!+sb-unicode
1111                                     (simple-array character (*))
1112                                     (simple-array base-char (*))
1113                                     t)
1114                                    ,var
1115                                  (replace .string. ,var :start1 .pos.)
1116                                  (incf .pos. (length ,var)))))
1117           .string.))
1118       lvars)))
1119 \f
1120 ;;;; CONS accessor DERIVE-TYPE optimizers
1121
1122 (defoptimizer (car derive-type) ((cons))
1123   ;; This and CDR needs to use LVAR-CONSERVATIVE-TYPE because type inference
1124   ;; gets confused by things like (SETF CAR).
1125   (let ((type (lvar-conservative-type cons))
1126         (null-type (specifier-type 'null)))
1127     (cond ((eq type null-type)
1128            null-type)
1129           ((cons-type-p type)
1130            (cons-type-car-type type)))))
1131
1132 (defoptimizer (cdr derive-type) ((cons))
1133   (let ((type (lvar-conservative-type cons))
1134         (null-type (specifier-type 'null)))
1135     (cond ((eq type null-type)
1136            null-type)
1137           ((cons-type-p type)
1138            (cons-type-cdr-type type)))))
1139 \f
1140 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
1141
1142 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
1143 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
1144 ;;; expansion, so we factor out the condition into this function.
1145 (defun check-inlineability-of-find-position-if (sequence from-end)
1146   (let ((ctype (lvar-type sequence)))
1147     (cond ((csubtypep ctype (specifier-type 'vector))
1148            ;; It's not worth trying to inline vector code unless we
1149            ;; know a fair amount about it at compile time.
1150            (upgraded-element-type-specifier-or-give-up sequence)
1151            (unless (constant-lvar-p from-end)
1152              (give-up-ir1-transform
1153               "FROM-END argument value not known at compile time")))
1154           ((csubtypep ctype (specifier-type 'list))
1155            ;; Inlining on lists is generally worthwhile.
1156            )
1157           (t
1158            (give-up-ir1-transform
1159             "sequence type not known at compile time")))))
1160
1161 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
1162 (macrolet ((def (name condition)
1163              `(deftransform ,name ((predicate sequence from-end start end key)
1164                                    (function list t t t function)
1165                                    *
1166                                    :policy (> speed space))
1167                 "expand inline"
1168                 `(let ((index 0)
1169                        (find nil)
1170                        (position nil))
1171                    (declare (type index index))
1172                    (dolist (i sequence
1173                             (if (and end (> end index))
1174                                 (sequence-bounding-indices-bad-error
1175                                  sequence start end)
1176                                 (values find position)))
1177                      (when (and end (>= index end))
1178                        (return (values find position)))
1179                      (when (>= index start)
1180                        (let ((key-i (funcall key i)))
1181                          (,',condition (funcall predicate key-i)
1182                                        ;; This hack of dealing with non-NIL
1183                                        ;; FROM-END for list data by iterating
1184                                        ;; forward through the list and keeping
1185                                        ;; track of the last time we found a
1186                                        ;; match might be more screwy than what
1187                                        ;; the user expects, but it seems to be
1188                                        ;; allowed by the ANSI standard. (And
1189                                        ;; if the user is screwy enough to ask
1190                                        ;; for FROM-END behavior on list data,
1191                                        ;; turnabout is fair play.)
1192                                        ;;
1193                                        ;; It's also not enormously efficient,
1194                                        ;; calling PREDICATE and KEY more often
1195                                        ;; than necessary; but all the
1196                                        ;; alternatives seem to have their own
1197                                        ;; efficiency problems.
1198                                        (if from-end
1199                                            (setf find i
1200                                                  position index)
1201                                            (return (values i index))))))
1202                      (incf index))))))
1203   (def %find-position-if when)
1204   (def %find-position-if-not unless))
1205
1206 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
1207 ;;; without loss of efficiency. (I.e., the optimizer should be able
1208 ;;; to straighten everything out.)
1209 (deftransform %find-position ((item sequence from-end start end key test)
1210                               (t list t t t t t)
1211                               *
1212                               :policy (> speed space))
1213   "expand inline"
1214   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
1215                         ;; The order of arguments for asymmetric tests
1216                         ;; (e.g. #'<, as opposed to order-independent
1217                         ;; tests like #'=) is specified in the spec
1218                         ;; section 17.2.1 -- the O/Zi stuff there.
1219                         (lambda (i)
1220                           (funcall test-fun item i)))
1221                       sequence
1222                       from-end
1223                       start
1224                       end
1225                       (%coerce-callable-to-fun key)))
1226
1227 ;;; The inline expansions for the VECTOR case are saved as macros so
1228 ;;; that we can share them between the DEFTRANSFORMs and the default
1229 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
1230 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1231 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1232                                                             from-end
1233                                                             start
1234                                                             end-arg
1235                                                             element
1236                                                             done-p-expr)
1237   (with-unique-names (offset block index n-sequence sequence end)
1238     `(let* ((,n-sequence ,sequence-arg))
1239        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1240                          (,start ,start)
1241                          (,end ,end-arg)
1242                          :check-fill-pointer t)
1243          (block ,block
1244            (macrolet ((maybe-return ()
1245                         ;; WITH-ARRAY-DATA has already performed bounds
1246                         ;; checking, so we can safely elide the checks
1247                         ;; in the inner loop.
1248                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1249                                            (aref ,sequence ,index))))
1250                           (when ,done-p-expr
1251                             (return-from ,block
1252                               (values ,element
1253                                       (- ,index ,offset)))))))
1254              (if ,from-end
1255                  (loop for ,index
1256                        ;; (If we aren't fastidious about declaring that
1257                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1258                        ;; can send us off into never-never land, since
1259                        ;; INDEX is initialized to -1.)
1260                        of-type index-or-minus-1
1261                        from (1- ,end) downto ,start do
1262                        (maybe-return))
1263                  (loop for ,index of-type index from ,start below ,end do
1264                           (maybe-return))))
1265            (values nil nil))))))
1266
1267 (def!macro %find-position-vector-macro (item sequence
1268                                              from-end start end key test)
1269   (with-unique-names (element)
1270     (%find-position-or-find-position-if-vector-expansion
1271      sequence
1272      from-end
1273      start
1274      end
1275      element
1276      ;; (See the LIST transform for a discussion of the correct
1277      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1278      ;; or after the checked sequence element.)
1279      `(funcall ,test ,item (funcall ,key ,element)))))
1280
1281 (def!macro %find-position-if-vector-macro (predicate sequence
1282                                                      from-end start end key)
1283   (with-unique-names (element)
1284     (%find-position-or-find-position-if-vector-expansion
1285      sequence
1286      from-end
1287      start
1288      end
1289      element
1290      `(funcall ,predicate (funcall ,key ,element)))))
1291
1292 (def!macro %find-position-if-not-vector-macro (predicate sequence
1293                                                          from-end start end key)
1294   (with-unique-names (element)
1295     (%find-position-or-find-position-if-vector-expansion
1296      sequence
1297      from-end
1298      start
1299      end
1300      element
1301      `(not (funcall ,predicate (funcall ,key ,element))))))
1302
1303 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1304 ;;; VECTOR data
1305 (deftransform %find-position-if ((predicate sequence from-end start end key)
1306                                  (function vector t t t function)
1307                                  *
1308                                  :policy (> speed space))
1309   "expand inline"
1310   (check-inlineability-of-find-position-if sequence from-end)
1311   '(%find-position-if-vector-macro predicate sequence
1312                                    from-end start end key))
1313
1314 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1315                                      (function vector t t t function)
1316                                      *
1317                                      :policy (> speed space))
1318   "expand inline"
1319   (check-inlineability-of-find-position-if sequence from-end)
1320   '(%find-position-if-not-vector-macro predicate sequence
1321                                        from-end start end key))
1322
1323 (deftransform %find-position ((item sequence from-end start end key test)
1324                               (t vector t t t function function)
1325                               *
1326                               :policy (> speed space))
1327   "expand inline"
1328   (check-inlineability-of-find-position-if sequence from-end)
1329   '(%find-position-vector-macro item sequence
1330     from-end start end key test))
1331
1332 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1333 ;;; POSITION-IF, etc.
1334 (define-source-transform effective-find-position-test (test test-not)
1335   (once-only ((test test)
1336               (test-not test-not))
1337     `(cond
1338       ((and ,test ,test-not)
1339        (error "can't specify both :TEST and :TEST-NOT"))
1340       (,test (%coerce-callable-to-fun ,test))
1341       (,test-not
1342        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1343        ;; inefficient, but since the TEST-NOT option is deprecated
1344        ;; anyway, we don't care.)
1345        (complement (%coerce-callable-to-fun ,test-not)))
1346       (t #'eql))))
1347 (define-source-transform effective-find-position-key (key)
1348   (once-only ((key key))
1349     `(if ,key
1350          (%coerce-callable-to-fun ,key)
1351          #'identity)))
1352
1353 (macrolet ((define-find-position (fun-name values-index)
1354              `(deftransform ,fun-name ((item sequence &key
1355                                              from-end (start 0) end
1356                                              key test test-not)
1357                                        (t (or list vector) &rest t))
1358                 '(nth-value ,values-index
1359                             (%find-position item sequence
1360                                             from-end start
1361                                             end
1362                                             (effective-find-position-key key)
1363                                             (effective-find-position-test
1364                                              test test-not))))))
1365   (define-find-position find 0)
1366   (define-find-position position 1))
1367
1368 (macrolet ((define-find-position-if (fun-name values-index)
1369              `(deftransform ,fun-name ((predicate sequence &key
1370                                                   from-end (start 0)
1371                                                   end key)
1372                                        (t (or list vector) &rest t))
1373                 '(nth-value
1374                   ,values-index
1375                   (%find-position-if (%coerce-callable-to-fun predicate)
1376                                      sequence from-end
1377                                      start end
1378                                      (effective-find-position-key key))))))
1379   (define-find-position-if find-if 0)
1380   (define-find-position-if position-if 1))
1381
1382 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1383 ;;; didn't bother to worry about optimizing them, except note that on
1384 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1385 ;;; sbcl-devel
1386 ;;;
1387 ;;;     My understanding is that while the :test-not argument is
1388 ;;;     deprecated in favour of :test (complement #'foo) because of
1389 ;;;     semantic difficulties (what happens if both :test and :test-not
1390 ;;;     are supplied, etc) the -if-not variants, while officially
1391 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1392 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1393 ;;;     reasons for allowing the -if-not versions equal status,
1394 ;;;     particularly remove-if-not (== filter).
1395 ;;;
1396 ;;;     This is only an informal understanding, I grant you, but
1397 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1398 ;;;     way as the others?
1399 ;;;
1400 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1401 ;;; implementation of SBCL.
1402 (macrolet ((define-find-position-if-not (fun-name values-index)
1403                `(deftransform ,fun-name ((predicate sequence &key
1404                                           from-end (start 0)
1405                                           end key)
1406                                          (t (or list vector) &rest t))
1407                  '(nth-value
1408                    ,values-index
1409                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1410                     sequence from-end
1411                     start end
1412                     (effective-find-position-key key))))))
1413   (define-find-position-if-not find-if-not 0)
1414   (define-find-position-if-not position-if-not 1))
1415
1416 (macrolet ((define-trimmer-transform (fun-name leftp rightp)
1417              `(deftransform ,fun-name ((char-bag string)
1418                                        (t simple-string))
1419                 (let ((find-expr
1420                        (if (constant-lvar-p char-bag)
1421                            ;; If the bag is constant, use MEMBER
1422                            ;; instead of FIND, since we have a
1423                            ;; deftransform for MEMBER that can
1424                            ;; open-code all of the comparisons when
1425                            ;; the list is constant. -- JES, 2007-12-10
1426                            `(not (member (schar string index)
1427                                          ',(coerce (lvar-value char-bag) 'list)
1428                                          :test #'char=))
1429                            '(not (find (schar string index) char-bag :test #'char=)))))
1430                   `(flet ((char-not-in-bag (index)
1431                             ,find-expr))
1432                      (let* ((end (length string))
1433                             (left-end (if ,',leftp
1434                                           (do ((index 0 (1+ index)))
1435                                               ((or (= index (the fixnum end))
1436                                                    (char-not-in-bag index))
1437                                                index)
1438                                             (declare (fixnum index)))
1439                                           0))
1440                             (right-end (if ,',rightp
1441                                            (do ((index (1- end) (1- index)))
1442                                                ((or (< index left-end)
1443                                                     (char-not-in-bag index))
1444                                                 (1+ index))
1445                                              (declare (fixnum index)))
1446                                            end)))
1447                        (if (and (eql left-end 0)
1448                                 (eql right-end (length string)))
1449                            string
1450                            (subseq string left-end right-end))))))))
1451   (define-trimmer-transform string-left-trim t nil)
1452   (define-trimmer-transform string-right-trim nil t)
1453   (define-trimmer-transform string-trim t t))
1454