src/compiler/target-main.lisp

   1 ;;;; functions from classic CMU CL src/compiler/main.lisp which are
   2 ;;;; needed only (and which may make sense only) on the
   3 ;;;; cross-compilation target, not the cross-compilation host
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15 \f
  16 ;;;; CL:COMPILE
  17
  18 (defun get-lambda-to-compile (definition-designator)
  19   (if (consp definition-designator)
  20       definition-designator
  21       (multiple-value-bind (definition env-p)
  22                            (function-lambda-expression definition-designator)
  23         (when env-p
  24           (error "~S was defined in a non-null environment."
  25                  definition-designator))
  26         (unless definition
  27           (error "can't find a definition for ~S" definition-designator))
  28         definition)))
  29
  30 ;;; Handle the nontrivial case of CL:COMPILE.
  31 (defun actually-compile (name definition *lexenv*)
  32   (with-compilation-values
  33     (sb!xc:with-compilation-unit ()
  34       ;; FIXME: These bindings were copied from SUB-COMPILE-FILE with
  35       ;; few changes. Once things are stable, the shared bindings
  36       ;; probably be merged back together into some shared utility
  37       ;; macro, or perhaps both merged into one of the existing utility
  38       ;; macros SB-C::WITH-COMPILATION-VALUES or
  39       ;; CL:WITH-COMPILATION-UNIT.
  40       (let* (;; FIXME: Do we need the *INFO-ENVIRONMENT* rebinding
  41              ;; here? It's a literal translation of the old CMU CL
  42              ;; rebinding to (OR *BACKEND-INFO-ENVIRONMENT*
  43              ;; *INFO-ENVIRONMENT*), and it's not obvious whether the
  44              ;; rebinding to itself is needed now that SBCL doesn't
  45              ;; need *BACKEND-INFO-ENVIRONMENT*.
  46              (*info-environment* *info-environment*)
  47              (form (get-lambda-to-compile definition))
  48              (*source-info* (make-lisp-source-info form))
  49              (*toplevel-lambdas* ())
  50              (*block-compile* nil)
  51              (*allow-instrumenting* nil)
  52              (*compiler-error-bailout*
  53               (lambda (&optional error)
  54                 (declare (ignore error))
  55                 (compiler-mumble
  56                  "~2&fatal error, aborting compilation~%")
  57                 (return-from actually-compile (values nil t nil))))
  58              (*current-path* nil)
  59              (*last-source-context* nil)
  60              (*last-original-source* nil)
  61              (*last-source-form* nil)
  62              (*last-format-string* nil)
  63              (*last-format-args* nil)
  64              (*last-message-count* 0)
  65              (*last-error-context* nil)
  66              (*gensym-counter* 0)
  67              ;; KLUDGE: This rebinding of policy is necessary so that
  68              ;; forms such as LOCALLY at the REPL actually extend the
  69              ;; compilation policy correctly.  However, there is an
  70              ;; invariant that is potentially violated: future
  71              ;; refactoring must not allow this to be done in the file
  72              ;; compiler.  At the moment we're clearly alright, as we
  73              ;; call %COMPILE with a core-object, not a fasl-stream,
  74              ;; but caveat future maintainers. -- CSR, 2002-10-27
  75              (*policy* (lexenv-policy *lexenv*))
  76              ;; see above
  77              (*handled-conditions* (lexenv-handled-conditions *lexenv*))
  78              ;; ditto
  79              (*disabled-package-locks* (lexenv-disabled-package-locks *lexenv*))
  80              ;; FIXME: ANSI doesn't say anything about CL:COMPILE
  81              ;; interacting with these variables, so we shouldn't. As
  82              ;; of SBCL 0.6.7, COMPILE-FILE controls its verbosity by
  83              ;; binding these variables, so as a quick hack we do so
  84              ;; too. But a proper implementation would have verbosity
  85              ;; controlled by function arguments and lexical variables.
  86              (*compile-verbose* nil)
  87              (*compile-print* nil))
  88         (handler-bind (((satisfies handle-condition-p) #'handle-condition-handler))
  89           (clear-stuff)
  90           (find-source-paths form 0)
  91           (%compile form (make-core-object)
  92                     :name name
  93                     :path '(original-source-start 0 0)))))))
  94
  95 (defun compile-in-lexenv (name definition lexenv)
  96   (multiple-value-bind (compiled-definition warnings-p failure-p)
  97       (if (compiled-function-p definition)
  98           (values definition nil nil)
  99           (actually-compile name definition lexenv))
 100     (cond (name
 101            (if (and (symbolp name)
 102                     (macro-function name))
 103                (setf (macro-function name) compiled-definition)
 104                (setf (fdefinition name) compiled-definition))
 105            (values name warnings-p failure-p))
 106           (t
 107            (values compiled-definition warnings-p failure-p)))))
 108
 109 (defun compile (name &optional (definition (or (macro-function name)
 110                                                (fdefinition name))))
 111   #!+sb-doc
 112   "Coerce DEFINITION (by default, the function whose name is NAME)
 113   to a compiled function, returning (VALUES THING WARNINGS-P FAILURE-P),
 114   where if NAME is NIL, THING is the result of compilation, and
 115   otherwise THING is NAME. When NAME is not NIL, the compiled function
 116   is also set into (MACRO-FUNCTION NAME) if NAME names a macro, or into
 117   (FDEFINITION NAME) otherwise."
 118   (multiple-value-bind (function warnings-p failure-p)
 119       (compile-in-lexenv name definition (make-null-lexenv))
 120     (values (or function
 121                 name
 122                 (lambda (&rest arguments)
 123                   (error 'simple-program-error
 124                          :format-control
 125                          "Called function compiled with errors. Original ~
 126                           definition:~%  ~S~@[~%Arguments:~% ~{ ~S~}~]"
 127                          :format-arguments (list definition arguments))))
 128             warnings-p
 129             failure-p)))