src/compiler/srctran.lisp

   1 ;;;; This file contains macro-like source transformations which
   2 ;;;; convert uses of certain functions into the canonical form desired
   3 ;;;; within the compiler. FIXME: and other IR1 transforms and stuff.
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15
  16 ;;; Convert into an IF so that IF optimizations will eliminate redundant
  17 ;;; negations.
  18 (define-source-transform not (x) `(if ,x nil t))
  19 (define-source-transform null (x) `(if ,x nil t))
  20
  21 ;;; ENDP is just NULL with a LIST assertion. The assertion will be
  22 ;;; optimized away when SAFETY optimization is low; hopefully that
  23 ;;; is consistent with ANSI's "should return an error".
  24 (define-source-transform endp (x) `(null (the list ,x)))
  25
  26 ;;; We turn IDENTITY into PROG1 so that it is obvious that it just
  27 ;;; returns the first value of its argument. Ditto for VALUES with one
  28 ;;; arg.
  29 (define-source-transform identity (x) `(prog1 ,x))
  30 (define-source-transform values (x) `(prog1 ,x))
  31
  32 ;;; Bind the value and make a closure that returns it.
  33 (define-source-transform constantly (value)
  34   (with-unique-names (rest n-value)
  35     `(let ((,n-value ,value))
  36       (lambda (&rest ,rest)
  37         (declare (ignore ,rest))
  38         ,n-value))))
  39
  40 ;;; If the function has a known number of arguments, then return a
  41 ;;; lambda with the appropriate fixed number of args. If the
  42 ;;; destination is a FUNCALL, then do the &REST APPLY thing, and let
  43 ;;; MV optimization figure things out.
  44 (deftransform complement ((fun) * * :node node)
  45   "open code"
  46   (multiple-value-bind (min max)
  47       (fun-type-nargs (continuation-type fun))
  48     (cond
  49      ((and min (eql min max))
  50       (let ((dums (make-gensym-list min)))
  51         `#'(lambda ,dums (not (funcall fun ,@dums)))))
  52      ((let* ((cont (node-cont node))
  53              (dest (continuation-dest cont)))
  54         (and (combination-p dest)
  55              (eq (combination-fun dest) cont)))
  56       '#'(lambda (&rest args)
  57            (not (apply fun args))))
  58      (t
  59       (give-up-ir1-transform
  60        "The function doesn't have a fixed argument count.")))))
  61 \f
  62 ;;;; list hackery
  63
  64 ;;; Translate CxR into CAR/CDR combos.
  65 (defun source-transform-cxr (form)
  66   (if (/= (length form) 2)
  67       (values nil t)
  68       (let ((name (symbol-name (car form))))
  69         (do ((i (- (length name) 2) (1- i))
  70              (res (cadr form)
  71                   `(,(ecase (char name i)
  72                        (#\A 'car)
  73                        (#\D 'cdr))
  74                     ,res)))
  75             ((zerop i) res)))))
  76
  77 ;;; Make source transforms to turn CxR forms into combinations of CAR
  78 ;;; and CDR. ANSI specifies that everything up to 4 A/D operations is
  79 ;;; defined.
  80 (/show0 "about to set CxR source transforms")
  81 (loop for i of-type index from 2 upto 4 do
  82       ;; Iterate over BUF = all names CxR where x = an I-element
  83       ;; string of #\A or #\D characters.
  84       (let ((buf (make-string (+ 2 i))))
  85         (setf (aref buf 0) #\C
  86               (aref buf (1+ i)) #\R)
  87         (dotimes (j (ash 2 i))
  88           (declare (type index j))
  89           (dotimes (k i)
  90             (declare (type index k))
  91             (setf (aref buf (1+ k))
  92                   (if (logbitp k j) #\A #\D)))
  93           (setf (info :function :source-transform (intern buf))
  94                 #'source-transform-cxr))))
  95 (/show0 "done setting CxR source transforms")
  96
  97 ;;; Turn FIRST..FOURTH and REST into the obvious synonym, assuming
  98 ;;; whatever is right for them is right for us. FIFTH..TENTH turn into
  99 ;;; Nth, which can be expanded into a CAR/CDR later on if policy
 100 ;;; favors it.
 101 (define-source-transform first (x) `(car ,x))
 102 (define-source-transform rest (x) `(cdr ,x))
 103 (define-source-transform second (x) `(cadr ,x))
 104 (define-source-transform third (x) `(caddr ,x))
 105 (define-source-transform fourth (x) `(cadddr ,x))
 106 (define-source-transform fifth (x) `(nth 4 ,x))
 107 (define-source-transform sixth (x) `(nth 5 ,x))
 108 (define-source-transform seventh (x) `(nth 6 ,x))
 109 (define-source-transform eighth (x) `(nth 7 ,x))
 110 (define-source-transform ninth (x) `(nth 8 ,x))
 111 (define-source-transform tenth (x) `(nth 9 ,x))
 112
 113 ;;; Translate RPLACx to LET and SETF.
 114 (define-source-transform rplaca (x y)
 115   (once-only ((n-x x))
 116     `(progn
 117        (setf (car ,n-x) ,y)
 118        ,n-x)))
 119 (define-source-transform rplacd (x y)
 120   (once-only ((n-x x))
 121     `(progn
 122        (setf (cdr ,n-x) ,y)
 123        ,n-x)))
 124
 125 (define-source-transform nth (n l) `(car (nthcdr ,n ,l)))
 126
 127 (defvar *default-nthcdr-open-code-limit* 6)
 128 (defvar *extreme-nthcdr-open-code-limit* 20)
 129
 130 (deftransform nthcdr ((n l) (unsigned-byte t) * :node node)
 131   "convert NTHCDR to CAxxR"
 132   (unless (constant-continuation-p n)
 133     (give-up-ir1-transform))
 134   (let ((n (continuation-value n)))
 135     (when (> n
 136              (if (policy node (and (= speed 3) (= space 0)))
 137                  *extreme-nthcdr-open-code-limit*
 138                  *default-nthcdr-open-code-limit*))
 139       (give-up-ir1-transform))
 140
 141     (labels ((frob (n)
 142                (if (zerop n)
 143                    'l
 144                    `(cdr ,(frob (1- n))))))
 145       (frob n))))
 146 \f
 147 ;;;; arithmetic and numerology
 148
 149 (define-source-transform plusp (x) `(> ,x 0))
 150 (define-source-transform minusp (x) `(< ,x 0))
 151 (define-source-transform zerop (x) `(= ,x 0))
 152
 153 (define-source-transform 1+ (x) `(+ ,x 1))
 154 (define-source-transform 1- (x) `(- ,x 1))
 155
 156 (define-source-transform oddp (x) `(not (zerop (logand ,x 1))))
 157 (define-source-transform evenp (x) `(zerop (logand ,x 1)))
 158
 159 ;;; Note that all the integer division functions are available for
 160 ;;; inline expansion.
 161
 162 (macrolet ((deffrob (fun)
 163              `(define-source-transform ,fun (x &optional (y nil y-p))
 164                 (declare (ignore y))
 165                 (if y-p
 166                     (values nil t)
 167                     `(,',fun ,x 1)))))
 168   (deffrob truncate)
 169   (deffrob round)
 170   #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
 171   (deffrob floor)
 172   #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
 173   (deffrob ceiling))
 174
 175 (define-source-transform lognand (x y) `(lognot (logand ,x ,y)))
 176 (define-source-transform lognor (x y) `(lognot (logior ,x ,y)))
 177 (define-source-transform logandc1 (x y) `(logand (lognot ,x) ,y))
 178 (define-source-transform logandc2 (x y) `(logand ,x (lognot ,y)))
 179 (define-source-transform logorc1 (x y) `(logior (lognot ,x) ,y))
 180 (define-source-transform logorc2 (x y) `(logior ,x (lognot ,y)))
 181 (define-source-transform logtest (x y) `(not (zerop (logand ,x ,y))))
 182 (define-source-transform logbitp (index integer)
 183   `(not (zerop (logand (ash 1 ,index) ,integer))))
 184 (define-source-transform byte (size position)
 185   `(cons ,size ,position))
 186 (define-source-transform byte-size (spec) `(car ,spec))
 187 (define-source-transform byte-position (spec) `(cdr ,spec))
 188 (define-source-transform ldb-test (bytespec integer)
 189   `(not (zerop (mask-field ,bytespec ,integer))))
 190
 191 ;;; With the ratio and complex accessors, we pick off the "identity"
 192 ;;; case, and use a primitive to handle the cell access case.
 193 (define-source-transform numerator (num)
 194   (once-only ((n-num `(the rational ,num)))
 195     `(if (ratiop ,n-num)
 196          (%numerator ,n-num)
 197          ,n-num)))
 198 (define-source-transform denominator (num)
 199   (once-only ((n-num `(the rational ,num)))
 200     `(if (ratiop ,n-num)
 201          (%denominator ,n-num)
 202          1)))
 203 \f
 204 ;;;; interval arithmetic for computing bounds
 205 ;;;;
 206 ;;;; This is a set of routines for operating on intervals. It
 207 ;;;; implements a simple interval arithmetic package. Although SBCL
 208 ;;;; has an interval type in NUMERIC-TYPE, we choose to use our own
 209 ;;;; for two reasons:
 210 ;;;;
 211 ;;;;   1. This package is simpler than NUMERIC-TYPE.
 212 ;;;;
 213 ;;;;   2. It makes debugging much easier because you can just strip
 214 ;;;;   out these routines and test them independently of SBCL. (This is a
 215 ;;;;   big win!)
 216 ;;;;
 217 ;;;; One disadvantage is a probable increase in consing because we
 218 ;;;; have to create these new interval structures even though
 219 ;;;; numeric-type has everything we want to know. Reason 2 wins for
 220 ;;;; now.
 221
 222 ;;; The basic interval type. It can handle open and closed intervals.
 223 ;;; A bound is open if it is a list containing a number, just like
 224 ;;; Lisp says. NIL means unbounded.
 225 (defstruct (interval (:constructor %make-interval)
 226                      (:copier nil))
 227   low high)
 228
 229 (defun make-interval (&key low high)
 230   (labels ((normalize-bound (val)
 231              (cond ((and (floatp val)
 232                          (float-infinity-p val))
 233                     ;; Handle infinities.
 234                     nil)
 235                    ((or (numberp val)
 236                         (eq val nil))
 237                     ;; Handle any closed bounds.
 238                     val)
 239                    ((listp val)
 240                     ;; We have an open bound. Normalize the numeric
 241                     ;; bound. If the normalized bound is still a number
 242                     ;; (not nil), keep the bound open. Otherwise, the
 243                     ;; bound is really unbounded, so drop the openness.
 244                     (let ((new-val (normalize-bound (first val))))
 245                       (when new-val
 246                         ;; The bound exists, so keep it open still.
 247                         (list new-val))))
 248                    (t
 249                     (error "unknown bound type in MAKE-INTERVAL")))))
 250     (%make-interval :low (normalize-bound low)
 251                     :high (normalize-bound high))))
 252
 253 ;;; Given a number X, create a form suitable as a bound for an
 254 ;;; interval. Make the bound open if OPEN-P is T. NIL remains NIL.
 255 #!-sb-fluid (declaim (inline set-bound))
 256 (defun set-bound (x open-p)
 257   (if (and x open-p) (list x) x))
 258
 259 ;;; Apply the function F to a bound X. If X is an open bound, then
 260 ;;; the result will be open. IF X is NIL, the result is NIL.
 261 (defun bound-func (f x)
 262   (declare (type function f))
 263   (and x
 264        (with-float-traps-masked (:underflow :overflow :inexact :divide-by-zero)
 265          ;; With these traps masked, we might get things like infinity
 266          ;; or negative infinity returned. Check for this and return
 267          ;; NIL to indicate unbounded.
 268          (let ((y (funcall f (type-bound-number x))))
 269            (if (and (floatp y)
 270                     (float-infinity-p y))
 271                nil
 272                (set-bound (funcall f (type-bound-number x)) (consp x)))))))
 273
 274 ;;; Apply a binary operator OP to two bounds X and Y. The result is
 275 ;;; NIL if either is NIL. Otherwise bound is computed and the result
 276 ;;; is open if either X or Y is open.
 277 ;;;
 278 ;;; FIXME: only used in this file, not needed in target runtime
 279 (defmacro bound-binop (op x y)
 280   `(and ,x ,y
 281        (with-float-traps-masked (:underflow :overflow :inexact :divide-by-zero)
 282          (set-bound (,op (type-bound-number ,x)
 283                          (type-bound-number ,y))
 284                     (or (consp ,x) (consp ,y))))))
 285
 286 ;;; Convert a numeric-type object to an interval object.
 287 (defun numeric-type->interval (x)
 288   (declare (type numeric-type x))
 289   (make-interval :low (numeric-type-low x)
 290                  :high (numeric-type-high x)))
 291
 292 (defun copy-interval-limit (limit)
 293   (if (numberp limit)
 294       limit
 295       (copy-list limit)))
 296
 297 (defun copy-interval (x)
 298   (declare (type interval x))
 299   (make-interval :low (copy-interval-limit (interval-low x))
 300                  :high (copy-interval-limit (interval-high x))))
 301
 302 ;;; Given a point P contained in the interval X, split X into two
 303 ;;; interval at the point P. If CLOSE-LOWER is T, then the left
 304 ;;; interval contains P. If CLOSE-UPPER is T, the right interval
 305 ;;; contains P. You can specify both to be T or NIL.
 306 (defun interval-split (p x &optional close-lower close-upper)
 307   (declare (type number p)
 308            (type interval x))
 309   (list (make-interval :low (copy-interval-limit (interval-low x))
 310                        :high (if close-lower p (list p)))
 311         (make-interval :low (if close-upper (list p) p)
 312                        :high (copy-interval-limit (interval-high x)))))
 313
 314 ;;; Return the closure of the interval. That is, convert open bounds
 315 ;;; to closed bounds.
 316 (defun interval-closure (x)
 317   (declare (type interval x))
 318   (make-interval :low (type-bound-number (interval-low x))
 319                  :high (type-bound-number (interval-high x))))
 320
 321 (defun signed-zero->= (x y)
 322   (declare (real x y))
 323   (or (> x y)
 324       (and (= x y)
 325            (>= (float-sign (float x))
 326                (float-sign (float y))))))
 327
 328 ;;; For an interval X, if X >= POINT, return '+. If X <= POINT, return
 329 ;;; '-. Otherwise return NIL.
 330 #+nil
 331 (defun interval-range-info (x &optional (point 0))
 332   (declare (type interval x))
 333   (let ((lo (interval-low x))
 334         (hi (interval-high x)))
 335     (cond ((and lo (signed-zero->= (type-bound-number lo) point))
 336            '+)
 337           ((and hi (signed-zero->= point (type-bound-number hi)))
 338            '-)
 339           (t
 340            nil))))
 341 (defun interval-range-info (x &optional (point 0))
 342   (declare (type interval x))
 343   (labels ((signed->= (x y)
 344              (if (and (zerop x) (zerop y) (floatp x) (floatp y))
 345                  (>= (float-sign x) (float-sign y))
 346                  (>= x y))))
 347     (let ((lo (interval-low x))
 348           (hi (interval-high x)))
 349       (cond ((and lo (signed->= (type-bound-number lo) point))
 350              '+)
 351             ((and hi (signed->= point (type-bound-number hi)))
 352              '-)
 353             (t
 354              nil)))))
 355
 356 ;;; Test to see whether the interval X is bounded. HOW determines the
 357 ;;; test, and should be either ABOVE, BELOW, or BOTH.
 358 (defun interval-bounded-p (x how)
 359   (declare (type interval x))
 360   (ecase how
 361     (above
 362      (interval-high x))
 363     (below
 364      (interval-low x))
 365     (both
 366      (and (interval-low x) (interval-high x)))))
 367
 368 ;;; signed zero comparison functions. Use these functions if we need
 369 ;;; to distinguish between signed zeroes.
 370 (defun signed-zero-< (x y)
 371   (declare (real x y))
 372   (or (< x y)
 373       (and (= x y)
 374            (< (float-sign (float x))
 375               (float-sign (float y))))))
 376 (defun signed-zero-> (x y)
 377   (declare (real x y))
 378   (or (> x y)
 379       (and (= x y)
 380            (> (float-sign (float x))
 381               (float-sign (float y))))))
 382 (defun signed-zero-= (x y)
 383   (declare (real x y))
 384   (and (= x y)
 385        (= (float-sign (float x))
 386           (float-sign (float y)))))
 387 (defun signed-zero-<= (x y)
 388   (declare (real x y))
 389   (or (< x y)
 390       (and (= x y)
 391            (<= (float-sign (float x))
 392                (float-sign (float y))))))
 393
 394 ;;; See whether the interval X contains the number P, taking into
 395 ;;; account that the interval might not be closed.
 396 (defun interval-contains-p (p x)
 397   (declare (type number p)
 398            (type interval x))
 399   ;; Does the interval X contain the number P?  This would be a lot
 400   ;; easier if all intervals were closed!
 401   (let ((lo (interval-low x))
 402         (hi (interval-high x)))
 403     (cond ((and lo hi)
 404            ;; The interval is bounded
 405            (if (and (signed-zero-<= (type-bound-number lo) p)
 406                     (signed-zero-<= p (type-bound-number hi)))
 407                ;; P is definitely in the closure of the interval.
 408                ;; We just need to check the end points now.
 409                (cond ((signed-zero-= p (type-bound-number lo))
 410                       (numberp lo))
 411                      ((signed-zero-= p (type-bound-number hi))
 412                       (numberp hi))
 413                      (t t))
 414                nil))
 415           (hi
 416            ;; Interval with upper bound
 417            (if (signed-zero-< p (type-bound-number hi))
 418                t
 419                (and (numberp hi) (signed-zero-= p hi))))
 420           (lo
 421            ;; Interval with lower bound
 422            (if (signed-zero-> p (type-bound-number lo))
 423                t
 424                (and (numberp lo) (signed-zero-= p lo))))
 425           (t
 426            ;; Interval with no bounds
 427            t))))
 428
 429 ;;; Determine whether two intervals X and Y intersect. Return T if so.
 430 ;;; If CLOSED-INTERVALS-P is T, the treat the intervals as if they
 431 ;;; were closed. Otherwise the intervals are treated as they are.
 432 ;;;
 433 ;;; Thus if X = [0, 1) and Y = (1, 2), then they do not intersect
 434 ;;; because no element in X is in Y. However, if CLOSED-INTERVALS-P
 435 ;;; is T, then they do intersect because we use the closure of X = [0,
 436 ;;; 1] and Y = [1, 2] to determine intersection.
 437 (defun interval-intersect-p (x y &optional closed-intervals-p)
 438   (declare (type interval x y))
 439   (multiple-value-bind (intersect diff)
 440       (interval-intersection/difference (if closed-intervals-p
 441                                             (interval-closure x)
 442                                             x)
 443                                         (if closed-intervals-p
 444                                             (interval-closure y)
 445                                             y))
 446     (declare (ignore diff))
 447     intersect))
 448
 449 ;;; Are the two intervals adjacent?  That is, is there a number
 450 ;;; between the two intervals that is not an element of either
 451 ;;; interval?  If so, they are not adjacent. For example [0, 1) and
 452 ;;; [1, 2] are adjacent but [0, 1) and (1, 2] are not because 1 lies
 453 ;;; between both intervals.
 454 (defun interval-adjacent-p (x y)
 455   (declare (type interval x y))
 456   (flet ((adjacent (lo hi)
 457            ;; Check to see whether lo and hi are adjacent. If either is
 458            ;; nil, they can't be adjacent.
 459            (when (and lo hi (= (type-bound-number lo) (type-bound-number hi)))
 460              ;; The bounds are equal. They are adjacent if one of
 461              ;; them is closed (a number). If both are open (consp),
 462              ;; then there is a number that lies between them.
 463              (or (numberp lo) (numberp hi)))))
 464     (or (adjacent (interval-low y) (interval-high x))
 465         (adjacent (interval-low x) (interval-high y)))))
 466
 467 ;;; Compute the intersection and difference between two intervals.
 468 ;;; Two values are returned: the intersection and the difference.
 469 ;;;
 470 ;;; Let the two intervals be X and Y, and let I and D be the two
 471 ;;; values returned by this function. Then I = X intersect Y. If I
 472 ;;; is NIL (the empty set), then D is X union Y, represented as the
 473 ;;; list of X and Y. If I is not the empty set, then D is (X union Y)
 474 ;;; - I, which is a list of two intervals.
 475 ;;;
 476 ;;; For example, let X = [1,5] and Y = [-1,3). Then I = [1,3) and D =
 477 ;;; [-1,1) union [3,5], which is returned as a list of two intervals.
 478 (defun interval-intersection/difference (x y)
 479   (declare (type interval x y))
 480   (let ((x-lo (interval-low x))
 481         (x-hi (interval-high x))
 482         (y-lo (interval-low y))
 483         (y-hi (interval-high y)))
 484     (labels
 485         ((opposite-bound (p)
 486            ;; If p is an open bound, make it closed. If p is a closed
 487            ;; bound, make it open.
 488            (if (listp p)
 489                (first p)
 490                (list p)))
 491          (test-number (p int)
 492            ;; Test whether P is in the interval.
 493            (when (interval-contains-p (type-bound-number p)
 494                                       (interval-closure int))
 495              (let ((lo (interval-low int))
 496                    (hi (interval-high int)))
 497                ;; Check for endpoints.
 498                (cond ((and lo (= (type-bound-number p) (type-bound-number lo)))
 499                       (not (and (consp p) (numberp lo))))
 500                      ((and hi (= (type-bound-number p) (type-bound-number hi)))
 501                       (not (and (numberp p) (consp hi))))
 502                      (t t)))))
 503          (test-lower-bound (p int)
 504            ;; P is a lower bound of an interval.
 505            (if p
 506                (test-number p int)
 507                (not (interval-bounded-p int 'below))))
 508          (test-upper-bound (p int)
 509            ;; P is an upper bound of an interval.
 510            (if p
 511                (test-number p int)
 512                (not (interval-bounded-p int 'above)))))
 513       (let ((x-lo-in-y (test-lower-bound x-lo y))
 514             (x-hi-in-y (test-upper-bound x-hi y))
 515             (y-lo-in-x (test-lower-bound y-lo x))
 516             (y-hi-in-x (test-upper-bound y-hi x)))
 517         (cond ((or x-lo-in-y x-hi-in-y y-lo-in-x y-hi-in-x)
 518                ;; Intervals intersect. Let's compute the intersection
 519                ;; and the difference.
 520                (multiple-value-bind (lo left-lo left-hi)
 521                    (cond (x-lo-in-y (values x-lo y-lo (opposite-bound x-lo)))
 522                          (y-lo-in-x (values y-lo x-lo (opposite-bound y-lo))))
 523                  (multiple-value-bind (hi right-lo right-hi)
 524                      (cond (x-hi-in-y
 525                             (values x-hi (opposite-bound x-hi) y-hi))
 526                            (y-hi-in-x
 527                             (values y-hi (opposite-bound y-hi) x-hi)))
 528                    (values (make-interval :low lo :high hi)
 529                            (list (make-interval :low left-lo
 530                                                 :high left-hi)
 531                                  (make-interval :low right-lo
 532                                                 :high right-hi))))))
 533               (t
 534                (values nil (list x y))))))))
 535
 536 ;;; If intervals X and Y intersect, return a new interval that is the
 537 ;;; union of the two. If they do not intersect, return NIL.
 538 (defun interval-merge-pair (x y)
 539   (declare (type interval x y))
 540   ;; If x and y intersect or are adjacent, create the union.
 541   ;; Otherwise return nil
 542   (when (or (interval-intersect-p x y)
 543             (interval-adjacent-p x y))
 544     (flet ((select-bound (x1 x2 min-op max-op)
 545              (let ((x1-val (type-bound-number x1))
 546                    (x2-val (type-bound-number x2)))
 547                (cond ((and x1 x2)
 548                       ;; Both bounds are finite. Select the right one.
 549                       (cond ((funcall min-op x1-val x2-val)
 550                              ;; x1 is definitely better.
 551                              x1)
 552                             ((funcall max-op x1-val x2-val)
 553                              ;; x2 is definitely better.
 554                              x2)
 555                             (t
 556                              ;; Bounds are equal. Select either
 557                              ;; value and make it open only if
 558                              ;; both were open.
 559                              (set-bound x1-val (and (consp x1) (consp x2))))))
 560                      (t
 561                       ;; At least one bound is not finite. The
 562                       ;; non-finite bound always wins.
 563                       nil)))))
 564       (let* ((x-lo (copy-interval-limit (interval-low x)))
 565              (x-hi (copy-interval-limit (interval-high x)))
 566              (y-lo (copy-interval-limit (interval-low y)))
 567              (y-hi (copy-interval-limit (interval-high y))))
 568         (make-interval :low (select-bound x-lo y-lo #'< #'>)
 569                        :high (select-bound x-hi y-hi #'> #'<))))))
 570
 571 ;;; basic arithmetic operations on intervals. We probably should do
 572 ;;; true interval arithmetic here, but it's complicated because we
 573 ;;; have float and integer types and bounds can be open or closed.
 574
 575 ;;; the negative of an interval
 576 (defun interval-neg (x)
 577   (declare (type interval x))
 578   (make-interval :low (bound-func #'- (interval-high x))
 579                  :high (bound-func #'- (interval-low x))))
 580
 581 ;;; Add two intervals.
 582 (defun interval-add (x y)
 583   (declare (type interval x y))
 584   (make-interval :low (bound-binop + (interval-low x) (interval-low y))
 585                  :high (bound-binop + (interval-high x) (interval-high y))))
 586
 587 ;;; Subtract two intervals.
 588 (defun interval-sub (x y)
 589   (declare (type interval x y))
 590   (make-interval :low (bound-binop - (interval-low x) (interval-high y))
 591                  :high (bound-binop - (interval-high x) (interval-low y))))
 592
 593 ;;; Multiply two intervals.
 594 (defun interval-mul (x y)
 595   (declare (type interval x y))
 596   (flet ((bound-mul (x y)
 597            (cond ((or (null x) (null y))
 598                   ;; Multiply by infinity is infinity
 599                   nil)
 600                  ((or (and (numberp x) (zerop x))
 601                       (and (numberp y) (zerop y)))
 602                   ;; Multiply by closed zero is special. The result
 603                   ;; is always a closed bound. But don't replace this
 604                   ;; with zero; we want the multiplication to produce
 605                   ;; the correct signed zero, if needed.
 606                   (* (type-bound-number x) (type-bound-number y)))
 607                  ((or (and (floatp x) (float-infinity-p x))
 608                       (and (floatp y) (float-infinity-p y)))
 609                   ;; Infinity times anything is infinity
 610                   nil)
 611                  (t
 612                   ;; General multiply. The result is open if either is open.
 613                   (bound-binop * x y)))))
 614     (let ((x-range (interval-range-info x))
 615           (y-range (interval-range-info y)))
 616       (cond ((null x-range)
 617              ;; Split x into two and multiply each separately
 618              (destructuring-bind (x- x+) (interval-split 0 x t t)
 619                (interval-merge-pair (interval-mul x- y)
 620                                     (interval-mul x+ y))))
 621             ((null y-range)
 622              ;; Split y into two and multiply each separately
 623              (destructuring-bind (y- y+) (interval-split 0 y t t)
 624                (interval-merge-pair (interval-mul x y-)
 625                                     (interval-mul x y+))))
 626             ((eq x-range '-)
 627              (interval-neg (interval-mul (interval-neg x) y)))
 628             ((eq y-range '-)
 629              (interval-neg (interval-mul x (interval-neg y))))
 630             ((and (eq x-range '+) (eq y-range '+))
 631              ;; If we are here, X and Y are both positive.
 632              (make-interval
 633               :low (bound-mul (interval-low x) (interval-low y))
 634               :high (bound-mul (interval-high x) (interval-high y))))
 635             (t
 636              (bug "excluded case in INTERVAL-MUL"))))))
 637
 638 ;;; Divide two intervals.
 639 (defun interval-div (top bot)
 640   (declare (type interval top bot))
 641   (flet ((bound-div (x y y-low-p)
 642            ;; Compute x/y
 643            (cond ((null y)
 644                   ;; Divide by infinity means result is 0. However,
 645                   ;; we need to watch out for the sign of the result,
 646                   ;; to correctly handle signed zeros. We also need
 647                   ;; to watch out for positive or negative infinity.
 648                   (if (floatp (type-bound-number x))
 649                       (if y-low-p
 650                           (- (float-sign (type-bound-number x) 0.0))
 651                           (float-sign (type-bound-number x) 0.0))
 652                       0))
 653                  ((zerop (type-bound-number y))
 654                   ;; Divide by zero means result is infinity
 655                   nil)
 656                  ((and (numberp x) (zerop x))
 657                   ;; Zero divided by anything is zero.
 658                   x)
 659                  (t
 660                   (bound-binop / x y)))))
 661     (let ((top-range (interval-range-info top))
 662           (bot-range (interval-range-info bot)))
 663       (cond ((null bot-range)
 664              ;; The denominator contains zero, so anything goes!
 665              (make-interval :low nil :high nil))
 666             ((eq bot-range '-)
 667              ;; Denominator is negative so flip the sign, compute the
 668              ;; result, and flip it back.
 669              (interval-neg (interval-div top (interval-neg bot))))
 670             ((null top-range)
 671              ;; Split top into two positive and negative parts, and
 672              ;; divide each separately
 673              (destructuring-bind (top- top+) (interval-split 0 top t t)
 674                (interval-merge-pair (interval-div top- bot)
 675                                     (interval-div top+ bot))))
 676             ((eq top-range '-)
 677              ;; Top is negative so flip the sign, divide, and flip the
 678              ;; sign of the result.
 679              (interval-neg (interval-div (interval-neg top) bot)))
 680             ((and (eq top-range '+) (eq bot-range '+))
 681              ;; the easy case
 682              (make-interval
 683               :low (bound-div (interval-low top) (interval-high bot) t)
 684               :high (bound-div (interval-high top) (interval-low bot) nil)))
 685             (t
 686              (bug "excluded case in INTERVAL-DIV"))))))
 687
 688 ;;; Apply the function F to the interval X. If X = [a, b], then the
 689 ;;; result is [f(a), f(b)]. It is up to the user to make sure the
 690 ;;; result makes sense. It will if F is monotonic increasing (or
 691 ;;; non-decreasing).
 692 (defun interval-func (f x)
 693   (declare (type function f)
 694            (type interval x))
 695   (let ((lo (bound-func f (interval-low x)))
 696         (hi (bound-func f (interval-high x))))
 697     (make-interval :low lo :high hi)))
 698
 699 ;;; Return T if X < Y. That is every number in the interval X is
 700 ;;; always less than any number in the interval Y.
 701 (defun interval-< (x y)
 702   (declare (type interval x y))
 703   ;; X < Y only if X is bounded above, Y is bounded below, and they
 704   ;; don't overlap.
 705   (when (and (interval-bounded-p x 'above)
 706              (interval-bounded-p y 'below))
 707     ;; Intervals are bounded in the appropriate way. Make sure they
 708     ;; don't overlap.
 709     (let ((left (interval-high x))
 710           (right (interval-low y)))
 711       (cond ((> (type-bound-number left)
 712                 (type-bound-number right))
 713              ;; The intervals definitely overlap, so result is NIL.
 714              nil)
 715             ((< (type-bound-number left)
 716                 (type-bound-number right))
 717              ;; The intervals definitely don't touch, so result is T.
 718              t)
 719             (t
 720              ;; Limits are equal. Check for open or closed bounds.
 721              ;; Don't overlap if one or the other are open.
 722              (or (consp left) (consp right)))))))
 723
 724 ;;; Return T if X >= Y. That is, every number in the interval X is
 725 ;;; always greater than any number in the interval Y.
 726 (defun interval->= (x y)
 727   (declare (type interval x y))
 728   ;; X >= Y if lower bound of X >= upper bound of Y
 729   (when (and (interval-bounded-p x 'below)
 730              (interval-bounded-p y 'above))
 731     (>= (type-bound-number (interval-low x))
 732         (type-bound-number (interval-high y)))))
 733
 734 ;;; Return an interval that is the absolute value of X. Thus, if
 735 ;;; X = [-1 10], the result is [0, 10].
 736 (defun interval-abs (x)
 737   (declare (type interval x))
 738   (case (interval-range-info x)
 739     (+
 740      (copy-interval x))
 741     (-
 742      (interval-neg x))
 743     (t
 744      (destructuring-bind (x- x+) (interval-split 0 x t t)
 745        (interval-merge-pair (interval-neg x-) x+)))))
 746
 747 ;;; Compute the square of an interval.
 748 (defun interval-sqr (x)
 749   (declare (type interval x))
 750   (interval-func (lambda (x) (* x x))
 751                  (interval-abs x)))
 752 \f
 753 ;;;; numeric DERIVE-TYPE methods
 754
 755 ;;; a utility for defining derive-type methods of integer operations. If
 756 ;;; the types of both X and Y are integer types, then we compute a new
 757 ;;; integer type with bounds determined Fun when applied to X and Y.
 758 ;;; Otherwise, we use Numeric-Contagion.
 759 (defun derive-integer-type (x y fun)
 760   (declare (type continuation x y) (type function fun))
 761   (let ((x (continuation-type x))
 762         (y (continuation-type y)))
 763     (if (and (numeric-type-p x) (numeric-type-p y)
 764              (eq (numeric-type-class x) 'integer)
 765              (eq (numeric-type-class y) 'integer)
 766              (eq (numeric-type-complexp x) :real)
 767              (eq (numeric-type-complexp y) :real))
 768         (multiple-value-bind (low high) (funcall fun x y)
 769           (make-numeric-type :class 'integer
 770                              :complexp :real
 771                              :low low
 772                              :high high))
 773         (numeric-contagion x y))))
 774
 775 ;;; simple utility to flatten a list
 776 (defun flatten-list (x)
 777   (labels ((flatten-helper (x r);; 'r' is the stuff to the 'right'.
 778              (cond ((null x) r)
 779                    ((atom x)
 780                     (cons x r))
 781                    (t (flatten-helper (car x)
 782                                       (flatten-helper (cdr x) r))))))
 783     (flatten-helper x nil)))
 784
 785 ;;; Take some type of continuation and massage it so that we get a
 786 ;;; list of the constituent types. If ARG is *EMPTY-TYPE*, return NIL
 787 ;;; to indicate failure.
 788 (defun prepare-arg-for-derive-type (arg)
 789   (flet ((listify (arg)
 790            (typecase arg
 791              (numeric-type
 792               (list arg))
 793              (union-type
 794               (union-type-types arg))
 795              (t
 796               (list arg)))))
 797     (unless (eq arg *empty-type*)
 798       ;; Make sure all args are some type of numeric-type. For member
 799       ;; types, convert the list of members into a union of equivalent
 800       ;; single-element member-type's.
 801       (let ((new-args nil))
 802         (dolist (arg (listify arg))
 803           (if (member-type-p arg)
 804               ;; Run down the list of members and convert to a list of
 805               ;; member types.
 806               (dolist (member (member-type-members arg))
 807                 (push (if (numberp member)
 808                           (make-member-type :members (list member))
 809                           *empty-type*)
 810                       new-args))
 811               (push arg new-args)))
 812         (unless (member *empty-type* new-args)
 813           new-args)))))
 814
 815 ;;; Convert from the standard type convention for which -0.0 and 0.0
 816 ;;; are equal to an intermediate convention for which they are
 817 ;;; considered different which is more natural for some of the
 818 ;;; optimisers.
 819 (defun convert-numeric-type (type)
 820   (declare (type numeric-type type))
 821   ;;; Only convert real float interval delimiters types.
 822   (if (eq (numeric-type-complexp type) :real)
 823       (let* ((lo (numeric-type-low type))
 824              (lo-val (type-bound-number lo))
 825              (lo-float-zero-p (and lo (floatp lo-val) (= lo-val 0.0)))
 826              (hi (numeric-type-high type))
 827              (hi-val (type-bound-number hi))
 828              (hi-float-zero-p (and hi (floatp hi-val) (= hi-val 0.0))))
 829         (if (or lo-float-zero-p hi-float-zero-p)
 830             (make-numeric-type
 831              :class (numeric-type-class type)
 832              :format (numeric-type-format type)
 833              :complexp :real
 834              :low (if lo-float-zero-p
 835                       (if (consp lo)
 836                           (list (float 0.0 lo-val))
 837                           (float (load-time-value (make-unportable-float :single-float-negative-zero)) lo-val))
 838                       lo)
 839              :high (if hi-float-zero-p
 840                        (if (consp hi)
 841                            (list (float (load-time-value (make-unportable-float :single-float-negative-zero)) hi-val))
 842                            (float 0.0 hi-val))
 843                        hi))
 844             type))
 845       ;; Not real float.
 846       type))
 847
 848 ;;; Convert back from the intermediate convention for which -0.0 and
 849 ;;; 0.0 are considered different to the standard type convention for
 850 ;;; which and equal.
 851 (defun convert-back-numeric-type (type)
 852   (declare (type numeric-type type))
 853   ;;; Only convert real float interval delimiters types.
 854   (if (eq (numeric-type-complexp type) :real)
 855       (let* ((lo (numeric-type-low type))
 856              (lo-val (type-bound-number lo))
 857              (lo-float-zero-p
 858               (and lo (floatp lo-val) (= lo-val 0.0)
 859                    (float-sign lo-val)))
 860              (hi (numeric-type-high type))
 861              (hi-val (type-bound-number hi))
 862              (hi-float-zero-p
 863               (and hi (floatp hi-val) (= hi-val 0.0)
 864                    (float-sign hi-val))))
 865         (cond
 866           ;; (float +0.0 +0.0) => (member 0.0)
 867           ;; (float -0.0 -0.0) => (member -0.0)
 868           ((and lo-float-zero-p hi-float-zero-p)
 869            ;; shouldn't have exclusive bounds here..
 870            (aver (and (not (consp lo)) (not (consp hi))))
 871            (if (= lo-float-zero-p hi-float-zero-p)
 872                ;; (float +0.0 +0.0) => (member 0.0)
 873                ;; (float -0.0 -0.0) => (member -0.0)
 874                (specifier-type `(member ,lo-val))
 875                ;; (float -0.0 +0.0) => (float 0.0 0.0)
 876                ;; (float +0.0 -0.0) => (float 0.0 0.0)
 877                (make-numeric-type :class (numeric-type-class type)
 878                                   :format (numeric-type-format type)
 879                                   :complexp :real
 880                                   :low hi-val
 881                                   :high hi-val)))
 882           (lo-float-zero-p
 883            (cond
 884              ;; (float -0.0 x) => (float 0.0 x)
 885              ((and (not (consp lo)) (minusp lo-float-zero-p))
 886               (make-numeric-type :class (numeric-type-class type)
 887                                  :format (numeric-type-format type)
 888                                  :complexp :real
 889                                  :low (float 0.0 lo-val)
 890                                  :high hi))
 891              ;; (float (+0.0) x) => (float (0.0) x)
 892              ((and (consp lo) (plusp lo-float-zero-p))
 893               (make-numeric-type :class (numeric-type-class type)
 894                                  :format (numeric-type-format type)
 895                                  :complexp :real
 896                                  :low (list (float 0.0 lo-val))
 897                                  :high hi))
 898              (t
 899               ;; (float +0.0 x) => (or (member 0.0) (float (0.0) x))
 900               ;; (float (-0.0) x) => (or (member 0.0) (float (0.0) x))
 901               (list (make-member-type :members (list (float 0.0 lo-val)))
 902                     (make-numeric-type :class (numeric-type-class type)
 903                                        :format (numeric-type-format type)
 904                                        :complexp :real
 905                                        :low (list (float 0.0 lo-val))
 906                                        :high hi)))))
 907           (hi-float-zero-p
 908            (cond
 909              ;; (float x +0.0) => (float x 0.0)
 910              ((and (not (consp hi)) (plusp hi-float-zero-p))
 911               (make-numeric-type :class (numeric-type-class type)
 912                                  :format (numeric-type-format type)
 913                                  :complexp :real
 914                                  :low lo
 915                                  :high (float 0.0 hi-val)))
 916              ;; (float x (-0.0)) => (float x (0.0))
 917              ((and (consp hi) (minusp hi-float-zero-p))
 918               (make-numeric-type :class (numeric-type-class type)
 919                                  :format (numeric-type-format type)
 920                                  :complexp :real
 921                                  :low lo
 922                                  :high (list (float 0.0 hi-val))))
 923              (t
 924               ;; (float x (+0.0)) => (or (member -0.0) (float x (0.0)))
 925               ;; (float x -0.0) => (or (member -0.0) (float x (0.0)))
 926               (list (make-member-type :members (list (float -0.0 hi-val)))
 927                     (make-numeric-type :class (numeric-type-class type)
 928                                        :format (numeric-type-format type)
 929                                        :complexp :real
 930                                        :low lo
 931                                        :high (list (float 0.0 hi-val)))))))
 932           (t
 933            type)))
 934       ;; not real float
 935       type))
 936
 937 ;;; Convert back a possible list of numeric types.
 938 (defun convert-back-numeric-type-list (type-list)
 939   (typecase type-list
 940     (list
 941      (let ((results '()))
 942        (dolist (type type-list)
 943          (if (numeric-type-p type)
 944              (let ((result (convert-back-numeric-type type)))
 945                (if (listp result)
 946                    (setf results (append results result))
 947                    (push result results)))
 948              (push type results)))
 949        results))
 950     (numeric-type
 951      (convert-back-numeric-type type-list))
 952     (union-type
 953      (convert-back-numeric-type-list (union-type-types type-list)))
 954     (t
 955      type-list)))
 956
 957 ;;; FIXME: MAKE-CANONICAL-UNION-TYPE and CONVERT-MEMBER-TYPE probably
 958 ;;; belong in the kernel's type logic, invoked always, instead of in
 959 ;;; the compiler, invoked only during some type optimizations. (In
 960 ;;; fact, as of 0.pre8.100 or so they probably are, under
 961 ;;; MAKE-MEMBER-TYPE, so probably this code can be deleted)
 962
 963 ;;; Take a list of types and return a canonical type specifier,
 964 ;;; combining any MEMBER types together. If both positive and negative
 965 ;;; MEMBER types are present they are converted to a float type.
 966 ;;; XXX This would be far simpler if the type-union methods could handle
 967 ;;; member/number unions.
 968 (defun make-canonical-union-type (type-list)
 969   (let ((members '())
 970         (misc-types '()))
 971     (dolist (type type-list)
 972       (if (member-type-p type)
 973           (setf members (union members (member-type-members type)))
 974           (push type misc-types)))
 975     #!+long-float
 976     (when (null (set-difference `(,(load-time-value (make-unportable-float :long-float-negative-zero)) 0.0l0) members))
 977       (push (specifier-type '(long-float 0.0l0 0.0l0)) misc-types)
 978       (setf members (set-difference members `(,(load-time-value (make-unportable-float :long-float-negative-zero)) 0.0l0))))
 979     (when (null (set-difference `(,(load-time-value (make-unportable-float :double-float-negative-zero)) 0.0d0) members))
 980       (push (specifier-type '(double-float 0.0d0 0.0d0)) misc-types)
 981       (setf members (set-difference members `(,(load-time-value (make-unportable-float :double-float-negative-zero)) 0.0d0))))
 982     (when (null (set-difference `(,(load-time-value (make-unportable-float :single-float-negative-zero)) 0.0f0) members))
 983       (push (specifier-type '(single-float 0.0f0 0.0f0)) misc-types)
 984       (setf members (set-difference members `(,(load-time-value (make-unportable-float :single-float-negative-zero)) 0.0f0))))
 985     (if members
 986         (apply #'type-union (make-member-type :members members) misc-types)
 987         (apply #'type-union misc-types))))
 988
 989 ;;; Convert a member type with a single member to a numeric type.
 990 (defun convert-member-type (arg)
 991   (let* ((members (member-type-members arg))
 992          (member (first members))
 993          (member-type (type-of member)))
 994     (aver (not (rest members)))
 995     (specifier-type `(,(if (subtypep member-type 'integer)
 996                            'integer
 997                            member-type)
 998                       ,member ,member))))
 999
1000 ;;; This is used in defoptimizers for computing the resulting type of
1001 ;;; a function.
1002 ;;;
1003 ;;; Given the continuation ARG, derive the resulting type using the
1004 ;;; DERIVE-FCN. DERIVE-FCN takes exactly one argument which is some
1005 ;;; "atomic" continuation type like numeric-type or member-type
1006 ;;; (containing just one element). It should return the resulting
1007 ;;; type, which can be a list of types.
1008 ;;;
1009 ;;; For the case of member types, if a member-fcn is given it is
1010 ;;; called to compute the result otherwise the member type is first
1011 ;;; converted to a numeric type and the derive-fcn is call.
1012 (defun one-arg-derive-type (arg derive-fcn member-fcn
1013                                 &optional (convert-type t))
1014   (declare (type function derive-fcn)
1015            (type (or null function) member-fcn))
1016   (let ((arg-list (prepare-arg-for-derive-type (continuation-type arg))))
1017     (when arg-list
1018       (flet ((deriver (x)
1019                (typecase x
1020                  (member-type
1021                   (if member-fcn
1022                       (with-float-traps-masked
1023                           (:underflow :overflow :divide-by-zero)
1024                         (make-member-type
1025                          :members (list
1026                                    (funcall member-fcn
1027                                             (first (member-type-members x))))))
1028                       ;; Otherwise convert to a numeric type.
1029                       (let ((result-type-list
1030                              (funcall derive-fcn (convert-member-type x))))
1031                         (if convert-type
1032                             (convert-back-numeric-type-list result-type-list)
1033                             result-type-list))))
1034                  (numeric-type
1035                   (if convert-type
1036                       (convert-back-numeric-type-list
1037                        (funcall derive-fcn (convert-numeric-type x)))
1038                       (funcall derive-fcn x)))
1039                  (t
1040                   *universal-type*))))
1041         ;; Run down the list of args and derive the type of each one,
1042         ;; saving all of the results in a list.
1043         (let ((results nil))
1044           (dolist (arg arg-list)
1045             (let ((result (deriver arg)))
1046               (if (listp result)
1047                   (setf results (append results result))
1048                   (push result results))))
1049           (if (rest results)
1050               (make-canonical-union-type results)
1051               (first results)))))))
1052
1053 ;;; Same as ONE-ARG-DERIVE-TYPE, except we assume the function takes
1054 ;;; two arguments. DERIVE-FCN takes 3 args in this case: the two
1055 ;;; original args and a third which is T to indicate if the two args
1056 ;;; really represent the same continuation. This is useful for
1057 ;;; deriving the type of things like (* x x), which should always be
1058 ;;; positive. If we didn't do this, we wouldn't be able to tell.
1059 (defun two-arg-derive-type (arg1 arg2 derive-fcn fcn
1060                                  &optional (convert-type t))
1061   (declare (type function derive-fcn fcn))
1062   (flet ((deriver (x y same-arg)
1063            (cond ((and (member-type-p x) (member-type-p y))
1064                   (let* ((x (first (member-type-members x)))
1065                          (y (first (member-type-members y)))
1066                          (result (with-float-traps-masked
1067                                      (:underflow :overflow :divide-by-zero
1068                                       :invalid)
1069                                    (funcall fcn x y))))
1070                     (cond ((null result))
1071                           ((and (floatp result) (float-nan-p result))
1072                            (make-numeric-type :class 'float
1073                                               :format (type-of result)
1074                                               :complexp :real))
1075                           (t
1076                            (make-member-type :members (list result))))))
1077                  ((and (member-type-p x) (numeric-type-p y))
1078                   (let* ((x (convert-member-type x))
1079                          (y (if convert-type (convert-numeric-type y) y))
1080                          (result (funcall derive-fcn x y same-arg)))
1081                     (if convert-type
1082                         (convert-back-numeric-type-list result)
1083                         result)))
1084                  ((and (numeric-type-p x) (member-type-p y))
1085                   (let* ((x (if convert-type (convert-numeric-type x) x))
1086                          (y (convert-member-type y))
1087                          (result (funcall derive-fcn x y same-arg)))
1088                     (if convert-type
1089                         (convert-back-numeric-type-list result)
1090                         result)))
1091                  ((and (numeric-type-p x) (numeric-type-p y))
1092                   (let* ((x (if convert-type (convert-numeric-type x) x))
1093                          (y (if convert-type (convert-numeric-type y) y))
1094                          (result (funcall derive-fcn x y same-arg)))
1095                     (if convert-type
1096                         (convert-back-numeric-type-list result)
1097                         result)))
1098                  (t
1099                   *universal-type*))))
1100     (let ((same-arg (same-leaf-ref-p arg1 arg2))
1101           (a1 (prepare-arg-for-derive-type (continuation-type arg1)))
1102           (a2 (prepare-arg-for-derive-type (continuation-type arg2))))
1103       (when (and a1 a2)
1104         (let ((results nil))
1105           (if same-arg
1106               ;; Since the args are the same continuation, just run
1107               ;; down the lists.
1108               (dolist (x a1)
1109                 (let ((result (deriver x x same-arg)))
1110                   (if (listp result)
1111                       (setf results (append results result))
1112                       (push result results))))
1113               ;; Try all pairwise combinations.
1114               (dolist (x a1)
1115                 (dolist (y a2)
1116                   (let ((result (or (deriver x y same-arg)
1117                                     (numeric-contagion x y))))
1118                     (if (listp result)
1119                         (setf results (append results result))
1120                         (push result results))))))
1121           (if (rest results)
1122               (make-canonical-union-type results)
1123               (first results)))))))
1124 \f
1125 #+sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
1126 (progn
1127 (defoptimizer (+ derive-type) ((x y))
1128   (derive-integer-type
1129    x y
1130    #'(lambda (x y)
1131        (flet ((frob (x y)
1132                 (if (and x y)
1133                     (+ x y)
1134                     nil)))
1135          (values (frob (numeric-type-low x) (numeric-type-low y))
1136                  (frob (numeric-type-high x) (numeric-type-high y)))))))
1137
1138 (defoptimizer (- derive-type) ((x y))
1139   (derive-integer-type
1140    x y
1141    #'(lambda (x y)
1142        (flet ((frob (x y)
1143                 (if (and x y)
1144                     (- x y)
1145                     nil)))
1146          (values (frob (numeric-type-low x) (numeric-type-high y))
1147                  (frob (numeric-type-high x) (numeric-type-low y)))))))
1148
1149 (defoptimizer (* derive-type) ((x y))
1150   (derive-integer-type
1151    x y
1152    #'(lambda (x y)
1153        (let ((x-low (numeric-type-low x))
1154              (x-high (numeric-type-high x))
1155              (y-low (numeric-type-low y))
1156              (y-high (numeric-type-high y)))
1157          (cond ((not (and x-low y-low))
1158                 (values nil nil))
1159                ((or (minusp x-low) (minusp y-low))
1160                 (if (and x-high y-high)
1161                     (let ((max (* (max (abs x-low) (abs x-high))
1162                                   (max (abs y-low) (abs y-high)))))
1163                       (values (- max) max))
1164                     (values nil nil)))
1165                (t
1166                 (values (* x-low y-low)
1167                         (if (and x-high y-high)
1168                             (* x-high y-high)
1169                             nil))))))))
1170
1171 (defoptimizer (/ derive-type) ((x y))
1172   (numeric-contagion (continuation-type x) (continuation-type y)))
1173
1174 ) ; PROGN
1175
1176 #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
1177 (progn
1178 (defun +-derive-type-aux (x y same-arg)
1179   (if (and (numeric-type-real-p x)
1180            (numeric-type-real-p y))
1181       (let ((result
1182              (if same-arg
1183                  (let ((x-int (numeric-type->interval x)))
1184                    (interval-add x-int x-int))
1185                  (interval-add (numeric-type->interval x)
1186                                (numeric-type->interval y))))
1187             (result-type (numeric-contagion x y)))
1188         ;; If the result type is a float, we need to be sure to coerce
1189         ;; the bounds into the correct type.
1190         (when (eq (numeric-type-class result-type) 'float)
1191           (setf result (interval-func
1192                         #'(lambda (x)
1193                             (coerce x (or (numeric-type-format result-type)
1194                                           'float)))
1195                         result)))
1196         (make-numeric-type
1197          :class (if (and (eq (numeric-type-class x) 'integer)
1198                          (eq (numeric-type-class y) 'integer))
1199                     ;; The sum of integers is always an integer.
1200                     'integer
1201                     (numeric-type-class result-type))
1202          :format (numeric-type-format result-type)
1203          :low (interval-low result)
1204          :high (interval-high result)))
1205       ;; general contagion
1206       (numeric-contagion x y)))
1207
1208 (defoptimizer (+ derive-type) ((x y))
1209   (two-arg-derive-type x y #'+-derive-type-aux #'+))
1210
1211 (defun --derive-type-aux (x y same-arg)
1212   (if (and (numeric-type-real-p x)
1213            (numeric-type-real-p y))
1214       (let ((result
1215              ;; (- X X) is always 0.
1216              (if same-arg
1217                  (make-interval :low 0 :high 0)
1218                  (interval-sub (numeric-type->interval x)
1219                                (numeric-type->interval y))))
1220             (result-type (numeric-contagion x y)))
1221         ;; If the result type is a float, we need to be sure to coerce
1222         ;; the bounds into the correct type.
1223         (when (eq (numeric-type-class result-type) 'float)
1224           (setf result (interval-func
1225                         #'(lambda (x)
1226                             (coerce x (or (numeric-type-format result-type)
1227                                           'float)))
1228                         result)))
1229         (make-numeric-type
1230          :class (if (and (eq (numeric-type-class x) 'integer)
1231                          (eq (numeric-type-class y) 'integer))
1232                     ;; The difference of integers is always an integer.
1233                     'integer
1234                     (numeric-type-class result-type))
1235          :format (numeric-type-format result-type)
1236          :low (interval-low result)
1237          :high (interval-high result)))
1238       ;; general contagion
1239       (numeric-contagion x y)))
1240
1241 (defoptimizer (- derive-type) ((x y))
1242   (two-arg-derive-type x y #'--derive-type-aux #'-))
1243
1244 (defun *-derive-type-aux (x y same-arg)
1245   (if (and (numeric-type-real-p x)
1246            (numeric-type-real-p y))
1247       (let ((result
1248              ;; (* X X) is always positive, so take care to do it right.
1249              (if same-arg
1250                  (interval-sqr (numeric-type->interval x))
1251                  (interval-mul (numeric-type->interval x)
1252                                (numeric-type->interval y))))
1253             (result-type (numeric-contagion x y)))
1254         ;; If the result type is a float, we need to be sure to coerce
1255         ;; the bounds into the correct type.
1256         (when (eq (numeric-type-class result-type) 'float)
1257           (setf result (interval-func
1258                         #'(lambda (x)
1259                             (coerce x (or (numeric-type-format result-type)
1260                                           'float)))
1261                         result)))
1262         (make-numeric-type
1263          :class (if (and (eq (numeric-type-class x) 'integer)
1264                          (eq (numeric-type-class y) 'integer))
1265                     ;; The product of integers is always an integer.
1266                     'integer
1267                     (numeric-type-class result-type))
1268          :format (numeric-type-format result-type)
1269          :low (interval-low result)
1270          :high (interval-high result)))
1271       (numeric-contagion x y)))
1272
1273 (defoptimizer (* derive-type) ((x y))
1274   (two-arg-derive-type x y #'*-derive-type-aux #'*))
1275
1276 (defun /-derive-type-aux (x y same-arg)
1277   (if (and (numeric-type-real-p x)
1278            (numeric-type-real-p y))
1279       (let ((result
1280              ;; (/ X X) is always 1, except if X can contain 0. In
1281              ;; that case, we shouldn't optimize the division away
1282              ;; because we want 0/0 to signal an error.
1283              (if (and same-arg
1284                       (not (interval-contains-p
1285                             0 (interval-closure (numeric-type->interval y)))))
1286                  (make-interval :low 1 :high 1)
1287                  (interval-div (numeric-type->interval x)
1288                                (numeric-type->interval y))))
1289             (result-type (numeric-contagion x y)))
1290         ;; If the result type is a float, we need to be sure to coerce
1291         ;; the bounds into the correct type.
1292         (when (eq (numeric-type-class result-type) 'float)
1293           (setf result (interval-func
1294                         #'(lambda (x)
1295                             (coerce x (or (numeric-type-format result-type)
1296                                           'float)))
1297                         result)))
1298         (make-numeric-type :class (numeric-type-class result-type)
1299                            :format (numeric-type-format result-type)
1300                            :low (interval-low result)
1301                            :high (interval-high result)))
1302       (numeric-contagion x y)))
1303
1304 (defoptimizer (/ derive-type) ((x y))
1305   (two-arg-derive-type x y #'/-derive-type-aux #'/))
1306
1307 ) ; PROGN
1308
1309 (defun ash-derive-type-aux (n-type shift same-arg)
1310   (declare (ignore same-arg))
1311   ;; KLUDGE: All this ASH optimization is suppressed under CMU CL for
1312   ;; some bignum cases because as of version 2.4.6 for Debian and 18d,
1313   ;; CMU CL blows up on (ASH 1000000000 -100000000000) (i.e. ASH of
1314   ;; two bignums yielding zero) and it's hard to avoid that
1315   ;; calculation in here.
1316   #+(and cmu sb-xc-host)
1317   (when (and (or (typep (numeric-type-low n-type) 'bignum)
1318                  (typep (numeric-type-high n-type) 'bignum))
1319              (or (typep (numeric-type-low shift) 'bignum)
1320                  (typep (numeric-type-high shift) 'bignum)))
1321     (return-from ash-derive-type-aux *universal-type*))
1322   (flet ((ash-outer (n s)
1323            (when (and (fixnump s)
1324                       (<= s 64)
1325                       (> s sb!xc:most-negative-fixnum))
1326              (ash n s)))
1327          ;; KLUDGE: The bare 64's here should be related to
1328          ;; symbolic machine word size values somehow.
1329
1330          (ash-inner (n s)
1331            (if (and (fixnump s)
1332                     (> s sb!xc:most-negative-fixnum))
1333              (ash n (min s 64))
1334              (if (minusp n) -1 0))))
1335     (or (and (csubtypep n-type (specifier-type 'integer))
1336              (csubtypep shift (specifier-type 'integer))
1337              (let ((n-low (numeric-type-low n-type))
1338                    (n-high (numeric-type-high n-type))
1339                    (s-low (numeric-type-low shift))
1340                    (s-high (numeric-type-high shift)))
1341                (make-numeric-type :class 'integer  :complexp :real
1342                                   :low (when n-low
1343                                          (if (minusp n-low)
1344                                            (ash-outer n-low s-high)
1345                                            (ash-inner n-low s-low)))
1346                                   :high (when n-high
1347                                           (if (minusp n-high)
1348                                             (ash-inner n-high s-low)
1349                                             (ash-outer n-high s-high))))))
1350         *universal-type*)))
1351
1352 (defoptimizer (ash derive-type) ((n shift))
1353   (two-arg-derive-type n shift #'ash-derive-type-aux #'ash))
1354
1355 #+sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
1356 (macrolet ((frob (fun)
1357              `#'(lambda (type type2)
1358                   (declare (ignore type2))
1359                   (let ((lo (numeric-type-low type))
1360                         (hi (numeric-type-high type)))
1361                     (values (if hi (,fun hi) nil) (if lo (,fun lo) nil))))))
1362
1363   (defoptimizer (%negate derive-type) ((num))
1364     (derive-integer-type num num (frob -))))
1365
1366 (defoptimizer (lognot derive-type) ((int))
1367   (derive-integer-type int int
1368                        (lambda (type type2)
1369                          (declare (ignore type2))
1370                          (let ((lo (numeric-type-low type))
1371                                (hi (numeric-type-high type)))
1372                            (values (if hi (lognot hi) nil)
1373                                    (if lo (lognot lo) nil)
1374                                    (numeric-type-class type)
1375                                    (numeric-type-format type))))))
1376
1377 #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
1378 (defoptimizer (%negate derive-type) ((num))
1379   (flet ((negate-bound (b)
1380            (and b
1381                 (set-bound (- (type-bound-number b))
1382                            (consp b)))))
1383     (one-arg-derive-type num
1384                          (lambda (type)
1385                            (modified-numeric-type
1386                             type
1387                             :low (negate-bound (numeric-type-high type))
1388                             :high (negate-bound (numeric-type-low type))))
1389                          #'-)))
1390
1391 #+sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
1392 (defoptimizer (abs derive-type) ((num))
1393   (let ((type (continuation-type num)))
1394     (if (and (numeric-type-p type)
1395              (eq (numeric-type-class type) 'integer)
1396              (eq (numeric-type-complexp type) :real))
1397         (let ((lo (numeric-type-low type))
1398               (hi (numeric-type-high type)))
1399           (make-numeric-type :class 'integer :complexp :real
1400                              :low (cond ((and hi (minusp hi))
1401                                          (abs hi))
1402                                         (lo
1403                                          (max 0 lo))
1404                                         (t
1405                                          0))
1406                              :high (if (and hi lo)
1407                                        (max (abs hi) (abs lo))
1408                                        nil)))
1409         (numeric-contagion type type))))
1410
1411 #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
1412 (defun abs-derive-type-aux (type)
1413   (cond ((eq (numeric-type-complexp type) :complex)
1414          ;; The absolute value of a complex number is always a
1415          ;; non-negative float.
1416          (let* ((format (case (numeric-type-class type)
1417                           ((integer rational) 'single-float)
1418                           (t (numeric-type-format type))))
1419                 (bound-format (or format 'float)))
1420            (make-numeric-type :class 'float
1421                               :format format
1422                               :complexp :real
1423                               :low (coerce 0 bound-format)
1424                               :high nil)))
1425         (t
1426          ;; The absolute value of a real number is a non-negative real
1427          ;; of the same type.
1428          (let* ((abs-bnd (interval-abs (numeric-type->interval type)))
1429                 (class (numeric-type-class type))
1430                 (format (numeric-type-format type))
1431                 (bound-type (or format class 'real)))
1432            (make-numeric-type
1433             :class class
1434             :format format
1435             :complexp :real
1436             :low (coerce-numeric-bound (interval-low abs-bnd) bound-type)
1437             :high (coerce-numeric-bound
1438                    (interval-high abs-bnd) bound-type))))))
1439
1440 #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
1441 (defoptimizer (abs derive-type) ((num))
1442   (one-arg-derive-type num #'abs-derive-type-aux #'abs))
1443
1444 #+sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
1445 (defoptimizer (truncate derive-type) ((number divisor))
1446   (let ((number-type (continuation-type number))
1447         (divisor-type (continuation-type divisor))
1448         (integer-type (specifier-type 'integer)))
1449     (if (and (numeric-type-p number-type)
1450              (csubtypep number-type integer-type)
1451              (numeric-type-p divisor-type)
1452              (csubtypep divisor-type integer-type))
1453         (let ((number-low (numeric-type-low number-type))
1454               (number-high (numeric-type-high number-type))
1455               (divisor-low (numeric-type-low divisor-type))
1456               (divisor-high (numeric-type-high divisor-type)))
1457           (values-specifier-type
1458            `(values ,(integer-truncate-derive-type number-low number-high
1459                                                    divisor-low divisor-high)
1460                     ,(integer-rem-derive-type number-low number-high
1461                                               divisor-low divisor-high))))
1462         *universal-type*)))
1463
1464 #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
1465 (progn
1466
1467 (defun rem-result-type (number-type divisor-type)
1468   ;; Figure out what the remainder type is. The remainder is an
1469   ;; integer if both args are integers; a rational if both args are
1470   ;; rational; and a float otherwise.
1471   (cond ((and (csubtypep number-type (specifier-type 'integer))
1472               (csubtypep divisor-type (specifier-type 'integer)))
1473          'integer)
1474         ((and (csubtypep number-type (specifier-type 'rational))
1475               (csubtypep divisor-type (specifier-type 'rational)))
1476          'rational)
1477         ((and (csubtypep number-type (specifier-type 'float))
1478               (csubtypep divisor-type (specifier-type 'float)))
1479          ;; Both are floats so the result is also a float, of
1480          ;; the largest type.
1481          (or (float-format-max (numeric-type-format number-type)
1482                                (numeric-type-format divisor-type))
1483              'float))
1484         ((and (csubtypep number-type (specifier-type 'float))
1485               (csubtypep divisor-type (specifier-type 'rational)))
1486          ;; One of the arguments is a float and the other is a
1487          ;; rational. The remainder is a float of the same
1488          ;; type.
1489          (or (numeric-type-format number-type) 'float))
1490         ((and (csubtypep divisor-type (specifier-type 'float))
1491               (csubtypep number-type (specifier-type 'rational)))
1492          ;; One of the arguments is a float and the other is a
1493          ;; rational. The remainder is a float of the same
1494          ;; type.
1495          (or (numeric-type-format divisor-type) 'float))
1496         (t
1497          ;; Some unhandled combination. This usually means both args
1498          ;; are REAL so the result is a REAL.
1499          'real)))
1500
1501 (defun truncate-derive-type-quot (number-type divisor-type)
1502   (let* ((rem-type (rem-result-type number-type divisor-type))
1503          (number-interval (numeric-type->interval number-type))
1504          (divisor-interval (numeric-type->interval divisor-type)))
1505     ;;(declare (type (member '(integer rational float)) rem-type))
1506     ;; We have real numbers now.
1507     (cond ((eq rem-type 'integer)
1508            ;; Since the remainder type is INTEGER, both args are
1509            ;; INTEGERs.
1510            (let* ((res (integer-truncate-derive-type
1511                         (interval-low number-interval)
1512                         (interval-high number-interval)
1513                         (interval-low divisor-interval)
1514                         (interval-high divisor-interval))))
1515              (specifier-type (if (listp res) res 'integer))))
1516           (t
1517            (let ((quot (truncate-quotient-bound
1518                         (interval-div number-interval
1519                                       divisor-interval))))
1520              (specifier-type `(integer ,(or (interval-low quot) '*)
1521                                        ,(or (interval-high quot) '*))))))))
1522
1523 (defun truncate-derive-type-rem (number-type divisor-type)
1524   (let* ((rem-type (rem-result-type number-type divisor-type))
1525          (number-interval (numeric-type->interval number-type))
1526          (divisor-interval (numeric-type->interval divisor-type))
1527          (rem (truncate-rem-bound number-interval divisor-interval)))
1528     ;;(declare (type (member '(integer rational float)) rem-type))
1529     ;; We have real numbers now.
1530     (cond ((eq rem-type 'integer)
1531            ;; Since the remainder type is INTEGER, both args are
1532            ;; INTEGERs.
1533            (specifier-type `(,rem-type ,(or (interval-low rem) '*)
1534                                        ,(or (interval-high rem) '*))))
1535           (t
1536            (multiple-value-bind (class format)
1537                (ecase rem-type
1538                  (integer
1539                   (values 'integer nil))
1540                  (rational
1541                   (values 'rational nil))
1542                  ((or single-float double-float #!+long-float long-float)
1543                   (values 'float rem-type))
1544                  (float
1545                   (values 'float nil))
1546                  (real
1547                   (values nil nil)))
1548              (when (member rem-type '(float single-float double-float
1549                                             #!+long-float long-float))
1550                (setf rem (interval-func #'(lambda (x)
1551                                             (coerce x rem-type))
1552                                         rem)))
1553              (make-numeric-type :class class
1554                                 :format format
1555                                 :low (interval-low rem)
1556                                 :high (interval-high rem)))))))
1557
1558 (defun truncate-derive-type-quot-aux (num div same-arg)
1559   (declare (ignore same-arg))
1560   (if (and (numeric-type-real-p num)
1561            (numeric-type-real-p div))
1562       (truncate-derive-type-quot num div)
1563       *empty-type*))
1564
1565 (defun truncate-derive-type-rem-aux (num div same-arg)
1566   (declare (ignore same-arg))
1567   (if (and (numeric-type-real-p num)
1568            (numeric-type-real-p div))
1569       (truncate-derive-type-rem num div)
1570       *empty-type*))
1571
1572 (defoptimizer (truncate derive-type) ((number divisor))
1573   (let ((quot (two-arg-derive-type number divisor
1574                                    #'truncate-derive-type-quot-aux #'truncate))
1575         (rem (two-arg-derive-type number divisor
1576                                   #'truncate-derive-type-rem-aux #'rem)))
1577     (when (and quot rem)
1578       (make-values-type :required (list quot rem)))))
1579
1580 (defun ftruncate-derive-type-quot (number-type divisor-type)
1581   ;; The bounds are the same as for truncate. However, the first
1582   ;; result is a float of some type. We need to determine what that
1583   ;; type is. Basically it's the more contagious of the two types.
1584   (let ((q-type (truncate-derive-type-quot number-type divisor-type))
1585         (res-type (numeric-contagion number-type divisor-type)))
1586     (make-numeric-type :class 'float
1587                        :format (numeric-type-format res-type)
1588                        :low (numeric-type-low q-type)
1589                        :high (numeric-type-high q-type))))
1590
1591 (defun ftruncate-derive-type-quot-aux (n d same-arg)
1592   (declare (ignore same-arg))
1593   (if (and (numeric-type-real-p n)
1594            (numeric-type-real-p d))
1595       (ftruncate-derive-type-quot n d)
1596       *empty-type*))
1597
1598 (defoptimizer (ftruncate derive-type) ((number divisor))
1599   (let ((quot
1600          (two-arg-derive-type number divisor
1601                               #'ftruncate-derive-type-quot-aux #'ftruncate))
1602         (rem (two-arg-derive-type number divisor
1603                                   #'truncate-derive-type-rem-aux #'rem)))
1604     (when (and quot rem)
1605       (make-values-type :required (list quot rem)))))
1606
1607 (defun %unary-truncate-derive-type-aux (number)
1608   (truncate-derive-type-quot number (specifier-type '(integer 1 1))))
1609
1610 (defoptimizer (%unary-truncate derive-type) ((number))
1611   (one-arg-derive-type number
1612                        #'%unary-truncate-derive-type-aux
1613                        #'%unary-truncate))
1614
1615 ;;; Define optimizers for FLOOR and CEILING.
1616 (macrolet
1617     ((def (name q-name r-name)
1618        (let ((q-aux (symbolicate q-name "-AUX"))
1619              (r-aux (symbolicate r-name "-AUX")))
1620          `(progn
1621            ;; Compute type of quotient (first) result.
1622            (defun ,q-aux (number-type divisor-type)
1623              (let* ((number-interval
1624                      (numeric-type->interval number-type))
1625                     (divisor-interval
1626                      (numeric-type->interval divisor-type))
1627                     (quot (,q-name (interval-div number-interval
1628                                                  divisor-interval))))
1629                (specifier-type `(integer ,(or (interval-low quot) '*)
1630                                          ,(or (interval-high quot) '*)))))
1631            ;; Compute type of remainder.
1632            (defun ,r-aux (number-type divisor-type)
1633              (let* ((divisor-interval
1634                      (numeric-type->interval divisor-type))
1635                     (rem (,r-name divisor-interval))
1636                     (result-type (rem-result-type number-type divisor-type)))
1637                (multiple-value-bind (class format)
1638                    (ecase result-type
1639                      (integer
1640                       (values 'integer nil))
1641                      (rational
1642                       (values 'rational nil))
1643                      ((or single-float double-float #!+long-float long-float)
1644                       (values 'float result-type))
1645                      (float
1646                       (values 'float nil))
1647                      (real
1648                       (values nil nil)))
1649                  (when (member result-type '(float single-float double-float
1650                                              #!+long-float long-float))
1651                    ;; Make sure that the limits on the interval have
1652                    ;; the right type.
1653                    (setf rem (interval-func (lambda (x)
1654                                               (coerce x result-type))
1655                                             rem)))
1656                  (make-numeric-type :class class
1657                                     :format format
1658                                     :low (interval-low rem)
1659                                     :high (interval-high rem)))))
1660            ;; the optimizer itself
1661            (defoptimizer (,name derive-type) ((number divisor))
1662              (flet ((derive-q (n d same-arg)
1663                       (declare (ignore same-arg))
1664                       (if (and (numeric-type-real-p n)
1665                                (numeric-type-real-p d))
1666                           (,q-aux n d)
1667                           *empty-type*))
1668                     (derive-r (n d same-arg)
1669                       (declare (ignore same-arg))
1670                       (if (and (numeric-type-real-p n)
1671                                (numeric-type-real-p d))
1672                           (,r-aux n d)
1673                           *empty-type*)))
1674                (let ((quot (two-arg-derive-type
1675                             number divisor #'derive-q #',name))
1676                      (rem (two-arg-derive-type
1677                            number divisor #'derive-r #'mod)))
1678                  (when (and quot rem)
1679                    (make-values-type :required (list quot rem))))))))))
1680
1681   (def floor floor-quotient-bound floor-rem-bound)
1682   (def ceiling ceiling-quotient-bound ceiling-rem-bound))
1683
1684 ;;; Define optimizers for FFLOOR and FCEILING
1685 (macrolet ((def (name q-name r-name)
1686              (let ((q-aux (symbolicate "F" q-name "-AUX"))
1687                    (r-aux (symbolicate r-name "-AUX")))
1688                `(progn
1689                   ;; Compute type of quotient (first) result.
1690                   (defun ,q-aux (number-type divisor-type)
1691                     (let* ((number-interval
1692                             (numeric-type->interval number-type))
1693                            (divisor-interval
1694                             (numeric-type->interval divisor-type))
1695                            (quot (,q-name (interval-div number-interval
1696                                                         divisor-interval)))
1697                            (res-type (numeric-contagion number-type
1698                                                         divisor-type)))
1699                       (make-numeric-type
1700                        :class (numeric-type-class res-type)
1701                        :format (numeric-type-format res-type)
1702                        :low  (interval-low quot)
1703                        :high (interval-high quot))))
1704
1705                   (defoptimizer (,name derive-type) ((number divisor))
1706                     (flet ((derive-q (n d same-arg)
1707                              (declare (ignore same-arg))
1708                              (if (and (numeric-type-real-p n)
1709                                       (numeric-type-real-p d))
1710                                  (,q-aux n d)
1711                                  *empty-type*))
1712                            (derive-r (n d same-arg)
1713                              (declare (ignore same-arg))
1714                              (if (and (numeric-type-real-p n)
1715                                       (numeric-type-real-p d))
1716                                  (,r-aux n d)
1717                                  *empty-type*)))
1718                       (let ((quot (two-arg-derive-type
1719                                    number divisor #'derive-q #',name))
1720                             (rem (two-arg-derive-type
1721                                   number divisor #'derive-r #'mod)))
1722                         (when (and quot rem)
1723                           (make-values-type :required (list quot rem))))))))))
1724
1725   (def ffloor floor-quotient-bound floor-rem-bound)
1726   (def fceiling ceiling-quotient-bound ceiling-rem-bound))
1727
1728 ;;; functions to compute the bounds on the quotient and remainder for
1729 ;;; the FLOOR function
1730 (defun floor-quotient-bound (quot)
1731   ;; Take the floor of the quotient and then massage it into what we
1732   ;; need.
1733   (let ((lo (interval-low quot))
1734         (hi (interval-high quot)))
1735     ;; Take the floor of the lower bound. The result is always a
1736     ;; closed lower bound.
1737     (setf lo (if lo
1738                  (floor (type-bound-number lo))
1739                  nil))
1740     ;; For the upper bound, we need to be careful.
1741     (setf hi
1742           (cond ((consp hi)
1743                  ;; An open bound. We need to be careful here because
1744                  ;; the floor of '(10.0) is 9, but the floor of
1745                  ;; 10.0 is 10.
1746                  (multiple-value-bind (q r) (floor (first hi))
1747                    (if (zerop r)
1748                        (1- q)
1749                        q)))
1750                 (hi
1751                  ;; A closed bound, so the answer is obvious.
1752                  (floor hi))
1753                 (t
1754                  hi)))
1755     (make-interval :low lo :high hi)))
1756 (defun floor-rem-bound (div)
1757   ;; The remainder depends only on the divisor. Try to get the
1758   ;; correct sign for the remainder if we can.
1759   (case (interval-range-info div)
1760     (+
1761      ;; The divisor is always positive.
1762      (let ((rem (interval-abs div)))
1763        (setf (interval-low rem) 0)
1764        (when (and (numberp (interval-high rem))
1765                   (not (zerop (interval-high rem))))
1766          ;; The remainder never contains the upper bound. However,
1767          ;; watch out for the case where the high limit is zero!
1768          (setf (interval-high rem) (list (interval-high rem))))
1769        rem))
1770     (-
1771      ;; The divisor is always negative.
1772      (let ((rem (interval-neg (interval-abs div))))
1773        (setf (interval-high rem) 0)
1774        (when (numberp (interval-low rem))
1775          ;; The remainder never contains the lower bound.
1776          (setf (interval-low rem) (list (interval-low rem))))
1777        rem))
1778     (otherwise
1779      ;; The divisor can be positive or negative. All bets off. The
1780      ;; magnitude of remainder is the maximum value of the divisor.
1781      (let ((limit (type-bound-number (interval-high (interval-abs div)))))
1782        ;; The bound never reaches the limit, so make the interval open.
1783        (make-interval :low (if limit
1784                                (list (- limit))
1785                                limit)
1786                       :high (list limit))))))
1787 #| Test cases
1788 (floor-quotient-bound (make-interval :low 0.3 :high 10.3))
1789 => #S(INTERVAL :LOW 0 :HIGH 10)
1790 (floor-quotient-bound (make-interval :low 0.3 :high '(10.3)))
1791 => #S(INTERVAL :LOW 0 :HIGH 10)
1792 (floor-quotient-bound (make-interval :low 0.3 :high 10))
1793 => #S(INTERVAL :LOW 0 :HIGH 10)
1794 (floor-quotient-bound (make-interval :low 0.3 :high '(10)))
1795 => #S(INTERVAL :LOW 0 :HIGH 9)
1796 (floor-quotient-bound (make-interval :low '(0.3) :high 10.3))
1797 => #S(INTERVAL :LOW 0 :HIGH 10)
1798 (floor-quotient-bound (make-interval :low '(0.0) :high 10.3))
1799 => #S(INTERVAL :LOW 0 :HIGH 10)
1800 (floor-quotient-bound (make-interval :low '(-1.3) :high 10.3))
1801 => #S(INTERVAL :LOW -2 :HIGH 10)
1802 (floor-quotient-bound (make-interval :low '(-1.0) :high 10.3))
1803 => #S(INTERVAL :LOW -1 :HIGH 10)
1804 (floor-quotient-bound (make-interval :low -1.0 :high 10.3))
1805 => #S(INTERVAL :LOW -1 :HIGH 10)
1806
1807 (floor-rem-bound (make-interval :low 0.3 :high 10.3))
1808 => #S(INTERVAL :LOW 0 :HIGH '(10.3))
1809 (floor-rem-bound (make-interval :low 0.3 :high '(10.3)))
1810 => #S(INTERVAL :LOW 0 :HIGH '(10.3))
1811 (floor-rem-bound (make-interval :low -10 :high -2.3))
1812 #S(INTERVAL :LOW (-10) :HIGH 0)
1813 (floor-rem-bound (make-interval :low 0.3 :high 10))
1814 => #S(INTERVAL :LOW 0 :HIGH '(10))
1815 (floor-rem-bound (make-interval :low '(-1.3) :high 10.3))
1816 => #S(INTERVAL :LOW '(-10.3) :HIGH '(10.3))
1817 (floor-rem-bound (make-interval :low '(-20.3) :high 10.3))
1818 => #S(INTERVAL :LOW (-20.3) :HIGH (20.3))
1819 |#
1820 \f
1821 ;;; same functions for CEILING
1822 (defun ceiling-quotient-bound (quot)
1823   ;; Take the ceiling of the quotient and then massage it into what we
1824   ;; need.
1825   (let ((lo (interval-low quot))
1826         (hi (interval-high quot)))
1827     ;; Take the ceiling of the upper bound. The result is always a
1828     ;; closed upper bound.
1829     (setf hi (if hi
1830                  (ceiling (type-bound-number hi))
1831                  nil))
1832     ;; For the lower bound, we need to be careful.
1833     (setf lo
1834           (cond ((consp lo)
1835                  ;; An open bound. We need to be careful here because
1836                  ;; the ceiling of '(10.0) is 11, but the ceiling of
1837                  ;; 10.0 is 10.
1838                  (multiple-value-bind (q r) (ceiling (first lo))
1839                    (if (zerop r)
1840                        (1+ q)
1841                        q)))
1842                 (lo
1843                  ;; A closed bound, so the answer is obvious.
1844                  (ceiling lo))
1845                 (t
1846                  lo)))
1847     (make-interval :low lo :high hi)))
1848 (defun ceiling-rem-bound (div)
1849   ;; The remainder depends only on the divisor. Try to get the
1850   ;; correct sign for the remainder if we can.
1851   (case (interval-range-info div)
1852     (+
1853      ;; Divisor is always positive. The remainder is negative.
1854      (let ((rem (interval-neg (interval-abs div))))
1855        (setf (interval-high rem) 0)
1856        (when (and (numberp (interval-low rem))
1857                   (not (zerop (interval-low rem))))
1858          ;; The remainder never contains the upper bound. However,
1859          ;; watch out for the case when the upper bound is zero!
1860          (setf (interval-low rem) (list (interval-low rem))))
1861        rem))
1862     (-
1863      ;; Divisor is always negative. The remainder is positive
1864      (let ((rem (interval-abs div)))
1865        (setf (interval-low rem) 0)
1866        (when (numberp (interval-high rem))
1867          ;; The remainder never contains the lower bound.
1868          (setf (interval-high rem) (list (interval-high rem))))
1869        rem))
1870     (otherwise
1871      ;; The divisor can be positive or negative. All bets off. The
1872      ;; magnitude of remainder is the maximum value of the divisor.
1873      (let ((limit (type-bound-number (interval-high (interval-abs div)))))
1874        ;; The bound never reaches the limit, so make the interval open.
1875        (make-interval :low (if limit
1876                                (list (- limit))
1877                                limit)
1878                       :high (list limit))))))
1879
1880 #| Test cases
1881 (ceiling-quotient-bound (make-interval :low 0.3 :high 10.3))
1882 => #S(INTERVAL :LOW 1 :HIGH 11)
1883 (ceiling-quotient-bound (make-interval :low 0.3 :high '(10.3)))
1884 => #S(INTERVAL :LOW 1 :HIGH 11)
1885 (ceiling-quotient-bound (make-interval :low 0.3 :high 10))
1886 => #S(INTERVAL :LOW 1 :HIGH 10)
1887 (ceiling-quotient-bound (make-interval :low 0.3 :high '(10)))
1888 => #S(INTERVAL :LOW 1 :HIGH 10)
1889 (ceiling-quotient-bound (make-interval :low '(0.3) :high 10.3))
1890 => #S(INTERVAL :LOW 1 :HIGH 11)
1891 (ceiling-quotient-bound (make-interval :low '(0.0) :high 10.3))
1892 => #S(INTERVAL :LOW 1 :HIGH 11)
1893 (ceiling-quotient-bound (make-interval :low '(-1.3) :high 10.3))
1894 => #S(INTERVAL :LOW -1 :HIGH 11)
1895 (ceiling-quotient-bound (make-interval :low '(-1.0) :high 10.3))
1896 => #S(INTERVAL :LOW 0 :HIGH 11)
1897 (ceiling-quotient-bound (make-interval :low -1.0 :high 10.3))
1898 => #S(INTERVAL :LOW -1 :HIGH 11)
1899
1900 (ceiling-rem-bound (make-interval :low 0.3 :high 10.3))
1901 => #S(INTERVAL :LOW (-10.3) :HIGH 0)
1902 (ceiling-rem-bound (make-interval :low 0.3 :high '(10.3)))
1903 => #S(INTERVAL :LOW 0 :HIGH '(10.3))
1904 (ceiling-rem-bound (make-interval :low -10 :high -2.3))
1905 => #S(INTERVAL :LOW 0 :HIGH (10))
1906 (ceiling-rem-bound (make-interval :low 0.3 :high 10))
1907 => #S(INTERVAL :LOW (-10) :HIGH 0)
1908 (ceiling-rem-bound (make-interval :low '(-1.3) :high 10.3))
1909 => #S(INTERVAL :LOW (-10.3) :HIGH (10.3))
1910 (ceiling-rem-bound (make-interval :low '(-20.3) :high 10.3))
1911 => #S(INTERVAL :LOW (-20.3) :HIGH (20.3))
1912 |#
1913 \f
1914 (defun truncate-quotient-bound (quot)
1915   ;; For positive quotients, truncate is exactly like floor. For
1916   ;; negative quotients, truncate is exactly like ceiling. Otherwise,
1917   ;; it's the union of the two pieces.
1918   (case (interval-range-info quot)
1919     (+
1920      ;; just like FLOOR
1921      (floor-quotient-bound quot))
1922     (-
1923      ;; just like CEILING
1924      (ceiling-quotient-bound quot))
1925     (otherwise
1926      ;; Split the interval into positive and negative pieces, compute
1927      ;; the result for each piece and put them back together.
1928      (destructuring-bind (neg pos) (interval-split 0 quot t t)
1929        (interval-merge-pair (ceiling-quotient-bound neg)
1930                             (floor-quotient-bound pos))))))
1931
1932 (defun truncate-rem-bound (num div)
1933   ;; This is significantly more complicated than FLOOR or CEILING. We
1934   ;; need both the number and the divisor to determine the range. The
1935   ;; basic idea is to split the ranges of NUM and DEN into positive
1936   ;; and negative pieces and deal with each of the four possibilities
1937   ;; in turn.
1938   (case (interval-range-info num)
1939     (+
1940      (case (interval-range-info div)
1941        (+
1942         (floor-rem-bound div))
1943        (-
1944         (ceiling-rem-bound div))
1945        (otherwise
1946         (destructuring-bind (neg pos) (interval-split 0 div t t)
1947           (interval-merge-pair (truncate-rem-bound num neg)
1948                                (truncate-rem-bound num pos))))))
1949     (-
1950      (case (interval-range-info div)
1951        (+
1952         (ceiling-rem-bound div))
1953        (-
1954         (floor-rem-bound div))
1955        (otherwise
1956         (destructuring-bind (neg pos) (interval-split 0 div t t)
1957           (interval-merge-pair (truncate-rem-bound num neg)
1958                                (truncate-rem-bound num pos))))))
1959     (otherwise
1960      (destructuring-bind (neg pos) (interval-split 0 num t t)
1961        (interval-merge-pair (truncate-rem-bound neg div)
1962                             (truncate-rem-bound pos div))))))
1963 ) ; PROGN
1964
1965 ;;; Derive useful information about the range. Returns three values:
1966 ;;; - '+ if its positive, '- negative, or nil if it overlaps 0.
1967 ;;; - The abs of the minimal value (i.e. closest to 0) in the range.
1968 ;;; - The abs of the maximal value if there is one, or nil if it is
1969 ;;;   unbounded.
1970 (defun numeric-range-info (low high)
1971   (cond ((and low (not (minusp low)))
1972          (values '+ low high))
1973         ((and high (not (plusp high)))
1974          (values '- (- high) (if low (- low) nil)))
1975         (t
1976          (values nil 0 (and low high (max (- low) high))))))
1977
1978 (defun integer-truncate-derive-type
1979        (number-low number-high divisor-low divisor-high)
1980   ;; The result cannot be larger in magnitude than the number, but the
1981   ;; sign might change. If we can determine the sign of either the
1982   ;; number or the divisor, we can eliminate some of the cases.
1983   (multiple-value-bind (number-sign number-min number-max)
1984       (numeric-range-info number-low number-high)
1985     (multiple-value-bind (divisor-sign divisor-min divisor-max)
1986         (numeric-range-info divisor-low divisor-high)
1987       (when (and divisor-max (zerop divisor-max))
1988         ;; We've got a problem: guaranteed division by zero.
1989         (return-from integer-truncate-derive-type t))
1990       (when (zerop divisor-min)
1991         ;; We'll assume that they aren't going to divide by zero.
1992         (incf divisor-min))
1993       (cond ((and number-sign divisor-sign)
1994              ;; We know the sign of both.
1995              (if (eq number-sign divisor-sign)
1996                  ;; Same sign, so the result will be positive.
1997                  `(integer ,(if divisor-max
1998                                 (truncate number-min divisor-max)
1999                                 0)
2000                            ,(if number-max
2001                                 (truncate number-max divisor-min)
2002                                 '*))
2003                  ;; Different signs, the result will be negative.
2004                  `(integer ,(if number-max
2005                                 (- (truncate number-max divisor-min))
2006                                 '*)
2007                            ,(if divisor-max
2008                                 (- (truncate number-min divisor-max))
2009                                 0))))
2010             ((eq divisor-sign '+)
2011              ;; The divisor is positive. Therefore, the number will just
2012              ;; become closer to zero.
2013              `(integer ,(if number-low
2014                             (truncate number-low divisor-min)
2015                             '*)
2016                        ,(if number-high
2017                             (truncate number-high divisor-min)
2018                             '*)))
2019             ((eq divisor-sign '-)
2020              ;; The divisor is negative. Therefore, the absolute value of
2021              ;; the number will become closer to zero, but the sign will also
2022              ;; change.
2023              `(integer ,(if number-high
2024                             (- (truncate number-high divisor-min))
2025                             '*)
2026                        ,(if number-low
2027                             (- (truncate number-low divisor-min))
2028                             '*)))
2029             ;; The divisor could be either positive or negative.
2030             (number-max
2031              ;; The number we are dividing has a bound. Divide that by the
2032              ;; smallest posible divisor.
2033              (let ((bound (truncate number-max divisor-min)))
2034                `(integer ,(- bound) ,bound)))
2035             (t
2036              ;; The number we are dividing is unbounded, so we can't tell
2037              ;; anything about the result.
2038              `integer)))))
2039
2040 #+sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
2041 (defun integer-rem-derive-type
2042        (number-low number-high divisor-low divisor-high)
2043   (if (and divisor-low divisor-high)
2044       ;; We know the range of the divisor, and the remainder must be
2045       ;; smaller than the divisor. We can tell the sign of the
2046       ;; remainer if we know the sign of the number.
2047       (let ((divisor-max (1- (max (abs divisor-low) (abs divisor-high)))))
2048         `(integer ,(if (or (null number-low)
2049                            (minusp number-low))
2050                        (- divisor-max)
2051                        0)
2052                   ,(if (or (null number-high)
2053                            (plusp number-high))
2054                        divisor-max
2055                        0)))
2056       ;; The divisor is potentially either very positive or very
2057       ;; negative. Therefore, the remainer is unbounded, but we might
2058       ;; be able to tell something about the sign from the number.
2059       `(integer ,(if (and number-low (not (minusp number-low)))
2060                      ;; The number we are dividing is positive.
2061                      ;; Therefore, the remainder must be positive.
2062                      0
2063                      '*)
2064                 ,(if (and number-high (not (plusp number-high)))
2065                      ;; The number we are dividing is negative.
2066                      ;; Therefore, the remainder must be negative.
2067                      0
2068                      '*))))
2069
2070 #+sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
2071 (defoptimizer (random derive-type) ((bound &optional state))
2072   (let ((type (continuation-type bound)))
2073     (when (numeric-type-p type)
2074       (let ((class (numeric-type-class type))
2075             (high (numeric-type-high type))
2076             (format (numeric-type-format type)))
2077         (make-numeric-type
2078          :class class
2079          :format format
2080          :low (coerce 0 (or format class 'real))
2081          :high (cond ((not high) nil)
2082                      ((eq class 'integer) (max (1- high) 0))
2083                      ((or (consp high) (zerop high)) high)
2084                      (t `(,high))))))))
2085
2086 #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
2087 (defun random-derive-type-aux (type)
2088   (let ((class (numeric-type-class type))
2089         (high (numeric-type-high type))
2090         (format (numeric-type-format type)))
2091     (make-numeric-type
2092          :class class
2093          :format format
2094          :low (coerce 0 (or format class 'real))
2095          :high (cond ((not high) nil)
2096                      ((eq class 'integer) (max (1- high) 0))
2097                      ((or (consp high) (zerop high)) high)
2098                      (t `(,high))))))
2099
2100 #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
2101 (defoptimizer (random derive-type) ((bound &optional state))
2102   (one-arg-derive-type bound #'random-derive-type-aux nil))
2103 \f
2104 ;;;; DERIVE-TYPE methods for LOGAND, LOGIOR, and friends
2105
2106 ;;; Return the maximum number of bits an integer of the supplied type
2107 ;;; can take up, or NIL if it is unbounded. The second (third) value
2108 ;;; is T if the integer can be positive (negative) and NIL if not.
2109 ;;; Zero counts as positive.
2110 (defun integer-type-length (type)
2111   (if (numeric-type-p type)
2112       (let ((min (numeric-type-low type))
2113             (max (numeric-type-high type)))
2114         (values (and min max (max (integer-length min) (integer-length max)))
2115                 (or (null max) (not (minusp max)))
2116                 (or (null min) (minusp min))))
2117       (values nil t t)))
2118
2119 (defun logand-derive-type-aux (x y &optional same-leaf)
2120   (declare (ignore same-leaf))
2121   (multiple-value-bind (x-len x-pos x-neg) (integer-type-length x)
2122     (declare (ignore x-pos))
2123     (multiple-value-bind (y-len y-pos y-neg) (integer-type-length  y)
2124       (declare (ignore y-pos))
2125       (if (not x-neg)
2126           ;; X must be positive.
2127           (if (not y-neg)
2128               ;; They must both be positive.
2129               (cond ((or (null x-len) (null y-len))
2130                      (specifier-type 'unsigned-byte))
2131                     ((or (zerop x-len) (zerop y-len))
2132                      (specifier-type '(integer 0 0)))
2133                     (t
2134                      (specifier-type `(unsigned-byte ,(min x-len y-len)))))
2135               ;; X is positive, but Y might be negative.
2136               (cond ((null x-len)
2137                      (specifier-type 'unsigned-byte))
2138                     ((zerop x-len)
2139                      (specifier-type '(integer 0 0)))
2140                     (t
2141                      (specifier-type `(unsigned-byte ,x-len)))))
2142           ;; X might be negative.
2143           (if (not y-neg)
2144               ;; Y must be positive.
2145               (cond ((null y-len)
2146                      (specifier-type 'unsigned-byte))
2147                     ((zerop y-len)
2148                      (specifier-type '(integer 0 0)))
2149                     (t
2150                      (specifier-type
2151                       `(unsigned-byte ,y-len))))
2152               ;; Either might be negative.
2153               (if (and x-len y-len)
2154                   ;; The result is bounded.
2155                   (specifier-type `(signed-byte ,(1+ (max x-len y-len))))
2156                   ;; We can't tell squat about the result.
2157                   (specifier-type 'integer)))))))
2158
2159 (defun logior-derive-type-aux (x y &optional same-leaf)
2160   (declare (ignore same-leaf))
2161   (multiple-value-bind (x-len x-pos x-neg) (integer-type-length x)
2162     (multiple-value-bind (y-len y-pos y-neg) (integer-type-length y)
2163       (cond
2164        ((and (not x-neg) (not y-neg))
2165         ;; Both are positive.
2166         (if (and x-len y-len (zerop x-len) (zerop y-len))
2167             (specifier-type '(integer 0 0))
2168             (specifier-type `(unsigned-byte ,(if (and x-len y-len)
2169                                              (max x-len y-len)
2170                                              '*)))))
2171        ((not x-pos)
2172         ;; X must be negative.
2173         (if (not y-pos)
2174             ;; Both are negative. The result is going to be negative
2175             ;; and be the same length or shorter than the smaller.
2176             (if (and x-len y-len)
2177                 ;; It's bounded.
2178                 (specifier-type `(integer ,(ash -1 (min x-len y-len)) -1))
2179                 ;; It's unbounded.
2180                 (specifier-type '(integer * -1)))
2181             ;; X is negative, but we don't know about Y. The result
2182             ;; will be negative, but no more negative than X.
2183             (specifier-type
2184              `(integer ,(or (numeric-type-low x) '*)
2185                        -1))))
2186        (t
2187         ;; X might be either positive or negative.
2188         (if (not y-pos)
2189             ;; But Y is negative. The result will be negative.
2190             (specifier-type
2191              `(integer ,(or (numeric-type-low y) '*)
2192                        -1))
2193             ;; We don't know squat about either. It won't get any bigger.
2194             (if (and x-len y-len)
2195                 ;; Bounded.
2196                 (specifier-type `(signed-byte ,(1+ (max x-len y-len))))
2197                 ;; Unbounded.
2198                 (specifier-type 'integer))))))))
2199
2200 (defun logxor-derive-type-aux (x y &optional same-leaf)
2201   (declare (ignore same-leaf))
2202   (multiple-value-bind (x-len x-pos x-neg) (integer-type-length x)
2203     (multiple-value-bind (y-len y-pos y-neg) (integer-type-length y)
2204       (cond
2205        ((or (and (not x-neg) (not y-neg))
2206             (and (not x-pos) (not y-pos)))
2207         ;; Either both are negative or both are positive. The result
2208         ;; will be positive, and as long as the longer.
2209         (if (and x-len y-len (zerop x-len) (zerop y-len))
2210             (specifier-type '(integer 0 0))
2211             (specifier-type `(unsigned-byte ,(if (and x-len y-len)
2212                                              (max x-len y-len)
2213                                              '*)))))
2214        ((or (and (not x-pos) (not y-neg))
2215             (and (not y-neg) (not y-pos)))
2216         ;; Either X is negative and Y is positive of vice-versa. The
2217         ;; result will be negative.
2218         (specifier-type `(integer ,(if (and x-len y-len)
2219                                        (ash -1 (max x-len y-len))
2220                                        '*)
2221                                   -1)))
2222        ;; We can't tell what the sign of the result is going to be.
2223        ;; All we know is that we don't create new bits.
2224        ((and x-len y-len)
2225         (specifier-type `(signed-byte ,(1+ (max x-len y-len)))))
2226        (t
2227         (specifier-type 'integer))))))
2228
2229 (macrolet ((deffrob (logfcn)
2230              (let ((fcn-aux (symbolicate logfcn "-DERIVE-TYPE-AUX")))
2231              `(defoptimizer (,logfcn derive-type) ((x y))
2232                 (two-arg-derive-type x y #',fcn-aux #',logfcn)))))
2233   (deffrob logand)
2234   (deffrob logior)
2235   (deffrob logxor))
2236 \f
2237 ;;;; miscellaneous derive-type methods
2238
2239 (defoptimizer (integer-length derive-type) ((x))
2240   (let ((x-type (continuation-type x)))
2241     (when (and (numeric-type-p x-type)
2242                (csubtypep x-type (specifier-type 'integer)))
2243       ;; If the X is of type (INTEGER LO HI), then the INTEGER-LENGTH
2244       ;; of X is (INTEGER (MIN lo hi) (MAX lo hi), basically.  Be
2245       ;; careful about LO or HI being NIL, though.  Also, if 0 is
2246       ;; contained in X, the lower bound is obviously 0.
2247       (flet ((null-or-min (a b)
2248                (and a b (min (integer-length a)
2249                              (integer-length b))))
2250              (null-or-max (a b)
2251                (and a b (max (integer-length a)
2252                              (integer-length b)))))
2253         (let* ((min (numeric-type-low x-type))
2254                (max (numeric-type-high x-type))
2255                (min-len (null-or-min min max))
2256                (max-len (null-or-max min max)))
2257           (when (ctypep 0 x-type)
2258             (setf min-len 0))
2259           (specifier-type `(integer ,(or min-len '*) ,(or max-len '*))))))))
2260
2261 (defoptimizer (code-char derive-type) ((code))
2262   (specifier-type 'base-char))
2263
2264 (defoptimizer (values derive-type) ((&rest values))
2265   (make-values-type :required (mapcar #'continuation-type values)))
2266 \f
2267 ;;;; byte operations
2268 ;;;;
2269 ;;;; We try to turn byte operations into simple logical operations.
2270 ;;;; First, we convert byte specifiers into separate size and position
2271 ;;;; arguments passed to internal %FOO functions. We then attempt to
2272 ;;;; transform the %FOO functions into boolean operations when the
2273 ;;;; size and position are constant and the operands are fixnums.
2274
2275 (macrolet (;; Evaluate body with SIZE-VAR and POS-VAR bound to
2276            ;; expressions that evaluate to the SIZE and POSITION of
2277            ;; the byte-specifier form SPEC. We may wrap a let around
2278            ;; the result of the body to bind some variables.
2279            ;;
2280            ;; If the spec is a BYTE form, then bind the vars to the
2281            ;; subforms. otherwise, evaluate SPEC and use the BYTE-SIZE
2282            ;; and BYTE-POSITION. The goal of this transformation is to
2283            ;; avoid consing up byte specifiers and then immediately
2284            ;; throwing them away.
2285            (with-byte-specifier ((size-var pos-var spec) &body body)
2286              (once-only ((spec `(macroexpand ,spec))
2287                          (temp '(gensym)))
2288                         `(if (and (consp ,spec)
2289                                   (eq (car ,spec) 'byte)
2290                                   (= (length ,spec) 3))
2291                         (let ((,size-var (second ,spec))
2292                               (,pos-var (third ,spec)))
2293                           ,@body)
2294                         (let ((,size-var `(byte-size ,,temp))
2295                               (,pos-var `(byte-position ,,temp)))
2296                           `(let ((,,temp ,,spec))
2297                              ,,@body))))))
2298
2299   (define-source-transform ldb (spec int)
2300     (with-byte-specifier (size pos spec)
2301       `(%ldb ,size ,pos ,int)))
2302
2303   (define-source-transform dpb (newbyte spec int)
2304     (with-byte-specifier (size pos spec)
2305       `(%dpb ,newbyte ,size ,pos ,int)))
2306
2307   (define-source-transform mask-field (spec int)
2308     (with-byte-specifier (size pos spec)
2309       `(%mask-field ,size ,pos ,int)))
2310
2311   (define-source-transform deposit-field (newbyte spec int)
2312     (with-byte-specifier (size pos spec)
2313       `(%deposit-field ,newbyte ,size ,pos ,int))))
2314
2315 (defoptimizer (%ldb derive-type) ((size posn num))
2316   (let ((size (continuation-type size)))
2317     (if (and (numeric-type-p size)
2318              (csubtypep size (specifier-type 'integer)))
2319         (let ((size-high (numeric-type-high size)))
2320           (if (and size-high (<= size-high sb!vm:n-word-bits))
2321               (specifier-type `(unsigned-byte ,size-high))
2322               (specifier-type 'unsigned-byte)))
2323         *universal-type*)))
2324
2325 (defoptimizer (%mask-field derive-type) ((size posn num))
2326   (let ((size (continuation-type size))
2327         (posn (continuation-type posn)))
2328     (if (and (numeric-type-p size)
2329              (csubtypep size (specifier-type 'integer))
2330              (numeric-type-p posn)
2331              (csubtypep posn (specifier-type 'integer)))
2332         (let ((size-high (numeric-type-high size))
2333               (posn-high (numeric-type-high posn)))
2334           (if (and size-high posn-high
2335                    (<= (+ size-high posn-high) sb!vm:n-word-bits))
2336               (specifier-type `(unsigned-byte ,(+ size-high posn-high)))
2337               (specifier-type 'unsigned-byte)))
2338         *universal-type*)))
2339
2340 (defoptimizer (%dpb derive-type) ((newbyte size posn int))
2341   (let ((size (continuation-type size))
2342         (posn (continuation-type posn))
2343         (int (continuation-type int)))
2344     (if (and (numeric-type-p size)
2345              (csubtypep size (specifier-type 'integer))
2346              (numeric-type-p posn)
2347              (csubtypep posn (specifier-type 'integer))
2348              (numeric-type-p int)
2349              (csubtypep int (specifier-type 'integer)))
2350         (let ((size-high (numeric-type-high size))
2351               (posn-high (numeric-type-high posn))
2352               (high (numeric-type-high int))
2353               (low (numeric-type-low int)))
2354           (if (and size-high posn-high high low
2355                    (<= (+ size-high posn-high) sb!vm:n-word-bits))
2356               (specifier-type
2357                (list (if (minusp low) 'signed-byte 'unsigned-byte)
2358                      (max (integer-length high)
2359                           (integer-length low)
2360                           (+ size-high posn-high))))
2361               *universal-type*))
2362         *universal-type*)))
2363
2364 (defoptimizer (%deposit-field derive-type) ((newbyte size posn int))
2365   (let ((size (continuation-type size))
2366         (posn (continuation-type posn))
2367         (int (continuation-type int)))
2368     (if (and (numeric-type-p size)
2369              (csubtypep size (specifier-type 'integer))
2370              (numeric-type-p posn)
2371              (csubtypep posn (specifier-type 'integer))
2372              (numeric-type-p int)
2373              (csubtypep int (specifier-type 'integer)))
2374         (let ((size-high (numeric-type-high size))
2375               (posn-high (numeric-type-high posn))
2376               (high (numeric-type-high int))
2377               (low (numeric-type-low int)))
2378           (if (and size-high posn-high high low
2379                    (<= (+ size-high posn-high) sb!vm:n-word-bits))
2380               (specifier-type
2381                (list (if (minusp low) 'signed-byte 'unsigned-byte)
2382                      (max (integer-length high)
2383                           (integer-length low)
2384                           (+ size-high posn-high))))
2385               *universal-type*))
2386         *universal-type*)))
2387
2388 (deftransform %ldb ((size posn int)
2389                     (fixnum fixnum integer)
2390                     (unsigned-byte #.sb!vm:n-word-bits))
2391   "convert to inline logical operations"
2392   `(logand (ash int (- posn))
2393            (ash ,(1- (ash 1 sb!vm:n-word-bits))
2394                 (- size ,sb!vm:n-word-bits))))
2395
2396 (deftransform %mask-field ((size posn int)
2397                            (fixnum fixnum integer)
2398                            (unsigned-byte #.sb!vm:n-word-bits))
2399   "convert to inline logical operations"
2400   `(logand int
2401            (ash (ash ,(1- (ash 1 sb!vm:n-word-bits))
2402                      (- size ,sb!vm:n-word-bits))
2403                 posn)))
2404
2405 ;;; Note: for %DPB and %DEPOSIT-FIELD, we can't use
2406 ;;;   (OR (SIGNED-BYTE N) (UNSIGNED-BYTE N))
2407 ;;; as the result type, as that would allow result types that cover
2408 ;;; the range -2^(n-1) .. 1-2^n, instead of allowing result types of
2409 ;;; (UNSIGNED-BYTE N) and result types of (SIGNED-BYTE N).
2410
2411 (deftransform %dpb ((new size posn int)
2412                     *
2413                     (unsigned-byte #.sb!vm:n-word-bits))
2414   "convert to inline logical operations"
2415   `(let ((mask (ldb (byte size 0) -1)))
2416      (logior (ash (logand new mask) posn)
2417              (logand int (lognot (ash mask posn))))))
2418
2419 (deftransform %dpb ((new size posn int)
2420                     *
2421                     (signed-byte #.sb!vm:n-word-bits))
2422   "convert to inline logical operations"
2423   `(let ((mask (ldb (byte size 0) -1)))
2424      (logior (ash (logand new mask) posn)
2425              (logand int (lognot (ash mask posn))))))
2426
2427 (deftransform %deposit-field ((new size posn int)
2428                               *
2429                               (unsigned-byte #.sb!vm:n-word-bits))
2430   "convert to inline logical operations"
2431   `(let ((mask (ash (ldb (byte size 0) -1) posn)))
2432      (logior (logand new mask)
2433              (logand int (lognot mask)))))
2434
2435 (deftransform %deposit-field ((new size posn int)
2436                               *
2437                               (signed-byte #.sb!vm:n-word-bits))
2438   "convert to inline logical operations"
2439   `(let ((mask (ash (ldb (byte size 0) -1) posn)))
2440      (logior (logand new mask)
2441              (logand int (lognot mask)))))
2442 \f
2443 ;;; Modular functions
2444
2445 ;;; (ldb (byte s 0) (foo x y ...)) =
2446 ;;; (ldb (byte s 0) (foo (ldb (byte s 0) x) y ...))
2447 ;;;
2448 ;;; and similar for other arguments. If
2449 ;;;
2450 ;;; (ldb (byte s 0) (foo x y ...)) =
2451 ;;; (foo (ldb (byte s 0) x) (ldb (byte s 0) y) ...)
2452 ;;;
2453 ;;; the function FOO is :GOOD.
2454
2455 ;;; Try to recursively cut all uses of the continuation CONT to WIDTH
2456 ;;; bits.
2457 (defun cut-to-width (cont width)
2458   (declare (type continuation cont) (type (integer 0) width))
2459   (labels ((reoptimize-node (node name)
2460              (setf (node-derived-type node)
2461                    (fun-type-returns
2462                     (info :function :type name)))
2463              (setf (continuation-%derived-type (node-cont node)) nil)
2464              (setf (node-reoptimize node) t)
2465              (setf (block-reoptimize (node-block node)) t)
2466              (setf (component-reoptimize (node-component node)) t))
2467            (cut-node (node &aux did-something)
2468              (when (and (combination-p node)
2469                         (fun-info-p (basic-combination-kind node)))
2470                (let* ((fun-ref (continuation-use (combination-fun node)))
2471                       (fun-name (leaf-source-name (ref-leaf fun-ref)))
2472                       (modular-fun (find-modular-version fun-name width))
2473                       (name (and (modular-fun-info-p modular-fun)
2474                                  (modular-fun-info-name modular-fun))))
2475                  (when (and modular-fun
2476                             (not (and (eq name 'logand)
2477                                       (csubtypep
2478                                        (single-value-type (node-derived-type node))
2479                                        (specifier-type `(unsigned-byte ,width))))))
2480                    (unless (eq modular-fun :good)
2481                      (setq did-something t)
2482                      (change-ref-leaf
2483                         fun-ref
2484                         (find-free-fun name "in a strange place"))
2485                        (setf (combination-kind node) :full))
2486                    (dolist (arg (basic-combination-args node))
2487                      (when (cut-continuation arg)
2488                        (setq did-something t)))
2489                    (when did-something
2490                      (reoptimize-node node fun-name))
2491                    did-something))))
2492            (cut-continuation (cont &aux did-something)
2493              (do-uses (node cont)
2494                (when (cut-node node)
2495                  (setq did-something t)))
2496              did-something))
2497     (cut-continuation cont)))
2498
2499 (defoptimizer (logand optimizer) ((x y) node)
2500   (let ((result-type (single-value-type (node-derived-type node))))
2501     (when (numeric-type-p result-type)
2502       (let ((low (numeric-type-low result-type))
2503             (high (numeric-type-high result-type)))
2504         (when (and (numberp low)
2505                    (numberp high)
2506                    (>= low 0))
2507           (let ((width (integer-length high)))
2508             (when (some (lambda (x) (<= width x))
2509                         *modular-funs-widths*)
2510               ;; FIXME: This should be (CUT-TO-WIDTH NODE WIDTH).
2511               (cut-to-width x width)
2512               (cut-to-width y width)
2513               nil ; After fixing above, replace with T.
2514               )))))))
2515 \f
2516 ;;; miscellanous numeric transforms
2517
2518 ;;; If a constant appears as the first arg, swap the args.
2519 (deftransform commutative-arg-swap ((x y) * * :defun-only t :node node)
2520   (if (and (constant-continuation-p x)
2521            (not (constant-continuation-p y)))
2522       `(,(continuation-fun-name (basic-combination-fun node))
2523         y
2524         ,(continuation-value x))
2525       (give-up-ir1-transform)))
2526
2527 (dolist (x '(= char= + * logior logand logxor))
2528   (%deftransform x '(function * *) #'commutative-arg-swap
2529                  "place constant arg last"))
2530
2531 ;;; Handle the case of a constant BOOLE-CODE.
2532 (deftransform boole ((op x y) * *)
2533   "convert to inline logical operations"
2534   (unless (constant-continuation-p op)
2535     (give-up-ir1-transform "BOOLE code is not a constant."))
2536   (let ((control (continuation-value op)))
2537     (case control
2538       (#.boole-clr 0)
2539       (#.boole-set -1)
2540       (#.boole-1 'x)
2541       (#.boole-2 'y)
2542       (#.boole-c1 '(lognot x))
2543       (#.boole-c2 '(lognot y))
2544       (#.boole-and '(logand x y))
2545       (#.boole-ior '(logior x y))
2546       (#.boole-xor '(logxor x y))
2547       (#.boole-eqv '(logeqv x y))
2548       (#.boole-nand '(lognand x y))
2549       (#.boole-nor '(lognor x y))
2550       (#.boole-andc1 '(logandc1 x y))
2551       (#.boole-andc2 '(logandc2 x y))
2552       (#.boole-orc1 '(logorc1 x y))
2553       (#.boole-orc2 '(logorc2 x y))
2554       (t
2555        (abort-ir1-transform "~S is an illegal control arg to BOOLE."
2556                             control)))))
2557 \f
2558 ;;;; converting special case multiply/divide to shifts
2559
2560 ;;; If arg is a constant power of two, turn * into a shift.
2561 (deftransform * ((x y) (integer integer) *)
2562   "convert x*2^k to shift"
2563   (unless (constant-continuation-p y)
2564     (give-up-ir1-transform))
2565   (let* ((y (continuation-value y))
2566          (y-abs (abs y))
2567          (len (1- (integer-length y-abs))))
2568     (unless (= y-abs (ash 1 len))
2569       (give-up-ir1-transform))
2570     (if (minusp y)
2571         `(- (ash x ,len))
2572         `(ash x ,len))))
2573
2574 ;;; If both arguments and the result are (UNSIGNED-BYTE 32), try to
2575 ;;; come up with a ``better'' multiplication using multiplier
2576 ;;; recoding. There are two different ways the multiplier can be
2577 ;;; recoded. The more obvious is to shift X by the correct amount for
2578 ;;; each bit set in Y and to sum the results. But if there is a string
2579 ;;; of bits that are all set, you can add X shifted by one more then
2580 ;;; the bit position of the first set bit and subtract X shifted by
2581 ;;; the bit position of the last set bit. We can't use this second
2582 ;;; method when the high order bit is bit 31 because shifting by 32
2583 ;;; doesn't work too well.
2584 (deftransform * ((x y)
2585                  ((unsigned-byte 32) (unsigned-byte 32))
2586                  (unsigned-byte 32))
2587   "recode as shift and add"
2588   (unless (constant-continuation-p y)
2589     (give-up-ir1-transform))
2590   (let ((y (continuation-value y))
2591         (result nil)
2592         (first-one nil))
2593     (labels ((tub32 (x) `(truly-the (unsigned-byte 32) ,x))
2594              (add (next-factor)
2595                (setf result
2596                      (tub32
2597                       (if result
2598                           `(+ ,result ,(tub32 next-factor))
2599                           next-factor)))))
2600       (declare (inline add))
2601       (dotimes (bitpos 32)
2602         (if first-one
2603             (when (not (logbitp bitpos y))
2604               (add (if (= (1+ first-one) bitpos)
2605                        ;; There is only a single bit in the string.
2606                        `(ash x ,first-one)
2607                        ;; There are at least two.
2608                        `(- ,(tub32 `(ash x ,bitpos))
2609                            ,(tub32 `(ash x ,first-one)))))
2610               (setf first-one nil))
2611             (when (logbitp bitpos y)
2612               (setf first-one bitpos))))
2613       (when first-one
2614         (cond ((= first-one 31))
2615               ((= first-one 30)
2616                (add '(ash x 30)))
2617               (t
2618                (add `(- ,(tub32 '(ash x 31)) ,(tub32 `(ash x ,first-one))))))
2619         (add '(ash x 31))))
2620     (or result 0)))
2621
2622 ;;; If arg is a constant power of two, turn FLOOR into a shift and
2623 ;;; mask. If CEILING, add in (1- (ABS Y)), do FLOOR and correct a
2624 ;;; remainder.
2625 (flet ((frob (y ceil-p)
2626          (unless (constant-continuation-p y)
2627            (give-up-ir1-transform))
2628          (let* ((y (continuation-value y))
2629                 (y-abs (abs y))
2630                 (len (1- (integer-length y-abs))))
2631            (unless (= y-abs (ash 1 len))
2632              (give-up-ir1-transform))
2633            (let ((shift (- len))
2634                  (mask (1- y-abs))
2635                  (delta (if ceil-p (* (signum y) (1- y-abs)) 0)))
2636              `(let ((x (+ x ,delta)))
2637                 ,(if (minusp y)
2638                      `(values (ash (- x) ,shift)
2639                               (- (- (logand (- x) ,mask)) ,delta))
2640                      `(values (ash x ,shift)
2641                               (- (logand x ,mask) ,delta))))))))
2642   (deftransform floor ((x y) (integer integer) *)
2643     "convert division by 2^k to shift"
2644     (frob y nil))
2645   (deftransform ceiling ((x y) (integer integer) *)
2646     "convert division by 2^k to shift"
2647     (frob y t)))
2648
2649 ;;; Do the same for MOD.
2650 (deftransform mod ((x y) (integer integer) *)
2651   "convert remainder mod 2^k to LOGAND"
2652   (unless (constant-continuation-p y)
2653     (give-up-ir1-transform))
2654   (let* ((y (continuation-value y))
2655          (y-abs (abs y))
2656          (len (1- (integer-length y-abs))))
2657     (unless (= y-abs (ash 1 len))
2658       (give-up-ir1-transform))
2659     (let ((mask (1- y-abs)))
2660       (if (minusp y)
2661           `(- (logand (- x) ,mask))
2662           `(logand x ,mask)))))
2663
2664 ;;; If arg is a constant power of two, turn TRUNCATE into a shift and mask.
2665 (deftransform truncate ((x y) (integer integer))
2666   "convert division by 2^k to shift"
2667   (unless (constant-continuation-p y)
2668     (give-up-ir1-transform))
2669   (let* ((y (continuation-value y))
2670          (y-abs (abs y))
2671          (len (1- (integer-length y-abs))))
2672     (unless (= y-abs (ash 1 len))
2673       (give-up-ir1-transform))
2674     (let* ((shift (- len))
2675            (mask (1- y-abs)))
2676       `(if (minusp x)
2677            (values ,(if (minusp y)
2678                         `(ash (- x) ,shift)
2679                         `(- (ash (- x) ,shift)))
2680                    (- (logand (- x) ,mask)))
2681            (values ,(if (minusp y)
2682                         `(- (ash (- x) ,shift))
2683                         `(ash x ,shift))
2684                    (logand x ,mask))))))
2685
2686 ;;; And the same for REM.
2687 (deftransform rem ((x y) (integer integer) *)
2688   "convert remainder mod 2^k to LOGAND"
2689   (unless (constant-continuation-p y)
2690     (give-up-ir1-transform))
2691   (let* ((y (continuation-value y))
2692          (y-abs (abs y))
2693          (len (1- (integer-length y-abs))))
2694     (unless (= y-abs (ash 1 len))
2695       (give-up-ir1-transform))
2696     (let ((mask (1- y-abs)))
2697       `(if (minusp x)
2698            (- (logand (- x) ,mask))
2699            (logand x ,mask)))))
2700 \f
2701 ;;;; arithmetic and logical identity operation elimination
2702
2703 ;;; Flush calls to various arith functions that convert to the
2704 ;;; identity function or a constant.
2705 (macrolet ((def (name identity result)
2706              `(deftransform ,name ((x y) (* (constant-arg (member ,identity))) *)
2707                 "fold identity operations"
2708                 ',result)))
2709   (def ash 0 x)
2710   (def logand -1 x)
2711   (def logand 0 0)
2712   (def logior 0 x)
2713   (def logior -1 -1)
2714   (def logxor -1 (lognot x))
2715   (def logxor 0 x))
2716
2717 (deftransform logand ((x y) (* (constant-arg t)) *)
2718   "fold identity operation"
2719   (let ((y (continuation-value y)))
2720     (unless (and (plusp y)
2721                  (= y (1- (ash 1 (integer-length y)))))
2722       (give-up-ir1-transform))
2723     (unless (csubtypep (continuation-type x)
2724                        (specifier-type `(integer 0 ,y)))
2725       (give-up-ir1-transform))
2726     'x))
2727
2728 ;;; These are restricted to rationals, because (- 0 0.0) is 0.0, not -0.0, and
2729 ;;; (* 0 -4.0) is -0.0.
2730 (deftransform - ((x y) ((constant-arg (member 0)) rational) *)
2731   "convert (- 0 x) to negate"
2732   '(%negate y))
2733 (deftransform * ((x y) (rational (constant-arg (member 0))) *)
2734   "convert (* x 0) to 0"
2735   0)
2736
2737 ;;; Return T if in an arithmetic op including continuations X and Y,
2738 ;;; the result type is not affected by the type of X. That is, Y is at
2739 ;;; least as contagious as X.
2740 #+nil
2741 (defun not-more-contagious (x y)
2742   (declare (type continuation x y))
2743   (let ((x (continuation-type x))
2744         (y (continuation-type y)))
2745     (values (type= (numeric-contagion x y)
2746                    (numeric-contagion y y)))))
2747 ;;; Patched version by Raymond Toy. dtc: Should be safer although it
2748 ;;; XXX needs more work as valid transforms are missed; some cases are
2749 ;;; specific to particular transform functions so the use of this
2750 ;;; function may need a re-think.
2751 (defun not-more-contagious (x y)
2752   (declare (type continuation x y))
2753   (flet ((simple-numeric-type (num)
2754            (and (numeric-type-p num)
2755                 ;; Return non-NIL if NUM is integer, rational, or a float
2756                 ;; of some type (but not FLOAT)
2757                 (case (numeric-type-class num)
2758                   ((integer rational)
2759                    t)
2760                   (float
2761                    (numeric-type-format num))
2762                   (t
2763                    nil)))))
2764     (let ((x (continuation-type x))
2765           (y (continuation-type y)))
2766       (if (and (simple-numeric-type x)
2767                (simple-numeric-type y))
2768           (values (type= (numeric-contagion x y)
2769                          (numeric-contagion y y)))))))
2770
2771 ;;; Fold (+ x 0).
2772 ;;;
2773 ;;; If y is not constant, not zerop, or is contagious, or a positive
2774 ;;; float +0.0 then give up.
2775 (deftransform + ((x y) (t (constant-arg t)) *)
2776   "fold zero arg"
2777   (let ((val (continuation-value y)))
2778     (unless (and (zerop val)
2779                  (not (and (floatp val) (plusp (float-sign val))))
2780                  (not-more-contagious y x))
2781       (give-up-ir1-transform)))
2782   'x)
2783
2784 ;;; Fold (- x 0).
2785 ;;;
2786 ;;; If y is not constant, not zerop, or is contagious, or a negative
2787 ;;; float -0.0 then give up.
2788 (deftransform - ((x y) (t (constant-arg t)) *)
2789   "fold zero arg"
2790   (let ((val (continuation-value y)))
2791     (unless (and (zerop val)
2792                  (not (and (floatp val) (minusp (float-sign val))))
2793                  (not-more-contagious y x))
2794       (give-up-ir1-transform)))
2795   'x)
2796
2797 ;;; Fold (OP x +/-1)
2798 (macrolet ((def (name result minus-result)
2799              `(deftransform ,name ((x y) (t (constant-arg real)) *)
2800                 "fold identity operations"
2801                 (let ((val (continuation-value y)))
2802                   (unless (and (= (abs val) 1)
2803                                (not-more-contagious y x))
2804                     (give-up-ir1-transform))
2805                   (if (minusp val) ',minus-result ',result)))))
2806   (def * x (%negate x))
2807   (def / x (%negate x))
2808   (def expt x (/ 1 x)))
2809
2810 ;;; Fold (expt x n) into multiplications for small integral values of
2811 ;;; N; convert (expt x 1/2) to sqrt.
2812 (deftransform expt ((x y) (t (constant-arg real)) *)
2813   "recode as multiplication or sqrt"
2814   (let ((val (continuation-value y)))
2815     ;; If Y would cause the result to be promoted to the same type as
2816     ;; Y, we give up. If not, then the result will be the same type
2817     ;; as X, so we can replace the exponentiation with simple
2818     ;; multiplication and division for small integral powers.
2819     (unless (not-more-contagious y x)
2820       (give-up-ir1-transform))
2821     (cond ((zerop val) '(float 1 x))
2822           ((= val 2) '(* x x))
2823           ((= val -2) '(/ (* x x)))
2824           ((= val 3) '(* x x x))
2825           ((= val -3) '(/ (* x x x)))
2826           ((= val 1/2) '(sqrt x))
2827           ((= val -1/2) '(/ (sqrt x)))
2828           (t (give-up-ir1-transform)))))
2829
2830 ;;; KLUDGE: Shouldn't (/ 0.0 0.0), etc. cause exceptions in these
2831 ;;; transformations?
2832 ;;; Perhaps we should have to prove that the denominator is nonzero before
2833 ;;; doing them?  -- WHN 19990917
2834 (macrolet ((def (name)
2835              `(deftransform ,name ((x y) ((constant-arg (integer 0 0)) integer)
2836                                    *)
2837                 "fold zero arg"
2838                 0)))
2839   (def ash)
2840   (def /))
2841
2842 (macrolet ((def (name)
2843              `(deftransform ,name ((x y) ((constant-arg (integer 0 0)) integer)
2844                                    *)
2845                 "fold zero arg"
2846                 '(values 0 0))))
2847   (def truncate)
2848   (def round)
2849   (def floor)
2850   (def ceiling))
2851 \f
2852 ;;;; character operations
2853
2854 (deftransform char-equal ((a b) (base-char base-char))
2855   "open code"
2856   '(let* ((ac (char-code a))
2857           (bc (char-code b))
2858           (sum (logxor ac bc)))
2859      (or (zerop sum)
2860          (when (eql sum #x20)
2861            (let ((sum (+ ac bc)))
2862              (and (> sum 161) (< sum 213)))))))
2863
2864 (deftransform char-upcase ((x) (base-char))
2865   "open code"
2866   '(let ((n-code (char-code x)))
2867      (if (and (> n-code #o140)  ; Octal 141 is #\a.
2868               (< n-code #o173)) ; Octal 172 is #\z.
2869          (code-char (logxor #x20 n-code))
2870          x)))
2871
2872 (deftransform char-downcase ((x) (base-char))
2873   "open code"
2874   '(let ((n-code (char-code x)))
2875      (if (and (> n-code 64)     ; 65 is #\A.
2876               (< n-code 91))    ; 90 is #\Z.
2877          (code-char (logxor #x20 n-code))
2878          x)))
2879 \f
2880 ;;;; equality predicate transforms
2881
2882 ;;; Return true if X and Y are continuations whose only use is a
2883 ;;; reference to the same leaf, and the value of the leaf cannot
2884 ;;; change.
2885 (defun same-leaf-ref-p (x y)
2886   (declare (type continuation x y))
2887   (let ((x-use (continuation-use x))
2888         (y-use (continuation-use y)))
2889     (and (ref-p x-use)
2890          (ref-p y-use)
2891          (eq (ref-leaf x-use) (ref-leaf y-use))
2892          (constant-reference-p x-use))))
2893
2894 ;;; If X and Y are the same leaf, then the result is true. Otherwise,
2895 ;;; if there is no intersection between the types of the arguments,
2896 ;;; then the result is definitely false.
2897 (deftransform simple-equality-transform ((x y) * *
2898                                          :defun-only t)
2899   (cond ((same-leaf-ref-p x y)
2900          t)
2901         ((not (types-equal-or-intersect (continuation-type x)
2902                                         (continuation-type y)))
2903          nil)
2904         (t
2905          (give-up-ir1-transform))))
2906
2907 (macrolet ((def (x)
2908              `(%deftransform ',x '(function * *) #'simple-equality-transform)))
2909   (def eq)
2910   (def char=)
2911   (def equal))
2912
2913 ;;; This is similar to SIMPLE-EQUALITY-PREDICATE, except that we also
2914 ;;; try to convert to a type-specific predicate or EQ:
2915 ;;; -- If both args are characters, convert to CHAR=. This is better than
2916 ;;;    just converting to EQ, since CHAR= may have special compilation
2917 ;;;    strategies for non-standard representations, etc.
2918 ;;; -- If either arg is definitely not a number, then we can compare
2919 ;;;    with EQ.
2920 ;;; -- Otherwise, we try to put the arg we know more about second. If X
2921 ;;;    is constant then we put it second. If X is a subtype of Y, we put
2922 ;;;    it second. These rules make it easier for the back end to match
2923 ;;;    these interesting cases.
2924 ;;; -- If Y is a fixnum, then we quietly pass because the back end can
2925 ;;;    handle that case, otherwise give an efficiency note.
2926 (deftransform eql ((x y) * *)
2927   "convert to simpler equality predicate"
2928   (let ((x-type (continuation-type x))
2929         (y-type (continuation-type y))
2930         (char-type (specifier-type 'character))
2931         (number-type (specifier-type 'number)))
2932     (cond ((same-leaf-ref-p x y)
2933            t)
2934           ((not (types-equal-or-intersect x-type y-type))
2935            nil)
2936           ((and (csubtypep x-type char-type)
2937                 (csubtypep y-type char-type))
2938            '(char= x y))
2939           ((or (not (types-equal-or-intersect x-type number-type))
2940                (not (types-equal-or-intersect y-type number-type)))
2941            '(eq x y))
2942           ((and (not (constant-continuation-p y))
2943                 (or (constant-continuation-p x)
2944                     (and (csubtypep x-type y-type)
2945                          (not (csubtypep y-type x-type)))))
2946            '(eql y x))
2947           (t
2948            (give-up-ir1-transform)))))
2949
2950 ;;; Convert to EQL if both args are rational and complexp is specified
2951 ;;; and the same for both.
2952 (deftransform = ((x y) * *)
2953   "open code"
2954   (let ((x-type (continuation-type x))
2955         (y-type (continuation-type y)))
2956     (if (and (csubtypep x-type (specifier-type 'number))
2957              (csubtypep y-type (specifier-type 'number)))
2958         (cond ((or (and (csubtypep x-type (specifier-type 'float))
2959                         (csubtypep y-type (specifier-type 'float)))
2960                    (and (csubtypep x-type (specifier-type '(complex float)))
2961                         (csubtypep y-type (specifier-type '(complex float)))))
2962                ;; They are both floats. Leave as = so that -0.0 is
2963                ;; handled correctly.
2964                (give-up-ir1-transform))
2965               ((or (and (csubtypep x-type (specifier-type 'rational))
2966                         (csubtypep y-type (specifier-type 'rational)))
2967                    (and (csubtypep x-type
2968                                    (specifier-type '(complex rational)))
2969                         (csubtypep y-type
2970                                    (specifier-type '(complex rational)))))
2971                ;; They are both rationals and complexp is the same.
2972                ;; Convert to EQL.
2973                '(eql x y))
2974               (t
2975                (give-up-ir1-transform
2976                 "The operands might not be the same type.")))
2977         (give-up-ir1-transform
2978          "The operands might not be the same type."))))
2979
2980 ;;; If CONT's type is a numeric type, then return the type, otherwise
2981 ;;; GIVE-UP-IR1-TRANSFORM.
2982 (defun numeric-type-or-lose (cont)
2983   (declare (type continuation cont))
2984   (let ((res (continuation-type cont)))
2985     (unless (numeric-type-p res) (give-up-ir1-transform))
2986     res))
2987
2988 ;;; See whether we can statically determine (< X Y) using type
2989 ;;; information. If X's high bound is < Y's low, then X < Y.
2990 ;;; Similarly, if X's low is >= to Y's high, the X >= Y (so return
2991 ;;; NIL). If not, at least make sure any constant arg is second.
2992 ;;;
2993 ;;; FIXME: Why should constant argument be second? It would be nice to
2994 ;;; find out and explain.
2995 #+sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
2996 (defun ir1-transform-< (x y first second inverse)
2997   (if (same-leaf-ref-p x y)
2998       nil
2999       (let* ((x-type (numeric-type-or-lose x))
3000              (x-lo (numeric-type-low x-type))
3001              (x-hi (numeric-type-high x-type))
3002              (y-type (numeric-type-or-lose y))
3003              (y-lo (numeric-type-low y-type))
3004              (y-hi (numeric-type-high y-type)))
3005         (cond ((and x-hi y-lo (< x-hi y-lo))
3006                t)
3007               ((and y-hi x-lo (>= x-lo y-hi))
3008                nil)
3009               ((and (constant-continuation-p first)
3010                     (not (constant-continuation-p second)))
3011                `(,inverse y x))
3012               (t
3013                (give-up-ir1-transform))))))
3014 #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
3015 (defun ir1-transform-< (x y first second inverse)
3016   (if (same-leaf-ref-p x y)
3017       nil
3018       (let ((xi (numeric-type->interval (numeric-type-or-lose x)))
3019             (yi (numeric-type->interval (numeric-type-or-lose y))))
3020         (cond ((interval-< xi yi)
3021                t)
3022               ((interval->= xi yi)
3023                nil)
3024               ((and (constant-continuation-p first)
3025                     (not (constant-continuation-p second)))
3026                `(,inverse y x))
3027               (t
3028                (give-up-ir1-transform))))))
3029
3030 (deftransform < ((x y) (integer integer) *)
3031   (ir1-transform-< x y x y '>))
3032
3033 (deftransform > ((x y) (integer integer) *)
3034   (ir1-transform-< y x x y '<))
3035
3036 #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
3037 (deftransform < ((x y) (float float) *)
3038   (ir1-transform-< x y x y '>))
3039
3040 #-sb-xc-host ; (See CROSS-FLOAT-INFINITY-KLUDGE.)
3041 (deftransform > ((x y) (float float) *)
3042   (ir1-transform-< y x x y '<))
3043
3044 (defun ir1-transform-char< (x y first second inverse)
3045   (cond
3046     ((same-leaf-ref-p x y) nil)
3047     ;; If we had interval representation of character types, as we
3048     ;; might eventually have to to support 2^21 characters, then here
3049     ;; we could do some compile-time computation as in IR1-TRANSFORM-<
3050     ;; above.  -- CSR, 2003-07-01
3051     ((and (constant-continuation-p first)
3052           (not (constant-continuation-p second)))
3053      `(,inverse y x))
3054     (t (give-up-ir1-transform))))
3055
3056 (deftransform char< ((x y) (character character) *)
3057   (ir1-transform-char< x y x y 'char>))
3058
3059 (deftransform char> ((x y) (character character) *)
3060   (ir1-transform-char< y x x y 'char<))
3061 \f
3062 ;;;; converting N-arg comparisons
3063 ;;;;
3064 ;;;; We convert calls to N-arg comparison functions such as < into
3065 ;;;; two-arg calls. This transformation is enabled for all such
3066 ;;;; comparisons in this file. If any of these predicates are not
3067 ;;;; open-coded, then the transformation should be removed at some
3068 ;;;; point to avoid pessimization.
3069
3070 ;;; This function is used for source transformation of N-arg
3071 ;;; comparison functions other than inequality. We deal both with
3072 ;;; converting to two-arg calls and inverting the sense of the test,
3073 ;;; if necessary. If the call has two args, then we pass or return a
3074 ;;; negated test as appropriate. If it is a degenerate one-arg call,
3075 ;;; then we transform to code that returns true. Otherwise, we bind
3076 ;;; all the arguments and expand into a bunch of IFs.
3077 (declaim (ftype (function (symbol list boolean t) *) multi-compare))
3078 (defun multi-compare (predicate args not-p type)
3079   (let ((nargs (length args)))
3080     (cond ((< nargs 1) (values nil t))
3081           ((= nargs 1) `(progn (the ,type ,@args) t))
3082           ((= nargs 2)
3083            (if not-p
3084                `(if (,predicate ,(first args) ,(second args)) nil t)
3085                (values nil t)))
3086           (t
3087            (do* ((i (1- nargs) (1- i))
3088                  (last nil current)
3089                  (current (gensym) (gensym))
3090                  (vars (list current) (cons current vars))
3091                  (result t (if not-p
3092                                `(if (,predicate ,current ,last)
3093                                     nil ,result)
3094                                `(if (,predicate ,current ,last)
3095                                     ,result nil))))
3096                ((zerop i)
3097                 `((lambda ,vars (declare (type ,type ,@vars)) ,result)
3098                   ,@args)))))))
3099
3100 (define-source-transform = (&rest args) (multi-compare '= args nil 'number))
3101 (define-source-transform < (&rest args) (multi-compare '< args nil 'real))
3102 (define-source-transform > (&rest args) (multi-compare '> args nil 'real))
3103 (define-source-transform <= (&rest args) (multi-compare '> args t 'real))
3104 (define-source-transform >= (&rest args) (multi-compare '< args t 'real))
3105
3106 (define-source-transform char= (&rest args) (multi-compare 'char= args nil
3107                                                            'character))
3108 (define-source-transform char< (&rest args) (multi-compare 'char< args nil
3109                                                            'character))
3110 (define-source-transform char> (&rest args) (multi-compare 'char> args nil
3111                                                            'character))
3112 (define-source-transform char<= (&rest args) (multi-compare 'char> args t
3113                                                             'character))
3114 (define-source-transform char>= (&rest args) (multi-compare 'char< args t
3115                                                             'character))
3116
3117 (define-source-transform char-equal (&rest args)
3118   (multi-compare 'char-equal args nil 'character))
3119 (define-source-transform char-lessp (&rest args)
3120   (multi-compare 'char-lessp args nil 'character))
3121 (define-source-transform char-greaterp (&rest args)
3122   (multi-compare 'char-greaterp args nil 'character))
3123 (define-source-transform char-not-greaterp (&rest args)
3124   (multi-compare 'char-greaterp args t 'character))
3125 (define-source-transform char-not-lessp (&rest args)
3126   (multi-compare 'char-lessp args t 'character))
3127
3128 ;;; This function does source transformation of N-arg inequality
3129 ;;; functions such as /=. This is similar to MULTI-COMPARE in the <3
3130 ;;; arg cases. If there are more than two args, then we expand into
3131 ;;; the appropriate n^2 comparisons only when speed is important.
3132 (declaim (ftype (function (symbol list t) *) multi-not-equal))
3133 (defun multi-not-equal (predicate args type)
3134   (let ((nargs (length args)))
3135     (cond ((< nargs 1) (values nil t))
3136           ((= nargs 1) `(progn (the ,type ,@args) t))
3137           ((= nargs 2)
3138            `(if (,predicate ,(first args) ,(second args)) nil t))
3139           ((not (policy *lexenv*
3140                         (and (>= speed space)
3141                              (>= speed compilation-speed))))
3142            (values nil t))
3143           (t
3144            (let ((vars (make-gensym-list nargs)))
3145              (do ((var vars next)
3146                   (next (cdr vars) (cdr next))
3147                   (result t))
3148                  ((null next)
3149                   `((lambda ,vars (declare (type ,type ,@vars)) ,result)
3150                     ,@args))
3151                (let ((v1 (first var)))
3152                  (dolist (v2 next)
3153                    (setq result `(if (,predicate ,v1 ,v2) nil ,result))))))))))
3154
3155 (define-source-transform /= (&rest args)
3156   (multi-not-equal '= args 'number))
3157 (define-source-transform char/= (&rest args)
3158   (multi-not-equal 'char= args 'character))
3159 (define-source-transform char-not-equal (&rest args)
3160   (multi-not-equal 'char-equal args 'character))
3161
3162 ;;; Expand MAX and MIN into the obvious comparisons.
3163 (define-source-transform max (arg0 &rest rest)
3164   (once-only ((arg0 arg0))
3165     (if (null rest)
3166         `(values (the real ,arg0))
3167         `(let ((maxrest (max ,@rest)))
3168           (if (> ,arg0 maxrest) ,arg0 maxrest)))))
3169 (define-source-transform min (arg0 &rest rest)
3170   (once-only ((arg0 arg0))
3171     (if (null rest)
3172         `(values (the real ,arg0))
3173         `(let ((minrest (min ,@rest)))
3174           (if (< ,arg0 minrest) ,arg0 minrest)))))
3175 \f
3176 ;;;; converting N-arg arithmetic functions
3177 ;;;;
3178 ;;;; N-arg arithmetic and logic functions are associated into two-arg
3179 ;;;; versions, and degenerate cases are flushed.
3180
3181 ;;; Left-associate FIRST-ARG and MORE-ARGS using FUNCTION.
3182 (declaim (ftype (function (symbol t list) list) associate-args))
3183 (defun associate-args (function first-arg more-args)
3184   (let ((next (rest more-args))
3185         (arg (first more-args)))
3186     (if (null next)
3187         `(,function ,first-arg ,arg)
3188         (associate-args function `(,function ,first-arg ,arg) next))))
3189
3190 ;;; Do source transformations for transitive functions such as +.
3191 ;;; One-arg cases are replaced with the arg and zero arg cases with
3192 ;;; the identity.  ONE-ARG-RESULT-TYPE is, if non-NIL, the type to
3193 ;;; ensure (with THE) that the argument in one-argument calls is.
3194 (defun source-transform-transitive (fun args identity
3195                                     &optional one-arg-result-type)
3196   (declare (symbol fun leaf-fun) (list args))
3197   (case (length args)
3198     (0 identity)
3199     (1 (if one-arg-result-type
3200            `(values (the ,one-arg-result-type ,(first args)))
3201            `(values ,(first args))))
3202     (2 (values nil t))
3203     (t
3204      (associate-args fun (first args) (rest args)))))
3205
3206 (define-source-transform + (&rest args)
3207   (source-transform-transitive '+ args 0 'number))
3208 (define-source-transform * (&rest args)
3209   (source-transform-transitive '* args 1 'number))
3210 (define-source-transform logior (&rest args)
3211   (source-transform-transitive 'logior args 0 'integer))
3212 (define-source-transform logxor (&rest args)
3213   (source-transform-transitive 'logxor args 0 'integer))
3214 (define-source-transform logand (&rest args)
3215   (source-transform-transitive 'logand args -1 'integer))
3216
3217 (define-source-transform logeqv (&rest args)
3218   (if (evenp (length args))
3219       `(lognot (logxor ,@args))
3220       `(logxor ,@args)))
3221
3222 ;;; Note: we can't use SOURCE-TRANSFORM-TRANSITIVE for GCD and LCM
3223 ;;; because when they are given one argument, they return its absolute
3224 ;;; value.
3225
3226 (define-source-transform gcd (&rest args)
3227   (case (length args)
3228     (0 0)
3229     (1 `(abs (the integer ,(first args))))
3230     (2 (values nil t))
3231     (t (associate-args 'gcd (first args) (rest args)))))
3232
3233 (define-source-transform lcm (&rest args)
3234   (case (length args)
3235     (0 1)
3236     (1 `(abs (the integer ,(first args))))
3237     (2 (values nil t))
3238     (t (associate-args 'lcm (first args) (rest args)))))
3239
3240 ;;; Do source transformations for intransitive n-arg functions such as
3241 ;;; /. With one arg, we form the inverse. With two args we pass.
3242 ;;; Otherwise we associate into two-arg calls.
3243 (declaim (ftype (function (symbol list t)
3244                           (values list &optional (member nil t)))
3245                 source-transform-intransitive))
3246 (defun source-transform-intransitive (function args inverse)
3247   (case (length args)
3248     ((0 2) (values nil t))
3249     (1 `(,@inverse ,(first args)))
3250     (t (associate-args function (first args) (rest args)))))
3251
3252 (define-source-transform - (&rest args)
3253   (source-transform-intransitive '- args '(%negate)))
3254 (define-source-transform / (&rest args)
3255   (source-transform-intransitive '/ args '(/ 1)))
3256 \f
3257 ;;;; transforming APPLY
3258
3259 ;;; We convert APPLY into MULTIPLE-VALUE-CALL so that the compiler
3260 ;;; only needs to understand one kind of variable-argument call. It is
3261 ;;; more efficient to convert APPLY to MV-CALL than MV-CALL to APPLY.
3262 (define-source-transform apply (fun arg &rest more-args)
3263   (let ((args (cons arg more-args)))
3264     `(multiple-value-call ,fun
3265        ,@(mapcar (lambda (x)
3266                    `(values ,x))
3267                  (butlast args))
3268        (values-list ,(car (last args))))))
3269 \f
3270 ;;;; transforming FORMAT
3271 ;;;;
3272 ;;;; If the control string is a compile-time constant, then replace it
3273 ;;;; with a use of the FORMATTER macro so that the control string is
3274 ;;;; ``compiled.'' Furthermore, if the destination is either a stream
3275 ;;;; or T and the control string is a function (i.e. FORMATTER), then
3276 ;;;; convert the call to FORMAT to just a FUNCALL of that function.
3277
3278 ;;; for compile-time argument count checking.
3279 ;;;
3280 ;;; FIXME I: this is currently called from DEFTRANSFORMs, the vast
3281 ;;; majority of which are not going to transform the code, but instead
3282 ;;; are going to GIVE-UP-IR1-TRANSFORM unconditionally.  It would be
3283 ;;; nice to make this explicit, maybe by implementing a new
3284 ;;; "optimizer" (say, DEFOPTIMIZER CONSISTENCY-CHECK).
3285 ;;;
3286 ;;; FIXME II: In some cases, type information could be correlated; for
3287 ;;; instance, ~{ ... ~} requires a list argument, so if the
3288 ;;; continuation-type of a corresponding argument is known and does
3289 ;;; not intersect the list type, a warning could be signalled.
3290 (defun check-format-args (string args fun)
3291   (declare (type string string))
3292   (unless (typep string 'simple-string)
3293     (setq string (coerce string 'simple-string)))
3294   (multiple-value-bind (min max)
3295       (handler-case (sb!format:%compiler-walk-format-string string args)
3296         (sb!format:format-error (c)
3297           (compiler-warn "~A" c)))
3298     (when min
3299       (let ((nargs (length args)))
3300         (cond
3301           ((< nargs min)
3302            (compiler-warn "Too few arguments (~D) to ~S ~S: ~
3303                            requires at least ~D."
3304                           nargs fun string min))
3305           ((> nargs max)
3306            (;; to get warned about probably bogus code at
3307             ;; cross-compile time.
3308             #+sb-xc-host compiler-warn
3309             ;; ANSI saith that too many arguments doesn't cause a
3310             ;; run-time error.
3311             #-sb-xc-host compiler-style-warn
3312             "Too many arguments (~D) to ~S ~S: uses at most ~D."
3313             nargs fun string max)))))))
3314
3315 (deftransform format ((dest control &rest args) (t simple-string &rest t) *
3316                       :node node)
3317
3318   (cond
3319     ((policy node (> speed space))
3320      (unless (constant-continuation-p control)
3321        (give-up-ir1-transform "The control string is not a constant."))
3322      (check-format-args (continuation-value control) args 'format)
3323      (let ((arg-names (make-gensym-list (length args))))
3324        `(lambda (dest control ,@arg-names)
3325          (declare (ignore control))
3326          (format dest (formatter ,(continuation-value control)) ,@arg-names))))
3327     (t (when (constant-continuation-p control)
3328          (check-format-args (continuation-value control) args 'format))
3329        (give-up-ir1-transform))))
3330
3331 (deftransform format ((stream control &rest args) (stream function &rest t) *
3332                       :policy (> speed space))
3333   (let ((arg-names (make-gensym-list (length args))))
3334     `(lambda (stream control ,@arg-names)
3335        (funcall control stream ,@arg-names)
3336        nil)))
3337
3338 (deftransform format ((tee control &rest args) ((member t) function &rest t) *
3339                       :policy (> speed space))
3340   (let ((arg-names (make-gensym-list (length args))))
3341     `(lambda (tee control ,@arg-names)
3342        (declare (ignore tee))
3343        (funcall control *standard-output* ,@arg-names)
3344        nil)))
3345
3346 (macrolet
3347     ((def (name)
3348          `(deftransform ,name
3349               ((control &rest args) (simple-string &rest t) *)
3350             (when (constant-continuation-p control)
3351               (check-format-args (continuation-value control) args ',name))
3352            (give-up-ir1-transform))))
3353   (def error)
3354   (def warn)
3355   #+sb-xc-host ; Only we should be using these
3356   (progn
3357     (def style-warn)
3358     (def compiler-abort)
3359     (def compiler-error)
3360     (def compiler-warn)
3361     (def compiler-style-warn)
3362     (def compiler-notify)
3363     (def maybe-compiler-notify)
3364     (def bug)))
3365
3366 (deftransform cerror ((report control &rest args)
3367                       (simple-string simple-string &rest t) *)
3368   (unless (and (constant-continuation-p control)
3369                (constant-continuation-p report))
3370     (give-up-ir1-transform))
3371   (multiple-value-bind (min1 max1)
3372       (handler-case (sb!format:%compiler-walk-format-string
3373                      (continuation-value control) args)
3374         (sb!format:format-error (c)
3375           (compiler-warn "~A" c)))
3376     (when min1
3377       (multiple-value-bind (min2 max2)
3378           (handler-case (sb!format:%compiler-walk-format-string
3379                          (continuation-value report) args)
3380             (sb!format:format-error (c)
3381               (compiler-warn "~A" c)))
3382         (when min2
3383           (let ((nargs (length args)))
3384             (cond
3385               ((< nargs (min min1 min2))
3386                (compiler-warn "Too few arguments (~D) to ~S ~S ~S: ~
3387                                requires at least ~D."
3388                               nargs 'cerror report control min))
3389               ((> nargs (max max1 max2))
3390                (;; to get warned about probably bogus code at
3391                 ;; cross-compile time.
3392                 #+sb-xc-host compiler-warn
3393                 ;; ANSI saith that too many arguments doesn't cause a
3394                 ;; run-time error.
3395                 #-sb-xc-host compiler-style-warn
3396                 "Too many arguments (~D) to ~S ~S ~S: uses at most ~D."
3397                 nargs 'cerror report control max))))))))
3398   (give-up-ir1-transform))
3399
3400 (defoptimizer (coerce derive-type) ((value type))
3401   (cond
3402     ((constant-continuation-p type)
3403      ;; This branch is essentially (RESULT-TYPE-SPECIFIER-NTH-ARG 2),
3404      ;; but dealing with the niggle that complex canonicalization gets
3405      ;; in the way: (COERCE 1 'COMPLEX) returns 1, which is not of
3406      ;; type COMPLEX.
3407      (let* ((specifier (continuation-value type))
3408             (result-typeoid (careful-specifier-type specifier)))
3409        (cond
3410          ((null result-typeoid) nil)
3411          ((csubtypep result-typeoid (specifier-type 'number))
3412           ;; the difficult case: we have to cope with ANSI 12.1.5.3
3413           ;; Rule of Canonical Representation for Complex Rationals,
3414           ;; which is a truly nasty delivery to field.
3415           (cond
3416             ((csubtypep result-typeoid (specifier-type 'real))
3417              ;; cleverness required here: it would be nice to deduce
3418              ;; that something of type (INTEGER 2 3) coerced to type
3419              ;; DOUBLE-FLOAT should return (DOUBLE-FLOAT 2.0d0 3.0d0).
3420              ;; FLOAT gets its own clause because it's implemented as
3421              ;; a UNION-TYPE, so we don't catch it in the NUMERIC-TYPE
3422              ;; logic below.
3423              result-typeoid)
3424             ((and (numeric-type-p result-typeoid)
3425                   (eq (numeric-type-complexp result-typeoid) :real))
3426              ;; FIXME: is this clause (a) necessary or (b) useful?
3427              result-typeoid)
3428             ((or (csubtypep result-typeoid
3429                             (specifier-type '(complex single-float)))
3430                  (csubtypep result-typeoid
3431                             (specifier-type '(complex double-float)))
3432                  #!+long-float
3433                  (csubtypep result-typeoid
3434                             (specifier-type '(complex long-float))))
3435              ;; float complex types are never canonicalized.
3436              result-typeoid)
3437             (t
3438              ;; if it's not a REAL, or a COMPLEX FLOAToid, it's
3439              ;; probably just a COMPLEX or equivalent.  So, in that
3440              ;; case, we will return a complex or an object of the
3441              ;; provided type if it's rational:
3442              (type-union result-typeoid
3443                          (type-intersection (continuation-type value)
3444                                             (specifier-type 'rational))))))
3445          (t result-typeoid))))
3446     (t
3447      ;; OK, the result-type argument isn't constant.  However, there
3448      ;; are common uses where we can still do better than just
3449      ;; *UNIVERSAL-TYPE*: e.g. (COERCE X (ARRAY-ELEMENT-TYPE Y)),
3450      ;; where Y is of a known type.  See messages on cmucl-imp
3451      ;; 2001-02-14 and sbcl-devel 2002-12-12.  We only worry here
3452      ;; about types that can be returned by (ARRAY-ELEMENT-TYPE Y), on
3453      ;; the basis that it's unlikely that other uses are both
3454      ;; time-critical and get to this branch of the COND (non-constant
3455      ;; second argument to COERCE).  -- CSR, 2002-12-16
3456      (let ((value-type (continuation-type value))
3457            (type-type (continuation-type type)))
3458        (labels
3459            ((good-cons-type-p (cons-type)
3460               ;; Make sure the cons-type we're looking at is something
3461               ;; we're prepared to handle which is basically something
3462               ;; that array-element-type can return.
3463               (or (and (member-type-p cons-type)
3464                        (null (rest (member-type-members cons-type)))
3465                        (null (first (member-type-members cons-type))))
3466                   (let ((car-type (cons-type-car-type cons-type)))
3467                     (and (member-type-p car-type)
3468                          (null (rest (member-type-members car-type)))
3469                          (or (symbolp (first (member-type-members car-type)))
3470                              (numberp (first (member-type-members car-type)))
3471                              (and (listp (first (member-type-members
3472                                                  car-type)))
3473                                   (numberp (first (first (member-type-members
3474                                                           car-type))))))
3475                          (good-cons-type-p (cons-type-cdr-type cons-type))))))
3476             (unconsify-type (good-cons-type)
3477               ;; Convert the "printed" respresentation of a cons
3478               ;; specifier into a type specifier.  That is, the
3479               ;; specifier (CONS (EQL SIGNED-BYTE) (CONS (EQL 16)
3480               ;; NULL)) is converted to (SIGNED-BYTE 16).
3481               (cond ((or (null good-cons-type)
3482                          (eq good-cons-type 'null))
3483                      nil)
3484                     ((and (eq (first good-cons-type) 'cons)
3485                           (eq (first (second good-cons-type)) 'member))
3486                      `(,(second (second good-cons-type))
3487                        ,@(unconsify-type (caddr good-cons-type))))))
3488             (coerceable-p (c-type)
3489               ;; Can the value be coerced to the given type?  Coerce is
3490               ;; complicated, so we don't handle every possible case
3491               ;; here---just the most common and easiest cases:
3492               ;;
3493               ;; * Any REAL can be coerced to a FLOAT type.
3494               ;; * Any NUMBER can be coerced to a (COMPLEX
3495               ;;   SINGLE/DOUBLE-FLOAT).
3496               ;;
3497               ;; FIXME I: we should also be able to deal with characters
3498               ;; here.
3499               ;;
3500               ;; FIXME II: I'm not sure that anything is necessary
3501               ;; here, at least while COMPLEX is not a specialized
3502               ;; array element type in the system.  Reasoning: if
3503               ;; something cannot be coerced to the requested type, an
3504               ;; error will be raised (and so any downstream compiled
3505               ;; code on the assumption of the returned type is
3506               ;; unreachable).  If something can, then it will be of
3507               ;; the requested type, because (by assumption) COMPLEX
3508               ;; (and other difficult types like (COMPLEX INTEGER)
3509               ;; aren't specialized types.
3510               (let ((coerced-type c-type))
3511                 (or (and (subtypep coerced-type 'float)
3512                          (csubtypep value-type (specifier-type 'real)))
3513                     (and (subtypep coerced-type
3514                                    '(or (complex single-float)
3515                                         (complex double-float)))
3516                          (csubtypep value-type (specifier-type 'number))))))
3517             (process-types (type)
3518               ;; FIXME: This needs some work because we should be able
3519               ;; to derive the resulting type better than just the
3520               ;; type arg of coerce.  That is, if X is (INTEGER 10
3521               ;; 20), then (COERCE X 'DOUBLE-FLOAT) should say
3522               ;; (DOUBLE-FLOAT 10d0 20d0) instead of just
3523               ;; double-float.
3524               (cond ((member-type-p type)
3525                      (let ((members (member-type-members type)))
3526                        (if (every #'coerceable-p members)
3527                            (specifier-type `(or ,@members))
3528                            *universal-type*)))
3529                     ((and (cons-type-p type)
3530                           (good-cons-type-p type))
3531                      (let ((c-type (unconsify-type (type-specifier type))))
3532                        (if (coerceable-p c-type)
3533                            (specifier-type c-type)
3534                            *universal-type*)))
3535                     (t
3536                      *universal-type*))))
3537          (cond ((union-type-p type-type)
3538                 (apply #'type-union (mapcar #'process-types
3539                                             (union-type-types type-type))))
3540                ((or (member-type-p type-type)
3541                     (cons-type-p type-type))
3542                 (process-types type-type))
3543                (t
3544                 *universal-type*)))))))
3545
3546 (defoptimizer (compile derive-type) ((nameoid function))
3547   (when (csubtypep (continuation-type nameoid)
3548                    (specifier-type 'null))
3549     (values-specifier-type '(values function boolean boolean))))
3550
3551 ;;; FIXME: Maybe also STREAM-ELEMENT-TYPE should be given some loving
3552 ;;; treatment along these lines? (See discussion in COERCE DERIVE-TYPE
3553 ;;; optimizer, above).
3554 (defoptimizer (array-element-type derive-type) ((array))
3555   (let ((array-type (continuation-type array)))
3556     (labels ((consify (list)
3557               (if (endp list)
3558                   '(eql nil)
3559                   `(cons (eql ,(car list)) ,(consify (rest list)))))
3560             (get-element-type (a)
3561               (let ((element-type
3562                      (type-specifier (array-type-specialized-element-type a))))
3563                 (cond ((eq element-type '*)
3564                        (specifier-type 'type-specifier))
3565                       ((symbolp element-type)
3566                        (make-member-type :members (list element-type)))
3567                       ((consp element-type)
3568                        (specifier-type (consify element-type)))
3569                       (t
3570                        (error "can't understand type ~S~%" element-type))))))
3571       (cond ((array-type-p array-type)
3572              (get-element-type array-type))
3573             ((union-type-p array-type)
3574              (apply #'type-union
3575                     (mapcar #'get-element-type (union-type-types array-type))))
3576             (t
3577              *universal-type*)))))
3578
3579 (define-source-transform sb!impl::sort-vector (vector start end predicate key)
3580   `(macrolet ((%index (x) `(truly-the index ,x))
3581               (%parent (i) `(ash ,i -1))
3582               (%left (i) `(%index (ash ,i 1)))
3583               (%right (i) `(%index (1+ (ash ,i 1))))
3584               (%heapify (i)
3585                `(do* ((i ,i)
3586                       (left (%left i) (%left i)))
3587                  ((> left current-heap-size))
3588                  (declare (type index i left))
3589                  (let* ((i-elt (%elt i))
3590                         (i-key (funcall keyfun i-elt))
3591                         (left-elt (%elt left))
3592                         (left-key (funcall keyfun left-elt)))
3593                    (multiple-value-bind (large large-elt large-key)
3594                        (if (funcall ,',predicate i-key left-key)
3595                            (values left left-elt left-key)
3596                            (values i i-elt i-key))
3597                      (let ((right (%right i)))
3598                        (multiple-value-bind (largest largest-elt)
3599                            (if (> right current-heap-size)
3600                                (values large large-elt)
3601                                (let* ((right-elt (%elt right))
3602                                       (right-key (funcall keyfun right-elt)))
3603                                  (if (funcall ,',predicate large-key right-key)
3604                                      (values right right-elt)
3605                                      (values large large-elt))))
3606                          (cond ((= largest i)
3607                                 (return))
3608                                (t
3609                                 (setf (%elt i) largest-elt
3610                                       (%elt largest) i-elt
3611                                       i largest)))))))))
3612               (%sort-vector (keyfun &optional (vtype 'vector))
3613                `(macrolet (;; KLUDGE: In SBCL ca. 0.6.10, I had trouble getting
3614                            ;; type inference to propagate all the way
3615                            ;; through this tangled mess of
3616                            ;; inlining. The TRULY-THE here works
3617                            ;; around that. -- WHN
3618                            (%elt (i)
3619                             `(aref (truly-the ,',vtype ,',',vector)
3620                               (%index (+ (%index ,i) start-1)))))
3621                  (let ((start-1 (1- ,',start)) ; Heaps prefer 1-based addressing.
3622                        (current-heap-size (- ,',end ,',start))
3623                        (keyfun ,keyfun))
3624                    (declare (type (integer -1 #.(1- most-positive-fixnum))
3625                                   start-1))
3626                    (declare (type index current-heap-size))
3627                    (declare (type function keyfun))
3628                    (loop for i of-type index
3629                          from (ash current-heap-size -1) downto 1 do
3630                          (%heapify i))
3631                    (loop
3632                     (when (< current-heap-size 2)
3633                       (return))
3634                     (rotatef (%elt 1) (%elt current-heap-size))
3635                     (decf current-heap-size)
3636                     (%heapify 1))))))
3637     (if (typep ,vector 'simple-vector)
3638         ;; (VECTOR T) is worth optimizing for, and SIMPLE-VECTOR is
3639         ;; what we get from (VECTOR T) inside WITH-ARRAY-DATA.
3640         (if (null ,key)
3641             ;; Special-casing the KEY=NIL case lets us avoid some
3642             ;; function calls.
3643             (%sort-vector #'identity simple-vector)
3644             (%sort-vector ,key simple-vector))
3645         ;; It's hard to anticipate many speed-critical applications for
3646         ;; sorting vector types other than (VECTOR T), so we just lump
3647         ;; them all together in one slow dynamically typed mess.
3648         (locally
3649           (declare (optimize (speed 2) (space 2) (inhibit-warnings 3)))
3650           (%sort-vector (or ,key #'identity))))))
3651 \f
3652 ;;;; debuggers' little helpers
3653
3654 ;;; for debugging when transforms are behaving mysteriously,
3655 ;;; e.g. when debugging a problem with an ASH transform
3656 ;;;   (defun foo (&optional s)
3657 ;;;     (sb-c::/report-continuation s "S outside WHEN")
3658 ;;;     (when (and (integerp s) (> s 3))
3659 ;;;       (sb-c::/report-continuation s "S inside WHEN")
3660 ;;;       (let ((bound (ash 1 (1- s))))
3661 ;;;         (sb-c::/report-continuation bound "BOUND")
3662 ;;;         (let ((x (- bound))
3663 ;;;               (y (1- bound)))
3664 ;;;           (sb-c::/report-continuation x "X")
3665 ;;;           (sb-c::/report-continuation x "Y"))
3666 ;;;         `(integer ,(- bound) ,(1- bound)))))
3667 ;;; (The DEFTRANSFORM doesn't do anything but report at compile time,
3668 ;;; and the function doesn't do anything at all.)
3669 #!+sb-show
3670 (progn
3671   (defknown /report-continuation (t t) null)
3672   (deftransform /report-continuation ((x message) (t t))
3673     (format t "~%/in /REPORT-CONTINUATION~%")
3674     (format t "/(CONTINUATION-TYPE X)=~S~%" (continuation-type x))
3675     (when (constant-continuation-p x)
3676       (format t "/(CONTINUATION-VALUE X)=~S~%" (continuation-value x)))
3677     (format t "/MESSAGE=~S~%" (continuation-value message))
3678     (give-up-ir1-transform "not a real transform"))
3679   (defun /report-continuation (&rest rest)
3680     (declare (ignore rest))))