src/compiler/target-disassem.lisp

   1 ;;;; disassembler-related stuff not needed in cross-compilation host
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!DISASSEM")
  13
  14 ;;;; FIXME: A lot of stupid package prefixes would go away if DISASSEM
  15 ;;;; would use the SB!DI package. And some more would go away if it would
  16 ;;;; use SB!SYS (in order to get to the SAP-FOO operators).
  17 \f
  18 ;;;; combining instructions where one specializes another
  19
  20 ;;; Return non-NIL if the instruction SPECIAL is a more specific
  21 ;;; version of GENERAL (i.e., the same instruction, but with more
  22 ;;; constraints).
  23 (defun inst-specializes-p (special general)
  24   (declare (type instruction special general))
  25   (let ((smask (inst-mask special))
  26         (gmask (inst-mask general)))
  27     (and (dchunk= (inst-id general)
  28                   (dchunk-and (inst-id special) gmask))
  29          (dchunk-strict-superset-p smask gmask))))
  30
  31 ;;; a bit arbitrary, but should work ok...
  32 ;;;
  33 ;;; Return an integer corresponding to the specificity of the
  34 ;;; instruction INST.
  35 (defun specializer-rank (inst)
  36   (declare (type instruction inst))
  37   (* (dchunk-count-bits (inst-mask inst)) 4))
  38
  39 ;;; Order the list of instructions INSTS with more specific (more
  40 ;;; constant bits, or same-as argument constains) ones first. Returns
  41 ;;; the ordered list.
  42 (defun order-specializers (insts)
  43   (declare (type list insts))
  44   (sort insts #'> :key #'specializer-rank))
  45
  46 (defun specialization-error (insts)
  47   (bug
  48    "~@<Instructions either aren't related or conflict in some way: ~4I~_~S~:>"
  49    insts))
  50
  51 ;;; Given a list of instructions INSTS, Sees if one of these instructions is a
  52 ;;; more general form of all the others, in which case they are put into its
  53 ;;; specializers list, and it is returned. Otherwise an error is signaled.
  54 (defun try-specializing (insts)
  55   (declare (type list insts))
  56   (let ((masters (copy-list insts)))
  57     (dolist (possible-master insts)
  58       (dolist (possible-specializer insts)
  59         (unless (or (eq possible-specializer possible-master)
  60                     (inst-specializes-p possible-specializer possible-master))
  61           (setf masters (delete possible-master masters))
  62           (return)                      ; exit the inner loop
  63           )))
  64     (cond ((null masters)
  65            (specialization-error insts))
  66           ((cdr masters)
  67            (error "multiple specializing masters: ~S" masters))
  68           (t
  69            (let ((master (car masters)))
  70              (setf (inst-specializers master)
  71                    (order-specializers (remove master insts)))
  72              master)))))
  73 \f
  74 ;;;; choosing an instruction
  75
  76 #!-sb-fluid (declaim (inline inst-matches-p choose-inst-specialization))
  77
  78 ;;; Return non-NIL if all constant-bits in INST match CHUNK.
  79 (defun inst-matches-p (inst chunk)
  80   (declare (type instruction inst)
  81            (type dchunk chunk))
  82   (dchunk= (dchunk-and (inst-mask inst) chunk) (inst-id inst)))
  83
  84 ;;; Given an instruction object, INST, and a bit-pattern, CHUNK, pick
  85 ;;; the most specific instruction on INST's specializer list whose
  86 ;;; constraints are met by CHUNK. If none do, then return INST.
  87 (defun choose-inst-specialization (inst chunk)
  88   (declare (type instruction inst)
  89            (type dchunk chunk))
  90   (or (dolist (spec (inst-specializers inst) nil)
  91         (declare (type instruction spec))
  92         (when (inst-matches-p spec chunk)
  93           (return spec)))
  94       inst))
  95 \f
  96 ;;;; searching for an instruction in instruction space
  97
  98 ;;; Return the instruction object within INST-SPACE corresponding to the
  99 ;;; bit-pattern CHUNK, or NIL if there isn't one.
 100 (defun find-inst (chunk inst-space)
 101   (declare (type dchunk chunk)
 102            (type (or null inst-space instruction) inst-space))
 103   (etypecase inst-space
 104     (null nil)
 105     (instruction
 106      (if (inst-matches-p inst-space chunk)
 107          (choose-inst-specialization inst-space chunk)
 108          nil))
 109     (inst-space
 110      (let* ((mask (ispace-valid-mask inst-space))
 111             (id (dchunk-and mask chunk)))
 112        (declare (type dchunk id mask))
 113        (dolist (choice (ispace-choices inst-space))
 114          (declare (type inst-space-choice choice))
 115          (when (dchunk= id (ischoice-common-id choice))
 116            (return (find-inst chunk (ischoice-subspace choice)))))))))
 117 \f
 118 ;;;; building the instruction space
 119
 120 ;;; Returns an instruction-space object corresponding to the list of
 121 ;;; instructions INSTS. If the optional parameter INITIAL-MASK is
 122 ;;; supplied, only bits it has set are used.
 123 (defun build-inst-space (insts &optional (initial-mask dchunk-one))
 124   ;; This is done by finding any set of bits that's common to
 125   ;; all instructions, building an instruction-space node that selects on those
 126   ;; bits, and recursively handle sets of instructions with a common value for
 127   ;; these bits (which, since there should be fewer instructions than in INSTS,
 128   ;; should have some additional set of bits to select on, etc). If there
 129   ;; are no common bits, or all instructions have the same value within those
 130   ;; bits, TRY-SPECIALIZING is called, which handles the cases of many
 131   ;; variations on a single instruction.
 132   (declare (type list insts)
 133            (type dchunk initial-mask))
 134   (cond ((null insts)
 135          nil)
 136         ((null (cdr insts))
 137          (car insts))
 138         (t
 139          (let ((vmask (dchunk-copy initial-mask)))
 140            (dolist (inst insts)
 141              (dchunk-andf vmask (inst-mask inst)))
 142            (if (dchunk-zerop vmask)
 143                (try-specializing insts)
 144                (let ((buckets nil))
 145                  (dolist (inst insts)
 146                    (let* ((common-id (dchunk-and (inst-id inst) vmask))
 147                           (bucket (assoc common-id buckets :test #'dchunk=)))
 148                      (cond ((null bucket)
 149                             (push (list common-id inst) buckets))
 150                            (t
 151                             (push inst (cdr bucket))))))
 152                  (let ((submask (dchunk-clear initial-mask vmask)))
 153                    (if (= (length buckets) 1)
 154                        (try-specializing insts)
 155                        (make-inst-space
 156                         :valid-mask vmask
 157                         :choices (mapcar (lambda (bucket)
 158                                            (make-inst-space-choice
 159                                             :subspace (build-inst-space
 160                                                        (cdr bucket)
 161                                                        submask)
 162                                             :common-id (car bucket)))
 163                                          buckets))))))))))
 164 \f
 165 ;;;; an inst-space printer for debugging purposes
 166
 167 (defun print-masked-binary (num mask word-size &optional (show word-size))
 168   (do ((bit (1- word-size) (1- bit)))
 169       ((< bit 0))
 170     (write-char (cond ((logbitp bit mask)
 171                        (if (logbitp bit num) #\1 #\0))
 172                       ((< bit show) #\x)
 173                       (t #\space)))))
 174
 175 (defun print-inst-bits (inst)
 176   (print-masked-binary (inst-id inst)
 177                        (inst-mask inst)
 178                        dchunk-bits
 179                        (bytes-to-bits (inst-length inst))))
 180
 181 ;;; Print a nicely-formatted version of INST-SPACE.
 182 (defun print-inst-space (inst-space &optional (indent 0))
 183   (etypecase inst-space
 184     (null)
 185     (instruction
 186      (format t "~Vt[~A(~A)~40T" indent
 187              (inst-name inst-space)
 188              (inst-format-name inst-space))
 189      (print-inst-bits inst-space)
 190      (dolist (inst (inst-specializers inst-space))
 191        (format t "~%~Vt:~A~40T" indent (inst-name inst))
 192        (print-inst-bits inst))
 193      (write-char #\])
 194      (terpri))
 195     (inst-space
 196      (format t "~Vt---- ~8,'0X ----~%"
 197              indent
 198              (ispace-valid-mask inst-space))
 199      (map nil
 200           (lambda (choice)
 201             (format t "~Vt~8,'0X ==>~%"
 202                     (+ 2 indent)
 203                     (ischoice-common-id choice))
 204             (print-inst-space (ischoice-subspace choice)
 205                               (+ 4 indent)))
 206           (ispace-choices inst-space)))))
 207 \f
 208 ;;;; (The actual disassembly part follows.)
 209 \f
 210 ;;; Code object layout:
 211 ;;;     header-word
 212 ;;;     code-size (starting from first inst, in words)
 213 ;;;     entry-points (points to first function header)
 214 ;;;     debug-info
 215 ;;;     trace-table-offset (starting from first inst, in bytes)
 216 ;;;     constant1
 217 ;;;     constant2
 218 ;;;     ...
 219 ;;;     <padding to dual-word boundary>
 220 ;;;     start of instructions
 221 ;;;     ...
 222 ;;;     fun-headers and lra's buried in here randomly
 223 ;;;     ...
 224 ;;;     start of trace-table
 225 ;;;     <padding to dual-word boundary>
 226 ;;;
 227 ;;; Function header layout (dual word aligned):
 228 ;;;     header-word
 229 ;;;     self pointer
 230 ;;;     next pointer (next function header)
 231 ;;;     name
 232 ;;;     arglist
 233 ;;;     type
 234 ;;;
 235 ;;; LRA layout (dual word aligned):
 236 ;;;     header-word
 237
 238 #!-sb-fluid (declaim (inline words-to-bytes bytes-to-words))
 239
 240 (eval-when (:compile-toplevel :load-toplevel :execute)
 241   ;;; Convert a word-offset NUM to a byte-offset.
 242   (defun words-to-bytes (num)
 243     (declare (type offset num))
 244     (ash num sb!vm:word-shift))
 245   ) ; EVAL-WHEN
 246
 247 ;;; Convert a byte-offset NUM to a word-offset.
 248 (defun bytes-to-words (num)
 249   (declare (type offset num))
 250   (ash num (- sb!vm:word-shift)))
 251
 252 (defconstant lra-size (words-to-bytes 1))
 253 \f
 254 (defstruct (offs-hook (:copier nil))
 255   (offset 0 :type offset)
 256   (fun (missing-arg) :type function)
 257   (before-address nil :type (member t nil)))
 258
 259 (defstruct (segment (:conc-name seg-)
 260                     (:constructor %make-segment)
 261                     (:copier nil))
 262   (sap-maker (missing-arg)
 263              :type (function () sb!sys:system-area-pointer))
 264   (length 0 :type disassem-length)
 265   (virtual-location 0 :type address)
 266   (storage-info nil :type (or null storage-info))
 267   (code nil :type (or null sb!kernel:code-component))
 268   (hooks nil :type list))
 269 (def!method print-object ((seg segment) stream)
 270   (print-unreadable-object (seg stream :type t)
 271     (let ((addr (sb!sys:sap-int (funcall (seg-sap-maker seg)))))
 272       (format stream "#X~X[~W]~:[ (#X~X)~;~*~]~@[ in ~S~]"
 273               addr
 274               (seg-length seg)
 275               (= (seg-virtual-location seg) addr)
 276               (seg-virtual-location seg)
 277               (seg-code seg)))))
 278 \f
 279 ;;;; function ops
 280
 281 (defun fun-self (fun)
 282   (declare (type compiled-function fun))
 283   (sb!kernel:%simple-fun-self fun))
 284
 285 (defun fun-code (fun)
 286   (declare (type compiled-function fun))
 287   (sb!kernel:fun-code-header (fun-self fun)))
 288
 289 (defun fun-next (fun)
 290   (declare (type compiled-function fun))
 291   (sb!kernel:%simple-fun-next fun))
 292
 293 (defun fun-address (fun)
 294   (declare (type compiled-function fun))
 295   (ecase (sb!kernel:widetag-of fun)
 296     (#.sb!vm:simple-fun-header-widetag
 297      (- (sb!kernel:get-lisp-obj-address fun) sb!vm:fun-pointer-lowtag))
 298     (#.sb!vm:closure-header-widetag
 299      (fun-address (sb!kernel:%closure-fun fun)))
 300     (#.sb!vm:funcallable-instance-header-widetag
 301      (fun-address (sb!kernel:funcallable-instance-fun fun)))))
 302
 303 ;;; the offset of FUNCTION from the start of its code-component's
 304 ;;; instruction area
 305 (defun fun-insts-offset (function)
 306   (declare (type compiled-function function))
 307   (- (fun-address function)
 308      (sb!sys:sap-int (sb!kernel:code-instructions (fun-code function)))))
 309
 310 ;;; the offset of FUNCTION from the start of its code-component
 311 (defun fun-offset (function)
 312   (declare (type compiled-function function))
 313   (words-to-bytes (sb!kernel:get-closure-length function)))
 314 \f
 315 ;;;; operations on code-components (which hold the instructions for
 316 ;;;; one or more functions)
 317
 318 ;;; Return the length of the instruction area in CODE-COMPONENT.
 319 (defun code-inst-area-length (code-component)
 320   (declare (type sb!kernel:code-component code-component))
 321   (sb!kernel:code-header-ref code-component
 322                              sb!vm:code-trace-table-offset-slot))
 323
 324 ;;; Return the address of the instruction area in CODE-COMPONENT.
 325 (defun code-inst-area-address (code-component)
 326   (declare (type sb!kernel:code-component code-component))
 327   (sb!sys:sap-int (sb!kernel:code-instructions code-component)))
 328
 329 ;;; unused as of sbcl-0.pre7.129
 330 #|
 331 ;;; Return the first function in CODE-COMPONENT.
 332 (defun code-first-function (code-component)
 333   (declare (type sb!kernel:code-component code-component))
 334   (sb!kernel:code-header-ref code-component
 335                              sb!vm:code-trace-table-offset-slot))
 336 |#
 337
 338 (defun segment-offs-to-code-offs (offset segment)
 339   (sb!sys:without-gcing
 340    (let* ((seg-base-addr (sb!sys:sap-int (funcall (seg-sap-maker segment))))
 341           (code-addr
 342            (logandc1 sb!vm:lowtag-mask
 343                      (sb!kernel:get-lisp-obj-address (seg-code segment))))
 344           (addr (+ offset seg-base-addr)))
 345      (declare (type address seg-base-addr code-addr addr))
 346      (- addr code-addr))))
 347
 348 (defun code-offs-to-segment-offs (offset segment)
 349   (sb!sys:without-gcing
 350    (let* ((seg-base-addr (sb!sys:sap-int (funcall (seg-sap-maker segment))))
 351           (code-addr
 352            (logandc1 sb!vm:lowtag-mask
 353                      (sb!kernel:get-lisp-obj-address (seg-code segment))))
 354           (addr (+ offset code-addr)))
 355      (declare (type address seg-base-addr code-addr addr))
 356      (- addr seg-base-addr))))
 357
 358 (defun code-insts-offs-to-segment-offs (offset segment)
 359   (sb!sys:without-gcing
 360    (let* ((seg-base-addr (sb!sys:sap-int (funcall (seg-sap-maker segment))))
 361           (code-insts-addr
 362            (sb!sys:sap-int (sb!kernel:code-instructions (seg-code segment))))
 363           (addr (+ offset code-insts-addr)))
 364      (declare (type address seg-base-addr code-insts-addr addr))
 365      (- addr seg-base-addr))))
 366 \f
 367 (defun lra-hook (chunk stream dstate)
 368   (declare (type dchunk chunk)
 369            (ignore chunk)
 370            (type (or null stream) stream)
 371            (type disassem-state dstate))
 372   (when (and (aligned-p (+ (seg-virtual-location (dstate-segment dstate))
 373                            (dstate-cur-offs dstate))
 374                         (* 2 sb!vm:n-word-bytes))
 375              ;; Check type.
 376              (= (sb!sys:sap-ref-8 (dstate-segment-sap dstate)
 377                                   (if (eq (dstate-byte-order dstate)
 378                                           :little-endian)
 379                                       (dstate-cur-offs dstate)
 380                                       (+ (dstate-cur-offs dstate)
 381                                          (1- lra-size))))
 382                 sb!vm:return-pc-header-widetag))
 383     (unless (null stream)
 384       (note "possible LRA header" dstate)))
 385   nil)
 386
 387 ;;; Print the fun-header (entry-point) pseudo-instruction at the
 388 ;;; current location in DSTATE to STREAM.
 389 (defun fun-header-hook (stream dstate)
 390   (declare (type (or null stream) stream)
 391            (type disassem-state dstate))
 392   (unless (null stream)
 393     (let* ((seg (dstate-segment dstate))
 394            (code (seg-code seg))
 395            (woffs
 396             (bytes-to-words
 397              (segment-offs-to-code-offs (dstate-cur-offs dstate) seg)))
 398            (name
 399             (sb!kernel:code-header-ref code
 400                                        (+ woffs
 401                                           sb!vm:simple-fun-name-slot)))
 402            (args
 403             (sb!kernel:code-header-ref code
 404                                        (+ woffs
 405                                           sb!vm:simple-fun-arglist-slot)))
 406            (type
 407             (sb!kernel:code-header-ref code
 408                                        (+ woffs
 409                                           sb!vm:simple-fun-type-slot))))
 410       (format stream ".~A ~S~:A" 'entry name args)
 411       (note (lambda (stream)
 412               (format stream "~:S" type)) ; use format to print NIL as ()
 413             dstate)))
 414   (incf (dstate-next-offs dstate)
 415         (words-to-bytes sb!vm:simple-fun-code-offset)))
 416 \f
 417 (defun alignment-hook (chunk stream dstate)
 418   (declare (type dchunk chunk)
 419            (ignore chunk)
 420            (type (or null stream) stream)
 421            (type disassem-state dstate))
 422   (let ((location
 423          (+ (seg-virtual-location (dstate-segment dstate))
 424             (dstate-cur-offs dstate)))
 425         (alignment (dstate-alignment dstate)))
 426     (unless (aligned-p location alignment)
 427       (when stream
 428         (format stream "~A~Vt~W~%" '.align
 429                 (dstate-argument-column dstate)
 430                 alignment))
 431       (incf(dstate-next-offs dstate)
 432            (- (align location alignment) location)))
 433     nil))
 434
 435 (defun rewind-current-segment (dstate segment)
 436   (declare (type disassem-state dstate)
 437            (type segment segment))
 438   (setf (dstate-segment dstate) segment)
 439   (setf (dstate-cur-offs-hooks dstate)
 440         (stable-sort (nreverse (copy-list (seg-hooks segment)))
 441                      (lambda (oh1 oh2)
 442                        (or (< (offs-hook-offset oh1) (offs-hook-offset oh2))
 443                            (and (= (offs-hook-offset oh1)
 444                                    (offs-hook-offset oh2))
 445                                 (offs-hook-before-address oh1)
 446                                 (not (offs-hook-before-address oh2)))))))
 447   (setf (dstate-cur-offs dstate) 0)
 448   (setf (dstate-cur-labels dstate) (dstate-labels dstate)))
 449
 450 (defun call-offs-hooks (before-address stream dstate)
 451   (declare (type (or null stream) stream)
 452            (type disassem-state dstate))
 453   (let ((cur-offs (dstate-cur-offs dstate)))
 454     (setf (dstate-next-offs dstate) cur-offs)
 455     (loop
 456       (let ((next-hook (car (dstate-cur-offs-hooks dstate))))
 457         (when (null next-hook)
 458           (return))
 459         (let ((hook-offs (offs-hook-offset next-hook)))
 460           (when (or (> hook-offs cur-offs)
 461                     (and (= hook-offs cur-offs)
 462                          before-address
 463                          (not (offs-hook-before-address next-hook))))
 464             (return))
 465           (unless (< hook-offs cur-offs)
 466             (funcall (offs-hook-fun next-hook) stream dstate))
 467           (pop (dstate-cur-offs-hooks dstate))
 468           (unless (= (dstate-next-offs dstate) cur-offs)
 469             (return)))))))
 470
 471 (defun call-fun-hooks (chunk stream dstate)
 472   (let ((hooks (dstate-fun-hooks dstate))
 473         (cur-offs (dstate-cur-offs dstate)))
 474     (setf (dstate-next-offs dstate) cur-offs)
 475     (dolist (hook hooks nil)
 476       (let ((prefix-p (funcall hook chunk stream dstate)))
 477         (unless (= (dstate-next-offs dstate) cur-offs)
 478           (return prefix-p))))))
 479
 480 (defun handle-bogus-instruction (stream dstate)
 481   (let ((alignment (dstate-alignment dstate)))
 482     (unless (null stream)
 483       (multiple-value-bind (words bytes)
 484           (truncate alignment sb!vm:n-word-bytes)
 485         (when (> words 0)
 486           (print-words words stream dstate))
 487         (when (> bytes 0)
 488           (print-inst bytes stream dstate)))
 489       (print-bytes alignment stream dstate))
 490     (incf (dstate-next-offs dstate) alignment)))
 491
 492 ;;; Iterate through the instructions in SEGMENT, calling FUNCTION for
 493 ;;; each instruction, with arguments of CHUNK, STREAM, and DSTATE.
 494 (defun map-segment-instructions (function segment dstate &optional stream)
 495   (declare (type function function)
 496            (type segment segment)
 497            (type disassem-state dstate)
 498            (type (or null stream) stream))
 499
 500   (let ((ispace (get-inst-space))
 501         (prefix-p nil)) ; just processed a prefix inst
 502
 503     (rewind-current-segment dstate segment)
 504
 505     (loop
 506       (when (>= (dstate-cur-offs dstate)
 507                 (seg-length (dstate-segment dstate)))
 508         ;; done!
 509         (return))
 510
 511       (setf (dstate-next-offs dstate) (dstate-cur-offs dstate))
 512
 513       (call-offs-hooks t stream dstate)
 514       (unless (or prefix-p (null stream))
 515         (print-current-address stream dstate))
 516       (call-offs-hooks nil stream dstate)
 517
 518       (unless (> (dstate-next-offs dstate) (dstate-cur-offs dstate))
 519         (sb!sys:without-gcing
 520          (setf (dstate-segment-sap dstate) (funcall (seg-sap-maker segment)))
 521
 522          (let ((chunk
 523                 (sap-ref-dchunk (dstate-segment-sap dstate)
 524                                 (dstate-cur-offs dstate)
 525                                 (dstate-byte-order dstate))))
 526            (let ((fun-prefix-p (call-fun-hooks chunk stream dstate)))
 527              (if (> (dstate-next-offs dstate) (dstate-cur-offs dstate))
 528                  (setf prefix-p fun-prefix-p)
 529                (let ((inst (find-inst chunk ispace)))
 530                  (cond ((null inst)
 531                         (handle-bogus-instruction stream dstate))
 532                        (t
 533                         (setf (dstate-next-offs dstate)
 534                               (+ (dstate-cur-offs dstate)
 535                                  (inst-length inst)))
 536                         (let ((orig-next (dstate-next-offs dstate)))
 537                           (print-inst (inst-length inst) stream dstate :trailing-space nil)
 538                           (let ((prefilter (inst-prefilter inst))
 539                                 (control (inst-control inst)))
 540                             (when prefilter
 541                               (funcall prefilter chunk dstate))
 542
 543                             ;; print any instruction bytes recognized by the prefilter which calls read-suffix
 544                             ;; and updates next-offs
 545                             (when stream
 546                               (let ((suffix-len (- (dstate-next-offs dstate) orig-next)))
 547                                 (when (plusp suffix-len)
 548                                   (print-inst suffix-len stream dstate :offset (inst-length inst) :trailing-space nil))
 549                               (dotimes (i (- *disassem-inst-column-width* (* 2 (+ (inst-length inst) suffix-len))))
 550                                 (write-char #\space stream)))
 551                               (write-char #\space stream))
 552
 553                             (funcall function chunk inst)
 554
 555                             (setf prefix-p (null (inst-printer inst)))
 556
 557                             (when control
 558                               (funcall control chunk inst stream dstate))
 559                             ))))))))))
 560
 561       (setf (dstate-cur-offs dstate) (dstate-next-offs dstate))
 562
 563       (unless (null stream)
 564         (unless prefix-p
 565           (print-notes-and-newline stream dstate))
 566         (setf (dstate-output-state dstate) nil)))))
 567 \f
 568 ;;; Make an initial non-printing disassembly pass through DSTATE,
 569 ;;; noting any addresses that are referenced by instructions in this
 570 ;;; segment.
 571 (defun add-segment-labels (segment dstate)
 572   ;; add labels at the beginning with a label-number of nil; we'll notice
 573   ;; later and fill them in (and sort them)
 574   (declare (type disassem-state dstate))
 575   (let ((labels (dstate-labels dstate)))
 576     (map-segment-instructions
 577      (lambda (chunk inst)
 578        (declare (type dchunk chunk) (type instruction inst))
 579        (let ((labeller (inst-labeller inst)))
 580          (when labeller
 581            (setf labels (funcall labeller chunk labels dstate)))))
 582      segment
 583      dstate)
 584     (setf (dstate-labels dstate) labels)
 585     ;; erase any notes that got there by accident
 586     (setf (dstate-notes dstate) nil)))
 587
 588 ;;; If any labels in DSTATE have been added since the last call to
 589 ;;; this function, give them label-numbers, enter them in the
 590 ;;; hash-table, and make sure the label list is in sorted order.
 591 (defun number-labels (dstate)
 592   (let ((labels (dstate-labels dstate)))
 593     (when (and labels (null (cdar labels)))
 594       ;; at least one label left un-numbered
 595       (setf labels (sort labels #'< :key #'car))
 596       (let ((max -1)
 597             (label-hash (dstate-label-hash dstate)))
 598         (dolist (label labels)
 599           (when (not (null (cdr label)))
 600             (setf max (max max (cdr label)))))
 601         (dolist (label labels)
 602           (when (null (cdr label))
 603             (incf max)
 604             (setf (cdr label) max)
 605             (setf (gethash (car label) label-hash)
 606                   (format nil "L~W" max)))))
 607       (setf (dstate-labels dstate) labels))))
 608 \f
 609 ;;; Get the instruction-space, creating it if necessary.
 610 (defun get-inst-space ()
 611   (let ((ispace *disassem-inst-space*))
 612     (when (null ispace)
 613       (let ((insts nil))
 614         (maphash (lambda (name inst-flavs)
 615                    (declare (ignore name))
 616                    (dolist (flav inst-flavs)
 617                      (push flav insts)))
 618                  *disassem-insts*)
 619         (setf ispace (build-inst-space insts)))
 620       (setf *disassem-inst-space* ispace))
 621     ispace))
 622 \f
 623 ;;;; Add global hooks.
 624
 625 (defun add-offs-hook (segment addr hook)
 626   (let ((entry (cons addr hook)))
 627     (if (null (seg-hooks segment))
 628         (setf (seg-hooks segment) (list entry))
 629         (push entry (cdr (last (seg-hooks segment)))))))
 630
 631 (defun add-offs-note-hook (segment addr note)
 632   (add-offs-hook segment
 633                  addr
 634                  (lambda (stream dstate)
 635                    (declare (type (or null stream) stream)
 636                             (type disassem-state dstate))
 637                    (when stream
 638                      (note note dstate)))))
 639
 640 (defun add-offs-comment-hook (segment addr comment)
 641   (add-offs-hook segment
 642                  addr
 643                  (lambda (stream dstate)
 644                    (declare (type (or null stream) stream)
 645                             (ignore dstate))
 646                    (when stream
 647                      (write-string ";;; " stream)
 648                      (etypecase comment
 649                        (string
 650                         (write-string comment stream))
 651                        (function
 652                         (funcall comment stream)))
 653                      (terpri stream)))))
 654
 655 (defun add-fun-hook (dstate function)
 656   (push function (dstate-fun-hooks dstate)))
 657 \f
 658 (defun set-location-printing-range (dstate from length)
 659   (setf (dstate-addr-print-len dstate)
 660         ;; 4 bits per hex digit
 661         (ceiling (integer-length (logxor from (+ from length))) 4)))
 662
 663 ;;; Print the current address in DSTATE to STREAM, plus any labels that
 664 ;;; correspond to it, and leave the cursor in the instruction column.
 665 (defun print-current-address (stream dstate)
 666   (declare (type stream stream)
 667            (type disassem-state dstate))
 668   (let* ((location
 669           (+ (seg-virtual-location (dstate-segment dstate))
 670              (dstate-cur-offs dstate)))
 671          (location-column-width *disassem-location-column-width*)
 672          (plen (dstate-addr-print-len dstate)))
 673
 674     (when (null plen)
 675       (setf plen location-column-width)
 676       (let ((seg (dstate-segment dstate)))
 677         (set-location-printing-range dstate
 678                                      (seg-virtual-location seg)
 679                                      (seg-length seg))))
 680     (when (eq (dstate-output-state dstate) :beginning)
 681       (setf plen location-column-width))
 682
 683     (fresh-line stream)
 684
 685     (setf location-column-width (+ 2 location-column-width))
 686     (princ "; " stream)
 687
 688     ;; print the location
 689     ;; [this is equivalent to (format stream "~V,'0x:" plen printed-value), but
 690     ;;  usually avoids any consing]
 691     (tab0 (- location-column-width plen) stream)
 692     (let* ((printed-bits (* 4 plen))
 693            (printed-value (ldb (byte printed-bits 0) location))
 694            (leading-zeros
 695             (truncate (- printed-bits (integer-length printed-value)) 4)))
 696       (dotimes (i leading-zeros)
 697         (write-char #\0 stream))
 698       (unless (zerop printed-value)
 699         (write printed-value :stream stream :base 16 :radix nil))
 700       (write-char #\: stream))
 701
 702     ;; print any labels
 703     (loop
 704       (let* ((next-label (car (dstate-cur-labels dstate)))
 705              (label-location (car next-label)))
 706         (when (or (null label-location) (> label-location location))
 707           (return))
 708         (unless (< label-location location)
 709           (format stream " L~W:" (cdr next-label)))
 710         (pop (dstate-cur-labels dstate))))
 711
 712     ;; move to the instruction column
 713     (tab0 (+ location-column-width 1 label-column-width) stream)
 714     ))
 715 \f
 716 (eval-when (:compile-toplevel :execute)
 717   (sb!xc:defmacro with-print-restrictions (&rest body)
 718     `(let ((*print-pretty* t)
 719            (*print-lines* 2)
 720            (*print-length* 4)
 721            (*print-level* 3))
 722        ,@body)))
 723
 724 ;;; Print a newline to STREAM, inserting any pending notes in DSTATE
 725 ;;; as end-of-line comments. If there is more than one note, a
 726 ;;; separate line will be used for each one.
 727 (defun print-notes-and-newline (stream dstate)
 728   (declare (type stream stream)
 729            (type disassem-state dstate))
 730   (with-print-restrictions
 731     (dolist (note (dstate-notes dstate))
 732       (format stream "~Vt " *disassem-note-column*)
 733       (pprint-logical-block (stream nil :per-line-prefix "; ")
 734       (etypecase note
 735         (string
 736          (write-string note stream))
 737         (function
 738          (funcall note stream))))
 739       (terpri stream))
 740     (fresh-line stream)
 741     (setf (dstate-notes dstate) nil)))
 742
 743 ;;; Print NUM instruction bytes to STREAM as hex values.
 744 (defun print-inst (num stream dstate &key (offset 0) (trailing-space t))
 745   (let ((sap (dstate-segment-sap dstate))
 746         (start-offs (+ offset (dstate-cur-offs dstate))))
 747     (dotimes (offs num)
 748       (format stream "~2,'0x" (sb!sys:sap-ref-8 sap (+ offs start-offs))))
 749     (when trailing-space
 750       (dotimes (i (- *disassem-inst-column-width* (* 2 num)))
 751         (write-char #\space stream))
 752       (write-char #\space stream))))
 753
 754 ;;; Disassemble NUM bytes to STREAM as simple `BYTE' instructions.
 755 (defun print-bytes (num stream dstate)
 756   (declare (type offset num)
 757            (type stream stream)
 758            (type disassem-state dstate))
 759   (format stream "~A~Vt" 'BYTE (dstate-argument-column dstate))
 760   (let ((sap (dstate-segment-sap dstate))
 761         (start-offs (dstate-cur-offs dstate)))
 762     (dotimes (offs num)
 763       (unless (zerop offs)
 764         (write-string ", " stream))
 765       (format stream "#X~2,'0x" (sb!sys:sap-ref-8 sap (+ offs start-offs))))))
 766
 767 ;;; Disassemble NUM machine-words to STREAM as simple `WORD' instructions.
 768 (defun print-words (num stream dstate)
 769   (declare (type offset num)
 770            (type stream stream)
 771            (type disassem-state dstate))
 772   (format stream "~A~Vt" 'WORD (dstate-argument-column dstate))
 773   (let ((sap (dstate-segment-sap dstate))
 774         (start-offs (dstate-cur-offs dstate))
 775         (byte-order (dstate-byte-order dstate)))
 776     (dotimes (word-offs num)
 777       (unless (zerop word-offs)
 778         (write-string ", " stream))
 779       (let ((word 0) (bit-shift 0))
 780         (dotimes (byte-offs sb!vm:n-word-bytes)
 781           (let ((byte
 782                  (sb!sys:sap-ref-8
 783                         sap
 784                         (+ start-offs
 785                            (* word-offs sb!vm:n-word-bytes)
 786                            byte-offs))))
 787             (setf word
 788                   (if (eq byte-order :big-endian)
 789                       (+ (ash word sb!vm:n-byte-bits) byte)
 790                       (+ word (ash byte bit-shift))))
 791             (incf bit-shift sb!vm:n-byte-bits)))
 792         (format stream "#X~V,'0X" (ash sb!vm:n-word-bits -2) word)))))
 793 \f
 794 (defvar *default-dstate-hooks* (list #'lra-hook))
 795
 796 ;;; Make a disassembler-state object.
 797 (defun make-dstate (&optional (fun-hooks *default-dstate-hooks*))
 798   (let ((sap
 799          (sb!sys:vector-sap (coerce #() '(vector (unsigned-byte 8)))))
 800         (alignment *disassem-inst-alignment-bytes*)
 801         (arg-column
 802          (+ (or *disassem-opcode-column-width* 0)
 803             *disassem-location-column-width*
 804             1
 805             label-column-width)))
 806
 807     (when (> alignment 1)
 808       (push #'alignment-hook fun-hooks))
 809
 810     (%make-dstate :segment-sap sap
 811                   :fun-hooks fun-hooks
 812                   :argument-column arg-column
 813                   :alignment alignment
 814                   :byte-order sb!c:*backend-byte-order*)))
 815
 816 (defun add-fun-header-hooks (segment)
 817   (declare (type segment segment))
 818   (do ((fun (sb!kernel:code-header-ref (seg-code segment)
 819                                        sb!vm:code-entry-points-slot)
 820             (fun-next fun))
 821        (length (seg-length segment)))
 822       ((null fun))
 823     (let ((offset (code-offs-to-segment-offs (fun-offset fun) segment)))
 824       (when (<= 0 offset length)
 825         (push (make-offs-hook :offset offset :fun #'fun-header-hook)
 826               (seg-hooks segment))))))
 827 \f
 828 ;;; A SAP-MAKER is a no-argument function that returns a SAP.
 829
 830 #!-sb-fluid (declaim (inline sap-maker))
 831
 832 (defun sap-maker (function input offset)
 833   (declare (optimize (speed 3))
 834            (type (function (t) sb!sys:system-area-pointer) function)
 835            (type offset offset))
 836   (let ((old-sap (sb!sys:sap+ (funcall function input) offset)))
 837     (declare (type sb!sys:system-area-pointer old-sap))
 838     (lambda ()
 839       (let ((new-addr
 840              (+ (sb!sys:sap-int (funcall function input)) offset)))
 841         ;; Saving the sap like this avoids consing except when the sap
 842         ;; changes (because the sap-int, arith, etc., get inlined).
 843         (declare (type address new-addr))
 844         (if (= (sb!sys:sap-int old-sap) new-addr)
 845             old-sap
 846             (setf old-sap (sb!sys:int-sap new-addr)))))))
 847
 848 (defun vector-sap-maker (vector offset)
 849   (declare (optimize (speed 3))
 850            (type offset offset))
 851   (sap-maker #'sb!sys:vector-sap vector offset))
 852
 853 (defun code-sap-maker (code offset)
 854   (declare (optimize (speed 3))
 855            (type sb!kernel:code-component code)
 856            (type offset offset))
 857   (sap-maker #'sb!kernel:code-instructions code offset))
 858
 859 (defun memory-sap-maker (address)
 860   (declare (optimize (speed 3))
 861            (type address address))
 862   (let ((sap (sb!sys:int-sap address)))
 863     (lambda () sap)))
 864 \f
 865 ;;; Return a memory segment located at the system-area-pointer returned by
 866 ;;; SAP-MAKER and LENGTH bytes long in the disassem-state object DSTATE.
 867 ;;;
 868 ;;; &KEY arguments include :VIRTUAL-LOCATION (by default the same as
 869 ;;; the address), :DEBUG-FUN, :SOURCE-FORM-CACHE (a
 870 ;;; SOURCE-FORM-CACHE object), and :HOOKS (a list of OFFS-HOOK
 871 ;;; objects).
 872 (defun make-segment (sap-maker length
 873                      &key
 874                      code virtual-location
 875                      debug-fun source-form-cache
 876                      hooks)
 877   (declare (type (function () sb!sys:system-area-pointer) sap-maker)
 878            (type disassem-length length)
 879            (type (or null address) virtual-location)
 880            (type (or null sb!di:debug-fun) debug-fun)
 881            (type (or null source-form-cache) source-form-cache))
 882   (let* ((segment
 883           (%make-segment
 884            :sap-maker sap-maker
 885            :length length
 886            :virtual-location (or virtual-location
 887                                  (sb!sys:sap-int (funcall sap-maker)))
 888            :hooks hooks
 889            :code code)))
 890     (add-debugging-hooks segment debug-fun source-form-cache)
 891     (add-fun-header-hooks segment)
 892     segment))
 893
 894 (defun make-vector-segment (vector offset &rest args)
 895   (declare (type vector vector)
 896            (type offset offset)
 897            (inline make-segment))
 898   (apply #'make-segment (vector-sap-maker vector offset) args))
 899
 900 (defun make-code-segment (code offset length &rest args)
 901   (declare (type sb!kernel:code-component code)
 902            (type offset offset)
 903            (inline make-segment))
 904   (apply #'make-segment (code-sap-maker code offset) length :code code args))
 905
 906 (defun make-memory-segment (address &rest args)
 907   (declare (type address address)
 908            (inline make-segment))
 909   (apply #'make-segment (memory-sap-maker address) args))
 910 \f
 911 ;;; just for fun
 912 (defun print-fun-headers (function)
 913   (declare (type compiled-function function))
 914   (let* ((self (fun-self function))
 915          (code (sb!kernel:fun-code-header self)))
 916     (format t "Code-header ~S: size: ~S, trace-table-offset: ~S~%"
 917             code
 918             (sb!kernel:code-header-ref code
 919                                        sb!vm:code-code-size-slot)
 920             (sb!kernel:code-header-ref code
 921                                        sb!vm:code-trace-table-offset-slot))
 922     (do ((fun (sb!kernel:code-header-ref code sb!vm:code-entry-points-slot)
 923               (fun-next fun)))
 924         ((null fun))
 925       (let ((fun-offset (sb!kernel:get-closure-length fun)))
 926         ;; There is function header fun-offset words from the
 927         ;; code header.
 928         (format t "Fun-header ~S at offset ~W (words): ~S~A => ~S~%"
 929                 fun
 930                 fun-offset
 931                 (sb!kernel:code-header-ref
 932                  code (+ fun-offset sb!vm:simple-fun-name-slot))
 933                 (sb!kernel:code-header-ref
 934                  code (+ fun-offset sb!vm:simple-fun-arglist-slot))
 935                 (sb!kernel:code-header-ref
 936                  code (+ fun-offset sb!vm:simple-fun-type-slot)))))))
 937 \f
 938 ;;; getting at the source code...
 939
 940 (defstruct (source-form-cache (:conc-name sfcache-)
 941                               (:copier nil))
 942   (debug-source nil :type (or null sb!di:debug-source))
 943   (toplevel-form-index -1 :type fixnum)
 944   (toplevel-form nil :type list)
 945   (form-number-mapping-table nil :type (or null (vector list)))
 946   (last-location-retrieved nil :type (or null sb!di:code-location))
 947   (last-form-retrieved -1 :type fixnum))
 948
 949 (defun get-toplevel-form (debug-source tlf-index)
 950   (let ((name (sb!di:debug-source-name debug-source)))
 951     (ecase (sb!di:debug-source-from debug-source)
 952       (:file
 953        (cond ((not (probe-file name))
 954               (warn "The source file ~S no longer seems to exist." name)
 955               nil)
 956              (t
 957               (let ((start-positions
 958                      (sb!di:debug-source-start-positions debug-source)))
 959                 (cond ((null start-positions)
 960                        (warn "There is no start positions map.")
 961                        nil)
 962                       (t
 963                        (let* ((local-tlf-index
 964                                (- tlf-index
 965                                   (sb!di:debug-source-root-number
 966                                    debug-source)))
 967                               (char-offset
 968                                (aref start-positions local-tlf-index)))
 969                          (with-open-file (f name)
 970                            (cond ((= (sb!di:debug-source-created debug-source)
 971                                      (file-write-date name))
 972                                   (file-position f char-offset))
 973                                  (t
 974                                   (warn "Source file ~S has been modified; ~@
 975                                          using form offset instead of ~
 976                                          file index."
 977                                         name)
 978                                   (let ((*read-suppress* t))
 979                                     (dotimes (i local-tlf-index) (read f)))))
 980                            (let ((*readtable* (copy-readtable)))
 981                              (set-dispatch-macro-character
 982                               #\# #\.
 983                               (lambda (stream sub-char &rest rest)
 984                                 (declare (ignore rest sub-char))
 985                                 (let ((token (read stream t nil t)))
 986                                   (format nil "#.~S" token))))
 987                              (read f))
 988                            ))))))))
 989       (:lisp
 990        (aref name tlf-index)))))
 991
 992 (defun cache-valid (loc cache)
 993   (and cache
 994        (and (eq (sb!di:code-location-debug-source loc)
 995                 (sfcache-debug-source cache))
 996             (eq (sb!di:code-location-toplevel-form-offset loc)
 997                 (sfcache-toplevel-form-index cache)))))
 998
 999 (defun get-source-form (loc context &optional cache)
1000   (let* ((cache-valid (cache-valid loc cache))
1001          (tlf-index (sb!di:code-location-toplevel-form-offset loc))
1002          (form-number (sb!di:code-location-form-number loc))
1003          (toplevel-form
1004           (if cache-valid
1005               (sfcache-toplevel-form cache)
1006               (get-toplevel-form (sb!di:code-location-debug-source loc)
1007                                   tlf-index)))
1008          (mapping-table
1009           (if cache-valid
1010               (sfcache-form-number-mapping-table cache)
1011               (sb!di:form-number-translations toplevel-form tlf-index))))
1012     (when (and (not cache-valid) cache)
1013       (setf (sfcache-debug-source cache) (sb!di:code-location-debug-source loc)
1014             (sfcache-toplevel-form-index cache) tlf-index
1015             (sfcache-toplevel-form cache) toplevel-form
1016             (sfcache-form-number-mapping-table cache) mapping-table))
1017     (cond ((null toplevel-form)
1018            nil)
1019           ((> form-number (length mapping-table))
1020            (warn "bogus form-number in form!  The source file has probably ~@
1021                   been changed too much to cope with.")
1022            (when cache
1023              ;; Disable future warnings.
1024              (setf (sfcache-toplevel-form cache) nil))
1025            nil)
1026           (t
1027            (when cache
1028              (setf (sfcache-last-location-retrieved cache) loc)
1029              (setf (sfcache-last-form-retrieved cache) form-number))
1030            (sb!di:source-path-context toplevel-form
1031                                       (aref mapping-table form-number)
1032                                       context)))))
1033
1034 (defun get-different-source-form (loc context &optional cache)
1035   (if (and (cache-valid loc cache)
1036            (or (= (sb!di:code-location-form-number loc)
1037                   (sfcache-last-form-retrieved cache))
1038                (and (sfcache-last-location-retrieved cache)
1039                     (sb!di:code-location=
1040                      loc
1041                      (sfcache-last-location-retrieved cache)))))
1042       (values nil nil)
1043       (values (get-source-form loc context cache) t)))
1044 \f
1045 ;;;; stuff to use debugging info to augment the disassembly
1046
1047 (defun code-fun-map (code)
1048   (declare (type sb!kernel:code-component code))
1049   (sb!c::compiled-debug-info-fun-map (sb!kernel:%code-debug-info code)))
1050
1051 (defstruct (location-group (:copier nil))
1052   (locations #() :type (vector (or list fixnum))))
1053
1054 (defstruct (storage-info (:copier nil))
1055   (groups nil :type list)               ; alist of (name . location-group)
1056   (debug-vars #() :type vector))
1057
1058 ;;; Return the vector of DEBUG-VARs currently associated with DSTATE.
1059 (defun dstate-debug-vars (dstate)
1060   (declare (type disassem-state dstate))
1061   (storage-info-debug-vars (seg-storage-info (dstate-segment dstate))))
1062
1063 ;;; Given the OFFSET of a location within the location-group called
1064 ;;; LG-NAME, see whether there's a current mapping to a source
1065 ;;; variable in DSTATE, and if so, return the offset of that variable
1066 ;;; in the current debug-var vector.
1067 (defun find-valid-storage-location (offset lg-name dstate)
1068   (declare (type offset offset)
1069            (type symbol lg-name)
1070            (type disassem-state dstate))
1071   (let* ((storage-info
1072           (seg-storage-info (dstate-segment dstate)))
1073          (location-group
1074           (and storage-info
1075                (cdr (assoc lg-name (storage-info-groups storage-info)))))
1076          (currently-valid
1077           (dstate-current-valid-locations dstate)))
1078     (and location-group
1079          (not (null currently-valid))
1080          (let ((locations (location-group-locations location-group)))
1081            (and (< offset (length locations))
1082                 (let ((used-by (aref locations offset)))
1083                   (and used-by
1084                        (let ((debug-var-num
1085                               (typecase used-by
1086                                 (fixnum
1087                                  (and (not
1088                                        (zerop (bit currently-valid used-by)))
1089                                       used-by))
1090                                 (list
1091                                  (some (lambda (num)
1092                                          (and (not
1093                                                (zerop
1094                                                 (bit currently-valid num)))
1095                                               num))
1096                                        used-by)))))
1097                          (and debug-var-num
1098                               (progn
1099                                 ;; Found a valid storage reference!
1100                                 ;; can't use it again until it's revalidated...
1101                                 (setf (bit (dstate-current-valid-locations
1102                                             dstate)
1103                                            debug-var-num)
1104                                       0)
1105                                 debug-var-num))
1106                          ))))))))
1107
1108 ;;; Return a new vector which has the same contents as the old one
1109 ;;; VEC, plus new cells (for a total size of NEW-LEN). The additional
1110 ;;; elements are initialized to INITIAL-ELEMENT.
1111 (defun grow-vector (vec new-len &optional initial-element)
1112   (declare (type vector vec)
1113            (type fixnum new-len))
1114   (let ((new
1115          (make-sequence `(vector ,(array-element-type vec) ,new-len)
1116                         new-len
1117                         :initial-element initial-element)))
1118     (dotimes (i (length vec))
1119       (setf (aref new i) (aref vec i)))
1120     new))
1121
1122 ;;; Return a STORAGE-INFO struction describing the object-to-source
1123 ;;; variable mappings from DEBUG-FUN.
1124 (defun storage-info-for-debug-fun (debug-fun)
1125   (declare (type sb!di:debug-fun debug-fun))
1126   (let ((sc-vec sb!c::*backend-sc-numbers*)
1127         (groups nil)
1128         (debug-vars (sb!di::debug-fun-debug-vars
1129                      debug-fun)))
1130     (and debug-vars
1131          (dotimes (debug-var-offset
1132                    (length debug-vars)
1133                    (make-storage-info :groups groups
1134                                       :debug-vars debug-vars))
1135            (let ((debug-var (aref debug-vars debug-var-offset)))
1136              #+nil
1137              (format t ";;; At offset ~W: ~S~%" debug-var-offset debug-var)
1138              (let* ((sc-offset
1139                      (sb!di::compiled-debug-var-sc-offset debug-var))
1140                     (sb-name
1141                      (sb!c:sb-name
1142                       (sb!c:sc-sb (aref sc-vec
1143                                         (sb!c:sc-offset-scn sc-offset))))))
1144                #+nil
1145                (format t ";;; SET: ~S[~W]~%"
1146                        sb-name (sb!c:sc-offset-offset sc-offset))
1147                (unless (null sb-name)
1148                  (let ((group (cdr (assoc sb-name groups))))
1149                    (when (null group)
1150                      (setf group (make-location-group))
1151                      (push `(,sb-name . ,group) groups))
1152                    (let* ((locations (location-group-locations group))
1153                           (length (length locations))
1154                           (offset (sb!c:sc-offset-offset sc-offset)))
1155                      (when (>= offset length)
1156                        (setf locations
1157                              (grow-vector locations
1158                                           (max (* 2 length)
1159                                                (1+ offset))
1160                                           nil)
1161                              (location-group-locations group)
1162                              locations))
1163                      (let ((already-there (aref locations offset)))
1164                        (cond ((null already-there)
1165                               (setf (aref locations offset) debug-var-offset))
1166                              ((eql already-there debug-var-offset))
1167                              (t
1168                               (if (listp already-there)
1169                                   (pushnew debug-var-offset
1170                                            (aref locations offset))
1171                                   (setf (aref locations offset)
1172                                         (list debug-var-offset
1173                                               already-there)))))
1174                        )))))))
1175          )))
1176
1177 (defun source-available-p (debug-fun)
1178   (handler-case
1179       (sb!di:do-debug-fun-blocks (block debug-fun)
1180         (declare (ignore block))
1181         (return t))
1182     (sb!di:no-debug-blocks () nil)))
1183
1184 (defun print-block-boundary (stream dstate)
1185   (let ((os (dstate-output-state dstate)))
1186     (when (not (eq os :beginning))
1187       (when (not (eq os :block-boundary))
1188         (terpri stream))
1189       (setf (dstate-output-state dstate)
1190             :block-boundary))))
1191
1192 ;;; Add hooks to track to track the source code in SEGMENT during
1193 ;;; disassembly. SFCACHE can be either NIL or it can be a
1194 ;;; SOURCE-FORM-CACHE structure, in which case it is used to cache
1195 ;;; forms from files.
1196 (defun add-source-tracking-hooks (segment debug-fun &optional sfcache)
1197   (declare (type segment segment)
1198            (type (or null sb!di:debug-fun) debug-fun)
1199            (type (or null source-form-cache) sfcache))
1200   (let ((last-block-pc -1))
1201     (flet ((add-hook (pc fun &optional before-address)
1202              (push (make-offs-hook
1203                     :offset pc ;; ### FIX to account for non-zero offs in code
1204                     :fun fun
1205                     :before-address before-address)
1206                    (seg-hooks segment))))
1207       (handler-case
1208           (sb!di:do-debug-fun-blocks (block debug-fun)
1209             (let ((first-location-in-block-p t))
1210               (sb!di:do-debug-block-locations (loc block)
1211                 (let ((pc (sb!di::compiled-code-location-pc loc)))
1212
1213                   ;; Put blank lines in at block boundaries
1214                   (when (and first-location-in-block-p
1215                              (/= pc last-block-pc))
1216                     (setf first-location-in-block-p nil)
1217                     (add-hook pc
1218                               (lambda (stream dstate)
1219                                 (print-block-boundary stream dstate))
1220                               t)
1221                     (setf last-block-pc pc))
1222
1223                   ;; Print out corresponding source; this information is not
1224                   ;; all that accurate, but it's better than nothing
1225                   (unless (zerop (sb!di:code-location-form-number loc))
1226                     (multiple-value-bind (form new)
1227                         (get-different-source-form loc 0 sfcache)
1228                       (when new
1229                          (let ((at-block-begin (= pc last-block-pc)))
1230                            (add-hook
1231                             pc
1232                             (lambda (stream dstate)
1233                               (declare (ignore dstate))
1234                               (when stream
1235                                 (unless at-block-begin
1236                                   (terpri stream))
1237                                 (format stream ";;; [~W] "
1238                                         (sb!di:code-location-form-number
1239                                          loc))
1240                                 (prin1-short form stream)
1241                                 (terpri stream)
1242                                 (terpri stream)))
1243                             t)))))
1244
1245                   ;; Keep track of variable live-ness as best we can.
1246                   (let ((live-set
1247                          (copy-seq (sb!di::compiled-code-location-live-set
1248                                     loc))))
1249                     (add-hook
1250                      pc
1251                      (lambda (stream dstate)
1252                        (declare (ignore stream))
1253                        (setf (dstate-current-valid-locations dstate)
1254                              live-set)
1255                        #+nil
1256                        (note (lambda (stream)
1257                                (let ((*print-length* nil))
1258                                  (format stream "live set: ~S"
1259                                          live-set)))
1260                              dstate))))
1261                   ))))
1262         (sb!di:no-debug-blocks () nil)))))
1263
1264 (defun add-debugging-hooks (segment debug-fun &optional sfcache)
1265   (when debug-fun
1266     (setf (seg-storage-info segment)
1267           (storage-info-for-debug-fun debug-fun))
1268     (add-source-tracking-hooks segment debug-fun sfcache)
1269     (let ((kind (sb!di:debug-fun-kind debug-fun)))
1270       (flet ((add-new-hook (n)
1271                (push (make-offs-hook
1272                       :offset 0
1273                       :fun (lambda (stream dstate)
1274                              (declare (ignore stream))
1275                              (note n dstate)))
1276                      (seg-hooks segment))))
1277         (case kind
1278           (:external)
1279           ((nil)
1280            (add-new-hook "no-arg-parsing entry point"))
1281           (t
1282            (add-new-hook (lambda (stream)
1283                            (format stream "~S entry point" kind)))))))))
1284 \f
1285 ;;; Return a list of the segments of memory containing machine code
1286 ;;; instructions for FUNCTION.
1287 (defun get-fun-segments (function)
1288   (declare (type compiled-function function))
1289   (let* ((code (fun-code function))
1290          (fun-map (code-fun-map code))
1291          (fname (sb!kernel:%simple-fun-name function))
1292          (sfcache (make-source-form-cache)))
1293     (let ((first-block-seen-p nil)
1294           (nil-block-seen-p nil)
1295           (last-offset 0)
1296           (last-debug-fun nil)
1297           (segments nil))
1298       (flet ((add-seg (offs len df)
1299                (when (> len 0)
1300                  (push (make-code-segment code offs len
1301                                           :debug-fun df
1302                                           :source-form-cache sfcache)
1303                        segments))))
1304         (dotimes (fmap-index (length fun-map))
1305           (let ((fmap-entry (aref fun-map fmap-index)))
1306             (etypecase fmap-entry
1307               (integer
1308                (when first-block-seen-p
1309                  (add-seg last-offset
1310                           (- fmap-entry last-offset)
1311                           last-debug-fun)
1312                  (setf last-debug-fun nil))
1313                (setf last-offset fmap-entry))
1314               (sb!c::compiled-debug-fun
1315                (let ((name (sb!c::compiled-debug-fun-name fmap-entry))
1316                      (kind (sb!c::compiled-debug-fun-kind fmap-entry)))
1317                  #+nil
1318                  (format t ";;; SAW ~S ~S ~S,~S ~W,~W~%"
1319                          name kind first-block-seen-p nil-block-seen-p
1320                          last-offset
1321                          (sb!c::compiled-debug-fun-start-pc fmap-entry))
1322                  (cond (#+nil (eq last-offset fun-offset)
1323                               (and (equal name fname) (not first-block-seen-p))
1324                               (setf first-block-seen-p t))
1325                        ((eq kind :external)
1326                         (when first-block-seen-p
1327                           (return)))
1328                        ((eq kind nil)
1329                         (when nil-block-seen-p
1330                           (return))
1331                         (when first-block-seen-p
1332                           (setf nil-block-seen-p t))))
1333                  (setf last-debug-fun
1334                        (sb!di::make-compiled-debug-fun fmap-entry code)))))))
1335         (let ((max-offset (code-inst-area-length code)))
1336           (when (and first-block-seen-p last-debug-fun)
1337             (add-seg last-offset
1338                      (- max-offset last-offset)
1339                      last-debug-fun))
1340           (if (null segments)
1341               (let ((offs (fun-insts-offset function)))
1342                 (list
1343                  (make-code-segment code offs (- max-offset offs))))
1344               (nreverse segments)))))))
1345
1346 ;;; Return a list of the segments of memory containing machine code
1347 ;;; instructions for the code-component CODE. If START-OFFSET and/or
1348 ;;; LENGTH is supplied, only that part of the code-segment is used
1349 ;;; (but these are constrained to lie within the code-segment).
1350 (defun get-code-segments (code
1351                           &optional
1352                           (start-offset 0)
1353                           (length (code-inst-area-length code)))
1354   (declare (type sb!kernel:code-component code)
1355            (type offset start-offset)
1356            (type disassem-length length))
1357   (let ((segments nil))
1358     (when code
1359       (let ((fun-map (code-fun-map code))
1360             (sfcache (make-source-form-cache)))
1361         (let ((last-offset 0)
1362               (last-debug-fun nil))
1363           (flet ((add-seg (offs len df)
1364                    (let* ((restricted-offs
1365                            (min (max start-offset offs)
1366                                 (+ start-offset length)))
1367                           (restricted-len
1368                            (- (min (max start-offset (+ offs len))
1369                                    (+ start-offset length))
1370                               restricted-offs)))
1371                      (when (> restricted-len 0)
1372                        (push (make-code-segment code
1373                                                 restricted-offs restricted-len
1374                                                 :debug-fun df
1375                                                 :source-form-cache sfcache)
1376                              segments)))))
1377             (dotimes (fun-map-index (length fun-map))
1378               (let ((fun-map-entry (aref fun-map fun-map-index)))
1379                 (etypecase fun-map-entry
1380                   (integer
1381                    (add-seg last-offset (- fun-map-entry last-offset)
1382                             last-debug-fun)
1383                    (setf last-debug-fun nil)
1384                    (setf last-offset fun-map-entry))
1385                   (sb!c::compiled-debug-fun
1386                    (setf last-debug-fun
1387                          (sb!di::make-compiled-debug-fun fun-map-entry
1388                                                          code))))))
1389             (when last-debug-fun
1390               (add-seg last-offset
1391                        (- (code-inst-area-length code) last-offset)
1392                        last-debug-fun))))))
1393     (if (null segments)
1394         (make-code-segment code start-offset length)
1395         (nreverse segments))))
1396 \f
1397 ;;; Return two values: the amount by which the last instruction in the
1398 ;;; segment goes past the end of the segment, and the offset of the
1399 ;;; end of the segment from the beginning of that instruction. If all
1400 ;;; instructions fit perfectly, return 0 and 0.
1401 (defun segment-overflow (segment dstate)
1402   (declare (type segment segment)
1403            (type disassem-state dstate))
1404   (let ((seglen (seg-length segment))
1405         (last-start 0))
1406     (map-segment-instructions (lambda (chunk inst)
1407                                 (declare (ignore chunk inst))
1408                                 (setf last-start (dstate-cur-offs dstate)))
1409                               segment
1410                               dstate)
1411     (values (- (dstate-cur-offs dstate) seglen)
1412             (- seglen last-start))))
1413
1414 ;;; Compute labels for all the memory segments in SEGLIST and adds
1415 ;;; them to DSTATE. It's important to call this function with all the
1416 ;;; segments you're interested in, so that it can find references from
1417 ;;; one to another.
1418 (defun label-segments (seglist dstate)
1419   (declare (type list seglist)
1420            (type disassem-state dstate))
1421   (dolist (seg seglist)
1422     (add-segment-labels seg dstate))
1423   ;; Now remove any labels that don't point anywhere in the segments
1424   ;; we have.
1425   (setf (dstate-labels dstate)
1426         (remove-if (lambda (lab)
1427                      (not
1428                       (some (lambda (seg)
1429                               (let ((start (seg-virtual-location seg)))
1430                                 (<= start
1431                                     (car lab)
1432                                     (+ start (seg-length seg)))))
1433                             seglist)))
1434                    (dstate-labels dstate))))
1435
1436 ;;; Disassemble the machine code instructions in SEGMENT to STREAM.
1437 (defun disassemble-segment (segment stream dstate)
1438   (declare (type segment segment)
1439            (type stream stream)
1440            (type disassem-state dstate))
1441   (let ((*print-pretty* nil)) ; otherwise the pp conses hugely
1442     (number-labels dstate)
1443     (map-segment-instructions
1444      (lambda (chunk inst)
1445        (declare (type dchunk chunk) (type instruction inst))
1446        (let ((printer (inst-printer inst)))
1447          (when printer
1448            (funcall printer chunk inst stream dstate))))
1449      segment
1450      dstate
1451      stream)))
1452
1453 ;;; Disassemble the machine code instructions in each memory segment
1454 ;;; in SEGMENTS in turn to STREAM.
1455 (defun disassemble-segments (segments stream dstate)
1456   (declare (type list segments)
1457            (type stream stream)
1458            (type disassem-state dstate))
1459   (unless (null segments)
1460     (let ((first (car segments))
1461           (last (car (last segments))))
1462       (set-location-printing-range dstate
1463                                   (seg-virtual-location first)
1464                                   (- (+ (seg-virtual-location last)
1465                                         (seg-length last))
1466                                      (seg-virtual-location first)))
1467       (setf (dstate-output-state dstate) :beginning)
1468       (dolist (seg segments)
1469         (disassemble-segment seg stream dstate)))))
1470 \f
1471 ;;;; top level functions
1472
1473 ;;; Disassemble the machine code instructions for FUNCTION.
1474 (defun disassemble-fun (fun &key
1475                             (stream *standard-output*)
1476                             (use-labels t))
1477   (declare (type compiled-function fun)
1478            (type stream stream)
1479            (type (member t nil) use-labels))
1480   (let* ((dstate (make-dstate))
1481          (segments (get-fun-segments fun)))
1482     (when use-labels
1483       (label-segments segments dstate))
1484     (disassemble-segments segments stream dstate)))
1485
1486 ;;; FIXME: We probably don't need this any more now that there are
1487 ;;; no interpreted functions, only compiled ones.
1488 (defun compile-function-lambda-expr (function)
1489   (declare (type function function))
1490   (multiple-value-bind (lambda closurep name)
1491       (function-lambda-expression function)
1492     (declare (ignore name))
1493     (when closurep
1494       (error "can't compile a lexical closure"))
1495     (compile nil lambda)))
1496
1497 (defun compiled-fun-or-lose (thing &optional (name thing))
1498   (cond ((legal-fun-name-p thing)
1499          (compiled-fun-or-lose (fdefinition thing) thing))
1500         ((functionp thing)
1501          thing)
1502         ((and (listp thing)
1503               (eq (car thing) 'lambda))
1504          (compile nil thing))
1505         (t
1506          (error "can't make a compiled function from ~S" name))))
1507
1508 (defun disassemble (object &key
1509                            (stream *standard-output*)
1510                            (use-labels t))
1511   #!+sb-doc
1512   "Disassemble the compiled code associated with OBJECT, which can be a
1513   function, a lambda expression, or a symbol with a function definition. If
1514   it is not already compiled, the compiler is called to produce something to
1515   disassemble."
1516   (declare (type (or function symbol cons) object)
1517            (type (or (member t) stream) stream)
1518            (type (member t nil) use-labels))
1519   (pprint-logical-block (*standard-output* nil :per-line-prefix "; ")
1520     (disassemble-fun (compiled-fun-or-lose object)
1521                      :stream stream
1522                      :use-labels use-labels)
1523     nil))
1524
1525 ;;; Disassembles the given area of memory starting at ADDRESS and
1526 ;;; LENGTH long. Note that if CODE-COMPONENT is NIL and this memory
1527 ;;; could move during a GC, you'd better disable it around the call to
1528 ;;; this function.
1529 (defun disassemble-memory (address
1530                            length
1531                            &key
1532                            (stream *standard-output*)
1533                            code-component
1534                            (use-labels t))
1535   (declare (type (or address sb!sys:system-area-pointer) address)
1536            (type disassem-length length)
1537            (type stream stream)
1538            (type (or null sb!kernel:code-component) code-component)
1539            (type (member t nil) use-labels))
1540   (let* ((address
1541           (if (sb!sys:system-area-pointer-p address)
1542               (sb!sys:sap-int address)
1543               address))
1544          (dstate (make-dstate))
1545          (segments
1546           (if code-component
1547               (let ((code-offs
1548                      (- address
1549                         (sb!sys:sap-int
1550                          (sb!kernel:code-instructions code-component)))))
1551                 (when (or (< code-offs 0)
1552                           (> code-offs (code-inst-area-length code-component)))
1553                   (error "address ~X not in the code component ~S"
1554                          address code-component))
1555                 (get-code-segments code-component code-offs length))
1556               (list (make-memory-segment address length)))))
1557     (when use-labels
1558       (label-segments segments dstate))
1559     (disassemble-segments segments stream dstate)))
1560
1561 ;;; Disassemble the machine code instructions associated with
1562 ;;; CODE-COMPONENT (this may include multiple entry points).
1563 (defun disassemble-code-component (code-component &key
1564                                                   (stream *standard-output*)
1565                                                   (use-labels t))
1566   (declare (type (or null sb!kernel:code-component compiled-function)
1567                  code-component)
1568            (type stream stream)
1569            (type (member t nil) use-labels))
1570   (let* ((code-component
1571           (if (functionp code-component)
1572               (fun-code code-component)
1573               code-component))
1574          (dstate (make-dstate))
1575          (segments (get-code-segments code-component)))
1576     (when use-labels
1577       (label-segments segments dstate))
1578     (disassemble-segments segments stream dstate)))
1579 \f
1580 ;;; code for making useful segments from arbitrary lists of code-blocks
1581
1582 ;;; the maximum size of an instruction. Note that this includes
1583 ;;; pseudo-instructions like error traps with their associated
1584 ;;; operands, so it should be big enough to include them, i.e. it's
1585 ;;; not just 4 on a risc machine!
1586 (defconstant max-instruction-size 16)
1587
1588 (defun add-block-segments (seg-code-block
1589                            seglist
1590                            location
1591                            connecting-vec
1592                            dstate)
1593   (declare (type list seglist)
1594            (type integer location)
1595            (type (or null (vector (unsigned-byte 8))) connecting-vec)
1596            (type disassem-state dstate))
1597   (flet ((addit (seg overflow)
1598            (let ((length (+ (seg-length seg) overflow)))
1599              (when (> length 0)
1600                (setf (seg-length seg) length)
1601                (incf location length)
1602                (push seg seglist)))))
1603     (let ((connecting-overflow 0)
1604           (amount (length seg-code-block)))
1605       (when connecting-vec
1606         ;; Tack on some of the new block to the old overflow vector.
1607         (let* ((beginning-of-block-amount
1608                 (if seg-code-block (min max-instruction-size amount) 0))
1609                (connecting-vec
1610                 (if seg-code-block
1611                     (concatenate
1612                      '(vector (unsigned-byte 8))
1613                      connecting-vec
1614                      (subseq seg-code-block 0 beginning-of-block-amount))
1615                     connecting-vec)))
1616           (when (and (< (length connecting-vec) max-instruction-size)
1617                      (not (null seg-code-block)))
1618             (return-from add-block-segments
1619               ;; We want connecting vectors to be large enough to hold
1620               ;; any instruction, and since the current seg-code-block
1621               ;; wasn't large enough to do this (and is now entirely
1622               ;; on the end of the overflow-vector), just save it for
1623               ;; next time.
1624               (values seglist location connecting-vec)))
1625           (when (> (length connecting-vec) 0)
1626             (let ((seg
1627                    (make-vector-segment connecting-vec
1628                                         0
1629                                         (- (length connecting-vec)
1630                                            beginning-of-block-amount)
1631                                         :virtual-location location)))
1632               (setf connecting-overflow (segment-overflow seg dstate))
1633               (addit seg connecting-overflow)))))
1634       (cond ((null seg-code-block)
1635              ;; nothing more to add
1636              (values seglist location nil))
1637             ((< (- amount connecting-overflow) max-instruction-size)
1638              ;; We can't create a segment with the minimum size
1639              ;; required for an instruction, so just keep on accumulating
1640              ;; in the overflow vector for the time-being.
1641              (values seglist
1642                      location
1643                      (subseq seg-code-block connecting-overflow amount)))
1644             (t
1645              ;; Put as much as we can into a new segment, and the rest
1646              ;; into the overflow-vector.
1647              (let* ((initial-length
1648                      (- amount connecting-overflow max-instruction-size))
1649                     (seg
1650                      (make-vector-segment seg-code-block
1651                                           connecting-overflow
1652                                           initial-length
1653                                           :virtual-location location))
1654                     (overflow
1655                      (segment-overflow seg dstate)))
1656                (addit seg overflow)
1657                (values seglist
1658                        location
1659                        (subseq seg-code-block
1660                                (+ connecting-overflow (seg-length seg))
1661                                amount))))))))
1662 \f
1663 ;;;; code to disassemble assembler segments
1664
1665 (defun assem-segment-to-disassem-segments (assem-segment dstate)
1666   (declare (type sb!assem:segment assem-segment)
1667            (type disassem-state dstate))
1668   (let ((location 0)
1669         (disassem-segments nil)
1670         (connecting-vec nil))
1671     (sb!assem:on-segment-contents-vectorly
1672      assem-segment
1673      (lambda (seg-code-block)
1674        (multiple-value-setq (disassem-segments location connecting-vec)
1675          (add-block-segments seg-code-block
1676                              disassem-segments
1677                              location
1678                              connecting-vec
1679                              dstate))))
1680     (when connecting-vec
1681       (setf disassem-segments
1682             (add-block-segments nil
1683                                 disassem-segments
1684                                 location
1685                                 connecting-vec
1686                                 dstate)))
1687     (sort disassem-segments #'< :key #'seg-virtual-location)))
1688
1689 ;;; Disassemble the machine code instructions associated with
1690 ;;; ASSEM-SEGMENT (of type assem:segment).
1691 (defun disassemble-assem-segment (assem-segment stream)
1692   (declare (type sb!assem:segment assem-segment)
1693            (type stream stream))
1694   (let* ((dstate (make-dstate))
1695          (disassem-segments
1696           (assem-segment-to-disassem-segments assem-segment dstate)))
1697     (label-segments disassem-segments dstate)
1698     (disassemble-segments disassem-segments stream dstate)))
1699 \f
1700 ;;; routines to find things in the Lisp environment
1701
1702 ;;; an alist of (SYMBOL-SLOT-OFFSET . ACCESS-FUN-NAME) for slots
1703 ;;; in a symbol object that we know about
1704 (defparameter *grokked-symbol-slots*
1705   (sort `((,sb!vm:symbol-value-slot . symbol-value)
1706           (,sb!vm:symbol-plist-slot . symbol-plist)
1707           (,sb!vm:symbol-name-slot . symbol-name)
1708           (,sb!vm:symbol-package-slot . symbol-package))
1709         #'<
1710         :key #'car))
1711
1712 ;;; Given ADDRESS, try and figure out if which slot of which symbol is
1713 ;;; being referred to. Of course we can just give up, so it's not a
1714 ;;; big deal... Return two values, the symbol and the name of the
1715 ;;; access function of the slot.
1716 (defun grok-symbol-slot-ref (address)
1717   (declare (type address address))
1718   (if (not (aligned-p address sb!vm:n-word-bytes))
1719       (values nil nil)
1720       (do ((slots-tail *grokked-symbol-slots* (cdr slots-tail)))
1721           ((null slots-tail)
1722            (values nil nil))
1723         (let* ((field (car slots-tail))
1724                (slot-offset (words-to-bytes (car field)))
1725                (maybe-symbol-addr (- address slot-offset))
1726                (maybe-symbol
1727                 (sb!kernel:make-lisp-obj
1728                  (+ maybe-symbol-addr sb!vm:other-pointer-lowtag))))
1729           (when (symbolp maybe-symbol)
1730             (return (values maybe-symbol (cdr field))))))))
1731
1732 (defvar *address-of-nil-object* (sb!kernel:get-lisp-obj-address nil))
1733
1734 ;;; Given a BYTE-OFFSET from NIL, try and figure out which slot of
1735 ;;; which symbol is being referred to. Of course we can just give up,
1736 ;;; so it's not a big deal... Return two values, the symbol and the
1737 ;;; access function.
1738 (defun grok-nil-indexed-symbol-slot-ref (byte-offset)
1739   (declare (type offset byte-offset))
1740   (grok-symbol-slot-ref (+ *address-of-nil-object* byte-offset)))
1741
1742 ;;; Return the Lisp object located BYTE-OFFSET from NIL.
1743 (defun get-nil-indexed-object (byte-offset)
1744   (declare (type offset byte-offset))
1745   (sb!kernel:make-lisp-obj (+ *address-of-nil-object* byte-offset)))
1746
1747 ;;; Return two values; the Lisp object located at BYTE-OFFSET in the
1748 ;;; constant area of the code-object in the current segment and T, or
1749 ;;; NIL and NIL if there is no code-object in the current segment.
1750 (defun get-code-constant (byte-offset dstate)
1751   #!+sb-doc
1752   (declare (type offset byte-offset)
1753            (type disassem-state dstate))
1754   (let ((code (seg-code (dstate-segment dstate))))
1755     (if code
1756         (values
1757          (sb!kernel:code-header-ref code
1758                                     (ash (+ byte-offset
1759                                             sb!vm:other-pointer-lowtag)
1760                                          (- sb!vm:word-shift)))
1761          t)
1762         (values nil nil))))
1763
1764 (defun get-code-constant-absolute (addr dstate)
1765   (declare (type address addr))
1766   (declare (type disassem-state dstate))
1767   (let ((code (seg-code (dstate-segment dstate))))
1768     (if (null code)
1769       (return-from get-code-constant-absolute (values nil nil)))
1770     (let ((code-size (ash (sb!kernel:get-header-data code) sb!vm:word-shift)))
1771       (sb!sys:without-gcing
1772        (let ((code-addr (- (sb!kernel:get-lisp-obj-address code)
1773                            sb!vm:other-pointer-lowtag)))
1774          (if (or (< addr code-addr) (>= addr (+ code-addr code-size)))
1775            (values nil nil)
1776            (values (sb!kernel:code-header-ref
1777                     code
1778                     (ash (- addr code-addr) (- sb!vm:word-shift)))
1779                    t)))))))
1780
1781 (defvar *assembler-routines-by-addr* nil)
1782
1783 (defvar *foreign-symbols-by-addr* nil)
1784
1785 ;;; Build an address-name hash-table from the name-address hash
1786 (defun invert-address-hash (htable &optional (addr-hash (make-hash-table)))
1787   (maphash (lambda (name address)
1788              (setf (gethash address addr-hash) name))
1789            htable)
1790   addr-hash)
1791
1792 ;;; Return the name of the primitive Lisp assembler routine or foreign
1793 ;;; symbol located at ADDRESS, or NIL if there isn't one.
1794 (defun find-assembler-routine (address)
1795   (declare (type address address))
1796   (when (null *assembler-routines-by-addr*)
1797     (setf *assembler-routines-by-addr*
1798           (invert-address-hash sb!fasl:*assembler-routines*))
1799     (setf *assembler-routines-by-addr*
1800           (invert-address-hash sb!sys:*static-foreign-symbols*
1801                                *assembler-routines-by-addr*)))
1802   (gethash address *assembler-routines-by-addr*))
1803 \f
1804 ;;;; some handy function for machine-dependent code to use...
1805
1806 #!-sb-fluid (declaim (maybe-inline sap-ref-int read-suffix))
1807
1808 (defun sap-ref-int (sap offset length byte-order)
1809   (declare (type sb!sys:system-area-pointer sap)
1810            (type (unsigned-byte 16) offset)
1811            (type (member 1 2 4 8) length)
1812            (type (member :little-endian :big-endian) byte-order)
1813            (optimize (speed 3) (safety 0)))
1814   (ecase length
1815     (1 (sb!sys:sap-ref-8 sap offset))
1816     (2 (if (eq byte-order :big-endian)
1817            (+ (ash (sb!sys:sap-ref-8 sap offset) 8)
1818               (sb!sys:sap-ref-8 sap (+ offset 1)))
1819            (+ (ash (sb!sys:sap-ref-8 sap (+ offset 1)) 8)
1820               (sb!sys:sap-ref-8 sap offset))))
1821     (4 (if (eq byte-order :big-endian)
1822            (+ (ash (sb!sys:sap-ref-8 sap offset) 24)
1823               (ash (sb!sys:sap-ref-8 sap (+ 1 offset)) 16)
1824               (ash (sb!sys:sap-ref-8 sap (+ 2 offset)) 8)
1825               (sb!sys:sap-ref-8 sap (+ 3 offset)))
1826            (+ (sb!sys:sap-ref-8 sap offset)
1827               (ash (sb!sys:sap-ref-8 sap (+ 1 offset)) 8)
1828               (ash (sb!sys:sap-ref-8 sap (+ 2 offset)) 16)
1829               (ash (sb!sys:sap-ref-8 sap (+ 3 offset)) 24))))
1830     (8 (if (eq byte-order :big-endian)
1831            (+ (ash (sb!sys:sap-ref-8 sap offset) 56)
1832               (ash (sb!sys:sap-ref-8 sap (+ 1 offset)) 48)
1833               (ash (sb!sys:sap-ref-8 sap (+ 2 offset)) 40)
1834               (ash (sb!sys:sap-ref-8 sap (+ 3 offset)) 32)
1835               (ash (sb!sys:sap-ref-8 sap (+ 4 offset)) 24)
1836               (ash (sb!sys:sap-ref-8 sap (+ 5 offset)) 16)
1837               (ash (sb!sys:sap-ref-8 sap (+ 6 offset)) 8)
1838               (sb!sys:sap-ref-8 sap (+ 7 offset)))
1839            (+ (sb!sys:sap-ref-8 sap offset)
1840               (ash (sb!sys:sap-ref-8 sap (+ 1 offset)) 8)
1841               (ash (sb!sys:sap-ref-8 sap (+ 2 offset)) 16)
1842               (ash (sb!sys:sap-ref-8 sap (+ 3 offset)) 24)
1843               (ash (sb!sys:sap-ref-8 sap (+ 4 offset)) 32)
1844               (ash (sb!sys:sap-ref-8 sap (+ 5 offset)) 40)
1845               (ash (sb!sys:sap-ref-8 sap (+ 6 offset)) 48)
1846               (ash (sb!sys:sap-ref-8 sap (+ 7 offset)) 56))))))
1847
1848 (defun read-suffix (length dstate)
1849   (declare (type (member 8 16 32 64) length)
1850            (type disassem-state dstate)
1851            (optimize (speed 3) (safety 0)))
1852   (let ((length (ecase length (8 1) (16 2) (32 4) (64 8))))
1853     (declare (type (unsigned-byte 4) length))
1854     (prog1
1855       (sap-ref-int (dstate-segment-sap dstate)
1856                    (dstate-next-offs dstate)
1857                    length
1858                    (dstate-byte-order dstate))
1859       (incf (dstate-next-offs dstate) length))))
1860 \f
1861 ;;;; optional routines to make notes about code
1862
1863 ;;; Store NOTE (which can be either a string or a function with a
1864 ;;; single stream argument) to be printed as an end-of-line comment
1865 ;;; after the current instruction is disassembled.
1866 (defun note (note dstate)
1867   (declare (type (or string function) note)
1868            (type disassem-state dstate))
1869   (push note (dstate-notes dstate)))
1870
1871 (defun prin1-short (thing stream)
1872   (with-print-restrictions
1873     (prin1 thing stream)))
1874
1875 (defun prin1-quoted-short (thing stream)
1876   (if (self-evaluating-p thing)
1877       (prin1-short thing stream)
1878       (prin1-short `',thing stream)))
1879
1880 ;;; Store a note about the lisp constant located BYTE-OFFSET bytes
1881 ;;; from the current code-component, to be printed as an end-of-line
1882 ;;; comment after the current instruction is disassembled.
1883 (defun note-code-constant (byte-offset dstate)
1884   (declare (type offset byte-offset)
1885            (type disassem-state dstate))
1886   (multiple-value-bind (const valid)
1887       (get-code-constant byte-offset dstate)
1888     (when valid
1889       (note (lambda (stream)
1890               (prin1-quoted-short const stream))
1891             dstate))
1892     const))
1893
1894 ;;; Store a note about the lisp constant located at ADDR in the
1895 ;;; current code-component, to be printed as an end-of-line comment
1896 ;;; after the current instruction is disassembled.
1897 (defun note-code-constant-absolute (addr dstate)
1898   (declare (type address addr)
1899            (type disassem-state dstate))
1900   (multiple-value-bind (const valid)
1901       (get-code-constant-absolute addr dstate)
1902     (when valid
1903       (note (lambda (stream)
1904               (prin1-quoted-short const stream))
1905             dstate))
1906     (values const valid)))
1907
1908 ;;; If the memory address located NIL-BYTE-OFFSET bytes from the
1909 ;;; constant NIL is a valid slot in a symbol, store a note describing
1910 ;;; which symbol and slot, to be printed as an end-of-line comment
1911 ;;; after the current instruction is disassembled. Returns non-NIL iff
1912 ;;; a note was recorded.
1913 (defun maybe-note-nil-indexed-symbol-slot-ref (nil-byte-offset dstate)
1914   (declare (type offset nil-byte-offset)
1915            (type disassem-state dstate))
1916   (multiple-value-bind (symbol access-fun)
1917       (grok-nil-indexed-symbol-slot-ref nil-byte-offset)
1918     (when access-fun
1919       (note (lambda (stream)
1920               (prin1 (if (eq access-fun 'symbol-value)
1921                          symbol
1922                          `(,access-fun ',symbol))
1923                      stream))
1924             dstate))
1925     access-fun))
1926
1927 ;;; If the memory address located NIL-BYTE-OFFSET bytes from the
1928 ;;; constant NIL is a valid lisp object, store a note describing which
1929 ;;; symbol and slot, to be printed as an end-of-line comment after the
1930 ;;; current instruction is disassembled. Returns non-NIL iff a note
1931 ;;; was recorded.
1932 (defun maybe-note-nil-indexed-object (nil-byte-offset dstate)
1933   (declare (type offset nil-byte-offset)
1934            (type disassem-state dstate))
1935   (let ((obj (get-nil-indexed-object nil-byte-offset)))
1936     (note (lambda (stream)
1937             (prin1-quoted-short obj stream))
1938           dstate)
1939     t))
1940
1941 ;;; If ADDRESS is the address of a primitive assembler routine or
1942 ;;; foreign symbol, store a note describing which one, to be printed
1943 ;;; as an end-of-line comment after the current instruction is
1944 ;;; disassembled. Returns non-NIL iff a note was recorded. If
1945 ;;; NOTE-ADDRESS-P is non-NIL, a note of the address is also made.
1946 (defun maybe-note-assembler-routine (address note-address-p dstate)
1947   (declare (type disassem-state dstate))
1948   (unless (typep address 'address)
1949     (return-from maybe-note-assembler-routine nil))
1950   (let ((name (or
1951                #!+linkage-table
1952                (sb!sys:foreign-symbol-in-address (sb!sys:int-sap address))
1953                (find-assembler-routine address))))
1954     (unless (null name)
1955       (note (lambda (stream)
1956               (if note-address-p
1957                   (format stream "#x~8,'0x: ~a" address name)
1958                   (princ name stream)))
1959             dstate))
1960     name))
1961
1962 ;;; If there's a valid mapping from OFFSET in the storage class
1963 ;;; SC-NAME to a source variable, make a note of the source-variable
1964 ;;; name, to be printed as an end-of-line comment after the current
1965 ;;; instruction is disassembled. Returns non-NIL iff a note was
1966 ;;; recorded.
1967 (defun maybe-note-single-storage-ref (offset sc-name dstate)
1968   (declare (type offset offset)
1969            (type symbol sc-name)
1970            (type disassem-state dstate))
1971   (let ((storage-location
1972          (find-valid-storage-location offset sc-name dstate)))
1973     (when storage-location
1974       (note (lambda (stream)
1975               (princ (sb!di:debug-var-symbol
1976                       (aref (storage-info-debug-vars
1977                              (seg-storage-info (dstate-segment dstate)))
1978                             storage-location))
1979                      stream))
1980             dstate)
1981       t)))
1982
1983 ;;; If there's a valid mapping from OFFSET in the storage-base called
1984 ;;; SB-NAME to a source variable, make a note equating ASSOC-WITH with
1985 ;;; the source-variable name, to be printed as an end-of-line comment
1986 ;;; after the current instruction is disassembled. Returns non-NIL iff
1987 ;;; a note was recorded.
1988 (defun maybe-note-associated-storage-ref (offset sb-name assoc-with dstate)
1989   (declare (type offset offset)
1990            (type symbol sb-name)
1991            (type (or symbol string) assoc-with)
1992            (type disassem-state dstate))
1993   (let ((storage-location
1994          (find-valid-storage-location offset sb-name dstate)))
1995     (when storage-location
1996       (note (lambda (stream)
1997               (format stream "~A = ~S"
1998                       assoc-with
1999                       (sb!di:debug-var-symbol
2000                        (aref (dstate-debug-vars dstate)
2001                              storage-location))))
2002             dstate)
2003       t)))
2004 \f
2005 (defun get-internal-error-name (errnum)
2006   (car (svref sb!c:*backend-internal-errors* errnum)))
2007
2008 (defun get-sc-name (sc-offs)
2009   (sb!c::location-print-name
2010    ;; FIXME: This seems like an awful lot of computation just to get a name.
2011    ;; Couldn't we just use lookup in *BACKEND-SC-NAMES*, without having to cons
2012    ;; up a new object?
2013    (sb!c:make-random-tn :kind :normal
2014                         :sc (svref sb!c:*backend-sc-numbers*
2015                                    (sb!c:sc-offset-scn sc-offs))
2016                         :offset (sb!c:sc-offset-offset sc-offs))))
2017
2018 ;;; When called from an error break instruction's :DISASSEM-CONTROL (or
2019 ;;; :DISASSEM-PRINTER) function, will correctly deal with printing the
2020 ;;; arguments to the break.
2021 ;;;
2022 ;;; ERROR-PARSE-FUN should be a function that accepts:
2023 ;;;   1) a SYSTEM-AREA-POINTER
2024 ;;;   2) a BYTE-OFFSET from the SAP to begin at
2025 ;;;   3) optionally, LENGTH-ONLY, which if non-NIL, means to only return
2026 ;;;      the byte length of the arguments (to avoid unnecessary consing)
2027 ;;; It should read information from the SAP starting at BYTE-OFFSET, and
2028 ;;; return four values:
2029 ;;;   1) the error number
2030 ;;;   2) the total length, in bytes, of the information
2031 ;;;   3) a list of SC-OFFSETs of the locations of the error parameters
2032 ;;;   4) a list of the length (as read from the SAP), in bytes, of each
2033 ;;;      of the return values.
2034 (defun handle-break-args (error-parse-fun stream dstate)
2035   (declare (type function error-parse-fun)
2036            (type (or null stream) stream)
2037            (type disassem-state dstate))
2038   (multiple-value-bind (errnum adjust sc-offsets lengths)
2039       (funcall error-parse-fun
2040                (dstate-segment-sap dstate)
2041                (dstate-next-offs dstate)
2042                (null stream))
2043     (when stream
2044       (setf (dstate-cur-offs dstate)
2045             (dstate-next-offs dstate))
2046       (flet ((emit-err-arg (note)
2047                (let ((num (pop lengths)))
2048                  (print-notes-and-newline stream dstate)
2049                  (print-current-address stream dstate)
2050                  (print-inst num stream dstate)
2051                  (print-bytes num stream dstate)
2052                  (incf (dstate-cur-offs dstate) num)
2053                  (when note
2054                    (note note dstate)))))
2055         (emit-err-arg nil)
2056         (emit-err-arg (symbol-name (get-internal-error-name errnum)))
2057         (dolist (sc-offs sc-offsets)
2058           (emit-err-arg (get-sc-name sc-offs)))))
2059     (incf (dstate-next-offs dstate)
2060           adjust)))