src/compiler/target-main.lisp

   1 ;;;; functions from classic CMU CL src/compiler/main.lisp which are
   2 ;;;; needed only (and which may make sense only) on the
   3 ;;;; cross-compilation target, not the cross-compilation host
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15 \f
  16 ;;;; CL:COMPILE
  17
  18 (defun get-lambda-to-compile (definition-designator)
  19   (if (consp definition-designator)
  20       definition-designator
  21       (multiple-value-bind (definition env-p)
  22                            (function-lambda-expression definition-designator)
  23         (when env-p
  24           (error "~S was defined in a non-null environment."
  25                  definition-designator))
  26         (unless definition
  27           (error "can't find a definition for ~S" definition-designator))
  28         definition)))
  29
  30 ;;; Handle the nontrivial case of CL:COMPILE.
  31 (defun actually-compile (name definition *lexenv*)
  32   (with-compilation-values
  33     (sb!xc:with-compilation-unit ()
  34       ;; FIXME: These bindings were copied from SUB-COMPILE-FILE with
  35       ;; few changes. Once things are stable, the shared bindings
  36       ;; probably be merged back together into some shared utility
  37       ;; macro, or perhaps both merged into one of the existing utility
  38       ;; macros SB-C::WITH-COMPILATION-VALUES or
  39       ;; CL:WITH-COMPILATION-UNIT.
  40       (let* (;; FIXME: Do we need the *INFO-ENVIRONMENT* rebinding
  41              ;; here? It's a literal translation of the old CMU CL
  42              ;; rebinding to (OR *BACKEND-INFO-ENVIRONMENT*
  43              ;; *INFO-ENVIRONMENT*), and it's not obvious whether the
  44              ;; rebinding to itself is needed now that SBCL doesn't
  45              ;; need *BACKEND-INFO-ENVIRONMENT*.
  46              (*info-environment* *info-environment*)
  47              (form (get-lambda-to-compile definition))
  48              (*source-info* (make-lisp-source-info form))
  49              (*toplevel-lambdas* ())
  50              (*block-compile* nil)
  51              (*compiler-error-bailout*
  52               (lambda ()
  53                 (compiler-mumble
  54                  "~2&fatal error, aborting compilation~%")
  55                 (return-from actually-compile (values nil t nil))))
  56              (*current-path* nil)
  57              (*last-source-context* nil)
  58              (*last-original-source* nil)
  59              (*last-source-form* nil)
  60              (*last-format-string* nil)
  61              (*last-format-args* nil)
  62              (*last-message-count* 0)
  63              (*gensym-counter* 0)
  64              ;; KLUDGE: This rebinding of policy is necessary so that
  65              ;; forms such as LOCALLY at the REPL actually extend the
  66              ;; compilation policy correctly.  However, there is an
  67              ;; invariant that is potentially violated: future
  68              ;; refactoring must not allow this to be done in the file
  69              ;; compiler.  At the moment we're clearly alright, as we
  70              ;; call %COMPILE with a core-object, not a fasl-stream,
  71              ;; but caveat future maintainers. -- CSR, 2002-10-27
  72              (*policy* (lexenv-policy *lexenv*))
  73              ;; FIXME: ANSI doesn't say anything about CL:COMPILE
  74              ;; interacting with these variables, so we shouldn't. As
  75              ;; of SBCL 0.6.7, COMPILE-FILE controls its verbosity by
  76              ;; binding these variables, so as a quick hack we do so
  77              ;; too. But a proper implementation would have verbosity
  78              ;; controlled by function arguments and lexical variables.
  79              (*compile-verbose* nil)
  80              (*compile-print* nil))
  81         (clear-stuff)
  82         (find-source-paths form 0)
  83         (%compile form (make-core-object)
  84                   :name name
  85                   :path '(original-source-start 0 0))))))
  86
  87 (defun compile-in-lexenv (name definition lexenv)
  88   (multiple-value-bind (compiled-definition warnings-p failure-p)
  89       (if (compiled-function-p definition)
  90           (values definition nil nil)
  91           (actually-compile name definition lexenv))
  92     (cond (name
  93            (if (and (symbolp name)
  94                     (macro-function name))
  95                (setf (macro-function name) compiled-definition)
  96                (setf (fdefinition name) compiled-definition))
  97            (values name warnings-p failure-p))
  98           (t
  99            (values compiled-definition warnings-p failure-p)))))
 100
 101 (defun compile (name &optional (definition (or (macro-function name)
 102                                                (fdefinition name))))
 103   #!+sb-doc
 104   "Coerce DEFINITION (by default, the function whose name is NAME)
 105   to a compiled function, returning (VALUES THING WARNINGS-P FAILURE-P),
 106   where if NAME is NIL, THING is the result of compilation, and
 107   otherwise THING is NAME. When NAME is not NIL, the compiled function
 108   is also set into (MACRO-FUNCTION NAME) if NAME names a macro, or into
 109   (FDEFINITION NAME) otherwise."
 110   (compile-in-lexenv name definition (make-null-lexenv)))