src/compiler/seqtran.lisp

   1 ;;;; optimizers for list and sequence functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; mapping onto lists: the MAPFOO functions
  15
  16 (defun mapfoo-transform (fn arglists accumulate take-car)
  17   (collect ((do-clauses)
  18             (args-to-fn)
  19             (tests))
  20     (let ((n-first (gensym)))
  21       (dolist (a (if accumulate
  22                      arglists
  23                      `(,n-first ,@(rest arglists))))
  24         (let ((v (gensym)))
  25           (do-clauses `(,v ,a (cdr ,v)))
  26           (tests `(endp ,v))
  27           (args-to-fn (if take-car `(car ,v) v))))
  28
  29       (let* ((fn-sym (gensym))  ; for ONCE-ONLY-ish purposes
  30              (call `(%funcall ,fn-sym . ,(args-to-fn)))
  31              (endtest `(or ,@(tests))))
  32
  33         `(let ((,fn-sym (%coerce-callable-to-fun ,fn)))
  34            ,(ecase accumulate
  35              (:nconc
  36               (let ((temp (gensym))
  37                     (map-result (gensym)))
  38                 `(let ((,map-result (list nil)))
  39                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  40                      (,endtest (cdr ,map-result))
  41                      (setq ,temp (last (nconc ,temp ,call)))))))
  42              (:list
  43               (let ((temp (gensym))
  44                     (map-result (gensym)))
  45                 `(let ((,map-result (list nil)))
  46                    (do-anonymous ((,temp ,map-result) . ,(do-clauses))
  47                      (,endtest (truly-the list (cdr ,map-result)))
  48                      (rplacd ,temp (setq ,temp (list ,call)))))))
  49              ((nil)
  50               `(let ((,n-first ,(first arglists)))
  51                  (do-anonymous ,(do-clauses)
  52                    (,endtest (truly-the list ,n-first))
  53                    ,call)))))))))
  54
  55 (define-source-transform mapc (function list &rest more-lists)
  56   (mapfoo-transform function (cons list more-lists) nil t))
  57
  58 (define-source-transform mapcar (function list &rest more-lists)
  59   (mapfoo-transform function (cons list more-lists) :list t))
  60
  61 (define-source-transform mapcan (function list &rest more-lists)
  62   (mapfoo-transform function (cons list more-lists) :nconc t))
  63
  64 (define-source-transform mapl (function list &rest more-lists)
  65   (mapfoo-transform function (cons list more-lists) nil nil))
  66
  67 (define-source-transform maplist (function list &rest more-lists)
  68   (mapfoo-transform function (cons list more-lists) :list nil))
  69
  70 (define-source-transform mapcon (function list &rest more-lists)
  71   (mapfoo-transform function (cons list more-lists) :nconc nil))
  72 \f
  73 ;;;; mapping onto sequences: the MAP function
  74
  75 ;;; MAP is %MAP plus a check to make sure that any length specified in
  76 ;;; the result type matches the actual result. We also wrap it in a
  77 ;;; TRULY-THE for the most specific type we can determine.
  78 (deftransform map ((result-type-arg fun seq &rest seqs) * * :node node)
  79   (let* ((seq-names (make-gensym-list (1+ (length seqs))))
  80          (bare `(%map result-type-arg fun ,@seq-names))
  81          (constant-result-type-arg-p (constant-lvar-p result-type-arg))
  82          ;; what we know about the type of the result. (Note that the
  83          ;; "result type" argument is not necessarily the type of the
  84          ;; result, since NIL means the result has NULL type.)
  85          (result-type (if (not constant-result-type-arg-p)
  86                           'consed-sequence
  87                           (let ((result-type-arg-value
  88                                  (lvar-value result-type-arg)))
  89                             (if (null result-type-arg-value)
  90                                 'null
  91                                 result-type-arg-value)))))
  92     `(lambda (result-type-arg fun ,@seq-names)
  93        (truly-the ,result-type
  94          ,(cond ((policy node (< safety 3))
  95                  ;; ANSI requires the length-related type check only
  96                  ;; when the SAFETY quality is 3... in other cases, we
  97                  ;; skip it, because it could be expensive.
  98                  bare)
  99                 ((not constant-result-type-arg-p)
 100                  `(sequence-of-checked-length-given-type ,bare
 101                                                          result-type-arg))
 102                 (t
 103                  (let ((result-ctype (ir1-transform-specifier-type
 104                                       result-type)))
 105                    (if (array-type-p result-ctype)
 106                        (let ((dims (array-type-dimensions result-ctype)))
 107                          (unless (and (listp dims) (= (length dims) 1))
 108                            (give-up-ir1-transform "invalid sequence type"))
 109                          (let ((dim (first dims)))
 110                            (if (eq dim '*)
 111                                bare
 112                                `(vector-of-checked-length-given-length ,bare
 113                                                                        ,dim))))
 114                        ;; FIXME: this is wrong, as not all subtypes of
 115                        ;; VECTOR are ARRAY-TYPEs [consider, for
 116                        ;; example, (OR (VECTOR T 3) (VECTOR T
 117                        ;; 4))]. However, it's difficult to see what we
 118                        ;; should put here... maybe we should
 119                        ;; GIVE-UP-IR1-TRANSFORM if the type is a
 120                        ;; subtype of VECTOR but not an ARRAY-TYPE?
 121                        bare))))))))
 122
 123 ;;; Return a DO loop, mapping a function FUN to elements of
 124 ;;; sequences. SEQS is a list of lvars, SEQ-NAMES - list of variables,
 125 ;;; bound to sequences, INTO - a variable, which is used in
 126 ;;; MAP-INTO. RESULT and BODY are forms, which can use variables
 127 ;;; FUNCALL-RESULT, containing the result of application of FUN, and
 128 ;;; INDEX, containing the current position in sequences.
 129 (defun build-sequence-iterator (seqs seq-names &key result into body)
 130   (declare (type list seqs seq-names)
 131            (type symbol into))
 132   (collect ((bindings)
 133             (declarations)
 134             (vector-lengths)
 135             (tests)
 136             (places))
 137     (let ((found-vector-p nil))
 138       (flet ((process-vector (length)
 139                (unless found-vector-p
 140                  (setq found-vector-p t)
 141                  (bindings `(index 0 (1+ index)))
 142                  (declarations `(type index index)))
 143                (vector-lengths length)))
 144         (loop for seq of-type lvar in seqs
 145            for seq-name in seq-names
 146            for type = (lvar-type seq)
 147            do (cond ((csubtypep type (specifier-type 'list))
 148                      (with-unique-names (index)
 149                        (bindings `(,index ,seq-name (cdr ,index)))
 150                        (declarations `(type list ,index))
 151                        (places `(car ,index))
 152                        (tests `(endp ,index))))
 153                     ((csubtypep type (specifier-type 'vector))
 154                      (process-vector `(length ,seq-name))
 155                      (places `(locally (declare (optimize (insert-array-bounds-checks 0)))
 156                                 (aref ,seq-name index))))
 157                     (t
 158                      (give-up-ir1-transform
 159                       "can't determine sequence argument type"))))
 160         (when into
 161           (process-vector `(array-dimension ,into 0))))
 162       (when found-vector-p
 163         (bindings `(length (min ,@(vector-lengths))))
 164         (tests `(>= index length)))
 165       `(do (,@(bindings))
 166            ((or ,@(tests)) ,result)
 167          (declare ,@(declarations))
 168          (let ((funcall-result (funcall fun ,@(places))))
 169            (declare (ignorable funcall-result))
 170            ,body)))))
 171
 172 ;;; Try to compile %MAP efficiently when we can determine sequence
 173 ;;; argument types at compile time.
 174 ;;;
 175 ;;; Note: This transform was written to allow open coding of
 176 ;;; quantifiers by expressing them in terms of (MAP NIL ..). For
 177 ;;; non-NIL values of RESULT-TYPE, it's still useful, but not
 178 ;;; necessarily as efficient as possible. In particular, it will be
 179 ;;; inefficient when RESULT-TYPE is a SIMPLE-ARRAY with specialized
 180 ;;; numeric element types. It should be straightforward to make it
 181 ;;; handle that case more efficiently, but it's left as an exercise to
 182 ;;; the reader, because the code is complicated enough already and I
 183 ;;; don't happen to need that functionality right now. -- WHN 20000410
 184 (deftransform %map ((result-type fun seq &rest seqs) * *
 185                     :policy (>= speed space))
 186   "open code"
 187   (unless (constant-lvar-p result-type)
 188     (give-up-ir1-transform "RESULT-TYPE argument not constant"))
 189   (labels ( ;; 1-valued SUBTYPEP, fails unless second value of SUBTYPEP is true
 190            (fn-1subtypep (fn x y)
 191              (multiple-value-bind (subtype-p valid-p) (funcall fn x y)
 192                (if valid-p
 193                    subtype-p
 194                    (give-up-ir1-transform
 195                     "can't analyze sequence type relationship"))))
 196            (1subtypep (x y) (fn-1subtypep #'sb!xc:subtypep x y)))
 197     (let* ((result-type-value (lvar-value result-type))
 198            (result-supertype (cond ((null result-type-value) 'null)
 199                                    ((1subtypep result-type-value 'vector)
 200                                     'vector)
 201                                    ((1subtypep result-type-value 'list)
 202                                     'list)
 203                                    (t
 204                                     (give-up-ir1-transform
 205                                      "result type unsuitable")))))
 206       (cond ((and result-type-value (null seqs))
 207              ;; The consing arity-1 cases can be implemented
 208              ;; reasonably efficiently as function calls, and the cost
 209              ;; of consing should be significantly larger than
 210              ;; function call overhead, so we always compile these
 211              ;; cases as full calls regardless of speed-versus-space
 212              ;; optimization policy.
 213              (cond ((subtypep result-type-value 'list)
 214                     '(%map-to-list-arity-1 fun seq))
 215                    ( ;; (This one can be inefficient due to COERCE, but
 216                     ;; the current open-coded implementation has the
 217                     ;; same problem.)
 218                     (subtypep result-type-value 'vector)
 219                     `(coerce (%map-to-simple-vector-arity-1 fun seq)
 220                              ',result-type-value))
 221                    (t (bug "impossible (?) sequence type"))))
 222             (t
 223              (let* ((seqs (cons seq seqs))
 224                     (seq-args (make-gensym-list (length seqs))))
 225                (multiple-value-bind (push-dacc result)
 226                    (ecase result-supertype
 227                      (null (values nil nil))
 228                      (list (values `(push funcall-result acc)
 229                                    `(nreverse acc)))
 230                      (vector (values `(push funcall-result acc)
 231                                      `(coerce (nreverse acc)
 232                                               ',result-type-value))))
 233                  ;; (We use the same idiom, of returning a LAMBDA from
 234                  ;; DEFTRANSFORM, as is used in the DEFTRANSFORMs for
 235                  ;; FUNCALL and ALIEN-FUNCALL, and for the same
 236                  ;; reason: we need to get the runtime values of each
 237                  ;; of the &REST vars.)
 238                  `(lambda (result-type fun ,@seq-args)
 239                     (declare (ignore result-type))
 240                     (let ((fun (%coerce-callable-to-fun fun))
 241                           (acc nil))
 242                       (declare (type list acc))
 243                       (declare (ignorable acc))
 244                       ,(build-sequence-iterator
 245                         seqs seq-args
 246                         :result result
 247                         :body push-dacc))))))))))
 248
 249 ;;; MAP-INTO
 250 (deftransform map-into ((result fun &rest seqs)
 251                         (vector * &rest *)
 252                         *)
 253   "open code"
 254   (let ((seqs-names (mapcar (lambda (x)
 255                               (declare (ignore x))
 256                               (gensym))
 257                             seqs)))
 258     `(lambda (result fun ,@seqs-names)
 259        ,(build-sequence-iterator
 260          seqs seqs-names
 261          :result '(when (array-has-fill-pointer-p result)
 262                    (setf (fill-pointer result) index))
 263          :into 'result
 264          :body '(locally (declare (optimize (insert-array-bounds-checks 0)))
 265                  (setf (aref result index) funcall-result)))
 266        result)))
 267
 268 \f
 269 ;;; FIXME: once the confusion over doing transforms with known-complex
 270 ;;; arrays is over, we should also transform the calls to (AND (ARRAY
 271 ;;; * (*)) (NOT (SIMPLE-ARRAY * (*)))) objects.
 272 (deftransform elt ((s i) ((simple-array * (*)) *) *)
 273   '(aref s i))
 274
 275 (deftransform elt ((s i) (list *) * :policy (< safety 3))
 276   '(nth i s))
 277
 278 (deftransform %setelt ((s i v) ((simple-array * (*)) * *) *)
 279   '(%aset s i v))
 280
 281 (deftransform %setelt ((s i v) (list * *) * :policy (< safety 3))
 282   '(setf (car (nthcdr i s)) v))
 283
 284 (deftransform %check-vector-sequence-bounds ((vector start end)
 285                                              (vector * *) *
 286                                              :node node)
 287   (if (policy node (= 0 insert-array-bounds-checks))
 288       '(or end (length vector))
 289       '(let ((length (length vector)))
 290          (if (<= 0 start (or end length) length)
 291              (or end length)
 292              (sequence-bounding-indices-bad-error vector start end)))))
 293
 294 (def!type eq-comparable-type ()
 295   '(or fixnum (not number)))
 296
 297 ;;; True if EQL comparisons involving type can be simplified to EQ.
 298 (defun eq-comparable-type-p (type)
 299   (csubtypep type (specifier-type 'eq-comparable-type)))
 300
 301 (defun specialized-list-seek-function-name (function-name key-functions &optional variant)
 302   (or (find-symbol (with-output-to-string (s)
 303                      ;; Write "%NAME-FUN1-FUN2-FUN3", etc. Not only is
 304                      ;; this ever so slightly faster then FORMAT, this
 305                      ;; way we are also proof against *PRINT-CASE*
 306                      ;; frobbing and such.
 307                      (write-char #\% s)
 308                      (write-string (symbol-name function-name) s)
 309                      (dolist (f key-functions)
 310                        (write-char #\- s)
 311                        (write-string (symbol-name f) s))
 312                      (when variant
 313                        (write-char #\- s)
 314                        (write-string (symbol-name variant) s)))
 315                    (load-time-value (find-package "SB!KERNEL")))
 316       (bug "Unknown list item seek transform: name=~S, key-functions=~S variant=~S"
 317            function-name key-functions variant)))
 318
 319 (defparameter *list-open-code-limit* 128)
 320
 321 (defun transform-list-item-seek (name item list key test test-not node)
 322   (when (and test test-not)
 323     (abort-ir1-transform "Both ~S and ~S supplied to ~S." :test :test-not name))
 324   ;; If TEST is EQL, drop it.
 325   (when (and test (lvar-fun-is test '(eql)))
 326     (setf test nil))
 327   ;; Ditto for KEY IDENTITY.
 328   (when (and key (lvar-fun-is key '(identity)))
 329     (setf key nil))
 330   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 331   ;; not there at all. If it might be NIL, make up a form to that
 332   ;; ensures it is a function.
 333   (multiple-value-bind (key key-form)
 334       (when key
 335         (let ((key-type (lvar-type key))
 336               (null-type (specifier-type 'null)))
 337           (cond ((csubtypep key-type null-type)
 338                  (values nil nil))
 339                 ((csubtypep null-type key-type)
 340                  (values key '(if key
 341                                (%coerce-callable-to-fun key)
 342                                #'identity)))
 343                 (t
 344                  (values key (ensure-lvar-fun-form key 'key))))))
 345     (let* ((c-test (cond ((and test (lvar-fun-is test '(eq)))
 346                           (setf test nil)
 347                           'eq)
 348                          ((and (not test) (not test-not))
 349                           (when (eq-comparable-type-p (lvar-type item))
 350                             'eq))))
 351            (funs (delete nil (list (when key (list key 'key))
 352                                    (when test (list test 'test))
 353                                    (when test-not (list test-not 'test-not)))))
 354            (target-expr (if key '(%funcall key target) 'target))
 355            (test-expr (cond (test `(%funcall test item ,target-expr))
 356                             (test-not `(not (%funcall test-not item ,target-expr)))
 357                             (c-test `(,c-test item ,target-expr))
 358                             (t `(eql item ,target-expr)))))
 359       (labels ((open-code (tail)
 360                  (when tail
 361                    `(if (let ((this ',(car tail)))
 362                           ,(ecase name
 363                                   ((assoc rassoc)
 364                                    (let ((cxx (if (eq name 'assoc) 'car 'cdr)))
 365                                      `(and this (let ((target (,cxx this)))
 366                                                   ,test-expr))))
 367                                   (member
 368                                    `(let ((target this))
 369                                       ,test-expr))))
 370                         ',(ecase name
 371                                  ((assoc rassoc) (car tail))
 372                                  (member tail))
 373                         ,(open-code (cdr tail)))))
 374                (ensure-fun (args)
 375                  (if (eq 'key (second args))
 376                      key-form
 377                      (apply #'ensure-lvar-fun-form args))))
 378         (let* ((cp (constant-lvar-p list))
 379                (c-list (when cp (lvar-value list))))
 380           (cond ((and cp c-list (member name '(assoc rassoc member))
 381                       (policy node (>= speed space))
 382                       (not (nthcdr *list-open-code-limit* c-list)))
 383                  `(let ,(mapcar (lambda (fun) `(,(second fun) ,(ensure-fun fun))) funs)
 384                     ,(open-code c-list)))
 385                 ((and cp (not c-list))
 386                  ;; constant nil list
 387                  (if (eq name 'adjoin)
 388                      '(list item)
 389                      nil))
 390                 (t
 391                  ;; specialized out-of-line version
 392                  `(,(specialized-list-seek-function-name name (mapcar #'second funs) c-test)
 393                     item list ,@(mapcar #'ensure-fun funs)))))))))
 394
 395 (defun transform-list-pred-seek (name pred list key node)
 396   ;; If KEY is IDENTITY, drop it.
 397   (when (and key (lvar-fun-is key '(identity)))
 398     (setf key nil))
 399   ;; Key can legally be NIL, but if it's NIL for sure we pretend it's
 400   ;; not there at all. If it might be NIL, make up a form to that
 401   ;; ensures it is a function.
 402   (multiple-value-bind (key key-form)
 403       (when key
 404         (let ((key-type (lvar-type key))
 405               (null-type (specifier-type 'null)))
 406           (cond ((csubtypep key-type null-type)
 407                  (values nil nil))
 408                 ((csubtypep null-type key-type)
 409                  (values key '(if key
 410                                (%coerce-callable-to-fun key)
 411                                #'identity)))
 412                 (t
 413                  (values key (ensure-lvar-fun-form key 'key))))))
 414     (let ((test-expr `(%funcall pred ,(if key '(%funcall key target) 'target)))
 415           (pred-expr (ensure-lvar-fun-form pred 'pred)))
 416       (when (member name '(member-if-not assoc-if-not rassoc-if-not))
 417         (setf test-expr `(not ,test-expr)))
 418       (labels ((open-code (tail)
 419                  (when tail
 420                    `(if (let ((this ',(car tail)))
 421                           ,(ecase name
 422                                   ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 423                                    (let ((cxx (if (member name '(assoc-if assoc-if-not)) 'car 'cdr)))
 424                                      `(and this (let ((target (,cxx this)))
 425                                                   ,test-expr))))
 426                                   ((member-if member-if-not)
 427                                    `(let ((target this))
 428                                       ,test-expr))))
 429                         ',(ecase name
 430                                  ((assoc-if assoc-if-not rassoc-if rassoc-if-not)
 431                                   (car tail))
 432                                  ((member-if member-if-not)
 433                                   tail))
 434                         ,(open-code (cdr tail))))))
 435         (let* ((cp (constant-lvar-p list))
 436                (c-list (when cp (lvar-value list))))
 437           (cond ((and cp c-list (policy node (>= speed space))
 438                       (not (nthcdr *list-open-code-limit* c-list)))
 439                  `(let ((pred ,pred-expr)
 440                         ,@(when key `((key ,key-form))))
 441                     ,(open-code c-list)))
 442                 ((and cp (not c-list))
 443                  ;; constant nil list -- nothing to find!
 444                  nil)
 445                 (t
 446                  ;; specialized out-of-line version
 447                  `(,(specialized-list-seek-function-name name (when key '(key)))
 448                     ,pred-expr list ,@(when key (list key-form))))))))))
 449
 450 (macrolet ((def (name &optional if/if-not)
 451              (let ((basic (symbolicate "%" name))
 452                    (basic-eq (symbolicate "%" name "-EQ"))
 453                    (basic-key (symbolicate "%" name "-KEY"))
 454                    (basic-key-eq (symbolicate "%" name "-KEY-EQ")))
 455                `(progn
 456                   (deftransform ,name ((item list &key key test test-not) * * :node node)
 457                     (transform-list-item-seek ',name item list key test test-not node))
 458                   (deftransform ,basic ((item list) (eq-comparable-type t))
 459                     `(,',basic-eq item list))
 460                   (deftransform ,basic-key ((item list) (eq-comparable-type t))
 461                     `(,',basic-key-eq item list))
 462                   ,@(when if/if-not
 463                           (let ((if-name (symbolicate name "-IF"))
 464                                 (if-not-name (symbolicate name "-IF-NOT")))
 465                             `((deftransform ,if-name ((pred list &key key) * * :node node)
 466                                 (transform-list-pred-seek ',if-name pred list key node))
 467                               (deftransform ,if-not-name ((pred list &key key) * * :node node)
 468                                 (transform-list-pred-seek ',if-not-name pred list key node)))))))))
 469   (def adjoin)
 470   (def assoc  t)
 471   (def member t)
 472   (def rassoc t))
 473
 474 (deftransform memq ((item list) (t (constant-arg list)))
 475   (labels ((rec (tail)
 476              (if tail
 477                  `(if (eq item ',(car tail))
 478                       ',tail
 479                       ,(rec (cdr tail)))
 480                  nil)))
 481     (rec (lvar-value list))))
 482
 483 ;;; A similar transform used to apply to MEMBER and ASSOC, but since
 484 ;;; TRANSFORM-LIST-ITEM-SEEK now takes care of them those transform
 485 ;;; would never fire, and (%MEMBER-TEST ITEM LIST #'EQ) should be
 486 ;;; almost as fast as MEMQ.
 487 (deftransform delete ((item list &key test) (t list &rest t) *)
 488   "convert to EQ test"
 489   (let ((type (lvar-type item)))
 490     (unless (or (and test (lvar-fun-is test '(eq)))
 491                 (and (eq-comparable-type-p type)
 492                      (or (not test) (lvar-fun-is test '(eql)))))
 493       (give-up-ir1-transform)))
 494   `(delq item list))
 495
 496 (deftransform delete-if ((pred list) (t list))
 497   "open code"
 498   '(do ((x list (cdr x))
 499         (splice '()))
 500        ((endp x) list)
 501      (cond ((funcall pred (car x))
 502             (if (null splice)
 503                 (setq list (cdr x))
 504                 (rplacd splice (cdr x))))
 505            (t (setq splice x)))))
 506
 507 (deftransform fill ((seq item &key (start 0) (end nil))
 508                     (list t &key (:start t) (:end t)))
 509   '(list-fill* seq item start end))
 510
 511 (deftransform fill ((seq item &key (start 0) (end nil))
 512                     (vector t &key (:start t) (:end t))
 513                     *
 514                     :node node)
 515   (let* ((type (lvar-type seq))
 516          (element-ctype (array-type-upgraded-element-type type))
 517          (element-type (type-specifier element-ctype))
 518          (saetp (unless (eq *wild-type* element-ctype)
 519                   (find-saetp-by-ctype element-ctype))))
 520     (cond ((eq *wild-type* element-ctype)
 521            (delay-ir1-transform node :constraint)
 522            `(vector-fill* seq item start end))
 523           ((and saetp (sb!vm::valid-bit-bash-saetp-p saetp))
 524            (let* ((n-bits (sb!vm:saetp-n-bits saetp))
 525                   (basher-name (format nil "UB~D-BASH-FILL" n-bits))
 526                   (basher (or (find-symbol basher-name
 527                                            (load-time-value (find-package :sb!kernel)))
 528                               (abort-ir1-transform
 529                                "Unknown fill basher, please report to sbcl-devel: ~A"
 530                                basher-name)))
 531                   (kind (cond ((sb!vm:saetp-fixnum-p saetp) :tagged)
 532                               ((member element-type '(character base-char)) :char)
 533                               ((eq element-type 'single-float) :single-float)
 534                               #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 535                               ((eq element-type 'double-float) :double-float)
 536                               #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 537                               ((equal element-type '(complex single-float))
 538                                :complex-single-float)
 539                               (t
 540                                (aver (integer-type-p element-ctype))
 541                                :bits)))
 542                   ;; BASH-VALUE is a word that we can repeatedly smash
 543                   ;; on the array: for less-than-word sized elements it
 544                   ;; contains multiple copies of the fill item.
 545                   (bash-value
 546                    (if (constant-lvar-p item)
 547                        (let ((tmp (lvar-value item)))
 548                          (unless (ctypep tmp element-ctype)
 549                            (abort-ir1-transform "~S is not ~S" tmp element-type))
 550                          (let* ((bits
 551                                  (ldb (byte n-bits 0)
 552                                       (ecase kind
 553                                         (:tagged
 554                                          (ash tmp sb!vm:n-fixnum-tag-bits))
 555                                         (:char
 556                                          (char-code tmp))
 557                                         (:bits
 558                                          tmp)
 559                                         (:single-float
 560                                          (single-float-bits tmp))
 561                                         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 562                                         (:double-float
 563                                          (logior (ash (double-float-high-bits tmp) 32)
 564                                                  (double-float-low-bits tmp)))
 565                                         #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 566                                         (:complex-single-float
 567                                          (logior (ash (single-float-bits (imagpart tmp)) 32)
 568                                                  (ldb (byte 32 0)
 569                                                       (single-float-bits (realpart tmp))))))))
 570                                 (res bits))
 571                            (loop for i of-type sb!vm:word from n-bits by n-bits
 572                                  until (= i sb!vm:n-word-bits)
 573                                  do (setf res (ldb (byte sb!vm:n-word-bits 0)
 574                                                    (logior res (ash bits i)))))
 575                            res))
 576                        (progn
 577                          (delay-ir1-transform node :constraint)
 578                         `(let* ((bits (ldb (byte ,n-bits 0)
 579                                            ,(ecase kind
 580                                                    (:tagged
 581                                                     `(ash item ,sb!vm:n-fixnum-tag-bits))
 582                                                    (:char
 583                                                     `(char-code item))
 584                                                    (:bits
 585                                                     `item)
 586                                                    (:single-float
 587                                                     `(single-float-bits item))
 588                                                    #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 589                                                    (:double-float
 590                                                     `(logior (ash (double-float-high-bits item) 32)
 591                                                              (double-float-low-bits item)))
 592                                                    #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 593                                                    (:complex-single-float
 594                                                     `(logior (ash (single-float-bits (imagpart item)) 32)
 595                                                              (ldb (byte 32 0)
 596                                                                   (single-float-bits (realpart item))))))))
 597                                 (res bits))
 598                            (declare (type sb!vm:word res))
 599                            ,@(unless (= sb!vm:n-word-bits n-bits)
 600                                      `((loop for i of-type sb!vm:word from ,n-bits by ,n-bits
 601                                              until (= i sb!vm:n-word-bits)
 602                                              do (setf res
 603                                                       (ldb (byte ,sb!vm:n-word-bits 0)
 604                                                            (logior res (ash bits (truly-the (integer 0 ,(- sb!vm:n-word-bits n-bits)) i))))))))
 605                            res)))))
 606              (values
 607               `(with-array-data ((data seq)
 608                                  (start start)
 609                                  (end end)
 610                                  :check-fill-pointer t)
 611                  (declare (type (simple-array ,element-type 1) data))
 612                  (declare (type index start end))
 613                  (declare (optimize (safety 0) (speed 3))
 614                           (muffle-conditions compiler-note))
 615                  (,basher ,bash-value data start (- end start))
 616                  seq)
 617               `((declare (type ,element-type item))))))
 618           ((policy node (> speed space))
 619            (values
 620             `(with-array-data ((data seq)
 621                                (start start)
 622                                (end end)
 623                                :check-fill-pointer t)
 624                (declare (type (simple-array ,element-type 1) data))
 625                (declare (type index start end))
 626                ;; WITH-ARRAY-DATA did our range checks once and for all, so
 627                ;; it'd be wasteful to check again on every AREF...
 628                (declare (optimize (safety 0) (speed 3)))
 629                (do ((i start (1+ i)))
 630                    ((= i end) seq)
 631                  (declare (type index i))
 632                  (setf (aref data i) item)))
 633             ;; ... though we still need to check that the new element can fit
 634             ;; into the vector in safe code. -- CSR, 2002-07-05
 635             `((declare (type ,element-type item)))))
 636           ((csubtypep type (specifier-type 'string))
 637            '(string-fill* seq item start end))
 638           (t
 639            '(vector-fill* seq item start end)))))
 640
 641 (deftransform fill ((seq item &key (start 0) (end nil))
 642                     ((and sequence (not vector) (not list)) t &key (:start t) (:end t)))
 643   `(sb!sequence:fill seq item
 644                      :start start
 645                      :end (%check-generic-sequence-bounds seq start end)))
 646 \f
 647 ;;;; hairy sequence transforms
 648
 649 ;;; FIXME: no hairy sequence transforms in SBCL?
 650 ;;;
 651 ;;; There used to be a bunch of commented out code about here,
 652 ;;; containing the (apparent) beginning of hairy sequence transform
 653 ;;; infrastructure. People interested in implementing better sequence
 654 ;;; transforms might want to look at it for inspiration, even though
 655 ;;; the actual code is ancient CMUCL -- and hence bitrotted. The code
 656 ;;; was deleted in 1.0.7.23.
 657 \f
 658 ;;;; string operations
 659
 660 ;;; We transform the case-sensitive string predicates into a non-keyword
 661 ;;; version. This is an IR1 transform so that we don't have to worry about
 662 ;;; changing the order of evaluation.
 663 (macrolet ((def (fun pred*)
 664              `(deftransform ,fun ((string1 string2 &key (start1 0) end1
 665                                                          (start2 0) end2)
 666                                    * *)
 667                 `(,',pred* string1 string2 start1 end1 start2 end2))))
 668   (def string< string<*)
 669   (def string> string>*)
 670   (def string<= string<=*)
 671   (def string>= string>=*)
 672   (def string= string=*)
 673   (def string/= string/=*))
 674
 675 ;;; Return a form that tests the free variables STRING1 and STRING2
 676 ;;; for the ordering relationship specified by LESSP and EQUALP. The
 677 ;;; start and end are also gotten from the environment. Both strings
 678 ;;; must be SIMPLE-BASE-STRINGs.
 679 (macrolet ((def (name lessp equalp)
 680              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 681                                    (simple-base-string simple-base-string t t t t) *)
 682                 `(let* ((end1 (if (not end1) (length string1) end1))
 683                         (end2 (if (not end2) (length string2) end2))
 684                         (index (sb!impl::%sp-string-compare
 685                                 string1 start1 end1 string2 start2 end2)))
 686                   (if index
 687                       (cond ((= index end1)
 688                              ,(if ',lessp 'index nil))
 689                             ((= (+ index (- start2 start1)) end2)
 690                              ,(if ',lessp nil 'index))
 691                             ((,(if ',lessp 'char< 'char>)
 692                                (schar string1 index)
 693                                (schar string2
 694                                       (truly-the index
 695                                                  (+ index
 696                                                     (truly-the fixnum
 697                                                                (- start2
 698                                                                   start1))))))
 699                              index)
 700                             (t nil))
 701                       ,(if ',equalp 'end1 nil))))))
 702   (def string<* t nil)
 703   (def string<=* t t)
 704   (def string>* nil nil)
 705   (def string>=* nil t))
 706
 707 (macrolet ((def (name result-fun)
 708              `(deftransform ,name ((string1 string2 start1 end1 start2 end2)
 709                                    (simple-base-string simple-base-string t t t t) *)
 710                 `(,',result-fun
 711                   (sb!impl::%sp-string-compare
 712                    string1 start1 (or end1 (length string1))
 713                    string2 start2 (or end2 (length string2)))))))
 714   (def string=* not)
 715   (def string/=* identity))
 716
 717 \f
 718 ;;;; transforms for sequence functions
 719
 720 ;;; Moved here from generic/vm-tran.lisp to satisfy clisp.  Only applies
 721 ;;; to vectors based on simple arrays.
 722 (def!constant vector-data-bit-offset
 723   (* sb!vm:vector-data-offset sb!vm:n-word-bits))
 724
 725 ;;; FIXME: In the copy loops below, we code the loops in a strange
 726 ;;; fashion:
 727 ;;;
 728 ;;; (do ((i (+ src-offset length) (1- i)))
 729 ;;;     ((<= i 0) ...)
 730 ;;;   (... (aref foo (1- i)) ...))
 731 ;;;
 732 ;;; rather than the more natural (and seemingly more efficient):
 733 ;;;
 734 ;;; (do ((i (1- (+ src-offset length)) (1- i)))
 735 ;;;     ((< i 0) ...)
 736 ;;;   (... (aref foo i) ...))
 737 ;;;
 738 ;;; (more efficient because we don't have to do the index adjusting on
 739 ;;; every iteration of the loop)
 740 ;;;
 741 ;;; We do this to avoid a suboptimality in SBCL's backend.  In the
 742 ;;; latter case, the backend thinks I is a FIXNUM (which it is), but
 743 ;;; when used as an array index, the backend thinks I is a
 744 ;;; POSITIVE-FIXNUM (which it is).  However, since the backend thinks of
 745 ;;; these as distinct storage classes, it cannot coerce a move from a
 746 ;;; FIXNUM TN to a POSITIVE-FIXNUM TN.  The practical effect of this
 747 ;;; deficiency is that we have two extra moves and increased register
 748 ;;; pressure, which can lead to some spectacularly bad register
 749 ;;; allocation.  (sub-FIXME: the register allocation even with the
 750 ;;; strangely written loops is not always excellent, either...).  Doing
 751 ;;; it the first way, above, means that I is always thought of as a
 752 ;;; POSITIVE-FIXNUM and there are no issues.
 753 ;;;
 754 ;;; Besides, the *-WITH-OFFSET machinery will fold those index
 755 ;;; adjustments in the first version into the array addressing at no
 756 ;;; performance penalty!
 757
 758 ;;; This transform is critical to the performance of string streams.  If
 759 ;;; you tweak it, make sure that you compare the disassembly, if not the
 760 ;;; performance of, the functions implementing string streams
 761 ;;; (e.g. SB!IMPL::STRING-OUCH).
 762 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 763   (defun make-replace-transform (saetp sequence-type1 sequence-type2)
 764     `(deftransform replace ((seq1 seq2 &key (start1 0) (start2 0) end1 end2)
 765                             (,sequence-type1 ,sequence-type2 &rest t)
 766                             ,sequence-type1
 767                             :node node)
 768        `(let* ((len1 (length seq1))
 769                (len2 (length seq2))
 770                (end1 (or end1 len1))
 771                (end2 (or end2 len2))
 772                (replace-len (min (- end1 start1) (- end2 start2))))
 773           ,(unless (policy node (= insert-array-bounds-checks 0))
 774              `(progn
 775                 (unless (<= 0 start1 end1 len1)
 776                   (sequence-bounding-indices-bad-error seq1 start1 end1))
 777                 (unless (<= 0 start2 end2 len2)
 778                   (sequence-bounding-indices-bad-error seq2 start2 end2))))
 779           ,',(cond
 780                ((and saetp (sb!vm:valid-bit-bash-saetp-p saetp))
 781                 (let* ((n-element-bits (sb!vm:saetp-n-bits saetp))
 782                        (bash-function (intern (format nil "UB~D-BASH-COPY"
 783                                                       n-element-bits)
 784                                               (find-package "SB!KERNEL"))))
 785                   `(funcall (function ,bash-function) seq2 start2
 786                     seq1 start1 replace-len)))
 787                (t
 788                 `(if (and
 789                       ;; If the sequence types are different, SEQ1 and
 790                       ;; SEQ2 must be distinct arrays.
 791                       ,(eql sequence-type1 sequence-type2)
 792                       (eq seq1 seq2) (> start1 start2))
 793                      (do ((i (truly-the index (+ start1 replace-len -1))
 794                              (1- i))
 795                           (j (truly-the index (+ start2 replace-len -1))
 796                              (1- j)))
 797                          ((< i start1))
 798                        (declare (optimize (insert-array-bounds-checks 0)))
 799                        (setf (aref seq1 i) (aref seq2 j)))
 800                      (do ((i start1 (1+ i))
 801                           (j start2 (1+ j))
 802                           (end (+ start1 replace-len)))
 803                          ((>= i end))
 804                        (declare (optimize (insert-array-bounds-checks 0)))
 805                        (setf (aref seq1 i) (aref seq2 j))))))
 806           seq1))))
 807
 808 (macrolet
 809     ((define-replace-transforms ()
 810        (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 811              for sequence-type = `(simple-array ,(sb!vm:saetp-specifier saetp) (*))
 812              unless (= (sb!vm:saetp-typecode saetp) sb!vm::simple-array-nil-widetag)
 813              collect (make-replace-transform saetp sequence-type sequence-type)
 814              into forms
 815              finally (return `(progn ,@forms))))
 816      (define-one-transform (sequence-type1 sequence-type2)
 817        (make-replace-transform nil sequence-type1 sequence-type2)))
 818   (define-replace-transforms)
 819   #!+sb-unicode
 820   (progn
 821    (define-one-transform (simple-array base-char (*)) (simple-array character (*)))
 822    (define-one-transform (simple-array character (*)) (simple-array base-char (*)))))
 823
 824 ;;; Expand simple cases of UB<SIZE>-BASH-COPY inline.  "simple" is
 825 ;;; defined as those cases where we are doing word-aligned copies from
 826 ;;; both the source and the destination and we are copying from the same
 827 ;;; offset from both the source and the destination.  (The last
 828 ;;; condition is there so we can determine the direction to copy at
 829 ;;; compile time rather than runtime.  Remember that UB<SIZE>-BASH-COPY
 830 ;;; acts like memmove, not memcpy.)  These conditions may seem rather
 831 ;;; restrictive, but they do catch common cases, like allocating a (* 2
 832 ;;; N)-size buffer and blitting in the old N-size buffer in.
 833
 834 (defun frob-bash-transform (src src-offset
 835                             dst dst-offset
 836                             length n-elems-per-word)
 837   (declare (ignore src dst length))
 838   (let ((n-bits-per-elem (truncate sb!vm:n-word-bits n-elems-per-word)))
 839     (multiple-value-bind (src-word src-elt)
 840         (truncate (lvar-value src-offset) n-elems-per-word)
 841       (multiple-value-bind (dst-word dst-elt)
 842           (truncate (lvar-value dst-offset) n-elems-per-word)
 843         ;; Avoid non-word aligned copies.
 844         (unless (and (zerop src-elt) (zerop dst-elt))
 845           (give-up-ir1-transform))
 846         ;; Avoid copies where we would have to insert code for
 847         ;; determining the direction of copying.
 848         (unless (= src-word dst-word)
 849           (give-up-ir1-transform))
 850         ;; FIXME: The cross-compiler doesn't optimize TRUNCATE properly,
 851         ;; so we have to do its work here.
 852         `(let ((end (+ ,src-word ,(if (= n-elems-per-word 1)
 853                                       'length
 854                                       `(truncate (the index length) ,n-elems-per-word)))))
 855            (declare (type index end))
 856            ;; Handle any bits at the end.
 857            (when (logtest length (1- ,n-elems-per-word))
 858              (let* ((extra (mod length ,n-elems-per-word))
 859                     ;; FIXME: The shift amount on this ASH is
 860                     ;; *always* negative, but the backend doesn't
 861                     ;; have a NEGATIVE-FIXNUM primitive type, so we
 862                     ;; wind up with a pile of code that tests the
 863                     ;; sign of the shift count prior to shifting when
 864                     ;; all we need is a simple negate and shift
 865                     ;; right.  Yuck.
 866                     (mask (ash #.(1- (ash 1 sb!vm:n-word-bits))
 867                                (* (- extra ,n-elems-per-word)
 868                                   ,n-bits-per-elem))))
 869                (setf (sb!kernel:%vector-raw-bits dst end)
 870                      (logior
 871                       (logandc2 (sb!kernel:%vector-raw-bits dst end)
 872                                 (ash mask
 873                                      ,(ecase sb!c:*backend-byte-order*
 874                                              (:little-endian 0)
 875                                              (:big-endian `(* (- ,n-elems-per-word extra)
 876                                                               ,n-bits-per-elem)))))
 877                       (logand (sb!kernel:%vector-raw-bits src end)
 878                               (ash mask
 879                                    ,(ecase sb!c:*backend-byte-order*
 880                                            (:little-endian 0)
 881                                            (:big-endian `(* (- ,n-elems-per-word extra)
 882                                                             ,n-bits-per-elem)))))))))
 883            ;; Copy from the end to save a register.
 884            (do ((i end (1- i)))
 885                ((<= i ,src-word))
 886              (setf (sb!kernel:%vector-raw-bits dst (1- i))
 887                    (sb!kernel:%vector-raw-bits src (1- i))))
 888            (values))))))
 889
 890 #.(loop for i = 1 then (* i 2)
 891         collect `(deftransform ,(intern (format nil "UB~D-BASH-COPY" i)
 892                                         "SB!KERNEL")
 893                                                         ((src src-offset
 894                                                           dst dst-offset
 895                                                           length)
 896                                                         ((simple-unboxed-array (*))
 897                                                          (constant-arg index)
 898                                                          (simple-unboxed-array (*))
 899                                                          (constant-arg index)
 900                                                          index)
 901                                                         *)
 902                   (frob-bash-transform src src-offset
 903                                        dst dst-offset length
 904                                        ,(truncate sb!vm:n-word-bits i))) into forms
 905         until (= i sb!vm:n-word-bits)
 906         finally (return `(progn ,@forms)))
 907
 908 ;;; We expand copy loops inline in SUBSEQ and COPY-SEQ if we're copying
 909 ;;; arrays with elements of size >= the word size.  We do this because
 910 ;;; we know the arrays cannot alias (one was just consed), therefore we
 911 ;;; can determine at compile time the direction to copy, and for
 912 ;;; word-sized elements, UB<WORD-SIZE>-BASH-COPY will do a bit of
 913 ;;; needless checking to figure out what's going on.  The same
 914 ;;; considerations apply if we are copying elements larger than the word
 915 ;;; size, with the additional twist that doing it inline is likely to
 916 ;;; cons far less than calling REPLACE and letting generic code do the
 917 ;;; work.
 918 ;;;
 919 ;;; However, we do not do this for elements whose size is < than the
 920 ;;; word size because we don't want to deal with any alignment issues
 921 ;;; inline.  The UB*-BASH-COPY transforms might fix things up later
 922 ;;; anyway.
 923
 924 (defun maybe-expand-copy-loop-inline (src src-offset dst dst-offset length
 925                                       element-type)
 926   (let ((saetp (find-saetp element-type)))
 927     (aver saetp)
 928     (if (>= (sb!vm:saetp-n-bits saetp) sb!vm:n-word-bits)
 929         (expand-aref-copy-loop src src-offset dst dst-offset length)
 930         `(locally (declare (optimize (safety 0)))
 931            (replace ,dst ,src :start1 ,dst-offset :start2 ,src-offset :end1 ,length)))))
 932
 933 (defun expand-aref-copy-loop (src src-offset dst dst-offset length)
 934   (if (eql src-offset dst-offset)
 935       `(do ((i (+ ,src-offset ,length) (1- i)))
 936            ((<= i ,src-offset))
 937          (declare (optimize (insert-array-bounds-checks 0)))
 938          (setf (aref ,dst (1- i)) (aref ,src (1- i))))
 939       ;; KLUDGE: The compiler is not able to derive that (+ offset
 940       ;; length) must be a fixnum, but arrives at (unsigned-byte 29).
 941       ;; We, however, know it must be so, as by this point the bounds
 942       ;; have already been checked.
 943       `(do ((i (truly-the fixnum (+ ,src-offset ,length)) (1- i))
 944             (j (+ ,dst-offset ,length) (1- j)))
 945            ((<= i ,src-offset))
 946          (declare (optimize (insert-array-bounds-checks 0))
 947                   (type (integer 0 #.sb!xc:array-dimension-limit) j i))
 948          (setf (aref ,dst (1- j)) (aref ,src (1- i))))))
 949
 950 ;;; SUBSEQ, COPY-SEQ
 951
 952 (deftransform subseq ((seq start &optional end)
 953                       (vector t &optional t)
 954                       *
 955                       :node node)
 956   (let ((type (lvar-type seq)))
 957     (cond
 958       ((and (array-type-p type)
 959             (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 960        (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 961          `(let* ((length (length seq))
 962                  (end (or end length)))
 963             ,(unless (policy node (zerop insert-array-bounds-checks))
 964                      '(progn
 965                        (unless (<= 0 start end length)
 966                          (sequence-bounding-indices-bad-error seq start end))))
 967             (let* ((size (- end start))
 968                    (result (make-array size :element-type ',element-type)))
 969               ,(maybe-expand-copy-loop-inline 'seq (if (constant-lvar-p start)
 970                                                        (lvar-value start)
 971                                                        'start)
 972                                               'result 0 'size element-type)
 973               result))))
 974       ((csubtypep type (specifier-type 'string))
 975        '(string-subseq* seq start end))
 976       (t
 977        '(vector-subseq* seq start end)))))
 978
 979 (deftransform subseq ((seq start &optional end)
 980                       (list t &optional t))
 981   `(list-subseq* seq start end))
 982
 983 (deftransform subseq ((seq start &optional end)
 984                       ((and sequence (not vector) (not list)) t &optional t))
 985   '(sb!sequence:subseq seq start end))
 986
 987 (deftransform copy-seq ((seq) (vector))
 988   (let ((type (lvar-type seq)))
 989     (cond ((and (array-type-p type)
 990                 (csubtypep type (specifier-type '(or (simple-unboxed-array (*)) simple-vector))))
 991            (let ((element-type (type-specifier (array-type-specialized-element-type type))))
 992              `(let* ((length (length seq))
 993                      (result (make-array length :element-type ',element-type)))
 994                 ,(maybe-expand-copy-loop-inline 'seq 0 'result 0 'length element-type)
 995                 result)))
 996           ((csubtypep type (specifier-type 'string))
 997            '(string-subseq* seq 0 nil))
 998           (t
 999            '(vector-subseq* seq 0 nil)))))
1000
1001 (deftransform copy-seq ((seq) (list))
1002   '(list-copy-seq* seq))
1003
1004 (deftransform copy-seq ((seq) ((and sequence (not vector) (not list))))
1005   '(sb!sequence:copy-seq seq))
1006
1007 ;;; FIXME: it really should be possible to take advantage of the
1008 ;;; macros used in code/seq.lisp here to avoid duplication of code,
1009 ;;; and enable even funkier transformations.
1010 (deftransform search ((pattern text &key (start1 0) (start2 0) end1 end2
1011                                (test #'eql)
1012                                (key #'identity)
1013                                from-end)
1014                       (vector vector &rest t)
1015                       *
1016                       :node node
1017                       :policy (> speed (max space safety)))
1018   "open code"
1019   (let ((from-end (when (lvar-p from-end)
1020                     (unless (constant-lvar-p from-end)
1021                       (give-up-ir1-transform ":FROM-END is not constant."))
1022                     (lvar-value from-end)))
1023         (keyp (lvar-p key))
1024         (testp (lvar-p test))
1025         (check-bounds-p (policy node (plusp insert-array-bounds-checks))))
1026     `(block search
1027        (flet ((oops (vector start end)
1028                 (sequence-bounding-indices-bad-error vector start end)))
1029          (let* ((len1 (length pattern))
1030                 (len2 (length text))
1031                 (end1 (or end1 len1))
1032                 (end2 (or end2 len2))
1033                ,@(when keyp
1034                        '((key (coerce key 'function))))
1035                ,@(when testp
1036                        '((test (coerce test 'function)))))
1037           (declare (type index start1 start2 end1 end2))
1038           ,@(when check-bounds-p
1039              `((unless (<= start1 end1 len1)
1040                  (oops pattern start1 end1))
1041                (unless (<= start2 end2 len2)
1042                  (oops pattern start2 end2))))
1043           (do (,(if from-end
1044                     '(index2 (- end2 (- end1 start1)) (1- index2))
1045                     '(index2 start2 (1+ index2))))
1046               (,(if from-end
1047                     '(< index2 start2)
1048                     '(>= index2 end2))
1049                nil)
1050             ;; INDEX2 is FIXNUM, not an INDEX, as right before the loop
1051             ;; terminates is hits -1 when :FROM-END is true and :START2
1052             ;; is 0.
1053             (declare (type fixnum index2))
1054             (when (do ((index1 start1 (1+ index1))
1055                        (index2 index2 (1+ index2)))
1056                       ((>= index1 end1) t)
1057                     (declare (type index index1 index2)
1058                              (optimize (insert-array-bounds-checks 0)))
1059                     ,@(unless from-end
1060                               '((when (= index2 end2)
1061                                   (return-from search nil))))
1062                     (unless (,@(if testp
1063                                    '(funcall test)
1064                                    '(eql))
1065                                ,(if keyp
1066                                     '(funcall key (aref pattern index1))
1067                                     '(aref pattern index1))
1068                                ,(if keyp
1069                                     '(funcall key (aref text index2))
1070                                     '(aref text index2)))
1071                       (return nil)))
1072               (return index2))))))))
1073
1074
1075 ;;; Open-code CONCATENATE for strings. It would be possible to extend
1076 ;;; this transform to non-strings, but I chose to just do the case that
1077 ;;; should cover 95% of CONCATENATE performance complaints for now.
1078 ;;;   -- JES, 2007-11-17
1079 ;;;
1080 ;;; Only handle the simple result type cases. If somebody does (CONCATENATE
1081 ;;; '(STRING 6) ...) their code won't be optimized, but nobody does that in
1082 ;;; practice.
1083 ;;;
1084 ;;; Limit full open coding based on length of constant sequences. Default
1085 ;;; value is chosen so that other parts of to compiler (constraint propagation
1086 ;;; mainly) won't go nonlinear too badly. It's not an exact number -- but
1087 ;;; in the right ballpark.
1088 (defvar *concatenate-open-code-limit* 129)
1089
1090 (deftransform concatenate ((result-type &rest lvars)
1091                            ((constant-arg
1092                              (member string simple-string base-string simple-base-string))
1093                             &rest sequence)
1094                            * :node node)
1095   (let ((vars (loop for x in lvars collect (gensym)))
1096         (type (lvar-value result-type)))
1097     (if (policy node (<= speed space))
1098         ;; Out-of-line
1099         `(lambda (.dummy. ,@vars)
1100            (declare (ignore .dummy.))
1101            ,(ecase type
1102                    ((string simple-string)
1103                     `(%concatenate-to-string ,@vars))
1104                    ((base-string simple-base-string)
1105                     `(%concatenate-to-base-string ,@vars))))
1106         ;; Inline
1107         (let* ((element-type (ecase type
1108                                ((string simple-string) 'character)
1109                                ((base-string simple-base-string) 'base-char)))
1110                (lvar-values (loop for lvar in lvars
1111                                   collect (when (constant-lvar-p lvar)
1112                                             (lvar-value lvar))))
1113                (lengths
1114                 (loop for value in lvar-values
1115                       for var in vars
1116                       collect (if value
1117                                   (length value)
1118                                   `(sb!impl::string-dispatch ((simple-array * (*))
1119                                                               sequence)
1120                                        ,var
1121                                      (declare (muffle-conditions compiler-note))
1122                                      (length ,var))))))
1123           `(apply
1124             (lambda ,vars
1125               (declare (ignorable ,@vars))
1126               (declare (optimize (insert-array-bounds-checks 0)))
1127               (let* ((.length. (+ ,@lengths))
1128                      (.pos. 0)
1129                      (.string. (make-string .length. :element-type ',element-type)))
1130                 (declare (type index .length. .pos.)
1131                          (muffle-conditions compiler-note))
1132                 ,@(loop for value in lvar-values
1133                         for var in vars
1134                         collect (if (and (stringp value)
1135                                          (< (length value) *concatenate-open-code-limit*))
1136                                     ;; Fold the array reads for constant arguments
1137                                     `(progn
1138                                        ,@(loop for c across value
1139                                                for i from 0
1140                                                collect
1141                                                ;; Without truly-the we get massive numbers
1142                                                ;; of pointless error traps.
1143                                                   `(setf (aref .string.
1144                                                                (truly-the index (+ .pos. ,i)))
1145                                                          ,c))
1146                                        (incf .pos. ,(length value)))
1147                                     `(sb!impl::string-dispatch
1148                                          (#!+sb-unicode
1149                                           (simple-array character (*))
1150                                           (simple-array base-char (*))
1151                                           t)
1152                                          ,var
1153                                        (replace .string. ,var :start1 .pos.)
1154                                        (incf .pos. (length ,var)))))
1155                 .string.))
1156             lvars)))))
1157 \f
1158 ;;;; CONS accessor DERIVE-TYPE optimizers
1159
1160 (defoptimizer (car derive-type) ((cons))
1161   ;; This and CDR needs to use LVAR-CONSERVATIVE-TYPE because type inference
1162   ;; gets confused by things like (SETF CAR).
1163   (let ((type (lvar-conservative-type cons))
1164         (null-type (specifier-type 'null)))
1165     (cond ((eq type null-type)
1166            null-type)
1167           ((cons-type-p type)
1168            (cons-type-car-type type)))))
1169
1170 (defoptimizer (cdr derive-type) ((cons))
1171   (let ((type (lvar-conservative-type cons))
1172         (null-type (specifier-type 'null)))
1173     (cond ((eq type null-type)
1174            null-type)
1175           ((cons-type-p type)
1176            (cons-type-cdr-type type)))))
1177 \f
1178 ;;;; FIND, POSITION, and their -IF and -IF-NOT variants
1179
1180 ;;; We want to make sure that %FIND-POSITION is inline-expanded into
1181 ;;; %FIND-POSITION-IF only when %FIND-POSITION-IF has an inline
1182 ;;; expansion, so we factor out the condition into this function.
1183 (defun check-inlineability-of-find-position-if (sequence from-end)
1184   (let ((ctype (lvar-type sequence)))
1185     (cond ((csubtypep ctype (specifier-type 'vector))
1186            ;; It's not worth trying to inline vector code unless we
1187            ;; know a fair amount about it at compile time.
1188            (upgraded-element-type-specifier-or-give-up sequence)
1189            (unless (constant-lvar-p from-end)
1190              (give-up-ir1-transform
1191               "FROM-END argument value not known at compile time")))
1192           ((csubtypep ctype (specifier-type 'list))
1193            ;; Inlining on lists is generally worthwhile.
1194            )
1195           (t
1196            (give-up-ir1-transform
1197             "sequence type not known at compile time")))))
1198
1199 ;;; %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for LIST data
1200 (macrolet ((def (name condition)
1201              `(deftransform ,name ((predicate sequence from-end start end key)
1202                                    (function list t t t function)
1203                                    *
1204                                    :policy (> speed space))
1205                 "expand inline"
1206                 `(let ((find nil)
1207                        (position nil))
1208                    (flet ((bounds-error ()
1209                             (sequence-bounding-indices-bad-error sequence start end)))
1210                      (if (and end (> start end))
1211                          (bounds-error)
1212                          (do ((slow sequence (cdr slow))
1213                               (fast (cdr sequence) (cddr fast))
1214                               (index 0 (+ index 1)))
1215                              ((cond ((null slow)
1216                                      (if (and end (> end index))
1217                                          (bounds-error)
1218                                          (return (values find position))))
1219                                     ((and end (>= index end))
1220                                      (return (values find position)))
1221                                     ((eq slow fast)
1222                                      (circular-list-error sequence)))
1223                               (bug "never"))
1224                            (declare (list slow fast))
1225                            (when (>= index start)
1226                              (let* ((element (car slow))
1227                                     (key-i (funcall key element)))
1228                                (,',condition (funcall predicate key-i)
1229                                              ;; This hack of dealing with non-NIL
1230                                              ;; FROM-END for list data by iterating
1231                                              ;; forward through the list and keeping
1232                                              ;; track of the last time we found a
1233                                              ;; match might be more screwy than what
1234                                              ;; the user expects, but it seems to be
1235                                              ;; allowed by the ANSI standard. (And
1236                                              ;; if the user is screwy enough to ask
1237                                              ;; for FROM-END behavior on list data,
1238                                              ;; turnabout is fair play.)
1239                                              ;;
1240                                              ;; It's also not enormously efficient,
1241                                              ;; calling PREDICATE and KEY more often
1242                                              ;; than necessary; but all the
1243                                              ;; alternatives seem to have their own
1244                                              ;; efficiency problems.
1245                                              (if from-end
1246                                                  (setf find element
1247                                                        position index)
1248                                                  (return (values element index)))))))))))))
1249   (def %find-position-if when)
1250   (def %find-position-if-not unless))
1251
1252 ;;; %FIND-POSITION for LIST data can be expanded into %FIND-POSITION-IF
1253 ;;; without loss of efficiency. (I.e., the optimizer should be able
1254 ;;; to straighten everything out.)
1255 (deftransform %find-position ((item sequence from-end start end key test)
1256                               (t list t t t t t)
1257                               *
1258                               :policy (> speed space))
1259   "expand inline"
1260   '(%find-position-if (let ((test-fun (%coerce-callable-to-fun test)))
1261                         ;; The order of arguments for asymmetric tests
1262                         ;; (e.g. #'<, as opposed to order-independent
1263                         ;; tests like #'=) is specified in the spec
1264                         ;; section 17.2.1 -- the O/Zi stuff there.
1265                         (lambda (i)
1266                           (funcall test-fun item i)))
1267                       sequence
1268                       from-end
1269                       start
1270                       end
1271                       (%coerce-callable-to-fun key)))
1272
1273 ;;; The inline expansions for the VECTOR case are saved as macros so
1274 ;;; that we can share them between the DEFTRANSFORMs and the default
1275 ;;; cases in the DEFUNs. (This isn't needed for the LIST case, because
1276 ;;; the DEFTRANSFORMs for LIST are less choosy about when to expand.)
1277 (defun %find-position-or-find-position-if-vector-expansion (sequence-arg
1278                                                             from-end
1279                                                             start
1280                                                             end-arg
1281                                                             element
1282                                                             done-p-expr)
1283   (with-unique-names (offset block index n-sequence sequence end)
1284     `(let* ((,n-sequence ,sequence-arg))
1285        (with-array-data ((,sequence ,n-sequence :offset-var ,offset)
1286                          (,start ,start)
1287                          (,end ,end-arg)
1288                          :check-fill-pointer t)
1289          (block ,block
1290            (macrolet ((maybe-return ()
1291                         ;; WITH-ARRAY-DATA has already performed bounds
1292                         ;; checking, so we can safely elide the checks
1293                         ;; in the inner loop.
1294                         '(let ((,element (locally (declare (optimize (insert-array-bounds-checks 0)))
1295                                            (aref ,sequence ,index))))
1296                           (when ,done-p-expr
1297                             (return-from ,block
1298                               (values ,element
1299                                       (- ,index ,offset)))))))
1300              (if ,from-end
1301                  (loop for ,index
1302                        ;; (If we aren't fastidious about declaring that
1303                        ;; INDEX might be -1, then (FIND 1 #() :FROM-END T)
1304                        ;; can send us off into never-never land, since
1305                        ;; INDEX is initialized to -1.)
1306                        of-type index-or-minus-1
1307                        from (1- ,end) downto ,start do
1308                        (maybe-return))
1309                  (loop for ,index of-type index from ,start below ,end do
1310                           (maybe-return))))
1311            (values nil nil))))))
1312
1313 (def!macro %find-position-vector-macro (item sequence
1314                                              from-end start end key test)
1315   (with-unique-names (element)
1316     (%find-position-or-find-position-if-vector-expansion
1317      sequence
1318      from-end
1319      start
1320      end
1321      element
1322      ;; (See the LIST transform for a discussion of the correct
1323      ;; argument order, i.e. whether the searched-for ,ITEM goes before
1324      ;; or after the checked sequence element.)
1325      `(funcall ,test ,item (funcall ,key ,element)))))
1326
1327 (def!macro %find-position-if-vector-macro (predicate sequence
1328                                                      from-end start end key)
1329   (with-unique-names (element)
1330     (%find-position-or-find-position-if-vector-expansion
1331      sequence
1332      from-end
1333      start
1334      end
1335      element
1336      `(funcall ,predicate (funcall ,key ,element)))))
1337
1338 (def!macro %find-position-if-not-vector-macro (predicate sequence
1339                                                          from-end start end key)
1340   (with-unique-names (element)
1341     (%find-position-or-find-position-if-vector-expansion
1342      sequence
1343      from-end
1344      start
1345      end
1346      element
1347      `(not (funcall ,predicate (funcall ,key ,element))))))
1348
1349 ;;; %FIND-POSITION, %FIND-POSITION-IF and %FIND-POSITION-IF-NOT for
1350 ;;; VECTOR data
1351 (deftransform %find-position-if ((predicate sequence from-end start end key)
1352                                  (function vector t t t function)
1353                                  *
1354                                  :policy (> speed space))
1355   "expand inline"
1356   (check-inlineability-of-find-position-if sequence from-end)
1357   '(%find-position-if-vector-macro predicate sequence
1358                                    from-end start end key))
1359
1360 (deftransform %find-position-if-not ((predicate sequence from-end start end key)
1361                                      (function vector t t t function)
1362                                      *
1363                                      :policy (> speed space))
1364   "expand inline"
1365   (check-inlineability-of-find-position-if sequence from-end)
1366   '(%find-position-if-not-vector-macro predicate sequence
1367                                        from-end start end key))
1368
1369 (deftransform %find-position ((item sequence from-end start end key test)
1370                               (t vector t t t function function)
1371                               *
1372                               :policy (> speed space))
1373   "expand inline"
1374   (check-inlineability-of-find-position-if sequence from-end)
1375   '(%find-position-vector-macro item sequence
1376     from-end start end key test))
1377
1378 (deftransform %find-position ((item sequence from-end start end key test)
1379                               (character string t t t function function)
1380                               *
1381                               :policy (> speed space))
1382   (if (eq '* (upgraded-element-type-specifier sequence))
1383       (let ((form
1384              `(sb!impl::string-dispatch ((simple-array character (*))
1385                                          (simple-array base-char (*))
1386                                          (simple-array nil (*)))
1387                   sequence
1388                 (%find-position item sequence from-end start end key test))))
1389         (if (csubtypep (lvar-type sequence) (specifier-type 'simple-string))
1390             form
1391             ;; Otherwise we'd get three instances of WITH-ARRAY-DATA from
1392             ;; %FIND-POSITION.
1393             `(with-array-data ((sequence sequence :offset-var offset)
1394                                (start start)
1395                                (end end)
1396                                :check-fill-pointer t)
1397                (multiple-value-bind (elt index) ,form
1398                  (values elt (when (fixnump index) (- index offset)))))))
1399       ;; The type is known exactly, other transforms will take care of it.
1400       (give-up-ir1-transform)))
1401
1402 ;;; logic to unravel :TEST, :TEST-NOT, and :KEY options in FIND,
1403 ;;; POSITION-IF, etc.
1404 (define-source-transform effective-find-position-test (test test-not)
1405   (once-only ((test test)
1406               (test-not test-not))
1407     `(cond
1408       ((and ,test ,test-not)
1409        (error "can't specify both :TEST and :TEST-NOT"))
1410       (,test (%coerce-callable-to-fun ,test))
1411       (,test-not
1412        ;; (Without DYNAMIC-EXTENT, this is potentially horribly
1413        ;; inefficient, but since the TEST-NOT option is deprecated
1414        ;; anyway, we don't care.)
1415        (complement (%coerce-callable-to-fun ,test-not)))
1416       (t #'eql))))
1417 (define-source-transform effective-find-position-key (key)
1418   (once-only ((key key))
1419     `(if ,key
1420          (%coerce-callable-to-fun ,key)
1421          #'identity)))
1422
1423 (macrolet ((define-find-position (fun-name values-index)
1424              `(deftransform ,fun-name ((item sequence &key
1425                                              from-end (start 0) end
1426                                              key test test-not)
1427                                        (t (or list vector) &rest t))
1428                 '(nth-value ,values-index
1429                             (%find-position item sequence
1430                                             from-end start
1431                                             end
1432                                             (effective-find-position-key key)
1433                                             (effective-find-position-test
1434                                              test test-not))))))
1435   (define-find-position find 0)
1436   (define-find-position position 1))
1437
1438 (macrolet ((define-find-position-if (fun-name values-index)
1439              `(deftransform ,fun-name ((predicate sequence &key
1440                                                   from-end (start 0)
1441                                                   end key)
1442                                        (t (or list vector) &rest t))
1443                 '(nth-value
1444                   ,values-index
1445                   (%find-position-if (%coerce-callable-to-fun predicate)
1446                                      sequence from-end
1447                                      start end
1448                                      (effective-find-position-key key))))))
1449   (define-find-position-if find-if 0)
1450   (define-find-position-if position-if 1))
1451
1452 ;;; the deprecated functions FIND-IF-NOT and POSITION-IF-NOT. We
1453 ;;; didn't bother to worry about optimizing them, except note that on
1454 ;;; Sat, Oct 06, 2001 at 04:22:38PM +0100, Christophe Rhodes wrote on
1455 ;;; sbcl-devel
1456 ;;;
1457 ;;;     My understanding is that while the :test-not argument is
1458 ;;;     deprecated in favour of :test (complement #'foo) because of
1459 ;;;     semantic difficulties (what happens if both :test and :test-not
1460 ;;;     are supplied, etc) the -if-not variants, while officially
1461 ;;;     deprecated, would be undeprecated were X3J13 actually to produce
1462 ;;;     a revised standard, as there are perfectly legitimate idiomatic
1463 ;;;     reasons for allowing the -if-not versions equal status,
1464 ;;;     particularly remove-if-not (== filter).
1465 ;;;
1466 ;;;     This is only an informal understanding, I grant you, but
1467 ;;;     perhaps it's worth optimizing the -if-not versions in the same
1468 ;;;     way as the others?
1469 ;;;
1470 ;;; FIXME: Maybe remove uses of these deprecated functions within the
1471 ;;; implementation of SBCL.
1472 (macrolet ((define-find-position-if-not (fun-name values-index)
1473                `(deftransform ,fun-name ((predicate sequence &key
1474                                           from-end (start 0)
1475                                           end key)
1476                                          (t (or list vector) &rest t))
1477                  '(nth-value
1478                    ,values-index
1479                    (%find-position-if-not (%coerce-callable-to-fun predicate)
1480                     sequence from-end
1481                     start end
1482                     (effective-find-position-key key))))))
1483   (define-find-position-if-not find-if-not 0)
1484   (define-find-position-if-not position-if-not 1))
1485
1486 (macrolet ((define-trimmer-transform (fun-name leftp rightp)
1487              `(deftransform ,fun-name ((char-bag string)
1488                                        (t simple-string))
1489                 (let ((find-expr
1490                        (if (constant-lvar-p char-bag)
1491                            ;; If the bag is constant, use MEMBER
1492                            ;; instead of FIND, since we have a
1493                            ;; deftransform for MEMBER that can
1494                            ;; open-code all of the comparisons when
1495                            ;; the list is constant. -- JES, 2007-12-10
1496                            `(not (member (schar string index)
1497                                          ',(coerce (lvar-value char-bag) 'list)
1498                                          :test #'char=))
1499                            '(not (find (schar string index) char-bag :test #'char=)))))
1500                   `(flet ((char-not-in-bag (index)
1501                             ,find-expr))
1502                      (let* ((end (length string))
1503                             (left-end (if ,',leftp
1504                                           (do ((index 0 (1+ index)))
1505                                               ((or (= index (the fixnum end))
1506                                                    (char-not-in-bag index))
1507                                                index)
1508                                             (declare (fixnum index)))
1509                                           0))
1510                             (right-end (if ,',rightp
1511                                            (do ((index (1- end) (1- index)))
1512                                                ((or (< index left-end)
1513                                                     (char-not-in-bag index))
1514                                                 (1+ index))
1515                                              (declare (fixnum index)))
1516                                            end)))
1517                        (if (and (eql left-end 0)
1518                                 (eql right-end (length string)))
1519                            string
1520                            (subseq string left-end right-end))))))))
1521   (define-trimmer-transform string-left-trim t nil)
1522   (define-trimmer-transform string-right-trim nil t)
1523   (define-trimmer-transform string-trim t t))
1524