src/compiler/target-main.lisp

   1 ;;;; functions from classic CMU CL src/compiler/main.lisp which are
   2 ;;;; needed only (and which may make sense only) on the
   3 ;;;; cross-compilation target, not the cross-compilation host
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15 \f
  16 ;;;; CL:COMPILE
  17
  18 (defun get-lambda-to-compile (definition-designator)
  19   (if (consp definition-designator)
  20       definition-designator
  21       (multiple-value-bind (definition env-p)
  22                            (function-lambda-expression definition-designator)
  23         (when env-p
  24           (error "~S was defined in a non-null environment."
  25                  definition-designator))
  26         (unless definition
  27           (error "can't find a definition for ~S" definition-designator))
  28         definition)))
  29
  30 ;;; Handle the nontrivial case of CL:COMPILE.
  31 (defun actually-compile (name definition *lexenv*)
  32   (with-compilation-values
  33     (sb!xc:with-compilation-unit ()
  34       ;; FIXME: These bindings were copied from SUB-COMPILE-FILE with
  35       ;; few changes. Once things are stable, the shared bindings
  36       ;; probably be merged back together into some shared utility
  37       ;; macro, or perhaps both merged into one of the existing utility
  38       ;; macros SB-C::WITH-COMPILATION-VALUES or
  39       ;; CL:WITH-COMPILATION-UNIT.
  40       (let* (;; FIXME: Do we need the *INFO-ENVIRONMENT* rebinding
  41              ;; here? It's a literal translation of the old CMU CL
  42              ;; rebinding to (OR *BACKEND-INFO-ENVIRONMENT*
  43              ;; *INFO-ENVIRONMENT*), and it's not obvious whether the
  44              ;; rebinding to itself is needed now that SBCL doesn't
  45              ;; need *BACKEND-INFO-ENVIRONMENT*.
  46              (*info-environment* *info-environment*)
  47              (form (get-lambda-to-compile definition))
  48              (*source-info* (make-lisp-source-info form))
  49              (*toplevel-lambdas* ())
  50              (*block-compile* nil)
  51              (*compiler-error-bailout*
  52               (lambda (&optional error)
  53                 (declare (ignore error))
  54                 (compiler-mumble
  55                  "~2&fatal error, aborting compilation~%")
  56                 (return-from actually-compile (values nil t nil))))
  57              (*current-path* nil)
  58              (*last-source-context* nil)
  59              (*last-original-source* nil)
  60              (*last-source-form* nil)
  61              (*last-format-string* nil)
  62              (*last-format-args* nil)
  63              (*last-message-count* 0)
  64              (*gensym-counter* 0)
  65              ;; KLUDGE: This rebinding of policy is necessary so that
  66              ;; forms such as LOCALLY at the REPL actually extend the
  67              ;; compilation policy correctly.  However, there is an
  68              ;; invariant that is potentially violated: future
  69              ;; refactoring must not allow this to be done in the file
  70              ;; compiler.  At the moment we're clearly alright, as we
  71              ;; call %COMPILE with a core-object, not a fasl-stream,
  72              ;; but caveat future maintainers. -- CSR, 2002-10-27
  73              (*policy* (lexenv-policy *lexenv*))
  74              ;; see above
  75              (*handled-conditions* (lexenv-handled-conditions *lexenv*))
  76              ;; ditto
  77              (*disabled-package-locks* (lexenv-disabled-package-locks *lexenv*))
  78              ;; FIXME: ANSI doesn't say anything about CL:COMPILE
  79              ;; interacting with these variables, so we shouldn't. As
  80              ;; of SBCL 0.6.7, COMPILE-FILE controls its verbosity by
  81              ;; binding these variables, so as a quick hack we do so
  82              ;; too. But a proper implementation would have verbosity
  83              ;; controlled by function arguments and lexical variables.
  84              (*compile-verbose* nil)
  85              (*compile-print* nil))
  86         (handler-bind (((satisfies handle-condition-p) #'handle-condition-handler))
  87           (clear-stuff)
  88           (find-source-paths form 0)
  89           (%compile form (make-core-object)
  90                     :name name
  91                     :path '(original-source-start 0 0)))))))
  92
  93 (defun compile-in-lexenv (name definition lexenv)
  94   (multiple-value-bind (compiled-definition warnings-p failure-p)
  95       (if (compiled-function-p definition)
  96           (values definition nil nil)
  97           (actually-compile name definition lexenv))
  98     (cond (name
  99            (if (and (symbolp name)
 100                     (macro-function name))
 101                (setf (macro-function name) compiled-definition)
 102                (setf (fdefinition name) compiled-definition))
 103            (values name warnings-p failure-p))
 104           (t
 105            (values compiled-definition warnings-p failure-p)))))
 106
 107 (defun compile (name &optional (definition (or (macro-function name)
 108                                                (fdefinition name))))
 109   #!+sb-doc
 110   "Coerce DEFINITION (by default, the function whose name is NAME)
 111   to a compiled function, returning (VALUES THING WARNINGS-P FAILURE-P),
 112   where if NAME is NIL, THING is the result of compilation, and
 113   otherwise THING is NAME. When NAME is not NIL, the compiled function
 114   is also set into (MACRO-FUNCTION NAME) if NAME names a macro, or into
 115   (FDEFINITION NAME) otherwise."
 116   (compile-in-lexenv name definition (make-null-lexenv)))