src/compiler/typetran.lisp

   1 ;;;; This file contains stuff that implements the portable IR1
   2 ;;;; semantics of type tests and coercion. The main thing we do is
   3 ;;;; convert complex type operations into simpler code that can be
   4 ;;;; compiled inline.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!C")
  16 \f
  17 ;;;; type predicate translation
  18 ;;;;
  19 ;;;; We maintain a bidirectional association between type predicates
  20 ;;;; and the tested type. The presence of a predicate in this
  21 ;;;; association implies that it is desirable to implement tests of
  22 ;;;; this type using the predicate. These are either predicates that
  23 ;;;; the back end is likely to have special knowledge about, or
  24 ;;;; predicates so complex that the only reasonable implentation is
  25 ;;;; via function call.
  26 ;;;;
  27 ;;;; Some standard types (such as SEQUENCE) are best tested by letting
  28 ;;;; the TYPEP source transform do its thing with the expansion. These
  29 ;;;; types (and corresponding predicates) are not maintained in this
  30 ;;;; association. In this case, there need not be any predicate
  31 ;;;; function unless it is required by the Common Lisp specification.
  32 ;;;;
  33 ;;;; The mapping between predicates and type structures is considered
  34 ;;;; part of the backend; different backends can support different
  35 ;;;; sets of predicates.
  36
  37 ;;; Establish an association between the type predicate NAME and the
  38 ;;; corresponding TYPE. This causes the type predicate to be
  39 ;;; recognized for purposes of optimization.
  40 (defmacro define-type-predicate (name type)
  41   `(%define-type-predicate ',name ',type))
  42 (defun %define-type-predicate (name specifier)
  43   (let ((type (specifier-type specifier)))
  44     (setf (gethash name *backend-predicate-types*) type)
  45     (setf *backend-type-predicates*
  46           (cons (cons type name)
  47                 (remove name *backend-type-predicates*
  48                         :key #'cdr)))
  49     (%deftransform name '(function (t) *) #'fold-type-predicate)
  50     name))
  51 \f
  52 ;;;; IR1 transforms
  53
  54 ;;; If we discover the type argument is constant during IR1
  55 ;;; optimization, then give the source transform another chance. The
  56 ;;; source transform can't pass, since we give it an explicit
  57 ;;; constant. At worst, it will convert to %TYPEP, which will prevent
  58 ;;; spurious attempts at transformation (and possible repeated
  59 ;;; warnings.)
  60 (deftransform typep ((object type))
  61   (unless (constant-continuation-p type)
  62     (give-up-ir1-transform "can't open-code test of non-constant type"))
  63   `(typep object ',(continuation-value type)))
  64
  65 ;;; If the continuation OBJECT definitely is or isn't of the specified
  66 ;;; type, then return T or NIL as appropriate. Otherwise quietly
  67 ;;; GIVE-UP-IR1-TRANSFORM.
  68 (defun ir1-transform-type-predicate (object type)
  69   (declare (type continuation object) (type ctype type))
  70   (let ((otype (continuation-type object)))
  71     (cond ((not (types-equal-or-intersect otype type))
  72            nil)
  73           ((csubtypep otype type)
  74            t)
  75           ((eq type *empty-type*)
  76            nil)
  77           (t
  78            (give-up-ir1-transform)))))
  79
  80 ;;; Flush %TYPEP tests whose result is known at compile time.
  81 (deftransform %typep ((object type))
  82   (unless (constant-continuation-p type)
  83     (give-up-ir1-transform))
  84   (ir1-transform-type-predicate
  85    object
  86    (ir1-transform-specifier-type (continuation-value type))))
  87
  88 ;;; This is the IR1 transform for simple type predicates. It checks
  89 ;;; whether the single argument is known to (not) be of the
  90 ;;; appropriate type, expanding to T or NIL as appropriate.
  91 (deftransform fold-type-predicate ((object) * * :node node :defun-only t)
  92   (let ((ctype (gethash (leaf-source-name
  93                          (ref-leaf
  94                           (continuation-use
  95                            (basic-combination-fun node))))
  96                         *backend-predicate-types*)))
  97     (aver ctype)
  98     (ir1-transform-type-predicate object ctype)))
  99
 100 ;;; If FIND-CLASS is called on a constant class, locate the CLASS-CELL
 101 ;;; at load time.
 102 (deftransform find-classoid ((name) ((constant-arg symbol)) *)
 103   (let* ((name (continuation-value name))
 104          (cell (find-classoid-cell name)))
 105     `(or (classoid-cell-classoid ',cell)
 106          (error "class not yet defined: ~S" name))))
 107 \f
 108 ;;;; standard type predicates, i.e. those defined in package COMMON-LISP,
 109 ;;;; plus at least one oddball (%INSTANCEP)
 110 ;;;;
 111 ;;;; Various other type predicates (e.g. low-level representation
 112 ;;;; stuff like SIMPLE-ARRAY-SINGLE-FLOAT-P) are defined elsewhere.
 113
 114 ;;; FIXME: This function is only called once, at top level. Why not
 115 ;;; just expand all its operations into toplevel code?
 116 (defun !define-standard-type-predicates ()
 117   (define-type-predicate arrayp array)
 118   ; (The ATOM predicate is handled separately as (NOT CONS).)
 119   (define-type-predicate bit-vector-p bit-vector)
 120   (define-type-predicate characterp character)
 121   (define-type-predicate compiled-function-p compiled-function)
 122   (define-type-predicate complexp complex)
 123   (define-type-predicate complex-rational-p (complex rational))
 124   (define-type-predicate complex-float-p (complex float))
 125   (define-type-predicate consp cons)
 126   (define-type-predicate floatp float)
 127   (define-type-predicate functionp function)
 128   (define-type-predicate integerp integer)
 129   (define-type-predicate keywordp keyword)
 130   (define-type-predicate listp list)
 131   (define-type-predicate null null)
 132   (define-type-predicate numberp number)
 133   (define-type-predicate rationalp rational)
 134   (define-type-predicate realp real)
 135   (define-type-predicate simple-bit-vector-p simple-bit-vector)
 136   (define-type-predicate simple-string-p simple-string)
 137   (define-type-predicate simple-vector-p simple-vector)
 138   (define-type-predicate stringp string)
 139   (define-type-predicate %instancep instance)
 140   (define-type-predicate funcallable-instance-p funcallable-instance)
 141   (define-type-predicate symbolp symbol)
 142   (define-type-predicate vectorp vector))
 143 (!define-standard-type-predicates)
 144 \f
 145 ;;;; transforms for type predicates not implemented primitively
 146 ;;;;
 147 ;;;; See also VM dependent transforms.
 148
 149 (define-source-transform atom (x)
 150   `(not (consp ,x)))
 151 \f
 152 ;;;; TYPEP source transform
 153
 154 ;;; Return a form that tests the variable N-OBJECT for being in the
 155 ;;; binds specified by TYPE. BASE is the name of the base type, for
 156 ;;; declaration. We make SAFETY locally 0 to inhibit any checking of
 157 ;;; this assertion.
 158 #!-negative-zero-is-not-zero
 159 (defun transform-numeric-bound-test (n-object type base)
 160   (declare (type numeric-type type))
 161   (let ((low (numeric-type-low type))
 162         (high (numeric-type-high type)))
 163     `(locally
 164        (declare (optimize (safety 0)))
 165        (and ,@(when low
 166                 (if (consp low)
 167                     `((> (the ,base ,n-object) ,(car low)))
 168                     `((>= (the ,base ,n-object) ,low))))
 169             ,@(when high
 170                 (if (consp high)
 171                     `((< (the ,base ,n-object) ,(car high)))
 172                     `((<= (the ,base ,n-object) ,high))))))))
 173
 174 #!+negative-zero-is-not-zero
 175 (defun transform-numeric-bound-test (n-object type base)
 176   (declare (type numeric-type type))
 177   (let ((low (numeric-type-low type))
 178         (high (numeric-type-high type))
 179         (float-type-p (csubtypep type (specifier-type 'float)))
 180         (x (gensym))
 181         (y (gensym)))
 182     `(locally
 183        (declare (optimize (safety 0)))
 184        (and ,@(when low
 185                 (if (consp low)
 186                     `((let ((,x (the ,base ,n-object))
 187                             (,y ,(car low)))
 188                         ,(if (not float-type-p)
 189                             `(> ,x ,y)
 190                             `(if (and (zerop ,x) (zerop ,y))
 191                                  (> (float-sign ,x) (float-sign ,y))
 192                                  (> ,x ,y)))))
 193                     `((let ((,x (the ,base ,n-object))
 194                             (,y ,low))
 195                         ,(if (not float-type-p)
 196                             `(>= ,x ,y)
 197                             `(if (and (zerop ,x) (zerop ,y))
 198                                  (>= (float-sign ,x) (float-sign ,y))
 199                                  (>= ,x ,y)))))))
 200             ,@(when high
 201                 (if (consp high)
 202                     `((let ((,x (the ,base ,n-object))
 203                             (,y ,(car high)))
 204                         ,(if (not float-type-p)
 205                              `(< ,x ,y)
 206                              `(if (and (zerop ,x) (zerop ,y))
 207                                   (< (float-sign ,x) (float-sign ,y))
 208                                   (< ,x ,y)))))
 209                     `((let ((,x (the ,base ,n-object))
 210                             (,y ,high))
 211                         ,(if (not float-type-p)
 212                              `(<= ,x ,y)
 213                              `(if (and (zerop ,x) (zerop ,y))
 214                                   (<= (float-sign ,x) (float-sign ,y))
 215                                   (<= ,x ,y)))))))))))
 216
 217 ;;; Do source transformation of a test of a known numeric type. We can
 218 ;;; assume that the type doesn't have a corresponding predicate, since
 219 ;;; those types have already been picked off. In particular, CLASS
 220 ;;; must be specified, since it is unspecified only in NUMBER and
 221 ;;; COMPLEX. Similarly, we assume that COMPLEXP is always specified.
 222 ;;;
 223 ;;; For non-complex types, we just test that the number belongs to the
 224 ;;; base type, and then test that it is in bounds. When CLASS is
 225 ;;; INTEGER, we check to see whether the range is no bigger than
 226 ;;; FIXNUM. If so, we check for FIXNUM instead of INTEGER. This allows
 227 ;;; us to use fixnum comparison to test the bounds.
 228 ;;;
 229 ;;; For complex types, we must test for complex, then do the above on
 230 ;;; both the real and imaginary parts. When CLASS is float, we need
 231 ;;; only check the type of the realpart, since the format of the
 232 ;;; realpart and the imagpart must be the same.
 233 (defun source-transform-numeric-typep (object type)
 234   (let* ((class (numeric-type-class type))
 235          (base (ecase class
 236                  (integer (containing-integer-type type))
 237                  (rational 'rational)
 238                  (float (or (numeric-type-format type) 'float))
 239                  ((nil) 'real))))
 240     (once-only ((n-object object))
 241       (ecase (numeric-type-complexp type)
 242         (:real
 243          `(and (typep ,n-object ',base)
 244                ,(transform-numeric-bound-test n-object type base)))
 245         (:complex
 246          `(and (complexp ,n-object)
 247                ,(once-only ((n-real `(realpart (the complex ,n-object)))
 248                             (n-imag `(imagpart (the complex ,n-object))))
 249                   `(progn
 250                      ,n-imag ; ignorable
 251                      (and (typep ,n-real ',base)
 252                           ,@(when (eq class 'integer)
 253                               `((typep ,n-imag ',base)))
 254                           ,(transform-numeric-bound-test n-real type base)
 255                           ,(transform-numeric-bound-test n-imag type
 256                                                          base))))))))))
 257
 258 ;;; Do the source transformation for a test of a hairy type. AND,
 259 ;;; SATISFIES and NOT are converted into the obvious code. We convert
 260 ;;; unknown types to %TYPEP, emitting an efficiency note if
 261 ;;; appropriate.
 262 (defun source-transform-hairy-typep (object type)
 263   (declare (type hairy-type type))
 264   (let ((spec (hairy-type-specifier type)))
 265     (cond ((unknown-type-p type)
 266            (when (policy *lexenv* (> speed inhibit-warnings))
 267              (compiler-note "can't open-code test of unknown type ~S"
 268                             (type-specifier type)))
 269            `(%typep ,object ',spec))
 270           (t
 271            (ecase (first spec)
 272              (satisfies `(if (funcall #',(second spec) ,object) t nil))
 273              ((not and)
 274               (once-only ((n-obj object))
 275                 `(,(first spec) ,@(mapcar (lambda (x)
 276                                             `(typep ,n-obj ',x))
 277                                           (rest spec))))))))))
 278
 279 (defun source-transform-negation-typep (object type)
 280   (declare (type negation-type type))
 281   (let ((spec (type-specifier (negation-type-type type))))
 282     `(not (typep ,object ',spec))))
 283
 284 ;;; Do source transformation for TYPEP of a known union type. If a
 285 ;;; union type contains LIST, then we pull that out and make it into a
 286 ;;; single LISTP call. Note that if SYMBOL is in the union, then LIST
 287 ;;; will be a subtype even without there being any (member NIL). We
 288 ;;; just drop through to the general code in this case, rather than
 289 ;;; trying to optimize it.
 290 (defun source-transform-union-typep (object type)
 291   (let* ((types (union-type-types type))
 292          (ltype (specifier-type 'list))
 293          (mtype (find-if #'member-type-p types)))
 294     (if (and mtype (csubtypep ltype type))
 295         (let ((members (member-type-members mtype)))
 296           (once-only ((n-obj object))
 297             `(or (listp ,n-obj)
 298                  (typep ,n-obj
 299                         '(or ,@(mapcar #'type-specifier
 300                                        (remove (specifier-type 'cons)
 301                                                (remove mtype types)))
 302                              (member ,@(remove nil members)))))))
 303         (once-only ((n-obj object))
 304           `(or ,@(mapcar (lambda (x)
 305                            `(typep ,n-obj ',(type-specifier x)))
 306                          types))))))
 307
 308 ;;; Do source transformation for TYPEP of a known intersection type.
 309 (defun source-transform-intersection-typep (object type)
 310   (once-only ((n-obj object))
 311     `(and ,@(mapcar (lambda (x)
 312                       `(typep ,n-obj ',(type-specifier x)))
 313                     (intersection-type-types type)))))
 314
 315 ;;; If necessary recurse to check the cons type.
 316 (defun source-transform-cons-typep (object type)
 317   (let* ((car-type (cons-type-car-type type))
 318          (cdr-type (cons-type-cdr-type type)))
 319     (let ((car-test-p (not (or (type= car-type *wild-type*)
 320                                (type= car-type (specifier-type t)))))
 321           (cdr-test-p (not (or (type= cdr-type *wild-type*)
 322                                (type= cdr-type (specifier-type t))))))
 323       (if (and (not car-test-p) (not cdr-test-p))
 324           `(consp ,object)
 325           (once-only ((n-obj object))
 326             `(and (consp ,n-obj)
 327                   ,@(if car-test-p
 328                         `((typep (car ,n-obj)
 329                                  ',(type-specifier car-type))))
 330                   ,@(if cdr-test-p
 331                         `((typep (cdr ,n-obj)
 332                                  ',(type-specifier cdr-type))))))))))
 333
 334 ;;; Return the predicate and type from the most specific entry in
 335 ;;; *TYPE-PREDICATES* that is a supertype of TYPE.
 336 (defun find-supertype-predicate (type)
 337   (declare (type ctype type))
 338   (let ((res nil)
 339         (res-type nil))
 340     (dolist (x *backend-type-predicates*)
 341       (let ((stype (car x)))
 342         (when (and (csubtypep type stype)
 343                    (or (not res-type)
 344                        (csubtypep stype res-type)))
 345           (setq res-type stype)
 346           (setq res (cdr x)))))
 347     (values res res-type)))
 348
 349 ;;; Return forms to test that OBJ has the rank and dimensions
 350 ;;; specified by TYPE, where STYPE is the type we have checked against
 351 ;;; (which is the same but for dimensions.)
 352 (defun test-array-dimensions (obj type stype)
 353   (declare (type array-type type stype))
 354   (let ((obj `(truly-the ,(type-specifier stype) ,obj))
 355         (dims (array-type-dimensions type)))
 356     (unless (eq dims '*)
 357       (collect ((res))
 358         (when (eq (array-type-dimensions stype) '*)
 359           (res `(= (array-rank ,obj) ,(length dims))))
 360         (do ((i 0 (1+ i))
 361              (dim dims (cdr dim)))
 362             ((null dim))
 363           (let ((dim (car dim)))
 364             (unless (eq dim '*)
 365               (res `(= (array-dimension ,obj ,i) ,dim)))))
 366         (res)))))
 367
 368 ;;; If we can find a type predicate that tests for the type without
 369 ;;; dimensions, then use that predicate and test for dimensions.
 370 ;;; Otherwise, just do %TYPEP.
 371 (defun source-transform-array-typep (obj type)
 372   (multiple-value-bind (pred stype) (find-supertype-predicate type)
 373     (if (and (array-type-p stype)
 374              ;; (If the element type hasn't been defined yet, it's
 375              ;; not safe to assume here that it will eventually
 376              ;; have (UPGRADED-ARRAY-ELEMENT-TYPE type)=T, so punt.)
 377              (not (unknown-type-p (array-type-element-type type)))
 378              (type= (array-type-specialized-element-type stype)
 379                     (array-type-specialized-element-type type))
 380              (eq (array-type-complexp stype) (array-type-complexp type)))
 381         (once-only ((n-obj obj))
 382           `(and (,pred ,n-obj)
 383                 ,@(test-array-dimensions n-obj type stype)))
 384         `(%typep ,obj ',(type-specifier type)))))
 385
 386 ;;; Transform a type test against some instance type. The type test is
 387 ;;; flushed if the result is known at compile time. If not properly
 388 ;;; named, error. If sealed and has no subclasses, just test for
 389 ;;; layout-EQ. If a structure then test for layout-EQ and then a
 390 ;;; general test based on layout-inherits. If safety is important,
 391 ;;; then we also check whether the layout for the object is invalid
 392 ;;; and signal an error if so. Otherwise, look up the indirect
 393 ;;; class-cell and call CLASS-CELL-TYPEP at runtime.
 394 (deftransform %instance-typep ((object spec) (* *) * :node node)
 395   (aver (constant-continuation-p spec))
 396   (let* ((spec (continuation-value spec))
 397          (class (specifier-type spec))
 398          (name (classoid-name class))
 399          (otype (continuation-type object))
 400          (layout (let ((res (info :type :compiler-layout name)))
 401                    (if (and res (not (layout-invalid res)))
 402                        res
 403                        nil))))
 404     (cond
 405       ;; Flush tests whose result is known at compile time.
 406       ((not (types-equal-or-intersect otype class))
 407        nil)
 408       ((csubtypep otype class)
 409        t)
 410       ;; If not properly named, error.
 411       ((not (and name (eq (find-classoid name) class)))
 412        (compiler-error "can't compile TYPEP of anonymous or undefined ~
 413                         class:~%  ~S"
 414                        class))
 415       (t
 416         ;; Delay the type transform to give type propagation a chance.
 417         (delay-ir1-transform node :constraint)
 418
 419        ;; Otherwise transform the type test.
 420        (multiple-value-bind (pred get-layout)
 421            (cond
 422              ((csubtypep class (specifier-type 'funcallable-instance))
 423               (values 'funcallable-instance-p '%funcallable-instance-layout))
 424              ((csubtypep class (specifier-type 'instance))
 425               (values '%instancep '%instance-layout))
 426              (t
 427               (values '(lambda (x) (declare (ignore x)) t) 'layout-of)))
 428          (cond
 429            ((and (eq (classoid-state class) :sealed) layout
 430                  (not (classoid-subclasses class)))
 431             ;; Sealed and has no subclasses.
 432             (let ((n-layout (gensym)))
 433               `(and (,pred object)
 434                     (let ((,n-layout (,get-layout object)))
 435                       ,@(when (policy *lexenv* (>= safety speed))
 436                               `((when (layout-invalid ,n-layout)
 437                                   (%layout-invalid-error object ',layout))))
 438                       (eq ,n-layout ',layout)))))
 439            ((and (typep class 'basic-structure-classoid) layout)
 440             ;; structure type tests; hierarchical layout depths
 441             (let ((depthoid (layout-depthoid layout))
 442                   (n-layout (gensym)))
 443               `(and (,pred object)
 444                     (let ((,n-layout (,get-layout object)))
 445                       ,@(when (policy *lexenv* (>= safety speed))
 446                               `((when (layout-invalid ,n-layout)
 447                                   (%layout-invalid-error object ',layout))))
 448                       (if (eq ,n-layout ',layout)
 449                           t
 450                           (and (> (layout-depthoid ,n-layout)
 451                                   ,depthoid)
 452                                (locally (declare (optimize (safety 0)))
 453                                  (eq (svref (layout-inherits ,n-layout)
 454                                             ,depthoid)
 455                                      ',layout))))))))
 456            ((and layout (>= (layout-depthoid layout) 0))
 457             ;; hierarchical layout depths for other things (e.g.
 458             ;; CONDITIONs)
 459             (let ((depthoid (layout-depthoid layout))
 460                   (n-layout (gensym))
 461                   (n-inherits (gensym)))
 462               `(and (,pred object)
 463                     (let ((,n-layout (,get-layout object)))
 464                       ,@(when (policy *lexenv* (>= safety speed))
 465                           `((when (layout-invalid ,n-layout)
 466                               (%layout-invalid-error object ',layout))))
 467                       (if (eq ,n-layout ',layout)
 468                           t
 469                           (let ((,n-inherits (layout-inherits ,n-layout)))
 470                             (declare (optimize (safety 0)))
 471                             (and (> (length ,n-inherits) ,depthoid)
 472                                  (eq (svref ,n-inherits ,depthoid)
 473                                      ',layout))))))))
 474            (t
 475             (/noshow "default case -- ,PRED and CLASS-CELL-TYPEP")
 476             `(and (,pred object)
 477                   (classoid-cell-typep (,get-layout object)
 478                                        ',(find-classoid-cell name)
 479                                        object)))))))))
 480
 481 ;;; If the specifier argument is a quoted constant, then we consider
 482 ;;; converting into a simple predicate or other stuff. If the type is
 483 ;;; constant, but we can't transform the call, then we convert to
 484 ;;; %TYPEP. We only pass when the type is non-constant. This allows us
 485 ;;; to recognize between calls that might later be transformed
 486 ;;; successfully when a constant type is discovered. We don't give an
 487 ;;; efficiency note when we pass, since the IR1 transform will give
 488 ;;; one if necessary and appropriate.
 489 ;;;
 490 ;;; If the type is TYPE= to a type that has a predicate, then expand
 491 ;;; to that predicate. Otherwise, we dispatch off of the type's type.
 492 ;;; These transformations can increase space, but it is hard to tell
 493 ;;; when, so we ignore policy and always do them.
 494 (define-source-transform typep (object spec)
 495   ;; KLUDGE: It looks bad to only do this on explicitly quoted forms,
 496   ;; since that would overlook other kinds of constants. But it turns
 497   ;; out that the DEFTRANSFORM for TYPEP detects any constant
 498   ;; continuation, transforms it into a quoted form, and gives this
 499   ;; source transform another chance, so it all works out OK, in a
 500   ;; weird roundabout way. -- WHN 2001-03-18
 501   (if (and (consp spec) (eq (car spec) 'quote))
 502       (let ((type (careful-specifier-type (cadr spec))))
 503         (or (when (not type)
 504               (compiler-warn "illegal type specifier for TYPEP: ~S"
 505                              (cadr spec))
 506               `(%typep ,object ,spec))
 507             (let ((pred (cdr (assoc type *backend-type-predicates*
 508                                     :test #'type=))))
 509               (when pred `(,pred ,object)))
 510             (typecase type
 511               (hairy-type
 512                (source-transform-hairy-typep object type))
 513               (negation-type
 514                (source-transform-negation-typep object type))
 515               (union-type
 516                (source-transform-union-typep object type))
 517               (intersection-type
 518                (source-transform-intersection-typep object type))
 519               (member-type
 520                `(member ,object ',(member-type-members type)))
 521               (args-type
 522                (compiler-warn "illegal type specifier for TYPEP: ~S"
 523                               (cadr spec))
 524                `(%typep ,object ,spec))
 525               (t nil))
 526             (typecase type
 527               (numeric-type
 528                (source-transform-numeric-typep object type))
 529               (classoid
 530                `(%instance-typep ,object ,spec))
 531               (array-type
 532                (source-transform-array-typep object type))
 533               (cons-type
 534                (source-transform-cons-typep object type))
 535               (t nil))
 536             `(%typep ,object ,spec)))
 537       (values nil t)))
 538 \f
 539 ;;;; coercion
 540
 541 (deftransform coerce ((x type) (* *) * :node node)
 542   (unless (constant-continuation-p type)
 543     (give-up-ir1-transform))
 544   (let ((tspec (ir1-transform-specifier-type (continuation-value type))))
 545     (if (csubtypep (continuation-type x) tspec)
 546         'x
 547         ;; Note: The THE here makes sure that specifiers like
 548         ;; (SINGLE-FLOAT 0.0 1.0) can raise a TYPE-ERROR.
 549         `(the ,(continuation-value type)
 550            ,(cond
 551              ((csubtypep tspec (specifier-type 'double-float))
 552               '(%double-float x))
 553              ;; FIXME: #!+long-float (t ,(error "LONG-FLOAT case needed"))
 554              ((csubtypep tspec (specifier-type 'float))
 555               '(%single-float x))
 556              ((and (csubtypep tspec (specifier-type 'simple-vector))
 557                    (policy node (< safety 3)))
 558               `(if (simple-vector-p x)
 559                    x
 560                    (replace (make-array (length x)) x)))
 561              ;; FIXME: other VECTOR types?
 562              (t
 563               (give-up-ir1-transform)))))))
 564